configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [7])
   6 m4_define([dbus_micro_version], [5])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22 # By default, rebuild autotools files on demand; only use ./missing if the
  23 # user says --disable-maintainer-mode (some distributions like to do this)
  24 AM_MAINTAINER_MODE([enable])
  25
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  29
  30 # libtool versioning - this applies to libdbus
  31 #
  32 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  33 #
  34
  35 ## increment if the interface has additions, changes, removals.
  36 LT_CURRENT=11
  37
  38 ## increment any time the source changes; set to
  39 ##  0 if you increment CURRENT
  40 LT_REVISION=2
  41
  42 ## increment if any interfaces have been added; set to 0
  43 ## if any interfaces have been changed or removed. removal has
  44 ## precedence over adding, so set to 0 if both happened.
  45 LT_AGE=8
  46
  47 AC_SUBST(LT_CURRENT)
  48 AC_SUBST(LT_REVISION)
  49 AC_SUBST(LT_AGE)
  50
  51 DBUS_MAJOR_VERSION=dbus_major_version
  52 DBUS_MINOR_VERSION=dbus_minor_version
  53 DBUS_MICRO_VERSION=dbus_micro_version
  54 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  55
  56 AC_SUBST(DBUS_MAJOR_VERSION)
  57 AC_SUBST(DBUS_MINOR_VERSION)
  58 AC_SUBST(DBUS_MICRO_VERSION)
  59 AC_SUBST(DBUS_VERSION)
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_CXX
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_ISC_POSIX
  66 AC_HEADER_STDC
  67 AC_C_INLINE
  68 AM_PROG_LIBTOOL
  69 AC_PROG_MKDIR_P
  70 COMPILER_COVERAGE
  71 COMPILER_OPTIMISATIONS
  72 PKG_PROG_PKG_CONFIG
  73
  74 # Initialize libtool
  75 LT_INIT([win32-dll])
  76 LT_LANG([Windows Resource])
  77
  78 # Set some internal variables depending on the platform for later use.
  79 dbus_win=no
  80 dbus_cygwin=no
  81 dbus_unix=no
  82 case "${host}" in
  83     *-mingw32ce*)
  84         dbus_win=yes
  85         dbus_wince=yes
  86         ;;
  87     *-mingw32*)
  88         dbus_win=yes
  89         ;;
  90     *-cygwin*)
  91         dbus_cygwin=yes
  92         dbus_unix=yes
  93         ;;
  94     *)
  95         dbus_unix=yes
  96        ;;
  97 esac
  98
  99 # Special defines for certain platforms
 100 if test "$dbus_win" = yes; then
 101     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 102     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 103     AC_SUBST(BUILD_TIMESTAMP)
 104     # Assume DBUS_VERSION is always three numbers
 105     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 106     AC_SUBST(BUILD_FILEVERSION)
 107     AC_CHECK_TOOL(WINDRES, windres, no)
 108     if test "$WINDRES" = no; then
 109       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 110     fi
 111     if test "$dbus_wince" = yes; then
 112       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 113       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 114     fi
 115 else
 116     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 117 fi
 118 if test "$dbus_cygwin" = yes; then
 119     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 120 fi
 121
 122 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 123 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 124 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 125 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 126
 127 # this must come first: other options use this to set their defaults
 128 AC_ARG_ENABLE([developer],
 129   [AS_HELP_STRING([--enable-developer],
 130     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
 131   [],
 132   [enable_developer=no])
 133
 134 DBUS_STATIC_BUILD_CPPFLAGS=
 135 if test "x$enable_shared" = xno; then
 136     # On Windows, linking against the static library requires special effort
 137     # to turn off DLL import/export processing. We normally link some things
 138     # against the dynamic library, but if we're not building that, we'll
 139     # have to link everything statically.
 140     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 141 fi
 142 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 143
 144 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 145 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 146 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 147 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 148 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 149 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 150 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 151 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 152 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 153 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 154 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 155 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 156 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 157 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 158 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 159 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 160
 161 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 162 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 163 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 164 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 165 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 166 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 167 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 168 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 169 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 170 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 171
 172 AC_ARG_ENABLE([embedded-tests],
 173   AS_HELP_STRING([--enable-embedded-tests],
 174     [enable unit test code in the library and binaries]),
 175   [], [enable_embedded_tests=$enable_developer])
 176 AC_ARG_ENABLE([modular-tests],
 177   AS_HELP_STRING([--enable-modular-tests],
 178     [enable modular regression tests (requires GLib)]),
 179   [], [enable_modular_tests=auto])
 180 # --enable-tests overrides both --enable-embedded-tests and
 181 # --enable-modular-tests
 182 AC_ARG_ENABLE([tests],
 183   AS_HELP_STRING([--enable-tests],
 184     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 185   [
 186   if test "x$enableval" = xyes; then
 187     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 188     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 189   fi
 190   enable_embedded_tests=$enableval
 191   enable_modular_tests=$enableval
 192   ],
 193   [])
 194
 195 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 196 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 197 # name for this.
 198 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 199 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 200   [test "x$enable_embedded_tests" = xyes])
 201 if test "x$enable_embedded_tests" = xyes; then
 202     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 203       [Define to build test code into the library and binaries])
 204     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 205       [Define to build test code into the library and binaries])
 206 fi
 207
 208 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 209 # These use GTest, from GLib, because life's too short. They're enabled by
 210 # default (unless you don't have GLib), because they don't bloat the library
 211 # or binaries.
 212
 213 AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_26], [Ignore post-2.26 deprecations])
 214 AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [GLIB_VERSION_2_32], [Prevent post-2.32 APIs])
 215
 216 with_glib=yes
 217
 218 if test "x$enable_modular_tests" != xno; then
 219   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 220     [],
 221     [if test "x$enable_modular_tests" = xyes; then
 222       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 223       AC_MSG_ERROR([$GLIB_ERRORS])
 224     else # assumed to be "auto"
 225       with_glib=no
 226     fi])
 227   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 228   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 229     [],
 230     [if test "x$enable_modular_tests" = xyes; then
 231       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 232       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 233     else # assumed to be "auto"
 234       with_glib=no
 235     fi])
 236 fi
 237 if test "x$enable_modular_tests" != xno; then
 238   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 239     [Define to build independent test binaries])
 240 fi
 241 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 242   [test "x$enable_modular_tests" != xno])
 243
 244 if test "x$with_glib" != xno; then
 245   AC_DEFINE([DBUS_WITH_GLIB], [1],
 246     [Define if GLib, GObject, GIO are available])
 247 fi
 248 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 249
 250 AC_ARG_ENABLE([installed-tests],
 251   AS_HELP_STRING([--enable-installed-tests],
 252     [enable unit test code in the library and binaries]),
 253   [], [enable_installed_tests=no])
 254 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 255   [test "x$enable_installed_tests" = xyes])
 256
 257 if test "x$enable_tests" = xyes; then
 258   # full test coverage is required, Python is a hard dependency
 259   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 260   AM_PATH_PYTHON([2.6])
 261   AC_MSG_CHECKING([for Python modules for full test coverage])
 262   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 263     AC_MSG_RESULT([yes])
 264   else
 265     AC_MSG_RESULT([no])
 266     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 267   fi
 268 else
 269   # --enable-tests not given: do not abort if Python is missing
 270   AM_PATH_PYTHON([2.6], [], [:])
 271 fi
 272
 273 if test x$enable_verbose_mode = xyes; then
 274     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 275 fi
 276
 277 if test x$enable_asserts = xno; then
 278     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 279     DISABLE_UNUSED_WARNINGS="unused-label"
 280     R_DYNAMIC_LDFLAG=""
 281 else
 282     # -rdynamic is needed for glibc's backtrace_symbols to work.
 283     # No clue how much overhead this adds, but it's useful
 284     # to do this on any assertion failure,
 285     # so for now it's enabled anytime asserts are (currently not
 286     # in production builds).
 287
 288     # To get -rdynamic you pass -export-dynamic to libtool.
 289     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 290     R_DYNAMIC_LDFLAG=-export-dynamic
 291 fi
 292 AC_SUBST(R_DYNAMIC_LDFLAG)
 293
 294 if test x$enable_checks = xno; then
 295     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 296     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 297     DISABLE_UNUSED_WARNINGS="unused-label"
 298 fi
 299
 300 AH_BOTTOM([
 301 /* explicitly define these macros to get less confusing conditions */
 302 #ifndef DBUS_DISABLE_ASSERT
 303 #  define DBUS_ENABLE_ASSERT 1
 304 #endif
 305 #ifndef DBUS_DISABLE_CHECKS
 306 #  define DBUS_ENABLE_CHECKS 1
 307 #endif])
 308
 309 if test x$enable_userdb_cache = xyes; then
 310     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 311 fi
 312
 313 if test x$enable_compiler_coverage = xyes; then
 314      ## so that config.h changes when you toggle gcov support
 315      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 316 fi
 317
 318 # glibc21.m4 serial 3
 319 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 320 dnl This file is free software; the Free Software Foundation
 321 dnl gives unlimited permission to copy and/or distribute it,
 322 dnl with or without modifications, as long as this notice is preserved.
 323
 324 # Test for the GNU C Library, version 2.1 or newer.
 325 # From Bruno Haible.
 326
 327 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 328   ac_cv_gnu_library_2_1,
 329   [AC_EGREP_CPP([Lucky GNU user],
 330     [
 331 #include <features.h>
 332 #ifdef __GNU_LIBRARY__
 333  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 334   Lucky GNU user
 335  #endif
 336 #endif
 337     ],
 338     ac_cv_gnu_library_2_1=yes,
 339     ac_cv_gnu_library_2_1=no)
 340   ]
 341 )
 342
 343 #### Integer sizes
 344
 345 AC_CHECK_SIZEOF(char)
 346 AC_CHECK_SIZEOF(short)
 347 AC_CHECK_SIZEOF(long)
 348 AC_CHECK_SIZEOF(int)
 349 AC_CHECK_SIZEOF(void *)
 350 AC_CHECK_SIZEOF(long long)
 351 AC_CHECK_SIZEOF(__int64)
 352
 353 AC_ARG_WITH([64-bit],
 354   [AS_HELP_STRING([--without-64-bit],
 355     [If you have to use this option, please report it as a bug])],
 356   [],
 357   [with_64_bit=yes])
 358
 359 ### See what our 64 bit type is called
 360 AC_MSG_CHECKING([64-bit integer type])
 361
 362 case 8 in
 363 $ac_cv_sizeof_int)
 364   dbusint64=int
 365   dbusint64_constant='(val)'
 366   dbusuint64_constant='(val)'
 367   dbusint64_printf_modifier='""'
 368   ;;
 369 $ac_cv_sizeof_long)
 370   dbusint64=long
 371   dbusint64_constant='(val##L)'
 372   dbusuint64_constant='(val##UL)'
 373   dbusint64_printf_modifier='"l"'
 374   ;;
 375 $ac_cv_sizeof_long_long)
 376   dbusint64='long long'
 377   dbusint64_constant='(val##LL)'
 378   dbusuint64_constant='(val##ULL)'
 379   # Ideally we discover what the format is, but this is
 380   # only used in verbose mode, so eh...
 381   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 382     dbusint64_printf_modifier='"ll"'
 383   fi
 384   ;;
 385 $ac_cv_sizeof___int64)
 386   dbusint64=__int64
 387   dbusint64_constant='(val##i64)'
 388   dbusuint64_constant='(val##ui64)'
 389   # See above case
 390   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 391     dbusint64_printf_modifier='"ll"'
 392   fi
 393   ;;
 394 esac
 395
 396 AS_IF(
 397   [test "x$with_64_bit" = xno],
 398   [
 399         DBUS_INT64_TYPE="no_int64_type_detected"
 400         DBUS_HAVE_INT64=0
 401         DBUS_INT64_CONSTANT=
 402         DBUS_UINT64_CONSTANT=
 403         AC_MSG_RESULT([disabled via --without-64-bit])
 404   ],
 405   dnl else if
 406   [test -z "$dbusint64"],
 407   [AC_MSG_RESULT([not found])
 408   AC_MSG_ERROR([Could not find a 64-bit integer type.
 409
 410 Please report a bug here with details of your platform and compiler:
 411
 412     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 413
 414 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 415 the option "--without-64-bit".
 416
 417 This option is likely to be removed in future, unless you report that your
 418 platform needs it.])
 419   ],
 420   dnl else
 421   [
 422         DBUS_INT64_TYPE="$dbusint64"
 423         DBUS_HAVE_INT64=1
 424         DBUS_INT64_CONSTANT="$dbusint64_constant"
 425         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 426         if test x"$dbusint64_printf_modifier" != x; then
 427                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 428         fi
 429         AC_MSG_RESULT($DBUS_INT64_TYPE)
 430   ])
 431
 432 AC_SUBST(DBUS_INT64_TYPE)
 433 AC_SUBST(DBUS_INT64_CONSTANT)
 434 AC_SUBST(DBUS_UINT64_CONSTANT)
 435 AC_SUBST(DBUS_HAVE_INT64)
 436
 437 ### see what 32-bit int is called
 438 AC_MSG_CHECKING([32-bit integer type])
 439
 440 case 4 in
 441 $ac_cv_sizeof_short)
 442   dbusint32=short
 443   ;;
 444 $ac_cv_sizeof_int)
 445   dbusint32=int
 446   ;;
 447 $ac_cv_sizeof_long)
 448   dbusint32=long
 449   ;;
 450 esac
 451
 452 if test -z "$dbusint32" ; then
 453         DBUS_INT32_TYPE="no_int32_type_detected"
 454         AC_MSG_ERROR([No 32-bit integer type found])
 455 else
 456         DBUS_INT32_TYPE="$dbusint32"
 457         AC_MSG_RESULT($DBUS_INT32_TYPE)
 458 fi
 459
 460 AC_SUBST(DBUS_INT32_TYPE)
 461
 462 ### see what 16-bit int is called
 463 AC_MSG_CHECKING([16-bit integer type])
 464
 465 case 2 in
 466 $ac_cv_sizeof_short)
 467   dbusint16=short
 468   ;;
 469 $ac_cv_sizeof_int)
 470   dbusint16=int
 471   ;;
 472 esac
 473
 474 if test -z "$dbusint16" ; then
 475         DBUS_INT16_TYPE="no_int16_type_detected"
 476         AC_MSG_ERROR([No 16-bit integer type found])
 477 else
 478         DBUS_INT16_TYPE="$dbusint16"
 479         AC_MSG_RESULT($DBUS_INT16_TYPE)
 480 fi
 481
 482 AC_SUBST(DBUS_INT16_TYPE)
 483
 484 ## byte order
 485 case $host_os in
 486         darwin*)
 487                 # check at compile-time, so that it is possible to build universal
 488                 # (with multiple architectures at once on the compile line)
 489                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 490                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 491                         #if defined(__BIG_ENDIAN__)
 492                         #define WORDS_BIGENDIAN 1
 493                         #endif
 494                 ])
 495                 ;;
 496         *)
 497                 AC_C_BIGENDIAN
 498                 ;;
 499 esac
 500
 501 dnl **********************************
 502 dnl *** va_copy checks (from GLib) ***
 503 dnl **********************************
 504 dnl we currently check for all three va_copy possibilities, so we get
 505 dnl all results in config.log for bug reports.
 506 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 507         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 508 #include <stdlib.h>
 509         static void f (int i, ...) {
 510         va_list args1, args2;
 511         va_start (args1, i);
 512         va_copy (args2, args1);
 513         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 514           exit (1);
 515         va_end (args1); va_end (args2);
 516         }
 517         int main() {
 518           f (0, 42);
 519           return 0;
 520         }])],
 521         [dbus_cv_va_copy=yes],
 522         [dbus_cv_va_copy=no])
 523 ])
 524 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 525         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 526 #include <stdlib.h>
 527         static void f (int i, ...) {
 528         va_list args1, args2;
 529         va_start (args1, i);
 530         __va_copy (args2, args1);
 531         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 532           exit (1);
 533         va_end (args1); va_end (args2);
 534         }
 535         int main() {
 536           f (0, 42);
 537           return 0;
 538         }])],
 539         [dbus_cv___va_copy=yes],
 540         [dbus_cv___va_copy=no])
 541 ])
 542
 543 if test "x$dbus_cv_va_copy" = "xyes"; then
 544   dbus_va_copy_func=va_copy
 545 else if test "x$dbus_cv___va_copy" = "xyes"; then
 546   dbus_va_copy_func=__va_copy
 547 fi
 548 fi
 549
 550 if test -n "$dbus_va_copy_func"; then
 551   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 552 fi
 553
 554 AC_LANG_PUSH(C)
 555 AC_CACHE_CHECK([whether va_lists can be copied by value],
 556         dbus_cv_va_val_copy,
 557         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 558 [[
 559         #include <stdarg.h>
 560         #include <stdlib.h>
 561 ]],
 562 [[
 563         static void f (int i, ...) {
 564         va_list args1, args2;
 565         va_start (args1, i);
 566         args2 = args1;
 567         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 568           exit (1);
 569         va_end (args1); va_end (args2);
 570         }
 571         int main() {
 572           f (0, 42);
 573           return 0;
 574         }
 575 ]])],
 576         [dbus_cv_va_val_copy=yes],
 577         [dbus_cv_va_val_copy=no],
 578         [dbus_cv_va_val_copy=yes])
 579 ])
 580 AC_LANG_POP(C)
 581
 582 if test "x$dbus_cv_va_val_copy" = "xno"; then
 583   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 584 fi
 585
 586
 587 #### Atomic integers
 588
 589 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 590   dbus_cv_sync_sub_and_fetch,
 591   [AC_LINK_IFELSE([
 592      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 593      [dbus_cv_sync_sub_and_fetch=yes],
 594      [dbus_cv_sync_sub_and_fetch=no])
 595   ])
 596
 597 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 598    have_sync=1
 599 else
 600    have_sync=0
 601 fi
 602
 603 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 604
 605 #### Various functions
 606 AC_SEARCH_LIBS(socket,[socket network])
 607 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 608
 609 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid)
 610
 611 AC_CHECK_HEADERS([syslog.h])
 612 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 613   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 614 fi
 615
 616 #### Check for broken poll; taken from Glib's configure
 617
 618 AC_MSG_CHECKING([for broken poll])
 619 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 620     #include <stdlib.h>
 621     #include <fcntl.h>
 622     #include <poll.h>
 623     #ifdef HAVE_SYS_POLL_H
 624     #include <sys/poll.h>
 625     #endif
 626     int main(void) {
 627       struct pollfd fds[1];
 628       int fd;
 629       fd = open("/dev/null", 1);
 630       fds[0].fd = fd;
 631       fds[0].events = POLLIN;
 632       fds[0].revents = 0;
 633       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 634             exit(1);  /* Does not work for devices -- fail */
 635       }
 636       exit(0);
 637     }]])],
 638   [broken_poll=no],
 639   [broken_poll=yes
 640    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 641   [broken_poll="no (cross compiling)"])
 642 AC_MSG_RESULT($broken_poll)
 643
 644 AC_MSG_CHECKING(for dirfd)
 645 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 646 #include <sys/types.h>
 647 #include <dirent.h>
 648 ]], [[
 649 DIR *dirp;
 650 dirp = opendir(".");
 651 dirfd(dirp);
 652 closedir(dirp);
 653 ]])],
 654 [dbus_have_dirfd=yes],
 655 [dbus_have_dirfd=no])
 656 AC_MSG_RESULT($dbus_have_dirfd)
 657 if test "$dbus_have_dirfd" = yes; then
 658         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 659 else
 660         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 661         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 662 #include <sys/types.h>
 663 #include <dirent.h>
 664         ]], [[
 665 DIR *dirp;
 666 int fd;
 667 dirp = opendir(".");
 668 fd = dirp->dd_fd;
 669 closedir(dirp);
 670         ]])],
 671         [dbus_have_ddfd=yes],
 672         [dbus_have_ddfd=no])
 673         AC_MSG_RESULT($dbus_have_ddfd)
 674         if test "$dbus_have_ddfd" = yes; then
 675                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 676         fi
 677 fi
 678
 679 AC_CHECK_HEADERS(sys/resource.h)
 680
 681 AC_CHECK_HEADERS(dirent.h)
 682
 683 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 684
 685 AC_CHECK_HEADERS(errno.h)
 686
 687 AC_CHECK_HEADERS(signal.h)
 688
 689 AC_CHECK_HEADERS(locale.h)
 690
 691 AC_CHECK_HEADERS(byteswap.h)
 692
 693 AC_CHECK_HEADERS(unistd.h)
 694
 695 AC_CHECK_HEADERS(ws2tcpip.h)
 696
 697 AC_CHECK_HEADERS(wspiapi.h)
 698
 699 AC_CHECK_HEADERS(alloca.h)
 700
 701 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 702 #
 703 case $host_os in
 704     solaris*)
 705        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 706 esac
 707
 708 # checking for a posix version of getpwnam_r
 709 # if we are cross compiling and can not run the test
 710 # assume getpwnam_r is the posix version
 711 # it is up to the person cross compiling to change
 712 # this behavior if desired
 713 AC_LANG_PUSH(C)
 714 AC_CACHE_CHECK([for posix getpwnam_r],
 715                 ac_cv_func_posix_getpwnam_r,
 716                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 717 [[
 718 #include <errno.h>
 719 #include <pwd.h>
 720 ]],
 721 [[
 722     char buffer[10000];
 723     struct passwd pwd, *pwptr = &pwd;
 724     int error;
 725     errno = 0;
 726     error = getpwnam_r ("", &pwd, buffer,
 727                         sizeof (buffer), &pwptr);
 728    return (error < 0 && errno == ENOSYS)
 729            || error == ENOSYS;
 730 ]])],
 731         [ac_cv_func_posix_getpwnam_r=yes],
 732         [ac_cv_func_posix_getpwnam_r=no],
 733         [ac_cv_func_posix_getpwnam_r=yes]
 734 )])
 735 AC_LANG_POP(C)
 736
 737 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 738         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 739                 [Have POSIX function getpwnam_r])
 740 else
 741         AC_CACHE_CHECK([for nonposix getpwnam_r],
 742                 ac_cv_func_nonposix_getpwnam_r,
 743                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 744                         struct passwd pwd;
 745                         getpwnam_r ("", &pwd, buffer,
 746                                         sizeof (buffer));]])],
 747                         [ac_cv_func_nonposix_getpwnam_r=yes],
 748                         [ac_cv_func_nonposix_getpwnam_r=no])])
 749                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 750                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 751                         [Have non-POSIX function getpwnam_r])
 752         fi
 753 fi
 754
 755 dnl check for socklen_t
 756 AC_MSG_CHECKING(whether socklen_t is defined)
 757 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 758 #include <sys/types.h>
 759 #include <sys/socket.h>
 760 #include <netdb.h>
 761 ]], [[
 762 socklen_t foo;
 763 foo = 1;
 764 ]])],
 765 [dbus_have_socklen_t=yes],
 766 [dbus_have_socklen_t=no])
 767 AC_MSG_RESULT($dbus_have_socklen_t)
 768
 769 if test "x$dbus_have_socklen_t" = "xyes"; then
 770     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 771 fi
 772
 773 dnl check for writev header and writev function so we're
 774 dnl good to go if HAVE_WRITEV gets defined.
 775 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 776
 777 dnl needed on darwin for NAME_MAX
 778 AC_CHECK_HEADERS(sys/syslimits.h)
 779
 780 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 781 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 782 #include <sys/socket.h> ]])
 783
 784 dnl check for flavours of varargs macros (test from GLib)
 785 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 786 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 787 int a(int p1, int p2, int p3);
 788 #define call_a(...) a(1,__VA_ARGS__)
 789 call_a(2,3);
 790 ]])],
 791 [dbus_have_iso_c_varargs=yes],
 792 [dbus_have_iso_c_varargs=no])
 793 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 794
 795 AC_MSG_CHECKING(for GNUC varargs macros)
 796 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 797 int a(int p1, int p2, int p3);
 798 #define call_a(params...) a(1,params)
 799 call_a(2,3);
 800 ]])],
 801 [dbus_have_gnuc_varargs=yes],
 802 [dbus_have_gnuc_varargs=no])
 803 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 804
 805 dnl Output varargs tests
 806 if test x$dbus_have_iso_c_varargs = xyes; then
 807     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 808 fi
 809 if test x$dbus_have_gnuc_varargs = xyes; then
 810     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 811 fi
 812
 813 dnl Check for various credentials.
 814 AC_MSG_CHECKING(for struct cmsgcred)
 815 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 816 #include <sys/types.h>
 817 #include <sys/socket.h>
 818 ]], [[
 819 struct cmsgcred cred;
 820
 821 cred.cmcred_pid = 0;
 822 ]])],
 823 [dbus_have_struct_cmsgcred=yes],
 824 [dbus_have_struct_cmsgcred=no])
 825 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 826
 827 if test x$dbus_have_struct_cmsgcred = xyes; then
 828     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 829 fi
 830
 831 AC_CHECK_FUNCS(getpeerucred getpeereid)
 832
 833 AC_CHECK_FUNCS(pipe2 accept4)
 834
 835 #### Abstract sockets
 836
 837 if test x$enable_abstract_sockets = xauto; then
 838 AC_LANG_PUSH(C)
 839 warn_on_xcompile=no
 840 AC_CACHE_CHECK([abstract socket namespace],
 841                 ac_cv_have_abstract_sockets,
 842                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 843 [[
 844 #include <sys/types.h>
 845 #include <stdlib.h>
 846 #include <string.h>
 847 #include <stdio.h>
 848 #include <sys/socket.h>
 849 #include <sys/un.h>
 850 #include <errno.h>
 851 ]],
 852 [[
 853   size_t slen;
 854   int listen_fd;
 855   struct sockaddr_un addr;
 856
 857   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 858
 859   if (listen_fd < 0)
 860     {
 861       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 862       exit (1);
 863     }
 864
 865   memset (&addr, '\0', sizeof (addr));
 866   addr.sun_family = AF_UNIX;
 867   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 868   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 869    * beginning.
 870    */
 871   slen = SUN_LEN(&addr);
 872   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 873
 874   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 875     {
 876        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 877                 strerror (errno));
 878        exit (1);
 879     }
 880   else
 881     exit (0);
 882 ]])],
 883               [ac_cv_have_abstract_sockets=yes],
 884               [ac_cv_have_abstract_sockets=no],
 885               [
 886                 ac_cv_have_abstract_sockets=no
 887                 warn_on_xcompile=yes
 888               ]
 889 )])
 890 if test x$warn_on_xcompile = xyes ; then
 891   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 892 fi
 893 AC_LANG_POP(C)
 894 fi
 895
 896 if test x$enable_abstract_sockets = xyes; then
 897     if test x$ac_cv_have_abstract_sockets = xno; then
 898         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 899     fi
 900 fi
 901
 902 if test x$enable_abstract_sockets = xno; then
 903    ac_cv_have_abstract_sockets=no;
 904 fi
 905
 906 if test x$ac_cv_have_abstract_sockets = xyes ; then
 907    DBUS_PATH_OR_ABSTRACT=abstract
 908    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 909 else
 910    DBUS_PATH_OR_ABSTRACT=path
 911 fi
 912
 913 # this is used in addresses to prefer abstract, e.g.
 914 # unix:path=/foo or unix:abstract=/foo
 915 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 916
 917 PKG_PROG_PKG_CONFIG
 918
 919 #### Sort out XML library
 920
 921 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 922              [ AC_CHECK_HEADERS(expat.h, [],
 923                                 [AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])]) ],
 924              [ AC_MSG_ERROR([Explicitly requested expat but expat not found]) ])
 925
 926 XML_LIBS=-lexpat
 927 XML_CFLAGS=
 928 AC_SUBST([XML_CFLAGS])
 929 AC_SUBST([XML_LIBS])
 930
 931 # Thread lib detection
 932 AC_ARG_VAR([THREAD_LIBS])
 933 save_libs="$LIBS"
 934 LIBS="$LIBS $THREAD_LIBS"
 935
 936 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 937
 938 # Don't do these automatic checks if the user set THREAD_LIBS on the
 939 # configure command-line. If they did, we assume they're right.
 940 #
 941 # We also don't do these checks on Windows, because you don't need magical
 942 # linker flags to have threading support there.
 943 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 944   [
 945     # Mandatory pthread functions. In principle, some of these could be made
 946     # optional if there are platforms that don't have them.
 947     #
 948     # Currently, we only look in -lpthread.
 949     # In principle we might need to look in -lpthreads, -lthreads, ...
 950     # as well - please file a bug if your platform needs this.
 951     AC_SEARCH_LIBS([pthread_cond_timedwait],
 952         [pthread],
 953         [THREAD_LIBS="$LIBS"],
 954         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 955         [])
 956     AC_SEARCH_LIBS([pthread_mutexattr_init],
 957         [pthread],
 958         [THREAD_LIBS="$LIBS"],
 959         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 960         [])
 961     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 962         [pthread],
 963         [THREAD_LIBS="$LIBS"],
 964         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 965         [])
 966
 967     # Optional, for monotonic clocks. Because it's optional, this check
 968     # is non-fatal if we don't find it.
 969     AC_SEARCH_LIBS([pthread_condattr_setclock],
 970         [pthread],
 971         [THREAD_LIBS="$LIBS"])
 972
 973     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
 974       [
 975         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
 976         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 977         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 978 [[#include <time.h>
 979 #include <pthread.h>
 980 ]], [[
 981 struct timespec monotonic_timer;
 982 pthread_condattr_t attr;
 983 pthread_condattr_init (&attr);
 984 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 985 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 986 ]])],
 987             [have_clock_monotonic=true],
 988             [have_clock_monotonic=false])
 989         AS_IF([test x$have_clock_monotonic = xtrue],
 990           [
 991             AC_MSG_RESULT([found])
 992             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 993           ],
 994           [AC_MSG_RESULT([not found])])
 995       ]) dnl have pthread_condattr_setclock
 996   ]) dnl on Unix
 997
 998 LIBS="$save_libs"
 999
