configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of PulseAudio.
   7 #
   8 # Copyright 2004-2008 Lennart Poettering
   9 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
  10 #
  11 # PulseAudio is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU Lesser General Public License as published by
  13 # the Free Software Foundation; either version 2 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # PulseAudio is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  19 # General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public License
  22 # along with PulseAudio; if not, write to the Free Software Foundation,
  23 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  24
  25 AC_PREREQ(2.60)
  26
  27 m4_define(PA_MAJOR, [0])
  28 m4_define(PA_MINOR, [9])
  29 m4_define(PA_MICRO, [10])
  30
  31 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzchyfrnhqvb (at) 0pointer (dot) net])
  32 AC_CONFIG_SRCDIR([src/daemon/main.c])
  33 AC_CONFIG_HEADERS([config.h])
  34 AM_INIT_AUTOMAKE([foreign -Wall])
  35
  36 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  37 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
  38
  39 AC_SUBST(PA_API_VERSION, 11)
  40 AC_SUBST(PA_PROTOCOL_VERSION, 12)
  41
  42 # The stable ABI for client applications, for the version info x:y:z
  43 # always will hold y=z
  44 AC_SUBST(LIBPULSE_VERSION_INFO, [4:1:4])
  45
  46 # A simplified, synchronous, ABI-stable interface for client
  47 # applications, for the version info x:y:z always will hold y=z
  48 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:1:0])
  49
  50 # The ABI-stable network browsing interface for client applications,
  51 # for the version info x:y:z always will hold y=z
  52 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  53
  54 # The ABI-stable GLib adapter for client applications, for the version
  55 # info x:y:z always will hold y=z
  56 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:3:0])
  57
  58 # An internally used, ABI-unstable library that contains the
  59 # PulseAudio core, SONAMEs are bumped on every release, version info
  60 # suffix will always be 0:0
  61 AC_SUBST(LIBPULSECORE_VERSION_INFO, [5:1:0])
  62
  63 AC_CANONICAL_HOST
  64
  65 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  66    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  67    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  68 fi
  69
  70 #### Platform hacks ####
  71
  72 case $host in
  73    *-*-solaris* )
  74       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  75       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  76       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  77       ;;
  78 esac
  79
  80 #### Checks for programs. ####
  81
  82 # mkdir -p
  83
  84 AC_PROG_MKDIR_P
  85
  86 # CC
  87
  88 AC_PROG_CC
  89 AM_PROG_CC_C_O
  90 AC_PROG_GCC_TRADITIONAL
  91 AC_GNU_SOURCE
  92
  93 # M4
  94
  95 AC_PATH_PROG([M4], [m4 gm4], [no])
  96 if test "x$M4" = xno ; then
  97    AC_MSG_ERROR([m4 missing])
  98 fi
  99
 100 # GCC flags
 101
 102 test_gcc_flag() {
 103     AC_LANG_CONFTEST([int main(int argc, char*argv[]) {}])
 104     $CC -c conftest.c $CFLAGS -o conftest.o > /dev/null 2> /dev/null
 105     ret=$?
 106     rm -f conftest.o
 107     return $ret
 108 }
 109
 110 # If using GCC specify some additional parameters
 111 if test "x$GCC" = "xyes" ; then
 112
 113     # We use gnu99 instead of c99 because many have interpreted the standard
 114     # in a way that int64_t isn't defined on non-64 bit platforms.
 115     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter -ffast-math"
 116
 117     for flag in $DESIRED_FLAGS ; do
 118         AC_MSG_CHECKING([whether $CC accepts $flag])
 119         if test_gcc_flag $flag ; then
 120            CFLAGS="$CFLAGS $flag"
 121            AC_MSG_RESULT([yes])
 122         else
 123            AC_MSG_RESULT([no])
 124         fi
 125     done
 126 fi
 127
 128 # Native atomic operation support
 129 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 130     AC_HELP_STRING([--disable-atomic-arm-linux-helpers], [use inline asm or libatomic_ops instead]),
 131         [
 132             case "${enableval}" in
 133                 yes) atomic_arm_linux_helpers=yes ;;
 134                 no) atomic_arm_linux_helpers=no ;;
 135                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 136             esac
 137         ],
 138         [atomic_arm_linux_helpers=auto])
 139
 140 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 141     AC_HELP_STRING([--enable-atomic-arm-memory-barrier], [only really needed in SMP arm systems]),
 142         [
 143             case "${enableval}" in
 144                 yes) AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers]) ;;
 145                 no) ;;
 146                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 147             esac
 148         ],)
 149
 150 AC_MSG_CHECKING([target operating system])
 151 case $host in
 152         *-*-linux*)
 153             AC_MSG_RESULT([linux])
 154             pulse_target_os=linux
 155         ;;
 156         *)
 157             AC_MSG_RESULT([unknown])
 158             pulse_target_os=unknown
 159         ;;
 160 esac
 161
 162 # If everything else fails use libatomic_ops
 163 need_libatomic_ops=yes
 164
 165 AC_MSG_CHECKING([whether $CC knows __sync_bool_compare_and_swap()])
 166 AC_LANG_CONFTEST([int main() { int a = 4; __sync_bool_compare_and_swap(&a, 4, 5); }])
 167 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 168 ret=$?
 169 rm -f conftest.o conftest
 170 if test $ret -eq 0 ; then
 171     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 172     AC_MSG_RESULT([yes])
 173     need_libatomic_ops=no
 174 else
 175     AC_MSG_RESULT([no])
 176     # HW specific atomic ops stuff
 177     AC_MSG_CHECKING([architecture for native atomic operations])
 178     case $host_cpu in
 179         arm*)
 180             AC_MSG_RESULT([arm])
 181             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 182             # The Linux kernel helper functions have been there since 2.6.16. However
 183             # compile time checking for kernel version in cross compile environment
 184             # (which is usually the case for arm cpu) is tricky (or impossible).
 185             if test "x$pulse_target_os" = "xlinux" && test "x$atomic_arm_linux_helpers" != "xno"; then
 186                 AC_MSG_RESULT([yes])
 187                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 188                 need_libatomic_ops=no
 189             else
 190                AC_MSG_RESULT([no])
 191                AC_MSG_CHECKING([compiler support for arm inline asm atomic operations])
 192                AC_LANG_CONFTEST([[int main()
 193                {
 194                    volatile int a=0;
 195                    int o=0, n=1, r;
 196                    asm volatile ("ldrex %0, [%1]\n"
 197                                  "subs  %0, %0, %2\n"
 198                                  "strexeq %0, %3, [%1]\n"
 199                                  : "=&r" (r)
 200                                  : "r" (&a), "Ir" (o), "r" (n)
 201                                  : "cc");
 202                    return (a==1 ? 0 : -1);
 203                }]])
 204                $CC conftest.c $CFLAGS -o conftest > /dev/null 2>&1
 205                ret=$?
 206                rm -f conftest.o conftest
 207                if test $ret -eq 0 ; then
 208                    AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARMv6 instructions.])
 209                    AC_MSG_RESULT([yes])
 210                    need_libatomic_ops=no
 211                else
 212                    AC_MSG_RESULT([no])
 213                fi
 214            fi
 215         ;;
 216         *)
 217             AC_MSG_RESULT([unknown])
 218         ;;
 219     esac
 220 fi
 221
 222 AC_MSG_CHECKING([whether $CC knows __thread])
 223 AC_LANG_CONFTEST([static __thread int a = 6; int main() { a = 5; }])
 224 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 225 ret=$?
 226 rm -f conftest.o conftest
 227 if test $ret -eq 0 ; then
 228     AC_DEFINE([HAVE_TLS_BUILTIN], 1, [Have __thread().])
 229     AC_MSG_RESULT([yes])
 230 else
 231     AC_MSG_RESULT([no])
 232 fi
 233
 234 AC_MSG_CHECKING([whether $CC knows _Bool])
 235 AC_LANG_CONFTEST([int main() { _Bool b; }])
 236 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 237 ret=$?
 238 rm -f conftest.o conftest
 239 if test $ret -eq 0 ; then
 240     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 241     AC_MSG_RESULT([yes])
 242 else
 243     AC_MSG_RESULT([no])
 244 fi
 245
 246 #### libtool stuff ####
 247
 248 AC_LTDL_ENABLE_INSTALL
 249 AC_LIBLTDL_INSTALLABLE
 250 AC_LIBTOOL_DLOPEN
 251 AC_LIBTOOL_WIN32_DLL
 252 AC_PROG_LIBTOOL
 253 AC_SUBST(LTDLINCL)
 254 AC_SUBST(LIBLTDL)
 255 AC_CONFIG_SUBDIRS(libltdl)
 256
 257 old_LIBS=$LIBS
 258 LIBS="$LIBS $LIBLTDL"
 259 AC_CHECK_FUNCS([lt_dlmutex_register])
 260 LIBS=$old_LIBS
 261 AC_CHECK_TYPES([struct lt_user_dlloader, lt_dladvise], , , [#include <ltdl.h>])
 262
 263 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 264     AC_MSG_ERROR([[
 265
 266         *** Cannot find the libltdl development files.
 267         *** Maybe you need to install the libltdl-dev package.
 268         ]])
 269 fi
 270
 271 #### Determine build environment ####
 272
 273 os_is_win32=0
 274
 275 case "$host_os" in
 276         mingw*)
 277         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 278         os_is_win32=1
 279                 ;;
 280         esac
 281
 282 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 283
 284 ###################################
 285 #   Basic environment checks      #
 286 ###################################
 287
 288 #### Checks for header files. ####
 289
 290 # ISO
 291 AC_HEADER_STDC
 292
 293 # POSIX
 294 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 295     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 296     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 297     syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 298 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 299                  [#include <sys/types.h>
 300                   #if HAVE_NETINET_IN_H
 301                   # include <netinet/in.h>
 302                   #endif
 303                   #if HAVE_NETINET_IN_SYSTM_H
 304                   # include <netinet/in_systm.h>
 305                   #endif
 306                  ])
 307 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 308 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 309
 310 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 311 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 312
 313 # Linux
 314 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 315
 316 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 317
 318 AC_CHECK_HEADERS([sys/prctl.h])
 319
 320 # Solaris
 321 AC_CHECK_HEADERS([sys/filio.h])
 322
 323 # Windows
 324 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 325
 326 # Other
 327 AC_CHECK_HEADERS([sys/ioctl.h])
 328 AC_CHECK_HEADERS([byteswap.h])
 329 AC_CHECK_HEADERS([sys/syscall.h])
 330
 331 #### Typdefs, structures, etc. ####
 332
 333 AC_C_CONST
 334 AC_C_BIGENDIAN
 335 AC_TYPE_PID_T
 336 AC_TYPE_SIZE_T
 337 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 338     [Define ssize_t if it is not done by the standard libs.])])
 339 AC_TYPE_OFF_T
 340 AC_TYPE_SIGNAL
 341 AC_TYPE_UID_T
 342
 343 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 344 HAVE_SIGXCPU=1
 345 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 346 ], [HAVE_SIGXCPU=0])
 347 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 348
 349 # Solaris lacks this
 350 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 351     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 352         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 353
 354 #### POSIX threads ####
 355
 356 ACX_PTHREAD
 357
 358 #### Check for libs ####
 359
 360 # ISO
 361 AC_SEARCH_LIBS([pow], [m])
 362
 363 # POSIX
 364 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 365 AC_SEARCH_LIBS([dlopen], [dl])
 366 AC_SEARCH_LIBS([shm_open], [rt])
 367 AC_SEARCH_LIBS([inet_ntop], [nsl])
 368 AC_SEARCH_LIBS([timer_create], [rt])
 369
 370 # BSD
 371 AC_SEARCH_LIBS([connect], [socket])
 372
 373 # Non-standard
 374
 375 # This magic is needed so we do not needlessly add static libs to the win32
 376 # build, disabling its ability to make dlls.
 377 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 378
 379 #### Check for functions ####
 380
 381 # ISO
 382 AC_CHECK_FUNCS([lrintf strtof])
 383
 384 # POSIX
 385 AC_FUNC_FORK
 386 AC_FUNC_GETGROUPS
 387 AC_FUNC_SELECT_ARGTYPES
 388 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r \
 389     getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 390     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 391     sigaction sleep sysconf])
 392 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 393
 394 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 395
 396 # X/OPEN
 397 AC_CHECK_FUNCS([readlink])
 398
 399 # SUSv2
 400 AC_CHECK_FUNCS([ctime_r usleep])
 401
 402 # SUSv3
 403 AC_CHECK_FUNCS([strerror_r])
 404
 405 # BSD
 406 AC_CHECK_FUNCS([lstat])
 407
 408 # Non-standard
 409
 410 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 411
 412 AC_MSG_CHECKING([for PTHREAD_PRIO_INHERIT])
 413 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
 414 #include <pthread.h>
 415 int main() { int i = PTHREAD_PRIO_INHERIT; }]])])
 416 $PTHREAD_CC conftest.c $PTHREAD_CFLAGS $CFLAGS $PTHREAD_LIBS -o conftest > /dev/null 2> /dev/null
 417 ret=$?
 418 rm -f conftest.o conftest
 419
 420 if test $ret -eq 0 ; then
 421     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 422     AC_MSG_RESULT([yes])
 423 else
 424     AC_MSG_RESULT([no])
 425 fi
 426
 427 #### Large File-Support (LFS) ####
 428
 429 AC_SYS_LARGEFILE
 430
 431 # Check for open64 to know if the current system does have open64() and similar functions
 432 AC_CHECK_FUNCS([open64])
 433
 434 #### [lib]iconv ####
 435
 436 AM_ICONV
 437
 438 ###################################
 439 #      External libraries         #
 440 ###################################
 441
 442 #### X11 (optional) ####
 443
 444 HAVE_X11=0
 445
 446 # The macro tests the host, not the build target
 447 if test "x$os_is_win32" != "x1" ; then
 448     AC_PATH_XTRA
 449     test "x$no_x" != "xyes" && HAVE_X11=1
 450 fi
 451
 452 AC_SUBST(HAVE_X11)
 453 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 454 if test "x$HAVE_X11" = "x1" ; then
 455     AC_DEFINE([HAVE_X11], 1, [Have X11])
 456 fi
 457
 458 #### Capabilities (optional) ####
 459
 460 CAP_LIBS=''
 461
 462 AC_ARG_WITH(
 463         [caps],
 464         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 465
 466 if test "x${with_caps}" != "xno"; then
 467     AC_SEARCH_LIBS([cap_init], [cap], [], [
 468                     if test "x${with_caps}" = "xyes" ; then
 469                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 470                     fi])
 471     AC_CHECK_HEADERS([sys/capability.h], [], [
 472                     if test "x${with_caps}" = "xyes" ; then
 473                         AC_MSG_ERROR([*** POSIX caps headers not found])
 474                     fi])
 475 fi
 476
 477 #### pkg-config ####
 478
 479 # Check for pkg-config manually first, as if its not installed the
 480 # PKG_PROG_PKG_CONFIG macro won't be defined.
 481 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 482
 483 if test x"$have_pkg_config" = "xno"; then
 484     AC_MSG_ERROR(pkg-config is required to install this program)
 485 fi
 486
 487 PKG_PROG_PKG_CONFIG
 488
 489 #### Sound file ####
 490
 491 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 492 AC_SUBST(LIBSNDFILE_CFLAGS)
 493 AC_SUBST(LIBSNDFILE_LIBS)
 494
 495 #### atomic-ops ###
 496
 497 AC_MSG_CHECKING([whether we need libatomic_ops])
 498 if test "x$need_libatomic_ops" = "xyes"; then
 499    AC_MSG_RESULT([yes])
 500    AC_CHECK_HEADERS([atomic_ops.h], [], [
 501    AC_MSG_ERROR([*** libatomic-ops headers not found])
 502    ])
 503
 504    # Win32 does not need the lib and breaks horribly if we try to include it
 505    if test "x$os_is_win32" != "x1" ; then
 506        LIBS="$LIBS -latomic_ops"
 507    fi
 508 else
 509    AC_MSG_RESULT([no])
 510 fi
 511
 512 #### Libsamplerate support (optional) ####
 513
 514 AC_ARG_ENABLE([samplerate],
 515     AC_HELP_STRING([--disable-samplerate], [Disable optional libsamplerate support]),
 516         [
 517             case "${enableval}" in
 518                 yes) samplerate=yes ;;
 519                 no) samplerate=no ;;
 520                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 521             esac
 522         ],
 523         [samplerate=auto])
 524
 525 if test "x${samplerate}" != xno ; then
 526     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 527         HAVE_LIBSAMPLERATE=1,
 528         [
 529             HAVE_LIBSAMPLERATE=0
 530             if test "x$samplerate" = xyes ; then
 531                 AC_MSG_ERROR([*** Libsamplerate not found])
 532             fi
 533         ])
 534 else
 535     HAVE_LIBSAMPLERATE=0
 536 fi
 537
 538 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 539    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 540 fi
 541
 542 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 543 AC_SUBST(LIBSAMPLERATE_LIBS)
 544 AC_SUBST(HAVE_LIBSAMPLERATE)
 545 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 546
 547 #### OSS support (optional) ####
 548
 549 AC_ARG_ENABLE([oss],
 550     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 551         [
 552             case "${enableval}" in
 553                 yes) oss=yes ;;
 554                 no) oss=no ;;
 555                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 556             esac
 557         ],
 558         [oss=auto])
 559
 560 if test "x${oss}" != xno ; then
 561     AC_CHECK_HEADERS([sys/soundcard.h],
 562         [
 563             HAVE_OSS=1
 564             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 565         ],
 566         [
 567             HAVE_OSS=0
 568             if test "x$oss" = xyes ; then
 569                 AC_MSG_ERROR([*** OSS support not found])
 570             fi
 571         ])
 572 else
 573     HAVE_OSS=0
 574 fi
 575
 576 AC_SUBST(HAVE_OSS)
 577 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 578
 579
 580 #### ALSA support (optional) ####
 581
 582 AC_ARG_ENABLE([alsa],
 583     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 584         [
 585             case "${enableval}" in
 586                 yes) alsa=yes ;;
 587                 no) alsa=no ;;
 588                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 589             esac
 590         ],
 591         [alsa=auto])
 592
 593 if test "x${alsa}" != xno ; then
 594     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 595         [
 596             HAVE_ALSA=1
 597             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 598         ],
 599         [
 600             HAVE_ALSA=0
 601             if test "x$alsa" = xyes ; then
 602                 AC_MSG_ERROR([*** ALSA support not found])
 603             fi
 604         ])
 605 else
 606     HAVE_ALSA=0
 607 fi
 608
 609 AC_SUBST(ASOUNDLIB_CFLAGS)
 610 AC_SUBST(ASOUNDLIB_LIBS)
 611 AC_SUBST(HAVE_ALSA)
 612 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 613
 614 #### Solaris audio support (optional) ####
 615
 616 AC_ARG_ENABLE([solaris],
 617     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 618         [
 619             case "${enableval}" in
 620                 yes) solaris=yes ;;
 621                 no) solaris=no ;;
 622                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 623             esac
 624         ],
 625         [solaris=auto])
 626
 627 if test "x${solaris}" != xno ; then
 628     AC_CHECK_HEADERS([sys/audio.h],
 629         [
 630             HAVE_SOLARIS=1
 631             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 632         ],
 633         [
 634             HAVE_SOLARIS=0
 635             if test "x$solaris" = xyes ; then
 636                 AC_MSG_ERROR([*** Solaris audio support not found])
 637             fi
 638         ])
 639 else
 640     HAVE_SOLARIS=0
 641 fi
 642
 643 AC_SUBST(HAVE_SOLARIS)
 644 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 645
 646 #### GLib 2 support (optional) ####
 647
 648 AC_ARG_ENABLE([glib2],
 649     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 650         [
 651             case "${enableval}" in
 652                 yes) glib2=yes ;;
 653                 no) glib2=no ;;
 654                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 655             esac
 656         ],
 657         [glib2=auto])
 658
 659 if test "x${glib2}" != xno ; then
 660     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 661         HAVE_GLIB20=1,
 662         [
 663             HAVE_GLIB20=0
 664             if test "x$glib2" = xyes ; then
 665                 AC_MSG_ERROR([*** GLib 2 support not found])
 666             fi
 667         ])
 668 else
 669     HAVE_GLIB20=0
 670 fi
 671
 672 AC_SUBST(GLIB20_CFLAGS)
 673 AC_SUBST(GLIB20_LIBS)
 674 AC_SUBST(HAVE_GLIB20)
 675 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 676
 677 #### GConf support (optional) ####
 678
 679 AC_ARG_ENABLE([gconf],
 680     AC_HELP_STRING([--disable-gconf], [Disable optional GConf support]),
 681         [
 682             case "${enableval}" in
 683                 yes) gconf=yes ;;
 684                 no) gconf=no ;;
 685                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 686             esac
 687         ],
 688         [glib=auto])
 689
 690 if test "x${gconf}" != xno ; then
 691     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 692         HAVE_GCONF=1,
 693         [
 694             HAVE_GCONF=0
 695             if test "x$gconf" = xyes ; then
 696                 AC_MSG_ERROR([*** GConf support not found])
 697             fi
 698         ])
 699 else
 700     HAVE_GCONF=0
 701 fi
 702
 703 AC_SUBST(GCONF_CFLAGS)
 704 AC_SUBST(GCONF_LIBS)
 705 AC_SUBST(HAVE_GCONF)
 706 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 707
 708 #### Avahi support (optional) ####
 709
 710 AC_ARG_ENABLE([avahi],
 711     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 712         [
 713             case "${enableval}" in
 714                 yes) avahi=yes ;;
 715                 no) avahi=no ;;
 716                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 717             esac
 718         ],
 719         [avahi=auto])
 720
 721 if test "x${avahi}" != xno ; then
 722     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 723         HAVE_AVAHI=1,
 724         [
 725                 HAVE_AVAHI=0
 726                 if test "x$avahi" = xyes ; then
 727                         AC_MSG_ERROR([*** Avahi support not found])
 728                 fi
 729         ])
 730 else
 731     HAVE_AVAHI=0
 732 fi
 733
 734 AC_SUBST(AVAHI_CFLAGS)
 735 AC_SUBST(AVAHI_LIBS)
 736 AC_SUBST(HAVE_AVAHI)
 737 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 738
 739 ### LIBOIL ####
 740
 741 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 742 AC_SUBST(LIBOIL_CFLAGS)
 743 AC_SUBST(LIBOIL_LIBS)
 744
 745 ### JACK (optional) ####
 746
 747 AC_ARG_ENABLE([jack],
 748     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 749         [
 750             case "${enableval}" in
 751                 yes) jack=yes ;;
 752                 no) jack=no ;;
 753                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 754             esac
 755         ],
 756         [jack=auto])
 757
 758 if test "x${jack}" != xno ; then
 759     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 760         HAVE_JACK=1,
 761         [
 762             HAVE_JACK=0
 763             if test "x$jack" = xyes ; then
 764                 AC_MSG_ERROR([*** JACK support not found])
 765             fi
 766         ])
 767 else
 768     HAVE_JACK=0
 769 fi
 770
 771 AC_SUBST(JACK_CFLAGS)
 772 AC_SUBST(JACK_LIBS)
 773 AC_SUBST(HAVE_JACK)
 774 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 775
 776 #### Async DNS support (optional) ####
 777
 778 AC_ARG_ENABLE([asyncns],
 779     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 780         [
 781             case "${enableval}" in
 782                 yes) asyncns=yes ;;
 783                 no) asyncns=no ;;
 784                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 785             esac
 786         ],
 787         [asyncns=auto])
 788
 789 if test "x${asyncns}" != xno ; then
 790     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 791         HAVE_LIBASYNCNS=1,
 792         [
 793             HAVE_LIBASYNCNS=0
 794             if test "x$asyncns" = xyes ; then
 795                 AC_MSG_ERROR([*** Async DNS support not found])
 796             fi
 797         ])
 798 else
 799     HAVE_LIBASYNCNS=0
 800 fi
 801
 802 AC_SUBST(LIBASYNCNS_CFLAGS)
 803 AC_SUBST(LIBASYNCNS_LIBS)
 804 AC_SUBST(HAVE_LIBASYNCNS)
 805 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 806
 807 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 808    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 809 fi
 810
 811 #### TCP wrappers (optional) ####
 812
 813 AC_ARG_ENABLE([tcpwrap],
 814     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 815         [
 816             case "${enableval}" in
 817                 yes) tcpwrap=yes ;;
 818                 no) tcpwrap=no ;;
 819                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 820             esac
 821         ],
 822         [tcpwrap=auto])
 823
 824 if test "x${tcpwrap}" != xno ; then
 825     ACX_LIBWRAP
 826     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 827         AC_MSG_ERROR([*** TCP wrappers support not found])
 828     fi
 829 else
 830     LIBWRAP_LIBS=
 831 fi
 832
 833 AC_SUBST(LIBWRAP_LIBS)
 834
 835 #### LIRC support (optional) ####
 836
 837 AC_ARG_ENABLE([lirc],
 838     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 839         [
 840             case "${enableval}" in
 841                 yes) lirc=yes ;;
 842                 no) lirc=no ;;
 843                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 844             esac
 845         ],
 846         [lirc=auto])
 847
 848 if test "x${lirc}" != xno ; then
 849     ACX_LIRC
 850     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 851         AC_MSG_ERROR([*** LIRC support not found])
 852     fi
 853 else
 854     HAVE_LIRC=0
 855 fi
 856
 857 AC_SUBST(LIRC_CFLAGS)
 858 AC_SUBST(LIRC_LIBS)
 859 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 860
 861 #### HAL support (optional) ####
 862
 863 AC_ARG_ENABLE([hal],
 864     AC_HELP_STRING([--disable-hal], [Disable optional HAL support]),
 865         [
 866             case "${enableval}" in
 867                 yes) hal=yes ;;
 868                 no) hal=no ;;
 869                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 870             esac
 871         ],
 872         [hal=auto])
 873 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 874     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 875         HAVE_HAL=1,
 876         [
 877             HAVE_HAL=0
 878             if test "x$hal" = xyes ; then
 879                 AC_MSG_ERROR([*** HAL support not found])
 880             fi
 881         ])
 882 else
 883     HAVE_HAL=0
 884 fi
 885
 886 AC_SUBST(HAL_CFLAGS)
 887 AC_SUBST(HAL_LIBS)
 888 AC_SUBST(HAVE_HAL)
 889 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 890
 891 #### BlueZ support (optional) ####
 892
 893 AC_ARG_ENABLE([bluez],
 894     AC_HELP_STRING([--disable-bluez], [Disable optional BlueZ support]),
 895         [
 896             case "${enableval}" in
 897                 yes) bluez=yes ;;
 898                 no) bluez=no ;;
 899                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-bluez) ;;
 900             esac
 901         ],
 902         [bluez=auto])
 903 if test "x${bluez}" != xno ; then
 904     PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ],
 905         HAVE_BLUEZ=1,
 906         [
 907             HAVE_BLUEZ=0
 908             if test "x$bluez" = xyes ; then
 909                 AC_MSG_ERROR([*** BLUEZ support not found])
 910             fi
 911         ])
 912 else
 913     HAVE_BLUEZ=0
 914 fi
 915
 916 AC_SUBST(BLUEZ_CFLAGS)
 917 AC_SUBST(BLUEZ_LIBS)
 918 AC_SUBST(HAVE_BLUEZ)
 919 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 920
 921 #### D-Bus support (optional) ####
 922
 923 AC_ARG_ENABLE([dbus],
 924     AC_HELP_STRING([--disable-dbus], [Disable optional D-Bus support]),
 925         [
 926             case "${enableval}" in
 927                 yes) dbus=yes ;;
 928                 no) dbus=no ;;
 929                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 930             esac
 931         ],
 932         [dbus=auto])
 933
 934 if test "x$HAVE_HAL" = x1 ; then
 935    dbus=yes
 936 fi
 937
 938 if test "x${dbus}" != xno || test "x${bluez}" != xno || "x${hal}" != xno ; then
 939
 940     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 941         [
 942             HAVE_DBUS=1
 943             saved_LIBS="$LIBS"
 944             LIBS="$LIBS $DBUS_LIBS"
 945             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 946             LIBS="$saved_LIBS"
 947             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 948         ],
 949         [
 950             HAVE_DBUS=0
 951             if test "x$dbus" = xyes ; then
 952                 AC_MSG_ERROR([*** D-Bus support not found])
 953             fi
 954         ])
 955 else
 956     HAVE_DBUS=0
 957 fi
 958
 959 AC_SUBST(DBUS_CFLAGS)
 960 AC_SUBST(DBUS_LIBS)
 961 AC_SUBST(HAVE_DBUS)
 962 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 963
 964 #### PolicyKit support (optional) ####
 965
 966 AC_ARG_ENABLE([polkit],
 967     AC_HELP_STRING([--disable-polkit], [Disable optional PolicyKit support]),
 968         [
 969             case "${enableval}" in
 970                 yes) polkit=yes ;;
 971                 no) polkit=no ;;
 972                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-polkit) ;;
 973             esac
 974         ],
 975         [polkit=auto])
 976
 977 if test "x${polkit}" != xno ; then
 978
 979     PKG_CHECK_MODULES(POLKIT, [ polkit-dbus >= 0.7 ],
 980         [
 981             HAVE_POLKIT=1
 982             AC_DEFINE([HAVE_POLKIT], 1, [Have PolicyKit])
 983             policydir=`pkg-config polkit-dbus --variable prefix`/share/PolicyKit/policy/
 984             AC_SUBST(policydir)
 985         ],
 986         [
 987             HAVE_POLKIT=0
 988             if test "x$polkit" = xyes ; then
 989                 AC_MSG_ERROR([*** PolicyKit support not found])
 990             fi
 991         ])
 992 else
 993     HAVE_POLKIT=0
 994 fi
 995
 996 AC_SUBST(POLKIT_CFLAGS)
 997 AC_SUBST(POLKIT_LIBS)
 998 AC_SUBST(HAVE_POLKIT)
 999 AM_CONDITIONAL([HAVE_POLKIT], [test "x$HAVE_POLKIT" = x1])
