configure.ac

   1 AC_INIT([libxml++], [2.40.1],
   2         [https://bugzilla.gnome.org/enter_bug.cgi?product=libxml%2B%2B],
   3         [libxml++], [http://libxmlplusplus.sourceforge.net/])
   4 AC_PREREQ([2.59])
   5
   6 AC_CONFIG_SRCDIR([libxml++/libxml++.h])
   7 AC_CONFIG_AUX_DIR([build])
   8 AC_CONFIG_MACRO_DIR([build])
   9 AC_CONFIG_HEADERS([config.h libxml++config.h])
  10
  11 AM_INIT_AUTOMAKE([1.9 -Wno-portability dist-bzip2 no-define nostdinc subdir-objects])
  12 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  13 AM_MAINTAINER_MODE([disable])
  14 AC_ARG_VAR([ACLOCAL_FLAGS], [aclocal flags, e.g. -I <macro dir>])
  15
  16 MM_PREREQ([0.9.8])
  17 MM_INIT_MODULE([libxml++-2.6])
  18
  19 # Copy the mm-common .pl scripts into docs/,
  20 # and use them from there,
  21 # so we can dist them to avoid a tarball-build dependency.
  22 MM_CONFIG_DOCTOOL_DIR([docs])
  23
  24 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  25 AC_SUBST([LIBXMLXX_SO_VERSION], [2:7:0])
  26
  27 AC_PROG_CXX
  28 MM_AX_CXX_COMPILE_STDCXX_11([noext],[mandatory])
  29
  30 LT_PREREQ([2.2.6])
  31 LT_INIT([dlopen win32-dll disable-static])
  32
  33 AC_SUBST([LIBXMLXX_MODULES], ['libxml-2.0 >= 2.7.7 glibmm-2.4 >= 2.32.0'])
  34 PKG_CHECK_MODULES([LIBXMLXX], [$LIBXMLXX_MODULES])
  35
  36 AC_LANG([C++])
  37 AC_CHECK_HEADERS([string list map], [], [AC_MSG_ERROR([required headers not found])])
  38 LIBXMLXX_CXX_HAS_EXCEPTION_PTR
  39
  40 MM_ARG_ENABLE_DOCUMENTATION
  41 MM_ARG_WITH_TAGFILE_DOC([libstdc++.tag], [mm-common-libstdc++])
  42 MM_ARG_WITH_TAGFILE_DOC([libsigc++-2.0.tag], [sigc++-2.0])
  43 MM_ARG_WITH_TAGFILE_DOC([glibmm-2.4.tag], [glibmm-2.4])
  44
  45 # Evaluate the --enable-warnings=level option.
  46 MM_ARG_ENABLE_WARNINGS([LIBXMLXX_WXXFLAGS],
  47         [-Wall],
  48         [-pedantic -Wall -Wextra -Wformat-security -Wshadow -Wno-long-long],
  49         [G GLIBMM SIGCXX])
  50
  51 # Offer the ability to omit some API from the library.
  52 MM_ARG_DISABLE_DEPRECATED_API([LIBXMLXX])
  53
  54 AC_PATH_PROG([XMLLINT], [xmllint], [xmllint])
  55 AC_ARG_VAR([XMLLINT], [path to xmllint utility])
  56 AC_PATH_PROGS([DB2LATEX], [db2latex docbook2latex], [db2latex])
  57 AC_ARG_VAR([DB2LATEX], [path to db2latex utility])
  58 MM_CHECK_PERL()
  59
  60 # This is just defined to avoid breaking old code:
  61 AC_DEFINE([LIBXMLCPP_EXCEPTIONS_ENABLED],[1], [This is always set. This is only for backwards compatibility.])
  62
  63 AC_CONFIG_FILES([Makefile
  64         libxml++/Makefile
  65         examples/Makefile
  66         tests/Makefile
  67         docs/Makefile
  68         docs/reference/Doxyfile
  69         MSVC_Net2010/libxml++/libxml++.rc
  70         libxml++-2.6.pc])
  71
  72 # Copy the generated configuration headers into the MSVC project directories.
  73 AC_CONFIG_COMMANDS([MSVC_Net2010/libxml++/libxml++config.h],
  74         [cp -f libxml++config.h MSVC_Net2010/libxml++/libxml++config.h])
  75
  76 AC_OUTPUT