configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [4])
   4 m4_define([gst_vaapi_micro_version], [0])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # glib version number
  13 m4_define([glib_major_version], [2])
  14 m4_define([glib_minor_version], [28])
  15 m4_define([glib_micro_version], [0])
  16 m4_define([glib_major_minor_version],
  17           [glib_major_version.glib_minor_version])
  18 m4_define([glib_version],
  19           [glib_major_version.glib_minor_version.glib_micro_version])
  20
  21 # gst version number
  22 m4_define([gst_major_version], [0])
  23 m4_define([gst_minor_version], [10])
  24 m4_define([gst_micro_version], [14])
  25 m4_define([gst_major_minor_version],
  26           [gst_major_version.gst_minor_version])
  27 m4_define([gst_version],
  28           [gst_major_version.gst_minor_version.gst_micro_version])
  29
  30 # gst plugins-base version number
  31 m4_define([gst_plugins_base_major_version], [0])
  32 m4_define([gst_plugins_base_minor_version], [10])
  33 m4_define([gst_plugins_base_micro_version], [31])
  34 m4_define([gst_plugins_base_version],
  35           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  36
  37 # gst plugins-bad version number
  38 m4_define([gst_plugins_bad_major_version], [0])
  39 m4_define([gst_plugins_bad_minor_version], [10])
  40 m4_define([gst_plugins_bad_micro_version], [22])
  41 m4_define([gst_plugins_bad_version],
  42           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
  43
  44 # VA-API minimum version number
  45 m4_define([va_api_version],     [0.30.4])
  46 m4_define([va_api_drm_version], [0.34.0])
  47 m4_define([va_api_x11_version], [0.31.0])
  48 m4_define([va_api_glx_version], [0.32.0])
  49 m4_define([va_api_wld_version], [0.34.0])
  50 m4_define([va_api_tpi_version], [0.33.0])
  51
  52 # libva package version number
  53 m4_define([libva_drm_package_version], [1.2.0])
  54 m4_define([libva_x11_package_version], [1.0.3])
  55 m4_define([libva_glx_package_version], [1.0.9])
  56 m4_define([libva_wld_package_version], [1.2.0])
  57
  58 # gtk-doc version number
  59 # XXX: introspection annotations require gtk-doc >= 1.12
  60 m4_define([gtkdoc_major_version], [1])
  61 m4_define([gtkdoc_minor_version], [9])
  62 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  63
  64 AC_PREREQ([2.58])
  65 AC_INIT([gst_vaapi], [gst_vaapi_version],
  66     [gwenole.beauchesne@intel.com],
  67     [gstreamer-vaapi])
  68
  69 AC_CONFIG_HEADERS([config.h])
  70 AC_CONFIG_SRCDIR([Makefile.am])
  71 AC_CONFIG_MACRO_DIR([m4])
  72 AC_CONFIG_AUX_DIR([build-aux])
  73
  74 AC_CANONICAL_TARGET
  75
  76 AM_INIT_AUTOMAKE
  77
  78 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  79 AC_SUBST(TODAY)
  80
  81 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
  82 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  83
  84 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  85 AC_SUBST(LIBVA_PACKAGE_VERSION)
  86
  87 dnl Versions for GStreamer and plugins-base
  88 GST_MAJORMINOR=gst_major_minor_version
  89 GST_VERSION_REQUIRED=gst_version
  90 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
  91 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
  92 AC_SUBST(GST_MAJORMINOR)
  93 AC_SUBST(GST_VERSION_REQUIRED)
  94 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
  95 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
  96
  97 dnl Use pretty build output with automake >= 1.11
  98 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  99   AM_DEFAULT_VERBOSITY=1
 100   AC_SUBST(AM_DEFAULT_VERBOSITY)
 101 ])
 102
 103 dnl Check for tools
 104 AC_PROG_CC
 105 AM_PROG_CC_C_O
 106
 107 dnl Initialize libtool
 108 LT_PREREQ([2.2])
 109 LT_INIT
 110
 111 AC_ARG_ENABLE(drm,
 112     AS_HELP_STRING([--enable-drm],
 113                    [enable DRM backend @<:@default=yes@:>@]),
 114     [], [enable_drm="yes"])
 115
 116 AC_ARG_ENABLE(x11,
 117     AS_HELP_STRING([--enable-x11],
 118                    [enable X11 output @<:@default=yes@:>@]),
 119     [], [enable_x11="yes"])
 120
 121 AC_ARG_ENABLE(glx,
 122     AS_HELP_STRING([--enable-glx],
 123                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
 124     [], [enable_glx="yes"])
 125
 126 AC_ARG_ENABLE(wayland,
 127     AC_HELP_STRING([--enable-wayland],
 128                    [enable Wayland output @<:@default=yes@:>@]),
 129     [], [enable_wayland="yes"])
 130
 131 AC_ARG_ENABLE(encoders,
 132     AC_HELP_STRING([--enable-encoders],
 133                    [enable encoders @<:@default=no@:>@]),
 134     [], [enable_encoders="no"])
 135
 136 dnl Check for basic libraries
 137 AC_CHECK_LIB(m, tan)
 138
 139 dnl Check for Gtk doc
 140 GTKDOC_VERSION=gtkdoc_version
 141 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 142 m4_ifdef([GTK_DOC_CHECK], [
 143 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 144 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 145 AC_SUBST(GTKDOC_VERSION)
 146
 147 dnl Check for GLib
 148 GLIB_VERSION_REQUIRED=glib_version
 149 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 150 AC_SUBST(GLIB_VERSION_REQUIRED)
 151
 152 dnl ---------------------------------------------------------------------------
 153 dnl -- GStreamer                                                             --
 154 dnl ---------------------------------------------------------------------------
 155
 156 dnl GStreamer Core
 157 PKG_CHECK_MODULES([GST],      [gstreamer-$GST_MAJORMINOR >= gst_version])
 158 PKG_CHECK_MODULES([GST_BASE], [gstreamer-base-$GST_MAJORMINOR >= gst_version])
 159
 160 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 161     saved_CFLAGS="$CFLAGS"
 162     CFLAGS="$CFLAGS $GST_BASE_CFLAGS"
 163     saved_LIBS="$LIBS"
 164     LIBS="$LIBS $GST_BASE_LIBS"
 165     AC_COMPILE_IFELSE(
 166         [AC_LANG_PROGRAM(
 167             [[#include <gst/base/gstbasesink.h>]],
 168             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 169         [ac_cv_have_gst_base_sink_query="yes"],
 170         [ac_cv_have_gst_base_sink_query="no"]
 171     )
 172     CFLAGS="$saved_CFLAGS"
 173     LIBS="$saved_LIBS"
 174 ])
 175 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 176     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 177 fi
 178
 179 dnl GStreamer -base plugins
 180 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 181     [gstreamer-plugins-base-$GST_MAJORMINOR >= gst_plugins_base_version])
 182 PKG_CHECK_MODULES([GST_INTERFACES],
 183     [gstreamer-interfaces-$GST_MAJORMINOR >= gst_plugins_base_version])
 184
 185 dnl ... GstVideoOverlayComposition (gstreamer-video)
 186 PKG_CHECK_MODULES([GST_VIDEO],
 187     [gstreamer-video-$GST_MAJORMINOR >= gst_plugins_base_version])
 188
 189 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 190     ac_cv_have_gst_video_overlay_composition, [
 191     saved_CFLAGS="$CFLAGS"
 192     CFLAGS="$CFLAGS $GST_CFLAGS"
 193     saved_LIBS="$LIBS"
 194     LIBS="$LIBS $GST_LIBS"
 195     AC_COMPILE_IFELSE(
 196         [AC_LANG_PROGRAM(
 197             [[#include <gst/video/video-overlay-composition.h>]],
 198             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
 199         [ac_cv_have_gst_video_overlay_composition="yes"],
 200         [ac_cv_have_gst_video_overlay_composition="no"]
 201     )
 202     CFLAGS="$saved_CFLAGS"
 203     LIBS="$saved_LIBS"
 204 ])
 205 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 206     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 207 fi
 208
 209 dnl GStreamer -bad plugins
 210 PKG_CHECK_MODULES([GST_BASEVIDEO],
 211     [gstreamer-basevideo-$GST_MAJORMINOR >= gst_plugins_bad_version])
 212
 213 dnl ... bitstream parsers
 214 USE_CODEC_PARSERS=1
 215 USE_LOCAL_CODEC_PARSERS=0
 216
 217 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 218     [gstreamer-codecparsers-$GST_MAJORMINOR >= gst_plugins_bad_version])
 219
 220 dnl ... 0.10.23 addition, could be implemented otherwise
 221 AC_CACHE_CHECK([for GstH264SliceHdr::n_emulation_prevention_bytes],
 222     ac_cv_have_gst_h264_slice_hdr_epb_count, [
 223     saved_CFLAGS="$CFLAGS"
 224     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 225     saved_LIBS="$LIBS"
 226     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 227     AC_COMPILE_IFELSE(
 228         [AC_LANG_PROGRAM(
 229             [[#include <gst/codecparsers/gsth264parser.h>]],
 230             [[GstH264SliceHdr slice_hdr;
 231               slice_hdr.n_emulation_prevention_bytes = 0;]])],
 232         [ac_cv_have_gst_h264_slice_hdr_epb_count="yes"],
 233         [ac_cv_have_gst_h264_slice_hdr_epb_count="no"]
 234     )
 235     CFLAGS="$saved_CFLAGS"
 236     LIBS="$saved_LIBS"
 237 ])
 238
 239 if test "$ac_cv_have_gst_h264_slice_hdr_epb_count" = "yes"; then
 240     AC_DEFINE_UNQUOTED(HAVE_GST_H264_SLICE_HDR_EPB_COUNT, 1,
 241         [Defined to 1 if GstH264SliceHdr::n_emulation_prevention_bytes exists.])
 242 fi
 243
 244 dnl ... JPEG parser, not upstream yet
 245 AC_CACHE_CHECK([for JPEG parser],
 246     ac_cv_have_gst_jpeg_parser, [
 247     saved_CFLAGS="$CFLAGS"
 248     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 249     saved_LIBS="$LIBS"
 250     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 251     AC_COMPILE_IFELSE(
 252         [AC_LANG_PROGRAM(
 253             [[#include <gst/codecparsers/gstjpegparser.h>]],
 254             [[GstJpegImage jpeg_image;]])],
 255         [ac_cv_have_gst_jpeg_parser="yes"],
 256         [ac_cv_have_gst_jpeg_parser="no" USE_LOCAL_CODEC_PARSERS=1]
 257     )
 258     CFLAGS="$saved_CFLAGS"
 259     LIBS="$saved_LIBS"
 260 ])
 261
 262 if test "$ac_cv_have_gst_jpeg_parser" = "yes"; then
 263     AC_DEFINE_UNQUOTED(HAVE_GST_JPEG_PARSER, 1,
 264         [Defined to 1 if JPEG parser exists.])
 265 fi
 266 AM_CONDITIONAL(USE_LOCAL_CODEC_PARSERS, test $USE_LOCAL_CODEC_PARSERS -eq 1)
 267
 268 dnl GST_ALL_LDFLAGS:
 269 dnl LDFLAGS really should only contain flags, not libs - they get added before
 270 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 271 GST_ALL_LDFLAGS="-no-undefined"
 272 AC_SUBST(GST_ALL_LDFLAGS)
 273
 274 dnl GST_PLUGIN_LDFLAGS:
 275 dnl this really should only contain flags, not libs - they get added before
 276 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 277 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 278 AC_SUBST(GST_PLUGIN_LDFLAGS)
 279
 280 dnl Check for the GStreamer plugins directory
 281 AC_MSG_CHECKING([for GStreamer plugins directory])
 282 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 283 if test -z "$GST_PLUGINS_DIR"; then
 284     echo "FAIL FAIL FAIL"
 285     GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 286 fi
 287 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 288 plugindir="$GST_PLUGINS_DIR"
 289 AC_SUBST(plugindir)
 290
 291 dnl ---------------------------------------------------------------------------
 292 dnl -- Renderers                                                             --
 293 dnl ---------------------------------------------------------------------------
 294
 295 dnl Check for DRM/libudev
 296 USE_DRM=0
 297 if test "$enable_drm" = "yes"; then
 298     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
 299     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
 300
 301     if test $USE_DRM -eq 1; then
 302         saved_CPPFLAGS="$CPPFLAGS"
 303         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 304         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
 305         CPPFLAGS="$saved_CPPFLAGS"
 306     fi
 307 fi
 308
 309 dnl Check for X11
 310 USE_X11=0
 311 if test "$enable_x11" = "yes"; then
 312     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 313     if test $USE_X11 -eq 1; then
 314         saved_CPPFLAGS="$CPPFLAGS"
 315         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 316         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 317         CPPFLAGS="$saved_CPPFLAGS"
 318     fi
 319 fi
 320
 321 dnl Check for XRandR
 322 HAVE_XRANDR=0
 323 if test $USE_X11 -eq 1; then
 324     HAVE_XRANDR=1
 325     PKG_CHECK_MODULES([XRANDR], [xrandr], [:], [HAVE_XRANDR=0])
 326     if test $HAVE_XRANDR -eq 1; then
 327         saved_CPPFLAGS="$CPPFLAGS"
 328         CPPFLAGS="$CPPFLAGS $XRANDR_CFLAGS"
 329         AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [:], [HAVE_XRANDR=0])
 330         CPPFLAGS="$saved_CPPFLAGS"
 331     fi
 332 fi
 333 if test $HAVE_XRANDR -eq 1; then
 334     AC_DEFINE_UNQUOTED(HAVE_XRANDR, 1,
 335         [Defined to 1 if the XRandR extension exists.])
 336 fi
 337
 338 dnl OpenGL
 339 enable_opengl="no"
 340 if test "$enable_glx" = "yes"; then
 341     enable_opengl="yes"
 342 fi
 343
 344 HAVE_GL=0
 345 if test "$enable_opengl" = "yes"; then
 346     HAVE_GL=1
 347     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 348     saved_CPPFLAGS="$CPPFLAGS"
 349     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 350     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 351 #ifdef HAVE_GL_GL_H
 352 # include <GL/gl.h>
 353 #endif
 354     ])
 355     CPPFLAGS="$saved_CPPFLAGS"
 356 fi
 357
 358 dnl Check for encoders
 359 USE_ENCODERS=0
 360 if test "$enable_encoders" = "yes"; then
 361     USE_ENCODERS=1
 362 fi
 363
 364 AC_DEFINE_UNQUOTED(USE_ENCODERS, $USE_ENCODERS,
 365     [Defined to 1 if GStreamer Vaapi Encoder are used])
 366 AM_CONDITIONAL(USE_ENCODERS, test $USE_ENCODERS -eq 1)
 367
 368 dnl ... GLX
 369 USE_GLX=0
 370 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 371     USE_GLX=1
 372     saved_CPPFLAGS="$CPPFLAGS"
 373     saved_LIBS="$LIBS"
 374     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 375     LIBS="$LIBS $GL_LIBS"
 376     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 377 #ifdef HAVE_GL_GL_H
 378 # include <GL/gl.h>
 379 #endif
 380     ])
 381     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 382     CPPFLAGS="$saved_CPPFLAGS"
 383     LIBS="$saved_LIBS"
 384 fi
 385
 386 dnl Check for Wayland
 387 USE_WAYLAND=0
 388 if test "$enable_wayland" = "yes"; then
 389     PKG_CHECK_MODULES(WAYLAND, [wayland-client],
 390         [USE_WAYLAND=1], [USE_WAYLAND=0])
 391
 392     if test $USE_WAYLAND -eq 1; then
 393         saved_CPPFLAGS="$CPPFLAGS"
 394         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 395         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
 396         CPPFLAGS="$saved_CPPFLAGS"
 397     fi
 398 fi
 399
 400 dnl ---------------------------------------------------------------------------
 401 dnl -- VA-API                                                                --
 402 dnl ---------------------------------------------------------------------------
 403
 404 dnl Core API
 405 LIBVA_PKGNAME="libva"
 406 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 407 AC_SUBST(LIBVA_PKGNAME)
 408
 409 LIBVA_TPI_PKGNAME="libva-tpi"
 410 PKG_CHECK_MODULES(LIBVA_TPI, [$LIBVA_TPI_PKGNAME >= va_api_tpi_version])
 411 AC_SUBST(LIBVA_TPI_PKGNAME)
 412
 413 VA_VERSION=`$PKG_CONFIG --modversion libva`
 414 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 415 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 416 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 417 VA_VERSION_STR="$VA_VERSION"
 418
 419 dnl VA/DRM API
 420 if test "$enable_drm" = "yes"; then
 421     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
 422         [:], [USE_DRM=0])
 423 fi
 424
 425 dnl VA/X11 API
 426 HAVE_VA_X11=0
 427 LIBVA_X11_PKGNAME="libva-x11"
 428 if test $USE_X11 -eq 1; then
 429     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 430         [HAVE_VA_X11=1], [USE_X11=0])
 431 fi
 432 AC_SUBST(LIBVA_X11_PKGNAME)
 433
 434 dnl VA/GLX API
 435 HAVE_VA_GLX=0
 436 LIBVA_GLX_PKGNAME="libva-glx"
 437 if test $USE_GLX -eq 1; then
 438     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
 439         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
 440
 441     if test $HAVE_VA_GLX -eq 1; then
 442         saved_CPPFLAGS="$CPPFLAGS"
 443         CPPFLAGS="$LIBVA_GLX_CPPFLAGS"
 444         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
 445         CPPFLAGS="$saved_CPPFLAGS"
 446     fi
 447 fi
 448 AC_SUBST(LIBVA_GLX_PKGNAME)
 449
 450 dnl Check for JPEG decoding API (0.32.1+)
 451 USE_JPEG_DECODER=0
 452 AC_CACHE_CHECK([for JPEG decoding API],
 453     ac_cv_have_jpeg_decoding_api, [
 454     saved_CFLAGS="$CFLAGS"
 455     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 456     saved_LIBS="$LIBS"
 457     LIBS="$CFLAGS $LIBVA_LIBS"
 458     AC_COMPILE_IFELSE(
 459         [AC_LANG_PROGRAM(
 460             [[#include <va/va.h>]],
 461             [[VAPictureParameterBufferJPEGBaseline pic_param;
 462               VASliceParameterBufferJPEGBaseline slice_param;
 463               VAHuffmanTableBufferJPEGBaseline huffman_table;
 464               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
 465         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 466         [ac_cv_have_jpeg_decoding_api="no"]
 467     )
 468     CFLAGS="$saved_CFLAGS"
 469     LIBS="$saved_LIBS"
 470 ])
 471
 472 dnl Check libva old H.264 encoder API
 473 HAVE_OLD_H264_ENCODER=0
 474 AC_CACHE_CHECK([for H264 encoder old structures],
 475     ac_cv_have_old_h264_encoder, [
 476         saved_CFLAGS="$CFLAGS"
 477         CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 478         saved_LIBS="$LIBS"
 479         LIBS="$CFLAGS $LIBVA_LIBS"
 480     AC_COMPILE_IFELSE(
 481         [AC_LANG_PROGRAM(
 482             [[#include <va/va_enc_h264.h>]],
 483             [[VAEncSequenceParameterBufferH264 seq;
 484               seq.seq_fields.value = 0;
 485                           seq.vui_fields.value = 0;]])],
 486         [ac_cv_have_old_h264_encoder="no" HAVE_OLD_H264_ENCODER=0],
 487         [ac_cv_have_old_h264_encoder="yes" HAVE_OLD_H264_ENCODER=1]
 488     )
 489     CFLAGS="$saved_CFLAGS"
 490     LIBS="$saved_LIBS"
 491 ])
 492
 493 AC_DEFINE_UNQUOTED(HAVE_OLD_H264_ENCODER, $HAVE_OLD_H264_ENCODER,
 494     [Defined to 1 if old h264 encoder API exists.])
 495
 496 dnl VA/Wayland API
 497 if test "$enable_wayland" = "yes"; then
 498     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
 499         [:], [USE_WAYLAND=0])
 500 fi
 501
 502 dnl ---------------------------------------------------------------------------
 503 dnl -- Generate files and summary                                            --
 504 dnl ---------------------------------------------------------------------------
 505
 506 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
 507 *:1:*)
 508     ;;
 509 *)
 510     AC_MSG_ERROR([No renderer is enabled])
 511     ;;
 512 esac
 513
 514 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 515     [Defined to 1 if JPEG decoder is used])
 516 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 517
 518 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
 519     [Defined to 1 if DRM is enabled])
 520 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
 521
 522 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 523     [Defined to 1 if X11 is enabled])
 524 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 525
 526 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 527     [Defined to 1 if GLX is enabled])
 528 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 529
 530 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
 531     [Defined to 1 if WAYLAND is enabled])
 532 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
 533
 534 pkgconfigdir=${libdir}/pkgconfig
 535 AC_SUBST(pkgconfigdir)
 536
 537 AC_CONFIG_FILES([
 538     Makefile
 539     debian.upstream/Makefile
 540     debian.upstream/changelog
 541     debian.upstream/control
 542     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 543 debian.upstream/gstreamer-vaapi-doc.install.in
 544     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 545 debian.upstream/gstreamer-vaapi.install.in
 546     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 547 debian.upstream/libgstvaapi.install.in
 548     debian.upstream/libgstvaapi-dev.install
 549     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
 550 debian.upstream/libgstvaapi-drm.install.in
 551     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 552 debian.upstream/libgstvaapi-glx.install.in
 553     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
 554 debian.upstream/libgstvaapi-wayland.install.in
 555     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 556 debian.upstream/libgstvaapi-x11.install.in
 557     docs/Makefile
 558     docs/reference/Makefile
 559     docs/reference/libs/Makefile
 560     docs/reference/libs/libs-docs.xml
 561     docs/reference/plugins/Makefile
 562     docs/reference/plugins/plugins-docs.xml
 563     gst-libs/Makefile
 564     gst-libs/gst/Makefile
 565     gst-libs/gst/codecparsers/Makefile
 566     gst-libs/gst/vaapi/Makefile
 567     gst/Makefile
 568     gst/vaapi/Makefile
 569     pkgconfig/Makefile
 570     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 571 pkgconfig/gstreamer-vaapi.pc.in
 572     pkgconfig/gstreamer-vaapi-drm-$GST_MAJORMINOR.pc:\
 573 pkgconfig/gstreamer-vaapi-drm.pc.in
 574     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 575 pkgconfig/gstreamer-vaapi-glx.pc.in
 576     pkgconfig/gstreamer-vaapi-wayland-$GST_MAJORMINOR.pc:\
 577 pkgconfig/gstreamer-vaapi-wayland.pc.in
 578     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 579 pkgconfig/gstreamer-vaapi-x11.pc.in
 580     tests/Makefile
 581 ])
 582 AC_OUTPUT
 583
 584 dnl Print summary
 585 yesno() {
 586     test $1 -eq 1 && echo yes || echo no
 587 }
 588
 589 VIDEO_OUTPUTS=""
 590 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
 591 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
 592 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
 593 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
 594
 595 echo
 596 echo $PACKAGE configuration summary:
 597 echo
 598 echo VA-API version ................... : $VA_VERSION_STR
 599 echo Video outputs .................... : $VIDEO_OUTPUTS
 600 echo VaapiEncoder support....... ...... : $(yesno $USE_ENCODERS)
 601 echo