configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.68)
   4
   5 AC_INIT([libffi], [3.3], [http://github.com/libffi/libffi/issues])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AC_CANONICAL_SYSTEM
   9 target_alias=${target_alias-$host_alias}
  10
  11 case "${host}" in
  12   frv*-elf)
  13     LDFLAGS=`echo $LDFLAGS | sed "s/\-B[^ ]*libgloss\/frv\///"`\ -B`pwd`/../libgloss/frv/
  14     ;;
  15 esac
  16
  17 AX_ENABLE_BUILDDIR
  18
  19 AM_INIT_AUTOMAKE
  20
  21 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  22 # We must force CC to /not/ be precious variables; otherwise
  23 # the wrong, non-multilib-adjusted value will be used in multilibs.
  24 # As a side effect, we have to subst CFLAGS ourselves.
  25 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
  26 # defaults of its own if none are provided.
  27
  28 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  29 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  30 save_CFLAGS=$CFLAGS
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 CFLAGS=$save_CFLAGS
  34 m4_undefine([_AC_ARG_VAR_PRECIOUS])
  35 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  36
  37 AC_SUBST(CFLAGS)
  38
  39 AM_PROG_AS
  40 AM_PROG_CC_C_O
  41 AC_PROG_LIBTOOL
  42 AC_CONFIG_MACRO_DIR([m4])
  43
  44 # Test for 64-bit build.
  45 AC_CHECK_SIZEOF([size_t])
  46
  47 AX_COMPILER_VENDOR
  48 AX_CC_MAXOPT
  49 # The AX_CFLAGS_WARN_ALL macro doesn't currently work for sunpro
  50 # compiler.
  51 if test "$ax_cv_c_compiler_vendor" != "sun"; then
  52   AX_CFLAGS_WARN_ALL
  53 fi
  54
  55 if test "x$GCC" = "xyes"; then
  56   CFLAGS="$CFLAGS -fexceptions"
  57 fi
  58
  59 cat > local.exp <<EOF
  60 set CC_FOR_TARGET "$CC"
  61 set CXX_FOR_TARGET "$CXX"
  62 EOF
  63
  64 AM_MAINTAINER_MODE
  65
  66 AC_CHECK_HEADERS(sys/mman.h)
  67 AC_CHECK_FUNCS([mmap mkostemp])
  68 AC_FUNC_MMAP_BLACKLIST
  69
  70 dnl The -no-testsuite modules omit the test subdir.
  71 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  72
  73 TARGETDIR="unknown"
  74 HAVE_LONG_DOUBLE_VARIANT=0
  75
  76 . ${srcdir}/configure.host
  77
  78 if test -n "${UNSUPPORTED}"; then
  79   AC_MSG_ERROR(["libffi has not been ported to $host."])
  80 fi
  81
  82 AC_SUBST(AM_RUNTESTFLAGS)
  83 AC_SUBST(AM_LTLDFLAGS)
  84
  85 AC_HEADER_STDC
  86 AC_CHECK_FUNCS(memcpy)
  87 AC_FUNC_ALLOCA
  88
  89 AC_CHECK_SIZEOF(double)
  90 AC_CHECK_SIZEOF(long double)
  91
  92 # Also AC_SUBST this variable for ffi.h.
  93 if test -z "$HAVE_LONG_DOUBLE"; then
  94   HAVE_LONG_DOUBLE=0
  95   if test $ac_cv_sizeof_long_double != 0; then
  96     if test $HAVE_LONG_DOUBLE_VARIANT != 0; then
  97       AC_DEFINE(HAVE_LONG_DOUBLE_VARIANT, 1, [Define if you support more than one size of the long double type])
  98       HAVE_LONG_DOUBLE=1
  99     else
 100       if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 101         HAVE_LONG_DOUBLE=1
 102         AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 103       fi
 104     fi
 105   fi
 106 fi
 107 AC_SUBST(HAVE_LONG_DOUBLE)
 108 AC_SUBST(HAVE_LONG_DOUBLE_VARIANT)
 109
 110 AC_C_BIGENDIAN
 111
 112 GCC_AS_CFI_PSEUDO_OP
 113
 114 case "$TARGET" in
 115   SPARC)
 116     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 117         libffi_cv_as_sparc_ua_pcrel, [
 118         save_CFLAGS="$CFLAGS"
 119         save_LDFLAGS="$LDFLAGS"
 120         CFLAGS="$CFLAGS -fpic"
 121         LDFLAGS="$LDFLAGS -shared"
 122         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 123                     [libffi_cv_as_sparc_ua_pcrel=yes],
 124                     [libffi_cv_as_sparc_ua_pcrel=no])
 125         CFLAGS="$save_CFLAGS"
 126         LDFLAGS="$save_LDFLAGS"])
 127     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 128         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 129                   [Define if your assembler and linker support unaligned PC relative relocs.])
 130     fi
 131
 132     AC_CACHE_CHECK([assembler .register pseudo-op support],
 133        libffi_cv_as_register_pseudo_op, [
 134        libffi_cv_as_register_pseudo_op=unknown
 135        # Check if we have .register
 136        AC_TRY_COMPILE(,[asm (".register %g2, #scratch");],
 137                        [libffi_cv_as_register_pseudo_op=yes],
 138                        [libffi_cv_as_register_pseudo_op=no])
 139     ])
 140     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 141        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 142                [Define if your assembler supports .register.])
 143     fi
 144     ;;
 145
 146   X86*)
 147     AC_CACHE_CHECK([assembler supports pc related relocs],
 148         libffi_cv_as_x86_pcrel, [
 149         libffi_cv_as_x86_pcrel=no
 150         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 151         if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 152             libffi_cv_as_x86_pcrel=yes
 153         fi
 154         ])
 155     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 156         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 157                   [Define if your assembler supports PC relative relocs.])
 158     fi
 159     ;;
 160
 161   S390)
 162     AC_CACHE_CHECK([compiler uses zarch features],
 163         libffi_cv_as_s390_zarch, [
 164         libffi_cv_as_s390_zarch=no
 165         echo 'void foo(void) { bar(); bar(); }' > conftest.c
 166         if $CC $CFLAGS -S conftest.c > /dev/null 2>&1; then
 167             if grep -q brasl conftest.s; then
 168                 libffi_cv_as_s390_zarch=yes
 169             fi
 170         fi
 171         ])
 172     if test "x$libffi_cv_as_s390_zarch" = xyes; then
 173         AC_DEFINE(HAVE_AS_S390_ZARCH, 1,
 174                   [Define if the compiler uses zarch features.])
 175     fi
 176     ;;
 177 esac
 178
 179 AC_CACHE_CHECK([whether compiler supports pointer authentication],
 180    libffi_cv_as_ptrauth, [
 181    libffi_cv_as_ptrauth=unknown
 182    AC_TRY_COMPILE(,[
 183 #ifdef __clang__
 184 # if __has_feature(ptrauth_calls)
 185 #  define HAVE_PTRAUTH 1
 186 # endif
 187 #endif
 188
 189 #ifndef HAVE_PTRAUTH
 190 # error Pointer authentication not supported
 191 #endif
 192                    ],
 193                    [libffi_cv_as_ptrauth=yes],
 194                    [libffi_cv_as_ptrauth=no])
 195 ])
 196 if test "x$libffi_cv_as_ptrauth" = xyes; then
 197     AC_DEFINE(HAVE_PTRAUTH, 1,
 198               [Define if your compiler supports pointer authentication.])
 199 fi
 200
 201 # On PaX enable kernels that have MPROTECT enable we can't use PROT_EXEC.
 202 AC_ARG_ENABLE(pax_emutramp,
 203   [  --enable-pax_emutramp       enable pax emulated trampolines, for we can't use PROT_EXEC],
 204   if test "$enable_pax_emutramp" = "yes"; then
 205     AC_DEFINE(FFI_MMAP_EXEC_EMUTRAMP_PAX, 1,
 206       [Define this if you want to enable pax emulated trampolines])
 207   fi)
 208
 209 LT_SYS_SYMBOL_USCORE
 210 if test "x$sys_symbol_underscore" = xyes; then
 211     AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
 212 fi
 213
 214 FFI_EXEC_TRAMPOLINE_TABLE=0
 215 case "$target" in
 216      *arm*-apple-* | aarch64-apple-*)
 217        FFI_EXEC_TRAMPOLINE_TABLE=1
 218        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
 219                  [Cannot use PROT_EXEC on this target, so, we revert to
 220                    alternative means])
 221      ;;
 222      *-apple-* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris* | *-linux-android*)
 223        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
 224                  [Cannot use malloc on this target, so, we revert to
 225                    alternative means])
 226      ;;
 227 esac
 228 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
 229 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
 230
 231 if test x$TARGET = xX86_64; then
 232     AC_CACHE_CHECK([toolchain supports unwind section type],
 233         libffi_cv_as_x86_64_unwind_section_type, [
 234         cat  > conftest1.s << EOF
 235 .text
 236 .globl foo
 237 foo:
 238 jmp bar
 239 .section .eh_frame,"a",@unwind
 240 bar:
 241 EOF
 242
 243         cat > conftest2.c  << EOF
 244 extern void foo();
 245 int main(){foo();}
 246 EOF
 247
 248         libffi_cv_as_x86_64_unwind_section_type=no
 249         # we ensure that we can compile _and_ link an assembly file containing an @unwind section
 250         # since the compiler can support it and not the linker (ie old binutils)
 251         if $CC -Wa,--fatal-warnings $CFLAGS -c conftest1.s > /dev/null 2>&1 && \
 252            $CC conftest2.c conftest1.o > /dev/null 2>&1 ; then
 253             libffi_cv_as_x86_64_unwind_section_type=yes
 254         fi
 255         ])
 256     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
 257         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 258                   [Define if your assembler supports unwind section type.])
 259     fi
 260 fi
 261
 262 if test "x$GCC" = "xyes"; then
 263   AX_CHECK_COMPILE_FLAG(-fno-lto, libffi_cv_no_lto=-fno-lto)
 264
 265   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 266       libffi_cv_ro_eh_frame, [
 267         libffi_cv_ro_eh_frame=yes
 268         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 269         if $CC $CFLAGS -c -fpic -fexceptions $libffi_cv_no_lto -o conftest.o conftest.c > /dev/null 2>&1; then
 270             if readelf -WS conftest.o | grep -q -n 'eh_frame .* WA'; then
 271                 libffi_cv_ro_eh_frame=no
 272             fi
 273         fi
 274         rm -f conftest.*
 275       ])
 276   if test "x$libffi_cv_ro_eh_frame" = xyes; then
 277       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 278               [Define if .eh_frame sections should be read-only.])
 279       AC_DEFINE(EH_FRAME_FLAGS, "a",
 280               [Define to the flags needed for the .section .eh_frame directive.  ])
 281   else
 282       AC_DEFINE(EH_FRAME_FLAGS, "aw",
 283               [Define to the flags needed for the .section .eh_frame directive.  ])
 284   fi
 285
 286   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 287       libffi_cv_hidden_visibility_attribute, [
 288         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
 289         libffi_cv_hidden_visibility_attribute=no
 290         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 291             if egrep '(\.hidden|\.private_extern).*foo' conftest.s >/dev/null; then
 292                 libffi_cv_hidden_visibility_attribute=yes
 293             fi
 294         fi
 295         rm -f conftest.*
 296       ])
 297   if test $libffi_cv_hidden_visibility_attribute = yes; then
 298       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 299               [Define if __attribute__((visibility("hidden"))) is supported.])
 300   fi
 301 fi
 302
 303 AC_ARG_ENABLE(docs,
 304               AC_HELP_STRING([--disable-docs],
 305                              [Disable building of docs (default: no)]),
 306               [enable_docs=no],
 307               [enable_docs=yes])
 308 AM_CONDITIONAL(BUILD_DOCS, [test x$enable_docs = xyes])
 309
 310 AH_BOTTOM([
 311 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 312 #ifdef LIBFFI_ASM
 313 #ifdef __APPLE__
 314 #define FFI_HIDDEN(name) .private_extern name
 315 #else
 316 #define FFI_HIDDEN(name) .hidden name
 317 #endif
 318 #else
 319 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 320 #endif
 321 #else
 322 #ifdef LIBFFI_ASM
 323 #define FFI_HIDDEN(name)
 324 #else
 325 #define FFI_HIDDEN
 326 #endif
 327 #endif
 328 ])
 329
 330 AC_SUBST(TARGET)
 331 AC_SUBST(TARGETDIR)
 332
 333 changequote(<,>)
 334 TARGET_OBJ=
 335 for i in $SOURCES; do
 336   TARGET_OBJ="${TARGET_OBJ} src/${TARGETDIR}/"`echo $i | sed 's/[cS]$/lo/'`
 337 done
 338 changequote([,])
 339 AC_SUBST(TARGET_OBJ)
 340
 341 AC_SUBST(SHELL)
 342
 343 AC_ARG_ENABLE(debug,
 344 [  --enable-debug          debugging mode],
 345   if test "$enable_debug" = "yes"; then
 346     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 347   fi)
 348 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
 349
 350 AC_ARG_ENABLE(structs,
 351 [  --disable-structs       omit code for struct support],
 352   if test "$enable_structs" = "no"; then
 353     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this if you do not want support for aggregate types.])
 354   fi)
 355 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
 356
 357 AC_ARG_ENABLE(raw-api,
 358 [  --disable-raw-api       make the raw api unavailable],
 359   if test "$enable_raw_api" = "no"; then
 360     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this if you do not want support for the raw API.])
 361   fi)
 362
 363 AC_ARG_ENABLE(purify-safety,
 364 [  --enable-purify-safety  purify-safe mode],
 365   if test "$enable_purify_safety" = "yes"; then
 366     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 367   fi)
 368
 369 AC_ARG_ENABLE(multi-os-directory,
 370 [  --disable-multi-os-directory
 371                           disable use of gcc --print-multi-os-directory to change the library installation directory])
 372
 373 # These variables are only ever used when we cross-build to X86_WIN32.
 374 # And we only support this with GCC, so...
 375 if test "x$GCC" = "xyes"; then
 376   if test -n "$with_cross_host" &&
 377      test x"$with_cross_host" != x"no"; then
 378     toolexecdir='${exec_prefix}'/'$(target_alias)'
 379     toolexeclibdir='${toolexecdir}'/lib
 380   else
 381     toolexecdir='${libdir}'/gcc-lib/'$(target_alias)'
 382     toolexeclibdir='${libdir}'
 383   fi
 384   if test x"$enable_multi_os_directory" != x"no"; then
 385     multi_os_directory=`$CC $CFLAGS -print-multi-os-directory`
 386     case $multi_os_directory in
 387       .) ;; # Avoid trailing /.
 388       ../*) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 389     esac
 390   fi
 391   AC_SUBST(toolexecdir)
 392 else
 393   toolexeclibdir='${libdir}'
 394 fi
 395 AC_SUBST(toolexeclibdir)
 396
 397 # Check linker support.
 398 LIBFFI_ENABLE_SYMVERS
 399
 400 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 401 AC_CONFIG_COMMANDS(src, [
 402 test -d src || mkdir src
 403 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 404 ], [TARGETDIR="$TARGETDIR"])
 405
 406 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile doc/Makefile libffi.pc)
 407
 408 AC_OUTPUT
 409
 410 # Copy this file instead of using AC_CONFIG_LINK in order to support
 411 # compiling with MSVC, which won't understand cygwin style symlinks.
 412 cp ${srcdir}/src/$TARGETDIR/ffitarget.h include/ffitarget.h