configure.ac

   1 dnl  Copyright © 2008 Dan Nicholson
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Keith Packard not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Keith Packard makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  DAN NICHOLSON DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 # Initialize Autoconf
  24 AC_PREREQ([2.62])
  25 AC_INIT([libxkbcommon], [0.4.3],
  26         [https://bugs.freedesktop.org/enter_bug.cgi?product=libxkbcommon],
  27         [libxkbcommon], [http://xkbcommon.org])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_HEADERS([src/config.h])
  30 AC_CONFIG_MACRO_DIR([m4])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 # Initialize Automake
  34 AM_INIT_AUTOMAKE([foreign dist-xz no-dist-gzip subdir-objects color-tests parallel-tests check-news])
  35 AM_MAINTAINER_MODE([enable])
  36
  37 # Get _GNU_SOURCE and friends
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 # Initialize libtool
  41 LT_INIT
  42
  43 # Add xorg-macros stuff
  44 m4_ifndef([XORG_MACROS_VERSION],
  45           [m4_fatal([must install xorg-macros 1.16 or later before running autoconf/autogen])])
  46 XORG_MACROS_VERSION(1.16)
  47 XORG_DEFAULT_OPTIONS
  48 XORG_MEMORY_CHECK_FLAGS
  49 XORG_ENABLE_DOCS
  50 XORG_WITH_DOXYGEN
  51
  52 # Needed in older Automakes for subdir-objects
  53 AM_PROG_CC_C_O
  54
  55 # Check for compiler features
  56 AC_C_INLINE
  57
  58 # Check for programs
  59 AC_PROG_MKDIR_P
  60 PKG_PROG_PKG_CONFIG
  61
  62 # Note: we use some yacc extensions, which work with either GNU bison
  63 # (preferred) or byacc. Other yacc's may or may not work.
  64 AC_PROG_YACC
  65 AC_PATH_PROG([YACC_INST], [$YACC])
  66 AS_IF([test ! -f "src/xkbcomp/parser.c" -a "x$YACC_INST" = x], [
  67     AC_MSG_ERROR([yacc not found - unable to compile src/xkbcomp/parser.y])
  68 ])
  69
  70 # Checks for library functions.
  71 AC_CHECK_FUNCS([strcasecmp strncasecmp])
  72 AS_IF([test "x$ac_cv_func_strcasecmp" = xno -o \
  73             "x$ac_cv_func_strncasecmp" = xno], [
  74     AC_MSG_ERROR([C library does not support strcasecmp/strncasecmp])
  75 ])
  76
  77 AC_CHECK_FUNCS([eaccess euidaccess mmap])
  78
  79 AC_CHECK_FUNCS([secure_getenv __secure_getenv])
  80 AS_IF([test "x$ac_cv_func_secure_getenv" = xno -a \
  81             "x$ac_cv_func___secure_getenv" = xno], [
  82     AC_MSG_WARN([C library does not support secure_getenv, using getenv instead])
  83 ])
  84
  85 AX_GCC_BUILTIN(__builtin_expect)
  86
  87 # Some tests use Linux-specific headers
  88 AC_CHECK_HEADER([linux/input.h])
  89 AM_CONDITIONAL(BUILD_LINUX_TESTS, [test "x$ac_cv_header_linux_input_h" = xyes])
  90
  91 XORG_TESTSET_CFLAG([BASE_CFLAGS], [-fvisibility=hidden])
  92 XORG_TESTSET_CFLAG([BASE_CFLAGS], [-Wextra -Wno-unused-parameter -Wno-missing-field-initializers])
  93 XORG_TESTSET_CFLAG([BASE_CFLAGS], [-Wdocumentation])
  94
  95 XORG_CHECK_LINKER_FLAGS([-Wl,--no-undefined], [have_no_undefined=yes])
  96 AM_CONDITIONAL([HAVE_NO_UNDEFINED], [test "x$have_no_undefined" = xyes])
  97
  98 # Define a configuration option for the XKB config root
  99 xkb_base=`$PKG_CONFIG --variable=xkb_base xkeyboard-config`
 100 AS_IF([test "x$xkb_base" = x], [
 101     xkb_base="$datadir/X11/xkb"
 102 ])
 103 AC_ARG_WITH([xkb_config_root],
 104     [AS_HELP_STRING([--with-xkb-config-root=<path>],
 105         [Set default XKB config root (default: xkeyboard-config install path)])],
 106     [XKBCONFIGROOT="$withval"],
 107     [XKBCONFIGROOT="$xkb_base"])
 108 AC_SUBST([XKBCONFIGROOT])
 109
 110 # Define a configuration option for the X locale directory for compose
 111 AC_ARG_WITH([x_locale_root],
 112     [AS_HELP_STRING([--with-x-locale-root=<path>],
 113         [Set X locale root (default: $datadir/X11/locale)])],
 114     [XLOCALEDIR="$withval"],
 115     [XLOCALEDIR="$datadir/X11/locale"])
 116 AC_SUBST([XLOCALEDIR])
 117
 118 AC_ARG_WITH([default_rules],
 119     [AS_HELP_STRING([--with-default-rules=<path>],
 120         [Default XKB ruleset (default: evdev)])],
 121     [DEFAULT_XKB_RULES="$withval"],
 122     [DEFAULT_XKB_RULES="evdev"])
 123 AC_DEFINE_UNQUOTED([DEFAULT_XKB_RULES], ["$DEFAULT_XKB_RULES"],
 124                    [Default XKB ruleset])
 125
 126 AC_ARG_WITH([default_model],
 127     [AS_HELP_STRING([--with-default-model=<path>],
 128         [Default XKB model (default: pc105)])],
 129     [DEFAULT_XKB_MODEL="$withval"],
 130     [DEFAULT_XKB_MODEL="pc105"])
 131 AC_DEFINE_UNQUOTED([DEFAULT_XKB_MODEL], ["$DEFAULT_XKB_MODEL"],
 132                    [Default XKB model])
 133
 134 AC_ARG_WITH([default_layout],
 135     [AS_HELP_STRING([--with-default-layout=<path>],
 136         [Default XKB layout (default: us)])],
 137     [DEFAULT_XKB_LAYOUT="$withval"],
 138     [DEFAULT_XKB_LAYOUT="us"])
 139 AC_DEFINE_UNQUOTED([DEFAULT_XKB_LAYOUT], ["$DEFAULT_XKB_LAYOUT"],
 140                    [Default XKB layout])
 141
 142 AC_ARG_WITH([default_variant],
 143     [AS_HELP_STRING([--with-default-variant=<path>],
 144         [Default XKB variant (default: (none))])],
 145     [DEFAULT_XKB_VARIANT="$withval"],
 146     [DEFAULT_XKB_VARIANT=])
 147 AS_IF([test "x$DEFAULT_XKB_VARIANT" != x], [
 148     AC_DEFINE_UNQUOTED([DEFAULT_XKB_VARIANT], ["$DEFAULT_XKB_VARIANT"],
 149                        [Default XKB variant])
 150 ])
 151
 152 AC_ARG_WITH([default_options],
 153     [AS_HELP_STRING([--with-default-options=<path>],
 154         [Default XKB options (default: (none))])],
 155     [DEFAULT_XKB_OPTIONS="$withval"],
 156     [DEFAULT_XKB_OPTIONS=])
 157 AS_IF([test "x$DEFAULT_XKB_OPTIONS" != x], [
 158     AC_DEFINE_UNQUOTED([DEFAULT_XKB_OPTIONS], ["$DEFAULT_XKB_OPTIONS"],
 159                        [Default XKB options])
 160 ])
 161
 162 AC_ARG_ENABLE([x11],
 163     [AS_HELP_STRING([--disable-x11],
 164         [Disable support for creating keymaps with the X11 protocol (default: enabled)])],
 165     [], [enable_x11=yes])
 166 AS_IF([test "x$enable_x11" = xyes], [
 167     PKG_CHECK_MODULES([XCB_XKB], [xcb xcb-xkb >= 1.10], [],
 168         [AC_MSG_ERROR([xkbcommon-x11 requires xcb-xkb >= 1.10 which was not found. \
 169 You can disable X11 support with --disable-x11.])])
 170 ], [enable_x11=no])
 171 AM_CONDITIONAL([ENABLE_X11], [test "x$enable_x11" = xyes])
 172
 173 AC_CONFIG_FILES([
 174     Makefile
 175     xkbcommon-uninstalled.pc
 176     xkbcommon.pc
 177     xkbcommon-x11.pc
 178     xkbcommon-x11-uninstalled.pc
 179     doc/Doxyfile
 180 ])
 181 AC_OUTPUT
 182
 183 AC_MSG_RESULT([
 184         $PACKAGE_NAME $VERSION
 185
 186         libxkbcommon:            yes
 187         libxkbcommon-x11:        ${enable_x11}
 188         documentation:           ${build_docs}
 189
 190         default XKB rules:       ${DEFAULT_XKB_RULES}
 191         default XKB model:       ${DEFAULT_XKB_MODEL}
 192         default XKB layout:      ${DEFAULT_XKB_LAYOUT}
 193         default XKB variant:     ${DEFAULT_XKB_VARIANT}
 194         default XKB options:     ${DEFAULT_XKB_OPTIONS}
 195
 196         prefix:                  ${prefix}
 197         includedir:              ${includedir}
 198         lib dir:                 ${libdir}
 199         XKB config root:         ${XKBCONFIGROOT}
 200         X11 locale root:         ${XLOCALEDIR}
 201 ])