configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [5])
   4 m4_define([gst_vaapi_micro_version], [0])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # gstreamer-vaapi library (libtool) version number
  13 m4_define([gst_vaapi_lt_current],  [1])
  14 m4_define([gst_vaapi_lt_revision], [0])
  15 m4_define([gst_vaapi_lt_age],      [0])
  16
  17 # glib version number
  18 m4_define([glib_major_version], [2])
  19 m4_define([glib_minor_version], [28])
  20 m4_define([glib_micro_version], [0])
  21 m4_define([glib_major_minor_version],
  22           [glib_major_version.glib_minor_version])
  23 m4_define([glib_version],
  24           [glib_major_version.glib_minor_version.glib_micro_version])
  25
  26 # gst version number
  27 m4_define([gst_major_version], [0])
  28 m4_define([gst_minor_version], [10])
  29 m4_define([gst_micro_version], [36])
  30 m4_define([gst_major_minor_version],
  31           [gst_major_version.gst_minor_version])
  32 m4_define([gst_version],
  33           [gst_major_version.gst_minor_version.gst_micro_version])
  34
  35 # gst plugins-base version number
  36 m4_define([gst_plugins_base_major_version], [0])
  37 m4_define([gst_plugins_base_minor_version], [10])
  38 m4_define([gst_plugins_base_micro_version], [31])
  39 m4_define([gst_plugins_base_version],
  40           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  41
  42 # gst plugins-bad version number
  43 m4_define([gst_plugins_bad_major_version], [0])
  44 m4_define([gst_plugins_bad_minor_version], [10])
  45 m4_define([gst_plugins_bad_micro_version], [22])
  46 m4_define([gst_plugins_bad_version],
  47           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
  48
  49 # Wayland minimum version number
  50 m4_define([wayland_api_version], [1.0.0])
  51
  52 # VA-API minimum version number
  53 m4_define([va_api_version],     [0.30.4])
  54 m4_define([va_api_drm_version], [0.33.0])
  55 m4_define([va_api_x11_version], [0.31.0])
  56 m4_define([va_api_glx_version], [0.32.0])
  57 m4_define([va_api_wld_version], [0.33.0])
  58
  59 # libva package version number
  60 m4_define([libva_drm_package_version], [1.1.0])
  61 m4_define([libva_x11_package_version], [1.0.3])
  62 m4_define([libva_glx_package_version], [1.0.9])
  63 m4_define([libva_wld_package_version], [1.1.0])
  64
  65 # gtk-doc version number
  66 # XXX: introspection annotations require gtk-doc >= 1.12
  67 m4_define([gtkdoc_major_version], [1])
  68 m4_define([gtkdoc_minor_version], [9])
  69 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  70
  71 AC_PREREQ([2.58])
  72 AC_INIT([gst_vaapi], [gst_vaapi_version],
  73     [gwenole.beauchesne@intel.com],
  74     [gstreamer-vaapi])
  75
  76 AC_CONFIG_HEADERS([config.h])
  77 AC_CONFIG_SRCDIR([Makefile.am])
  78 AC_CONFIG_MACRO_DIR([m4])
  79 AC_CONFIG_AUX_DIR([build-aux])
  80
  81 AC_CANONICAL_TARGET
  82
  83 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-bzip2])
  84
  85 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  86 AC_SUBST(TODAY)
  87
  88 GST_VAAPI_MAJOR_VERSION=gst_vaapi_lt_current
  89 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  90
  91 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  92 AC_SUBST(LIBVA_PACKAGE_VERSION)
  93
  94 WAYLAND_API_VERSION=wayland_api_version
  95 AC_SUBST(WAYLAND_API_VERSION)
  96
  97 dnl Versions for GStreamer and plugins-base
  98 GST_MAJORMINOR=gst_major_minor_version
  99 GST_VERSION_REQUIRED=gst_version
 100 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
 101 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
 102 AC_SUBST(GST_MAJORMINOR)
 103 AC_SUBST(GST_VERSION_REQUIRED)
 104 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
 105 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
 106
 107 dnl Use pretty build output with automake >= 1.11
 108 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
 109   AM_DEFAULT_VERBOSITY=1
 110   AC_SUBST(AM_DEFAULT_VERBOSITY)
 111 ])
 112
 113 dnl Check for tools
 114 AC_PROG_CC
 115 AM_PROG_CC_C_O
 116
 117 dnl Initialize libtool
 118 LT_PREREQ([2.2])
 119 LT_INIT
 120
 121 AC_ARG_ENABLE(drm,
 122     AS_HELP_STRING([--enable-drm],
 123                    [enable DRM backend @<:@default=yes@:>@]),
 124     [], [enable_drm="yes"])
 125
 126 AC_ARG_ENABLE(x11,
 127     AS_HELP_STRING([--enable-x11],
 128                    [enable X11 output @<:@default=yes@:>@]),
 129     [], [enable_x11="yes"])
 130
 131 AC_ARG_ENABLE(glx,
 132     AS_HELP_STRING([--enable-glx],
 133                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
 134     [], [enable_glx="yes"])
 135
 136 AC_ARG_ENABLE(wayland,
 137     AC_HELP_STRING([--enable-wayland],
 138                    [enable Wayland output @<:@default=yes@:>@]),
 139     [], [enable_wayland="yes"])
 140
 141 dnl Check for basic libraries
 142 AC_CHECK_LIB(m, tan)
 143
 144 dnl Check for Gtk doc
 145 GTKDOC_VERSION=gtkdoc_version
 146 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 147 m4_ifdef([GTK_DOC_CHECK], [
 148 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 149 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 150 AC_SUBST(GTKDOC_VERSION)
 151
 152 dnl Check for GLib
 153 GLIB_VERSION_REQUIRED=glib_version
 154 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 155 AC_SUBST(GLIB_VERSION_REQUIRED)
 156
 157 dnl ---------------------------------------------------------------------------
 158 dnl -- GStreamer                                                             --
 159 dnl ---------------------------------------------------------------------------
 160
 161 dnl GStreamer Core
 162 PKG_CHECK_MODULES([GST],      [gstreamer-$GST_MAJORMINOR >= gst_version])
 163 PKG_CHECK_MODULES([GST_BASE], [gstreamer-base-$GST_MAJORMINOR >= gst_version])
 164
 165 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 166     saved_CFLAGS="$CFLAGS"
 167     CFLAGS="$CFLAGS $GST_BASE_CFLAGS"
 168     saved_LIBS="$LIBS"
 169     LIBS="$LIBS $GST_BASE_LIBS"
 170     AC_COMPILE_IFELSE(
 171         [AC_LANG_PROGRAM(
 172             [[#include <gst/base/gstbasesink.h>]],
 173             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 174         [ac_cv_have_gst_base_sink_query="yes"],
 175         [ac_cv_have_gst_base_sink_query="no"]
 176     )
 177     CFLAGS="$saved_CFLAGS"
 178     LIBS="$saved_LIBS"
 179 ])
 180 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 181     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 182 fi
 183
 184 dnl GStreamer -base plugins
 185 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 186     [gstreamer-plugins-base-$GST_MAJORMINOR >= gst_plugins_base_version])
 187 PKG_CHECK_MODULES([GST_INTERFACES],
 188     [gstreamer-interfaces-$GST_MAJORMINOR >= gst_plugins_base_version])
 189
 190 dnl ... GstVideoOverlayComposition (gstreamer-video)
 191 PKG_CHECK_MODULES([GST_VIDEO],
 192     [gstreamer-video-$GST_MAJORMINOR >= gst_plugins_base_version])
 193
 194 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 195     ac_cv_have_gst_video_overlay_composition, [
 196     saved_CFLAGS="$CFLAGS"
 197     CFLAGS="$CFLAGS $GST_CFLAGS"
 198     saved_LIBS="$LIBS"
 199     LIBS="$LIBS $GST_LIBS"
 200     AC_COMPILE_IFELSE(
 201         [AC_LANG_PROGRAM(
 202             [[#include <gst/video/video-overlay-composition.h>]],
 203             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
 204         [ac_cv_have_gst_video_overlay_composition="yes"],
 205         [ac_cv_have_gst_video_overlay_composition="no"]
 206     )
 207     CFLAGS="$saved_CFLAGS"
 208     LIBS="$saved_LIBS"
 209 ])
 210 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 211     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 212 fi
 213
 214 dnl GStreamer -bad plugins
 215 PKG_CHECK_MODULES([GST_BASEVIDEO],
 216     [gstreamer-basevideo-$GST_MAJORMINOR >= gst_plugins_bad_version])
 217
 218 dnl ... bitstream parsers
 219 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 220     [gstreamer-codecparsers-$GST_MAJORMINOR >= gst_plugins_bad_version])
 221
 222 dnl ... MPEG-2 parser, with the required extensions
 223 AC_CACHE_CHECK([for MPEG-2 parser],
 224     ac_cv_have_gst_mpeg2_parser, [
 225     saved_CPPFLAGS="$CPPFLAGS"
 226     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 227     saved_LIBS="$LIBS"
 228     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 229     AC_COMPILE_IFELSE(
 230         [AC_LANG_PROGRAM(
 231             [[#include <gst/codecparsers/gstmpegvideoparser.h>]],
 232             [[GstMpegVideoSequenceHdr seq_hdr;
 233               GstMpegVideoSequenceExt seq_ext;
 234               GstMpegVideoSequenceDisplayExt seq_dpy;
 235               gst_mpeg_video_finalise_mpeg2_sequence_header(&seq_hdr,
 236                   &seq_ext, &seq_dpy);]])],
 237         [ac_cv_have_gst_mpeg2_parser="yes"],
 238         [ac_cv_have_gst_mpeg2_parser="no"]
 239     )
 240     CPPFLAGS="$saved_CPPFLAGS"
 241     LIBS="$saved_LIBS"
 242 ])
 243 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_MPEG2],
 244     [test "$ac_cv_have_gst_mpeg2_parser" != "yes"])
 245
 246 dnl ... H.264 parser, with the required extensions
 247 AC_CACHE_CHECK([for H.264 parser],
 248     ac_cv_have_gst_h264_parser, [
 249     saved_CPPFLAGS="$CPPFLAGS"
 250     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 251     saved_LIBS="$LIBS"
 252     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 253     AC_COMPILE_IFELSE(
 254         [AC_LANG_PROGRAM(
 255             [[#include <gst/codecparsers/gsth264parser.h>]],
 256             [[GstH264SliceHdr slice_hdr;
 257               GstH264VUIParams vui_params;
 258               slice_hdr.n_emulation_prevention_bytes = 0;
 259               vui_params.par_n = 0;
 260               vui_params.par_d = 0;]])],
 261         [ac_cv_have_gst_h264_parser="yes"],
 262         [ac_cv_have_gst_h264_parser="no"]
 263     )
 264     CPPFLAGS="$saved_CPPFLAGS"
 265     LIBS="$saved_LIBS"
 266 ])
 267 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_H264],
 268     [test "$ac_cv_have_gst_h264_parser" != "yes"])
 269
 270 dnl ... JPEG parser, not upstream yet
 271 AC_CACHE_CHECK([for JPEG parser],
 272     ac_cv_have_gst_jpeg_parser, [
 273     saved_CPPFLAGS="$CPPFLAGS"
 274     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 275     saved_LIBS="$LIBS"
 276     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 277     AC_COMPILE_IFELSE(
 278         [AC_LANG_PROGRAM(
 279             [[#include <gst/codecparsers/gstjpegparser.h>]],
 280             [[GstJpegImage jpeg_image;]])],
 281         [ac_cv_have_gst_jpeg_parser="yes"],
 282         [ac_cv_have_gst_jpeg_parser="no"]
 283     )
 284     CPPFLAGS="$saved_CPPFLAGS"
 285     LIBS="$saved_LIBS"
 286 ])
 287 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_JPEG],
 288     [test "$ac_cv_have_gst_jpeg_parser" != "yes"])
 289
 290 dnl GST_VAAPI_LT_LDFLAGS:
 291 GST_VAAPI_LT_CURRENT=gst_vaapi_lt_current
 292 GST_VAAPI_LT_REV=gst_vaapi_lt_revision
 293 GST_VAAPI_LT_AGE=gst_vaapi_lt_age
 294 GST_VAAPI_LT_VERSION="$GST_VAAPI_LT_CURRENT:$GST_VAAPI_LT_REV:$GST_VAAPI_LT_AGE"
 295 GST_VAAPI_LT_LDFLAGS="-version-info $GST_VAAPI_LT_VERSION"
 296 AC_SUBST(GST_VAAPI_LT_VERSION)
 297 AC_SUBST(GST_VAAPI_LT_LDFLAGS)
 298
 299 dnl GST_ALL_LDFLAGS:
 300 dnl LDFLAGS really should only contain flags, not libs - they get added before
 301 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 302 GST_ALL_LDFLAGS="-no-undefined"
 303 AC_SUBST(GST_ALL_LDFLAGS)
 304
 305 dnl GST_PLUGIN_LDFLAGS:
 306 dnl this really should only contain flags, not libs - they get added before
 307 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 308 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 309 AC_SUBST(GST_PLUGIN_LDFLAGS)
 310
 311 dnl Check for the GStreamer plugins directory
 312 AC_ARG_VAR([GST_PLUGIN_PATH], [installation path for gstreamer-vaapi plugin elements])
 313 AC_MSG_CHECKING([for GStreamer plugins directory])
 314 if test -d "$GST_PLUGIN_PATH"; then
 315     GST_PLUGINS_DIR="$GST_PLUGIN_PATH"
 316 else
 317     GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 318     if test -z "$GST_PLUGINS_DIR"; then
 319         GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 320     fi
 321 fi
 322 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 323 plugindir="$GST_PLUGINS_DIR"
 324 AC_SUBST(plugindir)
 325
 326 dnl ---------------------------------------------------------------------------
 327 dnl -- Renderers                                                             --
 328 dnl ---------------------------------------------------------------------------
 329
 330 dnl Check for DRM/libudev
 331 USE_DRM=0
 332 if test "$enable_drm" = "yes"; then
 333     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
 334     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
 335
 336     if test $USE_DRM -eq 1; then
 337         saved_CPPFLAGS="$CPPFLAGS"
 338         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 339         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
 340         CPPFLAGS="$saved_CPPFLAGS"
 341     fi
 342 fi
 343
 344 dnl Check for X11
 345 USE_X11=0
 346 if test "$enable_x11" = "yes"; then
 347     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 348     if test $USE_X11 -eq 1; then
 349         saved_CPPFLAGS="$CPPFLAGS"
 350         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 351         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 352         CPPFLAGS="$saved_CPPFLAGS"
 353     fi
 354 fi
 355
 356 dnl Check for XRandR
 357 HAVE_XRANDR=0
 358 if test $USE_X11 -eq 1; then
 359     HAVE_XRANDR=1
 360     PKG_CHECK_MODULES([XRANDR], [xrandr], [:], [HAVE_XRANDR=0])
 361     if test $HAVE_XRANDR -eq 1; then
 362         saved_CPPFLAGS="$CPPFLAGS"
 363         CPPFLAGS="$CPPFLAGS $XRANDR_CFLAGS"
 364         AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [:], [HAVE_XRANDR=0])
 365         CPPFLAGS="$saved_CPPFLAGS"
 366     fi
 367 fi
 368 if test $HAVE_XRANDR -eq 1; then
 369     AC_DEFINE_UNQUOTED(HAVE_XRANDR, 1,
 370         [Defined to 1 if the XRandR extension exists.])
 371 fi
 372
 373 dnl OpenGL
 374 enable_opengl="no"
 375 if test "$enable_glx" = "yes"; then
 376     enable_opengl="yes"
 377 fi
 378
 379 HAVE_GL=0
 380 if test "$enable_opengl" = "yes"; then
 381     HAVE_GL=1
 382     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 383     saved_CPPFLAGS="$CPPFLAGS"
 384     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 385     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 386 #ifdef HAVE_GL_GL_H
 387 # include <GL/gl.h>
 388 #endif
 389     ])
 390     CPPFLAGS="$saved_CPPFLAGS"
 391 fi
 392
 393 dnl ... GLX
 394 USE_GLX=0
 395 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 396     USE_GLX=1
 397     saved_CPPFLAGS="$CPPFLAGS"
 398     saved_LIBS="$LIBS"
 399     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 400     LIBS="$LIBS $GL_LIBS"
 401     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 402 #ifdef HAVE_GL_GL_H
 403 # include <GL/gl.h>
 404 #endif
 405     ])
 406     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 407     CPPFLAGS="$saved_CPPFLAGS"
 408     LIBS="$saved_LIBS"
 409 fi
 410
 411 dnl Check for Wayland
 412 USE_WAYLAND=0
 413 if test "$enable_wayland" = "yes"; then
 414     PKG_CHECK_MODULES(WAYLAND, [wayland-client >= wayland_api_version],
 415         [USE_WAYLAND=1], [USE_WAYLAND=0])
 416
 417     if test $USE_WAYLAND -eq 1; then
 418         saved_CPPFLAGS="$CPPFLAGS"
 419         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 420         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
 421         CPPFLAGS="$saved_CPPFLAGS"
 422     fi
 423 fi
 424
 425 dnl ---------------------------------------------------------------------------
 426 dnl -- VA-API                                                                --
 427 dnl ---------------------------------------------------------------------------
 428
 429 dnl Core API
 430 LIBVA_PKGNAME="libva"
 431 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 432 AC_SUBST(LIBVA_PKGNAME)
 433
 434 VA_VERSION=`$PKG_CONFIG --modversion libva`
 435 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 436 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 437 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 438 VA_VERSION_STR="$VA_VERSION"
 439
 440 dnl VA/DRM API
 441 HAVE_VA_DRM=0
 442 if test $USE_DRM -eq 1; then
 443     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
 444         [HAVE_VA_DRM=1], [USE_DRM=0])
 445
 446     if test $HAVE_VA_DRM -eq 1; then
 447         saved_CPPFLAGS="$CPPFLAGS"
 448         CPPFLAGS="$LIBVA_DRM_CFLAGS"
 449         AC_CHECK_HEADERS([va/va_drm.h], [:], [HAVE_VA_DRM=0 USE_DRM=0])
 450         CPPFLAGS="$saved_CPPFLAGS"
 451     fi
 452 fi
 453
 454 dnl VA/X11 API
 455 HAVE_VA_X11=0
 456 LIBVA_X11_PKGNAME="libva-x11"
 457 if test $USE_X11 -eq 1; then
 458     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 459         [HAVE_VA_X11=1], [USE_X11=0])
 460 fi
 461 AC_SUBST(LIBVA_X11_PKGNAME)
 462
 463 dnl VA/GLX API
 464 HAVE_VA_GLX=0
 465 LIBVA_GLX_PKGNAME="libva-glx"
 466 if test $USE_GLX -eq 1; then
 467     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
 468         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
 469
 470     if test $HAVE_VA_GLX -eq 1; then
 471         saved_CPPFLAGS="$CPPFLAGS"
 472         CPPFLAGS="$LIBVA_GLX_CFLAGS"
 473         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
 474         CPPFLAGS="$saved_CPPFLAGS"
 475     fi
 476 fi
 477 AC_SUBST(LIBVA_GLX_PKGNAME)
 478
 479 dnl Check for JPEG decoding API (0.32.1+)
 480 USE_JPEG_DECODER=0
 481 AC_CACHE_CHECK([for JPEG decoding API],
 482     ac_cv_have_jpeg_decoding_api, [
 483     saved_CFLAGS="$CFLAGS"
 484     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 485     saved_LIBS="$LIBS"
 486     LIBS="$CFLAGS $LIBVA_LIBS"
 487     AC_COMPILE_IFELSE(
 488         [AC_LANG_PROGRAM(
 489             [[#include <va/va.h>]],
 490             [[VAPictureParameterBufferJPEGBaseline pic_param;
 491               VASliceParameterBufferJPEGBaseline slice_param;
 492               VAHuffmanTableBufferJPEGBaseline huffman_table;
 493               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
 494         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 495         [ac_cv_have_jpeg_decoding_api="no"]
 496     )
 497     CFLAGS="$saved_CFLAGS"
 498     LIBS="$saved_LIBS"
 499 ])
 500
 501 dnl VA/Wayland API
 502 if test "$enable_wayland" = "yes"; then
 503     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
 504         [:], [USE_WAYLAND=0])
 505 fi
 506
 507 dnl ---------------------------------------------------------------------------
 508 dnl -- Generate files and summary                                            --
 509 dnl ---------------------------------------------------------------------------
 510
 511 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
 512 *:1:*)
 513     ;;
 514 *)
 515     AC_MSG_ERROR([No renderer is enabled])
 516     ;;
 517 esac
 518
 519 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 520     [Defined to 1 if JPEG decoder is used])
 521 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 522
 523 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
 524     [Defined to 1 if DRM is enabled])
 525 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
 526
 527 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 528     [Defined to 1 if X11 is enabled])
 529 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 530
 531 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 532     [Defined to 1 if GLX is enabled])
 533 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 534
 535 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
 536     [Defined to 1 if WAYLAND is enabled])
 537 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
 538
 539 pkgconfigdir=${libdir}/pkgconfig
 540 AC_SUBST(pkgconfigdir)
 541
 542 AC_CONFIG_FILES([
 543     Makefile
 544     debian.upstream/Makefile
 545     debian.upstream/changelog
 546     debian.upstream/control
 547     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 548 debian.upstream/gstreamer-vaapi-doc.install.in
 549     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 550 debian.upstream/gstreamer-vaapi.install.in
 551     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 552 debian.upstream/libgstvaapi.install.in
 553     debian.upstream/libgstvaapi-dev.install
 554     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
 555 debian.upstream/libgstvaapi-drm.install.in
 556     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 557 debian.upstream/libgstvaapi-glx.install.in
 558     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
 559 debian.upstream/libgstvaapi-wayland.install.in
 560     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 561 debian.upstream/libgstvaapi-x11.install.in
 562     docs/Makefile
 563     docs/reference/Makefile
 564     docs/reference/libs/Makefile
 565     docs/reference/libs/libs-docs.xml
 566     docs/reference/plugins/Makefile
 567     docs/reference/plugins/plugins-docs.xml
 568     ext/Makefile
 569     gst-libs/Makefile
 570     gst-libs/gst/Makefile
 571     gst-libs/gst/codecparsers/Makefile
 572     gst-libs/gst/vaapi/Makefile
 573     gst/Makefile
 574     gst/vaapi/Makefile
 575     pkgconfig/Makefile
 576     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 577 pkgconfig/gstreamer-vaapi.pc.in
 578     pkgconfig/gstreamer-vaapi-drm-$GST_MAJORMINOR.pc:\
 579 pkgconfig/gstreamer-vaapi-drm.pc.in
 580     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 581 pkgconfig/gstreamer-vaapi-glx.pc.in
 582     pkgconfig/gstreamer-vaapi-wayland-$GST_MAJORMINOR.pc:\
 583 pkgconfig/gstreamer-vaapi-wayland.pc.in
 584     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 585 pkgconfig/gstreamer-vaapi-x11.pc.in
 586     tests/Makefile
 587 ])
 588 AC_OUTPUT
 589
 590 dnl Print summary
 591 yesno() {
 592     test $1 -eq 1 && echo yes || echo no
 593 }
 594
 595 VIDEO_OUTPUTS=""
 596 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
 597 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
 598 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
 599 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
 600
 601 echo
 602 echo $PACKAGE configuration summary:
 603 echo
 604 echo VA-API version ................... : $VA_VERSION_STR
 605 echo Video outputs .................... : $VIDEO_OUTPUTS
 606 echo