1000
1001 ### Build and Install man pages ###
1002 AC_ARG_ENABLE(manpages,
1003         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
1004 [case "${enableval}" in
1005   yes) manpages=yes ;;
1006   no)  manpages=no ;;
1007   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
1008 esac],[manpages=yes])
1009
1010 if test x$manpages = xyes ; then
1011     #
1012     # XMLTOMAN manpage generation
1013     #
1014     AC_ARG_ENABLE(xmltoman,
1015     AS_HELP_STRING([--disable-xmltoman],[Enable rebuilding of man pages with xmltoman]),
1016     [case "${enableval}" in
1017       yes) xmltoman=yes ;;
1018       no)  xmltoman=no ;;
1019       *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
1020     esac],[xmltoman=yes])
1021
1022     if test x$xmltoman = xyes ; then
1023         AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
1024     fi
1025
1026     if test x$have_xmltoman = xno -o x$xmltoman = xno; then
1027         if ! test -e man/pulseaudio.1 ; then
1028             AC_MSG_ERROR([*** xmltoman was not found or was disabled, it is required to build the manpages as they have not been pre-built, install xmltoman, pass --disable-manpages or dont pass --disable-xmltoman])
1029             exit 1
1030         fi
1031         AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
1032         xmltoman=no
1033     fi
1034 fi
1035 AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
1036 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1037
1038 #### PulseAudio system group & user  #####
1039
1040 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1041 if test -z "$with_system_user" ; then
1042     PA_SYSTEM_USER=pulse
1043 else
1044     PA_SYSTEM_USER=$with_system_user
1045 fi
1046 AC_SUBST(PA_SYSTEM_USER)
1047 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1048
1049 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1050 if test -z "$with_system_group" ; then
1051     PA_SYSTEM_GROUP=pulse
1052 else
1053     PA_SYSTEM_GROUP=$with_system_group
1054 fi
1055 AC_SUBST(PA_SYSTEM_GROUP)
1056 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1057
1058 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
1059 if test -z "$with_realtime_group" ; then
1060     PA_REALTIME_GROUP=pulse-rt
1061 else
1062     PA_REALTIME_GROUP=$with_realtime_group
1063 fi
1064 AC_SUBST(PA_REALTIME_GROUP)
1065 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
1066
1067 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1068 if test -z "$with_access_group" ; then
1069     PA_ACCESS_GROUP=pulse-access
1070 else
1071     PA_ACCESS_GROUP=$with_access_group
1072 fi
1073 AC_SUBST(PA_ACCESS_GROUP)
1074 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1075
1076 AC_ARG_ENABLE(
1077         per_user_esound_socket,
1078         AS_HELP_STRING([--disable-per-user-esound-socket], [Use per-user esound socket directory, like /tmp/.esd-UID/socket.]),
1079         [
1080             case "${enableval}" in
1081                 yes) per_user_esound_socket=1 ;;
1082                 no) per_user_esound_socket=0 ;;
1083                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-per-user-esound-socket) ;;
1084             esac
1085         ],
1086         [per_user_esound_socket=1])
1087
1088 if test "x$per_user_esound_socket" = "x1"; then
1089    AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1090 fi
1091
1092 #### PulseAudio system runtime dir ####
1093 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1094 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1095
1096 ###################################
1097 #            Output               #
1098 ###################################
1099
1100 AC_ARG_ENABLE(
1101         [static-bins],
1102         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
1103         [STATIC_BINS=1], [STATIC_BINS=0])
1104 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1105
1106 AC_ARG_WITH(
1107         [preopen-mods],
1108         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1109         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1110 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1111 if test "x$PREOPEN_MODS" != "xall" ; then
1112     tmpLIBS=""
1113     for mod in $PREOPEN_MODS; do
1114         tmpLIBS="$tmpLIBS module-$mod.la"
1115     done
1116     PREOPEN_MODS="$tmpLIBS"
1117     AC_SUBST(PREOPEN_MODS)
1118 fi
1119
1120 AC_ARG_WITH(
1121         [module-dir],
1122         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
1123         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
1124
1125 AC_SUBST(modlibexecdir)
1126
1127 AC_ARG_ENABLE(
1128         [force-preopen],
1129         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
1130         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
1131 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
1132
1133 AC_CONFIG_FILES([
1134 Makefile
1135 src/Makefile
1136 man/Makefile
1137 libpulse.pc
1138 libpulse-simple.pc
1139 libpulse-browse.pc
1140 libpulse-mainloop-glib.pc
1141 doxygen/Makefile
1142 doxygen/doxygen.conf
1143 src/pulse/version.h
1144 ])
1145 AC_OUTPUT
1146
1147 # ==========================================================================
1148 ENABLE_X11=no
1149 if test "x$HAVE_X11" = "x1" ; then
1150    ENABLE_X11=yes
1151 fi
1152
1153 ENABLE_OSS=no
1154 if test "x$HAVE_OSS" = "x1" ; then
1155    ENABLE_OSS=yes
1156 fi
1157
1158 ENABLE_ALSA=no
1159 if test "x$HAVE_ALSA" = "x1" ; then
1160    ENABLE_ALSA=yes
1161 fi
1162
1163 ENABLE_SOLARIS=no
1164 if test "x$HAVE_SOLARIS" = "x1" ; then
1165    ENABLE_SOLARIS=yes
1166 fi
1167
1168 ENABLE_GLIB20=no
1169 if test "x$HAVE_GLIB20" = "x1" ; then
1170    ENABLE_GLIB20=yes
1171 fi
1172
1173 ENABLE_GCONF=no
1174 if test "x$HAVE_GCONF" = "x1" ; then
1175    ENABLE_GCONF=yes
1176 fi
1177
1178 ENABLE_AVAHI=no
1179 if test "x$HAVE_AVAHI" = "x1" ; then
1180    ENABLE_AVAHI=yes
1181 fi
1182
1183 ENABLE_JACK=no
1184 if test "x$HAVE_JACK" = "x1" ; then
1185    ENABLE_JACK=yes
1186 fi
1187
1188 ENABLE_LIBASYNCNS=no
1189 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
1190    ENABLE_LIBASYNCNS=yes
1191 fi
1192
1193 ENABLE_LIRC=no
1194 if test "x$HAVE_LIRC" = "x1" ; then
1195    ENABLE_LIRC=yes
1196 fi
1197
1198 ENABLE_HAL=no
1199 if test "x$HAVE_HAL" = "x1" ; then
1200    ENABLE_HAL=yes
1201 fi
1202
1203 ENABLE_TCPWRAP=no
1204 if test "x${LIBWRAP_LIBS}" != x ; then
1205    ENABLE_TCPWRAP=yes
1206 fi
1207
1208 ENABLE_LIBSAMPLERATE=no
1209 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
1210    ENABLE_LIBSAMPLERATE=yes
1211 fi
1212
1213 ENABLE_BLUEZ=no
1214 if test "x${HAVE_BLUEZ}" = "x1" ; then
1215    ENABLE_BLUEZ=yes
1216 fi
1217
1218 ENABLE_POLKIT=no
1219 if test "x${HAVE_POLKIT}" = "x1" ; then
1220    ENABLE_POLKIT=yes
1221 fi
1222
1223 ENABLE_PER_USER_ESOUND_SOCKET=no
1224 if test "x$per_user_esound_socket" = "x1" ; then
1225    ENABLE_PER_USER_ESOUND_SOCKET=yes
1226 fi
1227
1228 echo "
1229  ---{ $PACKAGE_NAME $VERSION }---
1230
1231     prefix:                        ${prefix}
1232     sysconfdir:                    ${sysconfdir}
1233     localstatedir:                 ${localstatedir}
1234     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1235     Compiler:                      ${CC}
1236     CFLAGS:                        ${CFLAGS}
1237     Have X11:                      ${ENABLE_X11}
1238     Enable OSS:                    ${ENABLE_OSS}
1239     Enable Alsa:                   ${ENABLE_ALSA}
1240     Enable Solaris:                ${ENABLE_SOLARIS}
1241     Enable GLib 2.0:               ${ENABLE_GLIB20}
1242     Enable GConf:                  ${ENABLE_GCONF}
1243     Enable Avahi:                  ${ENABLE_AVAHI}
1244     Enable Jack:                   ${ENABLE_JACK}
1245     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1246     Enable LIRC:                   ${ENABLE_LIRC}
1247     Enable HAL:                    ${ENABLE_HAL}
1248     Enable BlueZ:                  ${ENABLE_BLUEZ}
1249     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1250     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1251     Enable PolicyKit:              ${ENABLE_POLKIT}
1252     System User:                   ${PA_SYSTEM_USER}
1253     System Group:                  ${PA_SYSTEM_GROUP}
1254     Realtime Group:                ${PA_REALTIME_GROUP}
1255     Access Group:                  ${PA_ACCESS_GROUP}
1256     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1257 "