configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/librygel-core/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1 tar-ustar no-dist-gzip dist-xz -Wno-portability])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 dnl Required versions of library packages
  31 GLIB_REQUIRED=2.31.13
  32 VALA_REQUIRED=0.16.1
  33 VALADOC_REQUIRED=0.2
  34 GSSDP_REQUIRED=0.13.0
  35 GUPNP_REQUIRED=0.19.0
  36 GUPNP_AV_REQUIRED=0.11.0
  37 GUPNP_DLNA_REQUIRED=0.5.0
  38 GSTREAMER_REQUIRED=0.10.36
  39 GSTPBU_REQUIRED=0.10.35
  40 GIO_REQUIRED=2.26
  41 GEE_REQUIRED=0.5.2
  42 UUID_REQUIRED=1.41.3
  43 LIBSOUP_REQUIRED=2.34.0
  44 GTK_REQUIRED=2.90.3
  45
  46 dnl Additional requirements for media-export plugin
  47 GSTREAMER_TAG_REQUIRED=0.10.28
  48 GSTREAMER_APP_REQUIRED=0.10.28
  49 LIBSQLITE3_REQUIRED=3.5
  50
  51 dnl Additional requirements for tracker plugin
  52 TRACKER_SPARQL_REQUIRED_MIN=0.14.0
  53
  54 PKG_CHECK_MODULES(LIBGLIB, glib-2.0 >= $GLIB_REQUIRED)
  55 VALAFLAGS="--target-glib=2.32 $VALAFLAGS"
  56
  57 PKG_CHECK_MODULES(LIBGSSDP, gssdp-1.0 >= $GSSDP_REQUIRED)
  58 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED)
  59 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED)
  60 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  61 PKG_CHECK_MODULES(GEE, gee-1.0 >= $GEE_REQUIRED)
  62 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  63 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED)
  64
  65 dnl Media engine to use
  66 BUILT_ENGINES="librygel-media-engine-simple"
  67
  68 AC_ARG_WITH([media_engine],
  69             AS_HELP_STRING(
  70                 [--with-media-engine=@<:@gstreamer|none@:>@],
  71                 [Media Engine to use]),
  72             [with_media_engine="$withval"],
  73             [with_media_engine="gstreamer"])
  74
  75 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  76       [
  77         PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.0 >= $GUPNP_DLNA_REQUIRED)
  78         PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED)
  79         PKG_CHECK_MODULES(GSTREAMER_BASE, gstreamer-base-0.10 >= $GSTREAMER_REQUIRED)
  80         PKG_CHECK_MODULES(GST_PBU, gstreamer-pbutils-0.10 >= $GSTPBU_REQUIRED)
  81         enable_gstreamer="yes"
  82         BUILT_ENGINES="$BUILT_ENGINES;librygel-media-engine-gst"
  83       ],
  84       [enable_gstreamer="no"])
  85 AM_CONDITIONAL([HAVE_GSTREAMER],[test "x$enable_gstreamer" = "xyes"])
  86 AC_SUBST([BUILT_ENGINES])
  87
  88 dnl Add plugins
  89 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
  90 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
  91 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
  92 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
  93
  94 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  95       [
  96         RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
  97         RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
  98         RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
  99         RYGEL_ADD_STAMP([src/media-engines/gstreamer/librygel_media_engine_gst_la_vala.stamp])
 100         RYGEL_ADD_STAMP([src/librygel-renderer-gst/librygel_renderer_gst_2_0_la_vala.stamp])
 101       ],
 102       [
 103         RYGEL_DISABLE_PLUGIN([playbin])
 104         RYGEL_DISABLE_PLUGIN([media-export])
 105         RYGEL_DISABLE_PLUGIN([gst-launch])
 106       ])
 107
 108 dnl Example plugins:
 109 AC_ARG_ENABLE([example-plugins],
 110               AS_HELP_STRING([--enable-example-plugins],[enable example plugins]),,
 111               enable_example_plugins=no)
 112 AM_CONDITIONAL([BUILD_EXAMPLE_PLUGINS], [test "x$[]enable_example_plugins" = "xyes"])
 113
 114 dnl Explicitly add stamp files for targets that are not plugins
 115 RYGEL_ADD_STAMP([src/librygel-core/librygel_core_2_0_la_vala.stamp])
 116 RYGEL_ADD_STAMP([src/librygel-server/librygel_server_2_0_la_vala.stamp])
 117 RYGEL_ADD_STAMP([src/librygel-renderer/librygel_renderer_2_0_la_vala.stamp])
 118 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
 119 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
 120 RYGEL_ADD_STAMP([src/media-engines/simple/librygel_media_engine_simple_la_vala.stamp])
 121
 122 RYGEL_CHECK_VALA([$VALA_REQUIRED],
 123                  [gupnp-1.0
 124                   gupnp-av-1.0
 125                   gio-2.0
 126                   gee-1.0
 127                   posix])
 128
 129 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 130       [
 131         RYGEL_CHECK_PACKAGES([gupnp-dlna-1.0 gstreamer-0.10 gstreamer-pbutils-0.10])
 132       ])
 133
 134 dnl Debugging
 135 AC_ARG_ENABLE(debug,
 136         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 137         enable_debug=no)
 138 if test "x$enable_debug" = "xyes"; then
 139         CFLAGS="$CFLAGS -O0 -g"
 140         RYGEL_DEBUG_VALAFLAGS="-g"
 141 fi
 142
 143 AC_SUBST(RYGEL_DEBUG_VALAFLAGS)
 144
 145 dnl Strict compiler
 146 AC_ARG_ENABLE(strict-cc,
 147         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 148         enable_strict_cc=no)
 149 if test "x$enable_strict_cc" = "xyes"; then
 150         CFLAGS="$CFLAGS -Wall -Werror"
 151 else
 152         CFLAGS="$CFLAGS -w"
 153 fi
 154
 155 dnl Run uninstalled
 156 AC_ARG_ENABLE(uninstalled,
 157     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 158         enable_uninstalled=no)
 159 if test "x$enable_uninstalled" = "xyes"; then
 160         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 161 fi
 162 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 163
 164 dnl Check wether user wants to build UIs
 165 AC_ARG_WITH( ui,
 166   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 167   try_ui=$withval, try_ui=yes )
 168
 169 HAVE_GTK=no
 170 if test x$try_ui = xyes ; then
 171     dnl check for gtk
 172     PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQUIRED,
 173       [
 174         RYGEL_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 175       ],
 176       [
 177         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 178         AC_MSG_WARN([UI applications will not be built.])
 179       ])
 180 else
 181     AC_MSG_NOTICE([UI applications disabled.])
 182 fi
 183
 184 AM_CONDITIONAL(BUILD_UI, test "x$HAVE_GTK" = "xyes")
 185
 186 dnl Tests
 187 AC_ARG_ENABLE([tests],
 188               AS_HELP_STRING([--enable-tests],[always build tests]),,
 189               enable_tests=no)
 190 AM_CONDITIONAL([ALWAYS_TEST], [test "x$enable_tests" = "xyes"])
 191
 192 dnl Generate coverage data
 193 AC_ARG_ENABLE([coverage],
 194   AS_HELP_STRING([--enable-coverage],
 195                  [Generate converage reports for unit tests]),
 196   [],
 197   [enable_coverage=no])
 198 AM_CONDITIONAL([ENABLE_COVERAGE],[test "x$enable_coverage" != "xno"])
 199 AS_IF([test "x$enable_coverage" != "xno"],
 200   [
 201     AC_PATH_PROG([LCOV], [lcov])
 202     AC_PATH_PROG([GENHTML], [genhtml])
 203     AC_SUBST([COVERAGE_LIBS],["-lgcov"])
 204     AC_SUBST([COVERAGE_CFLAGS],["-fprofile-arcs -ftest-coverage"])
 205     AC_SUBST(COVERAGE_VALAFLAGS,["-g"])
 206   ]
 207 )
 208
 209 dnl Check additional requirements for MediaExport plugins
 210 if test "x$enable_media_export_plugin" = "xyes";
 211 then
 212     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 213     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-0.10 >= $GSTREAMER_TAG_REQUIRED);
 214     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-0.10 >= $GSTREAMER_APP_REQUIRED);
 215     RYGEL_CHECK_PACKAGES([sqlite3 gstreamer-tag-0.10 gstreamer-app-0.10])
 216     AC_CHECK_HEADER([unistr.h],
 217                     AC_CHECK_LIB([unistring],
 218                                  [u8_strcoll],
 219                                  [have_unistring=yes],[have_unistring=no]))
 220     if test "x$have_unistring" = "xyes"; then
 221         AC_DEFINE([HAVE_UNISTRING],[1],[Use libunistring for collation])
 222         COLLATION_CFLAGS=
 223         COLLATION_LIBS=-lunistring
 224         AC_SUBST([COLLATION_CFLAGS])
 225         AC_SUBST([COLLATION_LIBS])
 226     fi
 227 fi
 228
 229 AS_IF([test "x$enable_tracker_plugin" = "xyes"],
 230   [
 231     PKG_CHECK_MODULES(TRACKER_SPARQL,
 232                       tracker-sparql-0.14 >= $TRACKER_SPARQL_REQUIRED_MIN)
 233     AS_IF([test "x$enable_vala" = "xyes"],
 234           [VALA_CHECK_PACKAGES([tracker-sparql-0.14])])
 235   ])
 236
 237 dnl Gettext
 238 GETTEXT_PACKAGE=rygel
 239 AC_SUBST(GETTEXT_PACKAGE)
 240 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 241   [Define the gettext package to be used])
 242
 243 AM_GLIB_GNU_GETTEXT
 244 IT_PROG_INTLTOOL([0.40.0])
 245
 246 dnl Shave the output
 247 AM_SILENT_RULES([yes])
 248
 249 dnl documenation
 250 AC_PATH_PROG([XSLTPROC], [xsltproc])
 251 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 252
 253 dnl Use valadoc for API documentation:
 254 dnl This is on by default when using autogen.sh
 255 dnl (so it is not on by default when building from a tarball with configure.)
 256 AC_ARG_ENABLE(valadoc,
 257   AS_HELP_STRING([--enable-valadoc[=@<:@no/auto/yes@:>@]], [Enable valadoc support]),,
 258     [enable_valadoc=no])
 259
 260 found_valadoc=no
 261 AS_IF([test "x$enable_valadoc" != "xno"], [
 262     AC_PATH_PROG(VALADOC, valadoc, :)
 263     AS_IF([test -x "$VALADOC"], [
 264       found_valadoc=yes
 265       AC_SUBST(VALADOC)
 266       PKG_CHECK_MODULES([GTKDOC],[gtk-doc >= 1.0])
 267     ], [
 268       AS_IF([test "x$enable_valadoc" == "xyes"], AC_MSG_ERROR([Unable to find valadoc]))
 269     ])
 270   ])
 271
 272 AM_CONDITIONAL(ENABLE_VALADOC, test x$found_valadoc = xyes)
 273
 274 AC_CONFIG_FILES([
 275 Makefile
 276 src/Makefile
 277 src/librygel-core/Makefile
 278 src/librygel-renderer/Makefile
 279 src/librygel-renderer-gst/Makefile
 280 src/librygel-server/Makefile
 281 src/rygel/Makefile
 282 src/ui/Makefile
 283 src/media-engines/Makefile
 284 src/media-engines/gstreamer/Makefile
 285 src/media-engines/simple/Makefile
 286 src/plugins/Makefile
 287 data/Makefile
 288 data/xml/Makefile
 289 data/icons/Makefile
 290 data/icons/32x32/Makefile
 291 data/icons/48x48/Makefile
 292 data/icons/120x120/Makefile
 293 data/icons/128x128/Makefile
 294 data/icons/scalable/Makefile
 295 data/rygel.desktop.in
 296 data/rygel-preferences.desktop.in
 297 doc/Makefile
 298 doc/reference/Makefile
 299 doc/reference/librygel-core/Makefile
 300 doc/reference/librygel-renderer/Makefile
 301 doc/reference/librygel-server/Makefile
 302 doc/reference/librygel-renderer-gst/Makefile
 303 po/Makefile.in
 304 rygel-core-2.0.pc
 305 rygel-renderer-2.0.pc
 306 rygel-server-2.0.pc
 307 rygel-renderer-gst-2.0.pc
 308 tests/Makefile
 309 examples/Makefile
 310 examples/server-plugins/Makefile
 311 examples/server-plugins/vala/Makefile
 312 ])
 313 AC_OUTPUT
 314
 315 echo "
 316
 317                     ${PACKAGE} ${VERSION}
 318                     ============
 319
 320
 321         Prefix:                 ${prefix}
 322         Source code location:   ${srcdir}
 323         Compiler:               ${CC}
 324         CFLAGS:                 ${CFLAGS}
 325         VALAFLAGS:              ${VALAFLAGS}
 326         uninstalled:            ${enable_uninstalled}
 327         preferences ui:         ${HAVE_GTK}
 328         Media Engine:           ${with_media_engine}
 329     Plugins:
 330         examples:               ${enable_example_plugins}
 331         test:                   ${enable_test_plugin}
 332         tracker:                ${enable_tracker_plugin}
 333         mediathek:              ${enable_mediathek_plugin}
 334         media-export            ${enable_media_export_plugin}
 335         external:               ${enable_external_plugin}
 336         MPRIS2:                 ${enable_mpris_plugin}
 337         gst-launch:             ${enable_gst_launch_plugin}
 338         playbin:                ${enable_playbin_plugin}
 339 "