configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [7])
   6 m4_define([dbus_micro_version], [5])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22 # By default, rebuild autotools files on demand; only use ./missing if the
  23 # user says --disable-maintainer-mode (some distributions like to do this)
  24 AM_MAINTAINER_MODE([enable])
  25
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  29
  30 # libtool versioning - this applies to libdbus
  31 #
  32 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  33 #
  34
  35 ## increment if the interface has additions, changes, removals.
  36 LT_CURRENT=11
  37
  38 ## increment any time the source changes; set to
  39 ##  0 if you increment CURRENT
  40 LT_REVISION=2
  41
  42 ## increment if any interfaces have been added; set to 0
  43 ## if any interfaces have been changed or removed. removal has
  44 ## precedence over adding, so set to 0 if both happened.
  45 LT_AGE=8
  46
  47 AC_SUBST(LT_CURRENT)
  48 AC_SUBST(LT_REVISION)
  49 AC_SUBST(LT_AGE)
  50
  51 DBUS_MAJOR_VERSION=dbus_major_version
  52 DBUS_MINOR_VERSION=dbus_minor_version
  53 DBUS_MICRO_VERSION=dbus_micro_version
  54 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  55
  56 AC_SUBST(DBUS_MAJOR_VERSION)
  57 AC_SUBST(DBUS_MINOR_VERSION)
  58 AC_SUBST(DBUS_MICRO_VERSION)
  59 AC_SUBST(DBUS_VERSION)
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_CXX
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_ISC_POSIX
  66 AC_HEADER_STDC
  67 AC_C_INLINE
  68 AM_PROG_LIBTOOL
  69 AC_PROG_MKDIR_P
  70 COMPILER_COVERAGE
  71 COMPILER_OPTIMISATIONS
  72 PKG_PROG_PKG_CONFIG
  73
  74 # Initialize libtool
  75 LT_INIT([win32-dll])
  76 LT_LANG([Windows Resource])
  77
  78 # Set some internal variables depending on the platform for later use.
  79 dbus_win=no
  80 dbus_cygwin=no
  81 dbus_unix=no
  82 case "${host}" in
  83     *-mingw32ce*)
  84         dbus_win=yes
  85         dbus_wince=yes
  86         ;;
  87     *-mingw32*)
  88         dbus_win=yes
  89         ;;
  90     *-cygwin*)
  91         dbus_cygwin=yes
  92         dbus_unix=yes
  93         ;;
  94     *)
  95         dbus_unix=yes
  96        ;;
  97 esac
  98
  99 # Special defines for certain platforms
 100 if test "$dbus_win" = yes; then
 101     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 102     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 103     AC_SUBST(BUILD_TIMESTAMP)
 104     # Assume DBUS_VERSION is always three numbers
 105     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 106     AC_SUBST(BUILD_FILEVERSION)
 107     AC_CHECK_TOOL(WINDRES, windres, no)
 108     if test "$WINDRES" = no; then
 109       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 110     fi
 111     if test "$dbus_wince" = yes; then
 112       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 113       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 114     fi
 115 else
 116     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 117 fi
 118 if test "$dbus_cygwin" = yes; then
 119     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 120 fi
 121
 122 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 123 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 124 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 125 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 126
 127 # this must come first: other options use this to set their defaults
 128 AC_ARG_ENABLE([developer],
 129   [AS_HELP_STRING([--enable-developer],
 130     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
 131   [],
 132   [enable_developer=no])
 133
 134 DBUS_STATIC_BUILD_CPPFLAGS=
 135 if test "x$enable_shared" = xno; then
 136     # On Windows, linking against the static library requires special effort
 137     # to turn off DLL import/export processing. We normally link some things
 138     # against the dynamic library, but if we're not building that, we'll
 139     # have to link everything statically.
 140     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 141 fi
 142 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 143
 144 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 145 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 146 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 147 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 148 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 149 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 150 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 151 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 152 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 153 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 154 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 155 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 156 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 157 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 158 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 159
 160 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 161 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 162 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 163 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 164 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 165 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 166 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 167 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 168 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 169 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 170
 171 AC_ARG_ENABLE([embedded-tests],
 172   AS_HELP_STRING([--enable-embedded-tests],
 173     [enable unit test code in the library and binaries]),
 174   [], [enable_embedded_tests=$enable_developer])
 175 AC_ARG_ENABLE([modular-tests],
 176   AS_HELP_STRING([--enable-modular-tests],
 177     [enable modular regression tests (requires GLib)]),
 178   [], [enable_modular_tests=auto])
 179 # --enable-tests overrides both --enable-embedded-tests and
 180 # --enable-modular-tests
 181 AC_ARG_ENABLE([tests],
 182   AS_HELP_STRING([--enable-tests],
 183     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 184   [
 185   if test "x$enableval" = xyes; then
 186     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 187     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 188   fi
 189   enable_embedded_tests=$enableval
 190   enable_modular_tests=$enableval
 191   ],
 192   [])
 193
 194 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 195 # and also some stuff in the test/ subdir.
 196 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 197   [test "x$enable_embedded_tests" = xyes])
 198 if test "x$enable_embedded_tests" = xyes; then
 199     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 200       [Define to build test code into the library and binaries])
 201 fi
 202
 203 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 204 # These use GTest, from GLib, because life's too short. They're enabled by
 205 # default (unless you don't have GLib), because they don't bloat the library
 206 # or binaries.
 207
 208 AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_26], [Ignore post-2.26 deprecations])
 209 AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [GLIB_VERSION_2_32], [Prevent post-2.32 APIs])
 210
 211 with_glib=yes
 212
 213 if test "x$enable_modular_tests" != xno; then
 214   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 215     [],
 216     [if test "x$enable_modular_tests" = xyes; then
 217       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 218       AC_MSG_ERROR([$GLIB_ERRORS])
 219     else # assumed to be "auto"
 220       with_glib=no
 221     fi])
 222   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 223   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 224     [],
 225     [if test "x$enable_modular_tests" = xyes; then
 226       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 227       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 228     else # assumed to be "auto"
 229       with_glib=no
 230     fi])
 231 fi
 232 if test "x$enable_modular_tests" != xno; then
 233   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 234     [Define to build independent test binaries])
 235 fi
 236 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 237   [test "x$enable_modular_tests" != xno])
 238
 239 if test "x$with_glib" != xno; then
 240   AC_DEFINE([DBUS_WITH_GLIB], [1],
 241     [Define if GLib, GObject, GIO are available])
 242 fi
 243 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 244
 245 AC_ARG_ENABLE([installed-tests],
 246   AS_HELP_STRING([--enable-installed-tests],
 247     [enable unit test code in the library and binaries]),
 248   [], [enable_installed_tests=no])
 249 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 250   [test "x$enable_installed_tests" = xyes])
 251
 252 if test "x$enable_tests" = xyes; then
 253   # full test coverage is required, Python is a hard dependency
 254   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 255   AM_PATH_PYTHON([2.6])
 256   AC_MSG_CHECKING([for Python modules for full test coverage])
 257   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 258     AC_MSG_RESULT([yes])
 259   else
 260     AC_MSG_RESULT([no])
 261     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 262   fi
 263 else
 264   # --enable-tests not given: do not abort if Python is missing
 265   AM_PATH_PYTHON([2.6], [], [:])
 266 fi
 267
 268 if test x$enable_verbose_mode = xyes; then
 269     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 270 fi
 271
 272 if test x$enable_asserts = xno; then
 273     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 274     DISABLE_UNUSED_WARNINGS="unused-label"
 275     R_DYNAMIC_LDFLAG=""
 276     if test x$enable_embedded_tests = xyes; then
 277         DISABLE_UNUSED_WARNINGS="$DISABLE_UNUSED_WARNINGS \
 278                 unused-but-set-variable unused-variable \
 279                 unused-function"
 280     fi
 281 else
 282     # -rdynamic is needed for glibc's backtrace_symbols to work.
 283     # No clue how much overhead this adds, but it's useful
 284     # to do this on any assertion failure,
 285     # so for now it's enabled anytime asserts are (currently not
 286     # in production builds).
 287
 288     # To get -rdynamic you pass -export-dynamic to libtool.
 289     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 290     R_DYNAMIC_LDFLAG=-export-dynamic
 291 fi
 292 AC_SUBST(R_DYNAMIC_LDFLAG)
 293
 294 if test x$enable_checks = xno; then
 295     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 296     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 297     DISABLE_UNUSED_WARNINGS="unused-label"
 298 fi
 299
 300 AH_BOTTOM([
 301 /* explicitly define these macros to get less confusing conditions */
 302 #ifndef DBUS_DISABLE_ASSERT
 303 #  define DBUS_ENABLE_ASSERT 1
 304 #endif
 305 #ifndef DBUS_DISABLE_CHECKS
 306 #  define DBUS_ENABLE_CHECKS 1
 307 #endif])
 308
 309 if test x$enable_userdb_cache = xyes; then
 310     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 311 fi
 312
 313 if test x$enable_compiler_coverage = xyes; then
 314      ## so that config.h changes when you toggle gcov support
 315      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 316 fi
 317
 318 # glibc21.m4 serial 3
 319 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 320 dnl This file is free software; the Free Software Foundation
 321 dnl gives unlimited permission to copy and/or distribute it,
 322 dnl with or without modifications, as long as this notice is preserved.
 323
 324 # Test for the GNU C Library, version 2.1 or newer.
 325 # From Bruno Haible.
 326
 327 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 328   ac_cv_gnu_library_2_1,
 329   [AC_EGREP_CPP([Lucky GNU user],
 330     [
 331 #include <features.h>
 332 #ifdef __GNU_LIBRARY__
 333  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 334   Lucky GNU user
 335  #endif
 336 #endif
 337     ],
 338     ac_cv_gnu_library_2_1=yes,
 339     ac_cv_gnu_library_2_1=no)
 340   ]
 341 )
 342
 343 #### Integer sizes
 344
 345 AC_CHECK_SIZEOF(char)
 346 AC_CHECK_SIZEOF(short)
 347 AC_CHECK_SIZEOF(long)
 348 AC_CHECK_SIZEOF(int)
 349 AC_CHECK_SIZEOF(void *)
 350 AC_CHECK_SIZEOF(long long)
 351 AC_CHECK_SIZEOF(__int64)
 352
 353 AC_ARG_WITH([64-bit],
 354   [AS_HELP_STRING([--without-64-bit],
 355     [If you have to use this option, please report it as a bug])],
 356   [],
 357   [with_64_bit=yes])
 358
 359 ### See what our 64 bit type is called
 360 AC_MSG_CHECKING([64-bit integer type])
 361
 362 case 8 in
 363 $ac_cv_sizeof_int)
 364   dbusint64=int
 365   dbusint64_constant='(val)'
 366   dbusuint64_constant='(val)'
 367   dbusint64_printf_modifier='""'
 368   ;;
 369 $ac_cv_sizeof_long)
 370   dbusint64=long
 371   dbusint64_constant='(val##L)'
 372   dbusuint64_constant='(val##UL)'
 373   dbusint64_printf_modifier='"l"'
 374   ;;
 375 $ac_cv_sizeof_long_long)
 376   dbusint64='long long'
 377   dbusint64_constant='(val##LL)'
 378   dbusuint64_constant='(val##ULL)'
 379   # Ideally we discover what the format is, but this is
 380   # only used in verbose mode, so eh...
 381   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 382     dbusint64_printf_modifier='"ll"'
 383   fi
 384   ;;
 385 $ac_cv_sizeof___int64)
 386   dbusint64=__int64
 387   dbusint64_constant='(val##i64)'
 388   dbusuint64_constant='(val##ui64)'
 389   # See above case
 390   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 391     dbusint64_printf_modifier='"ll"'
 392   fi
 393   ;;
 394 esac
 395
 396 AS_IF(
 397   [test "x$with_64_bit" = xno],
 398   [
 399         DBUS_INT64_TYPE="no_int64_type_detected"
 400         DBUS_HAVE_INT64=0
 401         DBUS_INT64_CONSTANT=
 402         DBUS_UINT64_CONSTANT=
 403         AC_MSG_RESULT([disabled via --without-64-bit])
 404   ],
 405   dnl else if
 406   [test -z "$dbusint64"],
 407   [AC_MSG_RESULT([not found])
 408   AC_MSG_ERROR([Could not find a 64-bit integer type.
 409
 410 Please report a bug here with details of your platform and compiler:
 411
 412     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 413
 414 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 415 the option "--without-64-bit".
 416
 417 This option is likely to be removed in future, unless you report that your
 418 platform needs it.])
 419   ],
 420   dnl else
 421   [
 422         DBUS_INT64_TYPE="$dbusint64"
 423         DBUS_HAVE_INT64=1
 424         DBUS_INT64_CONSTANT="$dbusint64_constant"
 425         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 426         if test x"$dbusint64_printf_modifier" != x; then
 427                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 428         fi
 429         AC_MSG_RESULT($DBUS_INT64_TYPE)
 430   ])
 431
 432 AC_SUBST(DBUS_INT64_TYPE)
 433 AC_SUBST(DBUS_INT64_CONSTANT)
 434 AC_SUBST(DBUS_UINT64_CONSTANT)
 435 AC_SUBST(DBUS_HAVE_INT64)
 436
 437 ### see what 32-bit int is called
 438 AC_MSG_CHECKING([32-bit integer type])
 439
 440 case 4 in
 441 $ac_cv_sizeof_short)
 442   dbusint32=short
 443   ;;
 444 $ac_cv_sizeof_int)
 445   dbusint32=int
 446   ;;
 447 $ac_cv_sizeof_long)
 448   dbusint32=long
 449   ;;
 450 esac
 451
 452 if test -z "$dbusint32" ; then
 453         DBUS_INT32_TYPE="no_int32_type_detected"
 454         AC_MSG_ERROR([No 32-bit integer type found])
 455 else
 456         DBUS_INT32_TYPE="$dbusint32"
 457         AC_MSG_RESULT($DBUS_INT32_TYPE)
 458 fi
 459
 460 AC_SUBST(DBUS_INT32_TYPE)
 461
 462 ### see what 16-bit int is called
 463 AC_MSG_CHECKING([16-bit integer type])
 464
 465 case 2 in
 466 $ac_cv_sizeof_short)
 467   dbusint16=short
 468   ;;
 469 $ac_cv_sizeof_int)
 470   dbusint16=int
 471   ;;
 472 esac
 473
 474 if test -z "$dbusint16" ; then
 475         DBUS_INT16_TYPE="no_int16_type_detected"
 476         AC_MSG_ERROR([No 16-bit integer type found])
 477 else
 478         DBUS_INT16_TYPE="$dbusint16"
 479         AC_MSG_RESULT($DBUS_INT16_TYPE)
 480 fi
 481
 482 AC_SUBST(DBUS_INT16_TYPE)
 483
 484 ## byte order
 485 case $host_os in
 486         darwin*)
 487                 # check at compile-time, so that it is possible to build universal
 488                 # (with multiple architectures at once on the compile line)
 489                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 490                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 491                         #if defined(__BIG_ENDIAN__)
 492                         #define WORDS_BIGENDIAN 1
 493                         #endif
 494                 ])
 495                 ;;
 496         *)
 497                 AC_C_BIGENDIAN
 498                 ;;
 499 esac
 500
 501 dnl **********************************
 502 dnl *** va_copy checks (from GLib) ***
 503 dnl **********************************
 504 dnl we currently check for all three va_copy possibilities, so we get
 505 dnl all results in config.log for bug reports.
 506 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 507         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 508 #include <stdlib.h>
 509         static void f (int i, ...) {
 510         va_list args1, args2;
 511         va_start (args1, i);
 512         va_copy (args2, args1);
 513         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 514           exit (1);
 515         va_end (args1); va_end (args2);
 516         }
 517         int main() {
 518           f (0, 42);
 519           return 0;
 520         }])],
 521         [dbus_cv_va_copy=yes],
 522         [dbus_cv_va_copy=no])
 523 ])
 524 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 525         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 526 #include <stdlib.h>
 527         static void f (int i, ...) {
 528         va_list args1, args2;
 529         va_start (args1, i);
 530         __va_copy (args2, args1);
 531         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 532           exit (1);
 533         va_end (args1); va_end (args2);
 534         }
 535         int main() {
 536           f (0, 42);
 537           return 0;
 538         }])],
 539         [dbus_cv___va_copy=yes],
 540         [dbus_cv___va_copy=no])
 541 ])
 542
 543 if test "x$dbus_cv_va_copy" = "xyes"; then
 544   dbus_va_copy_func=va_copy
 545 else if test "x$dbus_cv___va_copy" = "xyes"; then
 546   dbus_va_copy_func=__va_copy
 547 fi
 548 fi
 549
 550 if test -n "$dbus_va_copy_func"; then
 551   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 552 fi
 553
 554 AC_LANG_PUSH(C)
 555 AC_CACHE_CHECK([whether va_lists can be copied by value],
 556         dbus_cv_va_val_copy,
 557         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 558 [[
 559         #include <stdarg.h>
 560         #include <stdlib.h>
 561 ]],
 562 [[
 563         static void f (int i, ...) {
 564         va_list args1, args2;
 565         va_start (args1, i);
 566         args2 = args1;
 567         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 568           exit (1);
 569         va_end (args1); va_end (args2);
 570         }
 571         int main() {
 572           f (0, 42);
 573           return 0;
 574         }
 575 ]])],
 576         [dbus_cv_va_val_copy=yes],
 577         [dbus_cv_va_val_copy=no],
 578         [dbus_cv_va_val_copy=yes])
 579 ])
 580 AC_LANG_POP(C)
 581
 582 if test "x$dbus_cv_va_val_copy" = "xno"; then
 583   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 584 fi
 585
 586
 587 #### Atomic integers
 588
 589 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 590   dbus_cv_sync_sub_and_fetch,
 591   [AC_LINK_IFELSE([
 592      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 593      [dbus_cv_sync_sub_and_fetch=yes],
 594      [dbus_cv_sync_sub_and_fetch=no])
 595   ])
 596
 597 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 598    have_sync=1
 599 else
 600    have_sync=0
 601 fi
 602
 603 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 604
 605 #### Various functions
 606 AC_SEARCH_LIBS(socket,[socket network])
 607 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 608
 609 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid)
 610
 611 AC_CHECK_HEADERS([syslog.h])
 612 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 613   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 614 fi
 615
 616 #### Check for broken poll; taken from Glib's configure
 617
 618 AC_MSG_CHECKING([for broken poll])
 619 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 620     #include <stdlib.h>
 621     #include <fcntl.h>
 622     #include <poll.h>
 623     #ifdef HAVE_SYS_POLL_H
 624     #include <sys/poll.h>
 625     #endif
 626     int main(void) {
 627       struct pollfd fds[1];
 628       int fd;
 629       fd = open("/dev/null", 1);
 630       fds[0].fd = fd;
 631       fds[0].events = POLLIN;
 632       fds[0].revents = 0;
 633       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 634             exit(1);  /* Does not work for devices -- fail */
 635       }
 636       exit(0);
 637     }]])],
 638   [broken_poll=no],
 639   [broken_poll=yes
 640    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 641   [broken_poll="no (cross compiling)"])
 642 AC_MSG_RESULT($broken_poll)
 643
 644 AC_MSG_CHECKING(for dirfd)
 645 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 646 #include <sys/types.h>
 647 #include <dirent.h>
 648 ]], [[
 649 DIR *dirp;
 650 dirp = opendir(".");
 651 dirfd(dirp);
 652 closedir(dirp);
 653 ]])],
 654 [dbus_have_dirfd=yes],
 655 [dbus_have_dirfd=no])
 656 AC_MSG_RESULT($dbus_have_dirfd)
 657 if test "$dbus_have_dirfd" = yes; then
 658         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 659 else
 660         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 661         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 662 #include <sys/types.h>
 663 #include <dirent.h>
 664         ]], [[
 665 DIR *dirp;
 666 int fd;
 667 dirp = opendir(".");
 668 fd = dirp->dd_fd;
 669 closedir(dirp);
 670         ]])],
 671         [dbus_have_ddfd=yes],
 672         [dbus_have_ddfd=no])
 673         AC_MSG_RESULT($dbus_have_ddfd)
 674         if test "$dbus_have_ddfd" = yes; then
 675                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 676         fi
 677 fi
 678
 679 AC_CHECK_HEADERS(sys/resource.h)
 680
 681 AC_CHECK_HEADERS(dirent.h)
 682
 683 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 684
 685 AC_CHECK_HEADERS(errno.h)
 686
 687 AC_CHECK_HEADERS(signal.h)
 688
 689 AC_CHECK_HEADERS(locale.h)
 690
 691 AC_CHECK_HEADERS(byteswap.h)
 692
 693 AC_CHECK_HEADERS(unistd.h)
 694
 695 AC_CHECK_HEADERS(ws2tcpip.h)
 696
 697 AC_CHECK_HEADERS(wspiapi.h)
 698
 699 AC_CHECK_HEADERS(alloca.h)
 700
 701 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 702 #
 703 case $host_os in
 704     solaris*)
 705        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 706 esac
 707
 708 # checking for a posix version of getpwnam_r
 709 # if we are cross compiling and can not run the test
 710 # assume getpwnam_r is the posix version
 711 # it is up to the person cross compiling to change
 712 # this behavior if desired
 713 AC_LANG_PUSH(C)
 714 AC_CACHE_CHECK([for posix getpwnam_r],
 715                 ac_cv_func_posix_getpwnam_r,
 716                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 717 [[
 718 #include <errno.h>
 719 #include <pwd.h>
 720 ]],
 721 [[
 722     char buffer[10000];
 723     struct passwd pwd, *pwptr = &pwd;
 724     int error;
 725     errno = 0;
 726     error = getpwnam_r ("", &pwd, buffer,
 727                         sizeof (buffer), &pwptr);
 728    return (error < 0 && errno == ENOSYS)
 729            || error == ENOSYS;
 730 ]])],
 731         [ac_cv_func_posix_getpwnam_r=yes],
 732         [ac_cv_func_posix_getpwnam_r=no],
 733         [ac_cv_func_posix_getpwnam_r=yes]
 734 )])
 735 AC_LANG_POP(C)
 736
 737 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 738         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 739                 [Have POSIX function getpwnam_r])
 740 else
 741         AC_CACHE_CHECK([for nonposix getpwnam_r],
 742                 ac_cv_func_nonposix_getpwnam_r,
 743                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 744                         struct passwd pwd;
 745                         getpwnam_r ("", &pwd, buffer,
 746                                         sizeof (buffer));]])],
 747                         [ac_cv_func_nonposix_getpwnam_r=yes],
 748                         [ac_cv_func_nonposix_getpwnam_r=no])])
 749                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 750                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 751                         [Have non-POSIX function getpwnam_r])
 752         fi
 753 fi
 754
 755 dnl check for socklen_t
 756 AC_MSG_CHECKING(whether socklen_t is defined)
 757 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 758 #include <sys/types.h>
 759 #include <sys/socket.h>
 760 #include <netdb.h>
 761 ]], [[
 762 socklen_t foo;
 763 foo = 1;
 764 ]])],
 765 [dbus_have_socklen_t=yes],
 766 [dbus_have_socklen_t=no])
 767 AC_MSG_RESULT($dbus_have_socklen_t)
 768
 769 if test "x$dbus_have_socklen_t" = "xyes"; then
 770     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 771 fi
 772
 773 dnl check for writev header and writev function so we're
 774 dnl good to go if HAVE_WRITEV gets defined.
 775 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 776
 777 dnl needed on darwin for NAME_MAX
 778 AC_CHECK_HEADERS(sys/syslimits.h)
 779
 780 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 781 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 782 #include <sys/socket.h> ]])
 783
 784 dnl check for flavours of varargs macros (test from GLib)
 785 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 786 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 787 int a(int p1, int p2, int p3);
 788 #define call_a(...) a(1,__VA_ARGS__)
 789 call_a(2,3);
 790 ]])],
 791 [dbus_have_iso_c_varargs=yes],
 792 [dbus_have_iso_c_varargs=no])
 793 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 794
 795 AC_MSG_CHECKING(for GNUC varargs macros)
 796 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 797 int a(int p1, int p2, int p3);
 798 #define call_a(params...) a(1,params)
 799 call_a(2,3);
 800 ]])],
 801 [dbus_have_gnuc_varargs=yes],
 802 [dbus_have_gnuc_varargs=no])
 803 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 804
 805 dnl Output varargs tests
 806 if test x$dbus_have_iso_c_varargs = xyes; then
 807     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 808 fi
 809 if test x$dbus_have_gnuc_varargs = xyes; then
 810     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 811 fi
 812
 813 dnl Check for various credentials.
 814 AC_MSG_CHECKING(for struct cmsgcred)
 815 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 816 #include <sys/types.h>
 817 #include <sys/socket.h>
 818 ]], [[
 819 struct cmsgcred cred;
 820
 821 cred.cmcred_pid = 0;
 822 ]])],
 823 [dbus_have_struct_cmsgcred=yes],
 824 [dbus_have_struct_cmsgcred=no])
 825 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 826
 827 if test x$dbus_have_struct_cmsgcred = xyes; then
 828     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 829 fi
 830
 831 AC_CHECK_FUNCS(getpeerucred getpeereid)
 832
 833 AC_CHECK_FUNCS(pipe2 accept4)
 834
 835 #### Abstract sockets
 836
 837 if test x$enable_abstract_sockets = xauto; then
 838 AC_LANG_PUSH(C)
 839 warn_on_xcompile=no
 840 AC_CACHE_CHECK([abstract socket namespace],
 841                 ac_cv_have_abstract_sockets,
 842                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 843 [[
 844 #include <sys/types.h>
 845 #include <stdlib.h>
 846 #include <string.h>
 847 #include <stdio.h>
 848 #include <sys/socket.h>
 849 #include <sys/un.h>
 850 #include <errno.h>
 851 ]],
 852 [[
 853   size_t slen;
 854   int listen_fd;
 855   struct sockaddr_un addr;
 856
 857   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 858
 859   if (listen_fd < 0)
 860     {
 861       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 862       exit (1);
 863     }
 864
 865   memset (&addr, '\0', sizeof (addr));
 866   addr.sun_family = AF_UNIX;
 867   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 868   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 869    * beginning.
 870    */
 871   slen = SUN_LEN(&addr);
 872   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 873
 874   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 875     {
 876        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 877                 strerror (errno));
 878        exit (1);
 879     }
 880   else
 881     exit (0);
 882 ]])],
 883               [ac_cv_have_abstract_sockets=yes],
 884               [ac_cv_have_abstract_sockets=no],
 885               [
 886                 ac_cv_have_abstract_sockets=no
 887                 warn_on_xcompile=yes
 888               ]
 889 )])
 890 if test x$warn_on_xcompile = xyes ; then
 891   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 892 fi
 893 AC_LANG_POP(C)
 894 fi
 895
 896 if test x$enable_abstract_sockets = xyes; then
 897     if test x$ac_cv_have_abstract_sockets = xno; then
 898         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 899     fi
 900 fi
 901
 902 if test x$enable_abstract_sockets = xno; then
 903    ac_cv_have_abstract_sockets=no;
 904 fi
 905
 906 if test x$ac_cv_have_abstract_sockets = xyes ; then
 907    DBUS_PATH_OR_ABSTRACT=abstract
 908    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 909 else
 910    DBUS_PATH_OR_ABSTRACT=path
 911 fi
 912
 913 # this is used in addresses to prefer abstract, e.g.
 914 # unix:path=/foo or unix:abstract=/foo
 915 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 916
 917 PKG_PROG_PKG_CONFIG
 918
 919 #### Sort out XML library
 920
 921 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 922              [ AC_CHECK_HEADERS(expat.h, [],
 923                                 [AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])]) ],
 924              [ AC_MSG_ERROR([Explicitly requested expat but expat not found]) ])
 925
 926 XML_LIBS=-lexpat
 927 XML_CFLAGS=
 928 AC_SUBST([XML_CFLAGS])
 929 AC_SUBST([XML_LIBS])
 930
 931 # Thread lib detection
 932 AC_ARG_VAR([THREAD_LIBS])
 933 save_libs="$LIBS"
 934 LIBS="$LIBS $THREAD_LIBS"
 935
 936 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 937
 938 # Don't do these automatic checks if the user set THREAD_LIBS on the
 939 # configure command-line. If they did, we assume they're right.
 940 #
 941 # We also don't do these checks on Windows, because you don't need magical
 942 # linker flags to have threading support there.
 943 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 944   [
 945     # Mandatory pthread functions. In principle, some of these could be made
 946     # optional if there are platforms that don't have them.
 947     #
 948     # Currently, we only look in -lpthread.
 949     # In principle we might need to look in -lpthreads, -lthreads, ...
 950     # as well - please file a bug if your platform needs this.
 951     AC_SEARCH_LIBS([pthread_cond_timedwait],
 952         [pthread],
 953         [THREAD_LIBS="$LIBS"],
 954         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 955         [])
 956     AC_SEARCH_LIBS([pthread_mutexattr_init],
 957         [pthread],
 958         [THREAD_LIBS="$LIBS"],
 959         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 960         [])
 961     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 962         [pthread],
 963         [THREAD_LIBS="$LIBS"],
 964         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 965         [])
 966
 967     # Optional, for monotonic clocks. Because it's optional, this check
 968     # is non-fatal if we don't find it.
 969     AC_SEARCH_LIBS([pthread_condattr_setclock],
 970         [pthread],
 971         [THREAD_LIBS="$LIBS"])
 972
 973     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
 974       [
 975         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
 976         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 977         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 978 [[#include <time.h>
 979 #include <pthread.h>
 980 ]], [[
 981 struct timespec monotonic_timer;
 982 pthread_condattr_t attr;
 983 pthread_condattr_init (&attr);
 984 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 985 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 986 ]])],
 987             [have_clock_monotonic=true],
 988             [have_clock_monotonic=false])
 989         AS_IF([test x$have_clock_monotonic = xtrue],
 990           [
 991             AC_MSG_RESULT([found])
 992             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 993           ],
 994           [AC_MSG_RESULT([not found])])
 995       ]) dnl have pthread_condattr_setclock
 996   ]) dnl on Unix
 997
 998 LIBS="$save_libs"
 999
