configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [7])
   5 m4_define([v_mic], [99])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39 AC_SYS_LARGEFILE
  40
  41 #lt_cv_deplibs_check_method='pass_all'
  42 AC_LIBTOOL_WIN32_DLL
  43 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  44 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  45 AC_PROG_LIBTOOL
  46
  47 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  48 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  49 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  50 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  51 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  52 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  53 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  54 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  55 version_info="lt_cur:lt_rev:lt_age"
  56 release_info="v_rel"
  57 AC_SUBST(version_info)
  58 AC_SUBST(release_info)
  59 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  60 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  61 VMAJ=v_maj
  62 AC_SUBST(VMAJ)
  63
  64
  65 ### Needed information
  66
  67 AC_CANONICAL_BUILD
  68 AC_CANONICAL_HOST
  69
  70 requirements_pc_eina=""
  71
  72 have_wince="no"
  73 have_win32="no"
  74 case "$host_os" in
  75    mingw32ce*)
  76       have_win32="yes"
  77       have_wince="yes"
  78       MODULE_ARCH="$host_os-$host_cpu"
  79       MODULE_EXT=".dll"
  80       ;;
  81    mingw*)
  82       have_win32="yes"
  83       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  84       MODULE_EXT=".dll"
  85       ;;
  86    *)
  87       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  88       MODULE_EXT=".so"
  89       ;;
  90 esac
  91 AM_CONDITIONAL([EINA_HAVE_WINCE], [test "x$have_wince" = "xyes"])
  92 AM_CONDITIONAL([EINA_HAVE_WIN32], [test "x$have_win32" = "xyes"])
  93 AC_SUBST([MODULE_ARCH])
  94 AC_DEFINE_UNQUOTED([MODULE_ARCH], ["${MODULE_ARCH}"], ["Module architecture"])
  95 AC_DEFINE_UNQUOTED([SHARED_LIB_SUFFIX], ["${MODULE_EXT}"], [Suffix for shared objects])
  96
  97 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  98 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  99 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
 100 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
 101
 102 EFL_CHECK_THREADS
 103
 104 if ! test "x${efl_have_threads}" = "xno" ; then
 105    EINA_CONFIGURE_HAVE_THREADS="#define EINA_HAVE_THREADS"
 106 fi
 107 if ! test "x${efl_have_pthread_barrier}" = "xno" ; then
 108    EINA_CONFIGURE_HAVE_PTHREAD_BARRIER="#define EINA_HAVE_PTHREAD_BARRIER"
 109 fi
 110 AC_SUBST(EINA_CONFIGURE_HAVE_THREADS)
 111 AC_SUBST(EINA_CONFIGURE_HAVE_PTHREAD_BARRIER)
 112 AM_CONDITIONAL([EINA_HAVE_THREADS], [! test "x${efl_have_threads}" = "xno"])
 113
 114 if test "x${efl_have_debug_threads}" = "xyes"; then
 115    EINA_CONFIGURE_HAVE_DEBUG_THREADS="#define EINA_HAVE_DEBUG_THREADS"
 116 fi
 117 AC_SUBST(EINA_CONFIGURE_HAVE_DEBUG_THREADS)
 118 AM_CONDITIONAL([EINA_DEBUG_THREADS], [test "x${efl_have_debug_threads}" = "xyes"])
 119
 120 if ! test "x${efl_have_on_off_threads}" = "xno"; then
 121    EINA_CONFIGURE_HAVE_ON_OFF_THREADS="#define EINA_HAVE_ON_OFF_THREADS"
 122 fi
 123 AC_SUBST(EINA_CONFIGURE_HAVE_ON_OFF_THREADS)
 124 AM_CONDITIONAL([EINA_ON_OFF_THREADS], [! test "x${efl_have_on_off_threads}" = "xno"])
 125
 126 if ! test "x${efl_have_setaffinity}" = "xno" ; then
 127    EINA_CONFIGURE_HAVE_PTHREAD_SETAFFINITY="#define EINA_HAVE_PTHREAD_AFFINITY"
 128 fi
 129 AC_SUBST(EINA_CONFIGURE_HAVE_PTHREAD_SETAFFINITY)
 130
 131 ### Additional options to configure
 132
 133 # Magic debug
 134 AC_ARG_ENABLE([magic-debug],
 135    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 136    [
 137     if test "x${enableval}" = "xyes" ; then
 138        have_magic_debug="yes"
 139     else
 140        have_magic_debug="no"
 141     fi
 142    ],
 143    [have_magic_debug="yes"])
 144
 145 AC_MSG_CHECKING([whether magic debug is enable])
 146 AC_MSG_RESULT([${have_magic_debug}])
 147
 148 if test "x${have_magic_debug}" = "xyes" ; then
 149    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 150 fi
 151 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 152
 153 # Safety checks (avoid crashes on wrong api usage)
 154 AC_ARG_ENABLE(safety-checks,
 155    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 156    [
 157     if test "x${enableval}" = "xyes" ; then
 158        have_safety_checks="yes"
 159     else
 160        have_safety_checks="no"
 161     fi
 162    ],
 163    [have_safety_checks="yes"])
 164
 165 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 166 AC_MSG_RESULT($have_safety_checks)
 167
 168 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 169 if test "x$have_safety_checks" = "xyes"; then
 170   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 171   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 172 fi
 173 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 174
 175 with_max_log_level="<unset>"
 176 AC_ARG_WITH(internal-maximum-log-level,
 177    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 178                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 179    [
 180     if test "x${withval}" != "xno"; then
 181        if echo "${withval}" | grep -E '^[[0-9]]+$' >/dev/null 2>/dev/null; then
 182           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 183           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 184           with_max_log_level="${withval}"
 185        else
 186           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 187        fi
 188     fi
 189     ], [:])
 190
 191 AC_ARG_ENABLE([amalgamation],
 192    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 193    [if test "x${enableval}" = "xyes"; then
 194        do_amalgamation="yes"
 195     else
 196        do_amalgamation="no"
 197     fi
 198    ],
 199    [do_amalgamation="no"]
 200 )
 201 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 202
 203 # Choose best memory pool
 204 AC_ARG_ENABLE([default-mempool],
 205    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 206    [
 207     if test "x${enableval}" = "xyes"; then
 208        have_default_mempool="yes"
 209     else
 210        have_default_mempool="no"
 211     fi
 212    ],
 213    [have_default_mempool="no"]
 214 )
 215 AC_MSG_CHECKING([whether to use default mempool allocator])
 216 AC_MSG_RESULT([${have_default_mempool}])
 217
 218 if test "x${have_default_mempool}" = "xyes" ; then
 219    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 220 fi
 221 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 222
 223 # Report stringshare usage
 224 AC_ARG_ENABLE([stringshare-usage],
 225    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 226    [
 227     if test "x${enableval}" = "xyes"; then
 228        have_stringshare_usage="yes"
 229     else
 230        have_stringshare_usage="no"
 231     fi
 232    ],
 233    [have_stringshare_usage="no"]
 234 )
 235 AC_MSG_CHECKING([whether to report stringshare usage])
 236 AC_MSG_RESULT([${have_stringshare_usage}])
 237
 238 if test "x${have_stringshare_usage}" = "xyes"; then
 239    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 240 fi
 241
 242 # Assert or fail.
 243
 244 AC_ARG_ENABLE([assert],
 245    [AC_HELP_STRING([--enable-assert], [enable assert, @<:@default=no@:>@])],
 246    [
 247     if test "x${enableval}" = "xyes" ; then
 248        prefer_assert="yes"
 249     else
 250        prefer_assert="no"
 251     fi
 252    ],
 253    [prefer_assert="no"])
 254
 255 # Check if we want to benchmark on real data
 256 enable_benchmark_e17="no"
 257 AC_ARG_ENABLE([e17],
 258    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 259    [
 260     if test "x${enableval}" = "xyes" ; then
 261        enable_benchmark_e17="yes"
 262     else
 263        enable_benchmark_e17="no"
 264     fi
 265    ],
 266    [enable_benchmark_e17="no"])
 267
 268 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 269 AC_MSG_RESULT([${enable_benchmark_e17}])
 270
 271 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 272
 273
 274 ### Checks for programs
 275 AC_PROG_CC
 276 #for src/tests...
 277 AC_PROG_CXX
 278
 279 # pkg-config
 280 PKG_PROG_PKG_CONFIG
 281
 282 # Check whether pkg-config supports Requires.private
 283 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 284    pkgconfig_requires_private="Requires.private"
 285 else
 286    pkgconfig_requires_private="Requires"
 287 fi
 288 AC_SUBST(pkgconfig_requires_private)
 289
 290 # doxygen program for documentation building
 291
 292 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 293
 294
 295 ### Checks for libraries
 296
 297 ## Compatibility layers
 298
 299 # Evil library for compilation on Windows
 300
 301 EFL_EINA_BUILD=""
 302 case "$host_os" in
 303    mingw*)
 304       PKG_CHECK_EXISTS([evil >= 1.6.99])
 305       AC_DEFINE([HAVE_EVIL], [1], [Set to 1 if Evil package is installed])
 306       requirements_pc_eina="${requirements_pc_eina} evil"
 307       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 308    ;;
 309 esac
 310 AC_SUBST([EFL_EINA_BUILD])
 311
 312 # Escape library for compilation on Playstation 3
 313
 314 case "$host_vendor" in
 315   ps3*)
 316       PKG_CHECK_EXISTS([escape])
 317       AC_DEFINE([HAVE_ESCAPE], [1], [Set to 1 if Escape package is installed])
 318       requirements_pc_eina="${requirements_pc_eina} escape"
 319     ;;
 320 esac
 321
 322 # Exotic library for copilation on Coyote
 323
 324 PKG_CHECK_EXISTS([exotic],
 325    [
 326     enable_exotic="yes"
 327     AC_DEFINE([HAVE_EXOTIC_H], [1], [Define to 1 if you have Exotic.])
 328     EINA_CONFIGURE_HAVE_EXOTIC="#define EINA_HAVE_EXOTIC"
 329     requirements_pc_eina="exotic ${requirements_pc_eina}"
 330    ],
 331    [enable_exotic="no"])
 332
 333 AM_CONDITIONAL([EINA_HAVE_EXOTIC], [test "x${enable_exotic}" = "xyes"])
 334 AC_SUBST([EINA_CONFIGURE_HAVE_EXOTIC])
 335
 336 if ! test "x${requirements_pc_eina}" = "x" ; then
 337    PKG_CHECK_MODULES([EINA], [${requirements_pc_eina}])
 338 fi
 339
 340 ## Options
 341
 342 # Valgrind
 343
 344 AC_ARG_ENABLE([valgrind],
 345    [AC_HELP_STRING([--enable-valgrind], [improve valgrind support by hinting it of our memory usages, having it to report proper mempool leaks.])],
 346    [
 347     if test "x${enableval}" = "xyes" ; then
 348        want_valgrind="yes"
 349     else
 350        want_valgrind="no"
 351     fi
 352    ],
 353    [want_valgrind="auto"])
 354
 355 AC_MSG_CHECKING([whether to enable build with valgrind])
 356 AC_MSG_RESULT([${want_valgrind}])
 357
 358 if test "x${want_valgrind}" = "xyes" || test "x${want_valgrind}" = "xauto"; then
 359    PKG_CHECK_MODULES([VALGRIND], [valgrind >= 2.4.0],
 360       [
 361        have_valgrind="yes"
 362        requirements_pc_eina="valgrind ${requirements_pc_eina}"
 363       ],
 364       [
 365        have_valgrind="no"
 366        AC_DEFINE([NVALGRIND], [1], [Valgrind support disabled])
 367        if test "x${want_valgrind}" = "xyes"; then
 368           AC_MSG_ERROR([Valgrind >= 2.4.0 is required])
 369        fi
 370       ])
 371 else
 372     AC_DEFINE([NVALGRIND], [1], [Valgrind support disabled])
 373 fi
 374
 375 ## Modules
 376
 377 # Check ememoa memory pool library
 378
 379 AC_ARG_ENABLE([ememoa],
 380    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 381    [
 382     if test "x${enableval}" = "xyes" ; then
 383        enable_ememoa="yes"
 384     else
 385        enable_ememoa="no"
 386     fi
 387    ],
 388    [enable_ememoa="yes"])
 389
 390 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 391 AC_MSG_RESULT([${enable_ememoa}])
 392
 393 if test "x${enable_ememoa}" = "xyes" ; then
 394    PKG_CHECK_MODULES([EMEMOA],
 395       [ememoa >= 0.0.26 ],
 396       [enable_ememoa="yes"],
 397       [enable_ememoa="no"])
 398 fi
 399
 400 ## Examples
 401
 402 PKG_CHECK_MODULES([ECORE_EVAS],
 403    [ecore-evas ecore evas],
 404    [build_tiler_example="yes"],
 405    [build_tiler_example="no"])
 406
 407 AM_CONDITIONAL([BUILD_TILER_EXAMPLE], [test "x${build_tiler_example}" = "xyes"])
 408
 409 ### Checks for header files
 410 AC_HEADER_ASSERT
 411 AC_HEADER_TIME
 412 AC_HEADER_DIRENT
 413
 414 AC_CHECK_HEADERS([unistd.h libgen.h inttypes.h stdint.h sys/types.h siginfo.h strings.h execinfo.h mcheck.h])
 415
 416 # sys/mman.h could be provided by evil/escape/exotic so we need to set CFLAGS accordingly
 417 CFLAGS_save="${CFLAGS}"
 418 CFLAGS="${CFLAGS} ${EINA_CFLAGS}"
 419 AC_CHECK_HEADERS([sys/mman.h])
 420 CFLAGS="${CFLAGS_save}"
 421
 422 if test "x${ac_cv_header_inttypes_h}" = "xyes" ; then
 423    EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"
 424    AC_DEFINE([HAVE_INTTYPES_H], [1], [Define to 1 if you have the <inttypes.h> header file.])
 425 fi
 426 AC_SUBST([EINA_CONFIGURE_HAVE_INTTYPES_H])
 427
 428 if test "x${ac_cv_header_inttypes_h}" = "xyes" ; then
 429     EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"
 430     AC_DEFINE([HAVE_STDINT_H], [1], [Define to 1 if you have the <stdint.h> header file.])
 431 fi
 432 AC_SUBST([EINA_CONFIGURE_HAVE_STDINT_H])
 433
 434 ### Checks for types
 435
 436 # wchar_t
 437
 438 AC_CHECK_SIZEOF([wchar_t])
 439 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 440 AC_SUBST([EINA_SIZEOF_WCHAR_T])
 441 AC_CHECK_TYPES([siginfo_t], [], [],
 442    [[
 443 #include <signal.h>
 444 #if HAVE_SIGINFO_H
 445 # include <siginfo.h>
 446 #endif
 447    ]])
 448
 449 # struct dirent
 450
 451 AC_CHECK_TYPES([struct dirent], [have_dirent="yes"], [have_dirent="no"],
 452    [[
 453 #include <dirent.h>
 454    ]])
 455
 456 if test "x${have_dirent}" = "xyes" ; then
 457     EINA_CONFIGURE_HAVE_DIRENT_H="#define EINA_HAVE_DIRENT_H"
 458     AC_DEFINE([HAVE_DIRENT_H], [1], [Define to 1 if you have a valid <dirent.h> header file.])
 459 fi
 460 AC_SUBST([EINA_CONFIGURE_HAVE_DIRENT_H])
 461
 462 ### Checks for structures
 463
 464 ### Checks for compiler characteristics
 465 AC_C_BIGENDIAN
 466 AC_C_INLINE
 467 AC_PROG_CC_STDC
 468 EFL_ATTRIBUTE_UNUSED
 469
 470 m4_ifdef([v_mic],
 471    [
 472     EFL_COMPILER_FLAG([-Wall])
 473     EFL_COMPILER_FLAG([-W])
 474    ])
 475
 476 EFL_COMPILER_FLAG([-Wshadow])
 477
 478 EFL_CHECK_PATH_MAX
 479
 480 ### Checks for linker characteristics
 481 lt_enable_auto_import=""
 482 case "${host_os}" in
 483    mingw*)
 484       lt_enable_auto_import="-Wl,--enable-auto-import"
 485    ;;
 486 esac
 487 AC_SUBST([lt_enable_auto_import])
 488
 489 EFL_LINKER_FLAG([-fno-strict-aliasing])
 490
 491 ### Checks for library functions
 492 AC_FUNC_ALLOCA
 493
 494 AC_CHECK_FUNCS([strlcpy openat fstatat fpathconf execvp backtrace backtrace_symbols malloc_usable_size mtrace])
 495
 496 EFL_CHECK_FUNCS([eina], [dirfd dlopen dladdr fnmatch iconv shm_open setxattr])
 497
 498 want_debug_malloc="no"
 499 AC_ARG_ENABLE([debug-malloc],
 500    [AC_HELP_STRING([--enable-debug-malloc], [enable debugging of malloc usage overhead in our allocator @<:@default=enabled@:>@])],
 501    [
 502      if test "x${enableval}" = "xyes" ; then
 503         want_debug_malloc="yes"
 504      else
 505         want_debug_malloc="no"
 506      fi
 507    ], [want_debug_malloc="no"])
 508
 509 if test "x${ac_cv_func_malloc_usable_size}" = "xyes" && test "x${want_debug_malloc}" = "xyes"; then
 510    AC_DEFINE([EINA_DEBUG_MALLOC], [1], [Turn on debugging overhead in mempool])
 511 fi
 512
 513 AC_ARG_ENABLE([log],
 514    [AC_HELP_STRING([--disable-log], [disable Eina_Log infrastructure completly @<:@default=enabled@:>@])],
 515    [
 516     if test "x${enableval}" = "xyes" ; then
 517        want_log="yes"
 518     else
 519        want_log="no"
 520     fi
 521    ],
 522    [want_log="yes"])
 523
 524 enable_log="no"
 525 if test "x${efl_func_fnmatch}" = "xyes" && test "x${want_log}" = "xyes" ; then
 526    enable_log="yes"
 527 fi
 528
 529 AC_MSG_CHECKING([wether to build Eina_Log infrastructure])
 530 AC_MSG_RESULT([${enable_log}])
 531
 532 if test "x${enable_log}" = "xyes"; then
 533     EINA_CONFIGURE_ENABLE_LOG="#define EINA_ENABLE_LOG"
 534     AC_DEFINE([HAVE_LOG], [1], [Define to 1 if we log support is on])
 535 fi
 536 AC_SUBST([EINA_CONFIGURE_ENABLE_LOG])
 537
 538
 539 ### Modules
 540
 541 if test "x${have_default_mempool}" = "xyes" ; then
 542    enable_chained_pool="no"
 543    enable_pass_through="static"
 544 else
 545    enable_chained_pool="static"
 546    enable_pass_through="no"
 547 fi
 548
 549 enable_one_big="static"
 550
 551 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 552 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 553 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 554 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 555 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 556 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 557 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 558
 559 ### Make the debug preprocessor configurable
 560
 561 ### Unit tests, coverage and benchmarking
 562
 563 EFL_CHECK_TESTS([eina], [enable_tests="yes"], [enable_tests="no"])
 564
 565 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 566 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 567 if test -n "$CXX" && test "x$enable_benchmark" = "xyes" ; then
 568    AC_DEFINE_UNQUOTED([CITYHASH_BENCH], [1], [enable bench tests for google hash method])
 569 fi
 570 AM_CONDITIONAL([CITYHASH_BENCH], [test -n "$CXX" && test "x$enable_benchmark" = "xyes"])
 571
 572 AC_SUBST([requirements_pc_eina])
 573 AC_SUBST([requirements_libs_eina])
 574
 575 ### Build and install examples
 576 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
 577 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
 578
 579 AC_CONFIG_FILES([
 580 Makefile
 581 eina.pc
 582 eina.spec
 583 doc/Makefile
 584 doc/Doxyfile
 585 src/Makefile
 586 src/include/Makefile
 587 src/include/eina_config.h
 588 src/lib/Makefile
 589 src/modules/Makefile
 590 src/modules/mp/Makefile
 591 src/modules/mp/chained_pool/Makefile
 592 src/modules/mp/ememoa_fixed/Makefile
 593 src/modules/mp/ememoa_unknown/Makefile
 594 src/modules/mp/pass_through/Makefile
 595 src/modules/mp/fixed_bitmap/Makefile
 596 src/modules/mp/buddy/Makefile
 597 src/modules/mp/one_big/Makefile
 598 src/tests/Makefile
 599 src/examples/Makefile
 600 src/scripts/Makefile
 601 ])
 602
 603 AC_OUTPUT
 604
 605 #####################################################################
 606 ## Info
 607
 608 echo
 609 echo
 610 echo
 611 echo "------------------------------------------------------------------------"
 612 echo "$PACKAGE $VERSION"
 613 echo "------------------------------------------------------------------------"
 614 echo
 615 echo
 616 echo "Configuration Options Summary:"
 617 echo
 618 echo "  Magic debug..........: ${have_magic_debug}"
 619 echo "  Safety checks........: ${have_safety_checks}"
 620 echo "  Maximum log level....: ${with_max_log_level}"
 621 echo "  Report string usage..: ${have_stringshare_usage}"
 622 echo "  Valgrind support.....: ${have_valgrind}"
 623 echo "  Default mempool......: ${have_default_mempool}"
 624 echo "  Log support..........: ${enable_log}"
 625 echo "  Thread Support.......: ${efl_have_threads}"
 626 if test "${efl_have_threads}" = "POSIX" ; then
 627 echo "    spinlock...........: ${efl_have_posix_threads_spinlock}"
 628 echo "    barrier............: ${efl_have_pthread_barrier}"
 629 echo "    affinity...........: ${efl_have_setaffinity}"
 630 echo "    debug usage........: ${efl_have_debug_threads}"
 631 echo "    on/off support.....: ${efl_have_on_off_threads}"
 632 fi
 633 echo "  Amalgamation.........: ${do_amalgamation}"
 634 echo "  Iconv support........: ${efl_func_iconv}"
 635 echo "  File dirfd...........: ${efl_func_dirfd}"
 636 echo "  File xattr...........: ${efl_func_setxattr}"
 637 echo "  shm_open.............: ${efl_func_shm_open}"
 638 echo
 639 echo "  Documentation........: ${build_doc}"
 640 echo "  Tests................: ${enable_tests} (Coverage: ${efl_enable_coverage})"
 641 echo "  Examples.............: ${enable_build_examples}"
 642 echo "  Tiler Example........: ${build_tiler_example}"
 643 echo "  Examples installed...: ${enable_install_examples}"
 644 echo "  Benchmark............: ${enable_benchmark}"
 645 if test "x${enable_benchmark}" = "xyes" ; then
 646 echo "    Glib...............: ${enable_benchmark_glib}"
 647 echo "    E17 real data......: ${enable_benchmark_e17}"
 648 fi
 649 echo
 650 echo "  CPU Specific Extensions:"
 651 echo "    MMX................: ${have_mmx}"
 652 echo "    SSE................: ${have_sse}"
 653 echo "    SSE2...............: ${have_sse2}"
 654 echo "    ALTIVEC............: ${have_altivec}"
 655 echo
 656 echo "  Memory pools:"
 657 echo "    Buddy..............: ${enable_buddy}"
 658 echo "    Chained pool.......: ${enable_chained_pool}"
 659 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 660 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 661 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 662 echo "    One big............: ${enable_one_big}"
 663 echo "    Pass through.......: ${enable_pass_through}"
 664 echo
 665 echo "Compilation............: make (or gmake)"
 666 echo "  CPPFLAGS.............: $CPPFLAGS"
 667 echo "  CFLAGS...............: $CFLAGS"
 668 echo "  LDFLAGS..............: $LDFLAGS"
 669 echo
 670 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 671 echo "  prefix...............: $prefix"
 672 echo
 673 EFL_FORM_VOLTRON