configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [0])
   4 m4_define([v_min], [2])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 m4_define([relname], [ver-pre-svn-07])
  12 m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])],
  15 [m4_define([v_ver], [v_maj.v_min.v_mic])])
  16 m4_define([lt_rev], m4_eval(v_maj + v_min))
  17 m4_define([lt_cur], v_mic)
  18 m4_define([lt_age], v_min)
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  21
  22 AC_INIT([emotion], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  23 AC_PREREQ([2.60])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_MACRO_DIR([m4])
  26 AC_CANONICAL_BUILD
  27 AC_CANONICAL_HOST
  28 AC_ISC_POSIX
  29
  30 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  31 AM_CONFIG_HEADER([config.h])
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33
  34 AC_LIBTOOL_WIN32_DLL
  35 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  36 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  37 AC_PROG_LIBTOOL
  38
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  41 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  42 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  43 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  44 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  45 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  46 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  47 version_info="lt_rev:lt_cur:lt_age"
  48 release_info="v_rel"
  49 AC_SUBST(version_info)
  50 AC_SUBST(release_info)
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  53 VMAJ=v_maj
  54 AC_SUBST(VMAJ)
  55
  56 want_generic="yes"
  57 case "$host_os" in
  58    mingw* | cegcc*)
  59       want_xine="no"
  60       want_gstreamer="yes"
  61       want_generic_vlc="no"
  62       ;;
  63    *)
  64       want_xine="yes"
  65       want_gstreamer="yes"
  66       want_generic_vlc="yes"
  67       ;;
  68 esac
  69
  70 requirement_emotion=""
  71
  72 ### Additional options to configure
  73
  74 EFL_ENABLE_BIN([emotion-test])
  75
  76 # edje_cc
  77
  78 AC_ARG_WITH([edje-cc],
  79    [AC_HELP_STRING([--with-edje-cc=PATH], [specify a specific path to edje_cc])],
  80    [
  81     v=$withval;
  82     edje_cc=$v
  83     echo "  Enlightenment edje_cc explicitly set to "$edje_cc;
  84    ],
  85    [edje_cc=$(pkg-config --variable=prefix edje)/bin/edje_cc])
  86 AC_SUBST(edje_cc)
  87
  88
  89 ### Checks for programs
  90 AC_PROG_CC
  91
  92 # pkg-config
  93 PKG_PROG_PKG_CONFIG
  94
  95 # Check whether pkg-config supports Requires.private
  96 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
  97    pkgconfig_requires_private="Requires.private"
  98 else
  99    pkgconfig_requires_private="Requires"
 100 fi
 101 AC_SUBST(pkgconfig_requires_private)
 102
 103 # doxygen program for documentation building
 104
 105 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 106
 107
 108 ### Checks for libraries
 109
 110 PKG_CHECK_MODULES(EMOTION, [eina >= 1.0.0 evas >= 1.0.0 ecore >= 1.0.0 eet >= 1.4.0])
 111 requirement_emotion="ecore >= 1.0.0 evas >= 1.0.0 eina >= 1.0.0 eet >= 1.4.0"
 112
 113 if test "x${have_emotion_test}" = "xyes" ; then
 114    PKG_CHECK_MODULES(EMOTION_BIN, [eina >= 1.0.0 evas >= 1.0.0 ecore >= 1.0.0 ecore-evas >= 1.0.0 edje >= 1.0.0])
 115 fi
 116
 117 PKG_CHECK_MODULES(ECORE_X, [ecore-x >= 1.0.0 ecore-evas >= 1.0.0], [have_ecore_x="yes"], [have_ecore_x="no"])
 118
 119 PKG_CHECK_MODULES(ECORE_FB, [ecore-fb >= 1.0.0], [have_ecore_fb="yes"], [have_ecore_fb="no"])
 120
 121 if test "x${have_ecore_x}" = "xyes" ; then
 122    AC_DEFINE(EMOTION_HAVE_ECORE_X, 1, [Define to 1 if Ecore_X is enabled])
 123 fi
 124
 125 if test "x${have_ecore_fb}" = "xyes" ; then
 126    AC_DEFINE(EMOTION_HAVE_ECORE_FB, 1, [Define to 1 if Ecore_Fb is enabled])
 127 fi
 128
 129 PKG_CHECK_EXISTS([evas-software-x11 >= 1.0.0], [AC_DEFINE(HAVE_EVAS_SOFWARE_X11, 1, [Evas Software Xlib Engine Support])])
 130
 131 PKG_CHECK_EXISTS([evas-xrender-x11 >= 1.0.0], [AC_DEFINE(HAVE_EVAS_XRENDER_X11, 1, [Evas Software Xlib Engine Support])])
 132
 133 PKG_CHECK_EXISTS([evas-opengl-x11 >= 1.0.0], [AC_DEFINE(HAVE_EVAS_OPENGL_X11, 1, [Evas OpenGL Xlib Engine Support])])
 134
 135 PKG_CHECK_EXISTS([evas-fb >= 1.0.0], [AC_DEFINE(HAVE_EVAS_FB, 1, [Evas Framebuffer Engine Support])])
 136
 137 EFL_EDJE_EXTERNAL([have_edje_external="yes"], [have_edje_external="no"])
 138
 139 PKG_CHECK_MODULES(EEZE, [eeze >= 1.0.99], [have_eeze="yes"], [have_eeze="no"])
 140
 141 if test "x${have_eeze}" = "xyes"; then
 142    AC_DEFINE(EMOTION_HAVE_EEZE, 1, [Define to 1 if Eeze is available])
 143    requirement_emotion="${requirement_emotion} eeze >= 1.0.99"
 144 fi
 145
 146 ### Checks for header files
 147 AC_HEADER_STDC
 148
 149 ### Checks for types
 150
 151
 152 ### Checks for structures
 153
 154
 155 ### Checks for compiler characteristics
 156 AC_C_CONST
 157 AC_C_BIGENDIAN
 158 AC_PROG_CC_STDC
 159 AC_C___ATTRIBUTE__
 160
 161 EFL_EMOTION_BUILD=""
 162 case "$host_os" in
 163    mingw32ce* | cegcc*)
 164       EMOTION_CPPFLAGS="-D_WIN32_WCE=0x0420"
 165       EFL_EMOTION_BUILD="-DEFL_EMOTION_BUILD"
 166       ;;
 167    mingw*)
 168       EMOTION_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 169       EFL_EMOTION_BUILD="-DEFL_EMOTION_BUILD"
 170       ;;
 171 esac
 172 AC_SUBST(EFL_EMOTION_BUILD)
 173 AC_SUBST(EMOTION_CPPFLAGS)
 174
 175
 176 ### Checks for linker characteristics
 177
 178 # use --enable-auto-import on Windows
 179
 180 lt_enable_auto_import=""
 181 case "$host_os" in
 182    mingw* | cegcc*)
 183       lt_enable_auto_import="-Wl,--enable-auto-import"
 184       ;;
 185 esac
 186 AC_SUBST(lt_enable_auto_import)
 187
 188 ### Check for video4linux
 189
 190 AC_COMPILE_IFELSE(
 191    [AC_LANG_PROGRAM(
 192        [[
 193 #include <stdio.h>
 194 #include <linux/videodev2.h>
 195        ]],
 196        [[
 197 fprintf(stdout, "%i\n", V4L2_CAP_VIDEO_CAPTURE);
 198        ]])],
 199    [
 200      AC_DEFINE(HAVE_V4L2, 1, [Define to 1 if you have Video4Linux 2 available])
 201      have_v4l2="yes"
 202    ],
 203    [have_v4l2="no"])
 204 AC_MSG_CHECKING([for V4L2])
 205 AC_MSG_RESULT([${have_v4l2}])
 206
 207 ### Modules
 208
 209 EMOTION_CHECK_MODULE([Xine], [${want_xine}])
 210 EMOTION_CHECK_MODULE([Gstreamer], [${want_gstreamer}])
 211 EMOTION_CHECK_MODULE([Generic], [${want_generic}])
 212
 213 EMOTION_CHECK_GENERIC_PLAYER([VLC], [${want_generic_vlc}])
 214
 215 if test "x${enable_xine}" = "xno" && test "x${enable_gstreamer}" = "xno" && test "x${enable_generic}" = "xno" ; then
 216    AC_MSG_ERROR([Xine, Gstreamer or Generic backends must be selected to build Emotion])
 217 fi
 218
 219
 220 PKG_CHECK_MODULES([EIO],
 221         [eio],
 222         [
 223          have_eio="yes"
 224          AC_DEFINE(HAVE_EIO, 1, [Use EIO for asynchronous file access])
 225          requirement_emotion="eio ${requirement_emotion}"
 226         ],
 227         [have_eio="no"])
 228
 229 AM_CONDITIONAL([HAVE_EIO], [test "x${have_eio}" = "xyes"])
 230
 231 ## Check Ecore-X availability, used for XV, VAAPI, VDPAU output.
 232
 233 have_ecore_x="no"
 234 want_ecore_x="auto"
 235 AC_ARG_ENABLE([ecore-x],
 236    [AC_HELP_STRING([--disable-ecore-x], [disable ecore-x support. @<:@default=detect@:>@])],
 237    [want_ecore_x=$enableval], [])
 238
 239 if test "x$want_ecore_x" != "xno"; then
 240    PKG_CHECK_MODULES([ECORE_X],
 241       [ecore-x >= 1.0.0],
 242       [
 243        AC_DEFINE(HAVE_ECORE_X, 1, [X11 support for Ecore])
 244        have_ecore_x="yes"
 245        requirement_elm="ecore-x >= 1.0.0 ${requirement_elm}"
 246       ],
 247       [have_ecore_x="no"]
 248    )
 249 else
 250     have_ecore_x="no"
 251 fi
 252 if test "x$want_ecore_x" = "xyes" -a "x$have_ecore_x" = "xno"; then
 253     AC_MSG_ERROR([ecore-x support requested, but not found by pkg-config.])
 254 fi
 255
 256 ## Check if gstreamer X Overlay is available
 257 build_xoverlay="no"
 258 if test "x$enable_gstreamer" = "xyes"; then
 259    PKG_CHECK_MODULES([GSTREAMER_INTERFACE],
 260         [ gstreamer-interfaces-0.10 >= 0.10.34 ],
 261         [ build_xoverlay="yes" ],
 262         [ build_xoverlay="no" ]
 263    )
 264    if test "x${build_xoverlay}" = "xyes"; then
 265       save_CPPFLAGS=$CPPFLAGS
 266       CPPFLAGS="$CPPFLAGS ${GSTREAMER_CFLAGS} ${GSTREAMER_INTERFACE_CFLAGS}"
 267       AC_CHECK_HEADER([gst/interfaces/xoverlay.h],
 268         [
 269           AC_DEFINE(HAVE_XOVERLAY_H, 1, [Build with Gstreamer Xoverlay support])
 270           build_xoverlay="yes"
 271         ], [
 272           build_xoverlay="no"
 273         ]
 274       )
 275       CPPFLAGS=$save_CPPFLAGS
 276
 277       save_LDFLAGS=$LDFLAGS
 278       LDFLAGS="$LDFLAGS ${GSTREAMER_INTERFACES}"
 279       AC_CHECK_LIB(gstinterfaces-0.10, gst_x_overlay_set_window_handle, AC_DEFINE(HAVE_X_OVERLAY_SET, 1, [Use gst_x_overlay_set_window_handle instead of old deprecated gst_x_overlay_set_xwindow_id]))
 280       LDFLAGS=$sava_LDFLAGS
 281    fi
 282 fi
 283
 284 ### install and build examples
 285
 286 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
 287 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
 288
 289 AC_SUBST(requirement_emotion)
 290
 291 AC_OUTPUT([
 292 Makefile
 293 emotion.pc
 294 emotion.spec
 295 src/Makefile
 296 src/lib/Makefile
 297 src/modules/Makefile
 298 src/modules/xine/Makefile
 299 src/modules/gstreamer/Makefile
 300 src/modules/generic/Makefile
 301 src/edje_external/Makefile
 302 src/generic_players/Makefile
 303 src/generic_players/vlc/Makefile
 304 src/bin/Makefile
 305 src/examples/Makefile
 306 doc/Makefile
 307 doc/Doxyfile
 308 data/Makefile
 309 ])
 310
 311
 312 #####################################################################
 313 ## Info
 314
 315 echo
 316 echo
 317 echo
 318 echo "------------------------------------------------------------------------"
 319 echo "$PACKAGE $VERSION"
 320 echo "------------------------------------------------------------------------"
 321 echo
 322 echo "Configuration Options Summary:"
 323 echo
 324 echo "  Modules:"
 325 echo "    Xine...............: ${enable_xine}"
 326 echo "    Gstreamer..........: ${enable_gstreamer} (X: ${have_ecore_x}/${build_xoverlay})"
 327 echo "    Generic............: ${enable_generic}"
 328
 329 if test "x${enable_generic}" = "xyes" || test "x${enable_generic}" = "xstatic"; then
 330 echo
 331 echo "  Generic Players:"
 332 echo "    VLC................: ${enable_generic_vlc}"
 333 fi
 334
 335 echo
 336 echo "  Build emotion_test...: $have_emotion_test"
 337 echo "  edje_cc..............: ${edje_cc}"
 338 echo
 339 echo "  Edje EXTERNAL support: ${have_edje_external}"
 340 echo
 341 echo "  Eio..................: ${have_eio}"
 342 echo "  V4L2.................: ${have_v4l2}"
 343 echo
 344 echo "Documentation..........: ${build_doc}"
 345 echo "Examples.............: ${enable_build_examples}"
 346 echo "Examples installed...: ${enable_install_examples}"
 347 echo
 348 echo "Compilation............: make (or gmake)"
 349 echo "  CPPFLAGS.............: $CPPFLAGS"
 350 echo "  CFLAGS...............: $CFLAGS"
 351 echo "  LDFLAGS..............: $LDFLAGS"
 352 echo
 353 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 354 echo "  prefix...............: $prefix"
 355 echo
 356 if test "x${have_static_module}" = "xyes" ; then
 357 echo -e "\0033\01331;31mWarning\0033\01331;0m: You are trying to link statically one or more modules to Emotion."
 358 echo "         You must know what you are doing, or else you will have a lot of problems."
 359 echo "         And asparagus will disappear from the earth."
 360 echo "         Think about that."
 361 echo
 362 fi