configure.ac

   1 dnl  Copyright © 2008 Dan Nicholson
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Keith Packard not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Keith Packard makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  DAN NICHOLSON DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 # Initialize Autoconf
  24 AC_PREREQ([2.62])
  25 AC_INIT([libxkbcommon], [0.4.0],
  26         [https://bugs.freedesktop.org/enter_bug.cgi?product=libxkbcommon],
  27         [libxkbcommon], [http://xkbcommon.org])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_HEADERS([src/config.h])
  30 AC_CONFIG_MACRO_DIR([m4])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 # Initialize Automake
  34 AM_INIT_AUTOMAKE([foreign dist-xz no-dist-gzip subdir-objects color-tests parallel-tests check-news])
  35 AM_MAINTAINER_MODE([enable])
  36
  37 # Get _GNU_SOURCE and friends
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 # Initialize libtool
  41 LT_INIT
  42
  43 # Add xorg-macros stuff
  44 m4_ifndef([XORG_MACROS_VERSION],
  45           [m4_fatal([must install xorg-macros 1.16 or later before running autoconf/autogen])])
  46 XORG_MACROS_VERSION(1.16)
  47 XORG_DEFAULT_OPTIONS
  48 XORG_MEMORY_CHECK_FLAGS
  49 XORG_ENABLE_DOCS
  50 XORG_WITH_DOXYGEN
  51
  52 # Needed in older Automakes for subdir-objects
  53 AM_PROG_CC_C_O
  54
  55 # Check for compiler features
  56 AC_C_INLINE
  57
  58 # Check for programs
  59 AC_PROG_MKDIR_P
  60 PKG_PROG_PKG_CONFIG
  61
  62 # Note: we use some yacc extensions, which work with either GNU bison
  63 # (preferred) or byacc. Other yacc's may or may not work.
  64 AC_PROG_YACC
  65 AS_IF([test ! -f "src/xkbcomp/parser.c" -a "x$ac_cv_prog_YACC" = x], [
  66     AC_MSG_ERROR([yacc not found - unable to compile src/xkbcomp/parser.y])
  67 ])
  68
  69 # Checks for library functions.
  70 AC_CHECK_FUNCS([strcasecmp strncasecmp])
  71 AS_IF([test "x$ac_cv_func_strcasecmp" = xno -o \
  72             "x$ac_cv_func_strncasecmp" = xno], [
  73     AC_MSG_ERROR([C library does not support strcasecmp/strncasecmp])
  74 ])
  75
  76 AC_CHECK_FUNCS([eaccess euidaccess mmap])
  77
  78 AC_CHECK_FUNCS([secure_getenv __secure_getenv])
  79 AS_IF([test "x$ac_cv_func_secure_getenv" = xno -a \
  80             "x$ac_cv_func___secure_getenv" = xno], [
  81     AC_MSG_WARN([C library does not support secure_getenv, using getenv instead])
  82 ])
  83
  84 AX_GCC_BUILTIN(__builtin_expect)
  85
  86 # Some tests use Linux-specific headers
  87 AC_CHECK_HEADER([linux/input.h])
  88 AM_CONDITIONAL(BUILD_LINUX_TESTS, [test "x$ac_cv_header_linux_input_h" = xyes])
  89
  90 XORG_TESTSET_CFLAG([BASE_CFLAGS], [-fvisibility=hidden])
  91 XORG_TESTSET_CFLAG([BASE_CFLAGS], [-Wextra -Wno-unused-parameter -Wno-missing-field-initializers])
  92
  93 XORG_CHECK_LINKER_FLAGS([-Wl,--no-undefined], [have_no_undefined=yes])
  94 AM_CONDITIONAL([HAVE_NO_UNDEFINED], [test "x$have_no_undefined" = xyes])
  95
  96 # Define a configuration option for the XKB config root
  97 xkb_base=`$PKG_CONFIG --variable=xkb_base xkeyboard-config`
  98 AS_IF([test "x$xkb_base" = x], [
  99     xkb_base="$datadir/X11/xkb"
 100 ])
 101 AC_ARG_WITH([xkb_config_root],
 102     [AS_HELP_STRING([--with-xkb-config-root=<path>],
 103         [Set default XKB config root (default: xkeyboard-config install path)])],
 104     [XKBCONFIGROOT="$withval"],
 105     [XKBCONFIGROOT="$xkb_base"])
 106 AC_SUBST([XKBCONFIGROOT])
 107
 108 AC_ARG_WITH([default_rules],
 109     [AS_HELP_STRING([--with-default-rules=<path>],
 110         [Default XKB ruleset (default: evdev)])],
 111     [DEFAULT_XKB_RULES="$withval"],
 112     [DEFAULT_XKB_RULES="evdev"])
 113 AC_DEFINE_UNQUOTED([DEFAULT_XKB_RULES], ["$DEFAULT_XKB_RULES"],
 114                    [Default XKB ruleset])
 115
 116 AC_ARG_WITH([default_model],
 117     [AS_HELP_STRING([--with-default-model=<path>],
 118         [Default XKB model (default: pc105)])],
 119     [DEFAULT_XKB_MODEL="$withval"],
 120     [DEFAULT_XKB_MODEL="pc105"])
 121 AC_DEFINE_UNQUOTED([DEFAULT_XKB_MODEL], ["$DEFAULT_XKB_MODEL"],
 122                    [Default XKB model])
 123
 124 AC_ARG_WITH([default_layout],
 125     [AS_HELP_STRING([--with-default-layout=<path>],
 126         [Default XKB layout (default: us)])],
 127     [DEFAULT_XKB_LAYOUT="$withval"],
 128     [DEFAULT_XKB_LAYOUT="us"])
 129 AC_DEFINE_UNQUOTED([DEFAULT_XKB_LAYOUT], ["$DEFAULT_XKB_LAYOUT"],
 130                    [Default XKB layout])
 131
 132 AC_ARG_WITH([default_variant],
 133     [AS_HELP_STRING([--with-default-variant=<path>],
 134         [Default XKB variant (default: (none))])],
 135     [DEFAULT_XKB_VARIANT="$withval"],
 136     [DEFAULT_XKB_VARAINT=])
 137 AS_IF([test "x$DEFAULT_XKB_VARIANT" != x], [
 138     AC_DEFINE_UNQUOTED([DEFAULT_XKB_VARIANT], ["$DEFAULT_XKB_VARIANT"],
 139                        [Default XKB variant])
 140 ])
 141
 142 AC_ARG_WITH([default_options],
 143     [AS_HELP_STRING([--with-default-options=<path>],
 144         [Default XKB options (default: (none))])],
 145     [DEFAULT_XKB_OPTIONS="$withval"],
 146     [DEFAULT_XKB_OPTIONS=])
 147 AS_IF([test "x$DEFAULT_XKB_OPTIONS" != x], [
 148     AC_DEFINE_UNQUOTED([DEFAULT_XKB_OPTIONS], ["$DEFAULT_XKB_OPTIONS"],
 149                        [Default XKB options])
 150 ])
 151
 152 AC_ARG_ENABLE([x11],
 153     [AS_HELP_STRING([--disable-x11],
 154         [Disable support for creating keymaps with the X11 protocol (default: enabled)])],
 155     [], [enable_x11=yes])
 156 AS_IF([test "x$enable_x11" = xyes], [
 157     PKG_CHECK_MODULES([XCB_XKB], [xcb xcb-xkb >= 1.10], [],
 158         [AC_MSG_ERROR([xkbcommon-x11 requires xcb-xkb >= 1.10 which was not found. \
 159 You can disable X11 support with --disable-x11.])])
 160 ])
 161 AM_CONDITIONAL([ENABLE_X11], [test "x$enable_x11" = xyes])
 162
 163 AC_CONFIG_FILES([
 164     Makefile
 165     xkbcommon-uninstalled.pc
 166     xkbcommon.pc
 167     xkbcommon-x11.pc
 168     xkbcommon-x11-uninstalled.pc
 169     doc/Doxyfile
 170 ])
 171 AC_OUTPUT
 172
 173 AC_MSG_RESULT([
 174         $PACKAGE_NAME $VERSION
 175
 176         libxkbcommon:            yes
 177         libxkbcommon-x11:        ${enable_x11}
 178         documentation:           ${build_docs}
 179
 180         default XKB rules:       ${DEFAULT_XKB_RULES}
 181         default XKB model:       ${DEFAULT_XKB_MODEL}
 182         default XKB layout:      ${DEFAULT_XKB_LAYOUT}
 183         default XKB variant:     ${DEFAULT_XKB_VARIANT}
 184         default XKB options:     ${DEFAULT_XKB_OPTIONS}
 185
 186         prefix:                  ${prefix}
 187         includedir:              ${includedir}
 188         lib dir:                 ${libdir}
 189         XKB config root:         ${XKBCONFIGROOT}
 190 ])