configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [35])
  34 m4_define([glib_micro_version], [3])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADER([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153
 154     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 155     ;;
 156   *)
 157     glib_native_win32=no
 158     glib_pid_type=int
 159     ;;
 160 esac
 161 case $host in
 162   *-*-linux*)
 163     glib_os_linux=yes
 164     ;;
 165 esac
 166
 167 AC_MSG_RESULT([$glib_native_win32])
 168
 169 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 170
 171 glib_have_carbon=no
 172 AC_MSG_CHECKING([for Mac OS X Carbon support])
 173 AC_TRY_CPP([
 174 #include <Carbon/Carbon.h>
 175 #include <CoreServices/CoreServices.h>
 176 ], glib_have_carbon=yes)
 177
 178 AC_MSG_RESULT([$glib_have_carbon])
 179
 180 glib_have_cocoa=no
 181 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 182 AC_TRY_CPP([
 183 #include <Cocoa/Cocoa.h>
 184 #ifdef GNUSTEP_BASE_VERSION
 185 #error "Detected GNUstep, not Cocoa"
 186 #endif
 187 ], glib_have_cocoa=yes)
 188
 189 AC_MSG_RESULT([$glib_have_cocoa])
 190
 191 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 192 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 193 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 194 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 195 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 196 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 197
 198 AS_IF([test "$glib_native_win32" = "yes"], [
 199   AC_CHECK_TOOL(WINDRES, windres, no)
 200   if test "$WINDRES" = no; then
 201     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 202   fi
 203   AC_CHECK_TOOL(NM, nm, no)
 204   if test "$NM" = no; then
 205     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 206   fi
 207   AC_CHECK_TOOL(RANLIB, ranlib, :)
 208   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 209   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 210 ])
 211 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 212
 213 if test "$glib_native_win32" != yes; then
 214     # libtool option to control which symbols are exported
 215     # right now, symbols starting with _ are not exported
 216     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 217 else
 218     # We currently use .def files on Windows
 219     LIBTOOL_EXPORT_OPTIONS=
 220 fi
 221 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 222
 223 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 224   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 225   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 226 ])
 227
 228 if test "x$glib_have_cocoa" = "xyes"; then
 229   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 230   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 231 fi
 232
 233 gl_GLIBC21
 234 AS_IF([test "x$GLIBC21" = "xyes"], [
 235   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 236 ])
 237
 238 dnl declare --enable-* args and collect ac_help strings
 239 AC_ARG_ENABLE(debug,
 240               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 241                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 242               enable_debug=glib_debug_default)
 243
 244 AC_ARG_ENABLE(gc_friendly,
 245               [AS_HELP_STRING([--enable-gc-friendly],
 246                               [turn on garbage collector friendliness [default=no]])],,
 247               [enable_gc_friendly=no])
 248 AC_ARG_ENABLE(mem_pools,
 249               [AS_HELP_STRING([--disable-mem-pools],
 250                               [disable all glib memory pools])],,
 251               [disable_mem_pools=no])
 252 AC_ARG_ENABLE(rebuilds,
 253               [AS_HELP_STRING([--disable-rebuilds],
 254                               [disable all source autogeneration rules])],,
 255               [enable_rebuilds=yes])
 256 AC_ARG_ENABLE(modular_tests,
 257               AS_HELP_STRING([--disable-modular-tests],
 258                              [Disable build of test programs (default: no)]),,
 259               [enable_modular_tests=yes])
 260 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 261
 262 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 263 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 264   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 265   AC_MSG_RESULT([yes])
 266 ], [ AC_MSG_RESULT([no]) ])
 267
 268 AC_MSG_CHECKING([whether to disable memory pools])
 269 AS_IF([test "x$disable_mem_pools" = "xno"], [
 270   AC_MSG_RESULT([no])
 271 ], [
 272   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 273   AC_MSG_RESULT([yes])
 274 ])
 275
 276 dnl location to install runtime libraries, e.g. ../../lib to install
 277 dnl to /lib if libdir is /usr/lib
 278 AC_ARG_WITH(runtime-libdir,
 279            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 280                            [install runtime libraries relative to libdir])],
 281            [],
 282            [with_runtime_libdir=""])
 283 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 284 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 285 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 286 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 287 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 288
 289 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 290 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 291 AC_LANG_SAVE
 292 AC_LANG_CPLUSPLUS
 293 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 294 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 295 AC_LANG_RESTORE
 296
 297 AM_PROG_CC_STDC
 298 AM_PROG_CC_C_O
 299 AC_PROG_INSTALL
 300
 301 AC_SYS_LARGEFILE
 302
 303 PKG_PROG_PKG_CONFIG(0.16)
 304
 305 if test "x$enable_debug" = "xyes"; then
 306   if test x$cflags_set != xset ; then
 307       case " $CFLAGS " in
 308       *[[\ \    ]]-g[[\ \       ]]*) ;;
 309       *) CFLAGS="$CFLAGS -g" ;;
 310       esac
 311   fi
 312   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 313 else
 314   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 315
 316   if test "x$enable_debug" = "xno"; then
 317     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 318   fi
 319 fi
 320
 321 # Ensure MSVC-compatible struct packing convention is used when
 322 # compiling for Win32 with gcc.
 323 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 324 # gcc2 uses "-fnative-struct".
 325 if test x"$glib_native_win32" = xyes; then
 326   if test x"$GCC" = xyes; then
 327     msnative_struct=''
 328     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 329     if test -z "$ac_cv_prog_CC"; then
 330       our_gcc="$CC"
 331     else
 332       our_gcc="$ac_cv_prog_CC"
 333     fi
 334     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 335       2.)
 336         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 337           msnative_struct='-fnative-struct'
 338         fi
 339         ;;
 340       *)
 341         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 342           msnative_struct='-mms-bitfields'
 343         fi
 344         ;;
 345     esac
 346     if test x"$msnative_struct" = x ; then
 347       AC_MSG_RESULT([no way])
 348       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 349     else
 350       CFLAGS="$CFLAGS $msnative_struct"
 351       AC_MSG_RESULT([${msnative_struct}])
 352     fi
 353   fi
 354 fi
 355 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 356 AC_SUBST(GLIB_EXTRA_CFLAGS)
 357
 358 AC_EXEEXT
 359
 360 # define a MAINT-like variable REBUILD which is set if Perl
 361 # and awk are found, so autogenerated sources can be rebuilt
 362 AC_PROG_AWK
 363 AC_CHECK_PROGS(PERL, [perl5 perl])
 364 # We would like indent, but don't require it.
 365 AC_CHECK_PROG(INDENT, indent, indent)
 366 REBUILD=\#
 367 if test "x$enable_rebuilds" = "xyes" && \
 368      test -n "$PERL" && \
 369      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 370      test -n "$AWK" ; then
 371   REBUILD=
 372 fi
 373 AC_SUBST(REBUILD)
 374
 375 # Need full path to Perl for glib-mkenums
 376 #
 377 if test "x$PERL" != x ; then
 378   AC_PATH_PROG(PERL_PATH, [$PERL])
 379 fi
 380 if test "x$PERL_PATH" = x ; then
 381   PERL_PATH="/usr/bin/env perl"
 382 fi
 383 AC_SUBST(PERL_PATH)
 384
 385 # Need suitable python path for greport
 386 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 387
 388
 389 dnl ***********************
 390 dnl *** Tests for iconv ***
 391 dnl ***********************
 392 dnl
 393 dnl We do this before the gettext checks, to avoid distortion
 394
 395 dnl On Windows we use a native implementation
 396
 397 AS_IF([ test x"$glib_native_win32" = xyes], [
 398   with_libiconv=native
 399 ], [
 400   AC_ARG_WITH(libiconv,
 401               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 402                               [use the libiconv library])],,
 403               [with_libiconv=maybe])
 404
 405   found_iconv=no
 406   case $with_libiconv in
 407     maybe)
 408       # Check in the C library first
 409       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 410       # Check if we have GNU libiconv
 411       if test $found_iconv = "no"; then
 412         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 413       fi
 414       # Check if we have a iconv in -liconv, possibly from vendor
 415       if test $found_iconv = "no"; then
 416         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 417       fi
 418       ;;
 419     no)
 420       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 421       ;;
 422     gnu|yes)
 423       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 424       ;;
 425     native)
 426       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 427       ;;
 428   esac
 429
 430   if test "x$found_iconv" = "xno" ; then
 431      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 432   fi
 433 ])
 434
 435 AC_ARG_ENABLE(iconv-cache,
 436               [AS_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 437                               [cache iconv descriptors [default=auto]])],,
 438               [enable_iconv_cache=auto])
 439
 440 AC_MSG_CHECKING([whether to cache iconv descriptors])
 441 case $enable_iconv_cache in
 442   auto)
 443     if test $ac_cv_gnu_library_2_1 = yes; then
 444       enable_iconv_cache=no
 445     else
 446       enable_iconv_cache=yes
 447     fi
 448   ;;
 449   yes|no)
 450   ;;
 451   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 452   ;;
 453 esac
 454
 455 if test $enable_iconv_cache = yes; then
 456    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 457 fi
 458
 459 AC_MSG_RESULT($enable_iconv_cache)
 460
 461
 462 dnl
 463 dnl zlib support
 464 dnl
 465 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 466 AS_IF([test "x$found_zlib" = "xno"], [
 467   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 468   if test "x$found_zlib" = "xno" ; then
 469     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 470   fi
 471   ZLIB_LIBS='-lz'
 472   AC_SUBST(ZLIB_LIBS)
 473 ])
 474
 475 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 476 AC_SUBST(LIBFFI_CFLAGS)
 477 AC_SUBST(LIBFFI_LIBS)
 478
 479 dnl
 480 dnl gettext support
 481 dnl
 482
 483 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 484 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 485 GLIB_GNU_GETTEXT
 486
 487 if test "$gt_cv_have_gettext" != "yes" ; then
 488   AC_MSG_ERROR([
 489 *** You must have either have gettext support in your C library, or use the
 490 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 491 ])
 492 fi
 493
 494 LIBS="$INTLLIBS $LIBS"
 495
 496 GETTEXT_PACKAGE=glib20
 497 AC_SUBST(GETTEXT_PACKAGE)
 498 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 499   [Define the gettext package to be used])
 500
 501 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 502
 503 dnl
 504 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 505 dnl
 506
 507 AS_IF([test x"$glib_native_win32" != xyes], [
 508   if test x$with_libiconv != xno ; then
 509     case " $INTLLIBS " in
 510     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 511     *) ICONV_LIBS="-liconv" ;;
 512     esac
 513   fi
 514 ])
 515 AC_SUBST(ICONV_LIBS)
 516
 517 case $with_libiconv in
 518   gnu)
 519     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 520     ;;
 521   native)
 522     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 523     ;;
 524 esac
 525
 526 dnl Initialize libtool
 527 LT_PREREQ([2.2])
 528 LT_INIT([disable-static win32-dll])
 529 dnl when using libtool 2.x create libtool early, because it's used in configure
 530 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 531
 532
 533 AS_IF([test "$glib_native_win32" = "yes"], [
 534   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 535     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 536   fi
 537   if test x$enable_static = xyes; then
 538     glib_win32_static_compilation=yes
 539     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 540 #define GOBJECT_STATIC_COMPILATION 1"
 541     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 542   fi
 543 ])
 544 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 545
 546 dnl
 547 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 548 dnl
 549 AS_IF([test $cross_compiling != yes], [
 550     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 551     glib_save_LIBS=$LIBS
 552     LIBS="$LIBS -lm"
 553     AC_TRY_RUN([#include <math.h>
 554                  int main (void) { return (log(1) != log(1.)); }],
 555          AC_MSG_RESULT(none needed),
 556          glib_save_CFLAGS=$CFLAGS
 557          CFLAGS="$CFLAGS -std1"
 558          AC_TRY_RUN([#include <math.h>
 559                      int main (void) { return (log(1) != log(1.)); }],
 560              AC_MSG_RESULT(-std1),
 561              AC_MSG_RESULT()
 562              CFLAGS=$glib_save_CFLAGS
 563              AC_MSG_WARN(
 564                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 565          )
 566     )
 567     LIBS=$glib_save_LIBS
 568 ])
 569
 570 dnl NeXTStep cc seems to need this
 571 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 572 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 573   AC_MSG_RESULT(none needed),
 574   glib_save_CFLAGS=$CFLAGS
 575   CFLAGS="$CFLAGS -posix"
 576   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 577     AC_MSG_RESULT(-posix),
 578     AC_MSG_RESULT()
 579     CFLAGS=$glib_save_CFLAGS
 580     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 581
 582 # Checks for library functions.
 583 AC_FUNC_VPRINTF
 584 AC_FUNC_ALLOCA
 585 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 586 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 587
 588 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 589   [AC_TRY_LINK([#include <unistd.h>
 590     extern int __libc_enable_secure;],
 591     [return __libc_enable_secure;],
 592    glib_cv_have_libc_enable_secure=yes,
 593    glib_cv_have_libc_enable_secure=no)])
 594 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 595    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 596      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 597 ])
 598
 599 AC_CHECK_SIZEOF(char)
 600 AC_CHECK_SIZEOF(short)
 601 AC_CHECK_SIZEOF(long)
 602 AC_CHECK_SIZEOF(int)
 603 AC_CHECK_SIZEOF(void *)
 604 AC_CHECK_SIZEOF(long long)
 605 AC_CHECK_SIZEOF(__int64)
 606
 607 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 608   [AC_TRY_LINK([#include <signal.h>
 609      #include <sys/types.h>
 610      sig_atomic_t val = 42;],
 611     [return val == 42 ? 0 : 1],
 612    ac_cv_type_sig_atomic_t=yes,
 613    ac_cv_type_sig_atomic_t=no)])
 614 if test x$ac_cv_type_sig_atomic_t = xyes; then
 615    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 616      [Define if you have the 'sig_atomic_t' type.])
 617 fi
 618
 619 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 620   :
 621 else
 622   AC_MSG_ERROR([
 623 *** GLib requires a 64 bit type. You might want to consider
 624 *** using the GNU C compiler.
 625 ])
 626 fi
 627
 628 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 629         # long long is a 64 bit integer.
 630         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 631         AC_CACHE_VAL(glib_cv_long_long_format,[
 632                 for format in ll q I64; do
 633                   AC_TRY_RUN([#include <stdio.h>
 634                         int main()
 635                         {
 636                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 637                           char buffer[1000];
 638                           sprintf (buffer, "%${format}u", a);
 639                           sscanf (buffer, "%${format}u", &b);
 640                           exit (b!=a);
 641                         }
 642                         ],
 643                         [glib_cv_long_long_format=${format}
 644                         break],
 645                         [],[:])
 646                 done])
 647         AS_IF([ test -n "$glib_cv_long_long_format"], [
 648           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 649           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 650           if test x"$glib_cv_long_long_format" = xI64; then
 651             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 652           fi
 653         ], [AC_MSG_RESULT(none)])
 654 ],[ test x$ac_cv_sizeof___int64 = x8], [
 655         # __int64 is a 64 bit integer.
 656         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 657         # We know this is MSVCRT.DLL, and what the formats are
 658         glib_cv_long_long_format=I64
 659         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 660         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 661         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 662 ])
 663
 664 AC_C_CONST
 665
 666 dnl ok, here we try to check whether the systems prototypes for
 667 dnl malloc and friends actually match the prototypes provided
 668 dnl by gmem.h (keep in sync). i currently only know how to check
 669 dnl this reliably with gcc (-Werror), improvements for other
 670 dnl compilers are apprechiated.
 671 SANE_MALLOC_PROTOS=no
 672 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 673 glib_save_CFLAGS=$CFLAGS
 674 AS_IF([test "x$GCC" = "xyes"], [
 675   CFLAGS="$CFLAGS -Werror"
 676   AC_TRY_COMPILE([#include <stdlib.h>], [
 677     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 678     void* (*my_malloc_p)  (size_t)         = malloc;
 679     void  (*my_free_p)    (void*)          = free;
 680     void* (*my_realloc_p) (void*, size_t)  = realloc;
 681     my_calloc_p = 0;
 682     my_malloc_p = 0;
 683     my_free_p = 0;
 684     my_realloc_p = 0;
 685   ],
 686     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 687       [Define if you have correct malloc prototypes])
 688     SANE_MALLOC_PROTOS=yes)
 689 ])
 690 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 691 CFLAGS=$glib_save_CFLAGS
 692
 693 dnl
 694 dnl check in which direction the stack grows
 695 dnl
 696 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 697         AC_TRY_RUN([
 698         volatile int *a = 0, *b = 0;
 699         void foo (void);
 700         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 701         void foo (void) { volatile int x = 5; b = &x; }
 702         ],
 703         glib_cv_stack_grows=no
 704         ,
 705         glib_cv_stack_grows=yes
 706         ,)
 707 ])
 708
 709 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 710 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 711 dnl actually supported.
 712 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 713         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 714         __inline int foo () { return 0; }
 715         int main () { return foo (); }
 716         ]])],
 717         glib_cv_has__inline=yes
 718         ,
 719         glib_cv_has__inline=no
 720         ,)
 721 ])
 722 case x$glib_cv_has__inline in
 723 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 724 esac
 725 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 726         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 727         __inline__ int foo () { return 0; }
 728         int main () { return foo (); }
 729         ]])],
 730         glib_cv_has__inline__=yes
 731         ,
 732         glib_cv_has__inline__=no
 733         ,)
 734 ])
 735 case x$glib_cv_has__inline__ in
 736 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 737 esac
 738 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 739         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 740         #undef inline
 741         inline int foo () { return 0; }
 742         int main () { return foo (); }
 743         ]])],
 744         glib_cv_hasinline=yes
 745         ,
 746         glib_cv_hasinline=no
 747         ,)
 748 ])
 749 case x$glib_cv_hasinline in
 750 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 751 esac
 752
 753 # if we can use inline functions in headers
 754 AC_MSG_CHECKING(if inline functions in headers work)
 755 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 756 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 757 #  undef inline
 758 #  define inline __inline__
 759 #elif !defined (G_HAVE_INLINE)
 760 #  undef inline
 761 #  if defined (G_HAVE___INLINE__)
 762 #    define inline __inline__
 763 #  elif defined (G_HAVE___INLINE)
 764 #    define inline __inline
 765 #  endif
 766 #endif
 767
 768 int glib_test_func2 (int);
 769
 770 static inline int
 771 glib_test_func1 (void) {
 772   return glib_test_func2 (1);
 773 }
 774
 775 int
 776 main (void) {
 777   int i = 1;
 778 }]])],[g_can_inline=yes],[g_can_inline=no])
 779 AC_MSG_RESULT($g_can_inline)
 780
 781 dnl *** check for working do while(0) macros ***
 782 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 783         AC_TRY_COMPILE([],[
 784         #define STMT_START do
 785         #define STMT_END while(0)
 786         #define STMT_TEST STMT_START { i = 0; } STMT_END
 787         int main(void) { int i = 1; STMT_TEST; return i; }],
 788         [g_cv_support_dowhile_macros=yes],
 789         [g_cv_support_dowhile_macros=no],
 790         [g_cv_support_dowhile_macros=yes])
 791 ])
 792 if test x$g_cv_support_dowhile_macros = xyes; then
 793   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 794 fi
 795
 796 # check for flavours of varargs macros
 797 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 798 AC_TRY_COMPILE([],[
 799 int a(int p1, int p2, int p3);
 800 #define call_a(...) a(1,__VA_ARGS__)
 801 call_a(2,3);
 802 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 803 AC_MSG_RESULT($g_have_iso_c_varargs)
 804
 805 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 806 AS_IF([test "$CXX" = ""], [
 807 dnl No C++ compiler
 808   g_have_iso_cxx_varargs=no
 809 else
 810   AC_LANG_CPLUSPLUS
 811   AC_TRY_COMPILE([],[
 812 int a(int p1, int p2, int p3);
 813 #define call_a(...) a(1,__VA_ARGS__)
 814 call_a(2,3);
 815 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 816   AC_LANG_C
 817 ])
 818 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 819
 820 AC_MSG_CHECKING(for GNUC varargs macros)
 821 AC_TRY_COMPILE([],[
 822 int a(int p1, int p2, int p3);
 823 #define call_a(params...) a(1,params)
 824 call_a(2,3);
 825 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 826 AC_MSG_RESULT($g_have_gnuc_varargs)
 827
 828 # check for GNUC visibility support
 829 AC_MSG_CHECKING(for GNUC visibility attribute)
 830 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 831 void
 832 __attribute__ ((visibility ("hidden")))
 833      f_hidden (void)
 834 {
 835 }
 836 void
 837 __attribute__ ((visibility ("internal")))
 838      f_internal (void)
 839 {
 840 }
 841 void
 842 __attribute__ ((visibility ("protected")))
 843      f_protected (void)
 844 {
 845 }
 846 void
 847 __attribute__ ((visibility ("default")))
 848      f_default (void)
 849 {
 850 }
 851 int main (void)
 852 {
 853         f_hidden();
 854         f_internal();
 855         f_protected();
 856         f_default();
 857         return 0;
 858 }
 859 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 860 AC_MSG_RESULT($g_have_gnuc_visibility)
 861 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 862
 863 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 864 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 865 #else
 866 # include "error: this is not Sun Studio."
 867 #endif
 868 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 869 AC_MSG_RESULT($g_have_sunstudio_visibility)
 870 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 871
 872 # check for bytesex stuff
 873 AC_C_BIGENDIAN
 874 if test x$ac_cv_c_bigendian = xuniversal ; then
 875 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 876 #else
 877 #error Not a big endian.
 878 #endif],
 879     ac_cv_c_bigendian=yes
 880     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 881 #else
 882 #error Not a little endian.
 883 #endif],
 884     ac_cv_c_bigendian=no
 885     ,AC_MSG_WARN([Could not determine endianness.])))
 886 fi
 887
 888
 889 # check for header files
 890 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 891 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 892 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 893 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 894 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 895 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 896 AC_CHECK_HEADERS([linux/magic.h])
 897 AC_CHECK_HEADERS([sys/prctl.h])
 898
 899 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 900 [#if HAVE_SYS_PARAM_H
 901  #include <sys/param.h>
 902  #endif
 903 ])
 904
 905 AC_CHECK_HEADERS([xlocale.h])
 906
 907 # check for structure fields
 908 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 909 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 910 #include <sys/stat.h>
 911 #include <unistd.h>
 912 #ifdef HAVE_SYS_STATFS_H
 913 #include <sys/statfs.h>
 914 #endif
 915 #ifdef HAVE_SYS_PARAM_H
 916 #include <sys/param.h>
 917 #endif
 918 #ifdef HAVE_SYS_MOUNT_H
 919 #include <sys/mount.h>
 920 #endif])
 921 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 922 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 923 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 924 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 925
 926 AC_STRUCT_DIRENT_D_TYPE
 927
 928 # Checks for libcharset
 929 AM_LANGINFO_CODESET
 930 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 931 AC_CHECK_FUNCS(setlocale)
 932
 933 # check additional type sizes
 934 AC_CHECK_SIZEOF(size_t)
 935
 936 dnl Try to figure out whether gsize, gssize should be long or int
 937 AC_MSG_CHECKING([for the appropriate definition for size_t])
 938
 939 case $ac_cv_sizeof_size_t in
 940   $ac_cv_sizeof_short)
 941       glib_size_type=short
 942       ;;
 943   $ac_cv_sizeof_int)
 944       glib_size_type=int
 945       ;;
 946   $ac_cv_sizeof_long)
 947       glib_size_type=long
 948       ;;
 949   $ac_cv_sizeof_long_long)
 950       glib_size_type='long long'
 951       ;;
 952   $ac_cv_sizeof__int64)
 953       glib_size_type='__int64'
 954       ;;
 955   *)  AC_MSG_ERROR([No type matching size_t in size])
 956       ;;
 957 esac
 958
 959 dnl If int/long are the same size, we see which one produces
 960 dnl warnings when used in the location as size_t. (This matters
 961 dnl on AIX with xlc)
 962 dnl
 963 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 964        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 965   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 966 #if defined(_AIX) && !defined(__GNUC__)
 967 #pragma options langlvl=stdc89
 968 #endif
 969 #include <stddef.h>
 970 int main ()
 971 {
 972   size_t s = 1;
 973   unsigned int *size_int = &s;
 974   return (int)*size_int;
 975 }
 976     ]])],glib_size_type=int,
 977       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 978 #if defined(_AIX) && !defined(__GNUC__)
 979 #pragma options langlvl=stdc89
 980 #endif
 981 #include <stddef.h>
 982 int main ()
 983 {
 984    size_t s = 1;
 985    unsigned long *size_long = &s;
 986    return (int)*size_long;
 987 }
 988         ]])],glib_size_type=long)])
 989 ])
 990
 991 AC_MSG_RESULT(unsigned $glib_size_type)
 992
 993 # Check for some functions
 994 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 995 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
 996 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 997 # Check for high-resolution sleep functions
 998 AC_CHECK_FUNCS(splice)
 999 AC_CHECK_FUNCS(prlimit)
