configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [29])
  30 m4_define([glib_micro_version], [12])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AC_CANONICAL_HOST
 112
 113 AC_MSG_CHECKING([for the BeOS])
 114 case $host in
 115   *-*-beos*)
 116     glib_native_beos="yes"
 117     ;;
 118   *)
 119     glib_native_beos="no"
 120     ;;
 121 esac
 122 AC_MSG_RESULT([$glib_native_beos])
 123
 124 dnl
 125
 126 AC_MSG_CHECKING([for Win32])
 127 LIB_EXE_MACHINE_FLAG=X86
 128 case "$host" in
 129   *-*-mingw*)
 130     glib_native_win32=yes
 131     glib_pid_type='void *'
 132     glib_cv_stack_grows=no
 133     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 134     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 135     # (Sorry, I don't know exactly what is the problem, but it is related to
 136     # floating point formatting and decimal point vs. comma.)
 137     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 138     # rigorous enough to notice, though.
 139     # So preset the autoconf cache variables.
 140     ac_cv_func_vsnprintf_c99=no
 141     ac_cv_func_snprintf_c99=no
 142     case "$host" in
 143     x86_64-*-*)
 144       LIB_EXE_MACHINE_FLAG=X64
 145       ;;
 146     esac
 147     ;;
 148   *)
 149     glib_native_win32=no
 150     glib_pid_type=int
 151     ;;
 152 esac
 153 case $host in
 154   *-*-linux*)
 155     glib_os_linux=yes
 156     ;;
 157 esac
 158
 159 AC_MSG_RESULT([$glib_native_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162
 163 glib_have_carbon=no
 164 AC_MSG_CHECKING([for Mac OS X Carbon support])
 165 AC_TRY_CPP([
 166 #include <Carbon/Carbon.h>
 167 #include <CoreServices/CoreServices.h>
 168 ], glib_have_carbon=yes)
 169
 170 AC_MSG_RESULT([$glib_have_carbon])
 171
 172 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 173 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 174 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 175 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 176 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 177
 178 if test "$glib_native_win32" = "yes"; then
 179   AC_CHECK_TOOL(WINDRES, windres, no)
 180   if test "$WINDRES" = no; then
 181     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 182   fi
 183   AC_CHECK_TOOL(NM, nm, no)
 184   if test "$NM" = no; then
 185     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 186   fi
 187   AC_CHECK_TOOL(RANLIB, ranlib, :)
 188   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 189 fi
 190 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 191
 192 if test "$glib_native_win32" != yes; then
 193     # libtool option to control which symbols are exported
 194     # right now, symbols starting with _ are not exported
 195     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 196 else
 197     # We currently use .def files on Windows
 198     LIBTOOL_EXPORT_OPTIONS=
 199 fi
 200 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 201
 202 if test "x$glib_have_carbon" = "xyes"; then
 203   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 204   LDFLAGS="$LDFLAGS -framework Carbon"
 205 fi
 206
 207 gl_GLIBC21
 208 if test "x$GLIBC21" = "xyes"; then
 209   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 210 fi
 211
 212 dnl declare --enable-* args and collect ac_help strings
 213 AC_ARG_ENABLE(debug,
 214               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 215                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 216               enable_debug=glib_debug_default)
 217
 218 AC_ARG_ENABLE(gc_friendly,
 219               [AC_HELP_STRING([--enable-gc-friendly],
 220                               [turn on garbage collector friendliness [default=no]])],,
 221               [enable_gc_friendly=no])
 222 AC_ARG_ENABLE(mem_pools,
 223               [AC_HELP_STRING([--disable-mem-pools],
 224                               [disable all glib memory pools])],,
 225               [disable_mem_pools=no])
 226 AC_ARG_ENABLE(threads,
 227               [AC_HELP_STRING([--enable-threads],
 228                               [turn on basic thread support [default=yes]
 229 ([=no] will override --with-threads)])],,
 230               [enable_threads=yes])
 231 AC_ARG_ENABLE(rebuilds,
 232               [AC_HELP_STRING([--disable-rebuilds],
 233                               [disable all source autogeneration rules])],,
 234               [enable_rebuilds=yes])
 235
 236 if test "x$enable_threads" != "xyes"; then
 237   enable_threads=no
 238 fi
 239
 240 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 241 if test "x$enable_gc_friendly" = "xyes"; then
 242   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 243   AC_MSG_RESULT([yes])
 244 else
 245   AC_MSG_RESULT([no])
 246 fi
 247
 248 AC_MSG_CHECKING([whether to disable memory pools])
 249 if test "x$disable_mem_pools" = "xno"; then
 250   AC_MSG_RESULT([no])
 251 else
 252   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 253   AC_SUBST(DISABLE_MEM_POOLS)
 254   AC_MSG_RESULT([yes])
 255 fi
 256
 257 dnl location to install runtime libraries, e.g. ../../lib to install
 258 dnl to /lib if libdir is /usr/lib
 259 AC_ARG_WITH(runtime-libdir,
 260            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 261                            [Install runtime libraries relative to libdir])],
 262            [],
 263            [with_runtime_libdir=""])
 264 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 265 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 266 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 267 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 268 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 269
 270 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 271 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 272 AC_LANG_SAVE
 273 AC_LANG_CPLUSPLUS
 274 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 275 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 276 AC_LANG_RESTORE
 277
 278 AM_PROG_CC_STDC
 279 AM_PROG_CC_C_O
 280 AC_PROG_INSTALL
 281
 282 AC_SYS_LARGEFILE
 283
 284 PKG_PROG_PKG_CONFIG(0.16)
 285
 286 if test "x$enable_debug" = "xyes"; then
 287   if test x$cflags_set != xset ; then
 288       case " $CFLAGS " in
 289       *[[\ \    ]]-g[[\ \       ]]*) ;;
 290       *) CFLAGS="$CFLAGS -g" ;;
 291       esac
 292   fi
 293
 294   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 295 else
 296   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 297
 298   if test "x$enable_debug" = "xno"; then
 299     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 300   fi
 301 fi
 302
 303 # Ensure MSVC-compatible struct packing convention is used when
 304 # compiling for Win32 with gcc.
 305 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 306 # gcc2 uses "-fnative-struct".
 307 if test x"$glib_native_win32" = xyes; then
 308   if test x"$GCC" = xyes; then
 309     msnative_struct=''
 310     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 311     if test -z "$ac_cv_prog_CC"; then
 312       our_gcc="$CC"
 313     else
 314       our_gcc="$ac_cv_prog_CC"
 315     fi
 316     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 317       2.)
 318         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 319           msnative_struct='-fnative-struct'
 320         fi
 321         ;;
 322       *)
 323         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 324           msnative_struct='-mms-bitfields'
 325         fi
 326         ;;
 327     esac
 328     if test x"$msnative_struct" = x ; then
 329       AC_MSG_RESULT([no way])
 330       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 331     else
 332       CFLAGS="$CFLAGS $msnative_struct"
 333       AC_MSG_RESULT([${msnative_struct}])
 334     fi
 335   fi
 336 fi
 337 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 338 AC_SUBST(GLIB_EXTRA_CFLAGS)
 339
 340 AC_EXEEXT
 341
 342 # define a MAINT-like variable REBUILD which is set if Perl
 343 # and awk are found, so autogenerated sources can be rebuilt
 344 AC_PROG_AWK
 345 AC_CHECK_PROGS(PERL, [perl5 perl])
 346 # We would like indent, but don't require it.
 347 AC_CHECK_PROG(INDENT, indent, indent)
 348 REBUILD=\#
 349 if test "x$enable_rebuilds" = "xyes" && \
 350      test -n "$PERL" && \
 351      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 352      test -n "$AWK" ; then
 353   REBUILD=
 354 fi
 355 AC_SUBST(REBUILD)
 356
 357 # Need full path to Perl for glib-mkenums
 358 #
 359 if test "x$PERL" != x ; then
 360   AC_PATH_PROG(PERL_PATH, [$PERL])
 361 fi
 362 if test "x$PERL_PATH" = x ; then
 363   PERL_PATH="/usr/bin/env perl"
 364 fi
 365 AC_SUBST(PERL_PATH)
 366
 367 # Need suitable python path for greport
 368 AM_PATH_PYTHON(2.4,,PYTHON="/usr/bin/env python2.4")
 369
 370
 371 dnl ***********************
 372 dnl *** Tests for iconv ***
 373 dnl ***********************
 374 dnl
 375 dnl We do this before the gettext checks, to avoid distortion
 376
 377 dnl On Windows we use a native implementation
 378
 379 if test x"$glib_native_win32" = xyes; then
 380   with_libiconv=native
 381 else
 382   AC_ARG_WITH(libiconv,
 383               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 384                               [use the libiconv library])],,
 385               [with_libiconv=maybe])
 386
 387   found_iconv=no
 388   case $with_libiconv in
 389     maybe)
 390       # Check in the C library first
 391       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 392       # Check if we have GNU libiconv
 393       if test $found_iconv = "no"; then
 394         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 395       fi
 396       # Check if we have a iconv in -liconv, possibly from vendor
 397       if test $found_iconv = "no"; then
 398         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 399       fi
 400       ;;
 401     no)
 402       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 403       ;;
 404     gnu|yes)
 405       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 406       ;;
 407     native)
 408       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 409       ;;
 410   esac
 411
 412   if test "x$found_iconv" = "xno" ; then
 413      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 414   fi
 415 fi
 416
 417 AC_ARG_ENABLE(iconv-cache,
 418               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 419                               [cache iconv descriptors [default=auto]])],,
 420               [enable_iconv_cache=auto])
 421
 422 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 423 case $enable_iconv_cache in
 424   auto)
 425     if test $ac_cv_gnu_library_2_1 = yes; then
 426       enable_iconv_cache=no
 427     else
 428       enable_iconv_cache=yes
 429     fi
 430   ;;
 431   yes|no)
 432   ;;
 433   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 434   ;;
 435 esac
 436
 437 if test $enable_iconv_cache = yes; then
 438    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 439 fi
 440
 441 AC_MSG_RESULT($enable_iconv_cache)
 442
 443
 444 dnl
 445 dnl zlib support
 446 dnl
 447 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 448 if test "x$found_zlib" = "xno" ; then
 449   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 450   if test "x$found_zlib" = "xno" ; then
 451     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 452   fi
 453   ZLIB_LIBS='-lz'
 454   AC_SUBST(ZLIB_LIBS)
 455 fi
 456
 457 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 458 AC_SUBST(LIBFFI_CFLAGS)
 459 AC_SUBST(LIBFFI_LIBS)
 460
 461 dnl
 462 dnl gettext support
 463 dnl
 464
 465 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 466 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 467 GLIB_GNU_GETTEXT
 468
 469 if test "$gt_cv_have_gettext" != "yes" ; then
 470   AC_MSG_ERROR([
 471 *** You must have either have gettext support in your C library, or use the
 472 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 473 ])
 474 fi
 475
 476 LIBS="$INTLLIBS $LIBS"
 477
 478 GETTEXT_PACKAGE=glib20
 479 AC_SUBST(GETTEXT_PACKAGE)
 480 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 481   [Define the gettext package to be used])
 482
 483 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 484
 485 dnl
 486 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 487 dnl
 488
 489 if test x"$glib_native_win32" != xyes; then
 490   if test x$with_libiconv != xno ; then
 491     case " $INTLLIBS " in
 492     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 493     *) ICONV_LIBS="-liconv" ;;
 494     esac
 495   fi
 496 fi
 497 AC_SUBST(ICONV_LIBS)
 498
 499 case $with_libiconv in
 500   gnu)
 501     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 502     ;;
 503   native)
 504     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 505     ;;
 506 esac
 507
 508 dnl Initialize libtool
 509 LT_PREREQ([2.2])
 510 LT_INIT([disable-static win32-dll])
 511 dnl when using libtool 2.x create libtool early, because it's used in configure
 512 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 513
 514
 515 if test "x$GCC" = "xyes"; then
 516   case " $CFLAGS " in
 517   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 518   *) CFLAGS="$CFLAGS -Wall" ;;
 519   esac
 520 fi
 521
 522 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 523
 524 if test "$glib_native_win32" = "yes"; then
 525   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 526     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 527   fi
 528   if test x$enable_static = xyes; then
 529     glib_win32_static_compilation=yes
 530     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 531 #define GOBJECT_STATIC_COMPILATION 1"
 532     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 533   fi
 534 fi
 535 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 536
 537 dnl
 538 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 539 dnl
 540 if test $cross_compiling != yes ; then
 541     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 542     glib_save_LIBS=$LIBS
 543     LIBS="$LIBS -lm"
 544     AC_TRY_RUN([#include <math.h>
 545                  int main (void) { return (log(1) != log(1.)); }],
 546          AC_MSG_RESULT(none needed),
 547          glib_save_CFLAGS=$CFLAGS
 548          CFLAGS="$CFLAGS -std1"
 549          AC_TRY_RUN([#include <math.h>
 550                      int main (void) { return (log(1) != log(1.)); }],
 551              AC_MSG_RESULT(-std1),
 552              AC_MSG_RESULT()
 553              CFLAGS=$glib_save_CFLAGS
 554              AC_MSG_WARN(
 555                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 556          )
 557     )
 558     LIBS=$glib_save_LIBS
 559 fi
 560
 561 dnl NeXTStep cc seems to need this
 562 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 563 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 564   AC_MSG_RESULT(none needed),
 565   glib_save_CFLAGS=$CFLAGS
 566   CFLAGS="$CFLAGS -posix"
 567   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 568     AC_MSG_RESULT(-posix),
 569     AC_MSG_RESULT()
 570     CFLAGS=$glib_save_CFLAGS
 571     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 572
 573 # Checks for header files.
 574 AC_HEADER_STDC
 575
 576 # Checks for library functions.
 577 AC_FUNC_VPRINTF
 578 AC_FUNC_ALLOCA
 579 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 580 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 581
 582 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 583 dnl be automatically defined, which we don't want to do
 584 dnl until we have checked this function is actually usable
 585 AC_CHECK_FUNC([qsort_r])
 586
 587 # BSD has a qsort_r with wrong argument order
 588 if test x$ac_cv_func_qsort_r = xyes ; then
 589   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 590   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 591   #define _GNU_SOURCE
 592   #include <stdlib.h>
 593
 594   static int
 595   cmp (const void *a, const void *b, void *c)
 596   {
 597     const int *ia = a;
 598     const int *ib = b;
 599
 600     if (*ia < *ib)
 601       return -1;
 602     else if (*ia > *ib)
 603       return 1;
 604     else
 605       return 0;
 606   }
 607
 608   int
 609   main (int argc, char **argv)
 610   {
 611     int arr[3] = { 1, 2, 0 };
 612     int d = 3;
 613
 614     qsort_r (arr, 3, sizeof (int), cmp, &d);
 615
 616     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 617       return 0;
 618     else
 619       return 1;
 620   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 621 fi
 622
 623 if test x$glib_cv_have_qsort_r = xyes ; then
 624   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 625 fi
 626
 627 AC_CHECK_SIZEOF(char)
 628 AC_CHECK_SIZEOF(short)
 629 AC_CHECK_SIZEOF(long)
 630 AC_CHECK_SIZEOF(int)
 631 AC_CHECK_SIZEOF(void *)
 632 AC_CHECK_SIZEOF(long long)
 633 AC_CHECK_SIZEOF(__int64)
 634
 635 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 636   :
 637 else
 638   AC_MSG_ERROR([
 639 *** GLib requires a 64 bit type. You might want to consider
 640 *** using the GNU C compiler.
 641 ])
 642 fi
 643
 644 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 645         # long long is a 64 bit integer.
 646         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 647         AC_CACHE_VAL(glib_cv_long_long_format,[
 648                 for format in ll q I64; do
 649                   AC_TRY_RUN([#include <stdio.h>
 650                         int main()
 651                         {
 652                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 653                           char buffer[1000];
 654                           sprintf (buffer, "%${format}u", a);
 655                           sscanf (buffer, "%${format}u", &b);
 656                           exit (b!=a);
 657                         }
 658                         ],
 659                         [glib_cv_long_long_format=${format}
 660                         break],
 661                         [],[:])
 662                 done])
 663         if test -n "$glib_cv_long_long_format"; then
 664           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 665           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 666           if test x"$glib_cv_long_long_format" = xI64; then
 667             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 668           fi
 669         else
 670           AC_MSG_RESULT(none)
 671         fi
 672 elif test x$ac_cv_sizeof___int64 = x8; then
 673         # __int64 is a 64 bit integer.
 674         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 675         # We know this is MSVCRT.DLL, and what the formats are
 676         glib_cv_long_long_format=I64
 677         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 678         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 679         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 680 fi
 681
 682 dnl long doubles were not used, and a portability problem
 683 dnl AC_C_LONG_DOUBLE
 684 AC_C_CONST
 685
 686 dnl ok, here we try to check whether the systems prototypes for
 687 dnl malloc and friends actually match the prototypes provided
 688 dnl by gmem.h (keep in sync). i currently only know how to check
 689 dnl this reliably with gcc (-Werror), improvements for other
 690 dnl compilers are apprechiated.
 691 SANE_MALLOC_PROTOS=no
 692 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 693 glib_save_CFLAGS=$CFLAGS
 694 if test "x$GCC" = "xyes"; then
 695   CFLAGS="$CFLAGS -Werror"
 696   AC_TRY_COMPILE([#include <stdlib.h>], [
 697     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 698     void* (*my_malloc_p)  (size_t)         = malloc;
 699     void  (*my_free_p)    (void*)          = free;
 700     void* (*my_realloc_p) (void*, size_t)  = realloc;
 701     my_calloc_p = 0;
 702     my_malloc_p = 0;
 703     my_free_p = 0;
 704     my_realloc_p = 0;
 705   ],
 706     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 707       [Define if you have correct malloc prototypes])
 708     SANE_MALLOC_PROTOS=yes)
 709 fi
 710 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 711 CFLAGS=$glib_save_CFLAGS
 712
 713 dnl
 714 dnl check in which direction the stack grows
 715 dnl
 716 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 717         AC_TRY_RUN([
 718         volatile int *a = 0, *b = 0;
 719         void foo (void);
 720         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 721         void foo (void) { volatile int x = 5; b = &x; }
 722         ],
 723         glib_cv_stack_grows=no
 724         ,
 725         glib_cv_stack_grows=yes
 726         ,)
 727 ])
 728
 729 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 730 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 731 dnl actually supported.
 732 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 733         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 734         __inline int foo () { return 0; }
 735         int main () { return foo (); }
 736         ]])],
 737         glib_cv_has__inline=yes
 738         ,
 739         glib_cv_has__inline=no
 740         ,)
 741 ])
 742 case x$glib_cv_has__inline in
 743 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 744 esac
 745 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 746         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 747         __inline__ int foo () { return 0; }
 748         int main () { return foo (); }
 749         ]])],
 750         glib_cv_has__inline__=yes
 751         ,
 752         glib_cv_has__inline__=no
 753         ,)
 754 ])
 755 case x$glib_cv_has__inline__ in
 756 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 757 esac
 758 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 759         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 760         #undef inline
 761         inline int foo () { return 0; }
 762         int main () { return foo (); }
 763         ]])],
 764         glib_cv_hasinline=yes
 765         ,
 766         glib_cv_hasinline=no
 767         ,)
 768 ])
 769 case x$glib_cv_hasinline in
 770 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 771 esac
 772
 773 # if we can use inline functions in headers
 774 AC_MSG_CHECKING(if inline functions in headers work)
 775 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 776 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 777 #  undef inline
 778 #  define inline __inline__
 779 #elif !defined (G_HAVE_INLINE)
 780 #  undef inline
 781 #  if defined (G_HAVE___INLINE__)
 782 #    define inline __inline__
 783 #  elif defined (G_HAVE___INLINE)
 784 #    define inline __inline
 785 #  endif
 786 #endif
 787
 788 int glib_test_func2 (int);
 789
 790 static inline int
 791 glib_test_func1 (void) {
 792   return glib_test_func2 (1);
 793 }
 794
 795 int
 796 main (void) {
 797   int i = 1;
 798 }]])],[g_can_inline=yes],[g_can_inline=no])
 799 AC_MSG_RESULT($g_can_inline)
 800
 801 dnl *** check for working do while(0) macros ***
 802 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 803         AC_TRY_COMPILE([],[
 804         #define STMT_START do
 805         #define STMT_END while(0)
 806         #define STMT_TEST STMT_START { i = 0; } STMT_END
 807         int main(void) { int i = 1; STMT_TEST; return i; }],
 808         [g_cv_support_dowhile_macros=yes],
 809         [g_cv_support_dowhile_macros=no],
 810         [g_cv_support_dowhile_macros=yes])
 811 ])
 812 if test x$g_cv_support_dowhile_macros = xyes; then
 813   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 814 fi
 815
 816 # check for flavours of varargs macros
 817 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 818 AC_TRY_COMPILE([],[
 819 int a(int p1, int p2, int p3);
 820 #define call_a(...) a(1,__VA_ARGS__)
 821 call_a(2,3);
 822 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 823 AC_MSG_RESULT($g_have_iso_c_varargs)
 824
 825 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 826 if test "$CXX" = ""; then
 827 dnl No C++ compiler
 828   g_have_iso_cxx_varargs=no
 829 else
 830   AC_LANG_CPLUSPLUS
 831   AC_TRY_COMPILE([],[
 832 int a(int p1, int p2, int p3);
 833 #define call_a(...) a(1,__VA_ARGS__)
 834 call_a(2,3);
 835 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 836   AC_LANG_C
 837 fi
 838 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 839
 840 AC_MSG_CHECKING(for GNUC varargs macros)
 841 AC_TRY_COMPILE([],[
 842 int a(int p1, int p2, int p3);
 843 #define call_a(params...) a(1,params)
 844 call_a(2,3);
 845 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 846 AC_MSG_RESULT($g_have_gnuc_varargs)
 847
 848 # check for GNUC visibility support
 849 AC_MSG_CHECKING(for GNUC visibility attribute)
 850 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 851 void
 852 __attribute__ ((visibility ("hidden")))
 853      f_hidden (void)
 854 {
 855 }
 856 void
 857 __attribute__ ((visibility ("internal")))
 858      f_internal (void)
 859 {
 860 }
 861 void
 862 __attribute__ ((visibility ("protected")))
 863      f_protected (void)
 864 {
 865 }
 866 void
 867 __attribute__ ((visibility ("default")))
 868      f_default (void)
 869 {
 870 }
 871 int main (int argc, char **argv)
 872 {
 873         f_hidden();
 874         f_internal();
 875         f_protected();
 876         f_default();
 877         return 0;
 878 }
 879 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 880 AC_MSG_RESULT($g_have_gnuc_visibility)
 881 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 882
 883 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 884 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 885 #else
 886 # include "error: this is not Sun Studio."
 887 #endif
 888 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 889 AC_MSG_RESULT($g_have_sunstudio_visibility)
 890 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 891
 892 # check for bytesex stuff
 893 AC_C_BIGENDIAN
 894 if test x$ac_cv_c_bigendian = xuniversal ; then
 895 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 896 #else
 897 #error Not a big endian.
 898 #endif],
 899     ac_cv_c_bigendian=yes
 900     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 901 #else
 902 #error Not a little endian.
 903 #endif],
 904     ac_cv_c_bigendian=no
 905     ,AC_MSG_WARN([Could not determine endianness.])))
 906 fi
 907
 908
 909 # check for header files
 910 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 911 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 912 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 913 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 914 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 915 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 916 AC_CHECK_HEADERS([linux/magic.h])
 917
 918 # check for structure fields
 919 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 920 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 921 #include <sys/stat.h>
 922 #include <unistd.h>
 923 #ifdef HAVE_SYS_STATFS_H
 924 #include <sys/statfs.h>
 925 #endif
 926 #ifdef HAVE_SYS_PARAM_H
 927 #include <sys/param.h>
 928 #endif
 929 #ifdef HAVE_SYS_MOUNT_H
 930 #include <sys/mount.h>
 931 #endif])
 932 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 933 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 934 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 935
 936 # Checks for libcharset
 937 AM_LANGINFO_CODESET
 938 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 939 AC_CHECK_FUNCS(setlocale)
 940
 941 # check additional type sizes
 942 AC_CHECK_SIZEOF(size_t)
 943
 944 dnl Try to figure out whether gsize, gssize should be long or int
 945 AC_MSG_CHECKING([for the appropriate definition for size_t])
 946
 947 case $ac_cv_sizeof_size_t in
 948   $ac_cv_sizeof_short)
 949       glib_size_type=short
 950       ;;
 951   $ac_cv_sizeof_int)
 952       glib_size_type=int
 953       ;;
 954   $ac_cv_sizeof_long)
 955       glib_size_type=long
 956       ;;
 957   $ac_cv_sizeof_long_long)
 958       glib_size_type='long long'
 959       ;;
 960   $ac_cv_sizeof__int64)
 961       glib_size_type='__int64'
 962       ;;
 963   *)  AC_MSG_ERROR([No type matching size_t in size])
 964       ;;
 965 esac
 966
 967 dnl If int/long are the same size, we see which one produces
 968 dnl warnings when used in the location as size_t. (This matters
 969 dnl on AIX with xlc)
 970 dnl
 971 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 972    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 973   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 974 #if defined(_AIX) && !defined(__GNUC__)
 975 #pragma options langlvl=stdc89
 976 #endif
 977 #include <stddef.h>
 978 int main ()
 979 {
 980   size_t s = 1;
 981   unsigned int *size_int = &s;
 982   return (int)*size_int;
 983 }
 984     ]])],glib_size_type=int,
 985       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 986 #if defined(_AIX) && !defined(__GNUC__)
 987 #pragma options langlvl=stdc89
 988 #endif
 989 #include <stddef.h>
 990 int main ()
 991 {
 992    size_t s = 1;
 993    unsigned long *size_long = &s;
 994    return (int)*size_long;
 995 }
 996         ]])],glib_size_type=long)])
 997 fi
 998
 999 AC_MSG_RESULT(unsigned $glib_size_type)
