configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.6.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AM_PROG_LIBTOOL
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=0.10.13
  50 GSTPB_REQ=0.10.13
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.11.5])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DEBUG
  69 AG_GST_ARG_PROFILING
  70 AG_GST_ARG_VALGRIND
  71 AG_GST_ARG_GCOV
  72
  73 AG_GST_ARG_EXAMPLES
  74
  75 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  76 AG_GST_ARG_WITH_PACKAGE_NAME
  77 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  78
  79 dnl these are all the gst plug-ins, compilable without additional libs
  80 dnl videofilter is at the top because others depend on it
  81 GST_PLUGINS_ALL="\
  82                 videofilter \
  83                 alpha \
  84                 apetag \
  85                 audiofx \
  86                 auparse \
  87                 autodetect \
  88                 avi \
  89                 cutter \
  90                 debug \
  91                 effectv \
  92                 id3demux \
  93                 icydemux \
  94                 flx \
  95                 goom \
  96                 law \
  97                 level \
  98                 matroska \
  99                 monoscope \
 100                 multipart \
 101                 qtdemux \
 102                 rtp     \
 103                 rtsp    \
 104                 smpte   \
 105                 udp     \
 106                 videobox \
 107                 videocrop \
 108                 videomixer \
 109                 wavenc \
 110                 wavparse \
 111                 "
 112 AC_SUBST(GST_PLUGINS_ALL)
 113
 114 GST_PLUGINS_SELECTED=""
 115
 116 AC_ARG_WITH(plugins,
 117     AC_HELP_STRING([--with-plugins],
 118       [comma-separated list of plug-ins to compile]),
 119     [for i in `echo $withval | tr , ' '`; do
 120         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 121         then
 122             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 123         else
 124             echo "plug-in $i not recognized, ignoring..."
 125         fi
 126     done],
 127     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 128
 129 dnl disable gst plugins we might not be able to build on this
 130 dnl platform: udp and rtsp (ugly but minimally invasive)
 131 dnl FIXME: maybe move to sys
 132 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 133 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 134
 135 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 136   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/udp//`
 137   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/rtsp//`
 138 fi
 139
 140 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 141   WIN32_LIBS="-lws2_32"
 142   AC_SUBST(WIN32_LIBS)
 143 fi
 144
 145 dnl ext plug-ins; plug-ins that have external dependencies
 146 AG_GST_CHECK_FEATURE(EXTERNAL, [building of plug-ins with external deps],,
 147   [HAVE_EXTERNAL=yes], enabled,
 148   [
 149     AC_MSG_NOTICE(building external plug-ins)
 150     BUILD_EXTERNAL="yes"
 151   ],[
 152     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 153     BUILD_EXTERNAL="no"
 154   ])
 155 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 156
 157 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
 158 AG_GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
 159 [HAVE_EXPERIMENTAL=yes],disabled,
 160 [
 161   AC_MSG_WARN(building experimental plug-ins)
 162   USE_GST_V4L2="yes"
 163 ],[
 164   AC_MSG_NOTICE(not building experimental plug-ins)
 165   USE_GST_V4L2="no"
 166   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/monoscope//`
 167 ])
 168
 169 AC_SUBST(GST_PLUGINS_SELECTED)
 170
 171 dnl *** checks for platform ***
 172
 173 dnl * hardware/architecture *
 174
 175 dnl common/m4/gst-arch.m4
 176 dnl check CPU type
 177 AG_GST_ARCH
 178
 179 dnl Determine endianness
 180 AC_C_BIGENDIAN
 181
 182 dnl *** checks for programs ***
 183
 184 dnl find a compiler
 185 AC_PROG_CC
 186
 187 dnl determine c++ compiler
 188 AC_PROG_CXX
 189 dnl determine if c++ is available on this system
 190 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 191
 192 dnl determine c++ preprocessor
 193 dnl FIXME: do we need this ?
 194 AC_PROG_CXXCPP
 195
 196 AS_PROG_OBJC
 197
 198 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 199 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 200
 201 dnl check for gconftool-2
 202 dnl this macro defines an am conditional, so it needs to be run always
 203 AM_GCONF_SOURCE_2
 204
 205 dnl check for documentation tools
 206 GTK_DOC_CHECK([1.3])
 207 AS_PATH_PYTHON([2.1])
 208 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 209
 210 dnl *** checks for libraries ***
 211
 212 dnl check for libm, for sin()
 213 AC_CHECK_LIBM
 214 AC_SUBST(LIBM)
 215
 216 dnl *** checks for header files ***
 217
 218 dnl check if we have ANSI C header files
 219 AC_HEADER_STDC
 220
 221 dnl used by ext/wavpack
 222 AX_CREATE_STDINT_H
 223
 224 dnl used in gst/rtp/gstasteriskh263.c
 225 AC_CHECK_HEADERS([netinet/in.h])
 226 AC_CHECK_HEADERS([winsock2.h])
 227 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 228
 229 dnl *** checks for types/defines ***
 230
 231 dnl Check for FIONREAD ioctl declaration.  This check is needed
 232 dnl for the UDP plugin to build on Solaris
 233 GST_CHECK_FIONREAD
 234
 235 dnl *** checks for structures ***
 236
 237 dnl *** checks for compiler characteristics ***
 238
 239 dnl FIXME: check if this is used; was used for floatcast.h in base
 240 dnl Check for fast float to int casting as defined in C99
 241 AC_C99_FUNC_LRINT
 242 AC_C99_FUNC_LRINTF
 243
 244 dnl *** checks for library functions ***
 245
 246 dnl Check for mmap (needed by electricfence plugin)
 247 AC_FUNC_MMAP
 248 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 249
 250 dnl *** checks for dependency libraries ***
 251
 252 dnl GLib is required
 253 AG_GST_GLIB_CHECK([2.6])
 254
 255 dnl liboil is required
 256 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.2, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 257 if test "x${HAVE_LIBOIL}" != xyes ; then
 258   AC_ERROR([liboil-0.3 is required])
 259 fi
 260
 261 dnl checks for gstreamer
 262 dnl uninstalled is selected preferentially -- see pkg-config(1)
 263 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 264 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 265 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 266 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 267 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 268 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ])
 269
 270 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 271 if test -z $GST_TOOLS_DIR; then
 272   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 273 fi
 274 AC_SUBST(GST_TOOLS_DIR)
 275
 276 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 277 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 278
 279 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 280
 281 dnl Check for documentation xrefs
 282 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 283 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 284 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 285 AC_SUBST(GLIB_PREFIX)
 286 AC_SUBST(GST_PREFIX)
 287 AC_SUBST(GSTPB_PREFIX)
 288
 289 dnl GTK is optional and used in examples
 290 HAVE_GTK=NO
 291 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 292 if test "x$HAVE_GTK_22" = "xyes"; then
 293   HAVE_GTK=yes
 294   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 295   AC_SUBST(GTK_VERSION)
 296   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 297   AC_SUBST(GTK_BASE_DIR)
 298   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 299   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 300   AC_SUBST(GTK_BASE_DIR)
 301 else
 302   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 303 fi
 304 if test "x$HAVE_GTK_20" = "xyes"; then
 305   HAVE_GTK=yes
 306 fi
 307 GTK_CFLAGS=$GTK2_CFLAGS
 308 GTK_LIBS=$GTK2_LIBS
 309 AC_SUBST(GTK_LIBS)
 310 AC_SUBST(GTK_CFLAGS)
 311 AC_SUBST(HAVE_GTK)
 312 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 313
 314 dnl should we install schemas ?
 315 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 316 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 317   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 318   if test x$GCONFTOOL = xno; then
 319     AC_MSG_WARN(Not installing GConf schemas)
 320     HAVE_GCONFTOOL="no"
 321   else
 322     HAVE_GCONFTOOL="yes"
 323   fi
 324   AC_SUBST(HAVE_GCONFTOOL)
 325 ])
 326
 327 dnl *** set variables based on configure arguments ***
 328
 329 dnl set license and copyright notice
 330 GST_LICENSE="LGPL"
 331 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 332 AC_SUBST(GST_LICENSE)
 333
 334 dnl set location of plugin directory
 335 AG_GST_SET_PLUGINDIR
 336
 337 dnl define an ERROR_CFLAGS Makefile variable
 338 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 339
 340 dnl define correct level for debugging messages
 341 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 342
 343 dnl used in examples
 344 AG_GST_DEFAULT_ELEMENTS
 345
 346 dnl *** sys plug-ins ***
 347
 348 echo
 349 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 350 echo
 351
 352 dnl DirectDraw
 353 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 354 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 355   HAVE_DIRECTDRAW="no"
 356   save_CFLAGS="$CFLAGS"
 357   save_LDFLAGS="$LDFLAGS"
 358   save_LIBS="$LIBS"
 359   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 360   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 361   LIBS="$LIBS -lddraw -lgdi32"
 362   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 363   AC_LINK_IFELSE([
 364 #include <windows.h>
 365 #include <ddraw.h>
 366
 367 int main ()
 368 {
 369   GetStockObject(0);
 370   DirectDrawCreate(NULL, NULL, NULL);
 371
 372   return 0;
 373 }
 374 ],
 375     [HAVE_DIRECTDRAW="yes"],
 376     [HAVE_DIRECTDRAW="no"])
 377   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 378   CFLAGS=$save_CFLAGS
 379   LDFLAGS=$save_LDFLAGS
 380   LIBS=$save_LIBS
 381
 382   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 383     dnl this is much more than we want
 384     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 385     AC_SUBST(DIRECTDRAW_CFLAGS)
 386     AC_SUBST(DIRECTDRAW_LDFLAGS)
 387     AC_SUBST(DIRECTDRAW_LIBS)
 388   fi
 389   AC_SUBST(HAVE_DIRECTDRAW)
 390 ])
 391
 392 dnl DirectSound
 393 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 394 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 395   HAVE_DIRECTSOUND="no"
 396   save_CFLAGS="$CFLAGS"
 397   save_LDFLAGS="$LDFLAGS"
 398   save_LIBS="$LIBS"
 399   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 400   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 401   LIBS="$LIBS -ldsound -ldxerr9"
 402   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 403   AC_LINK_IFELSE([
 404 #include <windows.h>
 405 #include <dxerr9.h>
 406 #include <dsound.h>
 407
 408 int main ()
 409 {
 410   DXGetErrorString9 (0);
 411   DirectSoundCreate(NULL, NULL, NULL);
 412
 413   return 0;
 414 }
 415 ],
 416     [HAVE_DIRECTSOUND="yes"],
 417     [HAVE_DIRECTSOUND="no"])
 418   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 419   CFLAGS=$save_CFLAGS
 420   LDFLAGS=$save_LDFLAGS
 421   LIBS=$save_LIBS
 422
 423   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 424     dnl this is much more than we want
 425     DIRECTSOUND_LIBS="-ldsound -ldxerr9"
 426     AC_SUBST(DIRECTSOUND_CFLAGS)
 427     AC_SUBST(DIRECTSOUND_LDFLAGS)
 428     AC_SUBST(DIRECTSOUND_LIBS)
 429   fi
 430   AC_SUBST(HAVE_DIRECTSOUND)
 431 ])
 432
 433 dnl *** OSS audio *** (Linux, *BSD)
 434 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 435 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 436  HAVE_OSS="yes"
 437 dnl Linux and newer BSD versions :
 438  AC_CHECK_HEADER(sys/soundcard.h, [
 439    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 440    ] , [
 441 dnl Some old BSD versions and also newer OpenBSD versions :
 442    AC_CHECK_HEADER(soundcard.h, [
 443      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 444      ], [
 445   dnl Some old BSD versions :
 446      AC_CHECK_HEADER(machine/soundcard.h, [
 447        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 448          [Define if OSS includes are in /machine/])
 449        ], [
 450        HAVE_OSS="no"
 451      ])
 452    ])
 453  ])
 454 ])
 455
 456 dnl *** Sun Audio ***
 457 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 458 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 459   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 460 ])
 461
 462 dnl *** OSX Audio ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 464 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 465   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 466 ])
 467
 468 dnl *** OS X video ***
 469 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 470 HAVE_OSX_VIDEO="no"
 471 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 472   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 473 ])
 474 dnl in case header OpenGL/gl.h is found on other platforms
 475 case "$host" in
 476   *-*darwin*)
 477     dnl do nothing
 478     ;;
 479   *)
 480     HAVE_OSX_VIDEO="no"
 481     ;;
 482 esac
 483
 484
 485 dnl *** Video 4 Linux 2 ***
 486 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 487 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 488 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 489 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 490   AC_MSG_CHECKING([Checking for uptodate v4l2 installation])
 491   AC_TRY_COMPILE([
 492 #include <sys/types.h>
 493 #include <linux/types.h>
 494 #define _LINUX_TIME_H
 495 #define __user
 496 #include <linux/videodev2.h>
 497 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 498 #error too early v4l2 version or no v4l2 at all
 499 #endif
 500     ], [
 501 return 0;
 502     ], [
 503       HAVE_GST_V4L2="yes"
 504       AC_MSG_RESULT(yes)
 505     ], [
 506       HAVE_GST_V4L2="no"
 507       AC_MSG_RESULT(no)
 508       AC_CHECK_HEADER(linux/videodev2.h,
 509       [
 510         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 511         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 512       ], [
 513         AC_MSG_WARN([video4linux2 was not found])
 514       ])
 515     ])
 516
 517   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 518     dnl check for missing v4l2_buffer declaration (see #135919)
 519     MISSING_DECL=0
 520     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 521     AC_TRY_COMPILE([
 522 #include <sys/types.h>
 523 #include <linux/types.h>
 524 #define _LINUX_TIME_H
 525 #define __user
 526 #include <linux/videodev2.h>
 527     ],[
 528 struct v4l2_buffer buf;
 529 buf.index = 0;
 530 return 0;
 531     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 532     if [ test x$MISSING_DECL = x1 ]; then
 533       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 534     fi
 535
 536     dnl check for XOverlay libraries
 537     AG_GST_CHECK_XV
 538   fi
 539 ])
 540
 541 dnl Check for X11
 542 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 543 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 544                   [ximagesrc], [
 545   AC_PATH_XTRA
 546
 547   dnl now try to find the HEADER
 548   ac_cflags_save="$CFLAGS"
 549   ac_cppflags_save="$CPPFLAGS"
 550   CFLAGS="$CFLAGS $X_CFLAGS"
 551   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 552   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 553
 554   if test "x$HAVE_X" = "xno"
 555   then
 556     AC_MSG_NOTICE([cannot find X11 development files])
 557   else
 558     dnl this is much more than we want
 559     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 560     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 561     dnl it does not add the libs; therefore we add them here
 562     X_LIBS="$X_LIBS -lX11"
 563     AC_SUBST(X_CFLAGS)
 564     AC_SUBST(X_LIBS)
 565
 566     dnl check for Xfixes
 567     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 568     if test "x$HAVE_XFIXES" = "xyes"
 569     then
 570         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 571     fi
 572     AC_SUBST(XFIXES_LIBS)
 573     AC_SUBST(XFIXES_CFLAGS)
 574
 575     dnl check for Xdamage
 576     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 577     if test "x$HAVE_XDAMAGE" = "xyes"
 578     then
 579         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 580     fi
 581     AC_SUBST(XDAMAGE_LIBS)
 582     AC_SUBST(XDAMAGE_CFLAGS)
 583   fi
 584   AC_SUBST(HAVE_X)
 585   CFLAGS="$ac_cflags_save"
 586   CPPFLAGS="$ac_cppflags_save"
 587 ])
 588
 589 dnl FIXME: this should be rolled into the test above, it's just an additional
 590 dnl feature of the ximagesrc plug-in
 591 dnl This is the same as in gst-plugins-base
 592 dnl check for X Shm
 593 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 594 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 595   if test x$HAVE_X = xyes; then
 596     AC_CHECK_LIB(Xext, XShmAttach,
 597                  HAVE_XSHM="yes", HAVE_XSHM="no",
 598                  $X_LIBS)
 599     if test "x$HAVE_XSHM" = "xyes"; then
 600       XSHM_LIBS="-lXext"
 601     else
 602       dnl On AIX, it is in XextSam instead, but we still need -lXext
 603       AC_CHECK_LIB(XextSam, XShmAttach,
 604                    HAVE_XSHM="yes", HAVE_XSHM="no",
 605                    $X_LIBS)
 606       if test "x$HAVE_XSHM" = "xyes"; then
 607         XSHM_LIBS="-lXext -lXextSam"
 608       fi
 609     fi
 610   fi
 611 ], ,[
 612   AC_SUBST(HAVE_XSHM)
 613   AC_SUBST(XSHM_LIBS)
 614 ])
 615
 616 dnl for V4L2, we also need to know if we have XVIDEO
 617 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 618 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 619                   [], [
 620   AG_GST_CHECK_XV
 621 ])
 622
 623 dnl *** ext plug-ins ***
 624 dnl keep this list sorted alphabetically !
 625
 626 if test "x$BUILD_EXTERNAL" = "xyes"; then
 627
 628 echo
 629 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 630 echo
 631
 632 dnl *** aalib ***
 633 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 634 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 635   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 636   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 637 ])
 638
 639 dnl *** annodex ***
 640 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 641 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 642   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 643 ])
 644
 645 dnl *** cairo ***
 646 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 647 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 648   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 649 ])
 650
 651 dnl *** cdio ***
 652 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 653 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 654   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.71)
 655 ])
 656
 657 dnl **** ESound ****
 658 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 659 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 660   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 661   if test $HAVE_ESD = no
 662   then
 663     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 664     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 665   fi
 666 ])
 667
 668 dnl *** FLAC ***
 669 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 670 AC_TRY_RUN([
 671 #include <FLAC/export.h>
 672 int main () { return FLAC_API_VERSION_CURRENT<8; }
 673 ],legacy_flac=no,legacy_flac=yes,legacy_flac=no)
 674
 675 if test "x$legacy_flac" = "xyes"; then
 676 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 677   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 678   dnl API change in FLAC 1.1.1, so require that...
 679   dnl (this check will also fail with FLAC 1.1.3 which changed API again)
 680   if test x$HAVE_FLAC = xyes; then
 681     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 682                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 683 #include <FLAC/seekable_stream_encoder.h>
 684                   ])
 685   fi
 686   AC_SUBST(FLAC_LIBS)
 687 ])
 688 else
 689 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 690   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 691   dnl API change in FLAC 1.1.3, so require that...
 692   if test x$HAVE_FLAC = xyes; then
 693     AC_CHECK_DECL(FLAC__STREAM_ENCODER_TELL_STATUS_ERROR,
 694                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 695 #include <FLAC/stream_encoder.h>
 696                   ])
 697   fi
 698   AC_SUBST(FLAC_LIBS)
 699 ])
 700 fi
 701
 702 dnl *** GConf ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 704 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 705   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 706 ])
 707
 708 dnl *** GDK pixbuf ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 710 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 711   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 712 ])
 713
 714 dnl *** HAL ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 716 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 717   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 718 ])
 719
 720 dnl *** jpeg ***
 721 dnl FIXME: we could use header checks here as well IMO
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 723 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 724   AC_ARG_WITH(jpeg-mmx,
 725     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 726   OLD_LIBS="$LIBS"
 727   if test x$with_jpeg_mmx != x; then
 728     LIBS="$LIBS -L$with_jpeg_mmx"
 729   fi
 730   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 731   JPEG_LIBS="$LIBS -ljpeg-mmx"
 732   LIBS="$OLD_LIBS"
 733   if test x$HAVE_JPEG != xyes; then
 734     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 735     JPEG_LIBS="-ljpeg"
 736   fi
 737   AC_SUBST(JPEG_LIBS)
 738 ])
 739
 740 dnl *** ladspa ***
 741 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 742 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 743   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 744 ], disabled)
 745
 746 dnl *** libcaca ***
 747 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 748 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 749   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 750   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 751   if test "x$HAVE_LIBCACA" != "xyes"; then
 752     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 753     dnl see if it compilation works too, might not if we are cross-compiling
 754     if test "x$HAVE_LIBCACA" = "xyes"; then
 755       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 756                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 757     fi
 758   fi
 759 ])
 760
 761 dnl *** libdv ***
 762 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 763 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 764   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 765 ])
 766
 767 dnl *** libpng ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 769 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 770   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 771 ])
 772
 773 dnl *** dv1394 ***
 774 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 775 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 776   dnl first test for libraw1394 >= 1.2.1
 777   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 778   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 779   dnl now see how far we got
 780   if test x$HAVE_RAW1394 = xyes && \
 781      test x$HAVE_LIBIEC61883 = xyes; then
 782        AG_GST_CHECK_LIBHEADER(AVC1394,
 783         avc1394, avc1394_send_command, $RAW1394_LIBS,
 784         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 785        AG_GST_CHECK_LIBHEADER(ROM1394,
 786         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 787         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 788        if test x$HAVE_AVC1394 = xyes && \
 789           test x$HAVE_AVC1394 = xyes && \
 790           test x$HAVE_ROM1394 = xyes; then
 791           HAVE_DV1394=yes
 792           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 793           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 794           AC_SUBST(DV1394_CFLAGS)
 795           AC_SUBST(DV1394_LIBS)
 796         fi
 797   else
 798        if test x$HAVE_RAW1394 = xno; then
 799           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 800           AG_GST_CHECK_LIBHEADER(AVC1394,
 801            avc1394, avc1394_send_command, $RAW1394_LIBS,
 802            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 803           AG_GST_CHECK_LIBHEADER(ROM1394,
 804            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 805            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 806           if test x$HAVE_RAW1394 = xyes && \
 807              test x$HAVE_AVC1394 = xyes && \
 808              test x$HAVE_ROM1394 = xyes; then
 809              HAVE_DV1394=yes
 810              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 811              DV1394_CFLAGS="$RAW1394_CFLAGS"
 812              if test x$HAVE_LIBIEC61883 = xyes; then
 813                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 814                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 815              fi
 816              AC_SUBST(DV1394_CFLAGS)
 817              AC_SUBST(DV1394_LIBS)
 818            fi
 819          fi
 820   fi
 821 ])
 822
 823 dnl *** shout2 ***
 824 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 825 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 826   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 827   if test $HAVE_SHOUT2 = no
 828   then
 829     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 830     AC_SUBST(SHOUT2_CFLAGS)
 831     AC_SUBST(SHOUT2_LIBS)
 832   fi
 833 ])
 834
 835 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 836 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 837 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 838 dnl   speex_jitter.h is 1.1.x only
 839 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 840 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 841   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 842   if test $HAVE_SPEEX = no
 843   then
 844     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 845       AC_CHECK_HEADER(speex/speex_jitter.h, [
 846         dnl speex 1.1.x :
 847         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 848           dnl speex 1.1.5 or + :
 849           HAVE_SPEEX="yes"
 850           SPEEX_LIBS="-lspeex"
 851           AC_SUBST(SPEEX_CFLAGS)
 852           AC_SUBST(SPEEX_LIBS)
 853         ],[
 854           HAVE_SPEEX="no"
 855         ])
 856       ],[
 857         dnl speex 1.0.x :
 858           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 859             dnl speex 1.0.4
 860             HAVE_SPEEX="yes"
 861             SPEEX_LIBS="-lspeex"
 862             AC_SUBST(SPEEX_CFLAGS)
 863             AC_SUBST(SPEEX_LIBS)
 864
 865             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 866               [defined if speex 1.0.x API detected])
 867         ],[
 868             HAVE_SPEEX="no"
 869             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 870         ], [
 871 #include <speex/speex.h>
 872         ])
 873       ])
 874     ])
 875   fi
 876 ])
 877
 878 dnl *** taglib ***
 879 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 880 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 881   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 882   if test "x$HAVE_CXX" != "xyes"; then
 883     USE_TAGLIB=false
 884     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 885   fi
 886 ])
 887
 888 dnl *** wavpack ***
 889 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 890 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 891   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 892     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 893       HAVE_WAVPACK=yes
 894       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 895     ],[
 896       HAVE_WAVPACK=no
 897       AC_MSG_RESULT(no)
 898     ])
 899   ])
 900   AC_SUBST(WAVPACK_CFLAGS)
 901   AC_SUBST(WAVPACK_LIBS)
 902 ])
 903
 904 dnl *** qtdemux & id3demux prefer to have zlib ***
 905 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 906 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux],, [
 907   AG_GST_CHECK_LIBHEADER(ZLIB,
 908     z, uncompress,, zlib.h, [
 909     HAVE_ZLIB="yes"
 910     ZLIB_LIBS="-lz"
 911     AC_SUBST(ZLIB_LIBS)
 912   ])
 913 ])
 914
 915 else
 916
 917 dnl not building plugins with external dependencies,
 918 dnl but we still need to set the conditionals
 919 AM_CONDITIONAL(USE_GCONFTOOL, false)
 920 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 921 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 922 AM_CONDITIONAL(USE_OSS, false)
 923 AM_CONDITIONAL(USE_SUNAUDIO, false)
 924 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 925 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 926 AM_CONDITIONAL(USE_X, false)
 927 AM_CONDITIONAL(USE_XSHM, false)
 928 AM_CONDITIONAL(USE_AALIB, false)
 929 AM_CONDITIONAL(USE_ANNODEX, false)
 930 AM_CONDITIONAL(USE_CAIRO, false)
 931 AM_CONDITIONAL(USE_CDIO, false)
 932 AM_CONDITIONAL(USE_ESD, false)
 933 AM_CONDITIONAL(USE_FLAC, false)
 934 AM_CONDITIONAL(USE_GCONF, false)
 935 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 936 AM_CONDITIONAL(USE_HAL, false)
 937 AM_CONDITIONAL(USE_JPEG, false)
 938 AM_CONDITIONAL(USE_LADSPA, false)
 939 AM_CONDITIONAL(USE_LIBCACA, false)
 940 AM_CONDITIONAL(USE_LIBDV, false)
 941 AM_CONDITIONAL(USE_LIBPNG, false)
 942 AM_CONDITIONAL(USE_DV1394, false)
 943 AM_CONDITIONAL(USE_SHOUT2, false)
 944 AM_CONDITIONAL(USE_SPEEX, false)
 945 AM_CONDITIONAL(USE_TAGLIB, false)
 946 AM_CONDITIONAL(USE_WAVPACK, false)
 947 AM_CONDITIONAL(USE_ZLIB, false)
 948
 949 fi dnl of EXT plugins
 950
 951 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 952
 953 dnl Overview:
 954 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 955 dnl GST_*:              flags shared by all built objects
 956 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 957 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 958 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 959 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 960
 961 dnl GST_OPTION_CFLAGS
 962 if test "x$USE_DEBUG" = xyes; then
 963    PROFILE_CFLAGS="-g"
 964 fi
 965 AC_SUBST(PROFILE_CFLAGS)
 966
 967 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 968 AC_SUBST(DEPRECATED_CFLAGS)
 969
 970 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 971 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 972 AC_SUBST(GST_OPTION_CFLAGS)
 973
 974 dnl our libraries need to be versioned correctly
 975 AC_SUBST(GST_LT_LDFLAGS)
 976
 977 dnl FIXME: do we want to rename to GST_ALL_* ?
 978 dnl prefer internal headers to already installed ones
 979 dnl also add builddir include for enumtypes and marshal
 980 dnl add ERROR_CFLAGS, but overridable
 981 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 982 AC_SUBST(GST_CFLAGS)
 983 AC_SUBST(GST_LIBS)
 984
 985 dnl LDFLAGS really should only contain flags, not libs - they get added before
 986 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 987 GST_ALL_LDFLAGS="-no-undefined"
 988 AC_SUBST(GST_ALL_LDFLAGS)
 989
 990 dnl this really should only contain flags, not libs - they get added before
 991 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 992 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 993 AC_SUBST(GST_PLUGIN_LDFLAGS)
 994
 995 dnl *** output files ***
 996
 997 dnl keep this alphabetic per directory, please
 998 AC_CONFIG_FILES(
 999 Makefile
1000 gst/Makefile
1001 gst/alpha/Makefile
1002 gst/apetag/Makefile
1003 gst/audiofx/Makefile
1004 gst/auparse/Makefile
1005 gst/autodetect/Makefile
1006 gst/avi/Makefile
1007 gst/cutter/Makefile
1008 gst/debug/Makefile
1009 gst/effectv/Makefile
1010 gst/id3demux/Makefile
1011 gst/icydemux/Makefile
1012 gst/goom/Makefile
1013 gst/law/Makefile
1014 gst/level/Makefile
1015 gst/matroska/Makefile
1016 gst/monoscope/Makefile
1017 gst/multipart/Makefile
1018 gst/qtdemux/Makefile
1019 gst/rtp/Makefile
1020 gst/rtsp/Makefile
1021 gst/smpte/Makefile
1022 gst/udp/Makefile
1023 gst/videobox/Makefile
1024 gst/videocrop/Makefile
1025 gst/videofilter/Makefile
1026 gst/videomixer/Makefile
1027 gst/wavenc/Makefile
1028 gst/wavparse/Makefile
1029 gst/flx/Makefile
1030 ext/jpeg/Makefile
1031 ext/Makefile
1032 ext/aalib/Makefile
1033 ext/annodex/Makefile
1034 ext/cairo/Makefile
1035 ext/cdio/Makefile
1036 ext/dv/Makefile
1037 ext/esd/Makefile
1038 ext/flac/Makefile
1039 ext/gconf/Makefile
1040 ext/gdk_pixbuf/Makefile
1041 ext/hal/Makefile
1042 ext/ladspa/Makefile
1043 ext/libcaca/Makefile
1044 ext/libpng/Makefile
1045 ext/raw1394/Makefile
1046 ext/shout2/Makefile
1047 ext/speex/Makefile
1048 ext/taglib/Makefile
1049 ext/wavpack/Makefile
1050 sys/Makefile
1051 sys/directdraw/Makefile
1052 sys/directsound/Makefile
1053 sys/oss/Makefile
1054 sys/sunaudio/Makefile
1055 sys/osxaudio/Makefile
1056 sys/osxvideo/Makefile
1057 sys/v4l2/Makefile
1058 sys/waveform/Makefile
1059 sys/ximage/Makefile
1060 po/Makefile.in
1061 tests/Makefile
1062 tests/check/Makefile
1063 tests/examples/Makefile
1064 tests/examples/level/Makefile
1065 tests/files/Makefile
1066 tests/icles/Makefile
1067 gconf/Makefile
1068 gconf/gstreamer.schemas
1069 common/Makefile
1070 common/m4/Makefile
1071 m4/Makefile
1072 docs/Makefile
1073 docs/plugins/Makefile
1074 docs/version.entities
1075 win32/common/config.h
1076 pkgconfig/Makefile
1077 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1078 gst-plugins-good.spec
1079 )
1080 AC_OUTPUT
1081
1082 AG_GST_OUTPUT_PLUGINS