configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.14.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 10, 0, 10)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.13.1
  58
  59 dnl *** autotools stuff ****
  60
  61 dnl allow for different autotools
  62 AS_AUTOTOOLS_ALTERNATE
  63
  64 dnl Add parameters for aclocal
  65 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  66
  67 dnl set up gettext
  68 dnl the version check needs to stay here because autopoint greps for it
  69 AM_GNU_GETTEXT_VERSION([0.11.5])
  70 AM_GNU_GETTEXT([external])
  71 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  72
  73 dnl *** check for arguments to configure ***
  74
  75 AG_GST_ARG_DEBUG
  76 AG_GST_ARG_PROFILING
  77 AG_GST_ARG_VALGRIND
  78 AG_GST_ARG_GCOV
  79
  80 AG_GST_ARG_EXAMPLES
  81
  82 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  83 AG_GST_ARG_WITH_PACKAGE_NAME
  84 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  85
  86 dnl let distro override plugin install helper path
  87 AC_ARG_WITH(install-plugins-helper,
  88   AC_HELP_STRING([--with-install-plugins-helper],
  89     [specify path of helper script to call to install plugins]),
  90   [
  91     case "${withval}" in
  92       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  93       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  95     esac
  96   ],
  97   [
  98     dnl Default value
  99     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 100   ]
 101 )
 102 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 103 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 104     [plugin install helper script])
 105 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 106
 107
 108 dnl these are all the gst plug-ins, compilable without additional libs
 109 GST_PLUGINS_ALL="\
 110         adder \
 111         audioconvert \
 112         audiorate \
 113         audioresample \
 114         audiotestsrc \
 115         ffmpegcolorspace \
 116         gdp \
 117         playback \
 118         typefind \
 119         videotestsrc \
 120         videorate \
 121         videoscale \
 122         volume \
 123         "
 124 AC_SUBST(GST_PLUGINS_ALL)
 125
 126 GST_PLUGINS_SELECTED=""
 127
 128 AC_ARG_WITH(plugins,
 129     AC_HELP_STRING([--with-plugins],
 130       [comma-separated list of plug-ins to compile]),
 131     [for i in `echo $withval | tr , ' '`; do
 132         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 133         then
 134             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 135         else
 136             echo "plug-in $i not recognized, ignoring..."
 137         fi
 138     done],
 139     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 140
 141 AC_SUBST(GST_PLUGINS_SELECTED)
 142
 143 dnl ext plug-ins; plug-ins that have external dependencies
 144 AG_GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 145   [HAVE_EXTERNAL=yes], enabled,
 146   [
 147     AC_MSG_NOTICE(building external plug-ins)
 148     BUILD_EXTERNAL="yes"
 149   ],[
 150     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 151     BUILD_EXTERNAL="no"
 152   ])
 153 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 154
 155 dnl *** checks for platform ***
 156
 157 dnl * hardware/architecture *
 158
 159 dnl common/m4/gst-arch.m4
 160 dnl check CPU type
 161 AG_GST_ARCH
 162
 163 dnl check for large file support
 164 dnl affected plugins must include config.h
 165 AC_SYS_LARGEFILE
 166
 167 dnl *** checks for programs ***
 168
 169 dnl find a compiler
 170 AC_PROG_CC
 171
 172 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 173 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 174
 175 dnl check for documentation tools
 176 GTK_DOC_CHECK([1.3])
 177 AS_PATH_PYTHON([2.1])
 178 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 179
 180 dnl *** checks for libraries ***
 181
 182 dnl For interactive UNIX (a Sun thing)
 183 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 184 AC_ISC_POSIX
 185
 186 dnl libm, for sin() etc.
 187 AC_CHECK_LIBM
 188 AC_SUBST(LIBM)
 189
 190 dnl *** checks for header files ***
 191
 192 dnl check if we have ANSI C header files
 193 AC_HEADER_STDC
 194
 195 dnl used in gst/ffmpegcolorspace/mem.c
 196 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 197 AC_CHECK_HEADERS([malloc.h])
 198
 199 dnl used in gst/subparse/gstsubparse.c
 200 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 201 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 202
 203 dnl used in gst/tcp
 204 AC_CHECK_HEADERS([sys/socket.h],
 205   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 206 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 207
 208 dnl used in gst-libs/gst/rtsp
 209 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 210 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 211   WIN32_LIBS="-lws2_32"
 212   AC_SUBST(WIN32_LIBS)
 213 fi
 214
 215 dnl used in gst-libs/gst/pbutils and associated unit test
 216 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 217
 218 dnl ffmpegcolorspace includes _stdint.h
 219 dnl also, Windows does not have long long
 220 AX_CREATE_STDINT_H
 221
 222 dnl *** checks for functions ***
 223 AC_CHECK_FUNCS([localtime_r])
 224
 225 dnl *** checks for types/defines ***
 226
 227 dnl Check for FIONREAD ioctl declaration
 228 dnl used in gst/tcp
 229 GST_CHECK_FIONREAD
 230
 231 dnl *** checks for structures ***
 232
 233 dnl *** checks for compiler characteristics ***
 234
 235 dnl make sure we can use "inline" from C code
 236 AC_C_INLINE
 237
 238 dnl *** checks for library functions ***
 239
 240 dnl check for fseeko()
 241 AC_FUNC_FSEEKO
 242
 243 dnl Check for fast float to int casting as defined in C99
 244 dnl used in gst-libs/gst/floatcast/floatcast.h
 245 AC_C99_FUNC_LRINT
 246 AC_C99_FUNC_LRINTF
 247
 248 dnl Check for a way to display the function name in debug output
 249 AG_GST_CHECK_FUNCTION
 250
 251 dnl *** checks for dependency libraries ***
 252
 253 dnl GLib is required
 254 AG_GST_GLIB_CHECK([2.6])
 255
 256 dnl liboil is required
 257 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 258 if test "x$HAVE_LIBOIL" != "xyes"
 259 then
 260   AC_ERROR([liboil-0.3.8 or later is required])
 261 fi
 262
 263 dnl checks for gstreamer
 264 dnl uninstalled is selected preferentially -- see pkg-config(1)
 265 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 266 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 267 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 268 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 269 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 270 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 271
 272 dnl Check for documentation xrefs
 273 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 274 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 275 AC_SUBST(GLIB_PREFIX)
 276 AC_SUBST(GST_PREFIX)
 277
 278 dnl GTK is optional and used in examples
 279 HAVE_GTK=NO
 280 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 281 if test "x$HAVE_GTK_22" = "xyes"; then
 282   HAVE_GTK=yes
 283   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 284   AC_SUBST(GTK_VERSION)
 285   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 286   AC_SUBST(GTK_BASE_DIR)
 287 else
 288   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 289 fi
 290 if test "x$HAVE_GTK_20" = "xyes"; then
 291   HAVE_GTK=yes
 292 fi
 293 GTK_CFLAGS=$GTK2_CFLAGS
 294 GTK_LIBS=$GTK2_LIBS
 295 AC_SUBST(GTK_LIBS)
 296 AC_SUBST(GTK_CFLAGS)
 297 AC_SUBST(HAVE_GTK)
 298 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 299
 300 dnl *** set variables based on configure arguments ***
 301
 302 dnl set license and copyright notice
 303 GST_LICENSE="LGPL"
 304 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 305 AC_SUBST(GST_LICENSE)
 306
 307 dnl set location of plugin directory
 308 AG_GST_SET_PLUGINDIR
 309
 310 dnl define an ERROR_CFLAGS Makefile variable
 311 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 312
 313 dnl define correct level for debugging messages
 314 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 315
 316 dnl used in examples
 317 AG_GST_DEFAULT_ELEMENTS
 318
 319 dnl *** sys plug-ins ***
 320
 321 echo
 322 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 323 echo
 324
 325 dnl *** X11 ***
 326 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 327 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 328                   [ximagesink], [
 329   AC_PATH_XTRA
 330   ac_cflags_save="$CFLAGS"
 331   ac_cppflags_save="$CPPFLAGS"
 332   CFLAGS="$CFLAGS $X_CFLAGS"
 333   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 334
 335   dnl now try to find the HEADER
 336   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 337
 338   if test "x$HAVE_X" = "xno"
 339   then
 340     AC_MSG_NOTICE([cannot find X11 development files])
 341   else
 342     dnl this is much more than we want
 343     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 344     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 345     dnl it does not add the libs; therefore we add them here
 346     X_LIBS="$X_LIBS -lX11"
 347     AC_SUBST(X_CFLAGS)
 348     AC_SUBST(X_LIBS)
 349   fi
 350   AC_SUBST(HAVE_X)
 351   CFLAGS="$ac_cflags_save"
 352   CPPFLAGS="$ac_cppflags_save"
 353 ])
 354
 355 dnl Check for Xv extension
 356 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 357 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 358                   [xvimagesink], [
 359   AG_GST_CHECK_XV
 360 ])
 361
 362 dnl check for X Shm
 363 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 364 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 365   if test x$HAVE_X = xyes; then
 366     AC_CHECK_LIB(Xext, XShmAttach,
 367                  HAVE_XSHM="yes", HAVE_XSHM="no",
 368                  $X_LIBS)
 369     if test "x$HAVE_XSHM" = "xyes"; then
 370       XSHM_LIBS="-lXext"
 371     else
 372       dnl On AIX, it is in XextSam instead, but we still need -lXext
 373       AC_CHECK_LIB(XextSam, XShmAttach,
 374                    HAVE_XSHM="yes", HAVE_XSHM="no",
 375                    $X_LIBS)
 376       if test "x$HAVE_XSHM" = "xyes"; then
 377         XSHM_LIBS="-lXext -lXextSam"
 378       fi
 379     fi
 380   fi
 381 ], , [
 382   AC_SUBST(HAVE_XSHM)
 383   AC_SUBST(XSHM_LIBS)
 384 ])
 385
 386 dnl v4l/v4l2 checks have been moved down because they require X
 387
 388 dnl *** Video 4 Linux ***
 389 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 390 dnl renamed to GST_V4L in accordance with V4L2 below
 391 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 392 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 393   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 394 #include <sys/types.h>
 395 #define _LINUX_TIME_H
 396 #define __user
 397 #include <linux/videodev.h>
 398   ])
 399
 400   dnl we can build v4l without Xv, but then we won't have XOverlay support
 401   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 402   then
 403     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 404     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 405   fi
 406 ])
 407
 408 dnl *** ext plug-ins ***
 409 dnl keep this list sorted alphabetically !
 410
 411 if test "x$BUILD_EXTERNAL" = "xyes"; then
 412
 413 echo
 414 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 415 echo
 416
 417 dnl *** alsa ***
 418 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 419 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 420   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 421     HAVE_ALSA="yes"
 422     AC_SUBST(ALSA_CFLAGS)
 423     AC_SUBST(ALSA_LIBS)
 424   ], [
 425     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 426   ])
 427 ])
 428
 429 dnl *** CDParanoia ***
 430 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 431 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 432   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 433                       cdda_open, -lm,
 434                       cdda_interface.h,
 435                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 436                       HEADER_DIR="no"
 437                       FOUND_CDPARANOIA="yes")
 438   if test "x$FOUND_CDPARANOIA" != "xyes";
 439   then
 440     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 441                         cdda_open, -lm,
 442                         cdda/cdda_interface.h,
 443                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 444                         HEADER_DIR="yes"
 445                         FOUND_CDPARANOIA="yes")
 446   fi
 447   if test "x$HEADER_DIR" = "xyes";
 448   then
 449     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 450                        defined if cdda headers are in a cdda/ directory)
 451   fi
 452   AC_SUBST(CDPARANOIA_LIBS)
 453 ])
 454 dnl FIXME : add second check somehow if that is necessary
 455 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 456 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 457
 458 dnl *** GNOME VFS ***
 459 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 460 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 461   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 462 ])
 463
 464 dnl *** libvisual ***
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 466 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 467   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 468   if test $HAVE_LIBVISUAL = no
 469   then
 470     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 471   fi
 472 ])
 473
 474 dnl *** ogg ***
 475 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 476 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 477   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 478   if test $HAVE_OGG = no
 479   then
 480     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 481     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 482   fi
 483 ])
 484
 485 dnl *** pango ***
 486 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 487 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 488   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 489 ])
 490
 491 dnl *** theora ***
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 493 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 494   dnl this check will work as long as theora uses 1.0.x or similar for the
 495   dnl first post-alpha release and not just 1.0
 496   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 497 ])
 498
 499 dnl *** vorbis ***
 500 dnl AM_PATH_VORBIS only takes two options
 501 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 502 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 503   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 504   if test $HAVE_VORBIS = no
 505   then
 506     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 507     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 508   fi
 509 ])
 510
 511 if test "x$HAVE_VORBIS" = "xyes"; then
 512   ac_cflags_save="$CFLAGS"
 513   dnl FIXME: does this work on non-gcc? -- Company
 514   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 515   CFLAGS="-Wall -Werror"
 516   AC_COMPILE_IFELSE(
 517     AC_LANG_PROGRAM([
 518 #include <vorbis/codec.h>
 519                      ],[
 520 vorbis_dsp_state *v;
 521
 522 vorbis_synthesis_restart (v);
 523                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 524   if test "x$HAVE_VSR" = "xyes"; then
 525     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 526                        [defined if vorbis_synthesis_restart is present])
 527   fi
 528   CFLAGS="$ac_cflags_save"
 529 fi
 530
 531 else
 532
 533 dnl not building plugins with external dependencies,
 534 dnl but we still need to set the conditionals
 535 AM_CONDITIONAL(USE_ALSA, false)
 536 AM_CONDITIONAL(USE_CDPARANOIA, false)
 537 AM_CONDITIONAL(USE_GNOME_VFS, false)
 538 AM_CONDITIONAL(USE_LIBVISUAL, false)
 539 AM_CONDITIONAL(USE_OGG, false)
 540 AM_CONDITIONAL(USE_PANGO, false)
 541 AM_CONDITIONAL(USE_THEORA, false)
 542 AM_CONDITIONAL(USE_VORBIS, false)
 543
 544 fi dnl of EXT plugins
 545
 546 dnl seeking needs freetype, so check for it here
 547 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 548   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 549 ])
 550 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 551 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 552 AC_SUBST(FT2_CFLAGS)
 553 AC_SUBST(FT2_LIBS)
 554
 555 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 556
 557 dnl Overview:
 558 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 559 dnl GST_*:              flags shared by built objects to link against GStreamer
 560 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 561 dnl                          (compare to other modules) or for i18n
 562 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 563 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 564 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 565 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 566
 567 dnl GST_OPTION_CFLAGS
 568 if test "x$USE_DEBUG" = xyes; then
 569    PROFILE_CFLAGS="-g"
 570 fi
 571 AC_SUBST(PROFILE_CFLAGS)
 572
 573 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 574 AC_SUBST(DEPRECATED_CFLAGS)
 575
 576 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 577 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 578 AC_SUBST(GST_OPTION_CFLAGS)
 579
 580 dnl our libraries need to be versioned correctly
 581 AC_SUBST(GST_LT_LDFLAGS)
 582
 583 dnl GST_PLUGINS_BASE_CFLAGS
 584 dnl prefer internal headers to already installed ones
 585 dnl also add builddir include for enumtypes and marshal
 586 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 587 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 588
 589 dnl FIXME: do we want to rename to GST_ALL_* ?
 590 dnl add GST_OPTION_CFLAGS, but overridable
 591 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 592 AC_SUBST(GST_CFLAGS)
 593 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 594 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 595 AC_SUBST(GST_LIBS)
 596
 597 dnl LDFLAGS really should only contain flags, not libs - they get added before
 598 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 599 GST_ALL_LDFLAGS="-no-undefined"
 600 AC_SUBST(GST_ALL_LDFLAGS)
 601
 602 dnl GST_LIB_LDFLAGS
 603 dnl linker flags shared by all libraries
 604 dnl LDFLAGS modifier defining exported symbols from built libraries
 605 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 606 AC_SUBST(GST_LIB_LDFLAGS)
 607
 608 dnl this really should only contain flags, not libs - they get added before
 609 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 610 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 611 AC_SUBST(GST_PLUGIN_LDFLAGS)
 612
 613 dnl *** output files ***
 614
 615 AC_CONFIG_FILES(
 616 Makefile
 617 gst-plugins-base.spec
 618 gst/Makefile
 619 gst/adder/Makefile
 620 gst/audioconvert/Makefile
 621 gst/audiorate/Makefile
 622 gst/audioresample/Makefile
 623 gst/audiotestsrc/Makefile
 624 gst/ffmpegcolorspace/Makefile
 625 gst/gdp/Makefile
 626 gst/playback/Makefile
 627 gst/subparse/Makefile
 628 gst/tcp/Makefile
 629 gst/typefind/Makefile
 630 gst/videotestsrc/Makefile
 631 gst/videorate/Makefile
 632 gst/videoscale/Makefile
 633 gst/volume/Makefile
 634 sys/Makefile
 635 sys/ximage/Makefile
 636 sys/xvimage/Makefile
 637 sys/v4l/Makefile
 638 ext/Makefile
 639 ext/alsa/Makefile
 640 ext/cdparanoia/Makefile
 641 ext/gnomevfs/Makefile
 642 ext/libvisual/Makefile
 643 ext/ogg/Makefile
 644 ext/pango/Makefile
 645 ext/theora/Makefile
 646 ext/vorbis/Makefile
 647 gst-libs/Makefile
 648 gst-libs/gst/Makefile
 649 gst-libs/gst/audio/Makefile
 650 gst-libs/gst/cdda/Makefile
 651 gst-libs/gst/fft/Makefile
 652 gst-libs/gst/floatcast/Makefile
 653 gst-libs/gst/interfaces/Makefile
 654 gst-libs/gst/netbuffer/Makefile
 655 gst-libs/gst/riff/Makefile
 656 gst-libs/gst/rtp/Makefile
 657 gst-libs/gst/rtsp/Makefile
 658 gst-libs/gst/sdp/Makefile
 659 gst-libs/gst/tag/Makefile
 660 gst-libs/gst/pbutils/Makefile
 661 gst-libs/gst/video/Makefile
 662 tools/Makefile
 663 win32/common/config.h
 664 pkgconfig/Makefile
 665 pkgconfig/gstreamer-plugins-base.pc
 666 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 667 tests/Makefile
 668 tests/check/Makefile
 669 tests/examples/Makefile
 670 tests/examples/seek/Makefile
 671 tests/examples/volume/Makefile
 672 tests/icles/Makefile
 673 docs/Makefile
 674 docs/design/Makefile
 675 docs/libs/Makefile
 676 docs/plugins/Makefile
 677 docs/version.entities
 678 po/Makefile.in
 679 common/Makefile
 680 common/m4/Makefile
 681 m4/Makefile
 682 )
 683 AC_OUTPUT
 684
 685 AG_GST_OUTPUT_PLUGINS