configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/librygel-core/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1 tar-ustar no-dist-gzip dist-xz -Wno-portability])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 AC_SYS_LARGEFILE
  31
  32 dnl Required versions of library packages
  33 dnl Not all of these are actually used, depending on the configure options.
  34 GLIB_REQUIRED=2.34.0
  35 LIBXML_REQUIRED=2.7
  36 VALA_REQUIRED=0.22.0
  37 VALADOC_REQUIRED=0.2
  38 GSSDP_REQUIRED=0.13.0
  39 GUPNP_REQUIRED=0.19.0
  40 GUPNP_AV_REQUIRED=0.12.4
  41 GUPNP_DLNA_REQUIRED=0.9.4
  42 GSTREAMER_REQUIRED=1.0
  43 GSTPBU_REQUIRED=1.0
  44 GIO_REQUIRED=2.26
  45 GEE_REQUIRED=0.8.0
  46 UUID_REQUIRED=1.41.3
  47 LIBSOUP_REQUIRED=2.42.0
  48 GTK_REQUIRED=3.0
  49
  50 dnl Additional requirements for media-export plugin
  51 GSTREAMER_TAG_REQUIRED=1.0
  52 GSTREAMER_APP_REQUIRED=1.0
  53 LIBSQLITE3_REQUIRED=3.5
  54
  55 dnl Additional requirements for tracker plugin
  56 TRACKER_SPARQL_REQUIRED_MIN=0.14.0
  57
  58 VALAFLAGS="--target-glib=2.32 $VALAFLAGS"
  59
  60 RYGEL_BASE_MODULES="gupnp-1.0 >= $GUPNP_REQUIRED gee-0.8 >= $GEE_REQUIRED"
  61 PKG_CHECK_MODULES([LIBRYGEL_CORE_DEPS], [$RYGEL_BASE_MODULES uuid >= $UUID_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gio-2.0 >= $GIO_REQUIRED gmodule-2.0 libxml-2.0 >= $LIBXML_REQUIRED])
  62 RYGEL_BASE_MODULES_VALAFLAGS='--pkg gupnp-1.0 --pkg gee-0.8'
  63 LIBRYGEL_CORE_DEPS_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gssdp-1.0 --pkg gio-2.0 --pkg gmodule-2.0 --pkg posix"
  64 AC_SUBST([LIBRYGEL_CORE_DEPS_VALAFLAGS])
  65
  66 RYGEL_COMMON_MODULES="$RYGEL_BASE_MODULES gupnp-av-1.0 >= $GUPNP_AV_REQUIRED"
  67 PKG_CHECK_MODULES([LIBRYGEL_SERVER_DEPS], [$RYGEL_COMMON_MODULES uuid >= $UUID_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gio-2.0 >= $GIO_REQUIRED gmodule-2.0 libxml-2.0 >= $LIBXML_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
  68 RYGEL_COMMON_MODULES_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gupnp-av-1.0"
  69 LIBRYGEL_SERVER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gssdp-1.0 --pkg gio-2.0 --pkg libsoup-2.4 --pkg gmodule-2.0"
  70 AC_SUBST([LIBRYGEL_SERVER_DEPS_VALAFLAGS])
  71
  72 PKG_CHECK_MODULES([LIBRYGEL_RENDERER_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
  73 LIBRYGEL_RENDERER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg libsoup-2.4"
  74 AC_SUBST([LIBRYGEL_RENDERER_DEPS_VALAFLAGS])
  75
  76 PKG_CHECK_MODULES([RYGEL_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED])
  77
  78 # Not all tests use all of these dependencies,
  79 # but having one set of dependencies keeps things simple.
  80 PKG_CHECK_MODULES([TEST_DEPS], [$RYGEL_COMMON_MODULES uuid >= $UUID_REQUIRED gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED])
  81 TEST_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg gssdp-1.0 --pkg libsoup-2.4 --pkg libxml-2.0 --pkg gmodule-2.0"
  82 AC_SUBST([TEST_DEPS_VALAFLAGS])
  83
  84 PKG_CHECK_MODULES([EXAMPLE_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED])
  85
  86
  87
  88 dnl Media engine to use
  89 BUILT_ENGINES="librygel-media-engine-simple"
  90
  91 dnl Disabling the gstreamer media_engine also disables
  92 dnl anything else that uses gstreamer.
  93 AC_ARG_WITH([media_engine],
  94             AS_HELP_STRING(
  95                 [--with-media-engine=@<:@gstreamer|simple@:>@],
  96                 [Media Engine to use]),
  97             [with_media_engine="$withval"],
  98             [with_media_engine="gstreamer"])
  99
 100 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 101       [
 102         enable_gstreamer="yes"
 103         BUILT_ENGINES="$BUILT_ENGINES;librygel-media-engine-gst"
 104
 105         PKG_CHECK_MODULES([RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS],
 106                           [$RYGEL_COMMON_MODULES
 107                            gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED
 108                            gstreamer-app-1.0 >= $GSTREAMER_APP_REQUIRED
 109                            gupnp-dlna-2.0 >= $GUPNP_DLNA_REQUIRED
 110                            gio-2.0 >= $GIO_REQUIRED])
 111         RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-base-1.0 --pkg gstreamer-pbutils-1.0 --pkg gupnp-dlna-2.0"
 112         AC_SUBST([RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS_VALAFLAGS])
 113
 114         PKG_CHECK_MODULES([LIBRYGEL_RENDERER_GST_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_REQUIRED gio-2.0 >= $GIO_REQUIRED])
 115         LIBRYGEL_RENDERER_GST_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-1.0"
 116         AC_SUBST([LIBRYGEL_RENDERER_GST_DEPS_VALAFLAGS])
 117       ],
 118       [enable_gstreamer="no"])
 119 AM_CONDITIONAL([HAVE_GSTREAMER],[test "x$enable_gstreamer" = "xyes"])
 120 AC_SUBST([BUILT_ENGINES])
 121
 122 dnl Add plugins
 123 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
 124 AS_IF([test "x$enable_external_plugin" = "xyes"],
 125   [
 126     PKG_CHECK_MODULES([RYGEL_PLUGIN_EXTERNAL_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 127   ])
 128
 129 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
 130 AS_IF([test "x$enable_mpris_plugin" = "xyes"],
 131   [
 132     PKG_CHECK_MODULES([RYGEL_PLUGIN_MPRIS_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 133   ])
 134
 135 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
 136 AS_IF([test "x$enable_mediathek_plugin" = "xyes"],
 137   [
 138     PKG_CHECK_MODULES([RYGEL_PLUGIN_MEDIATHEK_DEPS],
 139                       [$RYGEL_COMMON_MODULES
 140                        gio-2.0 >= $GIO_REQUIRED
 141                        libsoup-2.4 >= $LIBSOUP_REQUIRED
 142                        libxml-2.0 >= $LIBXML_REQUIRED])
 143   ])
 144
 145
 146 RYGEL_ADD_PLUGIN([lms],[LightMediaScanner],[yes])
 147 AS_IF([test "x$enable_lms_plugin" = "xyes"],
 148   [
 149     PKG_CHECK_MODULES([RYGEL_PLUGIN_LMS_DEPS],
 150                       [$RYGEL_COMMON_MODULES
 151                        gio-2.0 >= $GIO_REQUIRED
 152                        sqlite3 >= $LIBSQLITE3_REQUIRED])
 153     RYGEL_PLUGIN_LMS_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg gee-0.8 --pkg sqlite3"
 154     AC_SUBST([RYGEL_PLUGIN_LMS_DEPS_VALAFLAGS])
 155   ])
 156
 157 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 158       [
 159         RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
 160         AS_IF([test "x$enable_playbin_plugin" = "xyes"],
 161           [
 162             PKG_CHECK_MODULES([RYGEL_PLUGIN_PLAYBIN_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_TAG_REQUIRED])
 163           ])
 164
 165         RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
 166         AS_IF([test "x$enable_media_export_plugin" = "xyes"],
 167           [
 168             PKG_CHECK_MODULES([RYGEL_PLUGIN_MEDIA_EXPORT_DEPS],
 169                               [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED
 170                                gupnp-dlna-2.0 >= $GUPNP_DLNA_REQUIRED
 171                                gupnp-dlna-gst-2.0 >= $GUPNP_DLNA_REQUIRED
 172                                gstreamer-app-1.0 >= $GSTREAMER_APP_REQUIRED
 173                                gstreamer-tag-1.0 >= $GSTREAMER_TAG_REQUIRED
 174                                gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED
 175                                libsoup-2.4 >= $LIBSOUP_REQUIRED
 176                                sqlite3 >= $LIBSQLITE3_REQUIRED
 177                                uuid])
 178             RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gupnp-dlna-2.0 --pkg gupnp-dlna-gst-2.0 --pkg gstreamer-tag-1.0 --pkg gstreamer-app-1.0 --pkg gstreamer-pbutils-1.0 --pkg sqlite3"
 179             AC_SUBST([RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_VALAFLAGS])
 180           ])
 181
 182         RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
 183         AS_IF([test "x$enable_gst_launch_plugin" = "xyes"],
 184           [
 185             PKG_CHECK_MODULES([RYGEL_PLUGIN_GST_LAUNCH_DEPS], [$RYGEL_COMMON_MODULES])
 186             RYGEL_PLUGIN_GST_LAUNCH_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS"
 187             AC_SUBST([RYGEL_PLUGIN_GST_LAUNCH_DEPS_VALAFLAGS])
 188           ])
 189
 190         RYGEL_ADD_STAMP([src/media-engines/gstreamer/librygel_media_engine_gst_la_vala.stamp])
 191         RYGEL_ADD_STAMP([src/librygel-renderer-gst/librygel_renderer_gst_2_2_la_vala.stamp])
 192       ],
 193       [
 194         RYGEL_DISABLE_PLUGIN([playbin])
 195         RYGEL_DISABLE_PLUGIN([media-export])
 196         RYGEL_DISABLE_PLUGIN([gst-launch])
 197       ])
 198
 199 dnl Example plugins:
 200 AC_ARG_ENABLE([example-plugins],
 201               AS_HELP_STRING([--enable-example-plugins],[enable example plugins]),,
 202               enable_example_plugins=no)
 203 AM_CONDITIONAL([BUILD_EXAMPLE_PLUGINS], [test "x$[]enable_example_plugins" = "xyes"])
 204
 205 dnl Explicitly add stamp files for targets that are not plugins
 206 RYGEL_ADD_STAMP([src/librygel-core/librygel_core_2_2_la_vala.stamp])
 207 RYGEL_ADD_STAMP([src/librygel-server/librygel_server_2_2_la_vala.stamp])
 208 RYGEL_ADD_STAMP([src/librygel-renderer/librygel_renderer_2_2_la_vala.stamp])
 209 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
 210 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
 211 RYGEL_ADD_STAMP([src/media-engines/simple/librygel_media_engine_simple_la_vala.stamp])
 212
 213 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 214       [
 215         RYGEL_CHECK_PACKAGES([gupnp-dlna-2.0 gstreamer-1.0
 216                               gstreamer-pbutils-1.0])
 217       ])
 218
 219 dnl Debugging
 220 AC_ARG_ENABLE(debug,
 221         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 222         enable_debug=no)
 223 if test "x$enable_debug" = "xyes"; then
 224         CFLAGS="$CFLAGS -O0 -g"
 225         RYGEL_DEBUG_VALAFLAGS="-g"
 226 fi
 227
 228 AC_SUBST(RYGEL_DEBUG_VALAFLAGS)
 229
 230 dnl Strict compiler
 231 AC_ARG_ENABLE(strict-cc,
 232         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 233         enable_strict_cc=no)
 234 if test "x$enable_strict_cc" = "xyes"; then
 235         CFLAGS="$CFLAGS -Wall -Werror"
 236 else
 237         CFLAGS="$CFLAGS -w"
 238 fi
 239
 240 dnl Run uninstalled
 241 AC_ARG_ENABLE(uninstalled,
 242     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 243         enable_uninstalled=no)
 244 if test "x$enable_uninstalled" = "xyes"; then
 245         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 246 fi
 247 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 248
 249 dnl Check wether user wants to build UIs
 250 AC_ARG_WITH( ui,
 251   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 252   try_ui=$withval, try_ui=yes )
 253
 254 HAVE_GTK=no
 255 if test x$try_ui = xyes ; then
 256     dnl check for gtk
 257     PKG_CHECK_MODULES([RYGEL_UI_DEPS], [$RYGEL_BASE_MODULES gtk+-3.0 >= $GTK_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gee-0.8 >= $GEE_REQUIRED],
 258       [
 259         RYGEL_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 260         RYGEL_UI_DEPS_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gtk+-3.0 --pkg gssdp-1.0 --pkg gee-0.8"
 261         AC_SUBST([RYGEL_UI_DEPS_VALAFLAGS])
 262
 263         PKG_CHECK_MODULES([EXAMPLE_UI_DEPS],
 264                           [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED
 265                            gssdp-1.0 >= $GSSDP_REQUIRED
 266                            gstreamer-video-1.0 >= $GSTREAMER_REQUIRED
 267                            gtk+-3.0 >= $GTK_REQUIRED])
 268       ],
 269       [
 270         AC_MSG_WARN([UI dependencies not found.])
 271         AC_MSG_WARN([UI applications will not be built.])
 272       ])
 273
 274 else
 275     AC_MSG_NOTICE([UI applications disabled.])
 276 fi
 277
 278 AM_CONDITIONAL(BUILD_UI, test "x$HAVE_GTK" = "xyes")
 279
 280 dnl Tests
 281 AC_ARG_ENABLE([tests],
 282               AS_HELP_STRING([--enable-tests],[always build tests]),,
 283               enable_tests=no)
 284 AM_CONDITIONAL([ALWAYS_TEST], [test "x$enable_tests" = "xyes"])
 285
 286 dnl Generate coverage data
 287 AC_ARG_ENABLE([coverage],
 288   AS_HELP_STRING([--enable-coverage],
 289                  [Generate converage reports for unit tests]),
 290   [],
 291   [enable_coverage=no])
 292 AM_CONDITIONAL([ENABLE_COVERAGE],[test "x$enable_coverage" != "xno"])
 293 AS_IF([test "x$enable_coverage" != "xno"],
 294   [
 295     AC_PATH_PROG([LCOV], [lcov])
 296     AC_PATH_PROG([GENHTML], [genhtml])
 297     AC_SUBST([COVERAGE_LIBS],["-lgcov"])
 298     AC_SUBST([COVERAGE_CFLAGS],["-fprofile-arcs -ftest-coverage"])
 299     AC_SUBST(COVERAGE_VALAFLAGS,["-g"])
 300   ]
 301 )
 302
 303 dnl Check additional requirements for MediaExport plugins
 304 if test "x$enable_media_export_plugin" = "xyes";
 305 then
 306     RYGEL_CHECK_PACKAGES([sqlite3 gstreamer-tag-1.0 gstreamer-app-1.0])
 307     AC_CHECK_HEADER([unistr.h],
 308                     AC_CHECK_LIB([unistring],
 309                                  [u8_strcoll],
 310                                  [have_unistring=yes],[have_unistring=no]))
 311     if test "x$have_unistring" = "xyes"; then
 312         AC_DEFINE([HAVE_UNISTRING],[1],[Use libunistring for collation])
 313         RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_LIBS="$RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_LIBS -lunistring"
 314     fi
 315 fi
 316
 317 dnl Check additional requirements for LMS plugin
 318 if test "x$enable_lms_plugin" = "xyes";
 319 then
 320     RYGEL_CHECK_PACKAGES([sqlite3])
 321 fi
 322
 323 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
 324 AS_IF([test "x$enable_tracker_plugin" = "xyes"],
 325   [
 326     PKG_CHECK_MODULES([RYGEL_PLUGIN_TRACKER_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 327
 328     tracker_api_version="0.14"
 329     PKG_CHECK_MODULES(TRACKER_SPARQL,
 330                       tracker-sparql-0.14 >= $TRACKER_SPARQL_REQUIRED_MIN,
 331                       [tracker_api_version="0.14"],
 332                       [tracker_api_version=""])
 333     AS_IF([test "x$[]tracker_api_version" = "x"],
 334           [
 335             PKG_CHECK_MODULES(TRACKER_SPARQL,
 336                               tracker-sparql-0.15 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 337                               [tracker_api_version="0.15"],
 338                               [tracker_api_version=""])
 339           ])
 340     AS_IF([test "x$[]tracker_api_version" = "x"],
 341           [
 342             PKG_CHECK_MODULES(TRACKER_SPARQL,
 343                               tracker-sparql-0.16 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 344                               [tracker_api_version="0.16"],
 345                               [tracker_api_version=""])
 346           ])
 347     AS_IF([test "x$[]tracker_api_version" = "x"],
 348           [
 349             PKG_CHECK_MODULES(TRACKER_SPARQL,
 350                               tracker-sparql-0.18 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 351                               [tracker_api_version="0.18"],
 352                               [tracker_api_version=""])
 353           ])
 354      AS_IF([test "x$[]tracker_api_version" = "x"],
 355           [
 356             PKG_CHECK_MODULES(TRACKER_SPARQL,
 357                               tracker-sparql-1.0 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 358                               [tracker_api_version="1.0"],
 359                               [])
 360           ])
 361     AS_IF([test "x$enable_vala" = "xyes"],
 362           [VALA_CHECK_PACKAGES([tracker-sparql-$tracker_api_version])])
 363
 364     RYGEL_PLUGIN_TRACKER_DEPS_VALAFLAGS="--pkg tracker-sparql-$tracker_api_version"
 365     AC_SUBST([RYGEL_PLUGIN_TRACKER_DEPS_VALAFLAGS])
 366   ])
 367
 368 # This should be called only after all RYGEL_CHECK_VALA() and RYGEL_ADD_PLUGIN() calls:
 369 RYGEL_CHECK_VALA([$VALA_REQUIRED],
 370                  [gupnp-1.0
 371                   gupnp-av-1.0
 372                   gio-2.0
 373                   gee-0.8
 374                   posix])
 375
 376 dnl Gettext
 377 GETTEXT_PACKAGE=rygel
 378 AC_SUBST(GETTEXT_PACKAGE)
 379 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 380   [Define the gettext package to be used])
 381
 382 AM_GLIB_GNU_GETTEXT
 383 IT_PROG_INTLTOOL([0.40.0])
 384
 385 dnl Shave the output
 386 AM_SILENT_RULES([yes])
 387
 388 dnl documenation
 389 AC_PATH_PROG([XSLTPROC], [xsltproc])
 390 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 391
 392 dnl Use valadoc and gtk-doc for API documentation:
 393 dnl This is on by default when using autogen.sh
 394 dnl (so it is not on by default when building from a tarball with configure.)
 395 AC_ARG_ENABLE(apidocs,
 396               AS_HELP_STRING([--enable-apidocs[=@<:@no/auto/yes@:>@]],
 397                              [Create API documentation using valadoc and GTK-Doc]),,
 398     [enable_apidocs=auto])
 399
 400 found_valadoc=no
 401 AS_IF([test "x$enable_apidocs" != "xno"], [
 402     AC_PATH_PROG(VALADOC, valadoc, :)
 403     AS_IF([test -x "$VALADOC"], [
 404       found_valadoc=yes
 405       AC_SUBST(VALADOC)
 406       PKG_CHECK_MODULES([GTKDOC],[gtk-doc >= 1.0],,
 407                         AS_IF([test "x$enable_apidocs" == "xyes"],
 408                               [AC_MSG_ERROR([Unable to find gtk-doc])],
 409                               [found_valadoc=no])
 410                         )
 411     ], [
 412       AS_IF([test "x$enable_apidocs" == "xyes"], AC_MSG_ERROR([Unable to find valadoc]))
 413     ])
 414   ])
 415
 416 AM_CONDITIONAL(ENABLE_VALADOC, test x$found_valadoc = xyes)
 417
 418 AC_SUBST([RYGEL_PLUGIN_LINKER_FLAGS],
 419          ["-module -avoid-version -Wl,-z,defs"])
 420 AC_SUBST([RYGEL_PLUGIN_DIR],
 421          [${libdir}/rygel-2.2/plugins])
 422 AC_SUBST([RYGEL_MEDIA_ENGINE_DIR],
 423          [${libdir}/rygel-2.2/engines])
 424
 425 AC_CONFIG_FILES([
 426 Makefile
 427 src/Makefile
 428 src/librygel-core/Makefile
 429 src/librygel-renderer/Makefile
 430 src/librygel-renderer-gst/Makefile
 431 src/librygel-server/Makefile
 432 src/rygel/Makefile
 433 src/ui/Makefile
 434 src/media-engines/Makefile
 435 src/media-engines/gstreamer/Makefile
 436 src/media-engines/gstreamer/media-engine-gst.plugin
 437 src/media-engines/simple/Makefile
 438 src/media-engines/simple/media-engine-simple.plugin
 439 src/plugins/Makefile
 440 data/Makefile
 441 data/xml/Makefile
 442 data/xml/MediaServer3.xml.in
 443 data/xml/MediaRenderer2.xml.in
 444 data/icons/Makefile
 445 data/icons/32x32/Makefile
 446 data/icons/48x48/Makefile
 447 data/icons/120x120/Makefile
 448 data/icons/128x128/Makefile
 449 data/icons/scalable/Makefile
 450 data/rygel.desktop.in
 451 data/rygel-preferences.desktop.in
 452 doc/Makefile
 453 doc/reference/Makefile
 454 doc/reference/librygel-core/Makefile
 455 doc/reference/librygel-renderer/Makefile
 456 doc/reference/librygel-server/Makefile
 457 doc/reference/librygel-renderer-gst/Makefile
 458 po/Makefile.in
 459 rygel-core-2.2.pc
 460 rygel-renderer-2.2.pc
 461 rygel-server-2.2.pc
 462 rygel-renderer-gst-2.2.pc
 463 tests/Makefile
 464 examples/Makefile
 465 examples/renderer-plugins/Makefile
 466 examples/renderer-plugins/vala/Makefile
 467 examples/renderer-plugins/vala/example-renderer-vala.plugin
 468 examples/renderer-plugins/C/Makefile
 469 examples/renderer-plugins/C/example-renderer-c.plugin
 470 examples/server-plugins/Makefile
 471 examples/server-plugins/vala/Makefile
 472 examples/server-plugins/vala/example-server-vala.plugin
 473 examples/server-plugins/C/Makefile
 474 examples/server-plugins/C/example-server-c.plugin
 475 ])
 476 AC_OUTPUT
 477
 478 echo "
 479
 480                     ${PACKAGE} ${VERSION}
 481                     ============
 482
 483
 484         Prefix:                 ${prefix}
 485         Source code location:   ${srcdir}
 486         Compiler:               ${CC}
 487         CFLAGS:                 ${CFLAGS}
 488         VALAFLAGS:              ${VALAFLAGS}
 489         uninstalled:            ${enable_uninstalled}
 490         preferences ui:         ${HAVE_GTK}
 491         Media Engine:           ${with_media_engine}
 492         API documentation:      ${found_valadoc}
 493     Plugins:
 494         examples:               ${enable_example_plugins}
 495         tracker:                ${enable_tracker_plugin}
 496             version:            ${tracker_api_version}
 497         mediathek:              ${enable_mediathek_plugin}
 498         media-export            ${enable_media_export_plugin}
 499         lightmediascanner       ${enable_lms_plugin}
 500         external:               ${enable_external_plugin}
 501         MPRIS2:                 ${enable_mpris_plugin}
 502         gst-launch:             ${enable_gst_launch_plugin}
 503         playbin:                ${enable_playbin_plugin}
 504 "