configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.14.2,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AM_PROG_LIBTOOL
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=0.10.23
  51 GSTPB_REQ=0.10.23
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION([0.17])
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101
 102 dnl determine c++ compiler
 103 AC_PROG_CXX
 104 dnl determine if c++ is available on this system
 105 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 106
 107 dnl determine c++ preprocessor
 108 dnl FIXME: do we need this ?
 109 AC_PROG_CXXCPP
 110
 111 AS_PROG_OBJC
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 dnl find an assembler
 117 AM_PROG_AS
 118
 119 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 120 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 121
 122 dnl check for gconftool-2
 123 dnl this macro defines an am conditional, so it needs to be run always
 124 AM_GCONF_SOURCE_2
 125
 126 dnl check for documentation tools
 127 GTK_DOC_CHECK([1.3])
 128 AS_PATH_PYTHON([2.1])
 129 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 AC_CHECK_LIBM
 135 AC_SUBST(LIBM)
 136
 137 dnl *** checks for header files ***
 138
 139 dnl check if we have ANSI C header files
 140 AC_HEADER_STDC
 141
 142 dnl used by ext/wavpack
 143 AX_CREATE_STDINT_H
 144
 145 dnl used in gst/rtp/gstasteriskh263.c
 146 AC_CHECK_HEADERS([netinet/in.h])
 147 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 148 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 149
 150 dnl used in gst/udp
 151 AC_CHECK_HEADERS([sys/time.h])
 152
 153 dnl *** checks for types/defines ***
 154
 155 dnl Check for FIONREAD ioctl declaration.  This check is needed
 156 dnl for the UDP plugin to build on Solaris
 157 GST_CHECK_FIONREAD
 158
 159 dnl *** checks for structures ***
 160
 161 dnl *** checks for compiler characteristics ***
 162
 163 dnl check if we have GCC inline-asm
 164 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 165 if test x$HAVE_GCC_ASM = xyes ; then
 166   AC_DEFINE(HAVE_GCC_ASM, 1,
 167     [Define if compiler supports gcc inline assembly])
 168 fi
 169 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 170
 171 dnl *** checks for library functions ***
 172
 173 LIBS_SAVE=$LIBS
 174 LIBS="$LIBS $LIBM"
 175 AC_CHECK_FUNCS(rint sinh cosh asinh)
 176 LIBS=$LIBS_SAVE
 177
 178 dnl Check for mmap (needed by electricfence plugin)
 179 AC_FUNC_MMAP
 180 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 181
 182 dnl Check for mmap (needed by electricfence plugin)
 183
 184 AC_CHECK_TYPE([struct ip_mreqn], [
 185               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 186               [#include <netinet/in.h>])
 187
 188 dnl *** checks for dependency libraries ***
 189
 190 dnl GLib is required
 191 AG_GST_GLIB_CHECK([2.12])
 192
 193 dnl liboil is required
 194 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 195 if test "x$HAVE_LIBOIL" != "xyes"; then
 196   AC_ERROR([liboil-0.3.8 or later is required])
 197 fi
 198
 199 dnl checks for gstreamer
 200 dnl uninstalled is selected preferentially -- see pkg-config(1)
 201 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 202 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 203 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 204 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 205 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 206 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 207
 208 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 209 if test -z $GST_TOOLS_DIR; then
 210   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 211 fi
 212 AC_SUBST(GST_TOOLS_DIR)
 213
 214 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 215 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 216
 217 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 218
 219 dnl Check for documentation xrefs
 220 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 221 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 222 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 223 AC_SUBST(GLIB_PREFIX)
 224 AC_SUBST(GST_PREFIX)
 225 AC_SUBST(GSTPB_PREFIX)
 226
 227 dnl GTK is optional and used in examples
 228 if test "x$BUILD_EXAMPLES" = "xyes"; then
 229   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, HAVE_GTK=yes, HAVE_GTK=no)
 230   AC_SUBST(GTK_LIBS)
 231   AC_SUBST(GTK_CFLAGS)
 232 fi
 233 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 234
 235 dnl should we install schemas ?
 236 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 237 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 238   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 239   if test x$GCONFTOOL = xno; then
 240     AC_MSG_WARN(Not installing GConf schemas)
 241     HAVE_GCONFTOOL="no"
 242   else
 243     HAVE_GCONFTOOL="yes"
 244   fi
 245   AC_SUBST(HAVE_GCONFTOOL)
 246 ])
 247
 248 dnl *** set variables based on configure arguments ***
 249
 250 dnl set license and copyright notice
 251 GST_LICENSE="LGPL"
 252 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 253 AC_SUBST(GST_LICENSE)
 254
 255 dnl set location of plugin directory
 256 AG_GST_SET_PLUGINDIR
 257
 258 dnl define an ERROR_CFLAGS Makefile variable
 259 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 260
 261 dnl define an ERROR_CXXFLAGS Makefile variable
 262 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 263
 264 dnl define correct level for debugging messages
 265 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 266
 267 dnl used in examples
 268 AG_GST_DEFAULT_ELEMENTS
 269
 270 dnl *** plug-ins to include ***
 271
 272 dnl these are all the gst plug-ins, compilable without additional libs
 273 dnl videofilter is at the top because others depend on it
 274 AG_GST_CHECK_PLUGIN(videofilter)
 275 AG_GST_CHECK_PLUGIN(alpha)
 276 AG_GST_CHECK_PLUGIN(apetag)
 277 AG_GST_CHECK_PLUGIN(audiofx)
 278 AG_GST_CHECK_PLUGIN(auparse)
 279 AG_GST_CHECK_PLUGIN(autodetect)
 280 AG_GST_CHECK_PLUGIN(avi)
 281 AG_GST_CHECK_PLUGIN(cutter)
 282 AG_GST_CHECK_PLUGIN(debugutils)
 283 AG_GST_CHECK_PLUGIN(deinterlace)
 284 AG_GST_CHECK_PLUGIN(effectv)
 285 AG_GST_CHECK_PLUGIN(equalizer)
 286 AG_GST_CHECK_PLUGIN(flv)
 287 AG_GST_CHECK_PLUGIN(id3demux)
 288 AG_GST_CHECK_PLUGIN(icydemux)
 289 AG_GST_CHECK_PLUGIN(interleave)
 290 AG_GST_CHECK_PLUGIN(flx)
 291 AG_GST_CHECK_PLUGIN(goom)
 292 AG_GST_CHECK_PLUGIN(goom2k1)
 293 AG_GST_CHECK_PLUGIN(law)
 294 AG_GST_CHECK_PLUGIN(level)
 295 AG_GST_CHECK_PLUGIN(matroska)
 296 AG_GST_CHECK_PLUGIN(monoscope)
 297 AG_GST_CHECK_PLUGIN(multifile)
 298 AG_GST_CHECK_PLUGIN(multipart)
 299 AG_GST_CHECK_PLUGIN(qtdemux)
 300 AG_GST_CHECK_PLUGIN(replaygain)
 301 AG_GST_CHECK_PLUGIN(rtp)
 302 AG_GST_CHECK_PLUGIN(rtsp)
 303 AG_GST_CHECK_PLUGIN(smpte)
 304 AG_GST_CHECK_PLUGIN(spectrum)
 305 AG_GST_CHECK_PLUGIN(udp)
 306 AG_GST_CHECK_PLUGIN(videobox)
 307 AG_GST_CHECK_PLUGIN(videocrop)
 308 AG_GST_CHECK_PLUGIN(videomixer)
 309 AG_GST_CHECK_PLUGIN(wavenc)
 310 AG_GST_CHECK_PLUGIN(wavparse)
 311
 312 dnl *** checks for socket and nsl libraries ***
 313 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 314
 315 dnl disable gst plugins we might not be able to build on this
 316 dnl platform: udp and rtsp (ugly but minimally invasive)
 317 dnl FIXME: maybe move to sys
 318 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 319 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 320
 321 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 322   AG_GST_DISABLE_PLUGIN(udp)
 323   AG_GST_DISABLE_PLUGIN(rtsp)
 324 fi
 325
 326 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 327   WIN32_LIBS="-lws2_32"
 328   AC_SUBST(WIN32_LIBS)
 329 fi
 330
 331 dnl disable experimental plug-ins
 332 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 333   AG_GST_DISABLE_PLUGIN(monoscope)
 334 fi
 335
 336 dnl *** sys plug-ins ***
 337
 338 echo
 339 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 340 echo
 341
 342 dnl DirectDraw
 343 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 344 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 345   HAVE_DIRECTDRAW="no"
 346   save_CFLAGS="$CFLAGS"
 347   save_LDFLAGS="$LDFLAGS"
 348   save_LIBS="$LIBS"
 349   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 350   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 351   LIBS="$LIBS -lddraw -lgdi32"
 352   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 353   AC_LINK_IFELSE([
 354 #include <windows.h>
 355 #include <ddraw.h>
 356
 357 int main ()
 358 {
 359   GetStockObject(0);
 360   DirectDrawCreate(NULL, NULL, NULL);
 361
 362   return 0;
 363 }
 364 ],
 365     [HAVE_DIRECTDRAW="yes"],
 366     [HAVE_DIRECTDRAW="no"])
 367   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 368   CFLAGS=$save_CFLAGS
 369   LDFLAGS=$save_LDFLAGS
 370   LIBS=$save_LIBS
 371
 372   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 373     dnl this is much more than we want
 374     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 375     AC_SUBST(DIRECTDRAW_CFLAGS)
 376     AC_SUBST(DIRECTDRAW_LDFLAGS)
 377     AC_SUBST(DIRECTDRAW_LIBS)
 378   fi
 379   AC_SUBST(HAVE_DIRECTDRAW)
 380 ])
 381
 382 dnl DirectSound
 383 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 384 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 385   HAVE_DIRECTSOUND="no"
 386   save_CFLAGS="$CFLAGS"
 387   save_LDFLAGS="$LDFLAGS"
 388   save_LIBS="$LIBS"
 389   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 390   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 391   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 392   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 393   AC_LINK_IFELSE([
 394 #include <windows.h>
 395 #include <dxerr9.h>
 396 #include <dsound.h>
 397
 398 int main ()
 399 {
 400   DXGetErrorString9 (0);
 401   DirectSoundCreate(NULL, NULL, NULL);
 402
 403   return 0;
 404 }
 405 ],
 406     [HAVE_DIRECTSOUND="yes"],
 407     [HAVE_DIRECTSOUND="no"])
 408   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 409   CFLAGS=$save_CFLAGS
 410   LDFLAGS=$save_LDFLAGS
 411   LIBS=$save_LIBS
 412
 413   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 414     dnl this is much more than we want
 415     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 416     AC_SUBST(DIRECTSOUND_CFLAGS)
 417     AC_SUBST(DIRECTSOUND_LDFLAGS)
 418     AC_SUBST(DIRECTSOUND_LIBS)
 419   fi
 420   AC_SUBST(HAVE_DIRECTSOUND)
 421 ])
 422
 423 dnl *** OSS audio *** (Linux, *BSD)
 424 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 425 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 426  HAVE_OSS="yes"
 427 dnl Linux and newer BSD versions :
 428  AC_CHECK_HEADER(sys/soundcard.h, [
 429    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 430    ] , [
 431 dnl Some old BSD versions and also newer OpenBSD versions :
 432    AC_CHECK_HEADER(soundcard.h, [
 433      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 434      ], [
 435   dnl Some old BSD versions :
 436      AC_CHECK_HEADER(machine/soundcard.h, [
 437        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 438          [Define if OSS includes are in /machine/])
 439        ], [
 440        HAVE_OSS="no"
 441      ])
 442    ])
 443  ])
 444 ])
 445
 446 dnl *** Sun Audio ***
 447 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 448 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 449   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 450 ])
 451
 452 dnl *** OSX Audio ***
 453 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 454 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 455   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 456 ])
 457
 458 dnl *** OS X video ***
 459 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 460 HAVE_OSX_VIDEO="no"
 461 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 462   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 463 ])
 464 dnl in case header OpenGL/gl.h is found on other platforms
 465 case "$host" in
 466   *-*darwin*)
 467     dnl do nothing
 468     ;;
 469   *)
 470     HAVE_OSX_VIDEO="no"
 471     ;;
 472 esac
 473
 474
 475 dnl *** Video 4 Linux 2 ***
 476 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 477 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 478 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 479 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 480   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 481   AC_TRY_COMPILE([
 482 #include <sys/types.h>
 483 #ifdef __sun /* Solaris */
 484 #include <sys/types.h>
 485 #include <sys/videodev2.h>
 486 #else /* Linux */
 487 #include <linux/types.h>
 488 #define _LINUX_TIME_H
 489 #define __user
 490 #include <linux/videodev2.h>
 491 #endif
 492 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 493 #error too early v4l2 version or no v4l2 at all
 494 #endif
 495     ], [
 496 return 0;
 497     ], [
 498       HAVE_GST_V4L2="yes"
 499       AC_MSG_RESULT(yes)
 500     ], [
 501       HAVE_GST_V4L2="no"
 502       AC_MSG_RESULT(no)
 503
 504       HAVE_VIDEODEV=no
 505       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 506       [
 507         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 508       ])
 509
 510       if test "x$HAVE_VIDEODEV" = "xyes"; then
 511         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 512         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 513       else
 514         AC_MSG_WARN([video4linux2 was not found])
 515       fi
 516     ])
 517
 518   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 519     dnl check for missing v4l2_buffer declaration (see #135919)
 520     MISSING_DECL=0
 521     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 522     AC_TRY_COMPILE([
 523 #include <sys/types.h>
 524 #ifdef __sun /* Solaris */
 525 #include <sys/types.h>
 526 #include <sys/videodev2.h>
 527 #else /* Linux */
 528 #include <linux/types.h>
 529 #define _LINUX_TIME_H
 530 #define __user
 531 #include <linux/videodev2.h>
 532 #endif
 533     ],[
 534 struct v4l2_buffer buf;
 535 buf.index = 0;
 536 return 0;
 537     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 538     if [ test x$MISSING_DECL = x1 ]; then
 539       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 540     fi
 541
 542     dnl check for XOverlay libraries
 543     AG_GST_CHECK_XV
 544   fi
 545 ])
 546
 547 # Make libv4l2 non-automagic
 548 AC_ARG_WITH([libv4l2],
 549   AC_HELP_STRING([--with-libv4l2],
 550     [support video buffer conversion using libv4l2]),
 551   [],
 552   [with_libv4l2=check])
 553 if test x$HAVE_GST_V4L2 = xyes; then
 554   if test x$with_libv4l2 != xno; then
 555       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 556           [ have_libv4l2=yes
 557             AC_DEFINE(HAVE_LIBV4L2, 1,
 558                 [Whether libv4l2 is available for video buffer conversion])
 559           ], [
 560           have_libv4l2=no
 561           ])
 562   else
 563     have_libv4l2=no
 564   fi
 565 fi
 566
 567 dnl Check for X11
 568 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 569 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 570                   [ximagesrc], [
 571   AC_PATH_XTRA
 572
 573   dnl now try to find the HEADER
 574   ac_cflags_save="$CFLAGS"
 575   ac_cppflags_save="$CPPFLAGS"
 576   CFLAGS="$CFLAGS $X_CFLAGS"
 577   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 578   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 579
 580   if test "x$HAVE_X" = "xno"
 581   then
 582     AC_MSG_NOTICE([cannot find X11 development files])
 583   else
 584     dnl this is much more than we want
 585     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 586     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 587     dnl it does not add the libs; therefore we add them here
 588     X_LIBS="$X_LIBS -lX11"
 589     AC_SUBST(X_CFLAGS)
 590     AC_SUBST(X_LIBS)
 591
 592     dnl check for Xfixes
 593     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 594     if test "x$HAVE_XFIXES" = "xyes"
 595     then
 596         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 597     fi
 598     AC_SUBST(XFIXES_LIBS)
 599     AC_SUBST(XFIXES_CFLAGS)
 600
 601     dnl check for Xdamage
 602     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 603     if test "x$HAVE_XDAMAGE" = "xyes"
 604     then
 605         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 606     fi
 607     AC_SUBST(XDAMAGE_LIBS)
 608     AC_SUBST(XDAMAGE_CFLAGS)
 609   fi
 610   AC_SUBST(HAVE_X)
 611   CFLAGS="$ac_cflags_save"
 612   CPPFLAGS="$ac_cppflags_save"
 613 ])
 614
 615 dnl FIXME: this should be rolled into the test above, it's just an additional
 616 dnl feature of the ximagesrc plug-in
 617 dnl This is the same as in gst-plugins-base
 618 dnl check for X Shm
 619 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 620 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 621   if test x$HAVE_X = xyes; then
 622     AC_CHECK_LIB(Xext, XShmAttach,
 623                  HAVE_XSHM="yes", HAVE_XSHM="no",
 624                  $X_LIBS)
 625     if test "x$HAVE_XSHM" = "xyes"; then
 626       XSHM_LIBS="-lXext"
 627     else
 628       dnl On AIX, it is in XextSam instead, but we still need -lXext
 629       AC_CHECK_LIB(XextSam, XShmAttach,
 630                    HAVE_XSHM="yes", HAVE_XSHM="no",
 631                    $X_LIBS)
 632       if test "x$HAVE_XSHM" = "xyes"; then
 633         XSHM_LIBS="-lXext -lXextSam"
 634       fi
 635     fi
 636   fi
 637 ], ,[
 638   AC_SUBST(HAVE_XSHM)
 639   AC_SUBST(XSHM_LIBS)
 640 ])
 641
 642 dnl for V4L2, we also need to know if we have XVIDEO
 643 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 644 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 645                   [], [
 646   AG_GST_CHECK_XV
 647 ])
 648
 649 dnl *** ext plug-ins ***
 650 dnl keep this list sorted alphabetically !
 651
 652 if test "x$BUILD_EXTERNAL" = "xyes"; then
 653
 654 echo
 655 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 656 echo
 657
 658 dnl *** aalib ***
 659 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 660 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 661   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 662   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 663 ])
 664
 665 dnl *** annodex ***
 666 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 667 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 668   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 669 ])
 670
 671 dnl *** cairo ***
 672 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 673 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 674   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 675 ])
 676
 677 dnl **** ESound ****
 678 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 679 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 680   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 681   if test $HAVE_ESD = no
 682   then
 683     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 684     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 685   fi
 686 ])
 687
 688 dnl *** FLAC ***
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 690 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 691   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 692 ])
 693
 694 dnl *** GConf ***
 695 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 696 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 697   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 698 ])
 699
 700 dnl *** GDK pixbuf ***
 701 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 702 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 703   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 704 ])
 705
 706 dnl *** HAL ***
 707 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 708 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 709   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 710 ])
 711
 712 dnl *** jpeg ***
 713 dnl FIXME: we could use header checks here as well IMO
 714 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 715 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 716   AC_ARG_WITH(jpeg-mmx,
 717     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 718   OLD_LIBS="$LIBS"
 719   if test x$with_jpeg_mmx != x; then
 720     LIBS="$LIBS -L$with_jpeg_mmx"
 721   fi
 722   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 723   JPEG_LIBS="$LIBS -ljpeg-mmx"
 724   LIBS="$OLD_LIBS"
 725   if test x$HAVE_JPEG != xyes; then
 726     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 727     JPEG_LIBS="-ljpeg"
 728   fi
 729   AC_SUBST(JPEG_LIBS)
 730 ])
 731
 732 dnl *** libcaca ***
 733 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 734 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 735   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 736   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 737   if test "x$HAVE_LIBCACA" != "xyes"; then
 738     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 739     dnl see if it compilation works too, might not if we are cross-compiling
 740     if test "x$HAVE_LIBCACA" = "xyes"; then
 741       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 742                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 743     fi
 744   fi
 745 ])
 746
 747 dnl *** libdv ***
 748 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 749 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 750   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 751 ])
 752
 753 dnl *** libpng ***
 754 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 755 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 756   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 757 ])
 758
 759 dnl *** pulseaudio ***
 760 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 761 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 762   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.8)
 763   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 764   if test x$HAVE_PULSE_0_9_11 = xyes; then
 765     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 766   fi
 767   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 768   if test x$HAVE_PULSE_0_9_12 = xyes; then
 769     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 770   fi
 771   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 772   if test x$HAVE_PULSE_0_9_13 = xyes; then
 773     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 774   fi
 775 ])
 776
 777 dnl *** dv1394 ***
 778 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 779 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 780   dnl first test for libraw1394 >= 1.2.1
 781   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 782   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 783   dnl now see how far we got
 784   if test x$HAVE_RAW1394 = xyes && \
 785      test x$HAVE_LIBIEC61883 = xyes; then
 786        AG_GST_CHECK_LIBHEADER(AVC1394,
 787         avc1394, avc1394_send_command, $RAW1394_LIBS,
 788         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 789        AG_GST_CHECK_LIBHEADER(ROM1394,
 790         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 791         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 792        if test x$HAVE_AVC1394 = xyes && \
 793           test x$HAVE_AVC1394 = xyes && \
 794           test x$HAVE_ROM1394 = xyes; then
 795           HAVE_DV1394=yes
 796           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 797           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 798           AC_SUBST(DV1394_CFLAGS)
 799           AC_SUBST(DV1394_LIBS)
 800         fi
 801   else
 802        if test x$HAVE_RAW1394 = xno; then
 803           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 804           AG_GST_CHECK_LIBHEADER(AVC1394,
 805            avc1394, avc1394_send_command, $RAW1394_LIBS,
 806            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 807           AG_GST_CHECK_LIBHEADER(ROM1394,
 808            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 809            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 810           if test x$HAVE_RAW1394 = xyes && \
 811              test x$HAVE_AVC1394 = xyes && \
 812              test x$HAVE_ROM1394 = xyes; then
 813              HAVE_DV1394=yes
 814              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 815              DV1394_CFLAGS="$RAW1394_CFLAGS"
 816              if test x$HAVE_LIBIEC61883 = xyes; then
 817                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 818                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 819              fi
 820              AC_SUBST(DV1394_CFLAGS)
 821              AC_SUBST(DV1394_LIBS)
 822            fi
 823          fi
 824   fi
 825 ])
 826
 827 dnl *** shout2 ***
 828 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 829 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 830   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 831   if test $HAVE_SHOUT2 = no
 832   then
 833     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 834     AC_SUBST(SHOUT2_CFLAGS)
 835     AC_SUBST(SHOUT2_LIBS)
 836   fi
 837 ])
 838
 839 dnl *** soup ***
 840 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 841 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 842   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 843     HAVE_SOUP="yes"
 844     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 845   ],[
 846     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.3.2, HAVE_SOUP="yes", [
 847       HAVE_SOUP="no"
 848       AC_MSG_RESULT(no)
 849     ])
 850   ])
 851   AC_SUBST(SOUP_CFLAGS)
 852   AC_SUBST(SOUP_LIBS)
 853 ])
 854
 855 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 856 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 857 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 858 dnl   speex_jitter.h is 1.1.x only
 859 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 860 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 861   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 862   if test $HAVE_SPEEX = no
 863   then
 864     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 865       AC_CHECK_HEADER(speex/speex_jitter.h, [
 866         dnl speex 1.1.x :
 867         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 868           dnl speex 1.1.5 or + :
 869           HAVE_SPEEX="yes"
 870           SPEEX_LIBS="-lspeex"
 871           AC_SUBST(SPEEX_CFLAGS)
 872           AC_SUBST(SPEEX_LIBS)
 873         ],[
 874           HAVE_SPEEX="no"
 875         ])
 876       ],[
 877         dnl speex 1.0.x :
 878           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 879             dnl speex 1.0.4
 880             HAVE_SPEEX="yes"
 881             SPEEX_LIBS="-lspeex"
 882             AC_SUBST(SPEEX_CFLAGS)
 883             AC_SUBST(SPEEX_LIBS)
 884
 885             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 886               [defined if speex 1.0.x API detected])
 887         ],[
 888             HAVE_SPEEX="no"
 889             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 890         ], [
 891 #include <speex/speex.h>
 892         ])
 893       ])
 894     ])
 895   fi
 896 ])
 897
 898 dnl *** taglib ***
 899 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 900 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 901   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 902   if test "x$HAVE_CXX" != "xyes"; then
 903     USE_TAGLIB=false
 904     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 905   else
 906     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 907     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 908         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 909       ], [
 910         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 911     ])
 912     AC_SUBST(TAGLIB_CXXFLAGS)
 913   fi
 914 ])
 915
 916 dnl *** wavpack ***
 917 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 918 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 919   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 920     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 921       HAVE_WAVPACK=yes
 922       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 923     ],[
 924       HAVE_WAVPACK=no
 925       AC_MSG_RESULT(no)
 926     ])
 927   ])
 928   AC_SUBST(WAVPACK_CFLAGS)
 929   AC_SUBST(WAVPACK_LIBS)
 930 ])
 931
 932 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 933 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 934 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 935   AG_GST_CHECK_LIBHEADER(ZLIB,
 936     z, uncompress,, zlib.h, [
 937     HAVE_ZLIB="yes"
 938     ZLIB_LIBS="-lz"
 939     AC_SUBST(ZLIB_LIBS)
 940   ])
 941 ])
 942
 943 dnl *** matroska prefers to have bz2 ***
 944 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 945 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 946   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 947   AC_SUBST(BZ2_LIBS)
 948 ])
 949
 950 else
 951
 952 dnl not building plugins with external dependencies,
 953 dnl but we still need to set the conditionals
 954 AM_CONDITIONAL(USE_AALIB, false)
 955 AM_CONDITIONAL(USE_ANNODEX, false)
 956 AM_CONDITIONAL(USE_BZ2, false)
 957 AM_CONDITIONAL(USE_CAIRO, false)
 958 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 959 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 960 AM_CONDITIONAL(USE_DV1394, false)
 961 AM_CONDITIONAL(USE_ESD, false)
 962 AM_CONDITIONAL(USE_FLAC, false)
 963 AM_CONDITIONAL(USE_GCONF, false)
 964 AM_CONDITIONAL(USE_GCONFTOOL, false)
 965 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 966 AM_CONDITIONAL(USE_GST_V4L2, false)
 967 AM_CONDITIONAL(USE_HAL, false)
 968 AM_CONDITIONAL(USE_JPEG, false)
 969 AM_CONDITIONAL(USE_LIBCACA, false)
 970 AM_CONDITIONAL(USE_LIBDV, false)
 971 AM_CONDITIONAL(USE_LIBPNG, false)
 972 AM_CONDITIONAL(USE_OSS, false)
 973 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 974 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 975 AM_CONDITIONAL(USE_PULSE, false)
 976 AM_CONDITIONAL(USE_SHOUT2, false)
 977 AM_CONDITIONAL(USE_SOUP, false)
 978 AM_CONDITIONAL(USE_SPEEX, false)
 979 AM_CONDITIONAL(USE_SUNAUDIO, false)
 980 AM_CONDITIONAL(USE_TAGLIB, false)
 981 AM_CONDITIONAL(USE_WAVPACK, false)
 982 AM_CONDITIONAL(USE_X, false)
 983 AM_CONDITIONAL(USE_XSHM, false)
 984 AM_CONDITIONAL(USE_XVIDEO, false)
 985 AM_CONDITIONAL(USE_ZLIB, false)
 986
 987 fi dnl of EXT plugins
 988
 989 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 990
 991 dnl Overview:
 992 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 993 dnl GST_*:              flags shared by all built objects
 994 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 995 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 996 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 997 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 998
 999 dnl GST_OPTION_CFLAGS
