configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.23.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake
  12 AM_INIT_AUTOMAKE
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_CVS="no", GST_CVS="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 20, 0, 20)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** autotools stuff ****
  57
  58 dnl allow for different autotools
  59 AS_AUTOTOOLS_ALTERNATE
  60
  61 dnl Add parameters for aclocal
  62 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  63
  64 dnl set up gettext
  65 dnl the version check needs to stay here because autopoint greps for it
  66 AM_GNU_GETTEXT_VERSION([0.17])
  67 AM_GNU_GETTEXT([external])
  68 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  69
  70 dnl *** check for arguments to configure ***
  71
  72 dnl subsystems - can influence other decisions so needs to be high up
  73 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  74 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  75 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  76 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  77 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  78 dnl define a substitution to use in docs/gst/gstreamer.types
  79 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  80 then
  81   GST_LOADSAVE_DOC_TYPES="%"
  82 else
  83   GST_LOADSAVE_DOC_TYPES=
  84 fi
  85 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  86 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  87 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  88 if test "x$GST_DISABLE_PARSE" = xyes; then
  89   AC_DEFINE(GST_DISABLE_PARSE, 1,
  90     [Define if pipeline parsing code is disabled])
  91 fi
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  93 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  94 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  95   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  96     [Define if option parsing is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  99 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 100 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 101 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 103 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 104 dnl define a substitution to use in docs/gst/gstreamer.types
 105 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 106 then
 107   GST_REGISTRY_DOC_TYPES="%"
 108 else
 109   GST_REGISTRY_DOC_TYPES=
 110 fi
 111 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 112 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 113 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 115 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 116
 117 AG_GST_ARG_DEBUG
 118 AG_GST_ARG_PROFILING
 119 AG_GST_ARG_VALGRIND
 120 AG_GST_ARG_GCOV
 121
 122 AG_GST_ARG_EXAMPLES
 123
 124 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 125 AG_GST_ARG_WITH_PACKAGE_NAME
 126 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 127
 128 dnl building of tests
 129 AC_ARG_ENABLE(tests,
 130   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 131   [
 132     case "${enableval}" in
 133       yes) BUILD_TESTS=yes ;;
 134       no)  BUILD_TESTS=no ;;
 135       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 136     esac
 137   ],
 138 [BUILD_TESTS=yes]) dnl Default value
 139 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 140
 141 dnl tests known to fail
 142 AC_ARG_ENABLE(failing-tests,
 143   AC_HELP_STRING([--disable-failing-tests],
 144     [disable building tests known to fail]),
 145   [
 146     case "${enableval}" in
 147       yes) BUILD_FAILING_TESTS=yes ;;
 148       no)  BUILD_FAILING_TESTS=no ;;
 149       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 150     esac
 151   ],
 152   [BUILD_FAILING_TESTS=no]) dnl Default value
 153 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 154 if test x$BUILD_FAILING_TESTS = xyes; then
 155   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 156 else
 157   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 158 fi
 159
 160 dnl poison destroyed objects
 161 AC_ARG_ENABLE(poisoning,
 162   AC_HELP_STRING([--enable-poisoning],
 163     [enable poisoning of deallocated objects]),
 164   [
 165     case "${enableval}" in
 166       yes) USE_POISONING=yes ;;
 167       no)  USE_POISONING=no ;;
 168       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 169     esac
 170   ],
 171   [USE_POISONING=no]) dnl Default value
 172 if test "x$USE_POISONING" = xyes; then
 173   AC_DEFINE(USE_POISONING, 1,
 174     [Define if we should poison deallocated memory])
 175 fi
 176
 177 dnl Use binary registry
 178 AC_ARG_ENABLE(binary-registry,
 179   AC_HELP_STRING([--disable-binary-registry],
 180     [disable binary registry]),
 181   [
 182     case "${enableval}" in
 183       yes) USE_BINARY_REGISTRY=yes ;;
 184       no)  USE_BINARY_REGISTRY=no ;;
 185       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-binary-registry) ;;
 186     esac
 187   ],
 188   [USE_BINARY_REGISTRY=yes]) dnl Default value
 189
 190 if test "x$USE_BINARY_REGISTRY" = xyes; then
 191   dnl for config.h:
 192   AC_DEFINE(USE_BINARY_REGISTRY, 1,
 193     [Define if we should use binary registry instead xml registry])
 194 fi
 195 AM_CONDITIONAL(USE_BINARY_REGISTRY, test "x$USE_BINARY_REGISTRY" = "xyes")
 196
 197 dnl *** checks for platform ***
 198
 199 dnl * hardware/architecture *
 200
 201 dnl common/m4/gst-arch.m4
 202 dnl check CPU type
 203 AG_GST_ARCH
 204 dnl substitution for win32/common/config.h
 205 HOST_CPU=$host_cpu
 206 AC_SUBST(HOST_CPU)
 207
 208 dnl common/m4/gst-arch.m4
 209 dnl check for unaligned access
 210 AG_GST_UNALIGNED_ACCESS
 211 dnl create a configure variable for gst/gstconfig.h
 212 if test x${as_cv_unaligned_access} = xyes ; then
 213   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 214 else
 215   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 216 fi
 217 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 218
 219 dnl check for platform specific settings
 220 case $host_os in
 221      rhapsody*)
 222         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 223         ;;
 224      darwin*)
 225         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 226         AC_DEFINE_UNQUOTED(GST_HAVE_UNSAFE_FORK, 1, [Defined when registry scanning through fork is unsafe])
 227         ;;
 228      cygwin*)
 229         AC_DEFINE_UNQUOTED(GST_HAVE_UNSAFE_FORK, 1, [Defined when registry scanning through fork is unsafe])
 230         ;;
 231      mingw* | msvc* | mks*)
 232         dnl HAVE_WIN32 currently means "disable POSIXisms".
 233         AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 234
 235         dnl define __MSVCRT_VERSION__ version if not set already by the
 236         dnl compiler (ie. mostly for mingw). This is needed for things like
 237         dnl __stat64 to be available. If set by the compiler, ensure it's
 238         dnl new enough - we need at least WinXP SP2.
 239         AC_TRY_COMPILE([ ], [ return __MSVCRT_VERSION__; ], [
 240             AC_TRY_COMPILE([ ], [
 241               #if __MSVCRT_VERSION__ < 0x0601
 242               #error "MSVCRT too old"
 243               #endif
 244             ], [
 245               AC_MSG_NOTICE([MSVCRT version looks ok])
 246             ], [
 247               AC_MSG_ERROR([MSVCRT version too old, need at least WinXP SP2])
 248             ])
 249         ], [
 250           AC_MSG_NOTICE([Setting MSVCRT version to 0x0601])
 251           AC_DEFINE_UNQUOTED(__MSVCRT_VERSION__, 0x0601, [We need at least WinXP SP2 for __stat64])
 252         ])
 253         ;;
 254      *)
 255         ;;
 256 esac
 257
 258 dnl * software *
 259
 260 dnl check for large file support
 261 dnl affected plugins must include config.h
 262 AC_SYS_LARGEFILE
 263
 264 dnl *** checks for programs ***
 265
 266 dnl find a compiler
 267 AC_PROG_CC
 268
 269 dnl check if the compiler supports '-c' and '-o' options
 270 AM_PROG_CC_C_O
 271
 272 dnl find an assembler
 273 AM_PROG_AS
 274
 275 dnl Perl is used in building documentation and in the version checks
 276 AC_PATH_PROG(PERL_PATH, perl, no)
 277 if test x$PERL_PATH = xno; then
 278   AC_MSG_ERROR(Could not find perl)
 279 fi
 280
 281 dnl we require flex and bison for building the parser
 282 if test "x$GST_DISABLE_PARSE" != xyes; then
 283   AG_GST_BISON_CHECK
 284   AG_GST_FLEX_CHECK
 285 fi
 286
 287 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 288 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 289
 290 dnl check for documentation tools
 291 AG_GST_DOCBOOK_CHECK
 292 GTK_DOC_CHECK([1.3])
 293 AS_PATH_PYTHON([2.1])
 294 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 295
 296 dnl *** checks for libraries ***
 297
 298 dnl check for libm, for sin()
 299 AC_CHECK_LIBM
 300 AC_SUBST(LIBM)
 301
 302 dnl *** checks for header files ***
 303
 304 dnl check if we have ANSI C header files
 305 AC_HEADER_STDC
 306
 307 dnl Check for ucontext.h
 308 AC_CHECK_HEADERS([ucontext.h])
 309
 310 dnl Check for sys/socket.h
 311 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 312 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 313
 314 dnl check for sys/times.h for tests/examples/adapter/
 315 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 316 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 317 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 318
 319 dnl Check for process.h for getpid() on win32
 320 AC_CHECK_HEADERS([process.h])
 321
 322 dnl Check for sys/utsname.h for uname
 323 AC_CHECK_HEADERS([sys/utsname.h])
 324
 325 dnl Check for stdio_ext.f for __fbufsize
 326 AC_CHECK_HEADERS([stdio_ext.h])
 327
 328 dnl Check for valgrind.h
 329 dnl separate from HAVE_VALGRIND because you can have the program, but not
 330 dnl the dev package
 331 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 332
 333 dnl used in gst/gstpoll.c
 334 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 335 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 336 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 337   WIN32_LIBS="-lws2_32"
 338   AC_SUBST(WIN32_LIBS)
 339 fi
 340
 341 dnl *** checks for types/defines ***
 342
 343 dnl *** checks for structures ***
 344
 345 dnl *** checks for compiler characteristics ***
 346
 347 dnl make sure we can use "inline" from C code
 348 AC_C_INLINE
 349
 350 OPT_CFLAGS=
 351 dnl Check for some compiler flags that optimize our code.
 352 if test "x$GCC" = xyes; then
 353   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 354 fi
 355
 356 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 357 dnl flag
 358 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 359 dnl symbolic register names in inline asm
 360 if test x$HAVE_CPU_PPC = xyes ; then
 361   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 362     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 363 fi
 364
 365 dnl *** checks for library functions ***
 366
 367 AC_CHECK_FUNCS([sigaction])
 368
 369 dnl we use fork in the registry code
 370 AC_CHECK_FUNCS([fork])
 371
 372 dnl check for fseeko()
 373 AC_FUNC_FSEEKO
 374 dnl check for ftello()
 375 AC_CHECK_FUNCS([ftello])
 376
 377 AC_CHECK_FUNCS([fgetpos])
 378 AC_CHECK_FUNCS([fsetpos])
 379
 380 dnl check for poll(), ppoll() and pselect()
 381 AC_CHECK_FUNCS([poll])
 382 AC_CHECK_FUNCS([ppoll])
 383 AC_CHECK_FUNCS([pselect])
 384
 385 dnl check for mmap()
 386 AC_FUNC_MMAP
 387 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 388
 389 dnl Check for POSIX timers
 390 AC_CHECK_FUNCS(clock_gettime, [], [
 391   AC_CHECK_LIB(rt, clock_gettime, [
 392     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 393     LIBS="$LIBS -lrt"
 394   ])
 395 ])
 396
 397 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 398     AC_TRY_COMPILE([
 399 #include <time.h>
 400 #ifdef HAVE_UNISTD_H
 401 #include <unistd.h>
 402 #endif
 403     ], [
 404 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 405 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 406 #endif
 407       return 0;
 408     ], [
 409       gst_cv_posix_timers=yes
 410     ], [
 411       gst_cv_posix_timers=no
 412     ])
 413 )
 414
 415 if test "$gst_cv_posix_timers" = "yes"; then
 416   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 417   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 418 else
 419   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 420 fi
 421 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 422 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 423
 424 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 425     AC_TRY_COMPILE([
 426 #include <time.h>
 427 #ifdef HAVE_UNISTD_H
 428 #include <unistd.h>
 429 #endif
 430     ], [
 431 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 432 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 433 #endif
 434       return 0;
 435     ], [
 436       gst_cv_monotonic_clock=yes
 437     ], [
 438       gst_cv_monotonic_clock=no
 439     ])
 440 )
 441
 442 if test "$gst_cv_monotonic_clock" = "yes"; then
 443   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 444   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 445 else
 446   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 447 fi
 448 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 449 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 450
 451 dnl Check for a way to display the function name in debug output
 452 AG_GST_CHECK_FUNCTION
 453
 454 dnl test for register_printf_specifier or register_printf_function
 455 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 456     [HAVE_PRINTF_EXTENSION=yes])
 457
 458 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 459   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 460   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 461   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 462   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 463       [Defined if we have printf specifier extensions available])
 464 else
 465     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 466     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 467     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 468 fi
 469 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 470 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 471 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 472
 473 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 474 save_cflags="$CFLAGS"
 475 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 476 AC_CHECK_LIB(dl, dladdr,
 477    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 478    LIBS="$LIBS -ldl")
 479 CFLAGS="$save_cflags"
 480
 481 dnl *** checks for socket and nsl libraries ***
 482 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 483 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 484
 485 dnl check for inet_aton()
 486 save_libs="$LIBS"
 487 AC_CHECK_FUNC(inet_aton, ,
 488    AC_CHECK_LIB(nsl, inet_aton, ,
 489       AC_CHECK_LIB(socket, inet_aton, ,
 490          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 491 INET_ATON_LIBS=$LIBS
 492 AC_SUBST(INET_ATON_LIBS)
 493 LIBS="$save_libs"
 494
 495 dnl *** checks for dependency libraries ***
 496
 497 dnl GLib
 498 GLIB_REQ=2.14
 499
 500 AG_GST_GLIB_CHECK([$GLIB_REQ])
 501
 502 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 503 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 504 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 505
 506 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 507 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 508
 509 dnl Check for documentation xrefs
 510 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 511 AC_SUBST(GLIB_PREFIX)
 512
 513 dnl libxml 2 is optional in some cases
 514 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 515    ( test "x$GST_DISABLE_REGISTRY" = "xyes" || \
 516    test "x$USE_BINARY_REGISTRY" = "xyes" )
 517 then
 518   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 519   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 520 else
 521   dnl check for libxml2 with minimum req version
 522   AG_GST_LIBXML2_CHECK(2.4.9)
 523   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 524 fi
 525 AC_SUBST(GST_DISABLE_XML_DEFINE)
 526
 527 dnl check for "check", unit testing library/header
 528 if test "$cross_compiling" != yes; then
 529   AM_PATH_CHECK(0.9.2,
 530       HAVE_CHECK=yes,
 531       HAVE_CHECK=no)
 532 else
 533   HAVE_CHECK=no
 534 fi
 535 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 536
 537 dnl pkg-config check that for libcheck that works for cross-compiling
 538 dnl but not normal compilation on Fedora & Ubuntu:
 539 dnl PKG_CHECK_MODULES(CHECK, check >= 0.9.2,
 540 dnl   AM_CONDITIONAL(HAVE_CHECK, true),
 541 dnl   AM_CONDITIONAL(HAVE_CHECK, false)
 542 dnl )
 543
 544 dnl *** set variables based on configure arguments
 545
 546 dnl set license and copyright notice
 547 GST_LICENSE="LGPL"
 548 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 549 AC_SUBST(GST_LICENSE)
 550
 551 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 552 AS_AC_EXPAND(LIBDIR, $libdir)
 553 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 554 AS_AC_EXPAND(DATADIR, $datadir)
 555 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 556
 557 dnl set location of plugin directory
 558 AG_GST_SET_PLUGINDIR
 559
 560 dnl FIXME: add LIBXML_PKG here if we use it
 561 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 562 AC_SUBST(GST_PKG_DEPS)
 563
 564 dnl define an ERROR_CFLAGS Makefile variable
 565 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 566
 567 dnl define correct level for debugging messages
 568 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 569
 570 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 571
 572 dnl Overview:
 573 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 574 dnl GST_ALL_*:          vars shared by all built objects
 575 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 576 dnl GST_OBJ_*:          additional vars to link to the core library
 577 dnl                     include GST_ALL_*
 578 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 579 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 580
 581 dnl GST_OPTION_CFLAGS
 582 if test "x$USE_DEBUG" = xyes; then
 583    PROFILE_CFLAGS="-g"
 584 fi
 585 AC_SUBST(PROFILE_CFLAGS)
 586
 587 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 588 # functionality from the API that gstreamer uses
 589 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 590 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 591   dnl Define _only_ during CVS (not pre-releases or releases)
 592   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 593 else
 594   DEPRECATED_CFLAGS=""
 595 fi
 596 AC_SUBST(DEPRECATED_CFLAGS)
 597
 598 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 599 dnl make DEPRECATED_CFLAGS=''
 600 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 601 AC_SUBST(GST_OPTION_CFLAGS)
 602
 603 dnl GST_ALL_*
 604 dnl vars common to for all internal objects (core libs, elements, applications)
 605 dnl CFLAGS:
 606 dnl - XML needs to be added because xmlPtr is used in core
 607 dnl - src and build dirs need to be added because every piece that gets built
 608 dnl   will need the GStreamer source and generated headers
 609 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 610 dnl       from LibXML except for in the core library
 611 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 612
 613 dnl FIXME: check if LTLIBINTL is needed everywhere
 614 dnl I presume it is given that it contains the symbols that _() stuff maps to
 615 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 616
 617 dnl LDFLAGS really should only contain flags, not libs - they get added before
 618 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 619 GST_ALL_LDFLAGS="-no-undefined"
 620
 621 AC_SUBST(GST_ALL_CFLAGS)
 622 AC_SUBST(GST_ALL_LIBS)
 623 AC_SUBST(GST_ALL_LDFLAGS)
 624
 625 dnl GST_LIB_LDFLAGS
 626 dnl linker flags shared by all libraries
 627 dnl LDFLAGS modifier defining exported symbols from built libraries
 628 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 629 AC_SUBST(GST_LIB_LDFLAGS)
 630 dnl Version of the linker flags specifically for libgstcheck to support the boonky extra symbols it exports.
 631 GST_CHECK_LIB_LDFLAGS="-export-symbols-regex \^\([_]*\(gst_\|Gst\|GST_\).*\|check_\(debug\|mutex\|cond\)\|buffers\|mutex\|start_cond\|sync_cond\|thread_list\)$"
 632 dnl HACK: add non-portable --export-dynamic if we have GNU ld (needed on my debian stable, tpm)
 633 if test "x$ac_cv_prog_gnu_ld" = "xyes" -o "x$acl_cv_prog_gnu_ld" = "xyes" ; then
 634   GST_CHECK_LIB_LDFLAGS="-Wl,--export-dynamic $GST_CHECK_LIB_LDFLAGS"
 635 fi
 636 AC_SUBST(GST_CHECK_LIB_LDFLAGS)
 637
 638 dnl GST_OBJ_*
 639 dnl default vars for all internal objects built on libgstreamer
 640 dnl includes GST_ALL_*
 641 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 642 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 643 AC_SUBST(GST_OBJ_CFLAGS)
 644 AC_SUBST(GST_OBJ_LIBS)
 645
 646 dnl GST_PLUGIN_LDFLAGS
 647 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 648 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 649 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 650
 651 SHAVE_INIT([common],[enable])
 652
 653 AC_CONFIG_FILES(
 654 Makefile
 655 common/shave
 656 common/shave-libtool
 657 gst/Makefile
 658 gst/gstconfig.h
 659 gst/gstversion.h
 660 gst/parse/Makefile
 661 libs/Makefile
 662 libs/gst/Makefile
 663 libs/gst/base/Makefile
 664 libs/gst/check/Makefile
 665 libs/gst/controller/Makefile
 666 libs/gst/dataprotocol/Makefile
 667 libs/gst/net/Makefile
 668 plugins/Makefile
 669 plugins/indexers/Makefile
 670 plugins/elements/Makefile
 671 po/Makefile.in
 672 tests/Makefile
 673 tests/benchmarks/Makefile
 674 tests/check/Makefile
 675 tests/misc/Makefile
 676 tests/examples/Makefile
 677 tests/examples/adapter/Makefile
 678 tests/examples/controller/Makefile
 679 tests/examples/helloworld/Makefile
 680 tests/examples/launch/Makefile
 681 tests/examples/manual/Makefile
 682 tests/examples/metadata/Makefile
 683 tests/examples/queue/Makefile
 684 tests/examples/streams/Makefile
 685 tests/examples/typefind/Makefile
 686 tests/examples/xml/Makefile
 687 tools/Makefile
 688 common/Makefile
 689 common/m4/Makefile
 690 docs/Makefile
 691 docs/design/Makefile
 692 docs/faq/Makefile
 693 docs/gst/Makefile
 694 docs/gst/gstreamer.types
 695 docs/libs/Makefile
 696 docs/plugins/Makefile
 697 docs/manual/Makefile
 698 docs/pwg/Makefile
 699 docs/slides/Makefile
 700 docs/xsl/Makefile
 701 docs/version.entities
 702 pkgconfig/Makefile
 703 stamp.h
 704 pkgconfig/gstreamer.pc
 705 pkgconfig/gstreamer-uninstalled.pc
 706 pkgconfig/gstreamer-base.pc
 707 pkgconfig/gstreamer-base-uninstalled.pc
 708 pkgconfig/gstreamer-check.pc
 709 pkgconfig/gstreamer-check-uninstalled.pc
 710 pkgconfig/gstreamer-controller.pc
 711 pkgconfig/gstreamer-controller-uninstalled.pc
 712 pkgconfig/gstreamer-dataprotocol.pc
 713 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 714 pkgconfig/gstreamer-net.pc
 715 pkgconfig/gstreamer-net-uninstalled.pc
 716 gst-element-check.m4
 717 gstreamer.spec
 718 )
 719
 720 dnl Create the config.h file for Visual Studio builds
 721 dnl Beware of spaces and /'s in some of the shell variable contents.
 722 sed \
 723     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 724     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 725     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 726     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 727     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 728     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 729     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 730     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 731     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 732     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 733     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 734     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 735     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 736     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 737     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 738     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 739     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 740     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 741     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 742     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 743     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 744     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 745     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 746     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 747     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 748     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 749     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 750     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 751     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 752     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 753     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 754     config.h.in >win32/common/config.h-new
 755
 756 AC_OUTPUT
 757
 758 dnl negate for output
 759 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 760 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 761 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 762 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 763 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 764 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 765 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 766 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 767 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 768
 769 echo "
 770
 771 Configuration
 772         Version                    : ${VERSION}
 773         Source code location       : ${srcdir}
 774         Prefix                     : ${prefix}
 775         Compiler                   : ${SHAVE_SAVED_CC}
 776         Package name               : ${GST_PACKAGE_NAME}
 777         Package origin             : ${GST_PACKAGE_ORIGIN}
 778
 779         Documentation (manuals)    : ${enable_docbook}
 780         Documentation (API)        : ${enable_gtk_doc}
 781
 782         Debug Logging              : ${enable_gst_debug}
 783         Pipeline XML load/save     : ${enable_loadsave}
 784         Command-line parser        : ${enable_parse}
 785         Option parsing in gst_init : ${enable_option_parsing}
 786         Tracing subsystem          : ${enable_trace}
 787         Allocation tracing         : ${enable_alloc_trace}
 788         Plugin registry            : ${enable_registry}
 789         Plugin support             : ${enable_plugin}
 790         Network support            : ${enable_net}
 791
 792         Debug                      : ${USE_DEBUG}
 793         Profiling                  : ${USE_PROFILING}
 794
 795         Building examples          : ${BUILD_EXAMPLES}
 796         Building test apps         : ${BUILD_TESTS}
 797         Building tests that fail   : ${BUILD_FAILING_TESTS}
 798 "