configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.30.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl use pretty build output with automake >= 1.11
  33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  34   [AM_DEFAULT_VERBOSITY=1
  35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  36
  37 dnl our libraries and install dirs use major.minor as a version
  38 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  39 dnl we override it here for release candidates for a new series
  40 GST_MAJORMINOR=0.10
  41 AC_SUBST(GST_MAJORMINOR)
  42 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  43   [library major.minor version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl sets GST_LT_LDFLAGS
  51 AS_LIBTOOL(GST, 26, 0, 26)
  52
  53 dnl FIXME: this macro doesn't actually work;
  54 dnl the generated libtool script has no support for the listed tags.
  55 dnl So this needs to be fixed first if we want to use this
  56 dnl AS_LIBTOOL_TAGS
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AM_PROG_LIBTOOL
  60
  61 dnl *** autotools stuff ****
  62
  63 dnl allow for different autotools
  64 AS_AUTOTOOLS_ALTERNATE
  65
  66 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  67 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  68
  69 dnl set up gettext
  70 dnl the version check needs to stay here because autopoint greps for it
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 AM_GNU_GETTEXT([external])
  73 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  74
  75 dnl *** check for arguments to configure ***
  76
  77 dnl subsystems - can influence other decisions so needs to be high up
  78 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  79 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  80 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  81 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  82 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  83 dnl define a substitution to use in docs/gst/gstreamer.types
  84 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  85 then
  86   GST_LOADSAVE_DOC_TYPES="%"
  87 else
  88   GST_LOADSAVE_DOC_TYPES=
  89 fi
  90 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  92 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  93 if test "x$GST_DISABLE_PARSE" = xyes; then
  94   AC_DEFINE(GST_DISABLE_PARSE, 1,
  95     [Define if pipeline parsing code is disabled])
  96 fi
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  98 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  99 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 100   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 101     [Define if option parsing is disabled])
 102 fi
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 104 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 106 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 108 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 111 then
 112   GST_REGISTRY_DOC_TYPES="%"
 113 else
 114   GST_REGISTRY_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 118 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 119 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 120 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 121
 122 AG_GST_ARG_DEBUG
 123 AG_GST_ARG_PROFILING
 124 AG_GST_ARG_VALGRIND
 125 AG_GST_ARG_GCOV
 126
 127 AG_GST_ARG_EXAMPLES
 128
 129 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 130 AG_GST_ARG_WITH_PACKAGE_NAME
 131 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 132
 133 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 134   ["${srcdir}/gstreamer.doap"],
 135   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 136
 137 dnl building of tests
 138 AC_ARG_ENABLE(tests,
 139   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 140   [
 141     case "${enableval}" in
 142       yes) BUILD_TESTS=yes ;;
 143       no)  BUILD_TESTS=no ;;
 144       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 145     esac
 146   ],
 147 [BUILD_TESTS=yes]) dnl Default value
 148 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 149
 150 dnl tests known to fail
 151 AC_ARG_ENABLE(failing-tests,
 152   AC_HELP_STRING([--disable-failing-tests],
 153     [disable building tests known to fail]),
 154   [
 155     case "${enableval}" in
 156       yes) BUILD_FAILING_TESTS=yes ;;
 157       no)  BUILD_FAILING_TESTS=no ;;
 158       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 159     esac
 160   ],
 161   [BUILD_FAILING_TESTS=no]) dnl Default value
 162 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 163 if test x$BUILD_FAILING_TESTS = xyes; then
 164   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 165 else
 166   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 167 fi
 168
 169 dnl poison destroyed objects
 170 AC_ARG_ENABLE(poisoning,
 171   AC_HELP_STRING([--enable-poisoning],
 172     [enable poisoning of deallocated objects]),
 173   [
 174     case "${enableval}" in
 175       yes) USE_POISONING=yes ;;
 176       no)  USE_POISONING=no ;;
 177       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 178     esac
 179   ],
 180   [USE_POISONING=no]) dnl Default value
 181 if test "x$USE_POISONING" = xyes; then
 182   AC_DEFINE(USE_POISONING, 1,
 183     [Define if we should poison deallocated memory])
 184 fi
 185
 186 dnl *** checks for platform ***
 187
 188 dnl * hardware/architecture *
 189
 190 dnl common/m4/gst-arch.m4
 191 dnl check CPU type
 192 AG_GST_ARCH
 193 dnl substitution for win32/common/config.h
 194 HOST_CPU=$host_cpu
 195 AC_SUBST(HOST_CPU)
 196
 197 dnl common/m4/gst-arch.m4
 198 dnl check for unaligned access
 199 AG_GST_UNALIGNED_ACCESS
 200 dnl create a configure variable for gst/gstconfig.h
 201 if test x${as_cv_unaligned_access} = xyes ; then
 202   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 203 else
 204   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 205 fi
 206 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 207
 208 dnl check for platform specific settings
 209 AG_GST_PLATFORM
 210
 211 dnl * software *
 212
 213 dnl check for large file support
 214 dnl affected plugins must include config.h
 215 AC_SYS_LARGEFILE
 216
 217 dnl *** checks for programs ***
 218
 219 dnl find a compiler
 220 AC_PROG_CC
 221
 222 dnl check if the compiler supports '-c' and '-o' options
 223 AM_PROG_CC_C_O
 224
 225 dnl find an assembler
 226 AM_PROG_AS
 227
 228 dnl Perl is used in building documentation and in the version checks
 229 AC_PATH_PROG(PERL_PATH, perl, no)
 230 if test x$PERL_PATH = xno; then
 231   AC_MSG_ERROR(Could not find perl)
 232 fi
 233
 234 dnl we require flex and bison for building the parser
 235 if test "x$GST_DISABLE_PARSE" != xyes; then
 236   AG_GST_BISON_CHECK
 237   AG_GST_FLEX_CHECK
 238 fi
 239
 240 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 241 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 242
 243 dnl check for gobject-introspection
 244 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 245
 246 dnl check for documentation tools
 247 AG_GST_DOCBOOK_CHECK
 248 GTK_DOC_CHECK([1.3])
 249 AS_PATH_PYTHON([2.1])
 250 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 251
 252 dnl *** checks for libraries ***
 253
 254 dnl check for libm, for sin()
 255 AC_CHECK_LIBM
 256 AC_SUBST(LIBM)
 257
 258 dnl *** checks for header files ***
 259
 260 dnl check if we have ANSI C header files
 261 AC_HEADER_STDC
 262
 263 dnl Check for ucontext.h
 264 AC_CHECK_HEADERS([ucontext.h])
 265
 266 dnl Check for sys/socket.h
 267 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 268 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 269
 270 dnl check for sys/times.h for tests/examples/adapter/
 271 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 272 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 273 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 274
 275 dnl Check for process.h for getpid() on win32
 276 AC_CHECK_HEADERS([process.h])
 277
 278 dnl Check for sys/utsname.h for uname
 279 AC_CHECK_HEADERS([sys/utsname.h])
 280
 281 dnl Check for stdio_ext.f for __fbufsize
 282 AC_CHECK_HEADERS([stdio_ext.h])
 283
 284 dnl check for pthreads
 285 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 286 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 287
 288 dnl check for sys/prctl for setting thread name on Linux
 289 AC_CHECK_HEADERS([sys/prctl.h], HAVE_SYS_PRCTL_H=yes)
 290
 291 dnl Check for valgrind.h
 292 dnl separate from HAVE_VALGRIND because you can have the program, but not
 293 dnl the dev package
 294 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 295
 296 dnl used in gst/gstpoll.c
 297 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 298 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 299 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 300   WIN32_LIBS="-lws2_32"
 301   AC_SUBST(WIN32_LIBS)
 302 fi
 303
 304 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 305 if test "x$BUILD_TESTS" = "xyes"; then
 306   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 307                          __gmpz_init_set_d, ,
 308                          gmp.h,
 309                          GMP_LIBS="-lgmp"
 310                          AC_SUBST(GMP_LIBS)
 311                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 312   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 313                          gsl_rng_uniform_int, -lgslcblas,
 314                          gsl/gsl_rng.h,
 315                          GSL_LIBS="-lgsl -lgslcblas"
 316                          AC_SUBST(GSL_LIBS)
 317                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 318 fi
 319
 320 dnl *** checks for types/defines ***
 321
 322 dnl *** checks for structures ***
 323
 324 dnl *** checks for compiler characteristics ***
 325
 326 dnl check if the compiler supports __uint128_t (gcc)
 327 dnl Actually check for 128-bit division, since that's what we use
 328 dnl uint128_t for.
 329 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 330     AC_TRY_LINK([ ], [
 331       static __uint128_t v1 = 100;
 332       static __uint128_t v2 = 10;
 333       static __uint128_t u;
 334       u = v1 / v2;
 335     ], [
 336       gst_cv_uint128_t=yes
 337     ], [
 338       gst_cv_uint128_t=no
 339     ])
 340 )
 341 if test x$gst_cv_uint128_t = xyes; then
 342   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 343 fi
 344
 345 dnl *** checks for library functions ***
 346
 347 AC_CHECK_FUNCS([sigaction])
 348
 349 dnl check for fseeko()
 350 AC_FUNC_FSEEKO
 351 dnl check for ftello()
 352 AC_CHECK_FUNCS([ftello])
 353
 354 AC_CHECK_FUNCS([fgetpos])
 355 AC_CHECK_FUNCS([fsetpos])
 356
 357 dnl check for poll(), ppoll() and pselect()
 358 AC_CHECK_FUNCS([poll])
 359 AC_CHECK_FUNCS([ppoll])
 360 AC_CHECK_FUNCS([pselect])
 361
 362 dnl ****************************************
 363 dnl *** GLib POLL* compatibility defines ***
 364 dnl ****************************************
 365
 366 AC_MSG_CHECKING([for broken poll])
 367 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 368         #include <stdlib.h>
 369         #include <fcntl.h>
 370         #include <poll.h>
 371         #ifdef HAVE_SYS_POLL_H
 372         #include <sys/poll.h>
 373         #endif
 374         int main(void) {
 375           struct pollfd fds[1];
 376           int fd;
 377           fd = open("/dev/null", 1);
 378           fds[0].fd = fd;
 379           fds[0].events = POLLIN;
 380           fds[0].revents = 0;
 381           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 382                 exit(1);  /* Does not work for devices -- fail */
 383           }
 384           exit(0);
 385         }]])],
 386   [broken_poll=no],
 387   [broken_poll=yes
 388    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 389   [broken_poll="no (cross compiling)"])
 390 AC_MSG_RESULT($broken_poll)
 391
 392 dnl check for mmap()
 393 AC_FUNC_MMAP
 394 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 395
 396 dnl check for posix_memalign(), getpagesize()
 397 AC_CHECK_FUNCS([posix_memalign])
 398 AC_CHECK_FUNCS([getpagesize])
 399
 400 dnl Check for POSIX timers
 401 AC_CHECK_FUNCS(clock_gettime, [], [
 402   AC_CHECK_LIB(rt, clock_gettime, [
 403     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 404     LIBS="$LIBS -lrt"
 405   ])
 406 ])
 407
 408 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 409     AC_TRY_COMPILE([
 410 #include <time.h>
 411 #ifdef HAVE_UNISTD_H
 412 #include <unistd.h>
 413 #endif
 414     ], [
 415 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 416 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 417 #endif
 418     ], [
 419       gst_cv_posix_timers=yes
 420     ], [
 421       gst_cv_posix_timers=no
 422     ])
 423 )
 424
 425 if test "$gst_cv_posix_timers" = "yes"; then
 426   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 427   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 428 else
 429   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 430 fi
 431 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 432 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 433
 434 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 435     AC_TRY_COMPILE([
 436 #include <time.h>
 437 #ifdef HAVE_UNISTD_H
 438 #include <unistd.h>
 439 #endif
 440     ], [
 441 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 442 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 443 #endif
 444     ], [
 445       gst_cv_monotonic_clock=yes
 446     ], [
 447       gst_cv_monotonic_clock=no
 448     ])
 449 )
 450
 451 if test "$gst_cv_monotonic_clock" = "yes"; then
 452   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 453   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 454 else
 455   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 456 fi
 457 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 458 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 459
 460 dnl Check for a way to display the function name in debug output
 461 AG_GST_CHECK_FUNCTION
 462
 463 dnl test for register_printf_specifier or register_printf_function
 464 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 465     [HAVE_PRINTF_EXTENSION=yes])
 466
 467 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 468   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 469   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 470   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 471   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 472       [Defined if we have printf specifier extensions available])
 473 else
 474     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 475     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 476     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 477 fi
 478 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 479 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 480 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 481
 482 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 483 save_cflags="$CFLAGS"
 484 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 485 AC_CHECK_LIB(dl, dladdr,
 486    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 487    LIBS="$LIBS -ldl")
 488 CFLAGS="$save_cflags"
 489
 490 dnl *** checks for socket and nsl libraries ***
 491 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 492 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 493
 494 dnl check for inet_aton()
 495 save_libs="$LIBS"
 496 AC_CHECK_FUNC(inet_aton, ,
 497    AC_CHECK_LIB(nsl, inet_aton, ,
 498       AC_CHECK_LIB(socket, inet_aton, ,
 499          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 500 INET_ATON_LIBS=$LIBS
 501 AC_SUBST(INET_ATON_LIBS)
 502 LIBS="$save_libs"
 503
 504 dnl *** checks for dependency libraries ***
 505
 506 dnl GLib
 507 GLIB_REQ=2.20
 508
 509 AG_GST_GLIB_CHECK([$GLIB_REQ])
 510
 511 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 512 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 513 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 514
 515 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 516 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 517
 518 dnl Check for documentation xrefs
 519 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 520 AC_SUBST(GLIB_PREFIX)
 521
 522 dnl libxml2 is only needed for xml loading/saving of pipelines these days
 523 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
 524 then
 525   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 526   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 527 else
 528   dnl check for libxml2 with minimum req version
 529   AG_GST_LIBXML2_CHECK(2.4.9)
 530   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 531 fi
 532 AC_SUBST(GST_DISABLE_XML_DEFINE)
 533
 534 dnl building of unit test libraries
 535 AC_ARG_ENABLE(check,
 536   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 537   [
 538     case "${enableval}" in
 539       yes) BUILD_CHECK=yes ;;
 540       no)  BUILD_CHECK=no ;;
 541       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 542     esac
 543   ], [
 544     dnl Default value
 545     case $host_os in
 546       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 547       *) BUILD_CHECK=yes ;;
 548     esac
 549 ])
 550 dnl bit of a misnomer, but keep the conditional named like this so we don't
 551 dnl have to change too much elsewhere
 552 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 553
 554 dnl configure the desired buffer alignment
 555 AC_ARG_WITH([buffer-alignment],
 556   AS_HELP_STRING([--with-buffer-alignment],[8,N,malloc,pagesize (default is 32)]),
 557   [
 558     if test "x$withval" = "xyes"
 559     then
 560       AC_DEFINE(BUFFER_ALIGNMENT, 32, [Buffer alignment to use])
 561     else
 562       case "${withval}" in
 563         malloc) AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default]) ;;
 564         pagesize)  AC_DEFINE(BUFFER_ALIGNMENT_PAGESIZE, 1, [Buffer alignment by pagesize]) ;;
 565         *)   AC_DEFINE_UNQUOTED(BUFFER_ALIGNMENT, ${withval}, [Buffer alignment to use]) ;;
 566       esac
 567     fi
 568   ], [
 569     AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default])
 570   ]
 571 )
 572
 573 dnl *** set variables based on configure arguments
 574
 575 dnl set license and copyright notice
 576 GST_LICENSE="LGPL"
 577 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 578 AC_SUBST(GST_LICENSE)
 579
 580 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 581 AS_AC_EXPAND(LIBDIR, $libdir)
 582 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 583 AS_AC_EXPAND(DATADIR, $datadir)
 584 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 585
 586 dnl set location of plugin directory
 587 AG_GST_SET_PLUGINDIR
 588
 589 dnl FIXME: add LIBXML_PKG here if we use it
 590 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 591 AC_SUBST(GST_PKG_DEPS)
 592
 593 dnl define an ERROR_CFLAGS Makefile variable
 594 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs])
 595
 596 dnl define correct level for debugging messages
 597 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 598
 599 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 600
 601 dnl Overview:
 602 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 603 dnl GST_ALL_*:          vars shared by all built objects
 604 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 605 dnl GST_OBJ_*:          additional vars to link to the core library
 606 dnl                     include GST_ALL_*
 607 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 608 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 609
 610 dnl GST_OPTION_CFLAGS
 611 if test "x$USE_DEBUG" = xyes; then
 612    PROFILE_CFLAGS="-g"
 613 fi
 614 AC_SUBST(PROFILE_CFLAGS)
 615
 616 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 617 # functionality from the API that gstreamer uses
 618 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 619 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 620   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 621   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 622 else
 623   DEPRECATED_CFLAGS=""
 624 fi
 625 AC_SUBST(DEPRECATED_CFLAGS)
 626
 627 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 628 dnl make DEPRECATED_CFLAGS=''
 629 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 630 AC_SUBST(GST_OPTION_CFLAGS)
 631
 632 dnl GST_ALL_*
 633 dnl vars common to for all internal objects (core libs, elements, applications)
 634 dnl CFLAGS:
 635 dnl - XML needs to be added because xmlPtr is used in core
 636 dnl - src and build dirs need to be added because every piece that gets built
 637 dnl   will need the GStreamer source and generated headers
 638 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 639 dnl       from LibXML except for in the core library
 640 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS $GLIB_EXTRA_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 641
 642 dnl FIXME: check if LTLIBINTL is needed everywhere
 643 dnl I presume it is given that it contains the symbols that _() stuff maps to
 644 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 645
 646 dnl LDFLAGS really should only contain flags, not libs - they get added before
 647 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 648 GST_ALL_LDFLAGS="-no-undefined"
 649
 650 AC_SUBST(GST_ALL_CFLAGS)
 651 AC_SUBST(GST_ALL_LIBS)
 652 AC_SUBST(GST_ALL_LDFLAGS)
 653
 654 dnl GST_LIB_LDFLAGS
 655 dnl linker flags shared by all libraries
 656 dnl LDFLAGS modifier defining exported symbols from built libraries
 657 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 658 AC_SUBST(GST_LIB_LDFLAGS)
 659
 660 dnl GST_OBJ_*
 661 dnl default vars for all internal objects built on libgstreamer
 662 dnl includes GST_ALL_*
 663 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 664 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 665 AC_SUBST(GST_OBJ_CFLAGS)
 666 AC_SUBST(GST_OBJ_LIBS)
 667
 668 dnl GST_PLUGIN_LDFLAGS
 669 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 670 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 671 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 672
 673 dnl plugin scanner locations
 674 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_MAJORMINOR/gst-plugin-scanner)
 675 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 676     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 677 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 678
 679 dnl things for our internal libcheck (must be called even if building
 680 dnl libcheck is disabled because it defines conditionals)
 681 AG_GST_CHECK_CHECKS()
 682
 683 AC_CONFIG_FILES(
 684 Makefile
 685 gst/Makefile
 686 gst/gstconfig.h
 687 gst/gstversion.h
 688 gst/parse/Makefile
 689 libs/Makefile
 690 libs/gst/Makefile
 691 libs/gst/base/Makefile
 692 libs/gst/check/Makefile
 693 libs/gst/check/libcheck/Makefile
 694 libs/gst/check/libcheck/check.h
 695 libs/gst/controller/Makefile
 696 libs/gst/dataprotocol/Makefile
 697 libs/gst/helpers/Makefile
 698 libs/gst/net/Makefile
 699 plugins/Makefile
 700 plugins/indexers/Makefile
 701 plugins/elements/Makefile
 702 po/Makefile.in
 703 tests/Makefile
 704 tests/benchmarks/Makefile
 705 tests/check/Makefile
 706 tests/misc/Makefile
 707 tests/examples/Makefile
 708 tests/examples/adapter/Makefile
 709 tests/examples/controller/Makefile
 710 tests/examples/stepping/Makefile
 711 tests/examples/helloworld/Makefile
 712 tests/examples/launch/Makefile
 713 tests/examples/manual/Makefile
 714 tests/examples/metadata/Makefile
 715 tests/examples/queue/Makefile
 716 tests/examples/streams/Makefile
 717 tests/examples/typefind/Makefile
 718 tools/Makefile
 719 common/Makefile
 720 common/m4/Makefile
 721 docs/Makefile
 722 docs/design/Makefile
 723 docs/faq/Makefile
 724 docs/gst/Makefile
 725 docs/gst/gstreamer.types
 726 docs/libs/Makefile
 727 docs/plugins/Makefile
 728 docs/manual/Makefile
 729 docs/pwg/Makefile
 730 docs/slides/Makefile
 731 docs/xsl/Makefile
 732 docs/version.entities
 733 m4/Makefile
 734 pkgconfig/Makefile
 735 stamp.h
 736 pkgconfig/gstreamer.pc
 737 pkgconfig/gstreamer-uninstalled.pc
 738 pkgconfig/gstreamer-base.pc
 739 pkgconfig/gstreamer-base-uninstalled.pc
 740 pkgconfig/gstreamer-check.pc
 741 pkgconfig/gstreamer-check-uninstalled.pc
 742 pkgconfig/gstreamer-controller.pc
 743 pkgconfig/gstreamer-controller-uninstalled.pc
 744 pkgconfig/gstreamer-dataprotocol.pc
 745 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 746 pkgconfig/gstreamer-net.pc
 747 pkgconfig/gstreamer-net-uninstalled.pc
 748 gst-element-check.m4
 749 gstreamer.spec
 750 )
 751
 752 dnl Create the config.h file for Visual Studio builds
 753 dnl Beware of spaces and /'s in some of the shell variable contents.
 754 sed \
 755     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 756     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 757     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 758     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 759     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 760     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 761     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 762     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 763     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 764     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 765     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 766     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 767     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 768     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 769     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 770     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 771     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 772     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 773     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 774     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 775     -e 's/.* BUFFER_ALIGNMENT_MALLOC/#define BUFFER_ALIGNMENT_MALLOC 1/' \
 776     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 777     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 778     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 779     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 780     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 781     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 782     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 783     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 784     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 785     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 786     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 787     config.h.in >win32/common/config.h-new
 788
 789 AC_OUTPUT
 790
 791 dnl negate for output
 792 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 793 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 794 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 795 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 796 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 797 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 798 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 799 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 800 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 801
 802 echo "
 803
 804 Configuration
 805         Version                    : ${VERSION}
 806         Source code location       : ${srcdir}
 807         Prefix                     : ${prefix}
 808         Compiler                   : ${CC}
 809         Package name               : ${GST_PACKAGE_NAME}
 810         Package origin             : ${GST_PACKAGE_ORIGIN}
 811
 812         Documentation (manuals)    : ${enable_docbook}
 813         Documentation (API)        : ${enable_gtk_doc}
 814
 815         Debug Logging              : ${enable_gst_debug}
 816         Pipeline XML load/save     : ${enable_loadsave}
 817         Command-line parser        : ${enable_parse}
 818         Option parsing in gst_init : ${enable_option_parsing}
 819         Tracing subsystem          : ${enable_trace}
 820         Allocation tracing         : ${enable_alloc_trace}
 821         Plugin registry            : ${enable_registry}
 822         Plugin support             : ${enable_plugin}
 823         Network support            : ${enable_net}
 824         Unit testing support       : ${BUILD_CHECK}
 825
 826         Debug                      : ${USE_DEBUG}
 827         Profiling                  : ${USE_PROFILING}
 828
 829         Building examples          : ${BUILD_EXAMPLES}
 830         Building test apps         : ${BUILD_TESTS}
 831         Building tests that fail   : ${BUILD_FAILING_TESTS}
 832 "