1000 AC_SUBST([THREAD_LIBS])
1001
1002 # SELinux detection
1003 if test x$enable_selinux = xno ; then
1004     have_selinux=no;
1005 else
1006     # See if we have SELinux library
1007     AC_CHECK_LIB(selinux, is_selinux_enabled,
1008                  have_selinux=yes, have_selinux=no)
1009
1010     # see if we have the SELinux header with the new D-Bus stuff in it
1011     if test x$have_selinux = xyes ; then
1012         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
1013         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
1014                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
1015                             #else
1016                             #error DBUS__ACQUIRE_SVC not defined
1017                             #endif]])],
1018                           [have_selinux=yes],
1019                           [have_selinux=no])
1020         AC_MSG_RESULT($have_selinux)
1021     fi
1022
1023     if test x$enable_selinux = xauto ; then
1024         if test x$have_selinux = xno ; then
1025                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1026         fi
1027     else
1028         if test x$have_selinux = xno ; then
1029                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1030         fi
1031     fi
1032 fi
1033
1034 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1035
1036 if test x$have_selinux = xyes ; then
1037     # the selinux code creates threads
1038     # which requires libpthread even on linux
1039     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1040                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1041
1042     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1043     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1044 else
1045     SELINUX_LIBS=
1046 fi
1047
1048 # inotify checks
1049 if test x$enable_inotify = xno ; then
1050     have_inotify=no;
1051 else
1052     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1053 fi
1054
1055 dnl check if inotify backend is enabled
1056 if test x$have_inotify = xyes; then
1057    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1058    AC_CHECK_FUNCS(inotify_init1)
1059 fi
1060
1061 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1062
1063 # dnotify checks
1064 if test x$enable_dnotify = xno ; then
1065     have_dnotify=no;
1066 else
1067     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
1068         have_dnotify=yes;
1069     else
1070         have_dnotify=no;
1071     fi
1072 fi
1073
1074 dnl check if dnotify backend is enabled
1075 if test x$have_dnotify = xyes; then
1076    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
1077 fi
1078
1079 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
1080
1081 # For simplicity, we require the userland API for epoll_create1 at
1082 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1083 # not to have it at runtime.
1084 AC_ARG_ENABLE([epoll],
1085               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1086               [enable_epoll=$enableval], [enable_epoll=auto])
1087 if test x$enable_epoll = xno; then
1088     have_linux_epoll=no
1089 else
1090     AC_MSG_CHECKING([for Linux epoll(4)])
1091     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1092         [
1093         #ifndef __linux__
1094         #error This is not Linux
1095         #endif
1096         #include <sys/epoll.h>
1097         ],
1098         [epoll_create1 (EPOLL_CLOEXEC);])],
1099         [have_linux_epoll=yes],
1100         [have_linux_epoll=no])
1101     AC_MSG_RESULT([$have_linux_epoll])
1102 fi
1103 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1104     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1105 fi
1106 if test x$have_linux_epoll = xyes; then
1107   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1108 fi
1109 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1110
1111 # kqueue checks
1112 if test x$enable_kqueue = xno ; then
1113     have_kqueue=no
1114 else
1115     have_kqueue=yes
1116     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1117     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1118
1119     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1120         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1121     fi
1122 fi
1123
1124 dnl check if kqueue backend is enabled
1125 if test x$have_kqueue = xyes; then
1126    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1127 fi
1128
1129 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1130
1131 # launchd checks
1132 if test x$enable_launchd = xno ; then
1133     have_launchd=no
1134 else
1135     have_launchd=yes
1136     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1137     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1138     if test "x$LAUNCHCTL" = "x"; then
1139         have_launchd=no
1140     fi
1141
1142     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1143         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1144     fi
1145 fi
1146
1147 dnl check if launchd is enabled
1148 if test x$have_launchd = xyes; then
1149     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1150 fi
1151
1152 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1153
1154 #### Directory to place launchd agent file
1155 if test "x$with_launchd_agent_dir" = "x"; then
1156    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1157 else
1158    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1159 fi
1160
1161 AC_SUBST(LAUNCHD_AGENT_DIR)
1162
1163 dnl console owner file
1164 if test x$enable_console_owner_file = xno ; then
1165     have_console_owner_file=no;
1166 else
1167     case $host_os in
1168     solaris*)
1169         have_console_owner_file=yes;
1170         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1171         ;;
1172     *)
1173         have_console_owner_file=no;;
1174     esac
1175 fi
1176
1177 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1178
1179 dnl systemd detection
1180 if test x$enable_systemd = xno ; then
1181     have_systemd=no;
1182 else
1183     PKG_CHECK_MODULES(SYSTEMD,
1184         [libsystemd-login >= 32, libsystemd-daemon >= 32],
1185         have_systemd=yes,
1186         have_systemd=no)
1187 fi
1188
1189 if test x$have_systemd = xyes; then
1190     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1191 fi
1192
1193 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1194     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1195 fi
1196
1197 # libaudit detection
1198 if test x$enable_libaudit = xno ; then
1199     have_libaudit=no;
1200 else
1201     # See if we have audit daemon & capabilities library
1202     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1203                  have_libaudit=yes, have_libaudit=no)
1204     if test x$have_libaudit = xyes ; then
1205         AC_CHECK_LIB(cap-ng, capng_clear,
1206                  have_libaudit=yes, have_libaudit=no)
1207     fi
1208 fi
1209
1210 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1211
1212 if test x$have_libaudit = xyes ; then
1213     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1214     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1215 fi
1216
1217 AC_SUBST([SELINUX_LIBS])
1218
1219 # Check for ADT API (Solaris Basic Security Mode auditing)
1220 AC_MSG_CHECKING(for ADT API)
1221 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1222 #include <bsm/adt.h>
1223 adt_user_context = ADT_USER;
1224 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1225
1226 if test ${check_adt_audit} = yes
1227 then
1228    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1229    ADT_LIBS="-lbsm"
1230    LIBS="-lbsm $LIBS"
1231    AC_MSG_RESULT(yes)
1232 else
1233    AC_MSG_RESULT(no)
1234 fi
1235 AC_SUBST([ADT_LIBS])
1236
1237 # Check for SCM_RIGHTS
1238 AC_MSG_CHECKING([for SCM_RIGHTS])
1239 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1240 #include <sys/types.h>
1241 #include <sys/socket.h>
1242 #include <sys/un.h>
1243 static int x = SCM_RIGHTS;
1244 ]], [[]])],
1245 [ AC_MSG_RESULT([supported])
1246   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1247 [ AC_MSG_RESULT([not supported]) ])
1248
1249 NETWORK_libs=
1250 if test x$dbus_win = xyes ; then
1251   if test x$dbus_wince = xyes ; then
1252     NETWORK_libs="-lws2"
1253   else
1254     NETWORK_libs="-lws2_32 -liphlpapi"
1255   fi
1256 fi
1257
1258 AC_SUBST([NETWORK_libs])
1259
1260 AC_ARG_WITH([valgrind],
1261   [AS_HELP_STRING([--with-valgrind],
1262      [Add instrumentation to help valgrind to understand our allocator])],
1263   [],
1264   [with_valgrind=no])
1265
1266 if test x$with_valgrind != xno; then
1267   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1268   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1269 fi
1270
1271 # Determine maximum number of Unix fds which may be passed
1272 AS_CASE([$host_os],
1273   [*qnx*],
1274     [DEFAULT_MESSAGE_UNIX_FDS=256],
1275   [*],
1276     [DEFAULT_MESSAGE_UNIX_FDS=1024])
1277 AC_DEFINE_UNQUOTED([DBUS_DEFAULT_MESSAGE_UNIX_FDS],
1278   [$DEFAULT_MESSAGE_UNIX_FDS],
1279   [Default for dbus_connection_get_max_message_unix_fds()])
1280 AC_SUBST([DEFAULT_MESSAGE_UNIX_FDS])
1281
1282 #### Set up final flags
1283 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1284 AC_SUBST([LIBDBUS_LIBS])
1285
1286 ### X11 detection
1287 DBUS_X_LIBS=
1288 DBUS_X_CFLAGS=
1289
1290 AC_ARG_ENABLE([x11-autolaunch],
1291   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1292   [], [enable_x11_autolaunch=auto])
1293
1294 if test "x$dbus_win" = xyes; then
1295     if test "x$enable_x11_autolaunch" = xyes; then
1296         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1297     fi
1298
1299     enable_x11_autolaunch=no
1300     have_x11=no
1301 else
1302     AC_PATH_XTRA
1303
1304     if test "x$no_x" = xyes; then
1305         have_x11=no
1306     else
1307         have_x11=yes
1308         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1309         DBUS_X_CFLAGS="$X_CFLAGS"
1310     fi
1311 fi
1312
1313 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1314     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1315 else
1316     # move from "auto" to "yes" or "no" if necessary
1317     if test "x$enable_x11_autolaunch" != xno; then
1318         enable_x11_autolaunch="$have_x11"
1319     fi
1320 fi
1321
1322 if test "x$have_x11" = xyes ; then
1323    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1324 fi
1325
1326 if test "x$enable_x11_autolaunch" = xyes ; then
1327    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1328 fi
1329
1330 AC_SUBST([DBUS_X_CFLAGS])
1331 AC_SUBST([DBUS_X_LIBS])
1332
1333 #### gcc warning flags
1334
1335 cc_supports_flag() {
1336   AC_MSG_CHECKING(whether $CC supports "$*")
1337   save_CFLAGS="$CFLAGS"
1338   CFLAGS="$*"
1339   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1340   CFLAGS="$save_CFLAGS"
1341   AC_MSG_RESULT([$rc])
1342   test "x$rc" = xyes
1343 }
1344
1345 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1346   dnl Use -Werror by default if:
1347   dnl - we're not on Windows (too many warnings), and
1348   dnl - we're in developer mode (a D-Bus developer, not a distro or end-user)
1349   dnl Override with --enable-Werror or --disable-Werror
1350   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$enable_developer = xyes],
1351
1352   dnl Enable these warnings if possible:
1353   [all \
1354    extra \
1355    char-subscripts \
1356    missing-declarations \
1357    missing-prototypes \
1358    nested-externs \
1359    pointer-arith \
1360    cast-align \
1361    no-address \
1362    float-equal \
1363    declaration-after-statement \
1364   ],
1365
1366   dnl Disable these warnings if possible, make them non-fatal if possible,
1367   dnl and don't enable -Werror unless we succeeded.
1368   dnl
1369   dnl Intentional:
1370   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1371   dnl   checking or not asserting
1372   dnl - missing field initializers being 0 is a C feature, not a bug
1373   dnl - unused-parameter is to make writing callbacks less annoying
1374   dnl
1375   dnl To be fixed one day:
1376   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1377   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1378   dnl   is better than nothing
1379   [$DISABLE_UNUSED_WARNINGS \
1380    missing-field-initializers \
1381    unused-parameter \
1382    sign-compare \
1383    pointer-sign \
1384    type-limits \
1385   ])
1386
1387 if test "x$GCC" = "xyes"; then
1388   # We're treating -fno-common like a warning: it makes the linker more
1389   # strict, because on some systems the linker is *always* this strict
1390   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1391
1392   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1393   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1394
1395   if test "x$enable_ansi" = "xyes"; then
1396     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1397       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1398   fi
1399 fi
1400
1401 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1402 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1403 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1404 dnl is the next best thing
1405 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1406
1407 case $host_os in
1408     solaris*)
1409         # Solaris' C library apparently needs these runes to be threadsafe...
1410         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1411         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1412         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1413         # ... and this opt-in to get file descriptor passing support
1414         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1415         ;;
1416 esac
1417
1418 ### Doxygen Documentation
1419
1420 AC_PATH_PROG(DOXYGEN, doxygen, no)
1421
1422 AC_MSG_CHECKING([whether to build Doxygen documentation])
1423
1424 if test x$DOXYGEN = xno ; then
1425     have_doxygen=no
1426 else
1427     have_doxygen=yes
1428 fi
1429
1430 if test x$enable_doxygen_docs = xauto ; then
1431     if test x$have_doxygen = xno ; then
1432         enable_doxygen_docs=no
1433     else
1434         enable_doxygen_docs=yes
1435     fi
1436 fi
1437
1438 if test x$enable_doxygen_docs = xyes; then
1439     if test x$have_doxygen = xno; then
1440         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1441     fi
1442 fi
1443
1444 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1445 AC_MSG_RESULT($enable_doxygen_docs)
1446
1447 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1448 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1449
1450 ### XML Documentation
1451
1452 AC_PATH_PROG(XMLTO, xmlto, no)
1453
1454 AC_MSG_CHECKING([whether to build XML documentation])
1455
1456 if test x$XMLTO = xno ; then
1457     have_xmlto=no
1458 else
1459     have_xmlto=yes
1460 fi
1461
1462 if test x$enable_xml_docs = xauto ; then
1463     if test x$have_xmlto = xno ; then
1464         enable_xml_docs=no
1465     else
1466         enable_xml_docs=yes
1467     fi
1468 fi
1469
1470 if test x$enable_xml_docs = xyes; then
1471     if test x$have_xmlto = xno; then
1472         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1473     fi
1474 fi
1475
1476 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1477 AC_MSG_RESULT($enable_xml_docs)
1478
1479 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1480     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes])
1481
1482 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1483
1484 #### find the actual value for $prefix that we'll end up with
1485 ##   (I know this is broken and should be done in the Makefile, but
1486 ##    that's a major pain and almost nobody actually seems to care)
1487 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1488 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1489 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1490 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1491 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1492 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1493 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1494
1495 #### Check our operating system
1496 operating_system=unknown
1497 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1498    operating_system=redhat
1499 fi
1500
1501 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1502    operating_system=slackware
1503 fi
1504
1505 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1506    operating_system=cygwin
1507 fi
1508
1509 #### Sort out init scripts
1510
1511 if test x$with_init_scripts = x; then
1512     case x$operating_system in
1513         xredhat)        with_init_scripts=redhat ;;
1514         xslackware)     with_init_scripts=slackware ;;
1515         xcygwin)        with_init_scripts=cygwin ;;
1516         *)                      with_init_scripts=none ;;
1517     esac
1518 fi
1519
1520 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1521 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1522 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1523
1524 ##### systemd unit files
1525 AC_ARG_WITH([systemdsystemunitdir],
1526 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1527     [],
1528     [
1529     PKG_CHECK_EXISTS([systemd],
1530       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1531       [with_systemdsystemunitdir=no])
1532     ])
1533 if test "x$with_systemdsystemunitdir" != xno; then
1534    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1535 fi
1536 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1537
1538 ##### Set up location for system bus socket
1539 if ! test -z "$with_system_socket"; then
1540    DBUS_SYSTEM_SOCKET=$with_system_socket
1541 else
1542    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1543 fi
1544
1545 AC_SUBST(DBUS_SYSTEM_SOCKET)
1546 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1547
1548 ## System bus only listens on local domain sockets, and never
1549 ## on an abstract socket (so only root can create the socket).
1550 ##
1551 ## This won't work on Windows. It's not meant to - the system bus is
1552 ## meaningless on Windows anyway.
1553 ##
1554 ## This has to be suitable for hard-coding in client libraries as well as
1555 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1556 ## and also to connect to. If this ever changes, it'll need to be split into
1557 ## two variables, one for the listening address and one for the connecting
1558 ## address.
1559 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1560 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1561 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1562
1563 #### Set up the pid file
1564 if ! test -z "$with_system_pid_file"; then
1565    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1566 elif test x$with_init_scripts = xredhat ; then
1567    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1568 else
1569    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1570 fi
1571
1572 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1573
1574 #### Directory to check for console ownership
1575 if ! test -z "$with_console_auth_dir"; then
1576    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1577 else
1578    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1579 fi
1580
1581 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1582 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1583
1584 #### File to check for console ownership
1585 if test x$have_console_owner_file = xyes; then
1586    if ! test -z "$with_console_owner_file"; then
1587       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1588    else
1589       DBUS_CONSOLE_OWNER_FILE=/dev/console
1590    fi
1591 else
1592   DBUS_CONSOLE_OWNER_FILE=
1593 fi
1594
1595 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1596 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1597
1598 #### User to start the system bus as
1599 if test -z "$with_dbus_user" ; then
1600     DBUS_USER=messagebus
1601 else
1602     DBUS_USER=$with_dbus_user
1603 fi
1604 AC_SUBST(DBUS_USER)
1605 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1606
1607 #### Prefix to install into
1608 DBUS_PREFIX=$EXPANDED_PREFIX
1609 AC_SUBST(DBUS_PREFIX)
1610 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1611
1612 #### Direcotry to install data files into
1613 DBUS_DATADIR=$EXPANDED_DATADIR
1614 AC_SUBST(DBUS_DATADIR)
1615 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1616
1617 #### Directory to install dbus-daemon
1618 if test -z "$with_dbus_daemondir" ; then
1619     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1620 else
1621     DBUS_DAEMONDIR=$with_dbus_daemondir
1622 fi
1623 AC_SUBST(DBUS_DAEMONDIR)
1624 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1625
1626 #### Directory to install the other binaries
1627 DBUS_BINDIR="$EXPANDED_BINDIR"
1628 AC_SUBST(DBUS_BINDIR)
1629 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1630
1631 #### Directory to install the libexec binaries
1632 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1633 AC_SUBST(DBUS_LIBEXECDIR)
1634 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1635
1636 #### Tell tests where to find certain stuff in builddir
1637
1638 DBUS_PWD=`pwd`
1639 # Useful in a cross-compilation environment, where the tests are run on the host system.
1640 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1641                            DBUS_PWD=$withval)
1642
1643 DBUS_TEST_EXEC="$DBUS_PWD/test"
1644 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1645
1646 AC_SUBST([DBUS_TEST_DATA])
1647 AC_SUBST([DBUS_TEST_EXEC])
1648
1649 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1650                    [Full path to the daemon in the builddir])
1651 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1652                    [Extension for executables, typically empty or .exe])
1653
1654 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, ["$DBUS_PWD/bus/dbus-daemon$EXEEXT"],
1655                    [Full path to the daemon in the builddir])
1656 AC_SUBST(TEST_BUS_BINARY)
1657
1658 ## Export the non-setuid external helper
1659 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1660 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1661 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1662                    [Full path to the launch helper test program in the builddir])
1663
1664 #### Find socket directories
1665 if ! test -z "$TMPDIR" ; then
1666    DEFAULT_SOCKET_DIR=$TMPDIR
1667 elif ! test -z "$TEMP" ; then
1668    DEFAULT_SOCKET_DIR=$TEMP
1669 elif ! test -z "$TMP" ; then
1670    DEFAULT_SOCKET_DIR=$TMP
1671 else
1672    DEFAULT_SOCKET_DIR=/tmp
1673 fi
1674
1675 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1676
1677 if ! test -z "$with_test_socket_dir" ; then
1678    TEST_SOCKET_DIR="$with_test_socket_dir"
1679 else
1680    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1681 fi
1682 AC_SUBST(TEST_SOCKET_DIR)
1683 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1684
1685 if test "x$dbus_unix" = xyes; then
1686   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1687 else
1688   TEST_LISTEN="tcp:host=localhost"
1689 fi
1690 AC_SUBST([TEST_LISTEN])
1691 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1692   [Listening address for regression tests])
1693
1694 if ! test -z "$with_session_socket_dir" ; then
1695    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1696 else
1697    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1698 fi
1699 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1700 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1701
1702 # This must be a listening address. It doesn't necessarily need to be an
1703 # address you can connect to - it can be something vague like
1704 # "nonce-tcp:".
1705 #
1706 # The default varies by platform.
1707 AC_ARG_WITH([dbus_session_bus_listen_address],
1708             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1709                            [default address for a session bus to listen on (see configure.ac)]),
1710             [with_dbus_session_bus_listen_address=$withval],
1711             [with_dbus_session_bus_listen_address=])
1712
1713 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1714         # the user specified something, trust them
1715         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1716 elif test x$dbus_win = xyes; then
1717         # On Windows, you can (and should) listen on autolaunch addresses,
1718         # because autolaunching is different.
1719         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1720         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1721 elif test x$have_launchd = xyes; then
1722         # Mac OS X default is to use launchd
1723         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1724 else
1725         # The default on all other Unix platforms (notably Linux)
1726         # is to create a randomly named socket in /tmp or similar
1727         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1728 fi
1729 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1730
1731 # This must be an address you can connect to. It doesn't necessarily
1732 # need to be an address you can listen on - it can be "autolaunch:",
1733 # even on Unix.
1734 #
1735 # The default varies by platform.
1736 AC_ARG_WITH([dbus_session_bus_connect_address],
1737             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1738                            [fallback address for a session bus client to connect to (see configure.ac)]),
1739             [with_dbus_session_bus_connect_address=$withval],
1740             [with_dbus_session_bus_connect_address=])
1741
1742 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1743         # the user specified something, trust them
1744         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1745 elif test x$dbus_win = xyes; then
1746         # Windows autolaunching is a bit different; leaving it in its own
1747         # branch of the conditional because the default might conceivably
1748         # change (see #38201)
1749         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1750 else
1751         # The default on all other Unix platforms (notably Linux)
1752         # is to use auto-launching - this works a bit differently on Mac OS X
1753         # but comes out basically the same in the end
1754         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1755 fi
1756 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1757 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1758   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1759   [Fallback address for session bus clients])
1760
1761 # darwin needs this to initialize the environment
1762 AC_CHECK_HEADERS(crt_externs.h)
1763 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1764 AH_VERBATIM(_DARWIN_ENVIRON,
1765 [
1766 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1767 # include <sys/time.h>
1768 # include <crt_externs.h>
1769 # define environ (*_NSGetEnviron())
1770 #endif
1771 ])
1772
1773 AC_ARG_ENABLE([stats],
1774   [AS_HELP_STRING([--enable-stats],
1775     [enable bus daemon usage statistics])],
1776   [], [enable_stats=no])
1777 if test "x$enable_stats" = xyes; then
1778   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1779     [Define to enable bus daemon usage statistics])
1780 fi
1781
1782 AC_CONFIG_FILES([
1783 Doxyfile
1784 dbus/versioninfo.rc
1785 dbus/dbus-arch-deps.h
1786 bus/system.conf
1787 bus/session.conf
1788 bus/messagebus
1789 bus/messagebus-config
1790 bus/org.freedesktop.dbus-session.plist
1791 bus/rc.messagebus
1792 bus/dbus.service
1793 bus/dbus.socket
1794 Makefile
1795 dbus/Makefile
1796 bus/Makefile
1797 tools/Makefile
1798 test/Makefile
1799 test/name-test/Makefile
1800 doc/Makefile
1801 doc/dbus-cleanup-sockets.1.xml
1802 doc/dbus-daemon.1.xml
1803 doc/dbus-launch.1.xml
1804 doc/dbus-monitor.1.xml
1805 doc/dbus-run-session.1.xml
1806 doc/dbus-send.1.xml
1807 doc/dbus-uuidgen.1.xml
1808 dbus-1.pc
1809 dbus-1-uninstalled.pc
1810 test/data/valid-config-files/debug-allow-all.conf
1811 test/data/valid-config-files/debug-allow-all-sha1.conf
1812 test/data/valid-config-files-system/debug-allow-all-pass.conf
1813 test/data/valid-config-files-system/debug-allow-all-fail.conf
1814 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1815 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1816 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1817 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1818 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1819 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1820 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1821 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1822 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1823 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1824 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1825 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1826 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1827 ])
1828 AC_OUTPUT
1829
1830 dnl ==========================================================================
1831 echo "
1832                     D-Bus $VERSION
1833                   ==============
1834
1835         prefix:                   ${EXPANDED_PREFIX}
1836         exec_prefix:              ${exec_prefix}
1837         libdir:                   ${EXPANDED_LIBDIR}
1838         libexecdir:               ${EXPANDED_LIBEXECDIR}
1839         bindir:                   ${EXPANDED_BINDIR}
1840         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1841         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1842         datadir:                  ${EXPANDED_DATADIR}
1843         source code location:     ${srcdir}
1844         compiler:                 ${CC}
1845         cflags:                   ${CFLAGS}
1846         cppflags:                 ${CPPFLAGS}
1847         cxxflags:                 ${CXXFLAGS}
1848         64-bit int:               ${DBUS_INT64_TYPE}
1849         32-bit int:               ${DBUS_INT32_TYPE}
1850         16-bit int:               ${DBUS_INT16_TYPE}
1851         Doxygen:                  ${DOXYGEN:-not found}
1852         xmlto:                    ${XMLTO:-not found}"
1853
1854 echo "
1855         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1856         gcc coverage profiling:   ${enable_compiler_coverage}
1857         Building embedded tests:  ${enable_embedded_tests}
1858         Building modular tests:   ${enable_modular_tests}
1859             - with GLib:          ${with_glib}
1860         Building verbose mode:    ${enable_verbose_mode}
1861         Building assertions:      ${enable_asserts}
1862         Building checks:          ${enable_checks}
1863         Building bus stats API:   ${enable_stats}
1864         Building SELinux support: ${have_selinux}
1865         Building inotify support: ${have_inotify}
1866         Building dnotify support: ${have_dnotify}
1867         Building kqueue support:  ${have_kqueue}
1868         Building systemd support: ${have_systemd}
1869         Building X11 code:        ${have_x11}
1870         Building Doxygen docs:    ${enable_doxygen_docs}
1871         Building XML docs:        ${enable_xml_docs}
1872         Building cache support:   ${enable_userdb_cache}
1873         Building launchd support: ${have_launchd}
1874         Init scripts style:       ${with_init_scripts}
1875         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1876         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1877         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1878         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1879         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1880         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1881         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1882         Console owner file:       ${have_console_owner_file}
1883         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1884         System bus user:          ${DBUS_USER}
1885         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1886         'make check' socket dir:  ${TEST_SOCKET_DIR}
1887 "
1888 if test x$have_launchd = xyes; then
1889         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1890 fi
1891 echo
1892
1893 if test x$enable_embedded_tests = xyes; then
1894         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1895 fi
1896 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1897         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1898 fi
1899 if test x$enable_compiler_coverage = xyes; then
1900         echo "NOTE: building with coverage profiling is definitely for developers only."
1901 fi
1902 if test x$enable_verbose_mode = xyes; then
1903         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1904 fi
1905 if test x$enable_asserts = xyes; then
1906         echo "NOTE: building with assertions increases library size and decreases performance."
1907 fi
1908 if test x$enable_checks = xno; then
1909         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1910 fi
1911
1912 if test "x$DBUS_HAVE_INT64" = x0; then
1913   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1914
1915   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1916   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1917   used if your compiler lacks support for 64-bit integers. Please report a bug
1918   with details of your platform and compiler.
1919
1920   This option is likely to be removed in future, unless the D-Bus developers
1921   receive reports that it is still needed.
1922   ])
1923 fi