configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [0])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [6])
   6 m4_define([folks_micro_version], [7])
   7 m4_define([folks_nano_version], [1])
   8
   9 # If library source has changed since last release, increment revision
  10 # If public symbols have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If public symbols have been added since last release, increment age
  13 # If public symbols have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [31])
  15 m4_define([folks_lt_revision], [0])
  16 m4_define([folks_lt_age], [6])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-bzip2 no-define
  46                   no-dist-gzip tar-ustar -Wno-portability])
  47 AM_MAINTAINER_MODE([enable])
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54
  55 AC_SUBST([CFLAGS])
  56 AC_SUBST([CPPFLAGS])
  57 AC_SUBST([LDFLAGS])
  58
  59 LT_CURRENT=folks_lt_current
  60 LT_REVISION=folks_lt_revision
  61 LT_AGE=folks_lt_age
  62 AC_SUBST([LT_CURRENT])
  63 AC_SUBST([LT_REVISION])
  64 AC_SUBST([LT_AGE])
  65
  66 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  67 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  68
  69 API_VERSION=0.6
  70 AC_SUBST([API_VERSION])
  71
  72 AC_ARG_ENABLE(tracker-backend,
  73         AC_HELP_STRING([--enable-tracker-backend],
  74                        [ build the Tracker backend]),
  75         enable_tracker_backend=$enableval,
  76         enable_tracker_backend=no )
  77
  78 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  79
  80 if test "x$enable_tracker_backend" = "xyes"; then
  81         AC_DEFINE(HAVE_TRACKER, [1],
  82                   [Define as 1 if you have the Tracker backend])
  83 else
  84         AC_DEFINE(HAVE_TRACKER, [0],
  85                   [Define as 1 if you have the Tracker backend])
  86 fi
  87
  88 AC_ARG_ENABLE(eds-backend,
  89         AC_HELP_STRING([--enable-eds-backend],
  90                        [ build the E-D-S backend]),
  91         enable_eds_backend=$enableval,
  92         enable_eds_backend=yes )
  93
  94 if test "x$enable_eds_backend" = "xyes"; then
  95         AC_DEFINE(HAVE_EDS, [1], [Define as 1 if you have the eds backend])
  96 else
  97         AC_DEFINE(HAVE_EDS, [0], [Define as 1 if you have the eds backend])
  98 fi
  99
 100
 101 AM_CONDITIONAL([ENABLE_EDS], [test "x$enable_eds_backend" = "xyes"])
 102
 103 # Automatically check the dependencies for the libsocialweb backend
 104 SW_CLIENT_REQUIRED=0.25.15
 105 AC_ARG_ENABLE(libsocialweb-backend,
 106         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
 107                        [build the Libsocialweb backend (default: auto)]),
 108         enable_libsocialweb_backend=$enableval,
 109         enable_libsocialweb_backend=auto )
 110
 111 # this may be overwritten farther down
 112 AC_DEFINE(HAVE_LIBSOCIALWEB, [0],
 113           [Define as 1 if you have the libsocialweb backend])
 114 if test "x$enable_libsocialweb_backend" != "xno"; then
 115   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
 116       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
 117   if test "x$have_libsocialweb_backend" = "xyes" -a \
 118           "x$enable_vala" = "xyes"; then
 119     VALA_CHECK_PACKAGES([telepathy-glib
 120                          gio-2.0
 121                          gee-1.0
 122                          libsocialweb-client],
 123         ,
 124         have_libsocialweb_backend="no")
 125   fi
 126
 127   if test "x$have_libsocialweb_backend" = "xyes"; then
 128     AC_DEFINE(HAVE_LIBSOCIALWEB, [1],
 129               [Define if you have the libsocialweb backend])
 130   fi
 131 else
 132    have_libsocialweb_backend=no
 133 fi
 134
 135 if test "x$enable_libsocialweb_backend" = "xyes" -a \
 136   "x$have_libsocialweb_backend" != "xyes"; then
 137     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 138 fi
 139
 140 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 141         [test "x$have_libsocialweb_backend" = "xyes"])
 142
 143 # -----------------------------------------------------------
 144 # Dependencies
 145 # -----------------------------------------------------------
 146
 147 GLIB_REQUIRED=2.24.0
 148 TP_GLIB_REQUIRED=0.13.1
 149 VALA_REQUIRED=0.15.1
 150 VALADOC_REQUIRED=0.3.1
 151 TRACKER_SPARQL_MAJOR=0.14
 152 TRACKER_SPARQL_REQUIRED=0.13.1
 153 GCONF2_REQUIRED=2.31
 154 EBOOK_REQUIRED=3.1.5
 155 EDATASERVER_REQUIRED=3.1.5
 156
 157 AC_SUBST([TRACKER_SPARQL_MAJOR])
 158
 159 PKG_CHECK_MODULES([GLIB],
 160                   [glib-2.0 >= $GLIB_REQUIRED
 161                    gobject-2.0 >= $GLIB_REQUIRED])
 162 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 163 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 164 PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1])
 165 PKG_CHECK_MODULES([GCONF2], [gconf-2.0 >= $GCONF2_REQUIRED])
 166
 167 # FIXME: We depend on libgee < 0.7 because 0.7 breaks API. bgo#627746
 168 PKG_CHECK_MODULES([GEE], [gee-1.0 < 0.7],
 169                   have_gee_0_6_x="yes",
 170                   have_gee_0_6_x="no")
 171
 172 if test "x$have_gee_0_6_x" != "xyes"; then
 173     AC_MSG_ERROR([
 174 Gee 0.6.x required but not installed.
 175
 176 Note that Gee 0.8.x provides gee-0.8 (but gee-1.0 is, confusingly, provided by
 177 Gee 0.6.x)])
 178 fi
 179
 180 PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
 181
 182 if test x$enable_tracker_backend = xyes; then
 183         PKG_CHECK_MODULES([TRACKER_SPARQL],
 184                           [tracker-sparql-$TRACKER_SPARQL_MAJOR >= \
 185                            $TRACKER_SPARQL_REQUIRED])
 186 fi
 187
 188 if test x$enable_eds_backend = xyes; then
 189         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED])
 190         PKG_CHECK_MODULES([EDATASERVER], [libedataserver-1.2 >= $EDATASERVER_REQUIRED])
 191 fi
 192
 193 #
 194 # Vala building options -- allows tarball builds without installing Vala
 195 #
 196 AC_ARG_ENABLE([vala],
 197               AS_HELP_STRING([--enable-vala],
 198                              [Enable building from the Vala sources]),
 199               [enable_vala=$enableval],
 200               [enable_vala=no])
 201
 202 # will be re-set as necessary below
 203 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 204 sd=${srcdir}/
 205
 206 # Force Vala for non-release builds
 207 m4_if(folks_released, [1], [],
 208     [
 209         enable_vala=yes
 210         echo "Vala compiler required for non-release builds; requiring Vala..."
 211     ])
 212
 213 # Force Vala if generated source is missing or outdated
 214 if test \
 215         ! -e ${sd}tools/folks_import_vala.stamp -o \
 216         ! -e ${sd}tests/folks/abstract_field_details_vala.stamp -o \
 217         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 218         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 219         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 220         ! -e ${sd}tests/lib/folks-test.vapi -o \
 221         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 222         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 223         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 224         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 225         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 226         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 227         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 228         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 229         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 230         ! -e ${sd}backends/key-file/key_file_la_vala.stamp -o \
 231         ! -e ${sd}backends/telepathy/telepathy_la_vala.stamp \
 232                 -o \
 233         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 234         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 235         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 236         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 237         ! -e ${sd}folks/folks-internal.h -o \
 238         ! -e ${sd}folks/folks-internal.vapi -o \
 239         ! -e ${sd}folks/libfolks_internal_la_vala.stamp -o \
 240         ! -e ${sd}folks/folks.vapi -o \
 241         ! -e ${sd}folks/libfolks_la_vala.stamp ; then
 242         enable_vala=yes
 243         echo "Vala source needs to be re-compiled; requiring Vala..."
 244 fi
 245
 246 if test "x$enable_vala" = "xyes" ; then
 247         AM_PROG_VALAC([$VALA_REQUIRED])
 248         if test "x$VALAC" = "x"; then
 249               AC_MSG_ERROR([Vala requested but valac is not installed])
 250         fi
 251
 252         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 253         if test "x$VAPIGEN" = "x"; then
 254               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 255         fi
 256
 257         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 258         # automatically
 259         VALAFLAGS="$VALAFLAGS --target-glib=2.24"
 260         AC_SUBST([VALAFLAGS])
 261         AC_SUBST([VAPIGENFLAGS])
 262         AC_SUBST([VAPIDIR])
 263
 264         VALA_CHECK_PACKAGES([telepathy-glib
 265                              gio-2.0
 266                              gee-1.0])
 267
 268         if test x$enable_tracker_backend = xyes; then
 269           VALA_CHECK_PACKAGES([tracker-sparql-$TRACKER_SPARQL_MAJOR])
 270         fi
 271
 272         if test x$enable_eds_backend = xyes; then
 273           VALA_CHECK_PACKAGES([libebook-1.2 libedataserver-1.2 libxml-2.0])
 274         fi
 275 fi
 276
 277 # this will set HAVE_INTROSPECTION
 278 GOBJECT_INTROSPECTION_REQUIRE([1.30])
 279
 280 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 281
 282 # Various functions that we need (used in C code generated from Vala)
 283 AC_CHECK_FUNCS([memset])
 284 AC_CHECK_FUNCS([strstr])
 285
 286 # -----------------------------------------------------------
 287 # Backends
 288 # -----------------------------------------------------------
 289
 290 FOLKS_MODULE_VERSION=folks_module_version
 291 AC_SUBST([FOLKS_MODULE_VERSION])
 292 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 293
 294 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 295 AC_SUBST([BACKEND_DIR])
 296
 297 BACKEND_KF='$(top_builddir)/backends/key-file/.libs/key-file.so'
 298 AC_SUBST([BACKEND_KF])
 299 BACKEND_TP='$(top_builddir)/backends/telepathy/.libs/telepathy.so'
 300 AC_SUBST([BACKEND_TP])
 301
 302 if test x$have_libsocialweb_backend = xyes; then
 303   BACKEND_LIBSOCIALWEB='$(top_builddir)/backends/libsocialweb/.libs/libsocialweb.so'
 304   AC_SUBST([BACKEND_LIBSOCIALWEB])
 305 fi
 306
 307 if test x$enable_tracker_backend = xyes; then
 308   BACKEND_TRACKER='$(top_builddir)/backends/tracker/.libs/tracker.so'
 309   AC_SUBST([BACKEND_TRACKER])
 310 fi
 311
 312 if test x$enable_eds_backend = xyes; then
 313   BACKEND_EDS='$(top_builddir)/backends/eds/.libs/eds.so'
 314   AC_SUBST([BACKEND_EDS])
 315 fi
 316
 317 # All of the backend libraries in our tree; to be used by the tests
 318 BACKEND_UNINST_PATH='$(BACKEND_KF):$(BACKEND_TP)'
 319 if test x$have_libsocialweb_backend = xyes; then
 320   LIBSOCIALWEB_BACKEND_UNINST_PATH='$(BACKEND_LIBSOCIALWEB)'
 321   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$LIBSOCIALWEB_BACKEND_UNINST_PATH"
 322 fi
 323 if test x$enable_tracker_backend = xyes; then
 324   TRACKER_BACKEND_UNINST_PATH='$(BACKEND_TRACKER)'
 325   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$TRACKER_BACKEND_UNINST_PATH"
 326 fi
 327 if test x$enable_eds_backend = xyes; then
 328   EDS_BACKEND_UNINST_PATH='$(BACKEND_EDS)'
 329   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$EDS_BACKEND_UNINST_PATH"
 330 fi
 331 AC_SUBST([BACKEND_UNINST_PATH])
 332
 333 # -----------------------------------------------------------
 334 # Tools
 335 # -----------------------------------------------------------
 336
 337 AC_ARG_ENABLE([import-tool],
 338               AS_HELP_STRING([--enable-import-tool],
 339                              [Enable building the meta-contact import tool]),
 340               [enable_import_tool=$enableval with_import_tool=$enableval],
 341               [enable_import_tool=maybe with_import_tool=no])
 342 AS_IF([test "$enable_import_tool" != "no"],
 343       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 344                          [with_import_tool=yes], [with_import_tool=no])])
 345 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 346       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 347 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 348
 349 # Readline's required for the folks-inspect program
 350 AC_ARG_ENABLE([inspect-tool],
 351               AS_HELP_STRING([--enable-inspect-tool],
 352                              [Enable building the data inspection tool]),
 353               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 354               [enable_inspect_tool=maybe with_inspect_tool=no])
 355 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 356       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 357                      using --enable-vala])])
 358 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 359       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 360                       --enable-vala])])
 361 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 362       [AC_CHECK_LIB([readline], [main],
 363                     [with_inspect_tool=yes], [with_inspect_tool=no],
 364                     [-lncurses])])
 365 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 366        "x$enable_vala" = "xyes"],
 367       [VALA_CHECK_PACKAGES([readline])
 368        LIBREADLINE="-lreadline -lncurses"
 369        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 370        AC_SUBST([LIBREADLINE])])
 371 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 372       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 373 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 374
 375 # -----------------------------------------------------------
 376 # Documentation
 377 # -----------------------------------------------------------
 378
 379 AC_ARG_ENABLE([docs],
 380               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 381               [enable_docs=$enableval], [enable_docs=no])
 382 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 383
 384 have_valadoc=no
 385 if test x$enable_docs = xyes; then
 386   # make sure the library is new enough and the program exists
 387   PKG_CHECK_MODULES([VALADOC], [valadoc-1.0 >= $VALADOC_REQUIRED])
 388   AC_PATH_PROG([VALADOC], [valadoc], [:])
 389   AS_IF([test "$VALADOC" != :], have_valadoc=yes)
 390 fi
 391 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 392
 393 if test "x$enable_docs" = "xyes" -a "x$have_valadoc" != "xyes"; then
 394     AC_MSG_ERROR([Doc building requested but valadoc not installed.])
 395 fi
 396
 397 # -----------------------------------------------------------
 398 # Gettext
 399 # -----------------------------------------------------------
 400
 401 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 402 AC_SUBST(GETTEXT_PACKAGE)
 403 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 404 IT_PROG_INTLTOOL([0.35.0])
 405
 406 # -----------------------------------------------------------
 407 # Error flags
 408 # -----------------------------------------------------------
 409
 410 # Disable GLib deprecation warnings for now (#670196); GValueArray is deprecated
 411 # but we need it for dbus-glib. Porting to GDBus will solve this (#653198)
 412 AC_DEFINE(GLIB_DISABLE_DEPRECATION_WARNINGS, 1, [Build with GLib deprecated])
 413
 414 AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
 415 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 416
 417 AC_ARG_ENABLE([debug],
 418               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 419               [enable_debug=$enableval], [enable_debug=yes])
 420
 421 AC_ARG_ENABLE([Werror],
 422               AS_HELP_STRING([--disable-Werror],
 423                              [compile without -Werror (normally enabled in
 424                               development builds)]),
 425               [werror=$enableval], [werror=yes])
 426
 427 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 428 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 429                  [wno_missing_field_initializers=yes],
 430                  [wno_missing_field_initializers=no])
 431 AS_COMPILER_FLAG([-Wno-unused-parameter],
 432                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 433
 434 m4_if(folks_released, [1], [],
 435     [
 436         if test x$werror = xyes; then
 437             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 438         fi
 439         if test x$wextra = xyes -a \
 440             x$wno_missing_field_initializers = xyes -a \
 441             x$wno_unused_parameter = xyes; then
 442             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra \
 443                 -Wno-missing-field-initializers -Wno-unused-parameter"
 444         fi
 445     ])
 446
 447 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
 448 AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
 449 AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
 450 AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 451                                           -Wmissing-prototypes"])
 452 AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS \
 453                                             -Wmissing-declarations"])
 454 AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 455                                          -Wstrict-prototypes"])
 456
 457 AC_SUBST([ERROR_CFLAGS])
 458
 459 # -----------------------------------------------------------
 460 # Code coverage flags
 461 # -----------------------------------------------------------
 462
 463 AC_ARG_ENABLE([code-coverage],
 464               AS_HELP_STRING([--enable-code-coverage],
 465                              [compile with code coverage code]),
 466               [enable_code_coverage=$enableval], [enable_code_coverage=no])
 467
 468 # Only enable code coverage if this isn't a release.
 469 m4_if(folks_released, [1], [],
 470     [
 471         if test "x$GCC" = "xyes"; then
 472             if test "x$enable_code_coverage" = "xyes"; then
 473                 CODE_COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage -O0 -ggdb"
 474                 CODE_COVERAGE_LDFLAGS="-lgcov"
 475             fi
 476         fi
 477     ])
 478
 479 AC_SUBST([CODE_COVERAGE_CFLAGS])
 480 AC_SUBST([CODE_COVERAGE_LDFLAGS])
 481
 482 # Vala-related flags
 483 AS_IF([test "x$enable_vala" = "xyes"],
 484       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 485                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 486        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 487
 488 # Disable -g if we're building with code coverage enabled, since Vala's
 489 # insertion of #line directives into .c files confuses lcov. For the moment,
 490 # we'll have to do with looking at code coverage of the generated C files only.
 491 # We set the debug flags in CODE_COVERAGE_CFLAGS instead in that case.
 492 m4_if(folks_released, [1], [],
 493     [
 494         if test "x$enable_code_coverage" != "xyes" -o "x$GCC" != "xyes"; then
 495             ERROR_VALAFLAGS="$ERROR_VALAFLAGS -g"
 496         fi
 497     ])
 498
 499 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 500 AC_SUBST([ERROR_VALAFLAGS])
 501
 502 # -----------------------------------------------------------
 503 # Final output
 504 # -----------------------------------------------------------
 505
 506 AC_CONFIG_FILES([
 507     backends/telepathy/lib/folks-telepathy.pc
 508     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 509     backends/tracker/lib/folks-tracker.deps
 510     backends/tracker/lib/folks-tracker.pc
 511     backends/tracker/lib/folks-tracker-uninstalled.pc
 512     backends/eds/lib/folks-eds.pc
 513     backends/eds/lib/folks-eds-uninstalled.pc
 514     folks/folks.pc
 515     folks/folks-uninstalled.pc
 516     Makefile
 517     backends/Makefile
 518     backends/key-file/Makefile
 519     backends/libsocialweb/Makefile
 520     backends/libsocialweb/lib/Makefile
 521     backends/libsocialweb/lib/folks-libsocialweb.pc
 522     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 523     backends/telepathy/Makefile
 524     backends/telepathy/lib/Makefile
 525     backends/tracker/Makefile
 526     backends/tracker/lib/Makefile
 527     backends/eds/Makefile
 528     backends/eds/lib/Makefile
 529     folks/Makefile
 530     docs/Makefile
 531     po/Makefile.in
 532     tests/Makefile
 533     tests/data/Makefile
 534     tests/data/gconf.path
 535     tests/folks/Makefile
 536     tests/key-file/Makefile
 537     tests/libsocialweb/Makefile
 538     tests/telepathy/Makefile
 539     tests/tracker/Makefile
 540     tests/lib/Makefile
 541     tests/lib/folks-test-uninstalled.pc
 542     tests/lib/key-file/Makefile
 543     tests/lib/libsocialweb/Makefile
 544     tests/lib/libsocialweb/session.conf
 545     tests/eds/Makefile
 546     tests/lib/eds/Makefile
 547     tests/lib/telepathy/Makefile
 548     tests/lib/tracker/Makefile
 549     tests/lib/telepathy/contactlist/Makefile
 550     tests/lib/telepathy/contactlist/session.conf
 551     tests/tools/Makefile
 552     tools/Makefile
 553     tools/inspect/Makefile
 554 ])
 555
 556 AC_OUTPUT
 557
 558 echo "
 559 Configure summary:
 560
 561         Vala........................:  ${enable_vala}
 562         Vala Compiler...............:  ${VALAC}
 563         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS} ${CODE_COVERAGE_CFLAGS}
 564         Linker Flags................:  ${LDFLAGS} ${CODE_COVERAGE_LDFLAGS}
 565         Prefix......................:  ${prefix}
 566         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 567         Documentation...............:  ${have_valadoc}
 568         Import tool.................:  ${with_import_tool}
 569         Inspector tool..............:  ${with_inspect_tool}
 570         Tracker backend.............:  ${enable_tracker_backend}
 571         Libsocialweb backend........:  ${have_libsocialweb_backend}
 572         E-D-S backend...............:  ${enable_eds_backend}
 573
 574 "