1000
1001 # To avoid finding a compatibility unusable statfs, which typically
1002 # successfully compiles, but warns to use the newer statvfs interface:
1003 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1004 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1005
1006 AC_MSG_CHECKING([whether to use statfs or statvfs])
1007 # Some systems have both statfs and statvfs, pick the most "native" for these
1008 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1009    [
1010    # on solaris and irix, statfs doesn't even have the f_bavail field
1011    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1012       [ac_cv_func_statfs=no],
1013    # else, at least on linux, statfs is the actual syscall
1014       [ac_cv_func_statvfs=no])
1015    ])
1016
1017 AS_IF([test x$ac_cv_func_statfs = xyes],
1018       [
1019          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1020          AC_MSG_RESULT([statfs])
1021       ],
1022       [test x$ac_cv_func_statvfs = xyes],
1023       [
1024          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1025          AC_MSG_RESULT([statvfs])
1026       ],
1027       [  AC_MSG_RESULT([neither])])
1028
1029 AC_CHECK_HEADERS(crt_externs.h)
1030 AC_CHECK_FUNCS(_NSGetEnviron)
1031
1032 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1033
1034 AC_FUNC_VSNPRINTF_C99
1035 AC_FUNC_PRINTF_UNIX98
1036
1037 # Internet address families
1038 if test $glib_native_win32 = yes; then
1039   glib_inet_includes=["
1040 #include <winsock2.h>
1041   "]
1042 else
1043   glib_inet_includes=["
1044 #include <sys/types.h>
1045 #include <sys/socket.h>
1046   "]
1047 fi
1048
1049 glib_failed=false
1050 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1051 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1052 # winsock defines this even though it doesn't support it
1053 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1054 if $glib_failed ; then
1055   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1056 fi
1057
1058 glib_failed=false
1059 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1060 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1061 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1062 if $glib_failed ; then
1063   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1064 fi
1065
1066 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1067 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1068
1069 AS_IF([test $glib_native_win32 = no], [
1070   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1071   NETWORK_LIBS=""
1072   AC_MSG_CHECKING([for res_query])
1073   AC_TRY_LINK([#include <sys/types.h>
1074                #include <netinet/in.h>
1075                #include <arpa/nameser.h>
1076                #include <resolv.h>
1077               ],[
1078                res_query("test", 0, 0, (void *)0, 0);
1079               ],[AC_MSG_RESULT([yes])],
1080               [save_libs="$LIBS"
1081                LIBS="-lresolv $LIBS"
1082                AC_TRY_LINK([#include <sys/types.h>
1083                             #include <netinet/in.h>
1084                             #include <arpa/nameser.h>
1085                             #include <resolv.h>
1086                            ],[
1087                             res_query("test", 0, 0, (void *)0, 0);
1088                            ],[AC_MSG_RESULT([in -lresolv])
1089                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1090                            [LIBS="-lbind $save_libs"
1091                             AC_TRY_LINK([#include <resolv.h>],
1092                                         [res_query("test", 0, 0, (void *)0, 0);],
1093                                         [AC_MSG_RESULT([in -lbind])
1094                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1095                                         [AC_MSG_ERROR(not found)])])
1096                LIBS="$save_libs"])
1097   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1098                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1099                                         [AC_MSG_ERROR(Could not find socket())]))
1100 ])
1101 AC_SUBST(NETWORK_LIBS)
1102
1103 AC_CHECK_HEADER([linux/netlink.h],
1104                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1105                 [#include <sys/socket.h>])
1106 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1107
1108 AC_CHECK_TYPE([struct ip_mreqn], [
1109               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1110               [#include <netinet/in.h>])
1111
1112 case $host in
1113   *-*-solaris* )
1114      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1115      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1116      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1117      ;;
1118 esac
1119
1120 dnl
1121 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1122 dnl
1123 AS_IF([test "$ac_cv_func_statfs" = yes], [
1124   AC_MSG_CHECKING([number of arguments to statfs()])
1125   AC_TRY_COMPILE([#include <unistd.h>
1126   #ifdef HAVE_SYS_PARAM_H
1127   #include <sys/param.h>
1128   #endif
1129   #ifdef HAVE_SYS_VFS_H
1130   #include <sys/vfs.h>
1131   #endif
1132   #ifdef HAVE_SYS_MOUNT_H
1133   #include <sys/mount.h>
1134   #endif
1135   #ifdef HAVE_SYS_STATFS_H
1136   #include <sys/statfs.h>
1137   #endif], [struct statfs st;
1138   statfs(NULL, &st);],[
1139     AC_MSG_RESULT([2])
1140     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1141     AC_TRY_COMPILE([#include <unistd.h>
1142   #ifdef HAVE_SYS_PARAM_H
1143   #include <sys/param.h>
1144   #endif
1145   #ifdef HAVE_SYS_VFS_H
1146   #include <sys/vfs.h>
1147   #endif
1148   #ifdef HAVE_SYS_MOUNT_H
1149   #include <sys/mount.h>
1150   #endif
1151   #ifdef HAVE_SYS_STATFS_H
1152   #include <sys/statfs.h>
1153   #endif], [struct statfs st;
1154   statfs(NULL, &st, sizeof (st), 0);],[
1155       AC_MSG_RESULT([4])
1156       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1157       AC_MSG_RESULT(unknown)
1158       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1159 ])
1160
1161 #
1162 # Check whether to use an included printf
1163 #
1164
1165 AC_ARG_ENABLE(included-printf,
1166               [AS_HELP_STRING([--enable-included-printf],
1167                               [use included printf [default=auto]])],
1168               enable_included_printf="$enableval")
1169
1170 need_included_printf=no
1171 if test "x$enable_included_printf" = "xyes" ; then
1172   need_included_printf=yes
1173 fi
1174 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1175   need_included_printf=yes
1176 fi
1177 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1178   need_included_printf=yes
1179 fi
1180 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1181    test -z "$glib_cv_long_long_format" ; then
1182   need_included_printf=yes
1183 fi
1184
1185 if test "x$enable_included_printf" = "xno" &&
1186    test "x$need_included_printf" = "xyes" ; then
1187   AC_MSG_ERROR([
1188 *** Your C library's printf doesn't appear to have the features that
1189 *** GLib needs, but you specified --enable-included-printf=no.])
1190 fi
1191
1192 enable_included_printf=$need_included_printf
1193
1194 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1195 AS_IF([test "$enable_included_printf" != "yes"], [
1196   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1197 ], [
1198   if test -z "$glib_cv_long_long_format" ; then
1199     glib_cv_long_long_format="ll"
1200   fi
1201   AC_DEFINE(HAVE_VASPRINTF,1)
1202 ])
1203
1204 # Checks needed for gnulib vasnprintf
1205 bh_C_SIGNED
1206 jm_AC_TYPE_LONG_LONG
1207 gt_TYPE_LONGDOUBLE
1208 gt_TYPE_WCHAR_T
1209 gt_TYPE_WINT_T
1210 AC_TYPE_SIZE_T
1211 AC_CHECK_TYPES(ptrdiff_t)
1212 jm_AC_TYPE_INTMAX_T
1213 AC_CHECK_FUNCS([snprintf wcslen])
1214 AC_FUNC_SNPRINTF_C99
1215
1216 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1217 # The check is borrowed from the PERL Configure script.
1218 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1219   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1220     glib_cv_working_bcopy,[AC_TRY_RUN([
1221       int main() {
1222         char buf[128], abc[128], *b;
1223         int len, off, align;
1224         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1225         for (align = 7; align >= 0; align--) {
1226           for (len = 36; len; len--) {
1227             b = buf+align; bcopy(abc, b, len);
1228             for (off = 1; off <= len; off++) {
1229               bcopy(b, b+off, len); bcopy(b+off, b, len);
1230                 if (bcmp(b, abc, len)) return(1);
1231             }
1232           }
1233         }
1234         return(0);
1235       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1236
1237   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1238   if test "$glib_cv_working_bcopy" = "yes"; then
1239     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1240   fi
1241 ])
1242
1243 # Check if <sys/select.h> needs to be included for fd_set
1244 AC_MSG_CHECKING([for fd_set])
1245 AC_TRY_COMPILE([#include <sys/types.h>],
1246         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1247 AS_IF([test "$gtk_ok" = "yes"], [
1248     AC_MSG_RESULT([yes, found in sys/types.h])
1249 ], [
1250     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1251     if test "$gtk_ok" = "yes"; then
1252         # *** FIXME: give it a different name
1253         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1254         AC_MSG_RESULT([yes, found in sys/select.h])
1255     else
1256         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1257         AC_MSG_RESULT(no)
1258     fi
1259 ])
1260
1261 dnl *** check for sane realloc() ***
1262 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1263         AC_TRY_RUN([#include <stdlib.h>
1264         int main() {
1265           return realloc (0, sizeof (int)) == 0;
1266         }],
1267         [glib_cv_sane_realloc=yes],
1268         [glib_cv_sane_realloc=no],
1269         [glib_cv_sane_realloc=yes])
1270 ])
1271 AS_IF([test x$glib_cv_sane_realloc = xyes], [
1272   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1273 ])
1274
1275 dnl Check for nl_langinfo and CODESET
1276 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1277         AC_TRY_COMPILE([#include <langinfo.h>],
1278                 [char *codeset = nl_langinfo (CODESET);],
1279                 [glib_cv_langinfo_codeset=yes],
1280                 [glib_cv_langinfo_codeset=no])])
1281 if test x$glib_cv_langinfo_codeset = xyes; then
1282   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1283 fi
1284
1285 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1286 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1287         AC_TRY_COMPILE([#include <langinfo.h>],
1288                 [char *str;
1289                  str = nl_langinfo (PM_STR);
1290                  str = nl_langinfo (D_T_FMT);
1291                  str = nl_langinfo (D_FMT);
1292                  str = nl_langinfo (T_FMT);
1293                  str = nl_langinfo (T_FMT_AMPM);
1294                  str = nl_langinfo (MON_1);
1295                  str = nl_langinfo (ABMON_12);
1296                  str = nl_langinfo (DAY_1);
1297                  str = nl_langinfo (ABDAY_7);],
1298                 [glib_cv_langinfo_time=yes],
1299                 [glib_cv_langinfo_time=no])])
1300 if test x$glib_cv_langinfo_time = xyes; then
1301   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1302 fi
1303
1304 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1305 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1306         AC_TRY_COMPILE([#include <langinfo.h>],
1307                 [char *str;
1308                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1309                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1310                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1311                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1312                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1313                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1314                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1315                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1316                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1317                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1318                 [glib_cv_langinfo_outdigit=yes],
1319                 [glib_cv_langinfo_outdigit=no])])
1320 if test x$glib_cv_langinfo_outdigit = xyes; then
1321   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1322 fi
1323
1324 dnl ****************************************
1325 dnl *** posix_memalign                   ***
1326 dnl ****************************************
1327 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1328 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1329     glib_cv_compliant_posix_memalign=0
1330     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1331         AC_TRY_RUN([
1332                 #define _XOPEN_SOURCE 600
1333                 #include <stdlib.h> /* posix_memalign() should be defined here */
1334                 /* some systems break if #include <malloc.h> used */
1335                 static void test_memalign (size_t boundary, size_t size) {
1336                     void *mem = 0;
1337                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1338                         exit (1);
1339                     else
1340                       free (mem);
1341                 }
1342                 int main() {
1343                     test_memalign (  128,   128 - 2 * sizeof (void*));
1344                     test_memalign (  256,   256 - 2 * sizeof (void*));
1345                     test_memalign (  512,   512 - 2 * sizeof (void*));
1346                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1347                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1348                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1349                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1350                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1351                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1352                     exit (0); /* success */
1353                 }
1354                 ],
1355             [glib_cv_compliant_posix_memalign=1], [], [:])
1356       :
1357     fi
1358     ])
1359 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1360     AC_MSG_RESULT(yes)
1361     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1362 ], [
1363     AC_MSG_RESULT(no)
1364 ])
1365
1366
1367 dnl ****************************************
1368 dnl *** strlcpy/strlcat                  ***
1369 dnl ****************************************
1370 # Check for strlcpy
1371 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1372 AC_TRY_RUN([#include <stdlib.h>
1373 #include <string.h>
1374 int main() {
1375   char p[10];
1376   (void) strlcpy (p, "hi", 10);
1377   if (strlcat (p, "bye", 0) != 3)
1378     return 1;
1379   return 0;
1380 }], glib_cv_have_strlcpy=yes,
1381     glib_cv_have_strlcpy=no,
1382     glib_cv_have_strlcpy=no)])
1383 if test "$glib_cv_have_strlcpy" = "yes"; then
1384     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1385 fi
1386
1387
1388 dnl **********************
1389 dnl *** va_copy checks ***
1390 dnl **********************
1391 dnl we currently check for all three va_copy possibilities, so we get
1392 dnl all results in config.log for bug reports.
1393 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1394         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1395 #include <stdlib.h>
1396         void f (int i, ...) {
1397         va_list args1, args2;
1398         va_start (args1, i);
1399         va_copy (args2, args1);
1400         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1401           exit (1);
1402         va_end (args1); va_end (args2);
1403         }
1404         int main() {
1405           f (0, 42);
1406           return 0;
1407         }]])],
1408         [glib_cv_va_copy=yes],
1409         [glib_cv_va_copy=no])
1410 ])
1411 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1412         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1413 #include <stdlib.h>
1414         void f (int i, ...) {
1415         va_list args1, args2;
1416         va_start (args1, i);
1417         __va_copy (args2, args1);
1418         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1419           exit (1);
1420         va_end (args1); va_end (args2);
1421         }
1422         int main() {
1423           f (0, 42);
1424           return 0;
1425         }]])],
1426         [glib_cv___va_copy=yes],
1427         [glib_cv___va_copy=no])
1428 ])
1429
1430 if test "x$glib_cv_va_copy" = "xyes"; then
1431   g_va_copy_func=va_copy
1432 else if test "x$glib_cv___va_copy" = "xyes"; then
1433   g_va_copy_func=__va_copy
1434 fi
1435 fi
1436
1437 if test -n "$g_va_copy_func"; then
1438   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1439 fi
1440
1441 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1442         AC_TRY_RUN([#include <stdarg.h>
1443 #include <stdlib.h>
1444         void f (int i, ...) {
1445         va_list args1, args2;
1446         va_start (args1, i);
1447         args2 = args1;
1448         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1449           exit (1);
1450         va_end (args1); va_end (args2);
1451         }
1452         int main() {
1453           f (0, 42);
1454           return 0;
1455         }],
1456         [glib_cv_va_val_copy=yes],
1457         [glib_cv_va_val_copy=no],
1458         [glib_cv_va_val_copy=yes])
1459 ])
1460
1461 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1462   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1463 ])
1464
1465 dnl ***********************
1466 dnl *** g_module checks ***
1467 dnl ***********************
1468 G_MODULE_LIBS=
1469 G_MODULE_LIBS_EXTRA=
1470 G_MODULE_PLUGIN_LIBS=
1471 if test x"$glib_native_win32" = xyes; then
1472   dnl No use for this on Win32
1473   G_MODULE_LDFLAGS=
1474 else
1475   export SED
1476   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1477 fi
1478 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1479 G_MODULE_NEED_USCORE=0
1480 G_MODULE_BROKEN_RTLD_GLOBAL=0
1481 G_MODULE_HAVE_DLERROR=0
1482 dnl *** force native WIN32 shared lib loader
1483 if test -z "$G_MODULE_IMPL"; then
1484   case "$host" in
1485   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1486   esac
1487 fi
1488 dnl *** force native AIX library loader
1489 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1490 if test -z "$G_MODULE_IMPL"; then
1491   case "$host" in
1492   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1493   esac
1494 fi
1495 dnl *** dlopen() and dlsym() in system libraries
1496 AS_IF([ test -z "$G_MODULE_IMPL"], [
1497         AC_CHECK_FUNC(dlopen,
1498                       [AC_CHECK_FUNC(dlsym,
1499                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1500                       [])
1501 ])
1502 dnl *** load_image (BeOS)
1503 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1504   AC_CHECK_LIB(root, load_image,
1505       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1506       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1507       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1508       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1509       [])
1510 ])
1511 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1512 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1513         AC_CHECK_FUNC(NSLinkModule,
1514                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1515                        G_MODULE_NEED_USCORE=1],
1516                       [])
1517 ])
1518 dnl *** dlopen() and dlsym() in libdl
1519 AS_IF([ test -z "$G_MODULE_IMPL"], [
1520         AC_CHECK_LIB(dl, dlopen,
1521                      [AC_CHECK_LIB(dl, dlsym,
1522                                    [G_MODULE_LIBS=-ldl
1523                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1524                      [])
1525 ])
1526 dnl *** shl_load() in libdld (HP-UX)
1527 AS_IF([ test -z "$G_MODULE_IMPL"], [
1528         AC_CHECK_LIB(dld, shl_load,
1529                 [G_MODULE_LIBS=-ldld
1530                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1531                 [])
1532 ])
1533 dnl *** additional checks for G_MODULE_IMPL_DL
1534 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1535         LIBS_orig="$LIBS"
1536         LDFLAGS_orig="$LDFLAGS"
1537         LIBS="$G_MODULE_LIBS $LIBS"
1538         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1539 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1540         echo "void glib_plugin_test(void) { }" > plugin.c
1541         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1542                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1543         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1544                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1545                 -shrext ".o" -avoid-version plugin.lo \
1546                 -rpath /dont/care >/dev/null 2>&1
1547         eval `./libtool --config | grep ^objdir`
1548         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1549                 glib_cv_rtldglobal_broken,[
1550                 AC_TRY_RUN([
1551 #include <dlfcn.h>
1552 #ifndef RTLD_GLOBAL
1553 #  define RTLD_GLOBAL 0
1554 #endif
1555 #ifndef RTLD_LAZY
1556 #  define RTLD_LAZY 0
1557 #endif
1558 int glib_plugin_test;
1559 int main () {
1560     void *handle, *global, *local;
1561     global = &glib_plugin_test;
1562     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1563     if (!handle) return 0;
1564     local = dlsym (handle, "glib_plugin_test");
1565     return global == local;
1566 }                       ],
1567                         [glib_cv_rtldglobal_broken=no],
1568                         [glib_cv_rtldglobal_broken=yes],
1569                         [glib_cv_rtldglobal_broken=no])
1570                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1571                 rmdir ${objdir} 2>/dev/null
1572         ])
1573         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1574                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1575         else
1576                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1577         fi
1578 dnl *** check whether we need preceeding underscores
1579         AC_CACHE_CHECK([for preceeding underscore in symbols],
1580                 glib_cv_uscore,[
1581                 AC_TRY_RUN([#include <dlfcn.h>
1582                 int glib_underscore_test (void) { return 42; }
1583                 int main() {
1584                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1585                   handle = dlopen ((void*)0, 0);
1586                   if (handle) {
1587                     f1 = dlsym (handle, "glib_underscore_test");
1588                     f2 = dlsym (handle, "_glib_underscore_test");
1589                   } return (!f2 || f1);
1590                 }],
1591                         [glib_cv_uscore=yes],
1592                         [glib_cv_uscore=no],
1593                         [])
1594                 rm -f plugin.c plugin.$ac_objext plugin.lo
1595         ])
1596         GLIB_ASSERT_SET(glib_cv_uscore)
1597         if test "x$glib_cv_uscore" = "xyes"; then
1598                 G_MODULE_NEED_USCORE=1
1599         else
1600                 G_MODULE_NEED_USCORE=0
1601         fi
1602
1603         LDFLAGS="$LDFLAGS_orig"
1604 dnl *** check for having dlerror()
1605         AC_CHECK_FUNC(dlerror,
1606                 [G_MODULE_HAVE_DLERROR=1],
1607                 [G_MODULE_HAVE_DLERROR=0])
1608         LIBS="$LIBS_orig"
1609 ])
1610 dnl *** done, have we got an implementation?
1611 if test -z "$G_MODULE_IMPL"; then
1612         G_MODULE_IMPL=0
1613         G_MODULE_SUPPORTED=false
1614 else
1615         G_MODULE_SUPPORTED=true
1616 fi
1617
1618 AC_MSG_CHECKING(for the suffix of module shared libraries)
1619 export SED
1620 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1621 eval $shrext_cmds
1622 module=yes eval std_shrext=$shrext_cmds
1623 # chop the initial dot
1624 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1625 AC_MSG_RESULT(.$glib_gmodule_suffix)
1626 # any reason it may fail?
1627 if test "x$glib_gmodule_suffix" = x; then
1628         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1629 fi
1630
1631 AC_SUBST(G_MODULE_SUPPORTED)
1632 AC_SUBST(G_MODULE_IMPL)
1633 AC_SUBST(G_MODULE_LIBS)
1634 AC_SUBST(G_MODULE_LIBS_EXTRA)
1635 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1636 AC_SUBST(G_MODULE_LDFLAGS)
1637 AC_SUBST(G_MODULE_HAVE_DLERROR)
1638 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1639 AC_SUBST(G_MODULE_NEED_USCORE)
1640 AC_SUBST(GLIB_DEBUG_FLAGS)
1641
1642 dnl **********************
1643 dnl *** g_spawn checks ***
1644 dnl **********************
1645
1646 AC_MSG_CHECKING(for gspawn implementation)
1647 case "$host" in
1648   *-*-mingw*)
1649     GSPAWN=gspawn-win32.lo
1650     ;;
1651   *)
1652     GSPAWN=gspawn.lo
1653     ;;
1654 esac
1655 AC_MSG_RESULT($GSPAWN)
1656 AC_SUBST(GSPAWN)
1657
1658 dnl *************************
1659 dnl *** GIOChannel checks ***
1660 dnl *************************
1661
1662 AC_MSG_CHECKING(for GIOChannel implementation)
1663 case "$host" in
1664   *-*-mingw*)
1665     GIO=giowin32.lo
1666     ;;
1667   *)
1668     GIO=giounix.lo
1669     ;;
1670 esac
1671 AC_MSG_RESULT($GIO)
1672 AC_SUBST(GIO)
1673
1674 dnl *********************************
1675 dnl *** Directory for GIO modules ***
1676 dnl *********************************
1677
1678 AC_ARG_WITH(gio-module-dir,
1679            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1680                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1681            [],
1682            [with_gio_module_dir='${libdir}/gio/modules'])
1683 GIO_MODULE_DIR=$with_gio_module_dir
1684 AC_SUBST(GIO_MODULE_DIR)
1685
1686 dnl **********************************
1687 dnl *** Check for libselinux (GIO) ***
1688 dnl **********************************
1689 AC_ARG_ENABLE(selinux,
1690               AS_HELP_STRING([--disable-selinux],
1691                              [build without selinux support]))
1692 msg_selinux=no
1693 SELINUX_LIBS=
1694 AS_IF([ test "x$enable_selinux" != "xno"], [
1695
1696  AC_CHECK_LIB(selinux, is_selinux_enabled,
1697    [AC_CHECK_HEADERS(selinux/selinux.h,
1698      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1699        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1700         SELINUX_LIBS="-lselinux"
1701         msg_selinux=yes])
1702      ])
1703    ])
1704 ])
1705 AC_SUBST(SELINUX_LIBS)
1706
1707 dnl *****************************
1708 dnl ** Check for inotify (GIO) **
1709 dnl *****************************
1710 inotify_support=no
1711 AC_CHECK_HEADERS([sys/inotify.h],
1712 [
1713         inotify_support=yes
1714         AC_CHECK_FUNCS(inotify_init1)
1715 ])
1716
1717 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1718
1719 dnl ****************************
1720 dnl ** Check for kqueue (GIO) **
1721 dnl ****************************
1722 kqueue_support=no
1723 AC_CHECK_HEADERS([sys/event.h],
1724 [
1725         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1726 ])
1727
1728 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1729
1730 dnl *********************************
1731 dnl ** Check for Solaris FEN (GIO) **
1732 dnl *********************************
1733 fen_support=no
1734 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1735 #include <port.h>
1736 #ifndef PORT_SOURCE_FILE
1737 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1738 #endif
1739 int main() { return 0; } ]])],
1740 [
1741         fen_support=yes
1742 ],)
1743
1744 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1745
1746 dnl ****************************
1747 dnl *** Checks for FAM (GIO) ***
1748 dnl ****************************
1749
1750 should_disable_fam=no
1751
1752 AC_ARG_ENABLE(fam,
1753               AS_HELP_STRING([--disable-fam],
1754                              [don't use fam for file system monitoring]),
1755                          [
1756                                 if test "x$enable_fam" = "xno"; then
1757                                         should_disable_fam=yes
1758                                 fi
1759                          ]
1760                          )
1761 fam_support=no
1762 FAM_LIBS=
1763 if test "x$should_disable_fam" = "xno"; then
1764 AC_CHECK_LIB(fam, FAMOpen,
1765   [AC_CHECK_HEADERS(fam.h,
1766     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1767      AC_CHECK_LIB(fam, FAMNoExists,
1768                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1769      FAM_LIBS="-lfam"]
1770      fam_support=yes,
1771     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1772   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1773 AC_SUBST(FAM_LIBS)
1774 fi
1775 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1776
1777
1778 dnl *****************************
1779 dnl *** Check for xattr (GIO) ***
1780 dnl *****************************
1781 AC_ARG_ENABLE(xattr,
1782               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1783 msg_xattr=no
1784 XATTR_LIBS=
1785 AS_IF([ test "x$enable_xattr" != "xno"], [
1786
1787 dnl either glibc or libattr can provide xattr support
1788
1789 dnl for both of them, we check for getxattr being in
1790 dnl the library and a valid xattr header.
1791
1792 dnl try glibc
1793  AC_CHECK_LIB(c, getxattr,
1794    [AC_CHECK_HEADERS(sys/xattr.h,
1795      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1796       msg_xattr=yes])
1797    ])
1798
1799   AS_IF([ test "x$msg_xattr" != "xyes"], [
1800 dnl   failure. try libattr
1801    AC_CHECK_LIB(attr, getxattr,
1802       [AC_CHECK_HEADERS(attr/xattr.h,
1803        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1804         XATTR_LIBS="-lattr"
1805         msg_xattr=yes])
1806       ])
1807   ])
1808
1809   AS_IF([ test "x$msg_xattr" = "xyes"], [
1810     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1811     AC_TRY_COMPILE([
1812       #include <stdio.h>
1813       #ifdef HAVE_SYS_TYPES_H
1814       #include <sys/types.h>
1815       #endif
1816       #ifdef HAVE_SYS_XATTR_H
1817       #include <sys/xattr.h>
1818       #elif HAVE_ATTR_XATTR_H
1819       #include <attr/xattr.h>
1820       #endif
1821     ],
1822     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1823     [
1824       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1825       AC_MSG_RESULT([yes])
1826     ],
1827     [AC_MSG_RESULT([no])]
1828     )
1829   ])
1830 ])
1831 AC_SUBST(XATTR_LIBS)
1832
1833 dnl ************************
1834 dnl *** check for libelf ***
1835 dnl ************************
1836 AC_ARG_ENABLE(libelf,
1837               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1838 AS_IF([ test "x$enable_libelf" != "xno"],[
1839 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1840 AS_IF([ test $have_libelf = maybe ], [
1841   glib_save_LIBS=$LIBS
1842   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1843   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1844   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1845   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1846   LIBS=$glib_save_LIBS
1847
1848   if test $have_libelf != no; then
1849     LIBELF_LIBS=-lelf
1850     have_libelf=yes
1851   fi
1852 ])
1853 ])
1854
1855 if test x$have_libelf = xyes; then
1856   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1857 fi
1858
1859 dnl ****************************************
1860 dnl *** platform dependent source checks ***
1861 dnl ****************************************
1862
1863 AC_MSG_CHECKING(for platform-dependent source)
1864 case "$host" in
1865   *-*-cygwin*|*-*-mingw*)
1866     PLATFORMDEP=gwin32.lo
1867     ;;
1868   *)
1869     PLATFORMDEP=
1870     ;;
1871 esac
1872 AC_MSG_RESULT($PLATFORMDEP)
1873 AC_SUBST(PLATFORMDEP)
1874
1875 AC_MSG_CHECKING([whether to compile timeloop])
1876 case "$host" in
1877   *-*-cygwin*|*-*-mingw*|*-*-minix)
1878     enable_timeloop=no
1879     ;;
1880   *)
1881     enable_timeloop=yes
1882     ;;
1883 esac
1884 AC_MSG_RESULT($enable_timeloop)
1885 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1886
1887 AC_MSG_CHECKING([if building for some Win32 platform])
1888 case "$host" in
1889   *-*-mingw*|*-*-cygwin*)
1890     platform_win32=yes
1891     ;;
1892   *)
1893     platform_win32=no
1894     ;;
1895 esac
1896 AC_MSG_RESULT($platform_win32)
1897 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1898
1899 dnl ***********************
1900 dnl *** g_thread checks ***
1901 dnl ***********************
1902
1903 AC_ARG_WITH(threads,
1904            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1905                            [specify a thread implementation to use])],
1906            [],
1907            [with_threads=yes])
1908
1909 dnl error and warning message
1910 dnl *************************
1911
1912 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1913
1914 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1915                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1916                 compilation now, but then your programs might not work.
1917                 Please provide information on how it is done on your system."
1918
1919 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1920                  "
1921
1922 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1923                   provide information on your thread implementation."
1924
1925 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1926                 functions will not be MT-safe during their first call because
1927                 there is no working 'getpwuid_r' on your system."
1928
1929 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1930                 because there is no 'localtime_r' on your system."
1931
1932 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1933                 linking threaded applications. As GLib cannot do that
1934                 automatically, you will get an linkg error everytime you are
1935                 not using the right compiler. In that case you have to relink
1936                 with the right compiler. Ususally just '_r' is appended
1937                 to the compiler name."
1938
1939 dnl determination of thread implementation
1940 dnl ***************************************
1941
1942 AC_MSG_CHECKING(for thread implementation)
1943
1944 have_threads=no
1945 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1946         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1947         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1948         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1949         glib_save_CPPFLAGS="$CPPFLAGS"
1950         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1951         AS_IF([ test "x$have_threads" = xno], [
1952                 AC_TRY_COMPILE([#include <pthread.h>],
1953                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1954                         have_threads=posix)
1955         ])
1956         # Tru64Unix requires -pthread to find pthread.h. See #103020
1957         CPPFLAGS="$CPPFLAGS -pthread"
1958         if test "x$have_threads" = xno; then
1959         AC_TRY_COMPILE([#include <pthread.h>],
1960                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1961                        have_threads=posix)
1962         fi
1963         CPPFLAGS="$glib_save_CPPFLAGS"
1964 ])
1965 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1966         case $host in
1967                 *-*-mingw*)
1968                 have_threads=win32
1969                 ;;
1970         esac
1971 fi
1972
1973 if test "x$have_threads" = xno; then
1974         AC_MSG_RESULT(none available)
1975         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1976 else
1977         AC_MSG_RESULT($have_threads)
1978 fi
1979
1980
1981 dnl determination of G_THREAD_CFLAGS
1982 dnl ********************************
1983
1984 G_THREAD_LIBS=
1985 G_THREAD_LIBS_EXTRA=
1986 G_THREAD_CFLAGS=
1987
1988 dnl
1989 dnl Test program for basic POSIX threads functionality
1990 dnl
1991 m4_define([glib_thread_test],[
1992 #include <pthread.h>
1993 int check_me = 0;
1994 void* func(void* data) {check_me = 42; return &check_me;}
1995 int main()
1996  { pthread_t t;
1997    void *ret;
1998    pthread_create (&t, $1, func, 0);
1999    pthread_join (t, &ret);
2000    return (check_me != 42 || ret != &check_me);
2001 }])
2002
2003 AS_IF([ test x"$have_threads" = xposix], [
2004   # First we test for posix, whether -pthread or -pthreads do the trick as
2005   # both CPPFLAG and LIBS.
2006   # One of them does for most gcc versions and some other platforms/compilers
2007   # too and could be considered as the canonical way to go.
2008   case $host in
2009     *-*-cygwin*|*-*-darwin*)
2010        # skip cygwin and darwin -pthread or -pthreads test
2011        ;;
2012     *-solaris*)
2013       # These compiler/linker flags work with both Sun Studio and gcc
2014       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2015       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2016       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2017       G_THREAD_LIBS="-lpthread -lthread"
2018       ;;
2019     *)
2020       for flag in pthread pthreads mt; do
2021         glib_save_CFLAGS="$CFLAGS"
2022         CFLAGS="$CFLAGS -$flag"
2023         AC_TRY_RUN(glib_thread_test(0),
2024                    glib_flag_works=yes,
2025                    glib_flag_works=no,
2026                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2027                                    glib_flag_works=yes,
2028                                    glib_flag_works=no)])
2029         CFLAGS="$glib_save_CFLAGS"
2030         if test $glib_flag_works = yes ; then
2031            G_THREAD_CFLAGS=-$flag
2032         G_THREAD_LIBS=-$flag
2033         break;
2034         fi
2035       done
2036        ;;
2037   esac
2038 ])
2039
2040 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2041
2042   # The canonical -pthread[s] does not work. Try something different.
2043
2044   case $host in
2045         *-aix*)
2046                 if test x"$GCC" = xyes; then
2047                         # GCC 3.0 and above needs -pthread.
2048                         # Should be coverd by the case above.
2049                         # GCC 2.x and below needs -mthreads
2050                         G_THREAD_CFLAGS="-mthreads"
2051                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2052                 else
2053                         # We are probably using the aix compiler. Normaly a
2054                         # program would have to be compiled with the _r variant
2055                         # of the corresponding compiler, but we as GLib cannot
2056                         # do that: but the good news is that for compiling the
2057                         # only difference is the added -D_THREAD_SAFE compile
2058                         # option. This is according to the "C for AIX User's
2059                         # Guide".
2060                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2061                 fi
2062                 ;;
2063         *-dg-dgux*)  # DG/UX
2064                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2065                 ;;
2066         *-sysv5uw7*) # UnixWare 7
2067                 # We are not using gcc with -pthread. Catched above.
2068                 G_THREAD_CFLAGS="-Kthread"
2069                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2070                 ;;
2071         *-mingw*)
2072                 # No flag needed when using MSVCRT.DLL
2073                 G_THREAD_CFLAGS=""
2074                 ;;
2075         *)
2076                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2077                 ;;
2078   esac
2079 ])
2080
2081 # if we are not finding the localtime_r function, then we probably are
2082 # not using the proper multithread flag
2083
2084 glib_save_CPPFLAGS="$CPPFLAGS"
2085 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2086
2087 # First we test, whether localtime_r is declared in time.h
2088 # directly. Then we test whether a macro localtime_r exists, in
2089 # which case localtime_r in the test program is replaced and thus
2090 # if we still find localtime_r in the output, it is not defined as
2091 # a macro.
2092
2093 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2094   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2095                                                            localtime_r(a,b)],
2096                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2097
2098 CPPFLAGS="$glib_save_CPPFLAGS"
2099
2100 AC_MSG_CHECKING(thread related cflags)
2101 AC_MSG_RESULT($G_THREAD_CFLAGS)
2102 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2103
2104 dnl determination of G_THREAD_LIBS
2105 dnl ******************************
2106
2107 AS_IF([test x$have_threads = xposix], [
2108           glib_save_CPPFLAGS="$CPPFLAGS"
2109           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2110           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2111             case $host in
2112               *-aix*)
2113                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2114                 # probably using the aix compiler.
2115                 AC_MSG_WARN($AIX_COMPILE_INFO)
2116                 ;;
2117               *)
2118                 G_THREAD_LIBS=error
2119                 glib_save_LIBS="$LIBS"
2120                 for thread_lib in "" pthread pthread32 pthreads thread; do
2121                         if test x"$thread_lib" = x; then
2122                                 add_thread_lib=""
2123                                 IN=""
2124                         else
2125                                 add_thread_lib="-l$thread_lib"
2126                                 IN=" in -l$thread_lib"
2127                         fi
2128                         if test x"$have_threads" = xposix; then
2129                                 defattr=0
2130                         else
2131                                 defattr=pthread_attr_default
2132                         fi
2133
2134                         LIBS="$add_thread_lib $glib_save_LIBS"
2135
2136                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2137                         AC_TRY_RUN(glib_thread_test($defattr),
2138                                    glib_result=yes,
2139                                    glib_result=no,
2140                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2141                                                    glib_result=yes,
2142                                                    glib_result=no)])
2143                         AC_MSG_RESULT($glib_result)
2144
2145                         if test "$glib_result" = "yes" ; then
2146                           G_THREAD_LIBS="$add_thread_lib"
2147                           break
2148                         fi
2149                 done
2150                 if test "x$G_THREAD_LIBS" = xerror; then
2151                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2152                 fi
2153                 LIBS="$glib_save_LIBS"
2154                 ;;
2155             esac
2156           ])
2157
2158           g_threads_impl="POSIX"
2159           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2160           CPPFLAGS="$glib_save_CPPFLAGS"
2161 ], [test x$have_threads = xwin32], [
2162            g_threads_impl="WIN32"
2163 ], [
2164            g_threads_impl="NONE"
2165            G_THREAD_LIBS=error
2166 ])
2167
2168 if test "x$G_THREAD_LIBS" = xerror; then
2169         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2170 fi
2171
2172 case $host in
2173   *-*-beos*)
2174     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2175     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2176     ;;
2177   *)
2178     ;;
2179 esac
2180
2181 AC_MSG_CHECKING(thread related libraries)
2182 AC_MSG_RESULT($G_THREAD_LIBS)
2183
2184 dnl check for mt safe function variants and some posix functions
2185 dnl ************************************************************
2186
2187 glib_save_LIBS="$LIBS"
2188 # we are not doing the following for now, as this might require glib
2189 # to always be linked with the thread libs on some platforms.
2190 # LIBS="$LIBS $G_THREAD_LIBS"
2191 AC_CHECK_FUNCS(localtime_r gmtime_r)
2192 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2193         AC_CACHE_CHECK([for posix getpwuid_r],
2194                 ac_cv_func_posix_getpwuid_r,
2195                 [AC_TRY_RUN([
2196 #include <errno.h>
2197 #include <pwd.h>
2198 int main () {
2199     char buffer[10000];
2200     struct passwd pwd, *pwptr = &pwd;
2201     int error;
2202     errno = 0;
2203     error = getpwuid_r (0, &pwd, buffer,
2204                         sizeof (buffer), &pwptr);
2205    return (error < 0 && errno == ENOSYS)
2206            || error == ENOSYS;
2207 }                               ],
2208                         [ac_cv_func_posix_getpwuid_r=yes],
2209                         [ac_cv_func_posix_getpwuid_r=no])])
2210         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2211         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2212                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2213                         [Have POSIX function getpwuid_r])
2214         else
2215                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2216                         ac_cv_func_nonposix_getpwuid_r,
2217                         [AC_TRY_LINK([#include <pwd.h>],
2218                                 [char buffer[10000];
2219                                 struct passwd pwd;
2220                                 getpwuid_r (0, &pwd, buffer,
2221                                                 sizeof (buffer));],
2222                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2223                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2224                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2225                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2226                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2227                                 [Have non-POSIX function getpwuid_r])
2228                 fi
2229         fi
2230 ])
2231 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2232         AC_CACHE_CHECK([for posix getgrgid_r],
2233                 ac_cv_func_posix_getgrgid_r,
2234                 [AC_TRY_RUN([
2235 #include <errno.h>
2236 #include <grp.h>
2237 int main () {
2238     char buffer[10000];
2239     struct group grp, *grpptr = &grp;
2240     int error;
2241     errno = 0;
2242     error = getgrgid_r (0, &grp, buffer,
2243                         sizeof (buffer), &grpptr);
2244    return (error < 0 && errno == ENOSYS)
2245            || error == ENOSYS;
2246 }                              ],
2247                        [ac_cv_func_posix_getgrgid_r=yes],
2248                        [ac_cv_func_posix_getgrgid_r=no])])
2249         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2250         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2251                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2252                         [Have POSIX function getgrgid_r])
2253         ], [
2254                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2255                         ac_cv_func_nonposix_getgrgid_r,
2256                         [AC_TRY_LINK([#include <grp.h>],
2257                                 [char buffer[10000];
2258                                 struct group grp;
2259                                 getgrgid_r (0, &grp, buffer,
2260                                 sizeof (buffer));],
2261                         [ac_cv_func_nonposix_getgrgid_r=yes],
2262                         [ac_cv_func_nonposix_getgrgid_r=no])])
2263                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2264                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2265                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2266                                 [Have non-POSIX function getgrgid_r])
2267                 fi
2268         ])
2269 ])
2270 LIBS="$G_THREAD_LIBS $LIBS"
2271 AS_IF([ test x"$have_threads" = xposix], [
2272         glib_save_CPPFLAGS="$CPPFLAGS"
2273         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2274         # This is not AC_CHECK_FUNC to also work with function
2275         # name mangling in header files.
2276         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2277         AC_LINK_IFELSE(
2278             [AC_LANG_PROGRAM(
2279                 [#include <pthread.h>],
2280                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2281             [AC_MSG_RESULT(yes)
2282              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2283                 [Have function pthread_attr_setstacksize])],
2284             [AC_MSG_RESULT(no)])
2285         AC_MSG_CHECKING(for pthread_condattr_setclock)
2286         AC_LINK_IFELSE(
2287             [AC_LANG_PROGRAM(
2288                 [#include <pthread.h>],
2289                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2290             [AC_MSG_RESULT(yes)
2291              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2292                 [Have function pthread_condattr_setclock])],
2293             [AC_MSG_RESULT(no)])
2294         CPPFLAGS="$glib_save_CPPFLAGS"
2295 ])
2296
2297 LIBS="$glib_save_LIBS"
2298
2299 # now spit out all the warnings.
2300 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2301    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2302         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2303 fi
2304 if test "$ac_cv_func_localtime_r" != "yes"; then
2305         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2306 fi
2307
2308 #
2309 # Hack to deal with:
2310 #
2311 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2312 #     building shared libraries with linux.
2313 #  b) FreeBSD doesn't do this either.
2314 #
2315 case $host in
2316   *-*-freebsd*|*-*-linux*)
2317     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2318     ;;
2319   *-*-openbsd*)
2320     LDFLAGS="$LDFLAGS -pthread"
2321     ;;
2322   *)
2323     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2324     ;;
2325 esac
2326
2327 AC_SUBST(G_THREAD_CFLAGS)
2328 AC_SUBST(G_THREAD_LIBS)
2329 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2330 AC_SUBST(G_THREAD_LIBS_EXTRA)
2331
2332 AC_CHECK_FUNCS(clock_gettime, [], [
2333   AC_CHECK_LIB(rt, clock_gettime, [
2334     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2335     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2336     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2337   ])
2338 ])
2339
2340
2341 dnl ************************
2342 dnl *** g_atomic_* tests ***
2343 dnl ************************
2344
2345 dnl We need to decide at configure time if GLib will use real atomic
2346 dnl operations ("lock free") or emulated ones with a mutex.  This is
2347 dnl because we must put this information in glibconfig.h so we know if
2348 dnl it is safe or not to inline using compiler intrinsics directly from
2349 dnl the header.
2350 dnl
2351 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2352 dnl user is interested in knowing if they can use the atomic ops across
2353 dnl processes.
2354 dnl
2355 dnl We can currently support the atomic ops natively when building GLib
2356 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2357 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2358 dnl we are using GCC.
2359 dnl
2360 dnl Note that the atomic ops are only available with GCC on x86 when
2361 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2362 dnl not available but would be available given the right flags, we want
2363 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2364 dnl that then to silently fall back on emulated atomic ops just because
2365 dnl the user had the wrong build environment.
2366
2367 dnl We may add other compilers here in the future...
2368
2369 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2370   AC_TRY_COMPILE([],
2371                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2372                  [glib_cv_g_atomic_lock_free=yes],
2373                  [glib_cv_g_atomic_lock_free=no])])
2374
2375 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2376   SAVE_CFLAGS="${CFLAGS}"
2377   CFLAGS="-march=i486"
2378   AC_TRY_COMPILE([],
2379                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2380                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2381                  [])
2382   CFLAGS="${SAVE_CFLAGS}"
2383 fi
2384
2385 dnl We need a more robust approach here...
2386 case $host_cpu in
2387   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2388     glib_memory_barrier_needed=no
2389     ;;
2390   sparc*|alpha*|powerpc*|ia64)
2391     glib_memory_barrier_needed=yes
2392     ;;
2393   *)
2394     glib_memory_barrier_needed=yes
2395     ;;
2396 esac
2397
2398 dnl ************************
2399 dnl ** Check for futex(2) **
2400 dnl ************************
2401 AC_CACHE_CHECK(for futex(2) system call,
2402     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2403 #include <linux/futex.h>
2404 #include <sys/syscall.h>
2405 #include <unistd.h>
2406 ],[
2407 int
2408 main (void)
2409 {
2410   /* it is not like this actually runs or anything... */
2411   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2412   return 0;
2413 }
2414 ])],glib_cv_futex=yes,glib_cv_futex=no))
2415 if test x"$glib_cv_futex" = xyes; then
2416   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2417 fi
2418
2419 AC_CACHE_CHECK(for eventfd(2) system call,
2420     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2421 #include <sys/eventfd.h>
2422 #include <unistd.h>
2423 ],[
2424 int
2425 main (void)
2426 {
2427   eventfd (0, EFD_CLOEXEC);
2428   return 0;
2429 }
2430 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2431 if test x"$glib_cv_eventfd" = x"yes"; then
2432   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2433 fi
2434 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2435
2436 dnl ****************************************
2437 dnl *** GLib POLL* compatibility defines ***
2438 dnl ****************************************
2439
2440 glib_poll_includes=["
2441 #include <sys/types.h>
2442 #include <sys/poll.h>
2443 "]
2444
2445 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2446    test $ac_cv_header_sys_poll_h = yes ], [
2447   glib_failed=false
2448   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2449   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2450   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2451   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2452   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2453   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2454   if $glib_failed ; then
2455     AC_MSG_ERROR([Could not determine values for POLL* constants])
2456   fi
2457 ], [
2458   glib_cv_value_POLLIN=1
2459   glib_cv_value_POLLOUT=4
2460   glib_cv_value_POLLPRI=2
2461   glib_cv_value_POLLERR=8
2462   glib_cv_value_POLLHUP=16
2463   glib_cv_value_POLLNVAL=32
2464 ])
2465
2466 AC_MSG_CHECKING([for broken poll])
2467 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2468         #include <stdlib.h>
2469         #include <fcntl.h>
2470         #include <poll.h>
2471         #ifdef HAVE_SYS_POLL_H
2472         #include <sys/poll.h>
2473         #endif
2474         int main(void) {
2475           struct pollfd fds[1];
2476           int fd;
2477           fd = open("/dev/null", 1);
2478           fds[0].fd = fd;
2479           fds[0].events = POLLIN;
2480           fds[0].revents = 0;
2481           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2482                 exit(1);  /* Does not work for devices -- fail */
2483           }
2484           exit(0);
2485         }]])],
2486   [broken_poll=no],
2487   [broken_poll=yes
2488    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2489   [broken_poll="no (cross compiling)"])
2490 AC_MSG_RESULT($broken_poll)
2491
2492 dnl *********************
2493 dnl *** GRegex checks ***
2494 dnl *********************
2495
2496 PCRE_REQUIRED_VERSION=8.13
2497
2498 # Check if we should use the internal or the system-supplied pcre
2499 AC_ARG_WITH(pcre,
2500             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2501                             [whether to use system PCRE [default=internal]])])
2502
2503 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2504
2505 AS_IF([ test "x$with_pcre" = xsystem], [
2506   PKG_CHECK_MODULES(PCRE,
2507                     libpcre >= $PCRE_REQUIRED_VERSION)
2508   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2509                   glib_save_CFLAGS="$CFLAGS"
2510                   glib_save_LIBS="$LIBS"
2511                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2512                   AC_TRY_RUN([#include <pcre.h>
2513                               int main () {
2514                                 int support;
2515                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2516                                 if (!support)
2517                                   return 1;
2518                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2519                                 if (!support)
2520                                   return 1;
2521                                 return 0;
2522                               }],
2523                   glib_cv_pcre_has_unicode=yes,
2524                   glib_cv_pcre_has_unicode=no,
2525                   glib_cv_pcre_has_unicode=yes)
2526                   CFLAGS="$glib_save_CFLAGS"
2527                   LIBS="$glib_save_LIBS"
2528       ])
2529   if test "$glib_cv_pcre_has_unicode" = "no"; then
2530     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2531   fi
2532   AC_SUBST(PCRE_CFLAGS)
2533   AC_SUBST(PCRE_LIBS)
2534   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2535   PCRE_REQUIRES=libpcre
2536   AC_SUBST(PCRE_REQUIRES)
2537 ], [
2538   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2539   AS_IF([ test x"$GCC" = xyes], [
2540     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2541     save_CFLAGS="$CFLAGS"
2542     CFLAGS="$CFLAGS -Wno-pointer-sign"
2543     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2544                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2545     CFLAGS="$save_CFLAGS"
2546   ])
2547 ])
2548 AC_SUBST(PCRE_WARN_CFLAGS)
2549
2550 dnl **********************
2551 dnl *** Win32 API libs ***
2552 dnl **********************
2553
2554 case $host in
2555   *-*-cygwin*)
2556         G_LIBS_EXTRA="-luser32 -lkernel32"
2557     ;;
2558   *-*-mingw*)
2559         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2560     ;;
2561   *)
2562         G_LIBS_EXTRA=""
2563     ;;
2564 esac
2565 AC_SUBST(G_LIBS_EXTRA)
2566
2567 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2568 dnl since we need it for g_iconv()
2569
2570 AC_MSG_CHECKING([for EILSEQ])
2571 AC_TRY_COMPILE([
2572 #include <errno.h>
2573 ],
2574 [
2575 int error = EILSEQ;
2576 ], have_eilseq=yes, have_eilseq=no);
2577 AC_MSG_RESULT($have_eilseq)
2578
2579 dnl ******************************************************************
2580 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2581 dnl *** glib-compile-schemas in PATH                               ***
2582 dnl ******************************************************************
2583
2584 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2585
2586 AS_IF([ test $cross_compiling = yes && test x$enable_modular_tests = xyes], [
2587   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2588   if test x$GLIB_GENMARSHAL = xno; then
2589     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2590   fi
2591
2592   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2593   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2594     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2595   fi
2596
2597   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2598   if test x$GLIB_COMPILE_RESOURCES = xno; then
2599     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2600   fi
2601 ])
2602
2603 dnl **************************
2604 dnl *** Checks for gtk-doc ***
2605 dnl **************************
2606 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2607 # it on it's own line.
2608 m4_ifdef([GTK_DOC_CHECK], [
2609 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2610 ],[
2611 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2612 ])
2613
2614 AC_ARG_ENABLE(man,
2615               [AS_HELP_STRING([--enable-man],
2616                               [generate man pages [default=auto]])],,
2617               enable_man=maybe)
2618
2619 AS_IF([test "$enable_man" != no], [
2620   AC_PATH_PROG([XSLTPROC], [xsltproc])
2621   AS_IF([test -z "$XSLTPROC"], [
2622     AS_IF([test "$enable_man" = yes], [
2623       AC_MSG_ERROR([xsltproc is required for --enable-man])
2624     ])
2625     enable_man=no
2626   ])
2627 ])
2628
2629 AS_IF([ test "$enable_man" != no ], [
2630   dnl check for DocBook DTD in the local catalog
2631   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2632      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2633   AS_IF([test "$have_docbook_dtd" != yes], [
2634     AS_IF([test "$enable_man" = yes ], [
2635       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2636     ])
2637     enable_man=no
2638   ])
2639 ])
2640
2641 AS_IF([test "$enable_man" != no], [
2642   dnl check for DocBook XSL stylesheets in the local catalog
2643   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2644      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2645   AS_IF([ test "$have_docbook_dtd" != yes ], [
2646     AS_IF([ test "$enable_man" = yes ], [
2647       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2648     ])
2649     enable_man=no
2650   ])
2651 ])
2652
2653 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2654
2655 AC_MSG_CHECKING([whether to generate man pages])
2656 AS_IF([ test "$enable_man" != no ], [
2657   AC_MSG_RESULT([yes])
2658 ], [
2659   AC_MSG_RESULT([no])
2660 ])
2661
2662 dnl
2663 dnl Tracing
2664 dnl
2665
2666 AC_ARG_ENABLE([dtrace],
2667              [AS_HELP_STRING([--enable-dtrace],
2668                               [include tracing support for dtrace])])
2669 have_dtrace=no
2670 AC_MSG_CHECKING([whether to include dtrace tracing support])
2671 AS_IF([ test "x$enable_dtrace" != xno], [
2672   if test x$glib_have_carbon = xyes; then
2673     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2674   else
2675     AC_MSG_RESULT([yes])
2676     AC_CHECK_PROGS(DTRACE, dtrace)
2677     if test -z "$DTRACE"; then
2678       if test "x$enable_dtrace" = xyes; then
2679         AC_MSG_ERROR([dtrace not found])
2680       fi
2681     else
2682       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2683                       [if test "x$enable_dtrace" = xyes; then
2684                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2685                        fi])
2686     fi
2687   fi
2688 ], [
2689   AC_MSG_RESULT([no])
2690 ])
2691 if test "x$have_dtrace" = xyes; then
2692   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2693 fi
2694 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2695
2696 AC_MSG_CHECKING([whether to include systemtap tracing support])
2697 AC_ARG_ENABLE([systemtap],
2698              [AS_HELP_STRING([--enable-systemtap],
2699                               [include tracing support for systemtap])])
2700 have_systemtap=no
2701 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2702   have_systemtap=yes
2703 fi
2704 AC_MSG_RESULT(${have_systemtap})
2705
2706 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2707
2708 AC_ARG_WITH([tapset-install-dir],
2709             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2710                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2711             [if test "x${withval}" = x; then
2712                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2713              else
2714                ABS_TAPSET_DIR="${withval}"
2715               fi],
2716             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2717 AC_SUBST(ABS_TAPSET_DIR)
2718
2719 dnl ************************************
2720 dnl *** Enable lcov coverage reports ***
2721 dnl ************************************
2722
2723 AC_ARG_ENABLE(gcov,
2724   AS_HELP_STRING([--enable-gcov],
2725                  [enable coverage testing with gcov]),
2726   [use_gcov=$enableval], [use_gcov=no])
2727
2728 AS_IF([ test "x$use_gcov" = "xyes"], [
2729   dnl we need gcc:
2730   if test "$GCC" != "yes"; then
2731     AC_MSG_ERROR([GCC is required for --enable-gcov])
2732   fi
2733
2734   dnl Check if ccache is being used
2735   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2736   case `$SHTOOL path $CC` in
2737     *ccache*[)] gcc_ccache=yes;;
2738     *[)] gcc_ccache=no;;
2739   esac
2740
2741   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2742     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2743   fi
2744
2745   ltp_version_list="1.6 1.7 1.8 1.9"
2746   AC_CHECK_PROG(LTP, lcov, lcov)
2747   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2748
2749   AS_IF([ test "$LTP" ], [
2750     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2751       glib_cv_ltp_version=invalid
2752       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2753       for ltp_check_version in $ltp_version_list; do
2754         if test "$ltp_version" = "$ltp_check_version"; then
2755           glib_cv_ltp_version="$ltp_check_version (ok)"
2756         fi
2757       done
2758     ])
2759   ], [
2760     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2761     AC_MSG_ERROR([$ltp_msg])
2762   ])
2763
2764   case $glib_cv_ltp_version in
2765     ""|invalid[)]
2766       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2767       AC_MSG_ERROR([$ltp_msg])
2768       LTP="exit 0;"
2769       ;;
2770   esac
2771
2772   if test -z "$LTP_GENHTML"; then
2773     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2774   fi
2775
2776   dnl Remove all optimization flags from CFLAGS
2777   changequote({,})
2778   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2779   changequote([,])
2780
2781   dnl Add the special gcc flags
2782   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2783   LDFLAGS="$LDFLAGS -lgcov"
2784 ])
2785
2786 dnl ******************************
2787 dnl *** output the whole stuff ***
2788 dnl ******************************
2789
2790 dnl this section will only be run if config.status is invoked with no
2791 dnl arguments, or with "glib/glibconfig.h" as an argument.
2792 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2793 [
2794         outfile=glib/glibconfig.h-tmp
2795         cat > $outfile <<\_______EOF
2796 /* glibconfig.h
2797  *
2798  * This is a generated file.  Please modify 'configure.ac'
2799  */
2800
2801 #ifndef __GLIBCONFIG_H__
2802 #define __GLIBCONFIG_H__
2803
2804 #include <glib/gmacros.h>
2805
2806 _______EOF
2807
2808         if test x$glib_limits_h = xyes; then
2809           echo '#include <limits.h>' >> $outfile
2810         fi
2811         if test x$glib_float_h = xyes; then
2812           echo '#include <float.h>' >> $outfile
2813         fi
2814         if test x$glib_values_h = xyes; then
2815           echo '#include <values.h>' >> $outfile
2816         fi
2817         if test "$glib_header_alloca_h" = "yes"; then
2818           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2819         fi
2820         if test x$glib_sys_poll_h = xyes; then
2821           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2822         fi
2823         if test x$glib_included_printf != xyes; then
2824           echo "
2825 /* Specifies that GLib's g_print*() functions wrap the
2826  * system printf functions.  This is useful to know, for example,
2827  * when using glibc's register_printf_function().
2828  */" >> $outfile
2829           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2830         fi
2831
2832         cat >> $outfile <<_______EOF
2833
2834 G_BEGIN_DECLS
2835
2836 #define G_MINFLOAT      $glib_mf
2837 #define G_MAXFLOAT      $glib_Mf
2838 #define G_MINDOUBLE     $glib_md
2839 #define G_MAXDOUBLE     $glib_Md
2840 #define G_MINSHORT      $glib_ms
2841 #define G_MAXSHORT      $glib_Ms
2842 #define G_MAXUSHORT     $glib_Mus
2843 #define G_MININT        $glib_mi
2844 #define G_MAXINT        $glib_Mi
2845 #define G_MAXUINT       $glib_Mui
2846 #define G_MINLONG       $glib_ml
2847 #define G_MAXLONG       $glib_Ml
2848 #define G_MAXULONG      $glib_Mul
2849
2850 _______EOF
2851
2852
2853         ### this should always be true in a modern C/C++ compiler
2854         cat >>$outfile <<_______EOF
2855 typedef signed char gint8;
2856 typedef unsigned char guint8;
2857 _______EOF
2858
2859
2860         if test -n "$gint16"; then
2861           cat >>$outfile <<_______EOF
2862 typedef signed $gint16 gint16;
2863 typedef unsigned $gint16 guint16;
2864 #define G_GINT16_MODIFIER $gint16_modifier
2865 #define G_GINT16_FORMAT $gint16_format
2866 #define G_GUINT16_FORMAT $guint16_format
2867 _______EOF
2868         fi
2869
2870
2871         if test -n "$gint32"; then
2872           cat >>$outfile <<_______EOF
2873 typedef signed $gint32 gint32;
2874 typedef unsigned $gint32 guint32;
2875 #define G_GINT32_MODIFIER $gint32_modifier
2876 #define G_GINT32_FORMAT $gint32_format
2877 #define G_GUINT32_FORMAT $guint32_format
2878 _______EOF
2879         fi
2880
2881         cat >>$outfile <<_______EOF
2882 #define G_HAVE_GINT64 1          /* deprecated, always true */
2883
2884 ${glib_extension}typedef signed $gint64 gint64;
2885 ${glib_extension}typedef unsigned $gint64 guint64;
2886
2887 #define G_GINT64_CONSTANT(val)  $gint64_constant
2888 #define G_GUINT64_CONSTANT(val) $guint64_constant
2889 _______EOF
2890
2891         if test x$gint64_format != x ; then
2892           cat >>$outfile <<_______EOF
2893 #define G_GINT64_MODIFIER $gint64_modifier
2894 #define G_GINT64_FORMAT $gint64_format
2895 #define G_GUINT64_FORMAT $guint64_format
2896 _______EOF
2897         else
2898           cat >>$outfile <<_______EOF
2899 #undef G_GINT64_MODIFIER
2900 #undef G_GINT64_FORMAT
2901 #undef G_GUINT64_FORMAT
2902 _______EOF
2903         fi
2904
2905         cat >>$outfile <<_______EOF
2906
2907 #define GLIB_SIZEOF_VOID_P $glib_void_p
2908 #define GLIB_SIZEOF_LONG   $glib_long
2909 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2910
2911 _______EOF
2912
2913         cat >>$outfile <<_______EOF
2914 typedef signed $glib_size_type_define gssize;
2915 typedef unsigned $glib_size_type_define gsize;
2916 #define G_GSIZE_MODIFIER $gsize_modifier
2917 #define G_GSSIZE_FORMAT $gssize_format
2918 #define G_GSIZE_FORMAT $gsize_format
2919
2920 #define G_MAXSIZE       G_MAXU$glib_msize_type
2921 #define G_MINSSIZE      G_MIN$glib_msize_type
2922 #define G_MAXSSIZE      G_MAX$glib_msize_type
2923
2924 typedef gint64 goffset;
2925 #define G_MINOFFSET     G_MININT64
2926 #define G_MAXOFFSET     G_MAXINT64
2927
2928 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2929 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2930 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2931
2932 _______EOF
2933
2934         if test -z "$glib_unknown_void_p"; then
2935           cat >>$outfile <<_______EOF
2936
2937 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2938 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2939
2940 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2941 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2942
2943 typedef signed $glib_intptr_type_define gintptr;
2944 typedef unsigned $glib_intptr_type_define guintptr;
2945
2946 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2947 #define G_GINTPTR_FORMAT        $gintptr_format
2948 #define G_GUINTPTR_FORMAT       $guintptr_format
2949 _______EOF
2950         else
2951           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2952         fi
2953
2954
2955
2956         cat >>$outfile <<_______EOF
2957 $glib_atexit
2958 $glib_memmove
2959 $glib_defines
2960 $glib_os
2961 $glib_static_compilation
2962
2963 $glib_vacopy
2964
2965 #ifdef  __cplusplus
2966 #define G_HAVE_INLINE   1
2967 #else   /* !__cplusplus */
2968 $glib_inline
2969 #endif  /* !__cplusplus */
2970
2971 #ifdef  __cplusplus
2972 #define G_CAN_INLINE    1
2973 _______EOF
2974
2975         if test x$g_can_inline = xyes ; then
2976                 cat >>$outfile <<_______EOF
2977 #else   /* !__cplusplus */
2978 #define G_CAN_INLINE    1
2979 _______EOF
2980         fi
2981
2982         cat >>$outfile <<_______EOF
2983 #endif
2984
2985 _______EOF
2986
2987         if test x$g_have_iso_c_varargs = xyes ; then
2988                 cat >>$outfile <<_______EOF
2989 #ifndef __cplusplus
2990 # define G_HAVE_ISO_VARARGS 1
2991 #endif
2992 _______EOF
2993         fi
2994         if test x$g_have_iso_cxx_varargs = xyes ; then
2995                 cat >>$outfile <<_______EOF
2996 #ifdef __cplusplus
2997 # define G_HAVE_ISO_VARARGS 1
2998 #endif
2999 _______EOF
3000         fi
3001         if test x$g_have_gnuc_varargs = xyes ; then
3002                 cat >>$outfile <<_______EOF
3003
3004 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3005  * is passed ISO vararg support is turned off, and there is no work
3006  * around to turn it on, so we unconditionally turn it off.
3007  */
3008 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3009 #  undef G_HAVE_ISO_VARARGS
3010 #endif
3011
3012 #define G_HAVE_GNUC_VARARGS 1
3013 _______EOF
3014         fi
3015
3016         case x$g_stack_grows in
3017         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3018         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3019         esac
3020
3021
3022         echo >>$outfile
3023         if test x$g_have_eilseq = xno; then
3024                 cat >>$outfile <<_______EOF
3025 #ifndef EILSEQ
3026 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3027  * The correspondence between this and the corresponding definition
3028  * in libiconv is essential.
3029  */
3030 #  define EILSEQ ENOENT
3031 #endif
3032 _______EOF
3033
3034         fi
3035
3036         if test x$g_have_gnuc_visibility = xyes; then
3037                 cat >>$outfile <<_______EOF
3038 #define G_HAVE_GNUC_VISIBILITY 1
3039 _______EOF
3040         fi
3041                 cat >>$outfile <<_______EOF
3042 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3043 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3044 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3045 #define G_GNUC_INTERNAL __hidden
3046 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3047 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3048 #else
3049 #define G_GNUC_INTERNAL
3050 #endif
3051 _______EOF
3052
3053         echo >>$outfile
3054         cat >>$outfile <<_______EOF
3055 #define G_THREADS_ENABLED
3056 #define G_THREADS_IMPL_$g_threads_impl_def
3057 _______EOF
3058
3059         if test x"$g_memory_barrier_needed" != xno; then
3060           echo >>$outfile
3061           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3062         fi
3063         if test x"$g_atomic_lock_free" = xyes; then
3064           echo >>$outfile
3065           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3066         fi
3067         echo >>$outfile
3068         g_bit_sizes="16 32 64"
3069         for bits in $g_bit_sizes; do
3070           cat >>$outfile <<_______EOF
3071 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3072 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3073 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3074 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3075 _______EOF
3076         done
3077
3078         cat >>$outfile <<_______EOF
3079 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3080 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3081 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3082 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3083 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3084 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3085 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3086 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3087 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3088 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3089 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3090 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3091 #define G_BYTE_ORDER $g_byte_order
3092
3093 #define GLIB_SYSDEF_POLLIN =$g_pollin
3094 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3095 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3096 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3097 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3098 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3099
3100 #define G_MODULE_SUFFIX "$g_module_suffix"
3101
3102 typedef $g_pid_type GPid;
3103
3104 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3105 #define GLIB_SYSDEF_AF_INET $g_af_inet
3106 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3107
3108 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3109 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3110 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3111
3112 G_END_DECLS
3113
3114 #endif /* __GLIBCONFIG_H__ */
3115 _______EOF
3116
3117
3118         if cmp -s $outfile glib/glibconfig.h; then
3119           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3120           rm -f $outfile
3121         else
3122           mv $outfile glib/glibconfig.h
3123         fi
3124 ],[
3125
3126 # Note that if two cases are the same, case goes with the first one.
3127 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3128 # on variable expansion in case labels.  Look at the generated config.status
3129 # for a hint.
3130
3131 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3132   glib_header_alloca_h="$ac_cv_working_alloca_h"
3133 else
3134   glib_header_alloca_h="$ac_cv_header_alloca_h"
3135 fi
3136
3137 case xyes in
3138 x$ac_cv_header_float_h)
3139   glib_float_h=yes
3140   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3141   glib_md=DBL_MIN glib_Md=DBL_MAX
3142   ;;
3143 x$ac_cv_header_values_h)
3144   glib_values_h=yes
3145   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3146   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3147   ;;
3148 esac
3149
3150 case xyes in
3151 x$ac_cv_header_limits_h)
3152   glib_limits_h=yes
3153   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3154   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3155   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3156   ;;
3157 x$ac_cv_header_values_h)
3158   glib_values_h=yes
3159   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3160   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3161   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3162   ;;
3163 esac
3164
3165 if test x$ac_cv_header_sys_poll_h = xyes ; then
3166   glib_sys_poll_h=yes
3167 fi
3168
3169 if test x$enable_included_printf = xyes ; then
3170   glib_included_printf=yes
3171 fi
3172
3173 case 2 in
3174 $ac_cv_sizeof_short)
3175   gint16=short
3176   gint16_modifier='"h"'
3177   gint16_format='"hi"'
3178   guint16_format='"hu"'
3179   ;;
3180 $ac_cv_sizeof_int)
3181   gint16=int
3182   gint16_modifier='""'
3183   gint16_format='"i"'
3184   guint16_format='"u"'
3185   ;;
3186 esac
3187 case 4 in
3188 $ac_cv_sizeof_short)
3189   gint32=short
3190   gint32_modifier='"h"'
3191   gint32_format='"hi"'
3192   guint32_format='"hu"'
3193   ;;
3194 $ac_cv_sizeof_int)
3195   gint32=int
3196   gint32_modifier='""'
3197   gint32_format='"i"'
3198   guint32_format='"u"'
3199   ;;
3200 $ac_cv_sizeof_long)
3201   gint32=long
3202   gint32_modifier='"l"'
3203   gint32_format='"li"'
3204   guint32_format='"lu"'
3205   ;;
3206 esac
3207 case 8 in
3208 $ac_cv_sizeof_int)
3209   gint64=int
3210   gint64_modifier='""'
3211   gint64_format='"i"'
3212   guint64_format='"u"'
3213   glib_extension=
3214   gint64_constant='(val)'
3215   guint64_constant='(val)'
3216   ;;
3217 $ac_cv_sizeof_long)
3218   gint64=long
3219   gint64_modifier='"l"'
3220   gint64_format='"li"'
3221   guint64_format='"lu"'
3222   glib_extension=
3223   gint64_constant='(val##L)'
3224   guint64_constant='(val##UL)'
3225   ;;
3226 $ac_cv_sizeof_long_long)
3227   gint64='long long'
3228   if test -n "$glib_cv_long_long_format"; then
3229     gint64_modifier='"'$glib_cv_long_long_format'"'
3230     gint64_format='"'$glib_cv_long_long_format'i"'
3231     guint64_format='"'$glib_cv_long_long_format'u"'
3232   fi
3233   glib_extension='G_GNUC_EXTENSION '
3234   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3235   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3236   ;;
3237 $ac_cv_sizeof___int64)
3238   gint64='__int64'
3239   if test -n "$glib_cv_long_long_format"; then
3240     gint64_modifier='"'$glib_cv_long_long_format'"'
3241     gint64_format='"'$glib_cv_long_long_format'i"'
3242     guint64_format='"'$glib_cv_long_long_format'u"'
3243   fi
3244   glib_extension=
3245   gint64_constant='(val##i64)'
3246   guint64_constant='(val##ui64)'
3247   ;;
3248 esac
3249 glib_size_t=$ac_cv_sizeof_size_t
3250 glib_size_type_define="$glib_size_type"
3251 glib_void_p=$ac_cv_sizeof_void_p
3252 glib_long=$ac_cv_sizeof_long
3253
3254 case "$glib_size_type" in
3255 short)
3256   gsize_modifier='"h"'
3257   gsize_format='"hu"'
3258   gssize_format='"hi"'
3259   glib_msize_type='SHRT'
3260   ;;
3261 int)
3262   gsize_modifier='""'
3263   gsize_format='"u"'
3264   gssize_format='"i"'
3265   glib_msize_type='INT'
3266   ;;
3267 long)
3268   gsize_modifier='"l"'
3269   gsize_format='"lu"'
3270   gssize_format='"li"'
3271   glib_msize_type='LONG'
3272   ;;
3273 "long long"|__int64)
3274   gsize_modifier='"I64"'
3275   gsize_format='"I64u"'
3276   gssize_format='"I64i"'
3277   glib_msize_type='INT64'
3278   ;;
3279 esac
3280
3281 gintbits=`expr $ac_cv_sizeof_int \* 8`
3282 glongbits=`expr $ac_cv_sizeof_long \* 8`
3283 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3284
3285 case $ac_cv_sizeof_void_p in
3286 $ac_cv_sizeof_int)
3287   glib_intptr_type_define=int
3288   gintptr_modifier='""'
3289   gintptr_format='"i"'
3290   guintptr_format='"u"'
3291   glib_gpi_cast='(gint)'
3292   glib_gpui_cast='(guint)'
3293   ;;
3294 $ac_cv_sizeof_long)
3295   glib_intptr_type_define=long
3296   gintptr_modifier='"l"'
3297   gintptr_format='"li"'
3298   guintptr_format='"lu"'
3299   glib_gpi_cast='(glong)'
3300   glib_gpui_cast='(gulong)'
3301   ;;
3302 $ac_cv_sizeof_long_long)
3303   glib_intptr_type_define='long long'
3304   gintptr_modifier='"I64"'
3305   gintptr_format='"I64i"'
3306   guintptr_format='"I64u"'
3307   glib_gpi_cast='(gint64)'
3308   glib_gpui_cast='(guint64)'
3309   ;;
3310 $ac_cv_sizeof___int64)
3311   glib_intptr_type_define=__int64
3312   gintptr_modifier='"I64"'
3313   gintptr_format='"I64i"'
3314   guintptr_format='"I64u"'
3315   glib_gpi_cast='(gint64)'
3316   glib_gpui_cast='(guint64)'
3317   ;;
3318 *)
3319   glib_unknown_void_p=yes
3320   ;;
3321 esac
3322
3323
3324 case xyes in
3325 x$ac_cv_func_atexit)
3326   glib_atexit="
3327 #ifdef NeXT /* @#%@! NeXTStep */
3328 # define g_ATEXIT(proc) (!atexit (proc))
3329 #else
3330 # define g_ATEXIT(proc) (atexit (proc))
3331 #endif"
3332   ;;
3333 x$ac_cv_func_on_exit)
3334   glib_atexit="
3335 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3336   ;;
3337 esac
3338
3339 case xyes in
3340 x$ac_cv_func_memmove)
3341   glib_memmove='
3342 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3343   ;;
3344 x$glib_cv_working_bcopy)
3345   glib_memmove="
3346 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3347 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3348   ;;
3349 *)
3350   glib_memmove="
3351 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3352  * so we have to roll our own copy routine. */
3353 void g_memmove (void* dest, const void * src, unsigned long len);"
3354   ;;
3355 esac
3356
3357 glib_defines="
3358 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3359 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3360 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3361 "
3362
3363 case xyes in
3364 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3365 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3366 *)                      glib_vacopy=''
3367 esac
3368
3369 if test x$glib_cv_va_val_copy = xno; then
3370   glib_vacopy="\$glib_vacopy
3371 #define G_VA_COPY_AS_ARRAY 1"
3372 fi
3373
3374 if test x$glib_cv_hasinline = xyes; then
3375     glib_inline='#define G_HAVE_INLINE 1'
3376 fi
3377 if test x$glib_cv_has__inline = xyes; then
3378     glib_inline="\$glib_inline
3379 #define G_HAVE___INLINE 1"
3380 fi
3381 if test x$glib_cv_has__inline__ = xyes; then
3382     glib_inline="\$glib_inline
3383 #define G_HAVE___INLINE__ 1"
3384 fi
3385
3386 g_have_gnuc_varargs=$g_have_gnuc_varargs
3387 g_have_iso_c_varargs=$g_have_iso_c_varargs
3388 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3389
3390 g_can_inline=$g_can_inline
3391 g_have_gnuc_visibility=$g_have_gnuc_visibility
3392 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3393
3394 if test x$ac_cv_c_bigendian = xyes; then
3395   g_byte_order=G_BIG_ENDIAN
3396   g_bs_native=BE
3397   g_bs_alien=LE
3398 else
3399   g_byte_order=G_LITTLE_ENDIAN
3400   g_bs_native=LE
3401   g_bs_alien=BE
3402 fi
3403
3404 g_pollin=$glib_cv_value_POLLIN
3405 g_pollout=$glib_cv_value_POLLOUT
3406 g_pollpri=$glib_cv_value_POLLPRI
3407 g_pollhup=$glib_cv_value_POLLHUP
3408 g_pollerr=$glib_cv_value_POLLERR
3409 g_pollnval=$glib_cv_value_POLLNVAL
3410
3411 # If a family is not found on the system, define that family to
3412 # a negative value, picking a different one for each undefined
3413 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3414 # This is needed because glib-mkenums doesn't handle optional
3415 # values in enums, and thus we have to have all existing values
3416 # defined in the enum.
3417 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3418   g_af_unix=$glib_cv_value_AF_UNIX
3419 else
3420   g_af_unix=-1
3421 fi
3422 g_af_inet=$glib_cv_value_AF_INET
3423 g_af_inet6=$glib_cv_value_AF_INET6
3424
3425 g_msg_peek=$glib_cv_value_MSG_PEEK
3426 g_msg_oob=$glib_cv_value_MSG_OOB
3427 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3428
3429 g_stack_grows=$glib_cv_stack_grows
3430
3431 g_have_eilseq=$have_eilseq
3432
3433 g_threads_impl_def=$g_threads_impl
3434
3435 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3436 g_memory_barrier_needed="$glib_memory_barrier_needed"
3437 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3438
3439 g_module_suffix="$glib_gmodule_suffix"
3440
3441 g_pid_type="$glib_pid_type"
3442 case $host in
3443   *-*-beos*)
3444     glib_os="#define G_OS_BEOS"
3445     ;;
3446   *-*-cygwin*)
3447     glib_os="#define G_OS_UNIX
3448 #define G_PLATFORM_WIN32
3449 #define G_WITH_CYGWIN"
3450     ;;
3451   *-*-mingw*)
3452     glib_os="#define G_OS_WIN32
3453 #define G_PLATFORM_WIN32"
3454     ;;
3455   *)
3456     glib_os="#define G_OS_UNIX"
3457     ;;
3458 esac
3459 glib_static_compilation=""
3460 if test x$glib_win32_static_compilation = xyes; then
3461   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3462 #define GOBJECT_STATIC_COMPILATION 1"
3463 fi
3464 ])
3465
3466 # Redo enough to get guint32 and guint64 for the alignment checks below
3467 case 4 in
3468 $ac_cv_sizeof_short)
3469   gint32=short
3470   ;;
3471 $ac_cv_sizeof_int)
3472   gint32=int
3473   ;;
3474 $ac_cv_sizeof_long)
3475   gint32=long
3476   ;;
3477 esac
3478 case 8 in
3479 $ac_cv_sizeof_int)
3480   gint64=int
3481   ;;
3482 $ac_cv_sizeof_long)
3483   gint64=long
3484   ;;
3485 $ac_cv_sizeof_long_long)
3486   gint64='long long'
3487   ;;
3488 $ac_cv_sizeof___int64)
3489   gint64='__int64'
3490   ;;
3491 esac
3492
3493 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3494 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3495 typedef unsigned $gint32 guint32;])
3496 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3497 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3498 typedef unsigned $gint64 guint64;])
3499 AC_CHECK_TYPE([unsigned long])
3500 AC_CHECK_ALIGNOF([unsigned long])
3501
3502 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3503 #
3504 # 1.2.14 required for dbus_message_set_serial
3505 AS_IF([ test x$enable_modular_tests = xyes], [
3506    PKG_CHECK_MODULES(DBUS1,
3507                      dbus-1 >= 1.2.14,
3508                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3509                      have_dbus1=no)
3510    AC_SUBST(DBUS1_CFLAGS)
3511    AC_SUBST(DBUS1_LIBS)
3512 ])
3513 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3514
3515 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3516 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3517
3518 dnl
3519 dnl Check for -Bsymbolic-functions linker flag used to avoid
3520 dnl intra-library PLT jumps, if available.
3521 dnl
3522
3523 AC_ARG_ENABLE(Bsymbolic,
3524               [AS_HELP_STRING([--disable-Bsymbolic],
3525                               [avoid linking with -Bsymbolic])],,
3526               [SAVED_LDFLAGS="${LDFLAGS}"
3527                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3528                LDFLAGS=-Wl,-Bsymbolic-functions
3529                AC_TRY_LINK([], [int main (void) { return 0; }],
3530                            AC_MSG_RESULT(yes)
3531                            enable_Bsymbolic=yes,
3532                            AC_MSG_RESULT(no)
3533                            enable_Bsymbolic=no)
3534                LDFLAGS="${SAVED_LDFLAGS}"])
3535
3536 if test "x${enable_Bsymbolic}" = "xyes"; then
3537   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3538 fi
3539
3540 AC_SUBST(GLIB_LINK_FLAGS)
3541
3542 dnl Compiler flags; macro originates from systemd
3543 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3544 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
3545    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3546    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3547    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3548    -Werror=format=2 -Werror=missing-include-dirs])
3549 CFLAGS="$CFLAGS $with_cflags"
3550
3551 #
3552 # Define variables corresponding to the correct include paths to use for
3553 # in-tree building.
3554 #
3555
3556 # for config.h:
3557 config_h_INCLUDES='-I$(top_builddir)'
3558 AC_SUBST(config_h_INCLUDES)
3559
3560 # glib:
3561 #   config.h
3562 #   $(top_builddir)/glib: for glibconfig.h
3563 #   $(top_srcdir)/glib:   for glib.h
3564 #   $(top_srcdir):        for everything
3565 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3566 AC_SUBST(glib_INCLUDES)
3567
3568 # gobject:
3569 #   same as glib
3570 gobject_INCLUDES='$(glib_INCLUDES)'
3571 AC_SUBST(gobject_INCLUDES)
3572
3573 # gmodule:
3574 #   glib includes
3575 #   $(top_srcdir)/gmodule: for gmodule.h
3576 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3577 AC_SUBST(gmodule_INCLUDES)
3578
3579 # gio:
3580 #   same as gmodule
3581 gio_INCLUDES='$(gmodule_INCLUDES)'
3582 AC_SUBST(gio_INCLUDES)
3583
3584
3585 AC_CONFIG_FILES([
3586 glib-2.0.pc
3587 gmodule-2.0.pc
3588 gmodule-export-2.0.pc
3589 gmodule-no-export-2.0.pc
3590 gthread-2.0.pc
3591 gobject-2.0.pc
3592 gio-2.0.pc
3593 gio-unix-2.0.pc
3594 gio-windows-2.0.pc
3595 glib-zip
3596 glib-gettextize
3597 Makefile
3598 build/Makefile
3599 build/win32/Makefile
3600 build/win32/dirent/Makefile
3601 build/win32/vs9/Makefile
3602 build/win32/vs10/Makefile
3603 build/win32/vs11/Makefile
3604 glib/Makefile
3605 glib/glib.stp
3606 glib/libcharset/Makefile
3607 glib/gnulib/Makefile
3608 glib/pcre/Makefile
3609 glib/update-pcre/Makefile
3610 glib/tests/Makefile
3611 gmodule/Makefile
3612 gmodule/gmoduleconf.h
3613 gobject/Makefile
3614 gobject/gobject.stp
3615 gobject/glib-mkenums
3616 gobject/tests/Makefile
3617 gthread/Makefile
3618 gio/Makefile
3619 gio/gdbus-2.0/codegen/Makefile
3620 gio/gdbus-2.0/codegen/config.py
3621 gio/xdgmime/Makefile
3622 gio/inotify/Makefile
3623 gio/kqueue/Makefile
3624 gio/fen/Makefile
3625 gio/fam/Makefile
3626 gio/win32/Makefile
3627 gio/tests/Makefile
3628 gio/tests/gdbus-object-manager-example/Makefile
3629 po/Makefile.in
3630 docs/Makefile
3631 docs/reference/Makefile
3632 docs/reference/glib/Makefile
3633 docs/reference/glib/version.xml
3634 docs/reference/gobject/Makefile
3635 docs/reference/gobject/version.xml
3636 docs/reference/gio/Makefile
3637 docs/reference/gio/gdbus-object-manager-example/Makefile
3638 docs/reference/gio/version.xml
3639 tests/Makefile
3640 tests/gobject/Makefile
3641 tests/refcount/Makefile
3642 m4macros/Makefile
3643 ])
3644
3645 AC_CONFIG_COMMANDS([chmod-scripts],
3646 [chmod 0755 glib-zip
3647 chmod 0755 glib-gettextize
3648 chmod 0755 gobject/glib-mkenums])
3649
3650 # we want to invoke this macro solely so that the config.status script
3651 # and automake generated makefiles know about these generated files.
3652 # They are only needed to distcheck the package
3653 if false; then
3654   AC_CONFIG_FILES([
3655     INSTALL
3656     README
3657     config.h.win32
3658     glib/glibconfig.h.win32
3659     glib/makefile.msc
3660     glib/glib.rc
3661     gmodule/makefile.msc
3662     gmodule/gmodule.rc
3663     gobject/makefile.msc
3664     gobject/gobject.rc
3665     gthread/makefile.msc
3666     gthread/gthread.rc
3667     gio/gio.rc
3668     tests/makefile.msc
3669   ])
3670 fi
3671
3672 AC_OUTPUT