1000
1001 # Check for some functions
1002 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1003 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1004 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getmntinfo)
1005 # Check for high-resolution sleep functions
1006 AC_CHECK_FUNCS(splice)
1007
1008 # To avoid finding a compatibility unusable statfs, which typically
1009 # successfully compiles, but warns to use the newer statvfs interface:
1010 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1011 AS_IF([test $ac_cv_header_sys_statfs_h  = yes], [AC_CHECK_FUNCS([statfs])])
1012
1013 AC_MSG_CHECKING([whether to use statfs or statvfs])
1014 # Some systems have both statfs and statvfs, pick the most "native" for these
1015 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = yes],
1016    [
1017    # on solaris and irix, statfs doesn't even have the f_bavail field
1018    AS_IF([test $ac_cv_member_struct_statfs_f_bavail = yes],
1019       [ac_cv_func_statfs=no],
1020    # else, at least on linux, statfs is the actual syscall
1021       [ac_cv_func_statvfs=no])
1022    ])
1023
1024 AS_IF([test x$ac_cv_func_statfs = xyes],
1025       [
1026          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1027          AC_MSG_RESULT([statfs])
1028       ],
1029       [test x$ac_cv_func_statvfs = xyes],
1030       [
1031          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1032          AC_MSG_RESULT([statvfs])
1033       ],
1034       [  AC_MSG_RESULT([neither])])
1035
1036 AC_CHECK_HEADERS(crt_externs.h)
1037 AC_CHECK_FUNCS(_NSGetEnviron)
1038
1039 AC_FUNC_VSNPRINTF_C99
1040 AC_FUNC_PRINTF_UNIX98
1041
1042 # Internet address families
1043 if test $glib_native_win32 = yes; then
1044   glib_inet_includes=["
1045 #include <winsock2.h>
1046   "]
1047 else
1048   glib_inet_includes=["
1049 #include <sys/types.h>
1050 #include <sys/socket.h>
1051   "]
1052 fi
1053
1054 glib_failed=false
1055 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1056 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1057 # winsock defines this even though it doesn't support it
1058 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1059 if $glib_failed ; then
1060   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1061 fi
1062
1063 glib_failed=false
1064 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1065 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1066 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1067 if $glib_failed ; then
1068   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1069 fi
1070
1071 AC_CHECK_FUNCS(getprotobyname_r endservent)
1072 AC_CHECK_HEADERS([netdb.h wspiapi.h])
1073
1074 # For gio/libasyncns
1075 if test $glib_native_win32 = no; then
1076   AC_CHECK_FUNCS(strndup setresuid setreuid)
1077   AC_CHECK_HEADERS(sys/prctl.h arpa/nameser_compat.h)
1078
1079   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1080   AC_MSG_CHECKING([for res_query])
1081   AC_TRY_LINK([#include <sys/types.h>
1082 #include <netinet/in.h>
1083 #include <arpa/nameser.h>
1084 #include <resolv.h>],
1085               [res_query("test", 0, 0, (void *)0, 0);],
1086               [AC_MSG_RESULT([yes])],
1087               [save_libs="$LIBS"
1088                LIBS="-lresolv $LIBS"
1089                AC_TRY_LINK([#include <sys/types.h>
1090 #include <netinet/in.h>
1091 #include <arpa/nameser.h>
1092 #include <resolv.h>],
1093                            [res_query("test", 0, 0, (void *)0, 0);],
1094                            [AC_MSG_RESULT([in -lresolv])
1095                             LIBASYNCNS_LIBADD="-lresolv"],
1096                            [LIBS="-lbind $save_libs"
1097                             AC_TRY_LINK([#include <resolv.h>],
1098                                         [res_query("test", 0, 0, (void *)0, 0);],
1099                                         [AC_MSG_RESULT([in -lbind])
1100                                          LIBASYNCNS_LIBADD="-lbind"],
1101                                         [AC_MSG_ERROR(not found)])])
1102                LIBS="$save_libs"])
1103   AC_SUBST(LIBASYNCNS_LIBADD)
1104 fi
1105
1106 case $host in
1107   *-*-solaris* )
1108      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1109      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1110      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1111      ;;
1112 esac
1113
1114 dnl
1115 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1116 dnl
1117 if test "$ac_cv_func_statfs" = yes ; then
1118   AC_MSG_CHECKING([number of arguments to statfs()])
1119   AC_TRY_COMPILE([#include <unistd.h>
1120   #ifdef HAVE_SYS_PARAM_H
1121   #include <sys/param.h>
1122   #endif
1123   #ifdef HAVE_SYS_VFS_H
1124   #include <sys/vfs.h>
1125   #endif
1126   #ifdef HAVE_SYS_MOUNT_H
1127   #include <sys/mount.h>
1128   #endif
1129   #ifdef HAVE_SYS_STATFS_H
1130   #include <sys/statfs.h>
1131   #endif], [struct statfs st;
1132   statfs(NULL, &st);],[
1133     AC_MSG_RESULT([2])
1134     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1135     AC_TRY_COMPILE([#include <unistd.h>
1136   #ifdef HAVE_SYS_PARAM_H
1137   #include <sys/param.h>
1138   #endif
1139   #ifdef HAVE_SYS_VFS_H
1140   #include <sys/vfs.h>
1141   #endif
1142   #ifdef HAVE_SYS_MOUNT_H
1143   #include <sys/mount.h>
1144   #endif
1145   #ifdef HAVE_SYS_STATFS_H
1146   #include <sys/statfs.h>
1147   #endif], [struct statfs st;
1148   statfs(NULL, &st, sizeof (st), 0);],[
1149       AC_MSG_RESULT([4])
1150       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1151       AC_MSG_RESULT(unknown)
1152       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1153 fi
1154
1155 #
1156 # Check whether to use an included printf
1157 #
1158
1159 AC_ARG_ENABLE(included-printf,
1160               [AC_HELP_STRING([--enable-included-printf],
1161                               [use included printf [default=auto]])],
1162               enable_included_printf="$enableval")
1163
1164 need_included_printf=no
1165 if test "x$enable_included_printf" = "xyes" ; then
1166   need_included_printf=yes
1167 fi
1168 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1169   need_included_printf=yes
1170 fi
1171 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1172   need_included_printf=yes
1173 fi
1174 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1175    test -z "$glib_cv_long_long_format" ; then
1176   need_included_printf=yes
1177 fi
1178
1179 if test "x$enable_included_printf" = "xno" &&
1180    test "x$need_included_printf" = "xyes" ; then
1181   AC_MSG_ERROR([
1182 *** Your C library's printf doesn't appear to have the features that
1183 *** GLib needs, but you specified --enable-included-printf=no.])
1184 fi
1185
1186 enable_included_printf=$need_included_printf
1187
1188 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1189 if test "$enable_included_printf" != "yes" ; then
1190   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1191 else
1192   if test -z "$glib_cv_long_long_format" ; then
1193     glib_cv_long_long_format="ll"
1194   fi
1195   AC_DEFINE(HAVE_VASPRINTF,1)
1196 fi
1197
1198 # Checks needed for gnulib vasnprintf
1199 bh_C_SIGNED
1200 jm_AC_TYPE_LONG_LONG
1201 gt_TYPE_LONGDOUBLE
1202 gt_TYPE_WCHAR_T
1203 gt_TYPE_WINT_T
1204 AC_TYPE_SIZE_T
1205 AC_CHECK_TYPES(ptrdiff_t)
1206 jm_AC_TYPE_INTMAX_T
1207 AC_CHECK_FUNCS([snprintf wcslen])
1208 AC_FUNC_SNPRINTF_C99
1209
1210 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1211 # The check is borrowed from the PERL Configure script.
1212 if test "$ac_cv_func_memmove" != "yes"; then
1213   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1214     glib_cv_working_bcopy,[AC_TRY_RUN([
1215       int main() {
1216         char buf[128], abc[128], *b;
1217         int len, off, align;
1218         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1219         for (align = 7; align >= 0; align--) {
1220           for (len = 36; len; len--) {
1221             b = buf+align; bcopy(abc, b, len);
1222             for (off = 1; off <= len; off++) {
1223               bcopy(b, b+off, len); bcopy(b+off, b, len);
1224                 if (bcmp(b, abc, len)) return(1);
1225             }
1226           }
1227         }
1228         return(0);
1229       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1230
1231   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1232   if test "$glib_cv_working_bcopy" = "yes"; then
1233     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1234   fi
1235 fi
1236
1237 # Check for sys_errlist
1238 AC_MSG_CHECKING(for sys_errlist)
1239 AC_TRY_LINK(, [
1240 extern char *sys_errlist[];
1241 extern int sys_nerr;
1242 sys_errlist[sys_nerr-1][0] = 0;
1243 ], glib_ok=yes, glib_ok=no)
1244 AC_MSG_RESULT($glib_ok)
1245 if test "$glib_ok" = "no"; then
1246     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1247 fi
1248
1249 # Check for sys_siglist
1250 AC_MSG_CHECKING(for sys_siglist)
1251 AC_TRY_LINK(, [
1252 extern char *sys_siglist[];
1253 exit (sys_siglist[0]);
1254 ], glib_ok=yes, glib_ok=no)
1255 AC_MSG_RESULT($glib_ok)
1256 if test "$glib_ok" = "no"; then
1257     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1258 fi
1259
1260 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1261 AC_MSG_CHECKING(for sys_siglist declaration)
1262 AC_TRY_COMPILE([#include <signal.h>], [
1263 strlen (sys_siglist[0]);
1264 ], glib_ok=yes, glib_ok=no)
1265 AC_MSG_RESULT($glib_ok)
1266 if test "$glib_ok" = "no"; then
1267     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1268 fi
1269
1270 # Check if <sys/select.h> needs to be included for fd_set
1271 AC_MSG_CHECKING([for fd_set])
1272 AC_TRY_COMPILE([#include <sys/types.h>],
1273         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1274 if test "$gtk_ok" = "yes"; then
1275     AC_MSG_RESULT([yes, found in sys/types.h])
1276 else
1277     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1278     if test "$gtk_ok" = "yes"; then
1279         # *** FIXME: give it a different name
1280         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1281         AC_MSG_RESULT([yes, found in sys/select.h])
1282     else
1283         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1284         AC_MSG_RESULT(no)
1285     fi
1286 fi
1287
1288 dnl *** check for sane realloc() ***
1289 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1290         AC_TRY_RUN([#include <stdlib.h>
1291         int main() {
1292           return realloc (0, sizeof (int)) == 0;
1293         }],
1294         [glib_cv_sane_realloc=yes],
1295         [glib_cv_sane_realloc=no],
1296         [glib_cv_sane_realloc=yes])
1297 ])
1298 if test x$glib_cv_sane_realloc = xyes; then
1299   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1300 fi
1301
1302 dnl Check for nl_langinfo and CODESET
1303 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1304         AC_TRY_COMPILE([#include <langinfo.h>],
1305                 [char *codeset = nl_langinfo (CODESET);],
1306                 [glib_cv_langinfo_codeset=yes],
1307                 [glib_cv_langinfo_codeset=no])])
1308 if test x$glib_cv_langinfo_codeset = xyes; then
1309   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1310 fi
1311
1312 dnl ****************************************
1313 dnl *** posix_memalign                   ***
1314 dnl ****************************************
1315 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1316 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1317     glib_cv_compliant_posix_memalign=0
1318     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1319         AC_TRY_RUN([
1320                 #define _XOPEN_SOURCE 600
1321                 #include <stdlib.h> /* posix_memalign() should be defined here */
1322                 /* some systems break if #include <malloc.h> used */
1323                 static void test_memalign (size_t boundary, size_t size) {
1324                     void *mem = 0;
1325                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1326                         exit (1);
1327                     else
1328                       free (mem);
1329                 }
1330                 int main() {
1331                     test_memalign (  128,   128 - 2 * sizeof (void*));
1332                     test_memalign (  256,   256 - 2 * sizeof (void*));
1333                     test_memalign (  512,   512 - 2 * sizeof (void*));
1334                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1335                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1336                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1337                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1338                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1339                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1340                     exit (0); /* success */
1341                 }
1342                 ],
1343             [glib_cv_compliant_posix_memalign=1], [], [:])
1344       :
1345     fi
1346     ])
1347 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1348     AC_MSG_RESULT(yes)
1349     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1350 else
1351     AC_MSG_RESULT(no)
1352 fi
1353
1354
1355 dnl ****************************************
1356 dnl *** strlcpy/strlcat                  ***
1357 dnl ****************************************
1358 # Check for strlcpy
1359 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1360 AC_TRY_RUN([#include <stdlib.h>
1361 #include <string.h>
1362 int main() {
1363   char p[10];
1364   (void) strlcpy (p, "hi", 10);
1365   if (strlcat (p, "bye", 0) != 3)
1366     return 1;
1367   return 0;
1368 }], glib_cv_have_strlcpy=yes,
1369     glib_cv_have_strlcpy=no,
1370     glib_cv_have_strlcpy=no)])
1371 if test "$glib_cv_have_strlcpy" = "yes"; then
1372     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1373 fi
1374
1375
1376 dnl **********************
1377 dnl *** va_copy checks ***
1378 dnl **********************
1379 dnl we currently check for all three va_copy possibilities, so we get
1380 dnl all results in config.log for bug reports.
1381 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1382         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1383 #include <stdlib.h>
1384         void f (int i, ...) {
1385         va_list args1, args2;
1386         va_start (args1, i);
1387         va_copy (args2, args1);
1388         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1389           exit (1);
1390         va_end (args1); va_end (args2);
1391         }
1392         int main() {
1393           f (0, 42);
1394           return 0;
1395         }]])],
1396         [glib_cv_va_copy=yes],
1397         [glib_cv_va_copy=no])
1398 ])
1399 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1400         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1401 #include <stdlib.h>
1402         void f (int i, ...) {
1403         va_list args1, args2;
1404         va_start (args1, i);
1405         __va_copy (args2, args1);
1406         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1407           exit (1);
1408         va_end (args1); va_end (args2);
1409         }
1410         int main() {
1411           f (0, 42);
1412           return 0;
1413         }]])],
1414         [glib_cv___va_copy=yes],
1415         [glib_cv___va_copy=no])
1416 ])
1417
1418 if test "x$glib_cv_va_copy" = "xyes"; then
1419   g_va_copy_func=va_copy
1420 else if test "x$glib_cv___va_copy" = "xyes"; then
1421   g_va_copy_func=__va_copy
1422 fi
1423 fi
1424
1425 if test -n "$g_va_copy_func"; then
1426   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1427 fi
1428
1429 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1430         AC_TRY_RUN([#include <stdarg.h>
1431 #include <stdlib.h>
1432         void f (int i, ...) {
1433         va_list args1, args2;
1434         va_start (args1, i);
1435         args2 = args1;
1436         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1437           exit (1);
1438         va_end (args1); va_end (args2);
1439         }
1440         int main() {
1441           f (0, 42);
1442           return 0;
1443         }],
1444         [glib_cv_va_val_copy=yes],
1445         [glib_cv_va_val_copy=no],
1446         [glib_cv_va_val_copy=yes])
1447 ])
1448
1449 if test "x$glib_cv_va_val_copy" = "xno"; then
1450   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1451 fi
1452
1453 dnl ***********************
1454 dnl *** g_module checks ***
1455 dnl ***********************
1456 G_MODULE_LIBS=
1457 G_MODULE_LIBS_EXTRA=
1458 G_MODULE_PLUGIN_LIBS=
1459 if test x"$glib_native_win32" = xyes; then
1460   dnl No use for this on Win32
1461   G_MODULE_LDFLAGS=
1462 else
1463   export SED
1464   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1465 fi
1466 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1467 G_MODULE_NEED_USCORE=0
1468 G_MODULE_BROKEN_RTLD_GLOBAL=0
1469 G_MODULE_HAVE_DLERROR=0
1470 dnl *** force native WIN32 shared lib loader
1471 if test -z "$G_MODULE_IMPL"; then
1472   case "$host" in
1473   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1474   esac
1475 fi
1476 dnl *** force native AIX library loader
1477 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1478 if test -z "$G_MODULE_IMPL"; then
1479   case "$host" in
1480   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1481   esac
1482 fi
1483 dnl *** dlopen() and dlsym() in system libraries
1484 if test -z "$G_MODULE_IMPL"; then
1485         AC_CHECK_FUNC(dlopen,
1486                       [AC_CHECK_FUNC(dlsym,
1487                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1488                       [])
1489 fi
1490 dnl *** load_image (BeOS)
1491 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1492   AC_CHECK_LIB(root, load_image,
1493       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1494       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1495       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1496       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1497       [])
1498 fi
1499 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1500 if test -z "$G_MODULE_IMPL"; then
1501         AC_CHECK_FUNC(NSLinkModule,
1502                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1503                        G_MODULE_NEED_USCORE=1],
1504                       [])
1505 fi
1506 dnl *** dlopen() and dlsym() in libdl
1507 if test -z "$G_MODULE_IMPL"; then
1508         AC_CHECK_LIB(dl, dlopen,
1509                      [AC_CHECK_LIB(dl, dlsym,
1510                                    [G_MODULE_LIBS=-ldl
1511                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1512                      [])
1513 fi
1514 dnl *** shl_load() in libdld (HP-UX)
1515 if test -z "$G_MODULE_IMPL"; then
1516         AC_CHECK_LIB(dld, shl_load,
1517                 [G_MODULE_LIBS=-ldld
1518                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1519                 [])
1520 fi
1521 dnl *** additional checks for G_MODULE_IMPL_DL
1522 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1523         LIBS_orig="$LIBS"
1524         LDFLAGS_orig="$LDFLAGS"
1525         LIBS="$G_MODULE_LIBS $LIBS"
1526         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1527 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1528         echo "void glib_plugin_test(void) { }" > plugin.c
1529         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1530                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1531         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1532                 glib_cv_rtldglobal_broken,[
1533                 AC_TRY_RUN([
1534 #include <dlfcn.h>
1535 #ifndef RTLD_GLOBAL
1536 #  define RTLD_GLOBAL 0
1537 #endif
1538 #ifndef RTLD_LAZY
1539 #  define RTLD_LAZY 0
1540 #endif
1541 int glib_plugin_test;
1542 int main () {
1543     void *handle, *global, *local;
1544     global = &glib_plugin_test;
1545     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1546     if (!handle) return 0;
1547     local = dlsym (handle, "glib_plugin_test");
1548     return global == local;
1549 }                       ],
1550                         [glib_cv_rtldglobal_broken=no],
1551                         [glib_cv_rtldglobal_broken=yes],
1552                         [glib_cv_rtldglobal_broken=no])
1553                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1554                 rmdir .libs 2>/dev/null
1555         ])
1556         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1557                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1558         else
1559                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1560         fi
1561 dnl *** check whether we need preceeding underscores
1562         AC_CACHE_CHECK([for preceeding underscore in symbols],
1563                 glib_cv_uscore,[
1564                 AC_TRY_RUN([#include <dlfcn.h>
1565                 int glib_underscore_test (void) { return 42; }
1566                 int main() {
1567                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1568                   handle = dlopen ((void*)0, 0);
1569                   if (handle) {
1570                     f1 = dlsym (handle, "glib_underscore_test");
1571                     f2 = dlsym (handle, "_glib_underscore_test");
1572                   } return (!f2 || f1);
1573                 }],
1574                         [glib_cv_uscore=yes],
1575                         [glib_cv_uscore=no],
1576                         [])
1577                 rm -f plugin.c plugin.$ac_objext plugin.lo
1578         ])
1579         GLIB_ASSERT_SET(glib_cv_uscore)
1580         if test "x$glib_cv_uscore" = "xyes"; then
1581                 G_MODULE_NEED_USCORE=1
1582         else
1583                 G_MODULE_NEED_USCORE=0
1584         fi
1585
1586         LDFLAGS="$LDFLAGS_orig"
1587 dnl *** check for having dlerror()
1588         AC_CHECK_FUNC(dlerror,
1589                 [G_MODULE_HAVE_DLERROR=1],
1590                 [G_MODULE_HAVE_DLERROR=0])
1591         LIBS="$LIBS_orig"
1592 fi
1593 dnl *** done, have we got an implementation?
1594 if test -z "$G_MODULE_IMPL"; then
1595         G_MODULE_IMPL=0
1596         G_MODULE_SUPPORTED=false
1597 else
1598         G_MODULE_SUPPORTED=true
1599 fi
1600
1601 AC_MSG_CHECKING(for the suffix of module shared libraries)
1602 export SED
1603 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1604 eval $shrext_cmds
1605 module=yes eval std_shrext=$shrext_cmds
1606 # chop the initial dot
1607 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1608 AC_MSG_RESULT(.$glib_gmodule_suffix)
1609 # any reason it may fail?
1610 if test "x$glib_gmodule_suffix" = x; then
1611         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1612 fi
1613
1614 AC_SUBST(G_MODULE_SUPPORTED)
1615 AC_SUBST(G_MODULE_IMPL)
1616 AC_SUBST(G_MODULE_LIBS)
1617 AC_SUBST(G_MODULE_LIBS_EXTRA)
1618 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1619 AC_SUBST(G_MODULE_LDFLAGS)
1620 AC_SUBST(G_MODULE_HAVE_DLERROR)
1621 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1622 AC_SUBST(G_MODULE_NEED_USCORE)
1623 AC_SUBST(GLIB_DEBUG_FLAGS)
1624
1625 dnl **********************
1626 dnl *** g_spawn checks ***
1627 dnl **********************
1628
1629 AC_MSG_CHECKING(for gspawn implementation)
1630 case "$host" in
1631   *-*-mingw*)
1632     GSPAWN=gspawn-win32.lo
1633     ;;
1634   *)
1635     GSPAWN=gspawn.lo
1636     ;;
1637 esac
1638 AC_MSG_RESULT($GSPAWN)
1639 AC_SUBST(GSPAWN)
1640
1641 dnl *************************
1642 dnl *** GIOChannel checks ***
1643 dnl *************************
1644
1645 AC_MSG_CHECKING(for GIOChannel implementation)
1646 case "$host" in
1647   *-*-mingw*)
1648     GIO=giowin32.lo
1649     ;;
1650   *)
1651     GIO=giounix.lo
1652     ;;
1653 esac
1654 AC_MSG_RESULT($GIO)
1655 AC_SUBST(GIO)
1656
1657 dnl *********************************
1658 dnl *** Directory for GIO modules ***
1659 dnl *********************************
1660
1661 AC_ARG_WITH(gio-module-dir,
1662            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1663                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1664            [],
1665            [with_gio_module_dir='${libdir}/gio/modules'])
1666 GIO_MODULE_DIR=$with_gio_module_dir
1667 AC_SUBST(GIO_MODULE_DIR)
1668
1669 dnl **********************************
1670 dnl *** Check for libselinux (GIO) ***
1671 dnl **********************************
1672 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1673 msg_selinux=no
1674 SELINUX_LIBS=
1675 if test "x$enable_selinux" != "xno"; then
1676
1677  AC_CHECK_LIB(selinux, is_selinux_enabled,
1678    [AC_CHECK_HEADERS(selinux/selinux.h,
1679      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1680        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1681         SELINUX_LIBS="-lselinux"
1682         msg_selinux=yes])
1683      ])
1684    ])
1685 fi
1686 AC_SUBST(SELINUX_LIBS)
1687
1688 dnl *****************************
1689 dnl ** Check for inotify (GIO) **
1690 dnl *****************************
1691 inotify_support=no
1692 AC_CHECK_HEADERS([sys/inotify.h],
1693 [
1694         inotify_support=yes
1695         AC_CHECK_FUNCS(inotify_init1)
1696 ])
1697
1698 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1699
1700 dnl *********************************
1701 dnl ** Check for Solaris FEN (GIO) **
1702 dnl *********************************
1703 fen_support=no
1704 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1705 #include <port.h>
1706 #ifndef PORT_SOURCE_FILE
1707 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1708 #endif
1709 int main() { return 0; } ]])],
1710 [
1711         fen_support=yes
1712 ],)
1713
1714 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1715
1716 dnl ****************************
1717 dnl *** Checks for FAM (GIO) ***
1718 dnl ****************************
1719
1720 should_disable_fam=no
1721
1722 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1723                          [
1724                                 if test "x$enable_fam" = "xno"; then
1725                                         should_disable_fam=yes
1726                                         echo "Not building FAM support"
1727                                 fi
1728                          ]
1729                          )
1730 fam_support=no
1731 FAM_LIBS=
1732 if test "x$should_disable_fam" = "xno"; then
1733 AC_CHECK_LIB(fam, FAMOpen,
1734   [AC_CHECK_HEADERS(fam.h,
1735     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1736      AC_CHECK_LIB(fam, FAMNoExists,
1737                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1738      FAM_LIBS="-lfam"]
1739      fam_support=yes,
1740     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1741   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1742 AC_SUBST(FAM_LIBS)
1743 fi
1744 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1745
1746
1747 dnl *****************************
1748 dnl *** Check for xattr (GIO) ***
1749 dnl *****************************
1750 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1751 msg_xattr=no
1752 XATTR_LIBS=
1753 if test "x$enable_xattr" != "xno"; then
1754
1755 dnl either glibc or libattr can provide xattr support
1756
1757 dnl for both of them, we check for getxattr being in
1758 dnl the library and a valid xattr header.
1759
1760 dnl try glibc
1761  AC_CHECK_LIB(c, getxattr,
1762    [AC_CHECK_HEADERS(sys/xattr.h,
1763      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1764       msg_xattr=yes])
1765    ])
1766
1767   if test "x$msg_xattr" != "xyes"; then
1768 dnl   failure. try libattr
1769    AC_CHECK_LIB(attr, getxattr,
1770       [AC_CHECK_HEADERS(attr/xattr.h,
1771        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1772         XATTR_LIBS="-lattr"
1773         msg_xattr=yes])
1774       ])
1775   fi
1776
1777   if test "x$msg_xattr" = "xyes"; then
1778     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1779     AC_TRY_COMPILE([
1780       #include <stdio.h>
1781       #ifdef HAVE_SYS_TYPES_H
1782       #include <sys/types.h>
1783       #endif
1784       #ifdef HAVE_SYS_XATTR_H
1785       #include <sys/xattr.h>
1786       #elif HAVE_ATTR_XATTR_H
1787       #include <attr/xattr.h>
1788       #endif
1789     ],
1790     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1791     [
1792       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1793       AC_MSG_RESULT([yes])
1794     ],
1795     [AC_MSG_RESULT([no])]
1796     )
1797   fi
1798
1799 fi
1800 AC_SUBST(XATTR_LIBS)
1801
1802 dnl ****************************************
1803 dnl *** platform dependent source checks ***
1804 dnl ****************************************
1805
1806 AC_MSG_CHECKING(for platform-dependent source)
1807 case "$host" in
1808   *-*-cygwin*|*-*-mingw*)
1809     PLATFORMDEP=gwin32.lo
1810     ;;
1811   *)
1812     PLATFORMDEP=
1813     ;;
1814 esac
1815 AC_MSG_RESULT($PLATFORMDEP)
1816 AC_SUBST(PLATFORMDEP)
1817
1818 AC_MSG_CHECKING([whether to compile timeloop])
1819 case "$host" in
1820   *-*-cygwin*|*-*-mingw*|*-*-minix)
1821     enable_timeloop=no
1822     ;;
1823   *)
1824     enable_timeloop=yes
1825     ;;
1826 esac
1827 AC_MSG_RESULT($enable_timeloop)
1828 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1829
1830 AC_MSG_CHECKING([if building for some Win32 platform])
1831 case "$host" in
1832   *-*-mingw*|*-*-cygwin*)
1833     platform_win32=yes
1834     ;;
1835   *)
1836     platform_win32=no
1837     ;;
1838 esac
1839 AC_MSG_RESULT($platform_win32)
1840 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1841
1842 dnl ***********************
1843 dnl *** g_thread checks ***
1844 dnl ***********************
1845
1846 AC_ARG_WITH(threads,
1847            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1848                            [specify a thread implementation to use])],
1849            [if test "x$with_threads" = x; then
1850                 want_threads=yes
1851             else
1852                 want_threads=$with_threads
1853             fi],
1854            [want_threads=yes])
1855 if test "x$enable_threads" = "xno"; then
1856         want_threads=no
1857 fi
1858
1859 dnl error and warning message
1860 dnl *************************
1861
1862 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1863                 computer. GLib will not have a default thread implementation."
1864
1865 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1866                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1867                 compilation now, but then your programs might not work.
1868                 Please provide information on how it is done on your system."
1869
1870 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1871                 "
1872
1873 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1874                 provide information on your thread implementation.
1875                 You can also run 'configure --disable-threads'
1876                 to compile without thread support."
1877
1878 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1879                 functions will not be MT-safe during their first call because
1880                 there is no working 'getpwuid_r' on your system."
1881
1882 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1883                 because there is no 'localtime_r' on your system."
1884
1885 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1886                 crude surrogate will be used. If you happen to know a
1887                 yield function for your system, please inform the GLib
1888                 developers."
1889
1890 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1891                 threads on your system. Thus threads can only have the default
1892                 priority. If you happen to know these main/max
1893                 priorities, please inform the GLib developers."
1894
1895 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1896                 linking threaded applications. As GLib cannot do that
1897                 automatically, you will get an linkg error everytime you are
1898                 not using the right compiler. In that case you have to relink
1899                 with the right compiler. Ususally just '_r' is appended
1900                 to the compiler name."
1901
1902 dnl determination of thread implementation
1903 dnl ***************************************
1904
1905 # have_threads=no   means no thread support
1906 # have_threads=none means no default thread implementation
1907
1908 have_threads=no
1909 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1910                                 || test "x$want_threads" = xdce; then
1911         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1912         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1913         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1914         glib_save_CPPFLAGS="$CPPFLAGS"
1915         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1916         if test "x$have_threads" = xno; then
1917                 AC_TRY_COMPILE([#include <pthread.h>],
1918                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1919                         have_threads=posix)
1920         fi
1921         if test "x$have_threads" = xno; then
1922                 AC_TRY_COMPILE([#include <pthread.h>],
1923                         [pthread_mutex_t m;
1924                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1925                         have_threads=dce)
1926         fi
1927         # Tru64Unix requires -pthread to find pthread.h. See #103020
1928         CPPFLAGS="$CPPFLAGS -pthread"
1929         if test "x$have_threads" = xno; then
1930         AC_TRY_COMPILE([#include <pthread.h>],
1931                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1932                        have_threads=posix)
1933         fi
1934         CPPFLAGS="$glib_save_CPPFLAGS"
1935 fi
1936 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1937         case $host in
1938                 *-*-mingw*)
1939                 have_threads=win32
1940                 ;;
1941         esac
1942 fi
1943 if test "x$want_threads" = xnone; then
1944         have_threads=none
1945 fi
1946
1947 AC_MSG_CHECKING(for thread implementation)
1948
1949 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1950         AC_MSG_RESULT(none available)
1951         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1952 else
1953         AC_MSG_RESULT($have_threads)
1954 fi
1955
1956
1957 dnl determination of G_THREAD_CFLAGS
1958 dnl ********************************
1959
1960 G_THREAD_LIBS=
1961 G_THREAD_LIBS_EXTRA=
1962 G_THREAD_CFLAGS=
1963
1964 dnl
1965 dnl Test program for basic POSIX threads functionality
1966 dnl
1967 m4_define([glib_thread_test],[
1968 #include <pthread.h>
1969 int check_me = 0;
1970 void* func(void* data) {check_me = 42; return &check_me;}
1971 int main()
1972  { pthread_t t;
1973    void *ret;
1974    pthread_create (&t, $1, func, 0);
1975    pthread_join (t, &ret);
1976    return (check_me != 42 || ret != &check_me);
1977 }])
1978
1979 dnl
1980 dnl Test program for sched_get_priority_min()
1981 dnl
1982 m4_define([glib_sched_priority_test],[
1983 #include <sched.h>
1984 #include <errno.h>
1985 int main() {
1986     errno = 0;
1987     return sched_get_priority_min(SCHED_OTHER)==-1
1988            && errno != 0;
1989 }])
1990
1991 if test x"$have_threads" != xno; then
1992
1993   if test x"$have_threads" = xposix; then
1994     # First we test for posix, whether -pthread or -pthreads do the trick as
1995     # both CPPFLAG and LIBS.
1996     # One of them does for most gcc versions and some other platforms/compilers
1997     # too and could be considered as the canonical way to go.
1998     case $host in
1999       *-*-cygwin*|*-*-darwin*)
2000          # skip cygwin and darwin -pthread or -pthreads test
2001          ;;
2002       *-solaris*)
2003         # These compiler/linker flags work with both Sun Studio and gcc
2004         # Sun Studio expands -mt to -D_REENTRANT and -lthread
2005         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2006         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2007         G_THREAD_LIBS="-lpthread -lthread"
2008         ;;
2009       *)
2010         for flag in pthread pthreads mt; do
2011           glib_save_CFLAGS="$CFLAGS"
2012           CFLAGS="$CFLAGS -$flag"
2013           AC_TRY_RUN(glib_thread_test(0),
2014                      glib_flag_works=yes,
2015                      glib_flag_works=no,
2016                      [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2017                                      glib_flag_works=yes,
2018                                      glib_flag_works=no)])
2019           CFLAGS="$glib_save_CFLAGS"
2020           if test $glib_flag_works = yes ; then
2021              G_THREAD_CFLAGS=-$flag
2022              G_THREAD_LIBS=-$flag
2023              break;
2024           fi
2025         done
2026          ;;
2027     esac
2028   fi
2029
2030   if test x"$G_THREAD_CFLAGS" = x; then
2031
2032     # The canonical -pthread[s] does not work. Try something different.
2033
2034     case $host in
2035         *-aix*)
2036                 if test x"$GCC" = xyes; then
2037                         # GCC 3.0 and above needs -pthread.
2038                         # Should be coverd by the case above.
2039                         # GCC 2.x and below needs -mthreads
2040                         G_THREAD_CFLAGS="-mthreads"
2041                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2042                 else
2043                         # We are probably using the aix compiler. Normaly a
2044                         # program would have to be compiled with the _r variant
2045                         # of the corresponding compiler, but we as GLib cannot
2046                         # do that: but the good news is that for compiling the
2047                         # only difference is the added -D_THREAD_SAFE compile
2048                         # option. This is according to the "C for AIX User's
2049                         # Guide".
2050                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2051                 fi
2052                 ;;
2053         *-dg-dgux*)  # DG/UX
2054                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2055                 ;;
2056         *-osf*)
2057                 # So we are using dce threads. posix threads are already
2058                 # catched above.
2059                 G_THREAD_CFLAGS="-threads"
2060                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2061                 ;;
2062         *-sysv5uw7*) # UnixWare 7
2063                 # We are not using gcc with -pthread. Catched above.
2064                 G_THREAD_CFLAGS="-Kthread"
2065                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2066                 ;;
2067         *-mingw*)
2068                 # No flag needed when using MSVCRT.DLL
2069                 G_THREAD_CFLAGS=""
2070                 ;;
2071         *)
2072                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2073                 ;;
2074     esac
2075
2076   fi
2077
2078     # if we are not finding the localtime_r function, then we probably are
2079     # not using the proper multithread flag
2080
2081     glib_save_CPPFLAGS="$CPPFLAGS"
2082     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2083
2084     # First we test, whether localtime_r is declared in time.h
2085     # directly. Then we test whether a macro localtime_r exists, in
2086     # which case localtime_r in the test program is replaced and thus
2087     # if we still find localtime_r in the output, it is not defined as
2088     # a macro.
2089
2090     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2091       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2092                                                            localtime_r(a,b)],
2093                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2094
2095     CPPFLAGS="$glib_save_CPPFLAGS"
2096
2097     AC_MSG_CHECKING(thread related cflags)
2098     AC_MSG_RESULT($G_THREAD_CFLAGS)
2099     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2100 fi
2101
2102 dnl determination of G_THREAD_LIBS
2103 dnl ******************************
2104
2105 mutex_has_default=no
2106 case $have_threads in
2107         posix|dce)
2108           glib_save_CPPFLAGS="$CPPFLAGS"
2109           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2110           if test x"$G_THREAD_LIBS" = x; then
2111             case $host in
2112               *-aix*)
2113                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2114                 # probably using the aix compiler.
2115                 AC_MSG_WARN($AIX_COMPILE_INFO)
2116                 ;;
2117               *)
2118                 G_THREAD_LIBS=error
2119                 glib_save_LIBS="$LIBS"
2120                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2121                         if test x"$thread_lib" = x; then
2122                                 add_thread_lib=""
2123                                 IN=""
2124                         else
2125                                 add_thread_lib="-l$thread_lib"
2126                                 IN=" in -l$thread_lib"
2127                         fi
2128                         if test x"$have_threads" = xposix; then
2129                                 defattr=0
2130                         else
2131                                 defattr=pthread_attr_default
2132                         fi
2133
2134                         LIBS="$add_thread_lib $glib_save_LIBS"
2135
2136                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2137                         AC_TRY_RUN(glib_thread_test($defattr),
2138                                    glib_result=yes,
2139                                    glib_result=no,
2140                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2141                                                    glib_result=yes,
2142                                                    glib_result=no)])
2143                         AC_MSG_RESULT($glib_result)
2144
2145                         if test "$glib_result" = "yes" ; then
2146                           G_THREAD_LIBS="$add_thread_lib"
2147                           break
2148                         fi
2149                 done
2150                 if test "x$G_THREAD_LIBS" = xerror; then
2151                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2152                 fi
2153                 LIBS="$glib_save_LIBS"
2154                 ;;
2155             esac
2156           fi
2157
2158           glib_save_LIBS="$LIBS"
2159           for thread_lib in "" rt rte; do
2160             if test x"$thread_lib" = x; then
2161               add_thread_lib=""
2162               IN=""
2163             else
2164               add_thread_lib="-l$thread_lib"
2165               IN=" in -l$thread_lib"
2166             fi
2167             LIBS="$add_thread_lib $glib_save_LIBS"
2168
2169             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2170             AC_TRY_RUN(glib_sched_priority_test,
2171                        glib_result=yes,
2172                        glib_result=no,
2173                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2174                                        glib_result=yes,
2175                                        glib_result=no)])
2176             AC_MSG_RESULT($glib_result)
2177
2178             if test "$glib_result" = "yes" ; then
2179                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2180                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2181                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2182                break
2183             fi
2184           done
2185           LIBS="$glib_save_LIBS"
2186           mutex_has_default=yes
2187           mutex_default_type='pthread_mutex_t'
2188           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2189           mutex_header_file='pthread.h'
2190           if test "x$have_threads" = "xposix"; then
2191             g_threads_impl="POSIX"
2192           else
2193             g_threads_impl="DCE"
2194             have_threads="posix"
2195           fi
2196           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2197           CPPFLAGS="$glib_save_CPPFLAGS"
2198           ;;
2199         win32)
2200            g_threads_impl="WIN32"
2201            ;;
2202         none|no)
2203            g_threads_impl="NONE"
2204            ;;
2205         *)
2206            g_threads_impl="NONE"
2207            G_THREAD_LIBS=error
2208            ;;
2209 esac
2210
2211 if test "x$G_THREAD_LIBS" = xerror; then
2212         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2213 fi
2214
2215 case $host in
2216   *-*-beos*)
2217     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2218     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2219     ;;
2220   *)
2221     ;;
2222 esac
2223
2224 AC_MSG_CHECKING(thread related libraries)
2225 AC_MSG_RESULT($G_THREAD_LIBS)
2226
2227 dnl check for mt safe function variants and some posix functions
2228 dnl ************************************************************
2229
2230 if test x"$have_threads" != xno; then
2231         glib_save_LIBS="$LIBS"
2232         # we are not doing the following for now, as this might require glib
2233         # to always be linked with the thread libs on some platforms.
2234         # LIBS="$LIBS $G_THREAD_LIBS"
2235         AC_CHECK_FUNCS(localtime_r gmtime_r)
2236         if test "$ac_cv_header_pwd_h" = "yes"; then
2237                 AC_CACHE_CHECK([for posix getpwuid_r],
2238                         ac_cv_func_posix_getpwuid_r,
2239                         [AC_TRY_RUN([
2240 #include <errno.h>
2241 #include <pwd.h>
2242 int main () {
2243     char buffer[10000];
2244     struct passwd pwd, *pwptr = &pwd;
2245     int error;
2246     errno = 0;
2247     error = getpwuid_r (0, &pwd, buffer,
2248                         sizeof (buffer), &pwptr);
2249    return (error < 0 && errno == ENOSYS)
2250            || error == ENOSYS;
2251 }                               ],
2252                                 [ac_cv_func_posix_getpwuid_r=yes],
2253                                 [ac_cv_func_posix_getpwuid_r=no])])
2254                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2255                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2256                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2257                                 [Have POSIX function getpwuid_r])
2258                 else
2259                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2260                                 ac_cv_func_nonposix_getpwuid_r,
2261                                 [AC_TRY_LINK([#include <pwd.h>],
2262                                         [char buffer[10000];
2263                                         struct passwd pwd;
2264                                         getpwuid_r (0, &pwd, buffer,
2265                                                         sizeof (buffer));],
2266                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2267                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2268                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2269                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2270                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2271                                         [Have non-POSIX function getpwuid_r])
2272                         fi
2273                 fi
2274         fi
2275         if test "$ac_cv_header_grp_h" = "yes"; then
2276                 AC_CACHE_CHECK([for posix getgrgid_r],
2277                         ac_cv_func_posix_getgrgid_r,
2278                         [AC_TRY_RUN([
2279 #include <errno.h>
2280 #include <grp.h>
2281 int main () {
2282     char buffer[10000];
2283     struct group grp, *grpptr = &grp;
2284     int error;
2285     errno = 0;
2286     error = getgrgid_r (0, &grp, buffer,
2287                         sizeof (buffer), &grpptr);
2288    return (error < 0 && errno == ENOSYS)
2289            || error == ENOSYS;
2290 }                              ],
2291                                [ac_cv_func_posix_getgrgid_r=yes],
2292                                [ac_cv_func_posix_getgrgid_r=no])])
2293                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2294                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2295                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2296                                 [Have POSIX function getgrgid_r])
2297                 else
2298                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2299                                 ac_cv_func_nonposix_getgrgid_r,
2300                                 [AC_TRY_LINK([#include <grp.h>],
2301                                         [char buffer[10000];
2302                                         struct group grp;
2303                                         getgrgid_r (0, &grp, buffer,
2304                                         sizeof (buffer));],
2305                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2306                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2307                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2308                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2309                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2310                                         [Have non-POSIX function getgrgid_r])
2311                         fi
2312                 fi
2313         fi
2314         LIBS="$G_THREAD_LIBS $LIBS"
2315         if test x"$have_threads" = xposix; then
2316                 glib_save_CPPFLAGS="$CPPFLAGS"
2317                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2318                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2319                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2320                 # This is not AC_CHECK_FUNC to also work with function
2321                 # name mangling in header files.
2322                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2323                 AC_TRY_LINK([#include <pthread.h>],
2324                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2325                         [AC_MSG_RESULT(yes)
2326                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2327                                   [Have function pthread_attr_setstacksize])],
2328                         [AC_MSG_RESULT(no)])
2329                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2330                 if test x"$posix_priority_min" = x; then
2331                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2332                                 PX_PRIO_MIN],,[
2333                                 posix_priority_min=PX_PRIO_MIN
2334                                 posix_priority_max=PX_PRIO_MAX])
2335                 fi
2336                 if test x"$posix_priority_min" = x; then
2337                         # AIX
2338                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2339                                 PTHREAD_PRIO_MIN],,[
2340                                 posix_priority_min=PTHREAD_PRIO_MIN
2341                                 posix_priority_max=PTHREAD_PRIO_MAX])
2342                 fi
2343                 if test x"$posix_priority_min" = x; then
2344                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2345                                 PRI_OTHER_MIN],,[
2346                                 posix_priority_min=PRI_OTHER_MIN
2347                                 posix_priority_max=PRI_OTHER_MAX])
2348                 fi
2349                 if test x"$posix_priority_min" = x; then
2350                         AC_MSG_RESULT(none found)
2351                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2352                         posix_priority_min=-1
2353                         posix_priority_max=-1
2354                 else
2355                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2356                         AC_MSG_CHECKING(for pthread_setschedparam)
2357                         AC_TRY_LINK([#include <pthread.h>],
2358                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2359                           [AC_MSG_RESULT(yes)
2360                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2361                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2362                           [AC_MSG_RESULT(no)
2363                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2364                 fi
2365                 posix_yield_func=none
2366                 AC_MSG_CHECKING(for posix yield function)
2367                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2368                                                         thr_yield; do
2369                         AC_TRY_LINK([#include <pthread.h>],
2370                                 [$yield_func()],
2371                                 [posix_yield_func="$yield_func"
2372                                 break])
2373                 done
2374                 if test x"$posix_yield_func" = xnone; then
2375                         AC_MSG_RESULT(none found)
2376                         AC_MSG_WARN($POSIX_NO_YIELD)
2377                         posix_yield_func="g_usleep(1000)"
2378                 else
2379                         AC_MSG_RESULT($posix_yield_func)
2380                         posix_yield_func="$posix_yield_func()"
2381                 fi
2382                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2383                 CPPFLAGS="$glib_save_CPPFLAGS"
2384
2385         elif test x"$have_threads" = xwin32; then
2386                 # It's a pointer to a private struct
2387                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2388         fi
2389
2390         LIBS="$glib_save_LIBS"
2391
2392         # now spit out all the warnings.
2393         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2394            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2395                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2396         fi
2397         if test "$ac_cv_func_localtime_r" != "yes"; then
2398                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2399         fi
2400 fi
2401
2402 if test x"$glib_cv_sizeof_system_thread" = x; then
2403    # use a pointer as a fallback.
2404    GLIB_SIZEOF(,void *, system_thread)
2405 fi
2406
2407 #
2408 # Hack to deal with:
2409 #
2410 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2411 #     building shared libraries with linux.
2412 #  b) FreeBSD doesn't do this either.
2413 #
2414 case $host in
2415   *-*-freebsd*|*-*-linux*)
2416     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2417     ;;
2418   *)
2419     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2420     ;;
2421 esac
2422
2423 AM_CONDITIONAL(HAVE_THREADS, [test "$have_threads" != "none"])
2424 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2425                    [Source file containing theread implementation])
2426 AC_SUBST(G_THREAD_CFLAGS)
2427 AC_SUBST(G_THREAD_LIBS)
2428 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2429 AC_SUBST(G_THREAD_LIBS_EXTRA)
2430
2431 dnl **********************************************
2432 dnl *** GDefaultMutex setup and initialization ***
2433 dnl **********************************************
2434 dnl
2435 dnl if mutex_has_default = yes, we also got
2436 dnl mutex_default_type, mutex_default_init and mutex_header_file
2437 if test $mutex_has_default = yes ; then
2438         glib_save_CPPFLAGS="$CPPFLAGS"
2439         glib_save_LIBS="$LIBS"
2440         LIBS="$G_THREAD_LIBS $LIBS"
2441         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2442         GLIB_SIZEOF([#include <$mutex_header_file>],
2443                     $mutex_default_type,
2444                     gmutex)
2445         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2446                            $mutex_default_type,
2447                            gmutex,
2448                            $glib_cv_sizeof_gmutex,
2449                            $mutex_default_init)
2450         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2451                 mutex_has_default=no
2452         fi
2453         CPPFLAGS="$glib_save_CPPFLAGS"
2454         LIBS="$glib_save_LIBS"
2455 fi
2456
2457 AC_CHECK_FUNCS(clock_gettime, [], [
2458   AC_CHECK_LIB(rt, clock_gettime, [
2459     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2460     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2461     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2462     GLIB_RT_LIBS="-lrt"
2463   ])
2464 ])
2465 AC_SUBST(GLIB_RT_LIBS)
2466
2467 AC_CACHE_CHECK(for monotonic clocks,
2468     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2469 #include <time.h>
2470 #include <unistd.h>
2471 int main() {
2472 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2473         #error No monotonic clock
2474 #endif
2475         return 0;
2476 }
2477 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2478 if test "$glib_cv_monotonic_clock" = "yes"; then
2479   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2480 fi
2481
2482
2483 dnl ********************************
2484 dnl *** g_atomic_* tests for gcc ***
2485 dnl ********************************
2486
2487 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2488
2489 glib_cv_gcc_has_builtin_atomic_operations=no
2490 if test x"$GCC" = xyes; then
2491   AC_MSG_CHECKING([whether GCC supports build-in atomic intrinsics])
2492   AC_TRY_LINK([],
2493               [int i;
2494                __sync_synchronize ();
2495                __sync_bool_compare_and_swap (&i, 0, 1);
2496                __sync_fetch_and_add (&i, 1);
2497               ],
2498               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2499               [glib_cv_gcc_has_builtin_atomic_operations=no])
2500
2501   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2502     case $host_cpu in
2503       i386)
2504         AC_MSG_RESULT([none])
2505         glib_memory_barrier_needed=no
2506         ;;
2507       i?86)
2508         AC_MSG_RESULT([i486])
2509         AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2510                            [i486 atomic implementation])
2511         glib_memory_barrier_needed=no
2512         ;;
2513       sparc*)
2514         SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2515                          when you are using a sparc with v9 instruction set (most
2516                          sparcs nowadays). This will make the code for atomic
2517                          operations much faster. The resulting code will not run
2518                          on very old sparcs though."
2519
2520         AC_LINK_IFELSE([AC_LANG_SOURCE([[
2521           main ()
2522           {
2523             int tmp1, tmp2, tmp3;
2524             __asm__ __volatile__("casx [%2], %0, %1"
2525                                  : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2526           }]])],
2527           AC_MSG_RESULT([sparcv9])
2528           AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2529                              [sparcv9 atomic implementation]),
2530           AC_MSG_RESULT([no])
2531           AC_MSG_WARN([[$SPARCV9_WARNING]]))
2532         glib_memory_barrier_needed=yes
2533         ;;
2534       alpha*)
2535         AC_MSG_RESULT([alpha])
2536         AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2537                            [alpha atomic implementation])
2538         glib_memory_barrier_needed=yes
2539         ;;
2540       x86_64)
2541         AC_MSG_RESULT([x86_64])
2542         AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2543                            [x86_64 atomic implementation])
2544         glib_memory_barrier_needed=no
2545        ;;
2546       powerpc*)
2547         AC_MSG_RESULT([powerpc])
2548         AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2549                            [powerpc atomic implementation])
2550         glib_memory_barrier_needed=yes
2551         AC_MSG_CHECKING([whether asm supports numbered local labels])
2552         AC_TRY_COMPILE(
2553                        ,[
2554                        __asm__ __volatile__ ("1:       nop\n"
2555                                "         bne-    1b")
2556                        ],[
2557                        AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2558                        AC_MSG_RESULT([yes])
2559                        ],[
2560                        AC_MSG_RESULT([no])
2561                        ])
2562         ;;
2563       ia64)
2564         AC_MSG_RESULT([ia64])
2565         AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2566                            [ia64 atomic implementation])
2567         glib_memory_barrier_needed=yes
2568         ;;
2569       s390|s390x)
2570         AC_MSG_RESULT([s390])
2571         AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2572                            [s390 atomic implementation])
2573         glib_memory_barrier_needed=no
2574         ;;
2575       arm*)
2576         AC_MSG_RESULT([arm])
2577         AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2578                            [arm atomic implementation])
2579         glib_memory_barrier_needed=no
2580         ;;
2581       crisv32*|etraxfs*)
2582         AC_MSG_RESULT([crisv32])
2583         AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2584                            [crisv32 atomic implementation])
2585         glib_memory_barrier_needed=no
2586         ;;
2587       cris*|etrax*)
2588         AC_MSG_RESULT([cris])
2589         AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2590                            [cris atomic implementation])
2591         glib_memory_barrier_needed=no
2592         ;;
2593       *)
2594         AC_MSG_RESULT([none])
2595         glib_memory_barrier_needed=yes
2596         ;;
2597     esac
2598 else
2599   if test $glib_native_win32 = yes; then
2600     # For Windows but not using gcc. No barriers needed then either.
2601     glib_memory_barrier_needed=no
2602   fi
2603 fi
2604
2605 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2606                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2607
2608 dnl ************************
2609 dnl ** Check for futex(2) **
2610 dnl ************************
2611 AC_CACHE_CHECK(for futex(2) system call,
2612     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2613 #include <linux/futex.h>
2614 #include <sys/syscall.h>
2615 #include <unistd.h>
2616 ],[
2617 int
2618 main (void)
2619 {
2620   /* it is not like this actually runs or anything... */
2621   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2622   return 0;
2623 }
2624 ])],glib_cv_futex=yes,glib_cv_futex=no))
2625 if test x"$glib_cv_futex" = xyes; then
2626   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2627 fi
2628
2629 AC_CACHE_CHECK(for eventfd(2) system call,
2630     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2631 #include <sys/eventfd.h>
2632 #include <unistd.h>
2633 ],[
2634 int
2635 main (void)
2636 {
2637   eventfd (0, EFD_CLOEXEC);
2638   return 0;
2639 }
2640 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2641 if test x"$glib_cv_eventfd" = x"yes"; then
2642   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2643 fi
2644
2645 dnl ****************************************
2646 dnl *** GLib POLL* compatibility defines ***
2647 dnl ****************************************
2648
2649 glib_poll_includes=["
2650 #include <sys/types.h>
2651 #include <sys/poll.h>
2652 "]
2653
2654 if test $ac_cv_header_sys_types_h = yes &&
2655    test $ac_cv_header_sys_poll_h = yes ; then
2656   glib_failed=false
2657   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2658   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2659   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2660   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2661   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2662   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2663   if $glib_failed ; then
2664     AC_MSG_ERROR([Could not determine values for POLL* constants])
2665   fi
2666 else
2667   glib_cv_value_POLLIN=1
2668   glib_cv_value_POLLOUT=4
2669   glib_cv_value_POLLPRI=2
2670   glib_cv_value_POLLERR=8
2671   glib_cv_value_POLLHUP=16
2672   glib_cv_value_POLLNVAL=32
2673 fi
2674
2675 AC_MSG_CHECKING([for broken poll])
2676 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2677         #include <stdlib.h>
2678         #include <fcntl.h>
2679         #include <poll.h>
2680         #ifdef HAVE_SYS_POLL_H
2681         #include <sys/poll.h>
2682         #endif
2683         int main(void) {
2684           struct pollfd fds[1];
2685           int fd;
2686           fd = open("/dev/null", 1);
2687           fds[0].fd = fd;
2688           fds[0].events = POLLIN;
2689           fds[0].revents = 0;
2690           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2691                 exit(1);  /* Does not work for devices -- fail */
2692           }
2693           exit(0);
2694         }]])],
2695   [broken_poll=no],
2696   [broken_poll=yes
2697    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2698   [broken_poll="no (cross compiling)"])
2699 AC_MSG_RESULT($broken_poll)
2700
2701 dnl *********************
2702 dnl *** GRegex checks ***
2703 dnl *********************
2704 PCRE_REQUIRED_VERSION=8.11
2705
2706 # Check if we should compile GRegex
2707 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2708               [disable the compilation of GRegex]),
2709 [case "${enableval}" in
2710   yes) enable_regex=true ;;
2711   no)  enable_regex=false ;;
2712   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2713 esac],
2714 [enable_regex=true])
2715
2716 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2717
2718 if test x$enable_regex = xtrue; then
2719   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2720   # Check if we should use the internal or the system-supplied pcre
2721   AC_ARG_WITH(pcre,
2722              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2723                              [specify whether to use the internal or the
2724                               system-supplied PCRE library])])
2725
2726   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2727
2728   if test "x$with_pcre" = xsystem; then
2729     PKG_CHECK_MODULES(PCRE,
2730                       libpcre >= $PCRE_REQUIRED_VERSION)
2731     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2732                    glib_save_CFLAGS="$CFLAGS"
2733                    glib_save_LIBS="$LIBS"
2734                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2735                    AC_TRY_RUN([#include <pcre.h>
2736                                int main () {
2737                                  int support;
2738                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2739                                  if (!support)
2740                                    return 1;
2741                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2742                                  if (!support)
2743                                    return 1;
2744                                  return 0;
2745                                }],
2746                    glib_cv_pcre_has_unicode=yes,
2747                    glib_cv_pcre_has_unicode=no,
2748                    glib_cv_pcre_has_unicode=yes)
2749                    CFLAGS="$glib_save_CFLAGS"
2750                    LIBS="$glib_save_LIBS"
2751         ])
2752     if test "$glib_cv_pcre_has_unicode" = "no"; then
2753       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2754     fi
2755     AC_SUBST(PCRE_CFLAGS)
2756     AC_SUBST(PCRE_LIBS)
2757     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2758     PCRE_REQUIRES=libpcre
2759     AC_SUBST(PCRE_REQUIRES)
2760   else
2761     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2762     if test x"$GCC" = xyes; then
2763       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2764       save_CFLAGS="$CFLAGS"
2765       CFLAGS="$CFLAGS -Wno-pointer-sign"
2766       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2767                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2768       CFLAGS="$save_CFLAGS"
2769     fi
2770   fi
2771   AC_SUBST(PCRE_WARN_CFLAGS)
2772 else
2773   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2774 fi
2775
2776 dnl **********************
2777 dnl *** Win32 API libs ***
2778 dnl **********************
2779
2780 case $host in
2781   *-*-cygwin*)
2782         G_LIBS_EXTRA="-luser32 -lkernel32"
2783     ;;
2784   *-*-mingw*)
2785         G_LIBS_EXTRA="-lws2_32 -lole32"
2786     ;;
2787   *)
2788         G_LIBS_EXTRA=""
2789     ;;
2790 esac
2791 AC_SUBST(G_LIBS_EXTRA)
2792
2793 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2794 dnl since we need it for g_iconv()
2795
2796 AC_MSG_CHECKING([for EILSEQ])
2797 AC_TRY_COMPILE([
2798 #include <errno.h>
2799 ],
2800 [
2801 int error = EILSEQ;
2802 ], have_eilseq=yes, have_eilseq=no);
2803 AC_MSG_RESULT($have_eilseq)
2804
2805 dnl ******************************************************************
2806 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2807 dnl *** glib-compile-schemas in PATH                               ***
2808 dnl ******************************************************************
2809
2810 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2811
2812 if test $cross_compiling = yes; then
2813   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2814   if test x$GLIB_GENMARSHAL = xno; then
2815     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2816   fi
2817
2818   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2819   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2820     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2821   fi
2822 fi
2823
2824 dnl **************************
2825 dnl *** Checks for gtk-doc ***
2826 dnl **************************
2827
2828 GTK_DOC_CHECK([1.15])
2829
2830 AC_ARG_ENABLE(man,
2831               [AC_HELP_STRING([--enable-man],
2832                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2833               enable_man=no)
2834
2835 if test "${enable_man}" != no; then
2836 dnl
2837 dnl Check for xsltproc
2838 dnl
2839 AC_PATH_PROG([XSLTPROC], [xsltproc])
2840   if test -z "$XSLTPROC"; then
2841     enable_man=no
2842   fi
2843
2844   dnl check for DocBook DTD and stylesheets in the local catalog.
2845   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2846      [DocBook XML DTD V4.1.2],,enable_man=no)
2847   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2848      [DocBook XSL Stylesheets],,enable_man=no)
2849 fi
2850
2851 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2852
2853 dnl
2854 dnl Tracing
2855 dnl
2856
2857 AC_ARG_ENABLE([dtrace],
2858              [AS_HELP_STRING([--enable-dtrace],
2859                               [Enable inclusion of dtrace trace support])])
2860 have_dtrace=no
2861 AC_MSG_CHECKING([whether to include dtrace tracing support])
2862 if test "x$enable_dtrace" != xno; then
2863   if test x$glib_have_carbon = xyes; then
2864     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2865   else
2866     AC_MSG_RESULT([yes])
2867     AC_CHECK_PROGS(DTRACE, dtrace)
2868     if test -z "$DTRACE"; then
2869       if test "x$enable_dtrace" = xyes; then
2870         AC_MSG_ERROR([dtrace not found])
2871       fi
2872     else
2873       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2874                       [if test "x$enable_dtrace" = xyes; then
2875                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2876                        fi])
2877     fi
2878   fi
2879 else
2880   AC_MSG_RESULT([no])
2881 fi
2882 if test "x$have_dtrace" = xyes; then
2883   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2884 fi
2885 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2886
2887 AC_MSG_CHECKING([whether to include systemtap tracing support])
2888 AC_ARG_ENABLE([systemtap],
2889              [AS_HELP_STRING([--enable-systemtap],
2890                               [Enable inclusion of systemtap trace support])])
2891 have_systemtap=no
2892 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2893   have_systemtap=yes
2894 fi
2895 AC_MSG_RESULT(${have_systemtap})
2896
2897 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2898
2899 AC_ARG_WITH([tapset-install-dir],
2900             [AS_HELP_STRING([--with-tapset-install-dir],
2901             [The absolute path where the systemtap tapsets will be installed])],
2902             [if test "x${withval}" = x; then
2903                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2904              else
2905                ABS_TAPSET_DIR="${withval}"
2906               fi],
2907             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2908 AC_SUBST(ABS_TAPSET_DIR)
2909
2910 dnl ************************************
2911 dnl *** Enable lcov coverage reports ***
2912 dnl ************************************
2913
2914 AC_ARG_ENABLE(gcov,
2915   AS_HELP_STRING([--enable-gcov],
2916                  [Enable gcov]),
2917   [use_gcov=$enableval], [use_gcov=no])
2918
2919 if test "x$use_gcov" = "xyes"; then
2920   dnl we need gcc:
2921   if test "$GCC" != "yes"; then
2922     AC_MSG_ERROR([GCC is required for --enable-gcov])
2923   fi
2924
2925   dnl Check if ccache is being used
2926   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2927   case `$SHTOOL path $CC` in
2928     *ccache*[)] gcc_ccache=yes;;
2929     *[)] gcc_ccache=no;;
2930   esac
2931
2932   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2933     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2934   fi
2935
2936   ltp_version_list="1.6 1.7 1.8"
2937   AC_CHECK_PROG(LTP, lcov, lcov)
2938   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2939
2940   if test "$LTP"; then
2941     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2942       glib_cv_ltp_version=invalid
2943       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2944       for ltp_check_version in $ltp_version_list; do
2945         if test "$ltp_version" = "$ltp_check_version"; then
2946           glib_cv_ltp_version="$ltp_check_version (ok)"
2947         fi
2948       done
2949     ])
2950   else
2951     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2952     AC_MSG_ERROR([$ltp_msg])
2953   fi
2954
2955   case $glib_cv_ltp_version in
2956     ""|invalid[)]
2957       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2958       AC_MSG_ERROR([$ltp_msg])
2959       LTP="exit 0;"
2960       ;;
2961   esac
2962
2963   if test -z "$LTP_GENHTML"; then
2964     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2965   fi
2966
2967   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2968
2969   dnl Remove all optimization flags from CFLAGS
2970   changequote({,})
2971   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2972   changequote([,])
2973
2974   dnl Add the special gcc flags
2975   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2976   LDFLAGS="$LDFLAGS -lgcov"
2977 fi
2978
2979 dnl ******************************
2980 dnl *** output the whole stuff ***
2981 dnl ******************************
2982
2983 dnl this section will only be run if config.status is invoked with no
2984 dnl arguments, or with "glib/glibconfig.h" as an argument.
2985 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2986 [
2987         outfile=glib/glibconfig.h-tmp
2988         cat > $outfile <<\_______EOF
2989 /* glibconfig.h
2990  *
2991  * This is a generated file.  Please modify 'configure.ac'
2992  */
2993
2994 #ifndef __G_LIBCONFIG_H__
2995 #define __G_LIBCONFIG_H__
2996
2997 #include <glib/gmacros.h>
2998
2999 _______EOF
3000
3001         if test x$glib_limits_h = xyes; then
3002           echo '#include <limits.h>' >> $outfile
3003         fi
3004         if test x$glib_float_h = xyes; then
3005           echo '#include <float.h>' >> $outfile
3006         fi
3007         if test x$glib_values_h = xyes; then
3008           echo '#include <values.h>' >> $outfile
3009         fi
3010         if test "$glib_header_alloca_h" = "yes"; then
3011           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
3012         fi
3013         if test x$glib_sys_poll_h = xyes; then
3014           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
3015         fi
3016         if test x$glib_included_printf != xyes; then
3017           echo "
3018 /* Specifies that GLib's g_print*() functions wrap the
3019  * system printf functions.  This is useful to know, for example,
3020  * when using glibc's register_printf_function().
3021  */" >> $outfile
3022           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
3023         fi
3024
3025         cat >> $outfile <<_______EOF
3026
3027 G_BEGIN_DECLS
3028
3029 #define G_MINFLOAT      $glib_mf
3030 #define G_MAXFLOAT      $glib_Mf
3031 #define G_MINDOUBLE     $glib_md
3032 #define G_MAXDOUBLE     $glib_Md
3033 #define G_MINSHORT      $glib_ms
3034 #define G_MAXSHORT      $glib_Ms
3035 #define G_MAXUSHORT     $glib_Mus
3036 #define G_MININT        $glib_mi
3037 #define G_MAXINT        $glib_Mi
3038 #define G_MAXUINT       $glib_Mui
3039 #define G_MINLONG       $glib_ml
3040 #define G_MAXLONG       $glib_Ml
3041 #define G_MAXULONG      $glib_Mul
3042
3043 _______EOF
3044
3045
3046         ### this should always be true in a modern C/C++ compiler
3047         cat >>$outfile <<_______EOF
3048 typedef signed char gint8;
3049 typedef unsigned char guint8;
3050 _______EOF
3051
3052
3053         if test -n "$gint16"; then
3054           cat >>$outfile <<_______EOF
3055 typedef signed $gint16 gint16;
3056 typedef unsigned $gint16 guint16;
3057 #define G_GINT16_MODIFIER $gint16_modifier
3058 #define G_GINT16_FORMAT $gint16_format
3059 #define G_GUINT16_FORMAT $guint16_format
3060 _______EOF
3061         fi
3062
3063
3064         if test -n "$gint32"; then
3065           cat >>$outfile <<_______EOF
3066 typedef signed $gint32 gint32;
3067 typedef unsigned $gint32 guint32;
3068 #define G_GINT32_MODIFIER $gint32_modifier
3069 #define G_GINT32_FORMAT $gint32_format
3070 #define G_GUINT32_FORMAT $guint32_format
3071 _______EOF
3072         fi
3073
3074         cat >>$outfile <<_______EOF
3075 #define G_HAVE_GINT64 1          /* deprecated, always true */
3076
3077 ${glib_extension}typedef signed $gint64 gint64;
3078 ${glib_extension}typedef unsigned $gint64 guint64;
3079
3080 #define G_GINT64_CONSTANT(val)  $gint64_constant
3081 #define G_GUINT64_CONSTANT(val) $guint64_constant
3082 _______EOF
3083
3084         if test x$gint64_format != x ; then
3085           cat >>$outfile <<_______EOF
3086 #define G_GINT64_MODIFIER $gint64_modifier
3087 #define G_GINT64_FORMAT $gint64_format
3088 #define G_GUINT64_FORMAT $guint64_format
3089 _______EOF
3090         else
3091           cat >>$outfile <<_______EOF
3092 #undef G_GINT64_MODIFIER
3093 #undef G_GINT64_FORMAT
3094 #undef G_GUINT64_FORMAT
3095 _______EOF
3096         fi
3097
3098         cat >>$outfile <<_______EOF
3099
3100 #define GLIB_SIZEOF_VOID_P $glib_void_p
3101 #define GLIB_SIZEOF_LONG   $glib_long
3102 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3103
3104 _______EOF
3105
3106         cat >>$outfile <<_______EOF
3107 typedef signed $glib_size_type_define gssize;
3108 typedef unsigned $glib_size_type_define gsize;
3109 #define G_GSIZE_MODIFIER $gsize_modifier
3110 #define G_GSSIZE_FORMAT $gssize_format
3111 #define G_GSIZE_FORMAT $gsize_format
3112
3113 #define G_MAXSIZE       G_MAXU$glib_msize_type
3114 #define G_MINSSIZE      G_MIN$glib_msize_type
3115 #define G_MAXSSIZE      G_MAX$glib_msize_type
3116
3117 typedef gint64 goffset;
3118 #define G_MINOFFSET     G_MININT64
3119 #define G_MAXOFFSET     G_MAXINT64
3120
3121 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3122 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3123 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3124
3125 _______EOF
3126
3127         if test -z "$glib_unknown_void_p"; then
3128           cat >>$outfile <<_______EOF
3129
3130 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3131 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3132
3133 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3134 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3135
3136 typedef signed $glib_intptr_type_define gintptr;
3137 typedef unsigned $glib_intptr_type_define guintptr;
3138
3139 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3140 #define G_GINTPTR_FORMAT        $gintptr_format
3141 #define G_GUINTPTR_FORMAT       $guintptr_format
3142 _______EOF
3143         else
3144           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3145         fi
3146
3147
3148
3149         cat >>$outfile <<_______EOF
3150 $glib_atexit
3151 $glib_memmove
3152 $glib_defines
3153 $glib_os
3154 $glib_static_compilation
3155
3156 $glib_vacopy
3157
3158 #ifdef  __cplusplus
3159 #define G_HAVE_INLINE   1
3160 #else   /* !__cplusplus */
3161 $glib_inline
3162 #endif  /* !__cplusplus */
3163
3164 #ifdef  __cplusplus
3165 #define G_CAN_INLINE    1
3166 _______EOF
3167
3168         if test x$g_can_inline = xyes ; then
3169                 cat >>$outfile <<_______EOF
3170 #else   /* !__cplusplus */
3171 #define G_CAN_INLINE    1
3172 _______EOF
3173         fi
3174
3175         cat >>$outfile <<_______EOF
3176 #endif
3177
3178 _______EOF
3179
3180         if test x$g_have_iso_c_varargs = xyes ; then
3181                 cat >>$outfile <<_______EOF
3182 #ifndef __cplusplus
3183 # define G_HAVE_ISO_VARARGS 1
3184 #endif
3185 _______EOF
3186         fi
3187         if test x$g_have_iso_cxx_varargs = xyes ; then
3188                 cat >>$outfile <<_______EOF
3189 #ifdef __cplusplus
3190 # define G_HAVE_ISO_VARARGS 1
3191 #endif
3192 _______EOF
3193         fi
3194         if test x$g_have_gnuc_varargs = xyes ; then
3195                 cat >>$outfile <<_______EOF
3196
3197 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3198  * is passed ISO vararg support is turned off, and there is no work
3199  * around to turn it on, so we unconditionally turn it off.
3200  */
3201 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3202 #  undef G_HAVE_ISO_VARARGS
3203 #endif
3204
3205 #define G_HAVE_GNUC_VARARGS 1
3206 _______EOF
3207         fi
3208
3209         case x$g_stack_grows in
3210         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3211         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3212         esac
3213
3214
3215         echo >>$outfile
3216         if test x$g_have_eilseq = xno; then
3217                 cat >>$outfile <<_______EOF
3218 #ifndef EILSEQ
3219 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3220  * The correspondence between this and the corresponding definition
3221  * in libiconv is essential.
3222  */
3223 #  define EILSEQ ENOENT
3224 #endif
3225 _______EOF
3226
3227         fi
3228
3229         if test x$g_have_gnuc_visibility = xyes; then
3230                 cat >>$outfile <<_______EOF
3231 #define G_HAVE_GNUC_VISIBILITY 1
3232 _______EOF
3233         fi
3234                 cat >>$outfile <<_______EOF
3235 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3236 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3237 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3238 #define G_GNUC_INTERNAL __hidden
3239 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3240 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3241 #else
3242 #define G_GNUC_INTERNAL
3243 #endif
3244 _______EOF
3245
3246
3247         echo >>$outfile
3248         if test x$g_mutex_has_default = xyes; then
3249                 cat >>$outfile <<_______EOF
3250 $g_enable_threads_def G_THREADS_ENABLED
3251 #define G_THREADS_IMPL_$g_threads_impl_def
3252 typedef struct _GStaticMutex GStaticMutex;
3253 struct _GStaticMutex
3254 {
3255   struct _GMutex *runtime_mutex;
3256   union {
3257     char   pad[[$g_mutex_sizeof]];
3258     double dummy_double;
3259     void  *dummy_pointer;
3260     long   dummy_long;
3261   } static_mutex;
3262 };
3263 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
3264 #define g_static_mutex_get_mutex(mutex) \\
3265   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
3266    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
3267 _______EOF
3268         else
3269                 cat >>$outfile <<_______EOF
3270 $g_enable_threads_def G_THREADS_ENABLED
3271 #define G_THREADS_IMPL_$g_threads_impl_def
3272 typedef struct _GMutex* GStaticMutex;
3273 #define G_STATIC_MUTEX_INIT NULL
3274 #define g_static_mutex_get_mutex(mutex) \\
3275   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3276 _______EOF
3277         fi
3278
3279         cat >>$outfile <<_______EOF
3280 /* This represents a system thread as used by the implementation. An
3281  * alien implementaion, as loaded by g_thread_init can only count on
3282  * "sizeof (gpointer)" bytes to store their info. We however need more
3283  * for some of our native implementations. */
3284 typedef union _GSystemThread GSystemThread;
3285 union _GSystemThread
3286 {
3287   char   data[[$g_system_thread_sizeof]];
3288   double dummy_double;
3289   void  *dummy_pointer;
3290   long   dummy_long;
3291 };
3292 _______EOF
3293         if test x"$g_memory_barrier_needed" != xno; then
3294           echo >>$outfile
3295           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3296         fi
3297         if test x"$g_gcc_atomic_ops" != xno; then
3298           echo >>$outfile
3299           echo "#define G_ATOMIC_OP_USE_GCC_BUILTINS 1" >>$outfile
3300         fi
3301         echo >>$outfile
3302         g_bit_sizes="16 32 64"
3303         for bits in $g_bit_sizes; do
3304           cat >>$outfile <<_______EOF
3305 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3306 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3307 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3308 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3309 _______EOF
3310         done
3311
3312         cat >>$outfile <<_______EOF
3313 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3314 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3315 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3316 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3317 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3318 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3319 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3320 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3321 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3322 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3323 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3324 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3325 #define G_BYTE_ORDER $g_byte_order
3326
3327 #define GLIB_SYSDEF_POLLIN =$g_pollin
3328 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3329 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3330 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3331 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3332 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3333
3334 #define G_MODULE_SUFFIX "$g_module_suffix"
3335
3336 /* A GPid is an abstraction for a process "handle". It is *not* an
3337  * abstraction for a process identifier in general. GPid is used in
3338  * GLib only for descendant processes spawned with the g_spawn*
3339  * functions. On POSIX there is no "process handle" concept as such,
3340  * but on Windows a GPid is a handle to a process, a kind of pointer,
3341  * not a process identifier.
3342  */
3343 typedef $g_pid_type GPid;
3344
3345 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3346 #define GLIB_SYSDEF_AF_INET $g_af_inet
3347 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3348
3349 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3350 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3351 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3352
3353 G_END_DECLS
3354
3355 #endif /* GLIBCONFIG_H */
3356 _______EOF
3357
3358
3359         if cmp -s $outfile glib/glibconfig.h; then
3360           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3361           rm -f $outfile
3362         else
3363           mv $outfile glib/glibconfig.h
3364         fi
3365 ],[
3366
3367 # Note that if two cases are the same, case goes with the first one.
3368 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3369 # on variable expansion in case labels.  Look at the generated config.status
3370 # for a hint.
3371
3372 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3373   glib_header_alloca_h="$ac_cv_working_alloca_h"
3374 else
3375   glib_header_alloca_h="$ac_cv_header_alloca_h"
3376 fi
3377
3378 case xyes in
3379 x$ac_cv_header_float_h)
3380   glib_float_h=yes
3381   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3382   glib_md=DBL_MIN glib_Md=DBL_MAX
3383   ;;
3384 x$ac_cv_header_values_h)
3385   glib_values_h=yes
3386   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3387   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3388   ;;
3389 esac
3390
3391 case xyes in
3392 x$ac_cv_header_limits_h)
3393   glib_limits_h=yes
3394   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3395   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3396   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3397   ;;
3398 x$ac_cv_header_values_h)
3399   glib_values_h=yes
3400   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3401   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3402   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3403   ;;
3404 esac
3405
3406 if test x$ac_cv_header_sys_poll_h = xyes ; then
3407   glib_sys_poll_h=yes
3408 fi
3409
3410 if test x$enable_included_printf = xyes ; then
3411   glib_included_printf=yes
3412 fi
3413
3414 case 2 in
3415 $ac_cv_sizeof_short)
3416   gint16=short
3417   gint16_modifier='"h"'
3418   gint16_format='"hi"'
3419   guint16_format='"hu"'
3420   ;;
3421 $ac_cv_sizeof_int)
3422   gint16=int
3423   gint16_modifier='""'
3424   gint16_format='"i"'
3425   guint16_format='"u"'
3426   ;;
3427 esac
3428 case 4 in
3429 $ac_cv_sizeof_short)
3430   gint32=short
3431   gint32_modifier='"h"'
3432   gint32_format='"hi"'
3433   guint32_format='"hu"'
3434   ;;
3435 $ac_cv_sizeof_int)
3436   gint32=int
3437   gint32_modifier='""'
3438   gint32_format='"i"'
3439   guint32_format='"u"'
3440   ;;
3441 $ac_cv_sizeof_long)
3442   gint32=long
3443   gint32_modifier='"l"'
3444   gint32_format='"li"'
3445   guint32_format='"lu"'
3446   ;;
3447 esac
3448 case 8 in
3449 $ac_cv_sizeof_int)
3450   gint64=int
3451   gint64_modifier='""'
3452   gint64_format='"i"'
3453   guint64_format='"u"'
3454   glib_extension=
3455   gint64_constant='(val)'
3456   guint64_constant='(val)'
3457   ;;
3458 $ac_cv_sizeof_long)
3459   gint64=long
3460   gint64_modifier='"l"'
3461   gint64_format='"li"'
3462   guint64_format='"lu"'
3463   glib_extension=
3464   gint64_constant='(val##L)'
3465   guint64_constant='(val##UL)'
3466   ;;
3467 $ac_cv_sizeof_long_long)
3468   gint64='long long'
3469   if test -n "$glib_cv_long_long_format"; then
3470     gint64_modifier='"'$glib_cv_long_long_format'"'
3471     gint64_format='"'$glib_cv_long_long_format'i"'
3472     guint64_format='"'$glib_cv_long_long_format'u"'
3473   fi
3474   glib_extension='G_GNUC_EXTENSION '
3475   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3476   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3477   ;;
3478 $ac_cv_sizeof___int64)
3479   gint64='__int64'
3480   if test -n "$glib_cv_long_long_format"; then
3481     gint64_modifier='"'$glib_cv_long_long_format'"'
3482     gint64_format='"'$glib_cv_long_long_format'i"'
3483     guint64_format='"'$glib_cv_long_long_format'u"'
3484   fi
3485   glib_extension=
3486   gint64_constant='(val##i64)'
3487   guint64_constant='(val##ui64)'
3488   ;;
3489 esac
3490 glib_size_t=$ac_cv_sizeof_size_t
3491 glib_size_type_define="$glib_size_type"
3492 glib_void_p=$ac_cv_sizeof_void_p
3493 glib_long=$ac_cv_sizeof_long
3494
3495 case "$glib_size_type" in
3496 short)
3497   gsize_modifier='"h"'
3498   gsize_format='"hu"'
3499   gssize_format='"hi"'
3500   glib_msize_type='SHRT'
3501   ;;
3502 int)
3503   gsize_modifier='""'
3504   gsize_format='"u"'
3505   gssize_format='"i"'
3506   glib_msize_type='INT'
3507   ;;
3508 long)
3509   gsize_modifier='"l"'
3510   gsize_format='"lu"'
3511   gssize_format='"li"'
3512   glib_msize_type='LONG'
3513   ;;
3514 "long long"|__int64)
3515   gsize_modifier='"I64"'
3516   gsize_format='"I64u"'
3517   gssize_format='"I64i"'
3518   glib_msize_type='INT64'
3519   ;;
3520 esac
3521
3522 gintbits=`expr $ac_cv_sizeof_int \* 8`
3523 glongbits=`expr $ac_cv_sizeof_long \* 8`
3524 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3525
3526 case $ac_cv_sizeof_void_p in
3527 $ac_cv_sizeof_int)
3528   glib_intptr_type_define=int
3529   gintptr_modifier='""'
3530   gintptr_format='"i"'
3531   guintptr_format='"u"'
3532   glib_gpi_cast=''
3533   glib_gpui_cast=''
3534   ;;
3535 $ac_cv_sizeof_long)
3536   glib_intptr_type_define=long
3537   gintptr_modifier='"l"'
3538   gintptr_format='"li"'
3539   guintptr_format='"lu"'
3540   glib_gpi_cast='(glong)'
3541   glib_gpui_cast='(gulong)'
3542   ;;
3543 $ac_cv_sizeof_long_long)
3544   glib_intptr_type_define='long long'
3545   gintptr_modifier='"I64"'
3546   gintptr_format='"I64i"'
3547   guintptr_format='"I64u"'
3548   glib_gpi_cast='(gint64)'
3549   glib_gpui_cast='(guint64)'
3550   ;;
3551 $ac_cv_sizeof___int64)
3552   glib_intptr_type_define=__int64
3553   gintptr_modifier='"I64"'
3554   gintptr_format='"I64i"'
3555   guintptr_format='"I64u"'
3556   glib_gpi_cast='(gint64)'
3557   glib_gpui_cast='(guint64)'
3558   ;;
3559 *)
3560   glib_unknown_void_p=yes
3561   ;;
3562 esac
3563
3564
3565 case xyes in
3566 x$ac_cv_func_atexit)
3567   glib_atexit="
3568 #ifdef NeXT /* @#%@! NeXTStep */
3569 # define g_ATEXIT(proc) (!atexit (proc))
3570 #else
3571 # define g_ATEXIT(proc) (atexit (proc))
3572 #endif"
3573   ;;
3574 x$ac_cv_func_on_exit)
3575   glib_atexit="
3576 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3577   ;;
3578 esac
3579
3580 case xyes in
3581 x$ac_cv_func_memmove)
3582   glib_memmove='
3583 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3584   ;;
3585 x$glib_cv_working_bcopy)
3586   glib_memmove="
3587 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3588 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3589   ;;
3590 *)
3591   glib_memmove="
3592 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3593  * so we have to roll our own copy routine. */
3594 void g_memmove (void* dest, const void * src, unsigned long len);"
3595   ;;
3596 esac
3597
3598 glib_defines="
3599 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3600 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3601 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3602 "
3603
3604 case xyes in
3605 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3606 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3607 *)                      glib_vacopy=''
3608 esac
3609
3610 if test x$glib_cv_va_val_copy = xno; then
3611   glib_vacopy="\$glib_vacopy
3612 #define G_VA_COPY_AS_ARRAY 1"
3613 fi
3614
3615 if test x$glib_cv_hasinline = xyes; then
3616     glib_inline='#define G_HAVE_INLINE 1'
3617 fi
3618 if test x$glib_cv_has__inline = xyes; then
3619     glib_inline="\$glib_inline
3620 #define G_HAVE___INLINE 1"
3621 fi
3622 if test x$glib_cv_has__inline__ = xyes; then
3623     glib_inline="\$glib_inline
3624 #define G_HAVE___INLINE__ 1"
3625 fi
3626
3627 g_have_gnuc_varargs=$g_have_gnuc_varargs
3628 g_have_iso_c_varargs=$g_have_iso_c_varargs
3629 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3630
3631 g_can_inline=$g_can_inline
3632 g_have_gnuc_visibility=$g_have_gnuc_visibility
3633 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3634
3635 if test x$ac_cv_c_bigendian = xyes; then
3636   g_byte_order=G_BIG_ENDIAN
3637   g_bs_native=BE
3638   g_bs_alien=LE
3639 else
3640   g_byte_order=G_LITTLE_ENDIAN
3641   g_bs_native=LE
3642   g_bs_alien=BE
3643 fi
3644
3645 g_pollin=$glib_cv_value_POLLIN
3646 g_pollout=$glib_cv_value_POLLOUT
3647 g_pollpri=$glib_cv_value_POLLPRI
3648 g_pollhup=$glib_cv_value_POLLHUP
3649 g_pollerr=$glib_cv_value_POLLERR
3650 g_pollnval=$glib_cv_value_POLLNVAL
3651
3652 g_af_unix=$glib_cv_value_AF_UNIX
3653 g_af_inet=$glib_cv_value_AF_INET
3654 g_af_inet6=$glib_cv_value_AF_INET6
3655
3656 g_msg_peek=$glib_cv_value_MSG_PEEK
3657 g_msg_oob=$glib_cv_value_MSG_OOB
3658 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3659
3660 g_stack_grows=$glib_cv_stack_grows
3661
3662 g_have_eilseq=$have_eilseq
3663
3664 case x$have_threads in
3665 xno)    g_enable_threads_def="#undef";;
3666 *)      g_enable_threads_def="#define";;
3667 esac
3668
3669 g_threads_impl_def=$g_threads_impl
3670
3671 g_mutex_has_default="$mutex_has_default"
3672 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3673 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3674 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3675
3676 g_memory_barrier_needed="$glib_memory_barrier_needed"
3677 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3678
3679 g_module_suffix="$glib_gmodule_suffix"
3680
3681 g_pid_type="$glib_pid_type"
3682 case $host in
3683   *-*-beos*)
3684     glib_os="#define G_OS_BEOS"
3685     ;;
3686   *-*-cygwin*)
3687     glib_os="#define G_OS_UNIX
3688 #define G_PLATFORM_WIN32
3689 #define G_WITH_CYGWIN"
3690     ;;
3691   *-*-mingw*)
3692     glib_os="#define G_OS_WIN32
3693 #define G_PLATFORM_WIN32"
3694     ;;
3695   *)
3696     glib_os="#define G_OS_UNIX"
3697     ;;
3698 esac
3699 glib_static_compilation=""
3700 if test x$glib_win32_static_compilation = xyes; then
3701   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3702 #define GOBJECT_STATIC_COMPILATION 1"
3703 fi
3704 ])
3705
3706 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3707 #
3708 # 1.2.14 required for dbus_message_set_serial
3709 PKG_CHECK_MODULES(DBUS1,
3710                   dbus-1 >= 1.2.14,
3711                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3712                   have_dbus1=no)
3713 AC_SUBST(DBUS1_CFLAGS)
3714 AC_SUBST(DBUS1_LIBS)
3715 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3716
3717 dnl
3718 dnl Check for -Bsymbolic-functions linker flag used to avoid
3719 dnl intra-library PLT jumps, if available.
3720 dnl
3721
3722 AC_ARG_ENABLE(Bsymbolic,
3723               [AC_HELP_STRING([--disable-Bsymbolic],
3724                               [avoid linking with -Bsymbolic])],,
3725               [SAVED_LDFLAGS="${LDFLAGS}"
3726                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3727                LDFLAGS=-Wl,-Bsymbolic-functions
3728                AC_TRY_LINK([], [int main (void) { return 0; }],
3729                            AC_MSG_RESULT(yes)
3730                            enable_Bsymbolic=yes,
3731                            AC_MSG_RESULT(no)
3732                            enable_Bsymbolic=no)
3733                LDFLAGS="${SAVED_LDFLAGS}"])
3734
3735 if test "x${enable_Bsymbolic}" == "xyes"; then
3736   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3737 fi
3738
3739 AC_SUBST(GLIB_LINK_FLAGS)
3740
3741 #
3742 # Define variables corresponding to the correct include paths to use for
3743 # in-tree building.
3744 #
3745
3746 # for config.h:
3747 config_h_INCLUDES='-I$(top_builddir)'
3748 AC_SUBST(config_h_INCLUDES)
3749
3750 # glib:
3751 #   config.h
3752 #   $(top_builddir)/glib: for glibconfig.h
3753 #   $(top_srcdir)/glib:   for glib.h
3754 #   $(top_srcdir):        for everything
3755 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3756 AC_SUBST(glib_INCLUDES)
3757
3758 # gthread:
3759 #   same as glib
3760 gthread_INCLUDES='$(glib_INCLUDES)'
3761 AC_SUBST(gthread_INCLUDES)
3762
3763 # gobject:
3764 #   same as gthread
3765 gobject_INCLUDES='$(gthread_INCLUDES)'
3766 AC_SUBST(gobject_INCLUDES)
3767
3768 # gmodule:
3769 #   glib includes
3770 #   $(top_srcdir)/gmodule: for gmodule.h
3771 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3772 AC_SUBST(gmodule_INCLUDES)
3773
3774 # gio:
3775 #   same as gmodule
3776 gio_INCLUDES='$(gmodule_INCLUDES)'
3777 AC_SUBST(gio_INCLUDES)
3778
3779
3780 AC_CONFIG_FILES([
3781 glib-2.0.pc
3782 glib-2.0-uninstalled.pc
3783 gmodule-2.0.pc
3784 gmodule-export-2.0.pc
3785 gmodule-no-export-2.0.pc
3786 gmodule-2.0-uninstalled.pc
3787 gmodule-no-export-2.0-uninstalled.pc
3788 gthread-2.0.pc
3789 gthread-2.0-uninstalled.pc
3790 gobject-2.0.pc
3791 gobject-2.0-uninstalled.pc
3792 gio-2.0.pc
3793 gio-unix-2.0.pc
3794 gio-windows-2.0.pc
3795 gio-2.0-uninstalled.pc
3796 gio-unix-2.0-uninstalled.pc
3797 glib-zip
3798 glib-gettextize
3799 Makefile
3800 build/Makefile
3801 build/win32/Makefile
3802 build/win32/dirent/Makefile
3803 build/win32/vs9/Makefile
3804 build/win32/vs10/Makefile
3805 glib/Makefile
3806 glib/glib.stp
3807 glib/libcharset/Makefile
3808 glib/gnulib/Makefile
3809 glib/pcre/Makefile
3810 glib/update-pcre/Makefile
3811 glib/tests/Makefile
3812 gmodule/Makefile
3813 gmodule/gmoduleconf.h
3814 gobject/Makefile
3815 gobject/gobject.stp
3816 gobject/glib-mkenums
3817 gobject/tests/Makefile
3818 gthread/Makefile
3819 gthread/tests/Makefile
3820 gio/Makefile
3821 gio/gdbus-codegen/Makefile
3822 gio/gdbus-codegen/config.py
3823 gio/xdgmime/Makefile
3824 gio/inotify/Makefile
3825 gio/libasyncns/Makefile
3826 gio/fen/Makefile
3827 gio/fam/Makefile
3828 gio/win32/Makefile
3829 gio/tests/Makefile
3830 gio/tests/gdbus-object-manager-example/Makefile
3831 po/Makefile.in
3832 docs/Makefile
3833 docs/reference/Makefile
3834 docs/reference/glib/Makefile
3835 docs/reference/glib/version.xml
3836 docs/reference/gobject/Makefile
3837 docs/reference/gobject/version.xml
3838 docs/reference/gio/Makefile
3839 docs/reference/gio/gdbus-object-manager-example/Makefile
3840 docs/reference/gio/version.xml
3841 tests/Makefile
3842 tests/gobject/Makefile
3843 tests/refcount/Makefile
3844 m4macros/Makefile
3845 ])
3846
3847 AC_CONFIG_COMMANDS([chmod-scripts],
3848 [chmod 0755 glib-zip
3849 chmod 0755 glib-gettextize
3850 chmod 0755 gobject/glib-mkenums])
3851
3852 # we want to invoke this macro solely so that the config.status script
3853 # and automake generated makefiles know about these generated files.
3854 # They are only needed to distcheck the package
3855 if false; then
3856   AC_CONFIG_FILES([
3857     INSTALL
3858     README
3859     config.h.win32
3860     glib/glibconfig.h.win32
3861     glib/makefile.msc
3862     glib/glib.rc
3863     gmodule/makefile.msc
3864     gmodule/gmodule.rc
3865     gobject/makefile.msc
3866     gobject/gobject.rc
3867     gthread/makefile.msc
3868     gthread/gthread.rc
3869     gio/gio.rc
3870     tests/makefile.msc
3871   ])
3872 fi
3873
3874 AC_OUTPUT