configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [7])
   5 m4_define([v_mic], [8])
   6 m4_define([v_rev], m4_esyscmd([(git rev-list --count HEAD 2>/dev/null || echo 0) | tr -d '\n']))dnl
   7 ##--   When released, remove the dnl on the below line
   8 m4_undefine([v_rev])
   9 ##--   When doing snapshots - change soname. remove dnl on below line
  10 dnl m4_define([relname], [ver-pre-svn-07])
  11 dnl m4_define([v_rel], [-release relname])
  12 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  13 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  14 m4_define([lt_cur], m4_eval(v_maj + v_min))
  15 m4_define([lt_rev], v_mic)
  16 m4_define([lt_age], v_min)
  17 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19
  20 AC_INIT([ecore], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  21 AC_PREREQ([2.52])
  22 AC_CONFIG_SRCDIR([configure.ac])
  23 AC_CONFIG_MACRO_DIR([m4])
  24
  25 AC_CONFIG_HEADERS([config.h])
  26 AH_TOP([
  27 #ifndef EFL_CONFIG_H__
  28 #define EFL_CONFIG_H__
  29 ])
  30 AH_BOTTOM([
  31 #endif /* EFL_CONFIG_H__ */
  32 ])
  33
  34 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  36
  37 AC_GNU_SOURCE
  38
  39 AC_LIBTOOL_WIN32_DLL
  40 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  41 AC_PROG_LIBTOOL
  42
  43 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  44 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  45 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  46 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  47 AC_DEFINE_UNQUOTED(VERS_MAJ, [v_maj], [Major version])
  48 AC_DEFINE_UNQUOTED(VERS_MIN, [v_min], [Minor version])
  49 AC_DEFINE_UNQUOTED(VERS_MIC, [v_mic], [Micro version])
  50 AC_DEFINE_UNQUOTED(VERS_REV, [v_rev], [Revison])
  51 version_info="lt_cur:lt_rev:lt_age"
  52 release_info="v_rel"
  53 AC_SUBST(version_info)
  54 AC_SUBST(release_info)
  55 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  56 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  57 VMAJ=v_maj
  58 AC_SUBST(VMAJ)
  59
  60 AM_GNU_GETTEXT_VERSION(0.17)
  61
  62 m4_ifdef([AM_GNU_GETTEXT], [
  63 AM_GNU_GETTEXT([external])
  64 po_makefile_in=po/Makefile.in
  65 have_po="yes"
  66 ],[
  67 have_po="no"
  68 ])
  69 AC_SUBST(LTLIBINTL)
  70
  71 if test "x${POSUB}" = "x" ; then
  72    have_po="no"
  73 fi
  74
  75 AM_CONDITIONAL([HAVE_PO], [test "x${have_po}" = "xyes"])
  76
  77 with_max_log_level="<unset>"
  78 AC_ARG_WITH(internal-maximum-log-level,
  79    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
  80                    [limit ecore internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
  81    [
  82     if test "x${withval}" != "xno"; then
  83        if echo "${withval}" | grep -E '^[[0-9]]+$' >/dev/null 2>/dev/null; then
  84           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
  85           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
  86           with_max_log_level="${withval}"
  87        else
  88           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
  89        fi
  90     fi
  91     ], [:])
  92
  93
  94 ### Default options with respect to host
  95
  96 AC_CANONICAL_BUILD
  97 AC_CANONICAL_HOST
  98
  99 # dependencies and options
 100 want_curl="no"
 101 want_local_sockets="yes"
 102 want_abstract_sockets="no"
 103 want_gnutls="no"
 104 want_openssl="no"
 105 want_cares="no"
 106 want_cipher="no"
 107 want_signature="no"
 108 want_poll="yes"
 109 want_inotify="no"
 110 want_notify_win32="no"
 111 want_tslib="no"
 112 want_glib="no"
 113
 114 # core modules
 115 want_ecore_con="yes"
 116 want_ecore_ipc="yes"
 117 want_ecore_file="yes"
 118 #want_ecore_config="no"
 119 want_ecore_imf="no"
 120 want_ecore_input="yes"
 121
 122 # graphic system modules
 123 want_evas_simple_x11="no"
 124 want_ecore_x_xcb="no"
 125 want_ecore_x="no"
 126 want_ecore_win32="no"
 127 want_ecore_cocoa="no"
 128 want_ecore_sdl="no"
 129 want_ecore_psl1ght="no"
 130 want_ecore_fb="no"
 131 want_ecore_directfb="no"
 132 want_ecore_wince="no"
 133 want_ecore_wayland="no"
 134
 135 # ecore_x options (both xlib and xcb)
 136 want_ecore_x_composite="yes"
 137 want_ecore_x_damage="yes"
 138 want_ecore_x_dpms="yes"
 139 want_ecore_x_randr="yes"
 140 want_ecore_x_render="yes"
 141 want_ecore_x_screensaver="yes"
 142 want_ecore_x_shape="yes"
 143 want_ecore_x_gesture="no"
 144 want_ecore_x_sync="yes"
 145 want_ecore_x_xfixes="yes"
 146 want_ecore_x_xinerama="yes"
 147 want_ecore_x_xprint="yes"
 148 want_ecore_x_xtest="yes"
 149 want_ecore_x_cursor="yes"
 150 want_ecore_x_input="yes"
 151 want_ecore_x_dri="yes"
 152
 153 # ecore_evas modules
 154 want_ecore_evas="yes"
 155 want_ecore_evas_software_buffer="yes"
 156 want_ecore_evas_software_x11="no"
 157 want_ecore_evas_opengl_x11="no"
 158 want_ecore_evas_software_16_x11="no"
 159 want_ecore_evas_software_8_x11="no"
 160 want_ecore_evas_software_xcb="no"
 161 want_ecore_evas_software_gdi="no"
 162 want_ecore_evas_software_ddraw="no"
 163 want_ecore_evas_direct3d="no"
 164 want_ecore_evas_opengl_glew="no"
 165 want_ecore_evas_software_16_ddraw="no"
 166 want_ecore_evas_software_sdl="no"
 167 want_ecore_evas_gl_sdl="no"
 168 want_ecore_evas_gl_cocoa="no"
 169 want_ecore_evas_psl1ght="no"
 170 want_ecore_evas_directfb="no"
 171 want_ecore_evas_fb="no"
 172 want_ecore_evas_software_16_wince="no"
 173 want_ecore_evas_ews="yes"
 174 want_ecore_evas_extn="yes"
 175 want_ecore_evas_wayland_shm="no"
 176 want_ecore_evas_wayland_egl="no"
 177
 178 # ecore_imf modules
 179 want_ecore_imf_xim="no"
 180 want_ecore_imf_scim="no"
 181 want_ecore_imf_ibus="no"
 182
 183 case "$host_os" in
 184    mingw32ce*)
 185       want_ecore_con="no"
 186       want_ecore_ipc="no"
 187       want_ecore_wince="yes"
 188       want_ecore_evas_software_16_wince="yes"
 189       want_ecore_evas_extn="no"
 190       ;;
 191    mingw*)
 192       want_notify_win32="yes"
 193       want_curl="yes"
 194       want_glib="auto"
 195       want_gnutls="auto"
 196       want_openssl="auto"
 197       want_ecore_imf="yes"
 198       want_ecore_win32="yes"
 199       want_ecore_evas_software_gdi="yes"
 200       want_ecore_evas_software_ddraw="yes"
 201       want_ecore_evas_direct3d="yes"
 202       want_ecore_evas_opengl_glew="yes"
 203       want_ecore_evas_software_16_ddraw="auto"
 204       want_ecore_evas_software_sdl="yes"
 205       want_ecore_evas_gl_sdl="yes"
 206       ;;
 207    darwin*)
 208       want_curl="yes"
 209       want_glib="auto"
 210       want_gnutls="auto"
 211       want_openssl="auto"
 212       want_ecore_imf="yes"
 213       want_ecore_cocoa="yes"
 214       want_ecore_evas_software_sdl="yes"
 215       want_ecore_evas_gl_sdl="yes"
 216       want_ecore_evas_gl_cocoa="yes"
 217       ;;
 218    *)
 219       want_curl="yes"
 220       want_glib="auto"
 221       want_abstract_sockets="yes"
 222       want_gnutls="auto"
 223       want_openssl="auto"
 224       want_cipher="yes"
 225       want_signature="yes"
 226       want_inotify="yes"
 227       want_tslib="yes"
 228       want_ecore_fb="yes"
 229       want_ecore_imf="yes"
 230       want_ecore_x="yes"
 231       want_ecore_wayland="yes"
 232       want_ecore_evas_software_x11="yes"
 233       want_ecore_evas_opengl_x11="yes"
 234       want_ecore_evas_software_16_x11="yes"
 235       want_ecore_evas_software_8_x11="yes"
 236       want_ecore_evas_software_xcb="no"
 237       want_ecore_evas_software_sdl="yes"
 238       want_ecore_evas_gl_sdl="yes"
 239       want_ecore_evas_gl_cocoa="no"
 240       want_ecore_evas_directfb="yes"
 241       want_ecore_evas_fb="yes"
 242       want_ecore_evas_wayland_shm="yes"
 243       want_ecore_evas_wayland_egl="yes"
 244       want_ecore_imf_xim="yes"
 245       want_ecore_imf_scim="yes"
 246       want_ecore_imf_ibus="yes"
 247       ;;
 248 esac
 249
 250 case "$host_vendor" in
 251   ps3*)
 252       want_local_sockets="no"
 253       ;;
 254 esac
 255 requirements_ecore=""
 256 requirements_ecore_con=""
 257 #requirements_ecore_config=""
 258 requirements_ecore_directfb=""
 259 requirements_ecore_evas=""
 260 requirements_ecore_fb=""
 261 requirements_ecore_file=""
 262 requirements_ecore_imf=""
 263 requirements_ecore_imf_evas=""
 264 requirements_ecore_input=""
 265 requirements_ecore_input_evas=""
 266 requirements_ecore_ipc=""
 267 requirements_ecore_cocoa=""
 268 requirements_ecore_sdl=""
 269 requirements_ecore_psl1ght=""
 270 requirements_ecore_x=""
 271 requirements_ecore_win32=""
 272 requirements_ecore_wince=""
 273 requirements_ecore_imf_xim=""
 274 requirements_ecore_imf_scim=""
 275 requirements_ecore_imf_ibus=""
 276 requirements_ecore_wayland=""
 277
 278 ### Additional options to configure
 279
 280 want_glib_integration_always=no
 281 AC_ARG_ENABLE(glib-integration-always,
 282   AC_HELP_STRING([--enable-glib-integration-always], [enable glib integration when ecore_init() is called always]),
 283   [want_glib_integration_always=$enableval])
 284
 285 if test "x${want_glib_integration_always}" = "xyes" ; then
 286   AC_DEFINE([GLIB_INTEGRATION_ALWAYS], [1], [Always integrate glib if support compiled])
 287   want_glib=yes
 288 fi
 289
 290 want_g_main_loop=no
 291 AC_ARG_ENABLE(g-main-loop,
 292   AC_HELP_STRING([--enable-g-main-loop], [ecore_main_loop based on g_main_loop]),
 293   [want_g_main_loop=$enableval])
 294
 295 if test "x${want_g_main_loop}" = "xyes" ; then
 296   AC_DEFINE([USE_G_MAIN_LOOP], [1], [Use g_main_loop in ecore])
 297   want_glib=yes
 298 fi
 299
 300 if test "x${want_glib_integration_always}" = "xyes" -a "x${want_g_main_loop}" = "xyes"; then
 301   AC_MSG_ERROR([--enable-glib-integration-always and --enable-glib-main-loop are mutually exclusive])
 302 fi
 303
 304 # local sockets (ecore_con.c)
 305 AC_ARG_ENABLE([local-sockets],
 306    [AC_HELP_STRING([--disable-local-sockets], [disable local sockets.])],
 307    [
 308     if test "x${enableval}" = "xyes" ; then
 309        want_ecore_con_local_sockets="yes"
 310     else
 311        want_ecore_con_local_sockets="no"
 312     fi
 313    ],
 314    [want_ecore_con_local_sockets=${want_local_sockets}])
 315
 316 if test "x${want_ecore_con_local_sockets}" = "xyes" ; then
 317    AC_DEFINE([HAVE_LOCAL_SOCKETS], [1], [Have local sockets support])
 318 fi
 319
 320 # abstract sockets (ecore_con.c)
 321 AC_ARG_ENABLE([abstract-sockets],
 322    [AC_HELP_STRING([--disable-abstract-sockets], [disable abstract sockets.])],
 323    [
 324     if test "x${enableval}" = "xyes" ; then
 325        want_ecore_con_abstract_sockets="yes"
 326     else
 327        want_ecore_con_abstract_sockets="no"
 328     fi
 329    ],
 330    [want_ecore_con_abstract_sockets=${want_abstract_sockets}])
 331
 332 if test "x${want_ecore_con_abstract_sockets}" = "xyes" ; then
 333    AC_DEFINE([HAVE_ABSTRACT_SOCKETS], [1], [Have abstract sockets namespace])
 334 fi
 335
 336 # Simple X11 build/link
 337
 338 AC_ARG_ENABLE(simple-x11,
 339   AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking]),
 340   [want_evas_simple_x11=$enableval])
 341
 342 # XIM
 343 AC_ARG_ENABLE([xim],
 344    [AC_HELP_STRING([--disable-xim], [disable X Input Method.])],
 345    [
 346     if test "x${enableval}" = "xyes" ; then
 347        want_xim="yes"
 348     else
 349        want_xim="no"
 350     fi
 351    ],
 352    [want_xim="yes"])
 353
 354 if test "x${want_xim}" = "xyes" ; then
 355    AC_DEFINE([ENABLE_XIM], [1], [Enable X Input Method])
 356 fi
 357
 358 ### Checks for programs
 359
 360 m4_ifdef([AC_PROG_OBJC],
 361    [
 362     AC_PROG_OBJC
 363     _AM_DEPENDENCIES(OBJC)
 364    ],
 365    [
 366     AC_CHECK_TOOL([OBJC], [gcc])
 367     AC_SUBST([OBJC])
 368     AC_SUBST([OBJCFLAGS])
 369    ])
 370 m4_ifndef([am__fastdepOBJC], [
 371     AM_CONDITIONAL([am__fastdepOBJC], [false])
 372 ])
 373
 374 AC_PROG_CXX
 375 AC_PROG_CC_C99
 376 if test "x${ac_cv_prog_cc_c99}" = "xno" ; then
 377    AC_MSG_ERROR([ecore requires a c99-capable compiler])
 378 fi
 379
 380 have_gnu_objc=${ac_cv_objc_compiler_gnu}
 381
 382 # doxygen program for documentation building
 383
 384 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 385
 386 m4_ifdef([v_mic],
 387    [
 388     EFL_COMPILER_FLAG([-Wall])
 389     EFL_COMPILER_FLAG([-W])
 390    ])
 391
 392 # The first call to PKG_CHECK_MODULES is done conditionally,
 393 # so we should include this here:
 394 PKG_PROG_PKG_CONFIG
 395
 396 # Check whether pkg-config supports Requires.private
 397 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 398    pkgconfig_requires_private="Requires.private"
 399 else
 400    pkgconfig_requires_private="Requires"
 401 fi
 402 AC_SUBST(pkgconfig_requires_private)
 403
 404 ### Checks for some build time option
 405 have_backtrace="no"
 406 AC_CHECK_FUNCS([backtrace], [have_backtrace="yes"], [])
 407
 408 want_ecore_timer_dump="no"
 409
 410 AC_ARG_ENABLE([ecore-timer-dump],
 411    [AC_HELP_STRING([--disable-ecore-timer-dump], [disable tracking of timer allocation. @<:@default=enable@:>@])],
 412    [want_ecore_timer_dump=$enableval], [])
 413
 414 if test "x$want_ecore_timer_dump" = "xyes" -a "x$have_backtrace" = "xyes"; then
 415    AC_DEFINE(WANT_ECORE_TIMER_DUMP, [1], [Want Ecore_Timer dump infrastructure])
 416 fi
 417
 418 ### Checks for libraries
 419
 420 # Evil library for compilation on Windows
 421
 422 case "$host_os" in
 423    mingw*)
 424       PKG_CHECK_MODULES([EVIL], [evil >= 1.7.8])
 425       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 426       requirements_ecore="evil ${requirements_ecore}"
 427       requirements_ecore_evas="evil ${requirements_ecore_evas}"
 428       requirements_ecore_file="evil ${requirements_ecore_file}"
 429       requirements_ecore_imf="evil ${requirements_ecore_imf}"
 430       requirements_ecore_imf_evas="evil ${requirements_ecore_imf_evas}"
 431       EFL_ECORE_BUILD="-DEFL_ECORE_BUILD"
 432       EFL_ECORE_CON_BUILD="-DEFL_ECORE_CON_BUILD"
 433       EFL_ECORE_EVAS_BUILD="-DEFL_ECORE_EVAS_BUILD"
 434       EFL_ECORE_FILE_BUILD="-DEFL_ECORE_FILE_BUILD"
 435       EFL_ECORE_IMF_BUILD="-DEFL_ECORE_IMF_BUILD"
 436       EFL_ECORE_IMF_EVAS_BUILD="-DEFL_ECORE_IMF_EVAS_BUILD"
 437       EFL_ECORE_INPUT_BUILD="-DEFL_ECORE_INPUT_BUILD"
 438       EFL_ECORE_INPUT_EVAS_BUILD="-DEFL_ECORE_INPUT_EVAS_BUILD"
 439       EFL_ECORE_IPC_BUILD="-DEFL_ECORE_IPC_BUILD"
 440       ;;
 441 esac
 442
 443 have_win32=""
 444 have_wince=""
 445 case "$host_os" in
 446    mingw32ce* | cegcc*)
 447       EFL_ECORE_WINCE_BUILD="-DEFL_ECORE_WINCE_BUILD"
 448       requirements_ecore_wince="evil ${requirements_ecore_wince}"
 449       have_wince="yes"
 450       ;;
 451    mingw*)
 452       EFL_ECORE_WIN32_BUILD="-DEFL_ECORE_WIN32_BUILD"
 453       EFL_ECORE_SDL_BUILD="-DEFL_ECORE_SDL_BUILD"
 454       requirements_ecore_win32="evil ${requirements_ecore_win32}"
 455       requirements_ecore_sdl="evil ${requirements_ecore_sdl}"
 456       have_win32="yes"
 457       ;;
 458 esac
 459
 460 have_ps3=""
 461 case "$host_vendor" in
 462   ps3*)
 463       have_ps3="yes"
 464       PKG_CHECK_MODULES([ESCAPE], [escape])
 465       CFLAGS="$CFLAGS $ESCAPE_CFLAGS"
 466       AC_DEFINE(HAVE_ESCAPE, 1, [Set to 1 if Escape library is installed])
 467       EFL_ECORE_PSL1GHT_BUILD="-DEFL_ECORE_PSL1GHT_BUILD"
 468       requirements_ecore="escape ${requirements_ecore}"
 469       requirements_ecore_evas="escape ${requirements_ecore_evas}"
 470       requirements_ecore_file="escape ${requirements_ecore_file}"
 471       requirements_ecore_imf="escape ${requirements_ecore_imf}"
 472       requirements_ecore_imf_evas="escape ${requirements_ecore_imf_evas}"
 473       requirements_ecore_sdl="escape ${requirements_ecore_sdl}"
 474       want_ecore_psl1ght="yes"
 475       want_ecore_evas_psl1ght="yes"
 476       ;;
 477 esac
 478
 479
 480 ### Checks for portability layer
 481
 482 PKG_CHECK_MODULES([EXOTIC],
 483    [exotic],
 484    [enable_exotic="yes"],
 485    [enable_exotic="no"])
 486
 487 if test "x${enable_exotic}" = "xyes"; then
 488     requirements_ecore="exotic ${requirements_ecore}"
 489
 490     AC_DEFINE([HAVE_EXOTIC], [1], [Define to 1 if you have Exotic.])
 491 fi
 492 AM_CONDITIONAL([ECORE_HAVE_EXOTIC], [test "x${enable_exotic}" = "xyes"])
 493
 494 AC_SUBST(EFL_ECORE_BUILD)
 495 AC_SUBST(EFL_ECORE_CON_BUILD)
 496 AC_SUBST(EFL_ECORE_EVAS_BUILD)
 497 AC_SUBST(EFL_ECORE_FILE_BUILD)
 498 AC_SUBST(EFL_ECORE_IMF_BUILD)
 499 AC_SUBST(EFL_ECORE_IMF_EVAS_BUILD)
 500 AC_SUBST(EFL_ECORE_INPUT_BUILD)
 501 AC_SUBST(EFL_ECORE_INPUT_EVAS_BUILD)
 502 AC_SUBST(EFL_ECORE_IPC_BUILD)
 503 AC_SUBST(EFL_ECORE_WINCE_BUILD)
 504 AC_SUBST(EFL_ECORE_WIN32_BUILD)
 505 AC_SUBST(EFL_ECORE_SDL_BUILD)
 506 AC_SUBST(EFL_ECORE_PSL1GHT_BUILD)
 507
 508 AM_CONDITIONAL(ECORE_HAVE_WINCE, test "x${have_wince}" = "xyes")
 509 AM_CONDITIONAL(ECORE_HAVE_WIN32, test "x${have_win32}" = "xyes")
 510 AM_CONDITIONAL(ECORE_HAVE_PS3, test "x${have_ps3}" = "xyes")
 511
 512 WIN32_LIBS=""
 513 case "$host_os" in
 514    mingw32ce* | cegcc*)
 515       WIN32_LIBS="-lws2"
 516       dlopen_libs="-ldl"
 517       ;;
 518    mingw*)
 519       WIN32_LIBS="-lws2_32"
 520       dlopen_libs="-ldl"
 521       ;;
 522    *)
 523       AC_CHECK_LIB([c], [dlopen],
 524          [],
 525          [AC_CHECK_LIB([dl], [dlopen],
 526              [dlopen_libs=-ldl])
 527          ])
 528       AC_CHECK_LIB([c], [clock_gettime],
 529          [AC_DEFINE(HAVE_CLOCK_GETTIME, [1], [Have clock_gettime()])],
 530          [AC_CHECK_LIB([rt], [clock_gettime],
 531              [
 532               rt_libs=-lrt
 533               AC_DEFINE(HAVE_CLOCK_GETTIME, [1], [Have clock_gettime()])
 534              ])
 535          ])
 536       ;;
 537 esac
 538 AC_SUBST(WIN32_LIBS)
 539 AC_SUBST(dlopen_libs)
 540 AC_SUBST(rt_libs)
 541
 542 # Eina library
 543
 544 PKG_CHECK_MODULES(EINA, [eina >= 1.7.8])
 545 #FIXME check all the requirements when the eina move will be finished
 546 requirements_ecore="eina >= 1.7.8 ${requirements_ecore}"
 547 requirements_ecore_con="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_con}"
 548 #requirements_ecore_config="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_config}"
 549 requirements_ecore_directfb="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_directfb}"
 550 requirements_ecore_evas="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_evas}"
 551 requirements_ecore_fb="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_fb}"
 552 requirements_ecore_file="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_file}"
 553 requirements_ecore_imf="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_imf}"
 554 requirements_ecore_imf_evas="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_imf_evas}"
 555 requirements_ecore_input="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_input}"
 556 requirements_ecore_input_evas="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_input_evas}"
 557 requirements_ecore_ipc="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_ipc}"
 558 requirements_ecore_cocoa="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_cocoa}"
 559 requirements_ecore_sdl="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_sdl}"
 560 requirements_ecore_psl1ght="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_psl1ght}"
 561 requirements_ecore_win32="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_win32}"
 562 requirements_ecore_wince="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_wince}"
 563 requirements_ecore_x="ecore >= 1.7.8 eina >= 1.7.8 ${requirements_ecore_x}"
 564
 565
 566 # glib support (main loop integration)
 567 AC_ARG_ENABLE([glib],
 568    [AC_HELP_STRING([--disable-glib], [disable glib support. @<:@default=detect@:>@])],
 569    [want_glib=$enableval], [])
 570
 571 if test "x$want_glib" != "xno"; then
 572    PKG_CHECK_MODULES([GLIB], [glib-2.0], [have_glib="yes"], [have_glib="no"])
 573 else
 574    have_glib="no"
 575 fi
 576 if test "x$want_glib" = "xyes" -a "x$have_glib" = "xno"; then
 577    AC_MSG_ERROR([GLib support requested, but no GLib found by pkg-config.])
 578 elif test "x$have_glib" = "xyes"; then
 579    AC_DEFINE(HAVE_GLIB, [1], [Have GLib])
 580    requirements_ecore="glib-2.0 ${requirements_ecore}"
 581 fi
 582
 583
 584 # SDL library (ecore_sdl)
 585
 586 have_sdl="no"
 587 PKG_CHECK_MODULES([SDL], [sdl >= 1.2.0], [have_sdl="yes"], [have_sdl="no"])
 588 if test "x${have_sdl}" != "xyes" ; then
 589    SDL_CONFIG="sdl-config"
 590    AC_ARG_WITH([sdl-config],
 591       [AC_HELP_STRING([--with-sdl-config=PATH], [use sdl-config specified])],
 592       [
 593        SDL_CONFIG=$withval
 594        AC_MSG_NOTICE([using ${SDL_CONFIG} for sdl-config])
 595       ])
 596
 597    AC_PATH_PROG([SDL_CONFIG], ["sdl-config"], [""], [$PATH])
 598
 599    if test -n "$SDL_CONFIG" ; then
 600       SDL_CFLAGS=`$SDL_CONFIG --cflags`
 601       SDL_LIBS=`$SDL_CONFIG --libs`
 602       AC_SUBST(SDL_CFLAGS)
 603       AC_SUBST(SDL_LIBS)
 604       have_sdl="yes"
 605    fi
 606 fi
 607
 608 if test "x${have_sdl}" = "xyes" ; then
 609    PKG_CHECK_EXISTS([sdl >= 1.3.0],
 610       [AC_DEFINE(BUILD_ECORE_EVAS_SDL_130, 1, [Support for SVN SDL])])
 611 fi
 612
 613
 614 # DirectFB library (ecore_directfb)
 615
 616 PKG_CHECK_MODULES([DIRECTFB],
 617    [directfb >= 0.9.16],
 618    [have_directfb="yes"],
 619    [have_directfb="no"])
 620
 621
 622 # Eet library (ecore_config)
 623
 624 #PKG_CHECK_MODULES([EET],
 625 #   [eet >= 1.7.8],
 626 #   [have_eet="yes"],
 627 #   [have_eet="no"])
 628
 629
 630 # Xlib and XCB (ecore_x)
 631
 632 AC_CHECK_DECL([MAXHOSTNAMELEN], [FOUND_MAXHOSTNAMELEN=yes])
 633
 634 if test "x${FOUND_MAXHOSTNAMELEN}" != "xyes" ; then
 635    AC_MSG_CHECKING([for header that defines MAXHOSTNAMELEN])
 636    FOUND_MAXHOSTNAMELEN="not found"
 637
 638    AC_COMPILE_IFELSE(
 639       [
 640        AC_LANG_PROGRAM(
 641           [[
 642 #include <sys/param.h>
 643           ]],
 644           [[
 645 int h = MAXHOSTNAMELEN;
 646           ]])
 647       ],
 648       [
 649        FOUND_MAXHOSTNAMELEN="sys/param.h"
 650        AC_DEFINE([NEED_SYS_PARAM_H], [1], [Define to 1 if you need <sys/param.h> to define MAXHOSTNAMELEN])
 651       ])
 652
 653    AC_COMPILE_IFELSE(
 654       [
 655        AC_LANG_PROGRAM(
 656           [[
 657 #include <netdb.h>
 658           ]],
 659           [[
 660 int h = MAXHOSTNAMELEN;
 661           ]])
 662       ],
 663       [
 664        FOUND_MAXHOSTNAMELEN="netdb.h"
 665        AC_DEFINE([NEED_NETDB_H], [1], [Define to 1 if you need <netdb.h> to define MAXHOSTNAMELEN])
 666       ])
 667
 668    AC_MSG_RESULT([$FOUND_MAXHOSTNAMELEN])
 669 fi
 670
 671 have_x="no"
 672 have_ecore_x="no"
 673 have_ecore_x_xlib="no"
 674 have_ecore_x_xcb="no"
 675
 676 x_dir="";
 677 x_includes="";
 678 x_cflags="";
 679 x_libs="";
 680
 681 ecore_x_libs_private=""
 682
 683 AC_ARG_ENABLE(ecore-x-composite,
 684    [AC_HELP_STRING([--disable-ecore-x-composite],
 685        [disable the ecore_x support for Xcomposite extension.
 686         @<:@default=detect@:>@])],
 687    [want_ecore_x_composite=$enableval])
 688
 689 AC_ARG_ENABLE(ecore-x-damage,
 690    [AC_HELP_STRING([--disable-ecore-x-damage],
 691        [disable the ecore_x support for Xdamage extension.
 692         @<:@default=detect@:>@])],
 693    [want_ecore_x_damage=$enableval])
 694
 695 AC_ARG_ENABLE(ecore-x-dpms,
 696    [AC_HELP_STRING([--disable-ecore-x-dpms],
 697        [disable the ecore_x support for Xdpms extension.
 698         @<:@default=detect@:>@])],
 699    [want_ecore_x_dpms=$enableval])
 700
 701 AC_ARG_ENABLE(ecore-x-randr,
 702    [AC_HELP_STRING([--disable-ecore-x-randr],
 703        [disable the ecore_x support for Xrandr extension.
 704         @<:@default=detect@:>@])],
 705    [want_ecore_x_randr=$enableval])
 706
 707 AC_ARG_ENABLE(ecore-x-render,
 708    [AC_HELP_STRING([--disable-ecore-x-render],
 709        [disable the ecore_x support for Xrender extension.
 710         @<:@default=detect@:>@])],
 711    [want_ecore_x_render=$enableval])
 712
 713 AC_ARG_ENABLE(ecore-x-screensaver,
 714    [AC_HELP_STRING([--disable-ecore-x-screensaver],
 715        [disable the ecore_x support for Xscreensaver extension.
 716         @<:@default=detect@:>@])],
 717    [want_ecore_x_screensaver=$enableval])
 718
 719 AC_ARG_ENABLE(ecore-x-shape,
 720    [AC_HELP_STRING([--disable-ecore-x-shape],
 721        [disable the ecore_x support for Xshape extension.
 722         @<:@default=detect@:>@])],
 723    [want_ecore_x_shape=$enableval])
 724
 725 AC_ARG_ENABLE(ecore-x-gesture,
 726    [AC_HELP_STRING([--enable-ecore-x-gesture],
 727        [enable the ecore_x support for Xgesture extension.
 728         @<:@default=detect@:>@])],
 729    [want_ecore_x_gesture=$enableval])
 730
 731 AC_ARG_ENABLE(ecore-x-sync,
 732    [AC_HELP_STRING([--disable-ecore-x-sync],
 733        [disable the ecore_x support for Xsync extension.
 734         @<:@default=detect@:>@])],
 735    [want_ecore_x_sync=$enableval])
 736
 737 AC_ARG_ENABLE(ecore-x-xfixes,
 738    [AC_HELP_STRING([--disable-ecore-x-xfixes],
 739        [disable the ecore_x support for Xfixes extension.
 740         @<:@default=detect@:>@])],
 741    [want_ecore_x_xfixes=$enableval])
 742
 743 AC_ARG_ENABLE(ecore-x-xinerama,
 744    [AC_HELP_STRING([--disable-ecore-x-xinerama],
 745        [disable the ecore_x support for Xinerama extension.
 746         @<:@default=detect@:>@])],
 747    [want_ecore_x_xinerama=$enableval])
 748
 749 AC_ARG_ENABLE(ecore-x-xprint,
 750    [AC_HELP_STRING([--disable-ecore-x-xprint],
 751        [disable the ecore_x support for Xprint extension.
 752         @<:@default=detect@:>@])],
 753    [want_ecore_x_xprint=$enableval])
 754
 755 AC_ARG_ENABLE(ecore-x-xtest,
 756    [AC_HELP_STRING([--disable-ecore-x-xtest],
 757        [disable the ecore_x support for Xtest extension.
 758         @<:@default=detect@:>@])],
 759    [want_ecore_x_xtest=$enableval])
 760
 761 AC_ARG_ENABLE(ecore-x-cursor,
 762    [AC_HELP_STRING([--disable-ecore-x-cursor],
 763        [disable the ecore_x support for Xcursor extension.
 764         @<:@default=detect@:>@])],
 765    [want_ecore_x_cursor=$enableval])
 766
 767 AC_ARG_ENABLE(ecore-x-input,
 768    [AC_HELP_STRING([--disable-ecore-x-input],
 769        [disable the ecore_x support for Xinput/Xinput2 extension.
 770         @<:@default=detect@:>@])],
 771    [want_ecore_x_input=$enableval])
 772
 773 AC_ARG_ENABLE(ecore-x-dri,
 774    [AC_HELP_STRING([--disable-ecore-x-dri],
 775        [disable the ecore_x support for DRI extension.
 776         @<:@default=detect@:>@])],
 777    [want_ecore_x_dri=$enableval])
 778
 779 AC_ARG_ENABLE(ecore-x-xcb,
 780    [AC_HELP_STRING([--enable-ecore-x-xcb],
 781        [enable the ecore_x module with XCB backend. @<:@default=disabled@:>@])],
 782    [want_ecore_x_xcb=$enableval])
 783
 784 AC_MSG_CHECKING(whether ecore_x with XCB backend is to be built)
 785 AC_MSG_RESULT($want_ecore_x_xcb)
 786
 787 if test "x$want_ecore_x_xcb" = "xyes" ; then
 788
 789   AC_MSG_CHECKING([keysym definitions])
 790   KEYSYMDEFDIR=`$PKG_CONFIG --variable=includedir xproto`/X11
 791   FILES="keysymdef.h XF86keysym.h Sunkeysym.h DECkeysym.h HPkeysym.h"
 792   for i in $FILES; do
 793       if test -f "$KEYSYMDEFDIR/$i"; then
 794         KEYSYMDEFS="$KEYSYMDEFS $KEYSYMDEFDIR/$i"
 795       elif test "x$i" = "xkeysymdef.h"; then
 796         AC_MSG_ERROR([Cannot find keysymdef.h])
 797       fi
 798   done
 799   AC_MSG_RESULT([$KEYSYMDEFS])
 800   AC_SUBST(KEYSYMDEFS)
 801
 802   have_iconv="no"
 803   AC_ARG_WITH([iconv-link],
 804     AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 805       [
 806         LIBS="$withval $LIBS"
 807         have_iconv="yes"
 808       ])
 809
 810   AC_MSG_CHECKING(for explicit iconv link options)
 811   if test "x${iconv_libs}" = "x" ; then
 812     AC_MSG_RESULT([no explicit iconv link option])
 813   else
 814     AC_MSG_RESULT([$iconv_libs])
 815   fi
 816
 817   if test "x${have_iconv}" = "xno" ; then
 818     AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 819
 820     if test "x${have_iconv}" = "xyes" ; then
 821       AC_MSG_CHECKING([whether iconv() is in libc])
 822
 823       AC_LINK_IFELSE(
 824         [AC_LANG_PROGRAM(
 825         [[
 826           #include <stdlib.h>
 827           #include <iconv.h>
 828         ]],
 829         [[
 830           iconv_t ic;
 831           size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 832         ]])],
 833         [have_iconv="yes"],
 834         [have_iconv="no"])
 835
 836       AC_MSG_RESULT([${have_iconv}])
 837     fi
 838
 839     if test "x${have_iconv}" = "xno" ; then
 840       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 841
 842       LIBS_save="${LIBS}"
 843       LIBS="-liconv $LIBS"
 844       AC_LINK_IFELSE(
 845       [AC_LANG_PROGRAM(
 846         [[
 847           #include <stdlib.h>
 848           #include <iconv.h>
 849         ]],
 850         [[
 851           iconv_t ic;
 852           size_t count;
 853           count = iconv(ic, NULL, NULL, NULL, NULL);
 854         ]])],
 855         [have_iconv="yes"],
 856         [
 857           have_iconv="no"
 858           LIBS=${LIBS_save}
 859         ])
 860
 861       AC_MSG_RESULT([${have_iconv}])
 862     fi
 863
 864     if test "x${have_iconv}" = "xno" ; then
 865       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 866
 867       LIBS_save="${LIBS}"
 868       LIBS="-liconv_plug $LIBS"
 869       AC_LINK_IFELSE(
 870       [AC_LANG_PROGRAM(
 871       [[
 872         #include <stdlib.h>
 873         #include <iconv.h>
 874       ]],
 875       [[
 876         iconv_t ic;
 877         size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 878       ]])],
 879       [have_iconv="yes"],
 880       [
 881         have_iconv="no"
 882         LIBS=${LIBS_save}
 883       ])
 884
 885       AC_MSG_RESULT([${have_iconv}])
 886     fi
 887
 888     if test "x${have_iconv}" = "xyes" ; then
 889       AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 890     fi
 891   fi
 892
 893   PKG_CHECK_MODULES(ECORE_XCB, x11-xcb xcb xcb-shm xcb-event xcb-icccm >= 0.3.8 xcb-util >= 0.3.8 xcb-image xcb-keysyms >= 0.3.8,
 894     [ have_ecore_x_xcb="yes"
 895       requirements_ecore_x="x11-xcb xcb xcb-shm xcb-event xcb-icccm xcb-util xcb-image xcb-keysyms ${requirements_ecore_x}"
 896     ],
 897     [
 898         PKG_CHECK_MODULES(ECORE_XCB, x11-xcb xcb xcb-event xcb-shm xcb-icccm xcb-image xcb-keysyms,
 899           [ have_ecore_x_xcb="yes"
 900             AC_DEFINE(OLD_XCB_VERSION, 1, [xcb version])
 901             requirements_ecore_x="x11-xcb xcb xcb-event xcb-shm xcb-icccm xcb-image xcb-keysyms ${requirements_ecore_x}" ],
 902           [ have_ecore_x_xcb="no" ])
 903     ],
 904     [have_ecore_x_xcb="no" ])
 905
 906   if test "x$have_ecore_x_xcb" = "xyes" ; then
 907
 908    PKG_CHECK_MODULES([PIXMAN],
 909       [pixman-1],
 910       [
 911        have_pixman="yes"
 912        AC_DEFINE(HAVE_PIXMAN, 1, [have pixman for rendering])
 913        requirements_ecore_x="pixman-1 ${requirements_ecore_x}"
 914       ],
 915       [
 916        if test "x${want_pixman}" = "xyes" -a "x${use_strict}" = "xyes" ; then
 917           AC_MSG_ERROR([Pixman not found (strict dependencies checking)])
 918        fi
 919       ])
 920
 921     if test "x$want_ecore_x_composite" != "xno"; then
 922       PKG_CHECK_MODULES(XCB_COMPOSITE, xcb-composite,
 923         [ have_ecore_x_xcb_composite="yes"
 924           requirements_ecore_x="xcb-composite ${requirements_ecore_x}"
 925           AC_DEFINE(ECORE_XCB_COMPOSITE, 1, [Build support for XCB composite]) ],
 926         [ have_ecore_x_xcb_composite="no" ])
 927     else
 928       have_ecore_x_xcb_composite="no"
 929       AC_MSG_NOTICE("composite extension explicitly disabled")
 930     fi
 931
 932     if test "x$want_ecore_x_damage" != "xno"; then
 933       PKG_CHECK_MODULES(XCB_DAMAGE, xcb-damage,
 934         [ have_ecore_x_xcb_damage="yes"
 935           requirements_ecore_x="xcb-damage ${requirements_ecore_x}"
 936           AC_DEFINE(ECORE_XCB_DAMAGE, 1, [Build support for XCB damage]) ],
 937         [ have_ecore_x_xcb_damage="no" ])
 938     else
 939       have_ecore_x_xcb_damage="no"
 940       AC_MSG_NOTICE("damage extension explicitly disabled")
 941     fi
 942
 943     if test "x$want_ecore_x_dpms" != "xno"; then
 944       PKG_CHECK_MODULES(XCB_DPMS, xcb-dpms,
 945         [ have_ecore_x_xcb_dpms="yes"
 946           requirements_ecore_x="xcb-dpms ${requirements_ecore_x}"
 947           AC_DEFINE(ECORE_XCB_DPMS, 1, [Build support for XCB dpms]) ],
 948         [ have_ecore_x_xcb_dpms="no" ])
 949     else
 950       have_ecore_x_xcb_dpms="no"
 951       AC_MSG_NOTICE("dpms extension explicitly disabled")
 952     fi
 953
 954     if test "x$want_ecore_x_randr" != "xno"; then
 955       PKG_CHECK_MODULES(XCB_RANDR, xcb-randr,
 956         [ have_ecore_x_xcb_randr="yes"
 957           requirements_ecore_x="xcb-randr ${requirements_ecore_x}"
 958           AC_DEFINE(ECORE_XCB_RANDR, 1, [Build support for XCB randr]) ],
 959         [ have_ecore_x_xcb_randr="no" ])
 960     else
 961       have_ecore_x_xcb_randr="no"
 962       AC_MSG_NOTICE("randr extension explicitly disabled")
 963     fi
 964
 965     if test "x$want_ecore_x_render" != "xno"; then
 966       PKG_CHECK_MODULES(XCB_RENDER, xcb-render xcb-renderutil,
 967         [ have_ecore_x_xcb_render="yes"
 968           requirements_ecore_x="xcb-render xcb-renderutil ${requirements_ecore_x}"
 969           AC_DEFINE(ECORE_XCB_RENDER, 1, [Build support for XCB render]) ],
 970         [ have_ecore_x_xcb_render="no" ])
 971     else
 972       have_ecore_x_xcb_render="no"
 973       AC_MSG_NOTICE("render extension explicitly disabled")
 974     fi
 975
 976     if test "x$want_ecore_x_screensaver" != "xno"; then
 977       PKG_CHECK_MODULES(XCB_SCREENSAVER, xcb-screensaver,
 978         [ have_ecore_x_xcb_screensaver="yes"
 979           requirements_ecore_x="xcb-screensaver ${requirements_ecore_x}"
 980           AC_DEFINE(ECORE_XCB_SCREENSAVER, 1, [Build support for XCB screensaver]) ],
 981         [ have_ecore_x_xcb_screensaver="no" ])
 982     else
 983       have_ecore_x_xcb_screensaver="no"
 984       AC_MSG_NOTICE("screensaver extension explicitly disabled")
 985     fi
 986
 987     if test "x$want_ecore_x_shape" != "xno"; then
 988       PKG_CHECK_MODULES(XCB_SHAPE, xcb-shape,
 989         [ have_ecore_x_xcb_shape="yes"
 990           requirements_ecore_x="xcb-shape ${requirements_ecore_x}"
 991           AC_DEFINE(ECORE_XCB_SHAPE, 1, [Build support for XCB shape]) ],
 992         [ have_ecore_x_xcb_shape="no" ])
 993     else
 994       have_ecore_x_xcb_shape="no"
 995       AC_MSG_NOTICE("shape extension explicitly disabled")
 996     fi
 997
 998     if test "x$want_ecore_x_gesture" != "xno"; then
 999       PKG_CHECK_MODULES(XCB_XGESTURE, xcb-gesture,
1000         [ have_ecore_x_xcb_gesture="yes"
1001           requirements_ecore_x="xcb-gesture ${requirements_ecore_x}"
1002           AC_DEFINE(ECORE_XCB_XGESTURE, 1, [Build support for XCB gesture]) ],
1003         [ have_ecore_x_xcb_gesture="no" ])
1004     else
1005       have_ecore_x_xcb_gesture="no"
1006       AC_MSG_NOTICE("gesture extension explicitly disabled")
1007     fi
1008
1009     if test "x$want_ecore_x_sync" != "xno"; then
1010       PKG_CHECK_MODULES(XCB_SYNC, xcb-sync,
1011         [ have_ecore_x_xcb_sync="yes"
1012           requirements_ecore_x="xcb-sync ${requirements_ecore_x}"
1013           AC_DEFINE(ECORE_XCB_SYNC, 1, [Build support for XCB sync]) ],
1014         [ have_ecore_x_xcb_sync="no" ])
1015     else
1016       have_ecore_x_xcb_sync="no"
1017       AC_MSG_NOTICE("sync extension explicitly disabled")
1018     fi
1019
1020     if test "x$want_ecore_x_xfixes" != "xno"; then
1021       PKG_CHECK_MODULES(XCB_XFIXES, xcb-xfixes,
1022         [ have_ecore_x_xcb_xfixes="yes"
1023           requirements_ecore_x="xcb-xfixes ${requirements_ecore_x}"
1024           AC_DEFINE(ECORE_XCB_XFIXES, 1, [Build support for XCB xfixes]) ],
1025         [ have_ecore_x_xcb_xfixes="no" ])
1026     else
1027       have_ecore_x_xcb_xfixes="no"
1028       AC_MSG_NOTICE("xfixes extension explicitly disabled")
1029     fi
1030
1031     if test "x$want_ecore_x_xinerama" != "xno"; then
1032       PKG_CHECK_MODULES(XCB_XINERAMA, xcb-xinerama,
1033         [ have_ecore_x_xcb_xinerama="yes"
1034           requirements_ecore_x="xcb-xinerama ${requirements_ecore_x}"
1035           AC_DEFINE(ECORE_XCB_XINERAMA, 1, [Build support for XCB xinerama]) ],
1036         [ have_ecore_x_xcb_xinerama="no" ])
1037     else
1038       have_ecore_x_xcb_xinerama="no"
1039       AC_MSG_NOTICE("xinerama extension explicitly disabled")
1040     fi
1041
1042     if test "x$want_ecore_x_xprint" != "xno"; then
1043       PKG_CHECK_MODULES(XCB_XPRINT, xcb-xprint,
1044         [ have_ecore_x_xcb_xprint="yes"
1045           requirements_ecore_x="xcb-xprint ${requirements_ecore_x}"
1046           AC_DEFINE(ECORE_XCB_XPRINT, 1, [Build support for XCB xprint]) ],
1047         [ have_ecore_x_xcb_xprint="no" ])
1048     else
1049       have_ecore_x_xcb_xprint="no"
1050       AC_MSG_NOTICE("xprint extension explicitly disabled")
1051     fi
1052
1053     if test "x$want_ecore_x_xtest" != "xno"; then
1054       PKG_CHECK_MODULES(XCB_XTEST, xcb-xtest,
1055         [ have_ecore_x_xcb_xtest="yes"
1056           requirements_ecore_x="xcb-xtest ${requirements_ecore_x}"
1057           AC_DEFINE(ECORE_XCB_XTEST, 1, [Build support for XCB xtest]) ],
1058         [ have_ecore_x_xcb_xtest="no" ])
1059     else
1060       have_ecore_x_xcb_xtest="no"
1061       AC_MSG_NOTICE("xtest extension explicitly disabled")
1062     fi
1063
1064 # input extension disabled currently in xcb as xcb-input has some issues
1065     want_ecore_x_input="no"
1066     if test "x$want_ecore_x_input" != "xno"; then
1067       PKG_CHECK_MODULES(XCB_XINPUT, xcb-xinput,
1068         [ have_ecore_x_xcb_xinput="yes"
1069           requirements_ecore_x="xcb-xinput ${requirements_ecore_x}"
1070           AC_DEFINE(ECORE_XCB_XINPUT, 1, [Build support for XCB xinput]) ],
1071         [ have_ecore_x_xcb_xinput="no" ])
1072     else
1073       have_ecore_x_xcb_xinput="no"
1074       AC_MSG_NOTICE("xinput extension explicitly disabled")
1075     fi
1076
1077     if test "x$want_ecore_x_cursor" != "xno"; then
1078       PKG_CHECK_MODULES(XCB_CURSOR, xcb-render xcb-renderutil,
1079         [ have_ecore_x_xcb_cursor="yes"
1080           requirements_ecore_x="xcb-render xcb-renderutil ${requirements_ecore_x}"
1081           AC_DEFINE(ECORE_XCB_CURSOR, 1, [Build support for XCB cursor]) ],
1082         [ have_ecore_x_xcb_cursor="no" ])
1083     else
1084       have_ecore_x_xcb_cursor="no"
1085       AC_MSG_NOTICE("cursor extension explicitly disabled")
1086     fi
1087
1088 #    if test "x$want_ecore_x_dri" != "xno"; then
1089 #      PKG_CHECK_MODULES(XCB_DRI, xcb-dri2,
1090 #        [ have_ecore_x_xcb_dri="yes"
1091 #          requirements_ecore_x="xcb-dri2 ${requirements_ecore_x}"
1092 #          AC_DEFINE(ECORE_XCB_DRI, 1, [Build support for XCB dri/dri2]) ],
1093 #        [ have_ecore_x_xcb_dri="no" ])
1094 #    else
1095 #      have_ecore_x_xcb_dri="no"
1096 #      AC_MSG_NOTICE("dri extension explicitly disabled")
1097 #    fi
1098
1099     AC_DEFINE(HAVE_ECORE_X_XCB, 1, [Defined to 1 if XCB is enabled.])
1100
1101     x_cflags=$ECORE_XCB_CFLAGS
1102     x_libs=$ECORE_XCB_LIBS
1103     have_x="yes"
1104
1105     have_ecore_x_xcb_define="-DHAVE_ECORE_X_XCB"
1106     AC_SUBST(have_ecore_x_xcb_define)
1107   fi
1108 fi
1109
1110 if ! test "x$have_ecore_x_xcb" = "xyes" ; then
1111   AC_PATH_XTRA
1112   AC_CHECK_HEADER(X11/X.h,
1113     [
1114      if test "x$want_evas_simple_x11" = "xyes"; then
1115        x_libs="${x_libs} -lX11 -lXext"
1116      else
1117        x_dir=${x_dir:-/usr/X11R6}
1118        x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
1119        x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
1120      fi
1121      have_ecore_x_xlib="yes"
1122     ]
1123   )
1124
1125   if test "x$have_ecore_x_xlib" = "xyes"; then
1126     Xcursor_libs=""
1127     Xcursor_cflags=""
1128     use_Xcursor="no"
1129     PCFLAGS=$CFLAGS
1130     CFLAGS="$x_cflags $x_includes"
1131
1132     if test "x$want_ecore_x_cursor" = "xyes"; then
1133       AC_CHECK_HEADER(X11/Xcursor/Xcursor.h,
1134         [
1135           AC_CHECK_LIB(Xcursor, XcursorImageLoadCursor,
1136             [
1137               AC_DEFINE(ECORE_XCURSOR, 1, [Build support for Xcursor])
1138               Xcursor_cflags=""
1139               Xcursor_libs="-lXcursor"
1140               use_Xcursor="yes"
1141             ], [
1142               Xcursor_cflags=""
1143               Xcursor_libs=""
1144               use_Xcursor="no"
1145             ], [
1146               $x_libs -lXrender
1147             ]
1148           )
1149         ], [
1150           Xcursor_cflags=""
1151           Xcursor_libs=""
1152           use_Xcursor="no"
1153         ], [
1154           #include <X11/Xlib.h>
1155         ]
1156       )
1157       CFLAGS=$PCFLAGS
1158     else
1159       Xcursor_cflags=""
1160       Xcursor_libs=""
1161       use_Xcursor="no"
1162       AC_MSG_NOTICE("Xcursor explicitly disabled")
1163     fi
1164
1165     AC_SUBST(Xcursor_cflags)
1166     AC_SUBST(Xcursor_libs)
1167
1168     ECORE_CHECK_X_EXTENSION([Xkb], [XKB.h], [X11], [XkbSetDetectableAutoRepeat], [$want_ecore_x_xkb])
1169     ECORE_CHECK_X_EXTENSION([Xcomposite], [Xcomposite.h], [Xcomposite], [XCompositeQueryExtension], [$want_ecore_x_composite])
1170     ECORE_CHECK_X_EXTENSION([Xdamage], [Xdamage.h], [Xdamage], [XDamageSubtract], [$want_ecore_x_damage])
1171     ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xdpms], [DPMSQueryExtension], [$want_ecore_x_dpms])
1172     if test "x$use_xdpms" = "xno" ; then
1173       ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xext], [DPMSQueryExtension], [$want_ecore_x_dpms])
1174     fi
1175     ECORE_CHECK_X_EXTENSION([Xfixes], [Xfixes.h], [Xfixes], [XFixesExpandRegion], [$want_ecore_x_xfixes])
1176     ECORE_CHECK_X_EXTENSION([Xinerama], [Xinerama.h], [Xinerama], [XineramaQueryScreens], [$want_ecore_x_xinerama])
1177     ECORE_CHECK_X_EXTENSION([Xprint], [Print.h], [Xp], [XpQueryScreens], [$want_ecore_x_xprint])
1178     ECORE_CHECK_X_EXTENSION([Xrandr], [Xrandr.h], [Xrandr], [XRRGetScreenResourcesCurrent], [$want_ecore_x_randr])
1179     ECORE_CHECK_X_EXTENSION([Xgesture], [gesture.h], [Xgesture], [XGestureQueryExtension], [$want_ecore_x_gesture])
1180     ECORE_CHECK_X_EXTENSION([Xrender], [Xrender.h], [Xrender], [XRenderFindVisualFormat], [$want_ecore_x_render])
1181     ECORE_CHECK_X_EXTENSION([Xtest], [XTest.h], [Xtst], [XTestFakeKeyEvent], [$want_ecore_x_xtest])
1182     ECORE_CHECK_X_EXTENSION([Xss], [scrnsaver.h], [Xss], [XScreenSaverSelectInput], [$want_ecore_x_screensaver])
1183     ECORE_CHECK_X_EXTENSION([Xi2], [XInput2.h], [Xi], [XIQueryDevice], [$want_ecore_x_input])
1184
1185     ecore_x_libs_private="${Xcursor_libs} ${XKB_LIBS} ${XCOMPOSITE_LIBS} ${XGESTURE_LIBS} ${XDAMAGE_LIBS} ${XDPMS_LIBS} ${XFIXES_LIBS} ${XINERAMA_LIBS} ${XPRINT_LIBS} ${XRANDR_LIBS} ${XRENDER_LIBS} ${XTEST_LIBS} ${XSS_LIBS} ${XI2_LIBS}"
1186
1187     AC_DEFINE(HAVE_ECORE_X_XLIB, 1, [Defined to 1 if Xlib is enabled.])
1188     have_x="yes"
1189
1190     have_ecore_x_xlib="yes"
1191   fi
1192 fi
1193
1194 AC_SUBST(x_cflags)
1195 AC_SUBST(x_includes)
1196 AC_SUBST(x_libs)
1197 AC_SUBST(ecore_x_libs_private)
1198
1199 AM_CONDITIONAL(BUILD_ECORE_X_XLIB, test $have_ecore_x_xlib = yes)
1200 AM_CONDITIONAL(BUILD_ECORE_X_XCB, test $have_ecore_x_xcb = yes)
1201
1202
1203 # Evas library (ecore_config, ecore_input_evas, ecore_imf_evas and ecore_evas)
1204
1205 PKG_CHECK_MODULES([EVAS], [evas >= 1.7.8],
1206    [have_evas="yes"],
1207    [have_evas="no"])
1208
1209
1210 ### Checks for header files
1211
1212 AC_CHECK_HEADERS([sys/select.h sys/prctl.h])
1213
1214 EFL_CHECK_PATH_MAX
1215
1216 AC_HEADER_SYS_WAIT
1217 AC_SYS_LARGEFILE
1218
1219 have_addrinfo="no"
1220 case "$host_os" in
1221    mingw* | cegcc*)
1222       AC_DEFINE(HAVE_DLFCN_H, 1, [Define to 1 if you have the <dlfcn.h> header file.])
1223       AC_DEFINE(HAVE_SYS_MMAN_H, 1, [Define to 1 if you have the <sys/mman.h> header file.])
1224       AC_DEFINE(HAVE_SYS_TIME_H, 1, [Define to 1 if you have the <sys/time.h> header file.])
1225       have_addrinfo="yes"
1226       ;;
1227    *)
1228       AC_CHECK_HEADERS([dlfcn.h features.h langinfo.h locale.h sys/time.h sys/mman.h signal.h sys/resource.h])
1229       ;;
1230 esac
1231
1232 # ecore_con
1233
1234 AC_CHECK_HEADERS([sys/socket.h])
1235 AC_CHECK_HEADERS([net/if.h], [], [],
1236 [
1237 #include <stdio.h>
1238 #ifdef STDC_HEADERS
1239 # include <stdlib.h>
1240 # include <stddef.h>
1241 #else
1242 # ifdef HAVE_STDLIB_H
1243 #  include <stdlib.h>
1244 # endif
1245 #endif
1246 #ifdef HAVE_SYS_SOCKET_H
1247 # include <sys/socket.h>
1248 #endif
1249 ])
1250 AC_CHECK_HEADERS([sys/un.h], [], [],
1251 [
1252 #include <stdio.h>
1253 #ifdef STDC_HEADERS
1254 # include <stdlib.h>
1255 # include <stddef.h>
1256 #else
1257 # ifdef HAVE_STDLIB_H
1258 #  include <stdlib.h>
1259 # endif
1260 #endif
1261 #ifdef HAVE_SYS_SOCKET_H
1262 # include <sys/socket.h>
1263 #endif
1264 ])
1265 AC_CHECK_HEADERS([arpa/inet.h arpa/nameser.h netinet/tcp.h netinet/in.h ws2tcpip.h netdb.h errno.h])
1266
1267 if test "x${ac_cv_header_netdb_h}" = "xyes" ; then
1268    have_addrinfo="yes"
1269 fi
1270
1271 # Framebuffer (ecore_fb)
1272 have_fb="no"
1273 AC_CHECK_HEADER([linux/fb.h],
1274    [AC_CHECK_HEADER([linux/input.h], [have_fb="yes"])])
1275
1276 # Cocoa header files (ecore_cocoa)
1277
1278 if test "x${want_ecore_cocoa}" = "xyes" ; then
1279    cocoa_ldflags=""
1280    have_cocoa="no"
1281    m4_ifdef([AC_PROG_OBJC],
1282       [
1283        if test "x${have_gnu_objc}" = "xyes" ; then
1284           AC_LANG_PUSH([Objective C])
1285           LIBS_save="$LIBS"
1286           LIBS="$LIBS -framework Cocoa"
1287           AC_LINK_IFELSE(
1288              [AC_LANG_PROGRAM(
1289                  [[
1290 #include <Cocoa/Cocoa.h>
1291                  ]],
1292                  [[
1293 NSWindow *window;
1294 window = [[NSWindow alloc]
1295            initWithContentRect:NSMakeRect(0, 0, 1, 1)
1296            styleMask:(NSTitledWindowMask)
1297            backing:NSBackingStoreBuffered
1298            defer:NO
1299            screen:nil
1300          ];
1301                  ]])],
1302              [
1303               have_cocoa="yes"
1304               cocoa_ldflags="-framework Cocoa"
1305              ],
1306              [have_cocoa="no"])
1307           LIBS="$LIBS_save"
1308           AC_MSG_CHECKING([whether Cocoa framework is supported])
1309           AC_MSG_RESULT([${have_cocoa}])
1310           AC_LANG_POP([Objective C])
1311        fi
1312    ])
1313 fi
1314 AC_SUBST(cocoa_ldflags)
1315
1316 want_epoll=yes
1317 AC_ARG_ENABLE(epoll,
1318   AC_HELP_STRING([--enable-epoll], [enable or disable epoll support]),
1319   [want_epoll=$enableval])
1320
1321 if test "x${want_epoll}" = "xyes" ; then
1322   # check for epoll support
1323   AC_CHECK_HEADERS([sys/epoll.h])
1324 fi
1325
1326 # timerfd_create
1327 AC_CHECK_HEADERS([sys/timerfd.h])
1328 AC_CHECK_FUNCS(timerfd_create)
1329
1330 # thread support
1331
1332 EFL_CHECK_THREADS(
1333    [
1334     if test "x${_efl_have_posix_threads}" = "xyes" ; then
1335        have_threads="POSIX"
1336     else
1337        if test "x${_efl_have_win32_threads}" = "xyes" ; then
1338           have_threads="Win32"
1339        else
1340           have_threads="no"
1341        fi
1342     fi
1343    ],
1344    [have_threads="no"])
1345
1346 ### enable thread safety if we have threads, unless specifically asked not to
1347 if test "x${have_threads}" = "xno"
1348 then
1349   want_thread_safety="no"
1350 else
1351   want_thread_safety="no"  # to be changed to yes when ready
1352   AC_ARG_ENABLE(thread-safety,
1353     AC_HELP_STRING([--enable-thread-safety], [enable or disable thread safety]),
1354     [want_thread_safety=$enableval])
1355 fi
1356
1357 if test "x${want_thread_safety}" = "xyes"
1358 then
1359    AC_DEFINE([HAVE_THREAD_SAFETY], [1], [Define to enable thread safety])
1360 fi
1361
1362 ### Checks for types
1363 AC_CHECK_SIZEOF(int, 4)
1364 AC_CHECK_SIZEOF(long, 4)
1365
1366
1367 ### Checks for structures
1368
1369
1370 ### Checks for compiler characteristics
1371 AC_PROG_CC_STDC
1372 AC_C_CONST
1373 AC_C_BIGENDIAN
1374 AC_HEADER_STDC
1375 AC_C___ATTRIBUTE__
1376
1377 WIN32_CPPFLAGS=""
1378 WIN32_CFLAGS=""
1379 case "$host_os" in
1380    mingw32ce*)
1381       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
1382       ;;
1383    cegcc*)
1384       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
1385       WIN32_CFLAGS="-mwin32"
1386       ;;
1387    mingw*)
1388       WIN32_CPPFLAGS="-D_WIN32_WINNT=0x0501"
1389       ;;
1390 esac
1391 AC_SUBST(WIN32_CPPFLAGS)
1392 AC_SUBST(WIN32_CFLAGS)
1393
1394
1395 ### Checks for linker characteristics
1396
1397 # use --enable-auto-import on Windows
1398
1399 lt_enable_auto_import=""
1400 case "$host_os" in
1401    mingw* | cegcc*)
1402       lt_enable_auto_import="-Wl,--enable-auto-import"
1403       ;;
1404 esac
1405 AC_SUBST(lt_enable_auto_import)
1406
1407 ### Checks for library functions
1408 AC_ISC_POSIX
1409 AC_FUNC_ALLOCA
1410 AC_CHECK_FUNCS([gettimeofday strlcpy execvp])
1411
1412 AC_COMPILE_IFELSE(
1413    [AC_LANG_PROGRAM(
1414        [[
1415 #include <math.h>
1416        ]],
1417        [[
1418 int i = isfinite(0);
1419        ]])],
1420    [
1421     AC_DEFINE(HAVE_ISFINITE, 1, [Define to 1 if you have `isfinite', as a function or macro.])
1422     have_isfinite="yes"
1423    ],
1424    [have_isfinite="no"])
1425
1426 AC_MSG_CHECKING([for isfinite])
1427 AC_MSG_RESULT([${have_isfinite}])
1428
1429 have_atfile_source=auto
1430 AC_ARG_ENABLE([atfile-source],
1431    [AC_HELP_STRING([--disable-atfile-source],
1432        [disable use of atfile source functions as openat and mkdirat @<:@default=detect@:>@])],
1433    [
1434     if test "x${enableval}" = "xyes" ; then
1435        have_atfile_source="yes"
1436     else
1437        have_atfile_source="no"
1438     fi],
1439    [have_atfile_source=auto])
1440
1441 if ! test "x${have_atfile_source}" = "xno" ; then
1442    AC_CHECK_FUNCS(mkdirat,
1443       [
1444        have_atfile_source="yes"
1445        AC_DEFINE(HAVE_ATFILE_SOURCE, 1, [mkdirat exists])
1446       ],
1447       [
1448        if test "x${have_atfile_source}" = "xyes" ; then
1449           AC_MSG_ERROR([required atfile-source but no mkdirat()])
1450        fi
1451        have_atfile_source="no"
1452       ])
1453 fi
1454
1455 # shm_open
1456 EFL_CHECK_SHM_OPEN([have_shm_open="yes"], [have_shm_open="no"])
1457
1458 ### Checks for optionnal feature
1459 AC_CHECK_FUNC([mallinfo],
1460    [
1461     have_mallinfo="yes"
1462     AC_DEFINE(HAVE_MALLINFO, 1, [Gather memory statistic])
1463    ],
1464    [have_mallinfo="no"])
1465
1466 ### Ecore modules
1467
1468 ## Core modules
1469
1470 # ecore_con
1471 ECORE_CHECK_MODULE([con], [${want_ecore_con}], [Con], [${have_addrinfo}])
1472
1473 have_curl="no"
1474 have_gnutls="no"
1475 have_openssl="no"
1476 have_cares="no"
1477 want_ipv6="yes"
1478 have_ipv6="no"
1479
1480 AC_ARG_ENABLE([ipv6],
1481    [AC_HELP_STRING([--disable-ipv6],
1482        [disable ipv6 functionality @<:@default=detect@:>@])],
1483    [
1484     if test "x${enableval}" = "xyes" ; then
1485        want_ipv6="yes"
1486     else
1487        want_ipv6="no"
1488     fi],
1489    [want_ipv6="auto"])
1490
1491 if test "x${have_ecore_con}" = "xyes" ; then
1492
1493    # Verify IPV6 availability in headers
1494    if test "x${want_ipv6}" != "xno" ; then
1495       AC_CHECK_TYPES([struct ipv6_mreq],
1496          [have_ipv6="yes"],
1497          [have_ipv6="no"],
1498          [[
1499 #ifdef HAVE_NETINET_IN_H
1500 # include <netinet/in.h>
1501 #endif
1502 #ifdef HAVE_WS2TCPIP_H
1503 # include <ws2tcpip.h>
1504 #endif
1505          ]])
1506    fi
1507
1508    if test "x${have_ipv6}" = "xyes" ; then
1509       AC_DEFINE(HAVE_IPV6, 1, [Define if IPV6 is supported])
1510    fi
1511
1512    ECORE_CHECK_CURL([${want_curl}],
1513       [
1514        have_curl="yes"
1515        requirements_ecore_con="libcurl ${requirements_ecore_con}"
1516       ],
1517       [have_curl="no"])
1518
1519    ECORE_CHECK_GNUTLS([${want_gnutls}],
1520       [have_gnutls="yes"],
1521       [have_gnutls="no"])
1522
1523    ECORE_CHECK_OPENSSL([${want_openssl}],
1524       [have_openssl="yes"],
1525       [have_openssl="no"])
1526
1527    if test "x${have_gnutls}" = "xyes" ; then
1528       requirements_ecore_con="gnutls ${requirements_ecore_con}"
1529       # no need to add it to req_ecore_ipc, since they
1530       # depends on ecore_con anyway.
1531    else
1532       if test "x${have_openssl}" = "xyes" ; then
1533          requirements_ecore_con="openssl ${requirements_ecore_con}"
1534          # no need to add it to req_ecore_ipc, since they
1535          # depends on ecore_con anyway.
1536       fi
1537    fi
1538
1539    ECORE_CHECK_CARES([${want_cares}],
1540       [
1541        have_cares="yes"
1542        requirements_ecore_con="libcares ${requirements_ecore_con}"
1543       ],
1544       [have_cares="no"])
1545
1546 fi
1547
1548
1549 EFL_CHECK_COMPILER_FLAGS([ECORE_CON], [-Wno-override-init -Wno-initializer-overrides])
1550
1551 AM_CONDITIONAL([HAVE_IPV6], [test "x${have_ipv6}" = "xyes"])
1552 AM_CONDITIONAL([HAVE_CARES], [test "x${have_cares}" = "xyes"])
1553
1554 # ecore_ipc
1555 ECORE_CHECK_MODULE([ipc], [${want_ecore_ipc}], [Ipc], [${have_ecore_con}],
1556    [
1557      requirements_ecore_ipc="ecore-con >= 1.7.8 ${requirements_ecore_ipc}"
1558      requirements_ecore_evas="ecore-ipc >= 1.7.8 ${requirements_ecore_evas}"
1559    ])
1560
1561 # ecore_file
1562 ECORE_CHECK_MODULE([file], [${want_ecore_file}], [File])
1563
1564 have_poll="no"
1565 have_inotify="no"
1566 have_notify_win32="no"
1567 if test "x${have_ecore_file}" = "xyes" ; then
1568    ECORE_CHECK_POLL([${want_poll}], [have_poll="yes"], [have_poll="no"])
1569    ECORE_CHECK_INOTIFY([${want_inotify}], [have_inotify="yes"], [have_inotify="no"])
1570    ECORE_CHECK_NOTIFY_WIN32([${want_notify_win32}], [have_notify_win32="yes"], [have_notify_win32="no"])
1571
1572    if test "x${have_ecore_con}" = "xyes" ; then
1573       requirements_ecore_file="ecore-con >= 1.7.8 ${requirements_ecore_file}"
1574    else
1575       ECORE_CHECK_CURL([${want_curl}],
1576          [
1577           have_curl="yes"
1578           requirements_ecore_file="libcurl ${requirements_ecore_file}"
1579          ],
1580          [have_curl="no"])
1581    fi
1582
1583 fi
1584
1585 # ecore_config
1586 #ecore_config_deps="no"
1587 #if test "x${have_eet}" = "xyes" -a "x${have_evas}"  -a "x${have_ecore_ipc}" ; then
1588 #   ecore_config_deps="yes"
1589 #fi
1590
1591 #ECORE_CHECK_MODULE([config], [${want_ecore_config}], [Config], [${ecore_config_deps}],
1592 #   [requirements_ecore_config="ecore-ipc >= 1.7.8 evas >= 1.7.8 eet >= 1.7.8 ${requirements_ecore_config}"])
1593
1594 AM_CONDITIONAL(BUILD_ECORE_CONFIG, false)
1595
1596 # ecore_imf
1597
1598 ECORE_CHECK_MODULE([imf], [${want_ecore_imf}], [Imf])
1599
1600 # ecore_imf_evas
1601
1602 ecore_imf_evas_deps="no"
1603 if test "x${have_ecore_imf}" = "xyes" -a "x${have_evas}" = "xyes" ; then
1604    ecore_imf_evas_deps="yes"
1605 fi
1606
1607 ECORE_CHECK_MODULE([imf-evas], [${want_ecore_imf}], [Imf_Evas], [${ecore_imf_evas_deps}],
1608    [requirements_ecore_imf_evas="ecore-imf >= 1.7.8 evas >= 1.7.8 ${requirements_ecore_imf_evas}"])
1609
1610 # ecore_input{_evas}
1611 ECORE_CHECK_MODULE([input], [${want_ecore_input}], [Input])
1612 ECORE_CHECK_MODULE([input-evas], [${want_ecore_input}], [Input_Evas], [${have_evas}],
1613    [requirements_ecore_input_evas="ecore-input >= 1.7.8 evas >= 1.7.8 ${requirements_ecore_input}"])
1614
1615 # ecore_imf_xim
1616 AM_CONDITIONAL(BUILD_ECORE_IMF_XIM, false)
1617 ecore_imf_xim_deps="no"
1618 echo "have_ecore_x_xlib: ${have_ecore_x_xlib}"
1619 if test    "x${have_ecore_imf}" = "xyes" \
1620         -a "x${have_ecore_x_xlib}" = "xyes" \
1621         -a "x${have_ecore_input}" = "xyes" ; then
1622    ecore_imf_xim_deps="yes"
1623    AC_DEFINE(BUILD_ECORE_IMF_XIM, 1, [Ecore Imf XIM Support])
1624 fi
1625
1626 ECORE_CHECK_MODULE([imf-xim], [${want_ecore_imf}], [Imf_XIM], [${ecore_imf_xim_deps}],
1627    [requirements_ecore_imf_xim="ecore-imf >= 1.7.8 ecore-x >= 1.7.8 ecore-input >= 1.7.8 ${requirements_ecore_imf_xim}"])
1628
1629 # ecore_imf_scim
1630 PKG_CHECK_MODULES([SCIM], [scim], [have_scim="yes"], [have_scim="no"])
1631
1632 AM_CONDITIONAL(BUILD_ECORE_IMF_SCIM, false)
1633 ecore_imf_scim_deps="no"
1634 echo "have_ecore_x_xlib: ${have_ecore_x_xlib}"
1635 if test    "x${have_ecore_imf}" = "xyes" \
1636         -a "x${have_scim}" =  "xyes" \
1637         -a "x${have_ecore_input}" = "xyes" ; then
1638    ecore_imf_scim_deps="yes"
1639    AC_DEFINE(BUILD_ECORE_IMF_SCIM, 1, [Ecore Imf SCIM Support])
1640 fi
1641
1642 ECORE_CHECK_MODULE([imf-scim], [${want_ecore_imf}], [Imf_SCIM], [${ecore_imf_scim_deps}],
1643    [requirements_ecore_imf_scim="ecore-imf >= 1.7.8 ecore-x >= 1.7.8 ecore-input >= 1.7.8 ${requirements_ecore_imf_scim}"])
1644
1645 ## Graphic systems
1646
1647 # ecore_x{cb}
1648
1649 ecore_x_deps="no"
1650 if test "x${have_x}" = "xyes" -a \
1651         "x${have_ecore_input}" = "xyes" ; then
1652    ecore_x_deps="yes"
1653 fi
1654
1655 ECORE_CHECK_MODULE([x], [${want_ecore_x}], [X], [${ecore_x_deps}],
1656   [
1657    ecore_x_libs="$ecore_x_libs $x_libs"
1658    requirements_ecore_x="ecore-input >= 1.7.8 ${requirements_ecore_x}"
1659   ])
1660
1661 # ecore_win32
1662
1663 ECORE_CHECK_MODULE([win32], [${want_ecore_win32}], [Win32], [${have_ecore_input}],
1664    [
1665     ecore_win32_libs="-lole32 -lgdi32"
1666     requirements_ecore_win32="ecore-input >= 1.7.8 ${requirements_ecore_win32}"
1667    ])
1668 AC_SUBST(ecore_win32_libs)
1669
1670 # ecore_cocoa
1671
1672 ecore_cocoa_deps="no"
1673 if test "x${have_ecore_input}" = "xyes" -a "x${have_cocoa}" = "xyes" ; then
1674    ecore_cocoa_deps="yes"
1675 fi
1676
1677 ECORE_CHECK_MODULE([cocoa], [${want_ecore_cocoa}], [Cocoa], [${ecore_cocoa_deps}],
1678    [requirements_ecore_cocoa="ecore-input >= 1.7.8 ${requirements_ecore_cocoa}"])
1679
1680 # ecore_sdl
1681
1682 ecore_sdl_deps="no"
1683 if test "x${have_sdl}" = "xyes" -a "x${have_ecore_input}" = "xyes" ; then
1684    ecore_sdl_deps="yes"
1685 fi
1686
1687 ECORE_CHECK_MODULE([sdl], [${want_ecore_sdl}], [Sdl], [${ecore_sdl_deps}],
1688    [requirements_ecore_sdl="ecore-input >= 1.7.8 ${requirements_ecore_sdl}"])
1689
1690 ECORE_CHECK_MODULE([psl1ght], [${want_ecore_psl1ght}], [psl1ght], [${ecore_psl1ght_deps}],
1691    [requirements_ecore_psl1ght="ecore-input >= 1.7.8 ${requirements_ecore_psl1ght}"])
1692
1693 # ecore_fb
1694 ECORE_CHECK_MODULE([fb], [${want_ecore_fb}], [FB], [$have_fb])
1695
1696 if test "x${have_ecore_fb}" = "xyes" ; then
1697    ECORE_CHECK_TSLIB([${want_tslib}],
1698       [
1699        have_tslib="yes"
1700        requirements_ecore_fb="${_tslib_requirement} ${requirements_ecore_fb}"
1701       ],
1702       [have_tslib="no"])
1703 fi
1704
1705 # ecore_directfb
1706
1707 ECORE_CHECK_MODULE([directfb], [${want_ecore_directfb}], [DirectFB], [${have_directfb}],
1708    [requirements_ecore_directfb="directfb ${requirements_ecore_directfb}"])
1709
1710 # ecore_wince
1711
1712 ECORE_CHECK_MODULE([wince], [${want_ecore_wince}], [WinCE], [${have_ecore_input}],
1713    [requirements_ecore_wince="ecore-input >= 1.7.8 ${requirements_ecore_wince}"])
1714
1715 ## Ecore Evas
1716
1717 # ecore_evas
1718
1719 ecore_evas_deps="no"
1720 if test "x${have_evas}" = "xyes" && test "x${have_ecore_input}" = "xyes" && test "x${have_ecore_input_evas}" = "xyes" ; then
1721    ecore_evas_deps="yes"
1722 fi
1723
1724 ECORE_CHECK_MODULE([evas], [${want_ecore_evas}], [Evas], [${ecore_evas_deps}],
1725   [requirements_ecore_evas="ecore-input >= 1.7.8 ecore-input-evas >= 1.7.8 evas >= 1.7.8 ${requirements_ecore_evas}"])
1726
1727 # ecore_evas_buffer
1728
1729 ECORE_EVAS_CHECK_MODULE([software-buffer],
1730    [${want_ecore_evas_software_buffer}],
1731    [Software Buffer],
1732    [yes])
1733
1734 # ecore_evas_x11
1735
1736 # ecore_evas_software_x11
1737
1738 ECORE_EVAS_CHECK_MODULE([software-x11],
1739    [${want_ecore_evas_software_x11}],
1740    [Software X11],
1741    [${have_ecore_x}])
1742
1743 have_ecore_evas_software_xlib="no"
1744 have_ecore_evas_software_xcb="no"
1745 if test "x$have_ecore_evas_software_x11" = "xyes" ; then
1746    have_ecore_evas_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
1747    if test "x${have_ecore_evas_software_xlib}" = "xstatic"; then
1748       have_ecore_evas_software_xlib="yes"
1749    fi
1750    if test "x${have_ecore_evas_software_xlib}" = "xyes" -a "x${have_ecore_x_xlib}" = "xyes" ; then
1751       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
1752    fi
1753    have_ecore_evas_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
1754    if test "x$have_ecore_evas_software_xcb" = "xstatic"; then
1755       have_ecore_evas_software_xcb="yes"
1756    fi
1757    if test "x$have_ecore_evas_software_xcb" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1758       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
1759    fi
1760 fi
1761
1762 # ecore_evas_opengl_x11
1763
1764 ECORE_EVAS_CHECK_MODULE([opengl-x11],
1765    [${want_ecore_evas_opengl_x11}],
1766    [OpenGL Xlib],
1767    [${have_ecore_x}])
1768
1769 have_ecore_evas_opengl_xlib="no"
1770 have_ecore_evas_opengl_xcb="no"
1771 if test "x${have_ecore_evas_opengl_x11}" = "xyes" -o "x${have_ecore_evas_opengl_x11}" = "xstatic" ; then
1772    have_ecore_evas_opengl_xlib=`${PKG_CONFIG} --variable=Xlib evas-opengl-x11`
1773    if test "x${have_ecore_evas_opengl_xlib}" = "xyes" ; then
1774       AC_DEFINE(BUILD_ECORE_EVAS_OPENGL_XLIB, 1, [OpenGL Xlib rendering backend])
1775    fi
1776
1777 # opengl does not work with xcb (yet)
1778    have_ecore_evas_opengl_xcb=`${PKG_CONFIG} --variable=XCB evas-opengl-x11`
1779    if test "x${have_ecore_evas_opengl_xcb}" = "xstatic"; then
1780       have_ecore_evas_opengl_xcb="yes"
1781    fi
1782    if test "x${have_ecore_evas_opengl_xcb}" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1783       PKG_CHECK_MODULES(XCB_X11, x11-xcb,
1784         [ have_ecore_x_opengl_xcb="yes"
1785           requirements_ecore_x="x11-xcb ${requirements_ecore_x}"
1786           AC_DEFINE(BUILD_ECORE_X_OPENGL_XCB, 1, [Build support for XCB-based OpenGL])
1787           AC_DEFINE(BUILD_ECORE_EVAS_OPENGL_XCB, 1, [OpenGL XCB rendering backend])
1788         ],
1789         [ have_ecore_x_opengl_xcb="no" ])
1790     else
1791       have_ecore_x_opengl_xcb="no"
1792       AC_MSG_NOTICE("XCB-based OpenGL explicitly disabled")
1793     fi
1794 fi
1795
1796 # ecore_evas_software_x11 16 bits
1797
1798 ECORE_EVAS_CHECK_MODULE([software-16-x11],
1799    [${want_ecore_evas_software_16_x11}],
1800    [Software Xlib 16 bits],
1801    [${have_ecore_x_xlib}])
1802
1803 ECORE_EVAS_CHECK_MODULE([software-8-x11],
1804     [$want_ecore_evas_software_8_x11],
1805     [Software 8bit X11],
1806     $have_ecore_x_xcb)
1807
1808
1809 if test "x$have_ecore_evas_software_x11" = "xyes" -o \
1810         "x$have_ecore_evas_opengl_x11" = "xyes" -o \
1811         "x$have_ecore_evas_software_8_x11" = "xyes" -o \
1812         "x$have_ecore_evas_software_16_x11" = "xyes" -o \
1813         "x$have_ecore_evas_software_xcb" = "xyes"; then
1814    AC_DEFINE(BUILD_ECORE_EVAS_X11, 1, [Support for X Window Engines in Ecore_Evas])
1815    requirements_ecore_evas="ecore-x >= 1.7.8 ${requirements_ecore_evas}"
1816 fi
1817
1818 # ecore_evas_win32
1819
1820 ECORE_EVAS_CHECK_MODULE([software-gdi],
1821    [${want_ecore_evas_software_gdi}],
1822    [Software GDI],
1823    [${have_ecore_win32}])
1824
1825 ECORE_EVAS_CHECK_MODULE([software-ddraw],
1826    [${want_ecore_evas_software_ddraw}],
1827    [Software DirectDraw],
1828    [${have_ecore_win32}])
1829
1830 ECORE_EVAS_CHECK_MODULE([direct3d],
1831    [${want_ecore_evas_direct3d}],
1832    [Direct3d],
1833    [${have_ecore_win32}])
1834
1835 ECORE_EVAS_CHECK_MODULE([opengl-glew],
1836    [${want_ecore_evas_opengl_glew}],
1837    [Glew OpenGL],
1838    [${have_ecore_win32}])
1839
1840 ECORE_EVAS_CHECK_MODULE([software-16-ddraw],
1841    [${want_ecore_evas_software_16_ddraw}],
1842    [16 bpp Software DirectDraw],
1843    [${have_ecore_win32}])
1844
1845 if test "x${have_ecore_evas_software_gdi}" = "xyes" -o \
1846         "x${have_ecore_evas_software_ddraw}" = "xyes" -o \
1847         "x${have_ecore_evas_direct3d}" = "xyes" -o \
1848         "x${have_ecore_evas_opengl_glew}" = "xyes" -o \
1849         "x${have_ecore_evas_software_16_ddraw}" = "xyes" ; then
1850    AC_DEFINE(BUILD_ECORE_EVAS_WIN32, 1, [Support for Win32 Engine in Ecore_Evas])
1851    requirements_ecore_evas="ecore-win32 >= 1.7.8 ${requirements_ecore_evas}"
1852 fi
1853
1854 # ecore_evas_software_sdl
1855
1856 have_ecore_evas_software_sdl="no"
1857 if test "x${have_ecore_sdl}" = "xyes"; then
1858    requirements_ecore_evas="ecore-sdl >= 1.7.8 ${requirements_ecore_evas}"
1859    have_ecore_evas_software_sdl="yes"
1860    AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_SDL, 1, [Support for Software SDL Engine in Ecore_Evas])
1861    requirements_ecore_evas="ecore-sdl >= 1.7.8 ${requirements_ecore_evas}"
1862 fi
1863
1864 # ecore_evas_gl_sdl
1865
1866 ECORE_EVAS_CHECK_MODULE([opengl-sdl],
1867    [${want_ecore_evas_gl_sdl}],
1868    [OpenGL SDL],
1869    [${have_ecore_sdl}],
1870    [requirements_ecore_evas="ecore-sdl >= 1.7.8 ${requirements_ecore_evas}"])
1871
1872 # ecore_evas_cocoa
1873
1874 ECORE_EVAS_CHECK_MODULE([opengl-cocoa],
1875    [${want_ecore_evas_gl_cocoa}],
1876    [OpenGL Cocoa],
1877    [${have_ecore_cocoa}],
1878    [requirements_ecore_evas="ecore-cocoa >= 1.7.8 ${requirements_ecore_evas}"])
1879
1880 # ecore_evas_directfb
1881
1882 ECORE_EVAS_CHECK_MODULE([directfb],
1883    [${want_ecore_evas_directfb}],
1884    [DirectFB],
1885    [${have_ecore_directfb}],
1886    [requirements_ecore_evas="ecore-directfb >= 1.7.8 ${requirements_ecore_evas}"])
1887
1888 # ecore_evas_fb
1889
1890 ECORE_EVAS_CHECK_MODULE([fb],
1891    [${want_ecore_evas_fb}],
1892    [Linux Framebuffer],
1893    [${have_ecore_fb}],
1894    [requirements_ecore_evas="ecore-fb >= 1.7.8 ${requirements_ecore_evas}"])
1895
1896 # ecore_evas_wince
1897
1898 ECORE_EVAS_CHECK_MODULE([software-16-wince],
1899    [${want_ecore_evas_software_16_wince}],
1900    [16 bpp Software Windows CE],
1901    [${have_ecore_wince}],
1902    [requirements_ecore_evas="ecore-wince >= 1.7.8 ${requirements_ecore_evas}"])
1903
1904 # ecore_evas_ews
1905
1906 ECORE_EVAS_CHECK_MODULE_FULL([ews], [software-buffer],
1907    [${want_ecore_evas_ews}],
1908    [Ecore Evas Single Process Windowing System],
1909    [yes], [])
1910
1911 # ecore_evas_extn
1912
1913 have_extn="yes"
1914 if test "x${have_ecore_ipc}" = "xno" || \
1915    test "x${have_ecore_evas_software_buffer}" = "xno" || \
1916    test "x${have_shm_open}" = "xno" ; then
1917    have_extn="no"
1918 fi
1919
1920 dnl THIS IS SPECIAL - dont use normal ECORE_EVAS_CHECK_MODULE
1921 have_ecore_evas_extn="no"
1922 if test "x${want_ecore_evas_extn}" = "xyes" && \
1923    test "x${have_extn}" = "xyes" && \
1924    test "x${have_ecore_evas}" = "xyes"; then
1925    AC_DEFINE([BUILD_ECORE_EVAS_EXTN], [1], [Support for Extn Engine in Ecore_Evas])
1926    have_ecore_evas_extn="yes"
1927 fi
1928
1929 # ecore_evas_psl1ght
1930
1931 ECORE_EVAS_CHECK_MODULE([psl1ght],
1932    [${want_ecore_evas_psl1ght}],
1933    [PSL1GHT],
1934    [${have_ecore_psl1ght}],
1935    [requirements_ecore_evas="ecore-psl1ght >= 1.7.8 ${requirements_ecore_evas}"])
1936
1937 # ecore_imf_ibus
1938 PKG_CHECK_MODULES([IBUS], [ibus-1.0 >= 1.4], [have_ibus="yes"], [have_ibus="no"])
1939
1940 AM_CONDITIONAL(BUILD_ECORE_IMF_IBUS, false)
1941 ecore_imf_ibus_deps="no"
1942 echo "have_ecore_x_xlib: ${have_ecore_x_xlib}"
1943 if test    "x${have_ecore_imf}" = "xyes" \
1944         -a "x${have_ecore_evas}" = "xyes" \
1945         -a "x${have_glib}" =  "xyes" \
1946         -a "x${have_ibus}" =  "xyes" \
1947         -a "x${have_ecore_input}" = "xyes" ; then
1948    ecore_imf_ibus_deps="yes"
1949    AC_DEFINE(BUILD_ECORE_IMF_IBUS, 1, [Ecore Imf IBUS Support])
1950 fi
1951
1952 ECORE_CHECK_MODULE([imf-ibus], [${want_ecore_imf}], [Imf_IBUS], [${ecore_imf_ibus_deps}],
1953    [requirements_ecore_imf_ibus="ecore-imf >= 1.7.8 ecore-x >= 1.7.8 ecore-input >= 1.7.8 ${requirements_ecore_imf_ibus}"])
1954
1955 ### WAYLAND
1956
1957 ecore_wayland_deps="no"
1958 have_wayland="no"
1959 if test "x${want_ecore_wayland}" = "xyes" ; then
1960   PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-cursor xkbcommon], [have_wayland="yes"], [have_wayland="no"])
1961 fi
1962 if test "x${have_ecore_input}" = "xyes" -a "x${have_wayland}" = "xyes" ; then
1963   ecore_wayland_deps="yes"
1964 fi
1965
1966 ECORE_CHECK_MODULE([wayland], [${want_ecore_wayland}], [Wayland], [${ecore_wayland_deps}])
1967 if test "x${have_ecore_wayland}" = "xyes" ; then
1968   requirements_ecore_wayland="ecore-input >= 1.7.8 wayland-client wayland-cursor xkbcommon ${requirements_ecore_wayland}"
1969 fi
1970
1971 ECORE_EVAS_CHECK_MODULE_FULL([wayland-shm], [wayland-shm],
1972    [${want_ecore_evas_wayland_shm}],
1973    [Wayland Shm],
1974    [${have_ecore_wayland}],
1975    [requirements_ecore_evas="${requirements_ecore_wayland} ${requirements_ecore_evas}"])
1976
1977 ECORE_EVAS_CHECK_MODULE_FULL([wayland-egl], [wayland-egl egl >= 7.10],
1978    [${want_ecore_evas_wayland_egl}],
1979    [Wayland Egl],
1980    [${have_ecore_wayland}],
1981    [
1982       PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [have_wayland_egl="yes"], [have_wayland_egl="no"])
1983       if test "x${have_wayland_egl}" = "xyes" ; then
1984          requirements_ecore_evas="wayland-egl egl >= 7.10 ${requirements_ecore_wayland} ${requirements_ecore_evas}"
1985       fi
1986    ])
1987
1988 ### Unit tests and coverage
1989
1990 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
1991
1992 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
1993 CFLAGS="${CFLAGS} ${EFL_COVERAGE_CFLAGS}"
1994 ECORE_LIBS="${ECORE_LIBS} ${EFL_COVERAGE_LIBS}"
1995 if test "x$enable_coverage" = "xyes" ; then
1996    CFLAGS="${CFLAGS} ${EFL_DEBUG_CFLAGS}"
1997 fi
1998
1999 ### install and build examples
2000
2001 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
2002 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
2003
2004 ### requirements
2005
2006 AC_SUBST(requirements_ecore)
2007 AC_SUBST(requirements_ecore_con)
2008 #AC_SUBST(requirements_ecore_config)
2009 AC_SUBST(requirements_ecore_directfb)
2010 AC_SUBST(requirements_ecore_evas)
2011 AC_SUBST(requirements_ecore_fb)
2012 AC_SUBST(requirements_ecore_file)
2013 AC_SUBST(requirements_ecore_imf)
2014 AC_SUBST(requirements_ecore_imf_evas)
2015 AC_SUBST(requirements_ecore_input)
2016 AC_SUBST(requirements_ecore_input_evas)
2017 AC_SUBST(requirements_ecore_ipc)
2018 AC_SUBST(requirements_ecore_cocoa)
2019 AC_SUBST(requirements_ecore_sdl)
2020 AC_SUBST(requirements_ecore_psl1ght)
2021 AC_SUBST(requirements_ecore_x)
2022 AC_SUBST(requirements_ecore_win32)
2023 AC_SUBST(requirements_ecore_wince)
2024 AC_SUBST(requirements_ecore_imf_xim)
2025 AC_SUBST(requirements_ecore_imf_scim)
2026 AC_SUBST(requirements_ecore_imf_ibus)
2027 AC_SUBST(requirements_ecore_wayland)
2028
2029 AC_CONFIG_FILES([
2030 Makefile
2031 ecore-con.pc
2032 ecore-config.pc
2033 ecore-directfb.pc
2034 ecore-evas.pc
2035 ecore-fb.pc
2036 ecore-file.pc
2037 ecore-imf.pc
2038 ecore-imf-evas.pc
2039 ecore-ipc.pc
2040 ecore-x.pc
2041 ecore-input.pc
2042 ecore-input-evas.pc
2043 ecore-win32.pc
2044 ecore-sdl.pc
2045 ecore-cocoa.pc
2046 ecore-psl1ght.pc
2047 ecore-wince.pc
2048 ecore-wayland.pc
2049 ecore.pc
2050 doc/ecore.dox
2051 doc/Makefile
2052 doc/Doxyfile
2053 src/Makefile
2054 src/util/Makefile
2055 src/bin/Makefile
2056 src/lib/Makefile
2057 src/lib/ecore/Makefile
2058 src/lib/ecore_con/Makefile
2059 src/lib/ecore_config/Makefile
2060 src/lib/ecore_directfb/Makefile
2061 src/lib/ecore_evas/Makefile
2062 src/lib/ecore_fb/Makefile
2063 src/lib/ecore_file/Makefile
2064 src/lib/ecore_cocoa/Makefile
2065 src/lib/ecore_sdl/Makefile
2066 src/lib/ecore_psl1ght/Makefile
2067 src/lib/ecore_imf/Makefile
2068 src/lib/ecore_imf_evas/Makefile
2069 src/lib/ecore_input/Makefile
2070 src/lib/ecore_input_evas/Makefile
2071 src/lib/ecore_ipc/Makefile
2072 src/lib/ecore_win32/Makefile
2073 src/lib/ecore_wince/Makefile
2074 src/lib/ecore_x/Makefile
2075 src/lib/ecore_x/xlib/Makefile
2076 src/lib/ecore_x/xcb/Makefile
2077 src/lib/ecore_wayland/Makefile
2078 src/examples/Makefile
2079 src/tests/Makefile
2080 src/modules/Makefile
2081 src/modules/immodules/Makefile
2082 src/modules/immodules/xim/Makefile
2083 src/modules/immodules/scim/Makefile
2084 src/modules/immodules/ibus/Makefile
2085 ecore.spec
2086 $po_makefile_in
2087 ])
2088
2089 AC_OUTPUT
2090
2091 echo
2092 echo "$PACKAGE $VERSION"
2093 echo
2094 echo "Optional Modules:"
2095 echo
2096 echo " Core:"
2097 echo
2098 echo "  Ecore........................: always"
2099 echo "    Thread support.............: $have_threads"
2100 echo "    Thread safety..............: $want_thread_safety"
2101 echo "    GLib support...............: $have_glib"
2102 echo "    Always integrate GLib......: $want_glib_integration_always"
2103 echo "    Use g_main_loop............: $want_g_main_loop"
2104 echo "    Gathering memory statistic.: $have_mallinfo"
2105 echo "    Gathering timer allocation.: $want_ecore_timer_dump"
2106 echo "  Ecore_Con....................: $have_ecore_con"
2107 if test "x$have_ecore_con" = "xyes" ; then
2108   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
2109 if test "x$have_gnutls" = "xyes" ; then
2110   echo " (disabled)"
2111 else
2112   echo
2113 fi
2114   echo "    IPv6.......................: $have_ipv6"
2115   echo "    GnuTLS.....................: $have_gnutls"
2116   echo "    CURL.......................: $have_curl"
2117   echo "    Local Sockets..............: $want_ecore_con_local_sockets"
2118 if test "x$want_ecore_con_local_sockets" = "xyes" ; then
2119   echo "      Abstract Sockets.........: $want_ecore_con_abstract_sockets"
2120 fi
2121 if test "x$have_cares" = "xyes" ; then
2122   echo "    Resolver...................: c-ares"
2123 elif test "x$have_ipv6" = "xyes" ; then
2124   echo "    Resolver...................: dns.c"
2125 else
2126   echo "    Resolver...................: fork"
2127 fi
2128 fi
2129 echo "  Ecore_Ipc....................: $have_ecore_ipc"
2130 if test "x$have_ecore_ipc" = "xyes" ; then
2131   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
2132 if test "x$have_gnutls" = "xyes" ; then
2133   echo " (disabled)"
2134 else
2135   echo
2136 fi
2137   echo "    GnuTLS.....................: $have_gnutls"
2138 fi
2139 echo "  Ecore_File...................: $have_ecore_file"
2140 if test "x$have_ecore_file" = "xyes" ; then
2141   echo "    Inotify....................: $have_inotify"
2142   echo "    Windows notification.......: $have_notify_win32"
2143   echo "    Poll.......................: $have_poll"
2144   echo "    CURL.......................: $have_curl"
2145 fi
2146 #echo "  Ecore_Config.................: $have_ecore_config (deprecated)"
2147 echo "  Ecore_IMF....................: $have_ecore_imf"
2148 echo "    XIM........................: $have_ecore_imf_xim"
2149 echo "    SCIM.......................: $have_ecore_imf_scim"
2150 echo "    IBUS.......................: $have_ecore_imf_ibus"
2151 echo "  Ecore_IMF_Evas...............: $have_ecore_imf_evas"
2152 echo "  Ecore_Input..................: $have_ecore_input"
2153 echo "  Ecore_Input_Evas.............: $have_ecore_input_evas"
2154
2155 echo
2156 echo " Graphic systems:"
2157 echo
2158
2159 if test "x$have_ecore_x" = "xyes" ; then
2160   if test "x$have_ecore_x_xcb" = "xyes" ; then
2161     echo "  Ecore_X (XCB backend)........: $have_ecore_x_xcb"
2162     echo "    Xprint.....................: $have_ecore_x_xcb_xprint"
2163     echo "    Xinerama...................: $have_ecore_x_xcb_xinerama"
2164     echo "    Xrandr.....................: $have_ecore_x_xcb_randr"
2165     echo "    Xscreensaver...............: $have_ecore_x_xcb_screensaver"
2166     echo "    Xshape.....................: $have_ecore_x_xcb_shape"
2167     echo "    Xgesture...................: $have_ecore_x_xcb_gesture"
2168     echo "    Xsync......................: $have_ecore_x_xcb_sync"
2169     echo "    Xrender....................: $have_ecore_x_xcb_render"
2170     echo "    Xcomposite.................: $have_ecore_x_xcb_composite"
2171     echo "    Xfixes.....................: $have_ecore_x_xcb_xfixes"
2172     echo "    Xdamage....................: $have_ecore_x_xcb_damage"
2173     echo "    Xdpms......................: $have_ecore_x_xcb_dpms"
2174     echo "    Xtest......................: $have_ecore_x_xcb_xtest"
2175   else
2176     echo "  Ecore_X (Xlib backend).......: $have_ecore_x"
2177     echo "    Xcursor....................: $use_Xcursor"
2178     echo "    Xkb........................: $use_xkb"
2179     echo "    Xprint.....................: $use_xprint"
2180     echo "    Xinerama...................: $use_xinerama"
2181     echo "    Xrandr.....................: $use_xrandr"
2182     echo "    Xgesture...................: $use_xgesture"
2183     echo "    Xscreensaver...............: $use_xss"
2184     echo "    Xrender....................: $use_xrender"
2185     echo "    Xcomposite.................: $use_xcomposite"
2186     echo "    Xfixes.....................: $use_xfixes"
2187     echo "    Xdamage....................: $use_xdamage"
2188     echo "    Xdpms......................: $use_xdpms"
2189     echo "    Xtest......................: $use_xtest"
2190     echo "    XIM........................: $want_xim"
2191     echo "    Xi2........................: $use_xi2"
2192   fi
2193 else
2194   echo "  Ecore_X......................: $have_ecore_x"
2195 fi
2196 echo "  Ecore_Win32..................: $have_ecore_win32"
2197 echo "  Ecore_Cocoa..................: $have_ecore_cocoa"
2198 echo "  Ecore_SDL....................: $have_ecore_sdl"
2199 echo "  Ecore_FB.....................: $have_ecore_fb"
2200 if test "x${have_ecore_fb}" = "xyes" ; then
2201   echo "    Touchscreen................: $have_tslib"
2202 fi
2203 echo "  Ecore_DirectFB...............: $have_ecore_directfb"
2204 echo "  Ecore_WinCE..................: $have_ecore_wince"
2205 echo "  Ecore_PSL1GHT................: $have_ecore_psl1ght"
2206 echo "  Ecore_Wayland................: $have_ecore_wayland"
2207
2208 echo
2209 echo " Ecore Evas:"
2210 echo
2211
2212 echo "  Ecore_Evas...................: $have_ecore_evas"
2213 if test "x${have_ecore_evas}" = "xyes" ; then
2214   echo "    Software Memory Buffer.....: $have_ecore_evas_software_buffer"
2215   if test "x${have_ecore_evas_software_x11}" = "xyes" ; then
2216     echo "    Software X11...............: $have_ecore_evas_software_x11 (Xlib=${have_ecore_evas_software_xlib}) (XCB=${have_ecore_evas_software_xcb})"
2217   else
2218     echo "    Software X11...............: $have_ecore_evas_software_x11"
2219   fi
2220   if test "x${have_ecore_evas_opengl_x11}" = "xyes" ; then
2221     echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11 (Xlib=${have_ecore_evas_opengl_xlib}) (XCB=${have_ecore_evas_opengl_xcb})"
2222   else
2223     echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11"
2224   fi
2225   echo "    Software GDI...............: $have_ecore_evas_software_gdi"
2226   echo "    Software DirectDraw........: $have_ecore_evas_software_ddraw"
2227   echo "    Direct3D...................: $have_ecore_evas_direct3d"
2228   echo "    OpenGL Glew................: $have_ecore_evas_opengl_glew"
2229   echo "    Software SDL...............: $have_ecore_evas_software_sdl"
2230   echo "    OpenGL SDL.................: $have_ecore_evas_opengl_sdl"
2231   echo "    OpenGL Cocoa...............: $have_ecore_evas_opengl_cocoa"
2232   echo "    DirectFB...................: $have_ecore_evas_directfb"
2233   echo "    PSL1GHT....................: $have_ecore_evas_psl1ght"
2234   echo "    Software Framebuffer.......: $have_ecore_evas_fb"
2235   echo "    Software 8bit grayscale XCB: $have_ecore_evas_software_8_x11"
2236   echo "    Software 16bit X11.........: $have_ecore_evas_software_16_x11"
2237   echo "    Software 16bit DirectDraw..: $have_ecore_evas_software_16_ddraw"
2238   echo "    Software 16bit WinCE.......: $have_ecore_evas_software_16_wince"
2239   echo "    Sing.Proc. Windowing System: $have_ecore_evas_ews"
2240   echo "    Wayland Shm................: $have_ecore_evas_wayland_shm"
2241   echo "    Wayland Egl................: $have_ecore_evas_wayland_egl"
2242   echo "    Extn (Plug/socket Extn)....: $have_ecore_evas_extn"
2243 fi
2244 echo
2245 echo "  Tests................: ${enable_tests}"
2246 echo "  Coverage.............: ${enable_coverage}"
2247 echo "  Maximum log level....: ${with_max_log_level}"
2248 echo "Documentation..........: ${build_doc}"
2249 echo "Examples...............: ${enable_build_examples}"
2250 echo "Examples installed.....: ${enable_install_examples}"
2251 echo
2252 echo "Compilation............: make (or gmake)"
2253 echo "  CPPFLAGS.............: $CPPFLAGS"
2254 echo "  CFLAGS...............: $CFLAGS"
2255 echo "  CXXFLAGS.............: $CXXFLAGS"
2256 echo "  LDFLAGS..............: $LDFLAGS"
2257 echo
2258 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
2259 echo "  prefix...............: $prefix"
2260 echo