configure.ac

   1 dnl These m4 macros are whitespace sensitive and break if moved around much.
   2 m4_define([LU_VERSION_H], m4_include([libusb/version.h]))
   3 m4_define([LU_DEFINE_VERSION_ATOM],
   4         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   5         [^#define\s*$1\s*\([0-9]*\).*], [\1]))])
   6 m4_define([LU_DEFINE_VERSION_RC_ATOM],
   7         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   8         [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))])
   9 dnl The m4_bregexp() returns (only) the numbers following the #define named
  10 dnl in the first macro parameter. m4_define() then defines the name for use
  11 dnl in AC_INIT.
  12
  13 LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR])
  14 LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR])
  15 LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO])
  16 LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC])
  17
  18 AC_INIT([libusb],[LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC],[libusb-devel@lists.sourceforge.net],[libusb],[http://libusb.info])
  19
  20 # Library versioning
  21 # These numbers should be tweaked on every release. Read carefully:
  22 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  23 # http://sourceware.org/autobook/autobook/autobook_91.html
  24 lt_current="1"
  25 lt_revision="0"
  26 lt_age="1"
  27 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  28
  29 AM_INIT_AUTOMAKE
  30
  31 AC_CONFIG_SRCDIR([libusb/core.c])
  32 AC_CONFIG_MACRO_DIR([m4])
  33 AC_CONFIG_HEADERS([config.h])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  35
  36 AC_PREREQ([2.69])
  37 AC_PROG_CC
  38 AC_PROG_CXX
  39 LT_INIT
  40 LT_LANG([Windows Resource])
  41 AC_C_INLINE
  42 AM_PROG_CC_C_O
  43 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  44
  45 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  46
  47 AC_MSG_CHECKING([operating system])
  48
  49 dnl on linux-android platform, some functions are in different places
  50 case $host in
  51 *-linux-android*)
  52         AC_MSG_RESULT([This is a Linux-Android system])
  53         is_backend_android="yes"
  54         ;;
  55 *)
  56         is_backend_android="no"
  57 esac
  58
  59 case $host in
  60 *-linux* | *-uclinux*)
  61         AC_MSG_RESULT([Linux])
  62         backend="linux"
  63         threads="posix"
  64         ;;
  65 *-darwin*)
  66         AC_MSG_RESULT([Darwin/Mac OS X])
  67         backend="darwin"
  68         threads="posix"
  69         ;;
  70 *-openbsd*)
  71         AC_MSG_RESULT([OpenBSD])
  72         backend="openbsd"
  73         threads="posix"
  74         ;;
  75 *-netbsd*)
  76         AC_MSG_RESULT([NetBSD])
  77         backend="netbsd"
  78         threads="posix"
  79         ;;
  80 *-mingw* | *msys*)
  81         AC_MSG_RESULT([Windows])
  82         backend="windows"
  83         threads="windows"
  84         create_import_lib="yes"
  85         AM_CFLAGS="${AM_CFLAGS} -fno-omit-frame-pointer"
  86         ;;
  87 *-cygwin*)
  88         AC_MSG_RESULT([Cygwin (using Windows backend)])
  89         backend="windows"
  90         threads="posix"
  91         ;;
  92 *-haiku*)
  93         AC_MSG_RESULT([Haiku])
  94         backend="haiku"
  95         threads="posix"
  96         ;;
  97 *)
  98         AC_MSG_ERROR([unsupported operating system])
  99 esac
 100
 101 case $backend in
 102 linux)
 103         AC_DEFINE(OS_LINUX, 1, [Linux backend])
 104         AC_SUBST(OS_LINUX)
 105         AC_SEARCH_LIBS(clock_gettime, rt, [], [], -pthread)
 106         AC_ARG_ENABLE([udev],
 107                 [AC_HELP_STRING([--enable-udev], [use udev for device enumeration and hotplug support (recommended) [default=yes]])],
 108                 [], [enable_udev="yes"])
 109                 if test "x$enable_udev" = "xyes" ; then
 110                         # system has udev. use it or fail!
 111                         AC_CHECK_HEADERS([libudev.h],[],[AC_ERROR(["udev support requested but libudev not installed"])])
 112                         AC_CHECK_LIB([udev], [udev_new], [], [AC_ERROR(["udev support requested but libudev not installed"])])
 113                         AC_DEFINE(USE_UDEV, 1, [Use udev for device enumeration/hotplug])
 114                 else
 115                         AC_CHECK_HEADERS([asm/types.h], [], [])
 116                         AC_CHECK_HEADERS([sys/socket.h linux/netlink.h], [], [AC_ERROR(["Linux netlink headers not found"])], [
 117 #ifdef HAVE_ASM_TYPES_H
 118 #include <asm/types.h>
 119 #endif
 120 #include <sys/socket.h>
 121 ])
 122                 fi
 123                 AC_SUBST(USE_UDEV)
 124
 125 case $is_backend_android in
 126 yes)
 127         dnl there are gettimeofday function but configure doesn't seem to be able to find it.
 128         AC_DEFINE([HAVE_GETTIMEOFDAY], [1], [Define if you have gettimeofday])
 129         ;;
 130 *)
 131         THREAD_CFLAGS="-pthread"
 132         LIBS="${LIBS} -pthread"
 133 esac
 134
 135         AC_CHECK_HEADERS([poll.h])
 136         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 137         ;;
 138 darwin)
 139         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
 140         AC_SUBST(OS_DARWIN)
 141         LIBS="-lobjc -Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
 142         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
 143         AC_CHECK_HEADERS([poll.h])
 144         AC_CHECK_TYPE([nfds_t],
 145                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
 146                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
 147                 [#include <poll.h>])
 148         ;;
 149 openbsd)
 150         AC_DEFINE(OS_OPENBSD, 1, [OpenBSD backend])
 151         AC_SUBST(OS_OPENBSD)
 152         THREAD_CFLAGS="-pthread"
 153         LIBS="-pthread"
 154         AC_CHECK_HEADERS([poll.h])
 155         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 156         ;;
 157 netbsd)
 158         AC_DEFINE(OS_NETBSD, 1, [NetBSD backend])
 159         AC_SUBST(OS_NETBSD)
 160         THREAD_CFLAGS="-pthread"
 161         LIBS="-pthread"
 162         AC_CHECK_HEADERS([poll.h])
 163         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 164         ;;
 165 windows)
 166         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
 167         AC_SUBST(OS_WINDOWS)
 168         LIBS=""
 169         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
 170         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
 171         AC_DEFINE([WINVER], 0x0501, [Oldest Windows version supported])
 172
 173         AC_ARG_ENABLE([usbdk],
 174                 [AC_HELP_STRING([--enable-usbdk], [use UsbDk Windows backend [default=no]])],
 175                 [], [enable_usbdk="no"])
 176                 if test "x$enable_usbdk" = "xyes" ; then
 177                     AC_DEFINE(USE_USBDK, 1, [Use UsbDk Windows backend])
 178                 fi
 179                 AC_SUBST(USE_USBDK)
 180         ;;
 181 haiku)
 182         AC_DEFINE(OS_HAIKU, 1, [Haiku backend])
 183         AC_SUBST(OS_HAIKU)
 184         LIBS="${LIBS} -lbe"
 185         AC_CHECK_HEADERS([poll.h])
 186         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 187         ;;
 188 esac
 189
 190 AC_SUBST(LIBS)
 191
 192 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
 193 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
 194 AM_CONDITIONAL(OS_OPENBSD, test "x$backend" = xopenbsd)
 195 AM_CONDITIONAL(OS_NETBSD, test "x$backend" = xnetbsd)
 196 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
 197 AM_CONDITIONAL(OS_HAIKU, test "x$backend" = xhaiku)
 198 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
 199 AM_CONDITIONAL(CREATE_IMPORT_LIB, test "x$create_import_lib" = "xyes")
 200 AM_CONDITIONAL(USE_UDEV, test "x$enable_udev" = xyes)
 201 AM_CONDITIONAL(USE_USBDK, test "x$enable_usbdk" = xyes)
 202 if test "$threads" = posix; then
 203         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
 204 fi
 205
 206 # timerfd
 207 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 208 AC_ARG_ENABLE([timerfd],
 209         [AS_HELP_STRING([--enable-timerfd],
 210                 [use timerfd for timing [default=auto]])],
 211         [use_timerfd=$enableval], [use_timerfd='auto'])
 212
 213 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 214         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 215 fi
 216
 217 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 218 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 219         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 220 fi
 221
 222 AC_MSG_CHECKING([whether to use timerfd for timing])
 223 if test "x$use_timerfd" = "xno"; then
 224         AC_MSG_RESULT([no (disabled by user)])
 225 else
 226         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 227                 AC_MSG_RESULT([yes])
 228                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 229         else
 230                 AC_MSG_RESULT([no (header not available)])
 231         fi
 232 fi
 233
 234 AC_CHECK_TYPES(struct timespec)
 235
 236 # Message logging
 237 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 238         [log_enabled=$enableval],
 239         [log_enabled='yes'])
 240 if test "x$log_enabled" != "xno"; then
 241         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 242 fi
 243
 244 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 245         [start with debug message logging enabled [default=no]])],
 246         [debug_log_enabled=$enableval],
 247         [debug_log_enabled='no'])
 248 if test "x$debug_log_enabled" != "xno"; then
 249         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Start with debug message logging enabled])
 250 fi
 251
 252 AC_ARG_ENABLE([system-log], [AS_HELP_STRING([--enable-system-log],
 253         [output logging messages to system wide log, if supported by the OS [default=no]])],
 254         [system_log_enabled=$enableval],
 255         [system_log_enabled='no'])
 256 if test "x$system_log_enabled" != "xno"; then
 257         AC_DEFINE([USE_SYSTEM_LOGGING_FACILITY], 1, [Enable output to system log])
 258 fi
 259
 260 # Check if syslog is available in standard C library
 261 AC_CHECK_HEADERS(syslog.h)
 262 AC_CHECK_FUNC([syslog], [have_syslog=yes], [have_syslog=no])
 263 if test "x$have_syslog" != "xno"; then
 264         AC_DEFINE([HAVE_SYSLOG_FUNC], 1, [syslog() function available])
 265 fi
 266
 267 # Examples build
 268 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 269         [build example applications [default=no]])],
 270         [build_examples=$enableval],
 271         [build_examples='no'])
 272 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 273
 274 # Tests build
 275 AC_ARG_ENABLE([tests-build], [AS_HELP_STRING([--enable-tests-build],
 276         [build test applications [default=no]])],
 277         [build_tests=$enableval],
 278         [build_tests='no'])
 279 AM_CONDITIONAL([BUILD_TESTS], [test "x$build_tests" != "xno"])
 280
 281 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 282 saved_cflags="$CFLAGS"
 283 # -Werror required for cygwin
 284 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 285 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 286         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 287          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 288         [ VISIBILITY_CFLAGS=""
 289          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 290         ])
 291 CFLAGS="$saved_cflags"
 292
 293 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 294 saved_cflags="$CFLAGS"
 295 CFLAGS="$CFLAGS -Wno-pointer-sign"
 296 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 297         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 298 CFLAGS="$saved_cflags"
 299
 300 # sigaction not available on MinGW
 301 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 302 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 303
 304 # headers not available on all platforms but required on others
 305 AC_CHECK_HEADERS([sys/time.h])
 306 AC_CHECK_FUNCS(gettimeofday)
 307 AC_CHECK_HEADERS([signal.h])
 308
 309 # check for -std=gnu99 compiler support
 310 saved_cflags="$CFLAGS"
 311 CFLAGS="-std=gnu99"
 312 AC_MSG_CHECKING([whether CC supports -std=gnu99])
 313 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 314     [AC_MSG_RESULT([yes])]
 315     [AM_CFLAGS="${AM_CFLAGS} -std=gnu99"],
 316     [AC_MSG_RESULT([no])]
 317 )
 318 CFLAGS="$saved_cflags"
 319
 320 AM_CFLAGS="${AM_CFLAGS} -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow ${THREAD_CFLAGS} ${VISIBILITY_CFLAGS}"
 321
 322 AC_SUBST(AM_CFLAGS)
 323 AC_SUBST(LTLDFLAGS)
 324
 325 AC_CONFIG_FILES([libusb-1.0.pc])
 326 AC_CONFIG_FILES([Makefile])
 327 AC_CONFIG_FILES([libusb/Makefile])
 328 AC_CONFIG_FILES([examples/Makefile])
 329 AC_CONFIG_FILES([tests/Makefile])
 330 AC_CONFIG_FILES([doc/Makefile])
 331 AC_CONFIG_FILES([doc/doxygen.cfg])
 332 AC_OUTPUT