1000 if test "x$USE_DEBUG" = xyes; then
1001    PROFILE_CFLAGS="-g"
1002 fi
1003 AC_SUBST(PROFILE_CFLAGS)
1004
1005 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1006   dnl Define _only_ during CVS (not pre-releases or releases)
1007   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1008 else
1009   DEPRECATED_CFLAGS=""
1010 fi
1011 AC_SUBST(DEPRECATED_CFLAGS)
1012
1013 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1014 dnl at make time with e.g. make ERROR_CFLAGS=""
1015 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1016 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1017 AC_SUBST(GST_OPTION_CFLAGS)
1018 AC_SUBST(GST_OPTION_CXXFLAGS)
1019
1020 dnl our libraries need to be versioned correctly
1021 AC_SUBST(GST_LT_LDFLAGS)
1022
1023 dnl FIXME: do we want to rename to GST_ALL_* ?
1024 dnl prefer internal headers to already installed ones
1025 dnl also add builddir include for enumtypes and marshal
1026 dnl add ERROR_CFLAGS, but overridable
1027 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1028 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CXXFLAGS \$(GST_OPTION_CXXFLAGS)"
1029 AC_SUBST(GST_CFLAGS)
1030 AC_SUBST(GST_CXXFLAGS)
1031 AC_SUBST(GST_LIBS)
1032
1033 dnl LDFLAGS really should only contain flags, not libs - they get added before
1034 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1035 GST_ALL_LDFLAGS="-no-undefined"
1036 AC_SUBST(GST_ALL_LDFLAGS)
1037
1038 dnl this really should only contain flags, not libs - they get added before
1039 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1040 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1041 AC_SUBST(GST_PLUGIN_LDFLAGS)
1042
1043 SHAVE_INIT([common],[enable])
1044 dnl *** output files ***
1045
1046 dnl keep this alphabetic per directory, please
1047 AC_CONFIG_FILES(
1048 Makefile
1049 common/shave
1050 common/shave-libtool
1051 gst/Makefile
1052 gst/alpha/Makefile
1053 gst/apetag/Makefile
1054 gst/audiofx/Makefile
1055 gst/auparse/Makefile
1056 gst/autodetect/Makefile
1057 gst/avi/Makefile
1058 gst/cutter/Makefile
1059 gst/deinterlace/Makefile
1060 gst/debugutils/Makefile
1061 gst/effectv/Makefile
1062 gst/equalizer/Makefile
1063 gst/flv/Makefile
1064 gst/id3demux/Makefile
1065 gst/icydemux/Makefile
1066 gst/interleave/Makefile
1067 gst/goom/Makefile
1068 gst/goom2k1/Makefile
1069 gst/law/Makefile
1070 gst/level/Makefile
1071 gst/matroska/Makefile
1072 gst/monoscope/Makefile
1073 gst/multifile/Makefile
1074 gst/multipart/Makefile
1075 gst/qtdemux/Makefile
1076 gst/replaygain/Makefile
1077 gst/rtp/Makefile
1078 gst/rtsp/Makefile
1079 gst/smpte/Makefile
1080 gst/spectrum/Makefile
1081 gst/udp/Makefile
1082 gst/videobox/Makefile
1083 gst/videocrop/Makefile
1084 gst/videofilter/Makefile
1085 gst/videomixer/Makefile
1086 gst/wavenc/Makefile
1087 gst/wavparse/Makefile
1088 gst/flx/Makefile
1089 ext/jpeg/Makefile
1090 ext/Makefile
1091 ext/aalib/Makefile
1092 ext/annodex/Makefile
1093 ext/cairo/Makefile
1094 ext/dv/Makefile
1095 ext/esd/Makefile
1096 ext/flac/Makefile
1097 ext/gconf/Makefile
1098 ext/gdk_pixbuf/Makefile
1099 ext/hal/Makefile
1100 ext/ladspa/Makefile
1101 ext/libcaca/Makefile
1102 ext/libpng/Makefile
1103 ext/pulse/Makefile
1104 ext/raw1394/Makefile
1105 ext/shout2/Makefile
1106 ext/soup/Makefile
1107 ext/speex/Makefile
1108 ext/taglib/Makefile
1109 ext/wavpack/Makefile
1110 sys/Makefile
1111 sys/directdraw/Makefile
1112 sys/directsound/Makefile
1113 sys/oss/Makefile
1114 sys/sunaudio/Makefile
1115 sys/osxaudio/Makefile
1116 sys/osxvideo/Makefile
1117 sys/v4l2/Makefile
1118 sys/waveform/Makefile
1119 sys/ximage/Makefile
1120 po/Makefile.in
1121 tests/Makefile
1122 tests/check/Makefile
1123 tests/examples/Makefile
1124 tests/examples/audiofx/Makefile
1125 tests/examples/equalizer/Makefile
1126 tests/examples/level/Makefile
1127 tests/examples/rtp/Makefile
1128 tests/examples/spectrum/Makefile
1129 tests/files/Makefile
1130 tests/icles/Makefile
1131 gconf/Makefile
1132 gconf/gstreamer.schemas
1133 common/Makefile
1134 common/m4/Makefile
1135 m4/Makefile
1136 docs/Makefile
1137 docs/plugins/Makefile
1138 docs/version.entities
1139 pkgconfig/Makefile
1140 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1141 gst-plugins-good.spec
1142 )
1143
1144 dnl Create the config.h file for Visual Studio builds
1145 dnl Beware of spaces and /'s in some of the shell variable contents.
1146 sed \
1147     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1148     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1149     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1150     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1151     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1152     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1153     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1154     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1155     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1156     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1157     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1158     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1159     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1160     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1161     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1162     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1163     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1164     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1165     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1166     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1167     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1168     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1169     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1170     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1171     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1172     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1173     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1174     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1175     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1176     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1177     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1178     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1179     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1180     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1181     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1182     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1183     config.h.in >win32/common/config.h-new
1184
1185 AC_OUTPUT
1186
1187 AG_GST_OUTPUT_PLUGINS