configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([gupnp],
   3         [0.20.3],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=gupnp&component=gupnp],
   5         [gupnp],
   6         [http://www.gupnp.org/])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_SRCDIR([libgupnp/gupnp.h])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_CONFIG_AUX_DIR([build-aux])
  12
  13 AC_CANONICAL_HOST
  14 AC_CANONICAL_TARGET
  15
  16 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-xz])
  17 AM_MAINTAINER_MODE([enable])
  18
  19 AM_SILENT_RULES([yes])
  20
  21 # Check for programs
  22 AC_PROG_CC
  23 AC_FUNC_MMAP
  24 AC_SYS_LARGEFILE
  25
  26 # Initialize libtool
  27 LT_PREREQ([2.2])
  28 LT_INIT
  29
  30
  31 PKG_CHECK_MODULES(GTest, glib-2.0 >= 2.16, [gtest=yes], [gtest=no])
  32 AM_CONDITIONAL(HAVE_GTEST, [test x$gtest = xyes])
  33
  34 AC_MSG_CHECKING([operating system])
  35 os_win32=no
  36 case "$target_os" in
  37      mingw*|cygwin*)
  38         os_win32=yes
  39         AC_MSG_RESULT(Win32)
  40         UUID=
  41         ;;
  42      darwin*)
  43         AC_MSG_RESULT(Darwin)
  44         UUID=
  45         ;;
  46      *)
  47         AC_MSG_RESULT($target_os)
  48         UUID=uuid
  49         ;;
  50 esac
  51
  52 PKG_CHECK_MODULES(LIBGUPNP, glib-2.0 >= 2.24.0 \
  53                             gio-2.0 \
  54                             gmodule-2.0 \
  55                             gssdp-1.0 >= 0.13.0 \
  56                             libsoup-2.4 >= 2.28.2 \
  57                             libxml-2.0 \
  58                             $UUID)
  59 PKG_CHECK_MODULES(GTHREAD, gthread-2.0)
  60
  61 AM_CONDITIONAL(OS_WIN32, test "x$os_win32" = "xyes")
  62 if test "x$os_win32" = "xno"; then
  63     AC_ARG_WITH([context_manager],
  64             AS_HELP_STRING(
  65                         [--with-context-manager=@<:@network-manager/connman/unix/linux@:>@],
  66                         [Context Manager backend to use]),,
  67             [with_context_manager="none"])
  68 else
  69     LIBGUPNP_LIBS="$LIBGUPNP_LIBS -lrpcrt4"
  70     with_context_manager="windows"
  71 fi
  72
  73 if test "x$with_context_manager" = "xnone"; then
  74         case "$target_os" in
  75         linux*)
  76                 with_context_manager="linux"
  77                 ;;
  78         *)
  79                 with_context_manager="unix"
  80                 ;;
  81         esac
  82 fi
  83
  84 AC_CHECK_HEADERS([sys/socket.h linux/rtnetlink.h],
  85                 [ HAVE_NETLINK=yes ],
  86                 [ HAVE_NETLINK=no ],
  87                 [ #ifdef HAVE_SYS_SOCKET_H
  88                   #include <sys/socket.h>
  89                   #endif
  90                 ])
  91 AM_CONDITIONAL([HAVE_NETLINK], [test "x$HAVE_NETLINK" = "xyes"])
  92 AC_SUBST(HAVE_NETLINK)
  93
  94 AC_CHECK_HEADERS([linux/wireless.h], [], [],
  95                 [ #ifdef HAVE_SYS_SOCKET_H
  96                   #include <sys/socket.h>
  97                   #endif
  98                 ])
  99
 100 AC_MSG_CHECKING([Context Manager backend to use])
 101 AC_MSG_RESULT([${with_context_manager}])
 102
 103 AM_CONDITIONAL([USE_NETWORK_MANAGER],
 104                [test "x$with_context_manager" = "xnetwork-manager"])
 105 AS_IF([test "x$with_context_manager" = "xnetwork-manager"],
 106       [PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.26)])
 107
 108 AM_CONDITIONAL([USE_CONNMAN],
 109                [test "x$with_context_manager" = "xconnman"])
 110
 111 if test "x$with_context_manager" = "xconnman"; then
 112         PKG_CHECK_MODULES(CONNMAN, glib-2.0 >= 2.28 connman >= 0.80)
 113 fi
 114
 115 USE_NETLINK=no
 116 AS_IF([test "x$with_context_manager" = "xlinux"],
 117       [AS_IF([test "x$HAVE_NETLINK" = "xno"],
 118              [AC_MSG_NOTICE([No rtnetlink found, falling back to static context manager])],
 119              [USE_NETLINK=yes])
 120       ],[])
 121
 122 AM_CONDITIONAL(USE_NETLINK, test "x$USE_NETLINK" = "xyes")
 123 AC_SUBST(USE_NETLINK)
 124
 125 # glib-genmarshal
 126 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
 127 AC_SUBST(GLIB_GENMARSHAL)
 128
 129 # Debugging
 130 AC_ARG_ENABLE(debug,
 131         AS_HELP_STRING([--enable-debug], [enable debugging]),,
 132         enable_debug=no)
 133 if test "x$enable_debug" = "xyes"; then
 134         CFLAGS="$CFLAGS -g -Wall -Werror"
 135 fi
 136
 137 GOBJECT_INTROSPECTION_CHECK([0.6.4])
 138
 139 # vapigen
 140 have_vapigen=no
 141 AS_IF([test "x$found_introspection" = "xyes"],
 142       [
 143        dnl output of g-i >= 1.36.0 needs vapigen >= 0.20 to process
 144        AC_MSG_CHECKING([whether G-I is 1.36 or newer])
 145        VAPIGEN_MIN_VERSION=0.14
 146        AS_IF([pkg-config --atleast-version=1.36.0 gobject-introspection-1.0],
 147              [
 148               AC_MSG_RESULT([yes])
 149               VAPIGEN_MIN_VERSION=0.20
 150              ],[AC_MSG_RESULT([no])]
 151        )
 152        GUPNP_PROG_VAPIGEN([$VAPIGEN_MIN_VERSION])
 153       ]
 154 )
 155 AS_IF([test "x$VAPIGEN" != "x"], [have_vapigen=yes])
 156 AM_CONDITIONAL([HAVE_VAPIGEN], [test "x$VAPIGEN" != "x"])
 157
 158 # Gtk-doc
 159 GTK_DOC_CHECK([1.0])
 160
 161 AC_CONFIG_FILES([
 162 Makefile
 163 libgupnp/Makefile
 164 examples/Makefile
 165 tools/Makefile
 166 tests/Makefile
 167 tests/gtest/Makefile
 168 doc/Makefile
 169 doc/version.xml
 170 vala/Makefile
 171 gupnp-1.0.pc
 172 gupnp-1.0-uninstalled.pc
 173 ])
 174 AC_OUTPUT
 175
 176 echo "
 177     ${PACKAGE} ${VERSION}
 178     ---------------------
 179
 180     Prefix:                ${prefix}
 181     GObject-Introspection: ${found_introspection}
 182     VALA bindings:         ${have_vapigen}
 183     Context manager:       ${with_context_manager}
 184 "