configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.29,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.33
  58 GSTPB_REQ=0.10.33
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for gconftool-2
 134 dnl this macro defines an am conditional, so it needs to be run always
 135 AM_GCONF_SOURCE_2
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl check for libm, for sin()
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used by ext/wavpack
 154 AX_CREATE_STDINT_H
 155
 156 dnl used in gst/rtp/gstasteriskh263.c
 157 AC_CHECK_HEADERS([netinet/in.h])
 158 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 159 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 160
 161 dnl used in gst/udp
 162 AC_CHECK_HEADERS([sys/time.h])
 163
 164 dnl *** checks for types/defines ***
 165
 166 dnl Check for FIONREAD ioctl declaration.  This check is needed
 167 dnl for the UDP plugin to build on Solaris
 168 GST_CHECK_FIONREAD
 169
 170 dnl *** checks for structures ***
 171
 172 dnl *** checks for compiler characteristics ***
 173
 174 dnl check if we have GCC inline-asm
 175 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 176 if test x$HAVE_GCC_ASM = xyes ; then
 177   AC_DEFINE(HAVE_GCC_ASM, 1,
 178     [Define if compiler supports gcc inline assembly])
 179 fi
 180 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 181
 182 dnl *** checks for library functions ***
 183
 184 LIBS_SAVE=$LIBS
 185 LIBS="$LIBS $LIBM"
 186 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 187 LIBS=$LIBS_SAVE
 188
 189 dnl Check whether isinf() is defined by math.h
 190 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 191     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 192 if test "$ac_cv_have_isinf" = "yes"
 193 then
 194     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 195 fi
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198 AC_FUNC_MMAP
 199 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 200
 201 dnl Check for mmap (needed by electricfence plugin)
 202
 203 AC_CHECK_TYPE([struct ip_mreqn], [
 204               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 205               [#include <netinet/in.h>])
 206
 207 dnl *** checks for dependency libraries ***
 208
 209 dnl GLib is required
 210 AG_GST_GLIB_CHECK([2.20])
 211
 212 dnl Orc
 213 ORC_CHECK([0.4.11])
 214
 215 dnl checks for gstreamer
 216 dnl uninstalled is selected preferentially -- see pkg-config(1)
 217 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 222 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 223
 224 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 225 if test -z $GST_TOOLS_DIR; then
 226   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 227 fi
 228 AC_SUBST(GST_TOOLS_DIR)
 229
 230 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 231 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 232
 233 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 234
 235 dnl Check for documentation xrefs
 236 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 237 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 238 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 239 AC_SUBST(GLIB_PREFIX)
 240 AC_SUBST(GST_PREFIX)
 241 AC_SUBST(GSTPB_PREFIX)
 242
 243 dnl GTK is optional and used in examples
 244 HAVE_GTK=no
 245 GTK2_REQ=2.14.0
 246 GTK3_REQ=2.91.3
 247 if test "x$BUILD_EXAMPLES" = "xyes"; then
 248   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 249   AC_ARG_WITH([gtk],
 250     AC_HELP_STRING([--with-gtk=3.0|2.0],
 251                    [which gtk+ version to compile against (default: 2.0)]),
 252     [case "$with_gtk" in
 253         2.0) GTK_REQ=$GTK2_REQ ;;
 254         3.0) GTK_REQ=$GTK3_REQ ;;
 255         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 256     esac],
 257     [with_gtk=2.0
 258      GTK_REQ=$GTK2_REQ])
 259   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 260   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 261   dnl some examples need gtk+-x11
 262   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 263   AC_SUBST(GTK_LIBS)
 264   AC_SUBST(GTK_CFLAGS)
 265 fi
 266 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 267 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 268
 269 dnl should we install schemas ?
 270 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 271 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 272   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 273   if test x$GCONFTOOL = xno; then
 274     AC_MSG_WARN(Not installing GConf schemas)
 275     HAVE_GCONFTOOL="no"
 276   else
 277     HAVE_GCONFTOOL="yes"
 278   fi
 279   AC_SUBST(HAVE_GCONFTOOL)
 280 ])
 281
 282 dnl use divx drm --------------------------------------------------------------------------
 283 AC_ARG_ENABLE(divx-drm, AC_HELP_STRING([--enable-divx-drm], [using divx drm]),
 284   [
 285     case "${enableval}" in
 286       yes) USE_DIVX_DRM=yes ;;
 287        no) USE_DIVX_DRM=no ;;
 288         *) AC_MSG_ERROR(bad value ${enableval} for --enable-divx-drm) ;;
 289     esac
 290   ],
 291   [USE_DIVX_DRM=no])
 292 AM_CONDITIONAL(USE_DIVX_DRM, test "x$USE_DIVX_DRM" = "xyes")
 293
 294 dnl *** set variables based on configure arguments ***
 295
 296 dnl set license and copyright notice
 297 GST_LICENSE="LGPL"
 298 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 299 AC_SUBST(GST_LICENSE)
 300
 301 dnl set location of plugin directory
 302 AG_GST_SET_PLUGINDIR
 303
 304 dnl set release date/time
 305 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 306   ["${srcdir}/gst-plugins-good.doap"],
 307   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 308
 309 dnl define an ERROR_CFLAGS Makefile variable
 310 dnl -Wundef: too many broken headers
 311 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 312   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 313         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 314         -Wwrite-strings -Wold-style-definition -Waggregate-return
 315         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 316         -Wnested-externs ])
 317 else
 318   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 319   dnl doesn't understand all warning flags that the C compiler knows about
 320   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 321   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 322         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 323         -Wwrite-strings -Wold-style-definition
 324         -Winit-self -Wmissing-include-dirs -Wno-multichar
 325         -Wnested-externs ])
 326 fi
 327
 328 dnl define an ERROR_CXXFLAGS Makefile variable
 329 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 330         -Wmissing-declarations -Wredundant-decls
 331         -Wwrite-strings
 332         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 333
 334 dnl define correct level for debugging messages
 335 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 336
 337 dnl used in examples
 338 AG_GST_DEFAULT_ELEMENTS
 339
 340 dnl *** plug-ins to include ***
 341
 342 dnl these are all the gst plug-ins, compilable without additional libs
 343 dnl videofilter is at the top because others depend on it
 344 AG_GST_CHECK_PLUGIN(videofilter)
 345 AG_GST_CHECK_PLUGIN(alpha)
 346 AG_GST_CHECK_PLUGIN(apetag)
 347 AG_GST_CHECK_PLUGIN(audiofx)
 348 AG_GST_CHECK_PLUGIN(audioparsers)
 349 AG_GST_CHECK_PLUGIN(auparse)
 350 AG_GST_CHECK_PLUGIN(autodetect)
 351 AG_GST_CHECK_PLUGIN(avi)
 352 AG_GST_CHECK_PLUGIN(cutter)
 353 AG_GST_CHECK_PLUGIN(debugutils)
 354 AG_GST_CHECK_PLUGIN(deinterlace)
 355 AG_GST_CHECK_PLUGIN(effectv)
 356 AG_GST_CHECK_PLUGIN(equalizer)
 357 AG_GST_CHECK_PLUGIN(flv)
 358 AG_GST_CHECK_PLUGIN(id3demux)
 359 AG_GST_CHECK_PLUGIN(icydemux)
 360 AG_GST_CHECK_PLUGIN(interleave)
 361 AG_GST_CHECK_PLUGIN(flx)
 362 AG_GST_CHECK_PLUGIN(goom)
 363 AG_GST_CHECK_PLUGIN(goom2k1)
 364 AG_GST_CHECK_PLUGIN(imagefreeze)
 365 AG_GST_CHECK_PLUGIN(isomp4)
 366 AG_GST_CHECK_PLUGIN(law)
 367 AG_GST_CHECK_PLUGIN(level)
 368 AG_GST_CHECK_PLUGIN(matroska)
 369 AG_GST_CHECK_PLUGIN(monoscope)
 370 AG_GST_CHECK_PLUGIN(multifile)
 371 AG_GST_CHECK_PLUGIN(multipart)
 372 AG_GST_CHECK_PLUGIN(replaygain)
 373 AG_GST_CHECK_PLUGIN(rtp)
 374 AG_GST_CHECK_PLUGIN(rtpmanager)
 375 AG_GST_CHECK_PLUGIN(rtsp)
 376 AG_GST_CHECK_PLUGIN(shapewipe)
 377 AG_GST_CHECK_PLUGIN(smpte)
 378 AG_GST_CHECK_PLUGIN(spectrum)
 379 AG_GST_CHECK_PLUGIN(udp)
 380 AG_GST_CHECK_PLUGIN(videobox)
 381 AG_GST_CHECK_PLUGIN(videocrop)
 382 AG_GST_CHECK_PLUGIN(videomixer)
 383 AG_GST_CHECK_PLUGIN(wavenc)
 384 AG_GST_CHECK_PLUGIN(wavparse)
 385 AG_GST_CHECK_PLUGIN(y4m)
 386
 387 dnl *** checks for socket and nsl libraries ***
 388 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 389
 390 dnl disable gst plugins we might not be able to build on this
 391 dnl platform: udp and rtsp (ugly but minimally invasive)
 392 dnl FIXME: maybe move to sys
 393 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 394 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 395
 396 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 397   AG_GST_DISABLE_PLUGIN(udp)
 398   AG_GST_DISABLE_PLUGIN(rtsp)
 399 fi
 400
 401 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 402   WIN32_LIBS="-lws2_32"
 403   AC_SUBST(WIN32_LIBS)
 404 fi
 405
 406 dnl disable experimental plug-ins
 407 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 408   AG_GST_DISABLE_PLUGIN(monoscope)
 409 fi
 410
 411 dnl *** sys plug-ins ***
 412
 413 echo
 414 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 415 echo
 416
 417 dnl DirectSound
 418 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 419 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 420   HAVE_DIRECTSOUND="no"
 421   save_CFLAGS="$CFLAGS"
 422   save_LDFLAGS="$LDFLAGS"
 423   save_LIBS="$LIBS"
 424   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 425   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 426   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 427   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 428   AC_LINK_IFELSE([
 429 #include <windows.h>
 430 #include <dxerr9.h>
 431 #include <dsound.h>
 432
 433 int main ()
 434 {
 435   DXGetErrorString9 (0);
 436   DirectSoundCreate(NULL, NULL, NULL);
 437
 438   return 0;
 439 }
 440 ],
 441     [HAVE_DIRECTSOUND="yes"],
 442     [HAVE_DIRECTSOUND="no"])
 443   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 444   CFLAGS=$save_CFLAGS
 445   LDFLAGS=$save_LDFLAGS
 446   LIBS=$save_LIBS
 447
 448   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 449     dnl this is much more than we want
 450     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 451     AC_SUBST(DIRECTSOUND_CFLAGS)
 452     AC_SUBST(DIRECTSOUND_LDFLAGS)
 453     AC_SUBST(DIRECTSOUND_LIBS)
 454   fi
 455   AC_SUBST(HAVE_DIRECTSOUND)
 456 ])
 457
 458 dnl *** OSS audio *** (Linux, *BSD)
 459 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 460 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 461  HAVE_OSS="yes"
 462 dnl Linux and newer BSD versions :
 463  AC_CHECK_HEADER(sys/soundcard.h, [
 464    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 465    ] , [
 466 dnl Some old BSD versions and also newer OpenBSD versions :
 467    AC_CHECK_HEADER(soundcard.h, [
 468      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 469      ], [
 470   dnl Some old BSD versions :
 471      AC_CHECK_HEADER(machine/soundcard.h, [
 472        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 473          [Define if OSS includes are in /machine/])
 474        ], [
 475        HAVE_OSS="no"
 476      ])
 477    ])
 478  ])
 479 ])
 480
 481 dnl *** oss4 ***
 482 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 483 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 484   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 485   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 486       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 487       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 488 ])
 489
 490 dnl *** Sun Audio ***
 491 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 492 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 493   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 494 ])
 495
 496 dnl *** OSX Audio ***
 497 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 498 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 499   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 500 ])
 501
 502 dnl *** OS X video ***
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 504 HAVE_OSX_VIDEO="no"
 505 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 506   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 507 ])
 508 dnl in case header OpenGL/gl.h is found on other platforms
 509 case "$host" in
 510   *-*darwin*)
 511     dnl do nothing
 512     ;;
 513   *)
 514     HAVE_OSX_VIDEO="no"
 515     ;;
 516 esac
 517
 518
 519 dnl *** Video 4 Linux 2 ***
 520 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 521 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 522 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 523 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 524   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 525   AC_TRY_COMPILE([
 526 #include <sys/types.h>
 527 #ifdef __sun /* Solaris */
 528 #include <sys/types.h>
 529 #include <sys/videodev2.h>
 530 #else /* Linux */
 531 #include <linux/types.h>
 532 #define _LINUX_TIME_H
 533 #define __user
 534 #include <linux/videodev2.h>
 535 #endif
 536 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 537 #error too early v4l2 version or no v4l2 at all
 538 #endif
 539     ], [
 540 return 0;
 541     ], [
 542       HAVE_GST_V4L2="yes"
 543       AC_MSG_RESULT(yes)
 544     ], [
 545       HAVE_GST_V4L2="no"
 546       AC_MSG_RESULT(no)
 547
 548       HAVE_VIDEODEV=no
 549       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 550       [
 551         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 552       ])
 553
 554       if test "x$HAVE_VIDEODEV" = "xyes"; then
 555         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 556         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 557       else
 558         AC_MSG_WARN([video4linux2 was not found])
 559       fi
 560     ])
 561
 562   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 563     dnl check for missing v4l2_buffer declaration (see #135919)
 564     MISSING_DECL=0
 565     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 566     AC_TRY_COMPILE([
 567 #include <sys/types.h>
 568 #ifdef __sun /* Solaris */
 569 #include <sys/types.h>
 570 #include <sys/videodev2.h>
 571 #else /* Linux */
 572 #include <linux/types.h>
 573 #define _LINUX_TIME_H
 574 #define __user
 575 #include <linux/videodev2.h>
 576 #endif
 577     ],[
 578 struct v4l2_buffer buf;
 579 buf.index = 0;
 580 return 0;
 581     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 582     if [ test x$MISSING_DECL = x1 ]; then
 583       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 584     fi
 585
 586     dnl check for XOverlay libraries
 587     AG_GST_CHECK_XV
 588   fi
 589 ])
 590
 591 # Optional gudev for device probing
 592 AC_ARG_WITH([gudev],
 593   AC_HELP_STRING([--with-gudev],
 594     [device detection with gudev]),
 595   [],
 596   [with_gudev=check])
 597 if test x$HAVE_GST_V4L2 = xyes; then
 598   if test x$with_gudev != xno; then
 599       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 600           [ have_gudev=yes
 601             AC_DEFINE(HAVE_GUDEV, 1,
 602                [Whether gudev is available for device detection])
 603             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 604           ], [
 605           have_gudev=no
 606           ])
 607   else
 608     have_gudev=no
 609   fi
 610 fi
 611 AC_SUBST(GUDEV_CFLAGS)
 612 AC_SUBST(GUDEV_LIBS)
 613
 614 # Make libv4l2 non-automagic
 615 AC_ARG_WITH([libv4l2],
 616   AC_HELP_STRING([--with-libv4l2],
 617     [support video buffer conversion using libv4l2]),
 618   [],
 619   [with_libv4l2=check])
 620 if test x$HAVE_GST_V4L2 = xyes; then
 621   if test x$with_libv4l2 != xno; then
 622       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 623           [ have_libv4l2=yes
 624             AC_DEFINE(HAVE_LIBV4L2, 1,
 625                 [Whether libv4l2 is available for video buffer conversion])
 626           ], [
 627           have_libv4l2=no
 628           ])
 629   else
 630     have_libv4l2=no
 631   fi
 632 fi
 633
 634 dnl Check for X11
 635 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 636 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 637                   [ximagesrc], [
 638   AC_PATH_XTRA
 639
 640   dnl now try to find the HEADER
 641   ac_cflags_save="$CFLAGS"
 642   ac_cppflags_save="$CPPFLAGS"
 643   CFLAGS="$CFLAGS $X_CFLAGS"
 644   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 645   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 646
 647   if test "x$HAVE_X" = "xno"
 648   then
 649     AC_MSG_NOTICE([cannot find X11 development files])
 650   else
 651     dnl this is much more than we want
 652     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 653     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 654     dnl it does not add the libs; therefore we add them here
 655     X_LIBS="$X_LIBS -lX11"
 656     AC_SUBST(X_CFLAGS)
 657     AC_SUBST(X_LIBS)
 658
 659     dnl check for Xfixes
 660     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 661     if test "x$HAVE_XFIXES" = "xyes"
 662     then
 663         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 664     fi
 665     AC_SUBST(XFIXES_LIBS)
 666     AC_SUBST(XFIXES_CFLAGS)
 667
 668     dnl check for Xdamage
 669     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 670     if test "x$HAVE_XDAMAGE" = "xyes"
 671     then
 672         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 673     fi
 674     AC_SUBST(XDAMAGE_LIBS)
 675     AC_SUBST(XDAMAGE_CFLAGS)
 676   fi
 677   AC_SUBST(HAVE_X)
 678   CFLAGS="$ac_cflags_save"
 679   CPPFLAGS="$ac_cppflags_save"
 680 ])
 681
 682 dnl FIXME: this should be rolled into the test above, it's just an additional
 683 dnl feature of the ximagesrc plug-in
 684 dnl This is the same as in gst-plugins-base
 685 dnl check for X Shm
 686 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 687 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 688   if test x$HAVE_X = xyes; then
 689     AC_CHECK_LIB(Xext, XShmAttach,
 690                  HAVE_XSHM="yes", HAVE_XSHM="no",
 691                  $X_LIBS)
 692     if test "x$HAVE_XSHM" = "xyes"; then
 693       XSHM_LIBS="-lXext"
 694     else
 695       dnl On AIX, it is in XextSam instead, but we still need -lXext
 696       AC_CHECK_LIB(XextSam, XShmAttach,
 697                    HAVE_XSHM="yes", HAVE_XSHM="no",
 698                    $X_LIBS)
 699       if test "x$HAVE_XSHM" = "xyes"; then
 700         XSHM_LIBS="-lXext -lXextSam"
 701       fi
 702     fi
 703   fi
 704 ], ,[
 705   AC_SUBST(HAVE_XSHM)
 706   AC_SUBST(XSHM_LIBS)
 707 ])
 708
 709 dnl for V4L2, we also need to know if we have XVIDEO
 710 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 711 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 712                   [], [
 713   AG_GST_CHECK_XV
 714 ])
 715
 716 dnl *** ext plug-ins ***
 717 dnl keep this list sorted alphabetically !
 718
 719 if test "x$BUILD_EXTERNAL" = "xyes"; then
 720
 721 echo
 722 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 723 echo
 724
 725 dnl *** aalib ***
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 727 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 728   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 729   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 730 ])
 731
 732 dnl *** annodex ***
 733 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 734 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 735   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 736 ])
 737
 738 dnl *** cairo ***
 739 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 740 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 741   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 742 ])
 743
 744 dnl *** cairo-gobject ***
 745 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 746 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 747   [Cairo graphics rendering gobject bindings], cairooverlay, [
 748   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 749 ])
 750
 751 dnl **** ESound ****
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 753 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 754   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 755   if test $HAVE_ESD = no
 756   then
 757     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 758     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 759   fi
 760 ])
 761
 762 dnl *** FLAC ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 764 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 765   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 766 ])
 767
 768 dnl *** GConf ***
 769 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 770 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 771   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 772 ])
 773
 774 dnl *** GDK pixbuf ***
 775 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 776 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 777   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 778 ])
 779
 780 dnl *** HAL ***
 781 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 782 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 783   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 784 ])
 785
 786 dnl *** Jack ***
 787 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 788 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 789   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 790   AC_SUBST(JACK_CFLAGS)
 791   AC_SUBST(JACK_LIBS)
 792
 793   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 794   if test x$HAVE_JACK_0_120_1 = xyes; then
 795     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 796   fi
 797   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 798   if test x$HAVE_JACK_1_9_7 = xyes; then
 799     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 800   fi
 801
 802 ])
 803
 804 dnl *** jpeg ***
 805 dnl FIXME: we could use header checks here as well IMO
 806 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 807 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 808   AC_ARG_WITH(jpeg-mmx,
 809     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 810   OLD_LIBS="$LIBS"
 811   if test x$with_jpeg_mmx != x; then
 812     LIBS="$LIBS -L$with_jpeg_mmx"
 813   fi
 814   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 815   JPEG_LIBS="$LIBS -ljpeg-mmx"
 816   LIBS="$OLD_LIBS"
 817   if test x$HAVE_JPEG != xyes; then
 818     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 819     JPEG_LIBS="-ljpeg"
 820   fi
 821   AC_SUBST(JPEG_LIBS)
 822 ])
 823
 824 dnl *** libcaca ***
 825 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 826 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 827   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 828   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 829   if test "x$HAVE_LIBCACA" != "xyes"; then
 830     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 831     dnl see if it compilation works too, might not if we are cross-compiling
 832     if test "x$HAVE_LIBCACA" = "xyes"; then
 833       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 834                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 835     fi
 836   fi
 837 ])
 838
 839 dnl *** libdv ***
 840 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 841 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 842   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 843 ])
 844
 845 dnl *** libpng ***
 846 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 847 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 848   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 849 ])
 850
 851 dnl *** pulseaudio ***
 852 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 853 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 854
 855   dnl used in ext/pulse/pulseutil.c
 856   AC_CHECK_HEADERS([process.h])
 857
 858   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 859   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 860   if test x$HAVE_PULSE_0_9_11 = xyes; then
 861     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 862   fi
 863   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 864   if test x$HAVE_PULSE_0_9_12 = xyes; then
 865     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 866   fi
 867   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 868   if test x$HAVE_PULSE_0_9_13 = xyes; then
 869     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 870   fi
 871   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 872   if test x$HAVE_PULSE_0_9_15 = xyes; then
 873     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 874   fi
 875   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_16, libpulse >= 0.9.16)
 876   if test x$HAVE_PULSE_0_9_16 = xyes; then
 877     AC_DEFINE(HAVE_PULSE_0_9_16, 1, [defined if pulseaudio >= 0.9.16 is available])
 878   fi
 879   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 880   if test x$HAVE_PULSE_0_9_20 = xyes; then
 881     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 882   fi
 883 ])
 884
 885 dnl *** dv1394 ***
 886 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 887 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 888   dnl first test for libraw1394 >= 2.0.0
 889   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 890   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 891   dnl now see how far we got
 892   if test x$HAVE_RAW1394 = xyes && \
 893      test x$HAVE_LIBIEC61883 = xyes; then
 894        AG_GST_CHECK_LIBHEADER(AVC1394,
 895         avc1394, avc1394_send_command, $RAW1394_LIBS,
 896         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 897        AG_GST_CHECK_LIBHEADER(ROM1394,
 898         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 899         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 900        if test x$HAVE_AVC1394 = xyes && \
 901           test x$HAVE_AVC1394 = xyes && \
 902           test x$HAVE_ROM1394 = xyes; then
 903           HAVE_DV1394=yes
 904           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 905           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 906           AC_SUBST(DV1394_CFLAGS)
 907           AC_SUBST(DV1394_LIBS)
 908         fi
 909   else
 910        if test x$HAVE_RAW1394 = xno; then
 911           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 912           AG_GST_CHECK_LIBHEADER(AVC1394,
 913            avc1394, avc1394_send_command, $RAW1394_LIBS,
 914            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 915           AG_GST_CHECK_LIBHEADER(ROM1394,
 916            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 917            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 918           if test x$HAVE_RAW1394 = xyes && \
 919              test x$HAVE_AVC1394 = xyes && \
 920              test x$HAVE_ROM1394 = xyes; then
 921              HAVE_DV1394=yes
 922              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 923              DV1394_CFLAGS="$RAW1394_CFLAGS"
 924              if test x$HAVE_LIBIEC61883 = xyes; then
 925                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 926                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 927              fi
 928              AC_SUBST(DV1394_CFLAGS)
 929              AC_SUBST(DV1394_LIBS)
 930            fi
 931          fi
 932   fi
 933 ])
 934 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 935
 936 dnl *** shout2 ***
 937 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 938 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 939   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 940   if test $HAVE_SHOUT2 = no
 941   then
 942     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 943     AC_SUBST(SHOUT2_CFLAGS)
 944     AC_SUBST(SHOUT2_LIBS)
 945   fi
 946 ])
 947
 948 dnl *** soup ***
 949 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 950 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 951   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 952     HAVE_SOUP="yes"
 953     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 954   ],[
 955     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 956       HAVE_SOUP="no"
 957     ])
 958   ])
 959   AC_SUBST(SOUP_CFLAGS)
 960   AC_SUBST(SOUP_LIBS)
 961 ])
 962
 963 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 964 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 965 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 966 dnl   speex_jitter.h is 1.1.x only
 967 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 968 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 969   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 970   if test $HAVE_SPEEX = no
 971   then
 972     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 973       AC_CHECK_HEADER(speex/speex_jitter.h, [
 974         dnl speex 1.1.x :
 975         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 976           dnl speex 1.1.5 or + :
 977           HAVE_SPEEX="yes"
 978           SPEEX_LIBS="-lspeex"
 979           AC_SUBST(SPEEX_CFLAGS)
 980           AC_SUBST(SPEEX_LIBS)
 981         ],[
 982           HAVE_SPEEX="no"
 983         ])
 984       ],[
 985         dnl speex 1.0.x :
 986           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 987             dnl speex 1.0.4
 988             HAVE_SPEEX="yes"
 989             SPEEX_LIBS="-lspeex"
 990             AC_SUBST(SPEEX_CFLAGS)
 991             AC_SUBST(SPEEX_LIBS)
 992
 993             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 994               [defined if speex 1.0.x API detected])
 995         ],[
 996             HAVE_SPEEX="no"
 997             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 998         ], [
 999 #include <speex/speex.h>
1000         ])
1001       ])
1002     ])
1003   fi
1004 ])
1005
1006 dnl *** taglib ***
1007 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
1008 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
1009   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
1010   if test "x$HAVE_CXX" != "xyes"; then
1011     USE_TAGLIB=false
1012     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
1013   else
1014     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
1015     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
1016         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
1017       ], [
1018         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
1019     ])
1020     AC_SUBST(TAGLIB_CXXFLAGS)
1021   fi
1022 ])
1023
1024 dnl *** wavpack ***
1025 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
1026 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
1027   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
1028     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
1029       HAVE_WAVPACK=yes
1030       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
1031     ],[
1032       HAVE_WAVPACK=no
1033     ])
1034   ])
1035   AC_SUBST(WAVPACK_CFLAGS)
1036   AC_SUBST(WAVPACK_LIBS)
1037 ])
1038
1039 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
1040 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
1041 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
1042   AG_GST_CHECK_LIBHEADER(ZLIB,
1043     z, uncompress,, zlib.h, [
1044     HAVE_ZLIB="yes"
1045     ZLIB_LIBS="-lz"
1046     AC_SUBST(ZLIB_LIBS)
1047   ])
1048 ])
1049
1050 dnl *** matroska prefers to have bz2 ***
1051 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
1052 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
1053   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
1054   AC_SUBST(BZ2_LIBS)
1055 ])
1056
1057 else
1058
1059 dnl not building plugins with external dependencies,
1060 dnl but we still need to set the conditionals
1061 AM_CONDITIONAL(USE_AALIB, false)
1062 AM_CONDITIONAL(USE_ANNODEX, false)
1063 AM_CONDITIONAL(USE_BZ2, false)
1064 AM_CONDITIONAL(USE_CAIRO, false)
1065 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
1066 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1067 AM_CONDITIONAL(USE_DV1394, false)
1068 AM_CONDITIONAL(USE_ESD, false)
1069 AM_CONDITIONAL(USE_FLAC, false)
1070 AM_CONDITIONAL(USE_GCONF, false)
1071 AM_CONDITIONAL(USE_GCONFTOOL, false)
1072 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1073 AM_CONDITIONAL(USE_GST_V4L2, false)
1074 AM_CONDITIONAL(USE_HAL, false)
1075 AM_CONDITIONAL(USE_JACK, false)
1076 AM_CONDITIONAL(USE_JPEG, false)
1077 AM_CONDITIONAL(USE_LIBCACA, false)
1078 AM_CONDITIONAL(USE_LIBDV, false)
1079 AM_CONDITIONAL(USE_LIBIEC61883, false)
1080 AM_CONDITIONAL(USE_LIBPNG, false)
1081 AM_CONDITIONAL(USE_OSS, false)
1082 AM_CONDITIONAL(USE_OSS4, false)
1083 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1084 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1085 AM_CONDITIONAL(USE_PULSE, false)
1086 AM_CONDITIONAL(USE_SHOUT2, false)
1087 AM_CONDITIONAL(USE_SOUP, false)
1088 AM_CONDITIONAL(USE_SPEEX, false)
1089 AM_CONDITIONAL(USE_SUNAUDIO, false)
1090 AM_CONDITIONAL(USE_TAGLIB, false)
1091 AM_CONDITIONAL(USE_WAVPACK, false)
1092 AM_CONDITIONAL(USE_X, false)
1093 AM_CONDITIONAL(USE_XSHM, false)
1094 AM_CONDITIONAL(USE_XVIDEO, false)
1095 AM_CONDITIONAL(USE_ZLIB, false)
1096
1097 fi dnl of EXT plugins
1098
1099 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1100
1101 dnl Overview:
1102 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1103 dnl GST_*:              flags shared by all built objects
1104 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1105 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1106 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1107 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1108
1109 dnl GST_OPTION_CFLAGS
1110 if test "x$USE_DEBUG" = xyes; then
1111    PROFILE_CFLAGS="-g"
1112 fi
1113 AC_SUBST(PROFILE_CFLAGS)
1114
1115 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1116   dnl Define _only_ for git (not pre-releases or releases)
1117   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1118 else
1119   DEPRECATED_CFLAGS=""
1120 fi
1121 AC_SUBST(DEPRECATED_CFLAGS)
1122
1123 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1124 dnl at make time with e.g. make ERROR_CFLAGS=""
1125 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1126 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1127 AC_SUBST(GST_OPTION_CFLAGS)
1128 AC_SUBST(GST_OPTION_CXXFLAGS)
1129
1130 dnl our libraries need to be versioned correctly
1131 AC_SUBST(GST_LT_LDFLAGS)
1132
1133 dnl FIXME: do we want to rename to GST_ALL_* ?
1134 dnl prefer internal headers to already installed ones
1135 dnl also add builddir include for enumtypes and marshal
1136 dnl add ERROR_CFLAGS, but overridable
1137 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1138 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1139 AC_SUBST(GST_CFLAGS)
1140 AC_SUBST(GST_CXXFLAGS)
1141 AC_SUBST(GST_LIBS)
1142
1143 dnl LDFLAGS really should only contain flags, not libs - they get added before
1144 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1145 GST_ALL_LDFLAGS="-no-undefined"
1146 AC_SUBST(GST_ALL_LDFLAGS)
1147
1148 dnl this really should only contain flags, not libs - they get added before
1149 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1150 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1151 AC_SUBST(GST_PLUGIN_LDFLAGS)
1152
1153 dnl *** output files ***
1154
1155 dnl keep this alphabetic per directory, please
1156 AC_CONFIG_FILES(
1157 Makefile
1158 gst/Makefile
1159 gst/alpha/Makefile
1160 gst/apetag/Makefile
1161 gst/audiofx/Makefile
1162 gst/audioparsers/Makefile
1163 gst/auparse/Makefile
1164 gst/autodetect/Makefile
1165 gst/avi/Makefile
1166 gst/cutter/Makefile
1167 gst/deinterlace/Makefile
1168 gst/debugutils/Makefile
1169 gst/effectv/Makefile
1170 gst/equalizer/Makefile
1171 gst/flv/Makefile
1172 gst/goom/Makefile
1173 gst/goom2k1/Makefile
1174 gst/id3demux/Makefile
1175 gst/icydemux/Makefile
1176 gst/imagefreeze/Makefile
1177 gst/interleave/Makefile
1178 gst/isomp4/Makefile
1179 gst/law/Makefile
1180 gst/level/Makefile
1181 gst/matroska/Makefile
1182 gst/monoscope/Makefile
1183 gst/multifile/Makefile
1184 gst/multipart/Makefile
1185 gst/replaygain/Makefile
1186 gst/rtp/Makefile
1187 gst/rtpmanager/Makefile
1188 gst/rtsp/Makefile
1189 gst/shapewipe/Makefile
1190 gst/smpte/Makefile
1191 gst/spectrum/Makefile
1192 gst/udp/Makefile
1193 gst/videobox/Makefile
1194 gst/videocrop/Makefile
1195 gst/videofilter/Makefile
1196 gst/videomixer/Makefile
1197 gst/wavenc/Makefile
1198 gst/wavparse/Makefile
1199 gst/flx/Makefile
1200 gst/y4m/Makefile
1201 ext/Makefile
1202 ext/aalib/Makefile
1203 ext/annodex/Makefile
1204 ext/cairo/Makefile
1205 ext/dv/Makefile
1206 ext/esd/Makefile
1207 ext/flac/Makefile
1208 ext/gconf/Makefile
1209 ext/gdk_pixbuf/Makefile
1210 ext/hal/Makefile
1211 ext/jack/Makefile
1212 ext/jpeg/Makefile
1213 ext/libcaca/Makefile
1214 ext/libpng/Makefile
1215 ext/pulse/Makefile
1216 ext/raw1394/Makefile
1217 ext/shout2/Makefile
1218 ext/soup/Makefile
1219 ext/speex/Makefile
1220 ext/taglib/Makefile
1221 ext/wavpack/Makefile
1222 sys/Makefile
1223 sys/directsound/Makefile
1224 sys/oss/Makefile
1225 sys/oss4/Makefile
1226 sys/osxaudio/Makefile
1227 sys/osxvideo/Makefile
1228 sys/sunaudio/Makefile
1229 sys/v4l2/Makefile
1230 sys/waveform/Makefile
1231 sys/ximage/Makefile
1232 po/Makefile.in
1233 tests/Makefile
1234 tests/check/Makefile
1235 tests/examples/Makefile
1236 tests/examples/audiofx/Makefile
1237 tests/examples/cairo/Makefile
1238 tests/examples/equalizer/Makefile
1239 tests/examples/jack/Makefile
1240 tests/examples/level/Makefile
1241 tests/examples/pulse/Makefile
1242 tests/examples/rtp/Makefile
1243 tests/examples/shapewipe/Makefile
1244 tests/examples/spectrum/Makefile
1245 tests/examples/v4l2/Makefile
1246 tests/files/Makefile
1247 tests/icles/Makefile
1248 gconf/Makefile
1249 gconf/gstreamer.schemas
1250 common/Makefile
1251 common/m4/Makefile
1252 m4/Makefile
1253 docs/Makefile
1254 docs/plugins/Makefile
1255 docs/version.entities
1256 pkgconfig/Makefile
1257 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1258 gst-plugins-good.spec
1259 )
1260
1261 dnl Create the config.h file for Visual Studio builds
1262 dnl Beware of spaces and /'s in some of the shell variable contents.
1263 sed \
1264     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1265     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1266     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1267     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1268     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1269     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1270     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1271     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1272     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1273     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1274     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1275     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1276     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1277     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1278     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1279     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1280     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1281     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1282     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1283     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1284     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1285     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1286     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1287     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1288     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1289     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1290     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1291     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1292     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1293     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1294     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1295     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1296     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1297     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1298     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1299     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1300     config.h.in >win32/common/config.h-new
1301
1302 AC_OUTPUT
1303
1304 AG_GST_OUTPUT_PLUGINS
1305 ORC_OUTPUT
1306