1000 AC_SUBST([THREAD_LIBS])
1001
1002 # SELinux detection
1003 if test x$enable_selinux = xno ; then
1004     have_selinux=no;
1005 else
1006     # See if we have SELinux library
1007     AC_CHECK_LIB(selinux, is_selinux_enabled,
1008                  have_selinux=yes, have_selinux=no)
1009
1010     # see if we have the SELinux header with the new D-Bus stuff in it
1011     if test x$have_selinux = xyes ; then
1012         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
1013         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
1014                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
1015                             #else
1016                             #error DBUS__ACQUIRE_SVC not defined
1017                             #endif]])],
1018                           [have_selinux=yes],
1019                           [have_selinux=no])
1020         AC_MSG_RESULT($have_selinux)
1021     fi
1022
1023     if test x$enable_selinux = xauto ; then
1024         if test x$have_selinux = xno ; then
1025                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1026         fi
1027     else
1028         if test x$have_selinux = xno ; then
1029                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1030         fi
1031     fi
1032 fi
1033
1034 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1035
1036 if test x$have_selinux = xyes ; then
1037     # the selinux code creates threads
1038     # which requires libpthread even on linux
1039     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1040                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1041
1042     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1043     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1044 else
1045     SELINUX_LIBS=
1046 fi
1047
1048 # inotify checks
1049 if test x$enable_inotify = xno ; then
1050     have_inotify=no;
1051 else
1052     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1053 fi
1054
1055 dnl check if inotify backend is enabled
1056 if test x$have_inotify = xyes; then
1057    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1058    AC_CHECK_FUNCS(inotify_init1)
1059 fi
1060
1061 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1062
1063 # For simplicity, we require the userland API for epoll_create1 at
1064 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1065 # not to have it at runtime.
1066 AC_ARG_ENABLE([epoll],
1067               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1068               [enable_epoll=$enableval], [enable_epoll=auto])
1069 if test x$enable_epoll = xno; then
1070     have_linux_epoll=no
1071 else
1072     AC_MSG_CHECKING([for Linux epoll(4)])
1073     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1074         [
1075         #ifndef __linux__
1076         #error This is not Linux
1077         #endif
1078         #include <sys/epoll.h>
1079         ],
1080         [epoll_create1 (EPOLL_CLOEXEC);])],
1081         [have_linux_epoll=yes],
1082         [have_linux_epoll=no])
1083     AC_MSG_RESULT([$have_linux_epoll])
1084 fi
1085 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1086     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1087 fi
1088 if test x$have_linux_epoll = xyes; then
1089   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1090 fi
1091 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1092
1093 # kqueue checks
1094 if test x$enable_kqueue = xno ; then
1095     have_kqueue=no
1096 else
1097     have_kqueue=yes
1098     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1099     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1100
1101     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1102         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1103     fi
1104 fi
1105
1106 dnl check if kqueue backend is enabled
1107 if test x$have_kqueue = xyes; then
1108    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1109 fi
1110
1111 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1112
1113 # launchd checks
1114 if test x$enable_launchd = xno ; then
1115     have_launchd=no
1116 else
1117     have_launchd=yes
1118     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1119     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1120     if test "x$LAUNCHCTL" = "x"; then
1121         have_launchd=no
1122     fi
1123
1124     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1125         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1126     fi
1127 fi
1128
1129 dnl check if launchd is enabled
1130 if test x$have_launchd = xyes; then
1131     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1132 fi
1133
1134 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1135
1136 #### Directory to place launchd agent file
1137 if test "x$with_launchd_agent_dir" = "x"; then
1138    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1139 else
1140    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1141 fi
1142
1143 AC_SUBST(LAUNCHD_AGENT_DIR)
1144
1145 dnl console owner file
1146 if test x$enable_console_owner_file = xno ; then
1147     have_console_owner_file=no;
1148 else
1149     case $host_os in
1150     solaris*)
1151         have_console_owner_file=yes;
1152         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1153         ;;
1154     *)
1155         have_console_owner_file=no;;
1156     esac
1157 fi
1158
1159 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1160
1161 dnl systemd detection
1162 if test x$enable_systemd = xno ; then
1163     have_systemd=no;
1164 else
1165     PKG_CHECK_MODULES(SYSTEMD,
1166         [libsystemd-login >= 32, libsystemd-daemon >= 32],
1167         have_systemd=yes,
1168         have_systemd=no)
1169 fi
1170
1171 if test x$have_systemd = xyes; then
1172     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1173 fi
1174
1175 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1176     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1177 fi
1178
1179 # libaudit detection
1180 if test x$enable_libaudit = xno ; then
1181     have_libaudit=no;
1182 else
1183     # See if we have audit daemon & capabilities library
1184     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1185                  have_libaudit=yes, have_libaudit=no)
1186     if test x$have_libaudit = xyes ; then
1187         AC_CHECK_LIB(cap-ng, capng_clear,
1188                  have_libaudit=yes, have_libaudit=no)
1189     fi
1190 fi
1191
1192 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1193
1194 if test x$have_libaudit = xyes ; then
1195     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1196     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1197 fi
1198
1199 AC_SUBST([SELINUX_LIBS])
1200
1201 # Check for ADT API (Solaris Basic Security Mode auditing)
1202 AC_MSG_CHECKING(for ADT API)
1203 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1204 #include <bsm/adt.h>
1205 adt_user_context = ADT_USER;
1206 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1207
1208 if test ${check_adt_audit} = yes
1209 then
1210    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1211    ADT_LIBS="-lbsm"
1212    LIBS="-lbsm $LIBS"
1213    AC_MSG_RESULT(yes)
1214 else
1215    AC_MSG_RESULT(no)
1216 fi
1217 AC_SUBST([ADT_LIBS])
1218
1219 # Check for SCM_RIGHTS
1220 AC_MSG_CHECKING([for SCM_RIGHTS])
1221 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1222 #include <sys/types.h>
1223 #include <sys/socket.h>
1224 #include <sys/un.h>
1225 static int x = SCM_RIGHTS;
1226 ]], [[]])],
1227 [ AC_MSG_RESULT([supported])
1228   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1229 [ AC_MSG_RESULT([not supported]) ])
1230
1231 NETWORK_libs=
1232 if test x$dbus_win = xyes ; then
1233   if test x$dbus_wince = xyes ; then
1234     NETWORK_libs="-lws2"
1235   else
1236     NETWORK_libs="-lws2_32 -liphlpapi"
1237   fi
1238 fi
1239
1240 AC_SUBST([NETWORK_libs])
1241
1242 AC_ARG_WITH([valgrind],
1243   [AS_HELP_STRING([--with-valgrind],
1244      [Add instrumentation to help valgrind to understand our allocator])],
1245   [],
1246   [with_valgrind=no])
1247
1248 if test x$with_valgrind != xno; then
1249   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1250   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1251 fi
1252
1253 # Determine maximum number of Unix fds which may be passed
1254 AS_CASE([$host_os],
1255   [*qnx*],
1256     [DEFAULT_MESSAGE_UNIX_FDS=256],
1257   [*],
1258     [DEFAULT_MESSAGE_UNIX_FDS=1024])
1259 AC_DEFINE_UNQUOTED([DBUS_DEFAULT_MESSAGE_UNIX_FDS],
1260   [$DEFAULT_MESSAGE_UNIX_FDS],
1261   [Default for dbus_connection_get_max_message_unix_fds()])
1262 AC_SUBST([DEFAULT_MESSAGE_UNIX_FDS])
1263
1264 #### Set up final flags
1265 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1266 AC_SUBST([LIBDBUS_LIBS])
1267
1268 ### X11 detection
1269 DBUS_X_LIBS=
1270 DBUS_X_CFLAGS=
1271
1272 AC_ARG_ENABLE([x11-autolaunch],
1273   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1274   [], [enable_x11_autolaunch=auto])
1275
1276 if test "x$dbus_win" = xyes; then
1277     if test "x$enable_x11_autolaunch" = xyes; then
1278         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1279     fi
1280
1281     enable_x11_autolaunch=no
1282     have_x11=no
1283 else
1284     AC_PATH_XTRA
1285
1286     if test "x$no_x" = xyes; then
1287         have_x11=no
1288     else
1289         have_x11=yes
1290         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1291         DBUS_X_CFLAGS="$X_CFLAGS"
1292     fi
1293 fi
1294
1295 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1296     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1297 else
1298     # move from "auto" to "yes" or "no" if necessary
1299     if test "x$enable_x11_autolaunch" != xno; then
1300         enable_x11_autolaunch="$have_x11"
1301     fi
1302 fi
1303
1304 if test "x$have_x11" = xyes ; then
1305    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1306 fi
1307
1308 if test "x$enable_x11_autolaunch" = xyes ; then
1309    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1310 fi
1311
1312 AC_SUBST([DBUS_X_CFLAGS])
1313 AC_SUBST([DBUS_X_LIBS])
1314
1315 #### gcc warning flags
1316
1317 cc_supports_flag() {
1318   AC_MSG_CHECKING(whether $CC supports "$*")
1319   save_CFLAGS="$CFLAGS"
1320   CFLAGS="$*"
1321   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1322   CFLAGS="$save_CFLAGS"
1323   AC_MSG_RESULT([$rc])
1324   test "x$rc" = xyes
1325 }
1326
1327 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1328   dnl Use -Werror by default if:
1329   dnl - we're not on Windows (too many warnings), and
1330   dnl - we're in developer mode (a D-Bus developer, not a distro or end-user)
1331   dnl Override with --enable-Werror or --disable-Werror
1332   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$enable_developer = xyes],
1333
1334   dnl Enable these warnings if possible:
1335   [all \
1336    extra \
1337    char-subscripts \
1338    missing-declarations \
1339    missing-prototypes \
1340    nested-externs \
1341    pointer-arith \
1342    cast-align \
1343    no-address \
1344    float-equal \
1345    declaration-after-statement \
1346   ],
1347
1348   dnl Disable these warnings if possible, make them non-fatal if possible,
1349   dnl and don't enable -Werror unless we succeeded.
1350   dnl
1351   dnl Intentional:
1352   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1353   dnl   checking or not asserting
1354   dnl - missing field initializers being 0 is a C feature, not a bug
1355   dnl - unused-parameter is to make writing callbacks less annoying
1356   dnl
1357   dnl To be fixed one day:
1358   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1359   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1360   dnl   is better than nothing
1361   [$DISABLE_UNUSED_WARNINGS \
1362    missing-field-initializers \
1363    unused-parameter \
1364    sign-compare \
1365    pointer-sign \
1366    type-limits \
1367   ])
1368
1369 if test "x$GCC" = "xyes"; then
1370   # We're treating -fno-common like a warning: it makes the linker more
1371   # strict, because on some systems the linker is *always* this strict
1372   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1373
1374   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1375   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1376
1377   if test "x$enable_ansi" = "xyes"; then
1378     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1379       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1380   fi
1381 fi
1382
1383 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1384 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1385 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1386 dnl is the next best thing
1387 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1388
1389 case $host_os in
1390     solaris*)
1391         # Solaris' C library apparently needs these runes to be threadsafe...
1392         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1393         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1394         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1395         # ... and this opt-in to get file descriptor passing support
1396         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1397         ;;
1398 esac
1399
1400 ### Doxygen Documentation
1401
1402 AC_PATH_PROG(DOXYGEN, doxygen, no)
1403
1404 AC_MSG_CHECKING([whether to build Doxygen documentation])
1405
1406 if test x$DOXYGEN = xno ; then
1407     have_doxygen=no
1408 else
1409     have_doxygen=yes
1410 fi
1411
1412 if test x$enable_doxygen_docs = xauto ; then
1413     if test x$have_doxygen = xno ; then
1414         enable_doxygen_docs=no
1415     else
1416         enable_doxygen_docs=yes
1417     fi
1418 fi
1419
1420 if test x$enable_doxygen_docs = xyes; then
1421     if test x$have_doxygen = xno; then
1422         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1423     fi
1424 fi
1425
1426 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1427 AC_MSG_RESULT($enable_doxygen_docs)
1428
1429 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1430 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1431
1432 ### XML Documentation
1433
1434 AC_PATH_PROG(XMLTO, xmlto, no)
1435
1436 AC_MSG_CHECKING([whether to build XML documentation])
1437
1438 if test x$XMLTO = xno ; then
1439     have_xmlto=no
1440 else
1441     have_xmlto=yes
1442 fi
1443
1444 if test x$enable_xml_docs = xauto ; then
1445     if test x$have_xmlto = xno ; then
1446         enable_xml_docs=no
1447     else
1448         enable_xml_docs=yes
1449     fi
1450 fi
1451
1452 if test x$enable_xml_docs = xyes; then
1453     if test x$have_xmlto = xno; then
1454         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1455     fi
1456 fi
1457
1458 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1459 AC_MSG_RESULT($enable_xml_docs)
1460
1461 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1462     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes])
1463
1464 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1465
1466 #### find the actual value for $prefix that we'll end up with
1467 ##   (I know this is broken and should be done in the Makefile, but
1468 ##    that's a major pain and almost nobody actually seems to care)
1469 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1470 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1471 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1472 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1473 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1474 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1475 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1476
1477 #### Check our operating system
1478 operating_system=unknown
1479 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1480    operating_system=redhat
1481 fi
1482
1483 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1484    operating_system=slackware
1485 fi
1486
1487 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1488    operating_system=cygwin
1489 fi
1490
1491 #### Sort out init scripts
1492
1493 if test x$with_init_scripts = x; then
1494     case x$operating_system in
1495         xredhat)        with_init_scripts=redhat ;;
1496         xslackware)     with_init_scripts=slackware ;;
1497         xcygwin)        with_init_scripts=cygwin ;;
1498         *)                      with_init_scripts=none ;;
1499     esac
1500 fi
1501
1502 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1503 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1504 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1505
1506 ##### systemd unit files
1507 AC_ARG_WITH([systemdsystemunitdir],
1508 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1509     [],
1510     [
1511     PKG_CHECK_EXISTS([systemd],
1512       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1513       [with_systemdsystemunitdir=no])
1514     ])
1515 if test "x$with_systemdsystemunitdir" != xno; then
1516    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1517 fi
1518 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1519
1520 ##### Set up location for system bus socket
1521 if ! test -z "$with_system_socket"; then
1522    DBUS_SYSTEM_SOCKET=$with_system_socket
1523 else
1524    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1525 fi
1526
1527 AC_SUBST(DBUS_SYSTEM_SOCKET)
1528 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1529
1530 ## System bus only listens on local domain sockets, and never
1531 ## on an abstract socket (so only root can create the socket).
1532 ##
1533 ## This won't work on Windows. It's not meant to - the system bus is
1534 ## meaningless on Windows anyway.
1535 ##
1536 ## This has to be suitable for hard-coding in client libraries as well as
1537 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1538 ## and also to connect to. If this ever changes, it'll need to be split into
1539 ## two variables, one for the listening address and one for the connecting
1540 ## address.
1541 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1542 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1543 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1544
1545 #### Set up the pid file
1546 if ! test -z "$with_system_pid_file"; then
1547    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1548 elif test x$with_init_scripts = xredhat ; then
1549    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1550 else
1551    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1552 fi
1553
1554 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1555
1556 #### Directory to check for console ownership
1557 if ! test -z "$with_console_auth_dir"; then
1558    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1559 else
1560    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1561 fi
1562
1563 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1564 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1565
1566 #### File to check for console ownership
1567 if test x$have_console_owner_file = xyes; then
1568    if ! test -z "$with_console_owner_file"; then
1569       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1570    else
1571       DBUS_CONSOLE_OWNER_FILE=/dev/console
1572    fi
1573 else
1574   DBUS_CONSOLE_OWNER_FILE=
1575 fi
1576
1577 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1578 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1579
1580 #### User to start the system bus as
1581 if test -z "$with_dbus_user" ; then
1582     DBUS_USER=messagebus
1583 else
1584     DBUS_USER=$with_dbus_user
1585 fi
1586 AC_SUBST(DBUS_USER)
1587 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1588
1589 #### Prefix to install into
1590 DBUS_PREFIX=$EXPANDED_PREFIX
1591 AC_SUBST(DBUS_PREFIX)
1592 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1593
1594 #### Direcotry to install data files into
1595 DBUS_DATADIR=$EXPANDED_DATADIR
1596 AC_SUBST(DBUS_DATADIR)
1597 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1598
1599 #### Directory to install dbus-daemon
1600 if test -z "$with_dbus_daemondir" ; then
1601     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1602 else
1603     DBUS_DAEMONDIR=$with_dbus_daemondir
1604 fi
1605 AC_SUBST(DBUS_DAEMONDIR)
1606 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1607
1608 #### Directory to install the other binaries
1609 DBUS_BINDIR="$EXPANDED_BINDIR"
1610 AC_SUBST(DBUS_BINDIR)
1611 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1612
1613 #### Directory to install the libexec binaries
1614 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1615 AC_SUBST(DBUS_LIBEXECDIR)
1616 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1617
1618 #### Tell tests where to find certain stuff in builddir
1619
1620 DBUS_PWD=`pwd`
1621 # Useful in a cross-compilation environment, where the tests are run on the host system.
1622 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1623                            DBUS_PWD=$withval)
1624
1625 DBUS_TEST_EXEC="$DBUS_PWD/test"
1626 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1627
1628 AC_SUBST([DBUS_TEST_DATA])
1629 AC_SUBST([DBUS_TEST_EXEC])
1630
1631 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1632                    [Full path to the daemon in the builddir])
1633 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1634                    [Extension for executables, typically empty or .exe])
1635
1636 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, ["$DBUS_PWD/bus/dbus-daemon$EXEEXT"],
1637                    [Full path to the daemon in the builddir])
1638 AC_SUBST(TEST_BUS_BINARY)
1639
1640 ## Export the non-setuid external helper
1641 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1642 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1643 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1644                    [Full path to the launch helper test program in the builddir])
1645
1646 #### Find socket directories
1647 if ! test -z "$TMPDIR" ; then
1648    DEFAULT_SOCKET_DIR=$TMPDIR
1649 elif ! test -z "$TEMP" ; then
1650    DEFAULT_SOCKET_DIR=$TEMP
1651 elif ! test -z "$TMP" ; then
1652    DEFAULT_SOCKET_DIR=$TMP
1653 else
1654    DEFAULT_SOCKET_DIR=/tmp
1655 fi
1656
1657 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1658
1659 if ! test -z "$with_test_socket_dir" ; then
1660    TEST_SOCKET_DIR="$with_test_socket_dir"
1661 else
1662    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1663 fi
1664 AC_SUBST(TEST_SOCKET_DIR)
1665 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1666
1667 if test "x$dbus_unix" = xyes; then
1668   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1669 else
1670   TEST_LISTEN="tcp:host=localhost"
1671 fi
1672 AC_SUBST([TEST_LISTEN])
1673 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1674   [Listening address for regression tests])
1675
1676 if ! test -z "$with_session_socket_dir" ; then
1677    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1678 else
1679    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1680 fi
1681 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1682 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1683
1684 # This must be a listening address. It doesn't necessarily need to be an
1685 # address you can connect to - it can be something vague like
1686 # "nonce-tcp:".
1687 #
1688 # The default varies by platform.
1689 AC_ARG_WITH([dbus_session_bus_listen_address],
1690             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1691                            [default address for a session bus to listen on (see configure.ac)]),
1692             [with_dbus_session_bus_listen_address=$withval],
1693             [with_dbus_session_bus_listen_address=])
1694
1695 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1696         # the user specified something, trust them
1697         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1698 elif test x$dbus_win = xyes; then
1699         # On Windows, you can (and should) listen on autolaunch addresses,
1700         # because autolaunching is different.
1701         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1702         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1703 elif test x$have_launchd = xyes; then
1704         # Mac OS X default is to use launchd
1705         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1706 else
1707         # The default on all other Unix platforms (notably Linux)
1708         # is to create a randomly named socket in /tmp or similar
1709         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1710 fi
1711 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1712
1713 # This must be an address you can connect to. It doesn't necessarily
1714 # need to be an address you can listen on - it can be "autolaunch:",
1715 # even on Unix.
1716 #
1717 # The default varies by platform.
1718 AC_ARG_WITH([dbus_session_bus_connect_address],
1719             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1720                            [fallback address for a session bus client to connect to (see configure.ac)]),
1721             [with_dbus_session_bus_connect_address=$withval],
1722             [with_dbus_session_bus_connect_address=])
1723
1724 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1725         # the user specified something, trust them
1726         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1727 elif test x$dbus_win = xyes; then
1728         # Windows autolaunching is a bit different; leaving it in its own
1729         # branch of the conditional because the default might conceivably
1730         # change (see #38201)
1731         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1732 else
1733         # The default on all other Unix platforms (notably Linux)
1734         # is to use auto-launching - this works a bit differently on Mac OS X
1735         # but comes out basically the same in the end
1736         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1737 fi
1738 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1739 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1740   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1741   [Fallback address for session bus clients])
1742
1743 # darwin needs this to initialize the environment
1744 AC_CHECK_HEADERS(crt_externs.h)
1745 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1746 AH_VERBATIM(_DARWIN_ENVIRON,
1747 [
1748 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1749 # include <sys/time.h>
1750 # include <crt_externs.h>
1751 # define environ (*_NSGetEnviron())
1752 #endif
1753 ])
1754
1755 AC_ARG_ENABLE([stats],
1756   [AS_HELP_STRING([--enable-stats],
1757     [enable bus daemon usage statistics])],
1758   [], [enable_stats=no])
1759 if test "x$enable_stats" = xyes; then
1760   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1761     [Define to enable bus daemon usage statistics])
1762 fi
1763
1764 AC_CONFIG_FILES([
1765 Doxyfile
1766 dbus/versioninfo.rc
1767 dbus/dbus-arch-deps.h
1768 bus/system.conf
1769 bus/session.conf
1770 bus/messagebus
1771 bus/messagebus-config
1772 bus/org.freedesktop.dbus-session.plist
1773 bus/rc.messagebus
1774 bus/dbus.service
1775 bus/dbus.socket
1776 Makefile
1777 dbus/Makefile
1778 bus/Makefile
1779 tools/Makefile
1780 test/Makefile
1781 test/name-test/Makefile
1782 doc/Makefile
1783 doc/dbus-cleanup-sockets.1.xml
1784 doc/dbus-daemon.1.xml
1785 doc/dbus-launch.1.xml
1786 doc/dbus-monitor.1.xml
1787 doc/dbus-run-session.1.xml
1788 doc/dbus-send.1.xml
1789 doc/dbus-uuidgen.1.xml
1790 dbus-1.pc
1791 dbus-1-uninstalled.pc
1792 test/data/valid-config-files/debug-allow-all.conf
1793 test/data/valid-config-files/debug-allow-all-sha1.conf
1794 test/data/valid-config-files-system/debug-allow-all-pass.conf
1795 test/data/valid-config-files-system/debug-allow-all-fail.conf
1796 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1797 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1798 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1799 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1800 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1801 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1802 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1803 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1804 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1805 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1806 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1807 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1808 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1809 ])
1810 AC_OUTPUT
1811
1812 dnl ==========================================================================
1813 echo "
1814                     D-Bus $VERSION
1815                   ==============
1816
1817         prefix:                   ${EXPANDED_PREFIX}
1818         exec_prefix:              ${exec_prefix}
1819         libdir:                   ${EXPANDED_LIBDIR}
1820         libexecdir:               ${EXPANDED_LIBEXECDIR}
1821         bindir:                   ${EXPANDED_BINDIR}
1822         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1823         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1824         datadir:                  ${EXPANDED_DATADIR}
1825         source code location:     ${srcdir}
1826         compiler:                 ${CC}
1827         cflags:                   ${CFLAGS}
1828         cppflags:                 ${CPPFLAGS}
1829         cxxflags:                 ${CXXFLAGS}
1830         64-bit int:               ${DBUS_INT64_TYPE}
1831         32-bit int:               ${DBUS_INT32_TYPE}
1832         16-bit int:               ${DBUS_INT16_TYPE}
1833         Doxygen:                  ${DOXYGEN:-not found}
1834         xmlto:                    ${XMLTO:-not found}"
1835
1836 echo "
1837         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1838         gcc coverage profiling:   ${enable_compiler_coverage}
1839         Building embedded tests:  ${enable_embedded_tests}
1840         Building modular tests:   ${enable_modular_tests}
1841             - with GLib:          ${with_glib}
1842         Building verbose mode:    ${enable_verbose_mode}
1843         Building assertions:      ${enable_asserts}
1844         Building checks:          ${enable_checks}
1845         Building bus stats API:   ${enable_stats}
1846         Building SELinux support: ${have_selinux}
1847         Building inotify support: ${have_inotify}
1848         Building kqueue support:  ${have_kqueue}
1849         Building systemd support: ${have_systemd}
1850         Building X11 code:        ${have_x11}
1851         Building Doxygen docs:    ${enable_doxygen_docs}
1852         Building XML docs:        ${enable_xml_docs}
1853         Building cache support:   ${enable_userdb_cache}
1854         Building launchd support: ${have_launchd}
1855         Init scripts style:       ${with_init_scripts}
1856         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1857         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1858         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1859         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1860         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1861         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1862         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1863         Console owner file:       ${have_console_owner_file}
1864         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1865         System bus user:          ${DBUS_USER}
1866         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1867         'make check' socket dir:  ${TEST_SOCKET_DIR}
1868 "
1869 if test x$have_launchd = xyes; then
1870         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1871 fi
1872 echo
1873
1874 if test x$enable_embedded_tests = xyes; then
1875         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1876 fi
1877 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1878         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1879 fi
1880 if test x$enable_compiler_coverage = xyes; then
1881         echo "NOTE: building with coverage profiling is definitely for developers only."
1882 fi
1883 if test x$enable_verbose_mode = xyes; then
1884         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1885 fi
1886 if test x$enable_asserts = xyes; then
1887         echo "NOTE: building with assertions increases library size and decreases performance."
1888 fi
1889 if test x$enable_checks = xno; then
1890         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1891 fi
1892
1893 if test "x$DBUS_HAVE_INT64" = x0; then
1894   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1895
1896   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1897   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1898   used if your compiler lacks support for 64-bit integers. Please report a bug
1899   with details of your platform and compiler.
1900
1901   This option is likely to be removed in future, unless the D-Bus developers
1902   receive reports that it is still needed.
1903   ])
1904 fi