configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [37])
  34 m4_define([glib_micro_version], [0])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153
 154     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 155     ;;
 156   *)
 157     glib_native_win32=no
 158     glib_pid_type=int
 159     ;;
 160 esac
 161 case $host in
 162   *-*-linux*)
 163     glib_os_linux=yes
 164     ;;
 165 esac
 166
 167 AC_MSG_RESULT([$glib_native_win32])
 168
 169 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 170
 171 glib_have_carbon=no
 172 AC_MSG_CHECKING([for Mac OS X Carbon support])
 173 AC_TRY_CPP([
 174 #include <Carbon/Carbon.h>
 175 #include <CoreServices/CoreServices.h>
 176 ], glib_have_carbon=yes)
 177
 178 AC_MSG_RESULT([$glib_have_carbon])
 179
 180 glib_have_cocoa=no
 181 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 182 AC_TRY_CPP([
 183 #include <Cocoa/Cocoa.h>
 184 #ifdef GNUSTEP_BASE_VERSION
 185 #error "Detected GNUstep, not Cocoa"
 186 #endif
 187 ], glib_have_cocoa=yes)
 188
 189 AC_MSG_RESULT([$glib_have_cocoa])
 190
 191 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 192 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 193 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 194 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 195 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 196 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 197
 198 AS_IF([test "$glib_native_win32" = "yes"], [
 199   AC_CHECK_TOOL(WINDRES, windres, no)
 200   if test "$WINDRES" = no; then
 201     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 202   fi
 203   AC_CHECK_TOOL(NM, nm, no)
 204   if test "$NM" = no; then
 205     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 206   fi
 207   AC_CHECK_TOOL(RANLIB, ranlib, :)
 208   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 209   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 210 ])
 211 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 212
 213 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 214   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 215   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 216 ])
 217
 218 if test "x$glib_have_cocoa" = "xyes"; then
 219   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 220   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 221 fi
 222
 223 gl_GLIBC21
 224 AS_IF([test "x$GLIBC21" = "xyes"], [
 225   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 226 ])
 227
 228 dnl declare --enable-* args and collect ac_help strings
 229 AC_ARG_ENABLE(debug,
 230               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 231                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 232               enable_debug=glib_debug_default)
 233
 234 AC_ARG_ENABLE(gc_friendly,
 235               [AS_HELP_STRING([--enable-gc-friendly],
 236                               [turn on garbage collector friendliness [default=no]])],,
 237               [enable_gc_friendly=no])
 238 AC_ARG_ENABLE(mem_pools,
 239               [AS_HELP_STRING([--disable-mem-pools],
 240                               [disable all glib memory pools])],,
 241               [disable_mem_pools=no])
 242 AC_ARG_ENABLE(rebuilds,
 243               [AS_HELP_STRING([--disable-rebuilds],
 244                               [disable all source autogeneration rules])],,
 245               [enable_rebuilds=yes])
 246 AC_ARG_ENABLE(modular_tests,
 247               AS_HELP_STRING([--disable-modular-tests],
 248                              [Disable build of test programs (default: no)]),,
 249               [enable_modular_tests=yes])
 250 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 251
 252 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 253 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 254   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 255   AC_MSG_RESULT([yes])
 256 ], [ AC_MSG_RESULT([no]) ])
 257
 258 AC_MSG_CHECKING([whether to disable memory pools])
 259 AS_IF([test "x$disable_mem_pools" = "xno"], [
 260   AC_MSG_RESULT([no])
 261 ], [
 262   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 263   AC_MSG_RESULT([yes])
 264 ])
 265
 266 dnl location to install runtime libraries, e.g. ../../lib to install
 267 dnl to /lib if libdir is /usr/lib
 268 AC_ARG_WITH(runtime-libdir,
 269            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 270                            [install runtime libraries relative to libdir])],
 271            [],
 272            [with_runtime_libdir=""])
 273 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 274 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 275 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 276 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 277 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 278
 279 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 280 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 281 AC_LANG_SAVE
 282 AC_LANG_CPLUSPLUS
 283 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 284 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 285 AC_LANG_RESTORE
 286
 287 AM_PROG_CC_C_O
 288 AC_PROG_INSTALL
 289
 290 AC_SYS_LARGEFILE
 291
 292 PKG_PROG_PKG_CONFIG(0.16)
 293
 294 if test "x$enable_debug" = "xyes"; then
 295   if test x$cflags_set != xset ; then
 296       case " $CFLAGS " in
 297       *[[\ \    ]]-g[[\ \       ]]*) ;;
 298       *) CFLAGS="$CFLAGS -g" ;;
 299       esac
 300   fi
 301   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 302 else
 303   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 304
 305   if test "x$enable_debug" = "xno"; then
 306     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 307   fi
 308 fi
 309
 310 # Ensure MSVC-compatible struct packing convention is used when
 311 # compiling for Win32 with gcc.
 312 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 313 # gcc2 uses "-fnative-struct".
 314 if test x"$glib_native_win32" = xyes; then
 315   if test x"$GCC" = xyes; then
 316     msnative_struct=''
 317     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 318     if test -z "$ac_cv_prog_CC"; then
 319       our_gcc="$CC"
 320     else
 321       our_gcc="$ac_cv_prog_CC"
 322     fi
 323     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 324       2.)
 325         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 326           msnative_struct='-fnative-struct'
 327         fi
 328         ;;
 329       *)
 330         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 331           msnative_struct='-mms-bitfields'
 332         fi
 333         ;;
 334     esac
 335     if test x"$msnative_struct" = x ; then
 336       AC_MSG_RESULT([no way])
 337       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 338     else
 339       CFLAGS="$CFLAGS $msnative_struct"
 340       AC_MSG_RESULT([${msnative_struct}])
 341     fi
 342   fi
 343 fi
 344 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 345 AC_SUBST(GLIB_EXTRA_CFLAGS)
 346
 347 AC_EXEEXT
 348
 349 # define a MAINT-like variable REBUILD which is set if Perl
 350 # and awk are found, so autogenerated sources can be rebuilt
 351 AC_PROG_AWK
 352 AC_CHECK_PROGS(PERL, [perl5 perl])
 353 # We would like indent, but don't require it.
 354 AC_CHECK_PROG(INDENT, indent, indent)
 355 REBUILD=\#
 356 if test "x$enable_rebuilds" = "xyes" && \
 357      test -n "$PERL" && \
 358      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 359      test -n "$AWK" ; then
 360   REBUILD=
 361 fi
 362 AC_SUBST(REBUILD)
 363
 364 # Need full path to Perl for glib-mkenums
 365 #
 366 if test "x$PERL" != x ; then
 367   AC_PATH_PROG(PERL_PATH, [$PERL])
 368 fi
 369 if test "x$PERL_PATH" = x ; then
 370   PERL_PATH="/usr/bin/env perl"
 371 fi
 372 AC_SUBST(PERL_PATH)
 373
 374 # option to specify python interpreter to use; this just sets $PYTHON, so that
 375 # we will fallback to reading $PYTHON if --with-python is not given, and
 376 # python.m4 will get the expected input
 377 AC_ARG_WITH(python,
 378             AS_HELP_STRING([--with-python=PATH],
 379                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 380             [PYTHON="$withval"], [])
 381 if test x"$PYTHON" = xyes; then
 382   AC_MSG_ERROR([--with-python option requires a path or program argument])
 383 fi
 384 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 385
 386
 387 dnl ***********************
 388 dnl *** Tests for iconv ***
 389 dnl ***********************
 390 dnl
 391 dnl We do this before the gettext checks, to avoid distortion
 392
 393 dnl On Windows we use a native implementation
 394
 395 AS_IF([ test x"$glib_native_win32" = xyes], [
 396   with_libiconv=native
 397 ], [
 398   AC_ARG_WITH(libiconv,
 399               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 400                               [use the libiconv library])],,
 401               [with_libiconv=maybe])
 402
 403   found_iconv=no
 404   case $with_libiconv in
 405     maybe)
 406       # Check in the C library first
 407       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 408       # Check if we have GNU libiconv
 409       if test $found_iconv = "no"; then
 410         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 411       fi
 412       # Check if we have a iconv in -liconv, possibly from vendor
 413       if test $found_iconv = "no"; then
 414         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 415       fi
 416       ;;
 417     no)
 418       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 419       ;;
 420     gnu|yes)
 421       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 422       ;;
 423     native)
 424       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 425       ;;
 426   esac
 427
 428   if test "x$found_iconv" = "xno" ; then
 429      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 430   fi
 431 ])
 432
 433 AC_ARG_ENABLE(iconv-cache,
 434               [AS_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 435                               [cache iconv descriptors [default=auto]])],,
 436               [enable_iconv_cache=auto])
 437
 438 AC_MSG_CHECKING([whether to cache iconv descriptors])
 439 case $enable_iconv_cache in
 440   auto)
 441     if test $ac_cv_gnu_library_2_1 = yes; then
 442       enable_iconv_cache=no
 443     else
 444       enable_iconv_cache=yes
 445     fi
 446   ;;
 447   yes|no)
 448   ;;
 449   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 450   ;;
 451 esac
 452
 453 if test $enable_iconv_cache = yes; then
 454    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 455 fi
 456
 457 AC_MSG_RESULT($enable_iconv_cache)
 458
 459
 460 dnl
 461 dnl zlib support
 462 dnl
 463 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 464 AS_IF([test "x$found_zlib" = "xno"], [
 465   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 466   if test "x$found_zlib" = "xno" ; then
 467     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 468   fi
 469   ZLIB_LIBS='-lz'
 470   AC_SUBST(ZLIB_LIBS)
 471 ])
 472
 473 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 474 AC_SUBST(LIBFFI_CFLAGS)
 475 AC_SUBST(LIBFFI_LIBS)
 476
 477 dnl
 478 dnl gettext support
 479 dnl
 480
 481 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 482 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 483 GLIB_GNU_GETTEXT
 484
 485 if test "$gt_cv_have_gettext" != "yes" ; then
 486   AC_MSG_ERROR([
 487 *** You must have either have gettext support in your C library, or use the
 488 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 489 ])
 490 fi
 491
 492 LIBS="$INTLLIBS $LIBS"
 493
 494 GETTEXT_PACKAGE=glib20
 495 AC_SUBST(GETTEXT_PACKAGE)
 496 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 497   [Define the gettext package to be used])
 498
 499 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 500
 501 dnl
 502 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 503 dnl
 504
 505 AS_IF([test x"$glib_native_win32" != xyes], [
 506   if test x$with_libiconv != xno ; then
 507     case " $INTLLIBS " in
 508     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 509     *) ICONV_LIBS="-liconv" ;;
 510     esac
 511   fi
 512 ])
 513 AC_SUBST(ICONV_LIBS)
 514
 515 case $with_libiconv in
 516   gnu)
 517     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 518     ;;
 519   native)
 520     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 521     ;;
 522 esac
 523
 524 dnl Initialize libtool
 525 LT_PREREQ([2.2])
 526 LT_INIT([disable-static win32-dll])
 527 dnl when using libtool 2.x create libtool early, because it's used in configure
 528 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 529
 530
 531 AS_IF([test "$glib_native_win32" = "yes"], [
 532   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 533     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 534   fi
 535   if test x$enable_static = xyes; then
 536     glib_win32_static_compilation=yes
 537     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 538 #define GOBJECT_STATIC_COMPILATION 1"
 539     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 540   fi
 541 ])
 542 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 543
 544 dnl
 545 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 546 dnl
 547 AS_IF([test $cross_compiling != yes], [
 548     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 549     glib_save_LIBS=$LIBS
 550     LIBS="$LIBS -lm"
 551     AC_TRY_RUN([#include <math.h>
 552                  int main (void) { return (log(1) != log(1.)); }],
 553          AC_MSG_RESULT(none needed),
 554          glib_save_CFLAGS=$CFLAGS
 555          CFLAGS="$CFLAGS -std1"
 556          AC_TRY_RUN([#include <math.h>
 557                      int main (void) { return (log(1) != log(1.)); }],
 558              AC_MSG_RESULT(-std1),
 559              AC_MSG_RESULT()
 560              CFLAGS=$glib_save_CFLAGS
 561              AC_MSG_WARN(
 562                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 563          )
 564     )
 565     LIBS=$glib_save_LIBS
 566 ])
 567
 568 dnl NeXTStep cc seems to need this
 569 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 570 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 571   AC_MSG_RESULT(none needed),
 572   glib_save_CFLAGS=$CFLAGS
 573   CFLAGS="$CFLAGS -posix"
 574   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 575     AC_MSG_RESULT(-posix),
 576     AC_MSG_RESULT()
 577     CFLAGS=$glib_save_CFLAGS
 578     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 579
 580 # Checks for library functions.
 581 AC_FUNC_VPRINTF
 582 AC_FUNC_ALLOCA
 583 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 584 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 585
 586 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 587   [AC_TRY_LINK([#include <unistd.h>
 588     extern int __libc_enable_secure;],
 589     [return __libc_enable_secure;],
 590    glib_cv_have_libc_enable_secure=yes,
 591    glib_cv_have_libc_enable_secure=no)])
 592 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 593    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 594      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 595 ])
 596
 597 AC_CHECK_SIZEOF(char)
 598 AC_CHECK_SIZEOF(short)
 599 AC_CHECK_SIZEOF(long)
 600 AC_CHECK_SIZEOF(int)
 601 AC_CHECK_SIZEOF(void *)
 602 AC_CHECK_SIZEOF(long long)
 603 AC_CHECK_SIZEOF(__int64)
 604
 605 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 606   [AC_TRY_LINK([#include <signal.h>
 607      #include <sys/types.h>
 608      sig_atomic_t val = 42;],
 609     [return val == 42 ? 0 : 1],
 610    ac_cv_type_sig_atomic_t=yes,
 611    ac_cv_type_sig_atomic_t=no)])
 612 if test x$ac_cv_type_sig_atomic_t = xyes; then
 613    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 614      [Define if you have the 'sig_atomic_t' type.])
 615 fi
 616
 617 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 618   :
 619 else
 620   AC_MSG_ERROR([
 621 *** GLib requires a 64 bit type. You might want to consider
 622 *** using the GNU C compiler.
 623 ])
 624 fi
 625
 626 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 627         # long long is a 64 bit integer.
 628         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 629         AC_CACHE_VAL(glib_cv_long_long_format,[
 630                 for format in ll q I64; do
 631                   AC_TRY_RUN([#include <stdio.h>
 632                         int main()
 633                         {
 634                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 635                           char buffer[1000];
 636                           sprintf (buffer, "%${format}u", a);
 637                           sscanf (buffer, "%${format}u", &b);
 638                           exit (b!=a);
 639                         }
 640                         ],
 641                         [glib_cv_long_long_format=${format}
 642                         break],
 643                         [],[:])
 644                 done])
 645         AS_IF([ test -n "$glib_cv_long_long_format"], [
 646           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 647           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 648           if test x"$glib_cv_long_long_format" = xI64; then
 649             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 650           fi
 651         ], [AC_MSG_RESULT(none)])
 652 ],[ test x$ac_cv_sizeof___int64 = x8], [
 653         # __int64 is a 64 bit integer.
 654         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 655         # We know this is MSVCRT.DLL, and what the formats are
 656         glib_cv_long_long_format=I64
 657         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 658         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 659         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 660 ])
 661
 662 AC_C_CONST
 663
 664 dnl ok, here we try to check whether the systems prototypes for
 665 dnl malloc and friends actually match the prototypes provided
 666 dnl by gmem.h (keep in sync). i currently only know how to check
 667 dnl this reliably with gcc (-Werror), improvements for other
 668 dnl compilers are apprechiated.
 669 SANE_MALLOC_PROTOS=no
 670 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 671 glib_save_CFLAGS=$CFLAGS
 672 AS_IF([test "x$GCC" = "xyes"], [
 673   CFLAGS="$CFLAGS -Werror"
 674   AC_TRY_COMPILE([#include <stdlib.h>], [
 675     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 676     void* (*my_malloc_p)  (size_t)         = malloc;
 677     void  (*my_free_p)    (void*)          = free;
 678     void* (*my_realloc_p) (void*, size_t)  = realloc;
 679     my_calloc_p = 0;
 680     my_malloc_p = 0;
 681     my_free_p = 0;
 682     my_realloc_p = 0;
 683   ],
 684     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 685       [Define if you have correct malloc prototypes])
 686     SANE_MALLOC_PROTOS=yes)
 687 ])
 688 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 689 CFLAGS=$glib_save_CFLAGS
 690
 691 dnl
 692 dnl check in which direction the stack grows
 693 dnl
 694 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 695         AC_TRY_RUN([
 696         volatile int *a = 0, *b = 0;
 697         void foo (void);
 698         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 699         void foo (void) { volatile int x = 5; b = &x; }
 700         ],
 701         glib_cv_stack_grows=no
 702         ,
 703         glib_cv_stack_grows=yes
 704         ,)
 705 ])
 706
 707 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 708 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 709 dnl actually supported.
 710 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 711         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 712         __inline int foo () { return 0; }
 713         int main () { return foo (); }
 714         ]])],
 715         glib_cv_has__inline=yes
 716         ,
 717         glib_cv_has__inline=no
 718         ,)
 719 ])
 720 case x$glib_cv_has__inline in
 721 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 722 esac
 723 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 724         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 725         __inline__ int foo () { return 0; }
 726         int main () { return foo (); }
 727         ]])],
 728         glib_cv_has__inline__=yes
 729         ,
 730         glib_cv_has__inline__=no
 731         ,)
 732 ])
 733 case x$glib_cv_has__inline__ in
 734 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 735 esac
 736 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 737         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 738         #undef inline
 739         inline int foo () { return 0; }
 740         int main () { return foo (); }
 741         ]])],
 742         glib_cv_hasinline=yes
 743         ,
 744         glib_cv_hasinline=no
 745         ,)
 746 ])
 747 case x$glib_cv_hasinline in
 748 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 749 esac
 750
 751 # if we can use inline functions in headers
 752 AC_MSG_CHECKING(if inline functions in headers work)
 753 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 754 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 755 #  undef inline
 756 #  define inline __inline__
 757 #elif !defined (G_HAVE_INLINE)
 758 #  undef inline
 759 #  if defined (G_HAVE___INLINE__)
 760 #    define inline __inline__
 761 #  elif defined (G_HAVE___INLINE)
 762 #    define inline __inline
 763 #  endif
 764 #endif
 765
 766 int glib_test_func2 (int);
 767
 768 static inline int
 769 glib_test_func1 (void) {
 770   return glib_test_func2 (1);
 771 }
 772
 773 int
 774 main (void) {
 775   int i = 1;
 776 }]])],[g_can_inline=yes],[g_can_inline=no])
 777 AC_MSG_RESULT($g_can_inline)
 778
 779 dnl *** check for working do while(0) macros ***
 780 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 781         AC_TRY_COMPILE([],[
 782         #define STMT_START do
 783         #define STMT_END while(0)
 784         #define STMT_TEST STMT_START { i = 0; } STMT_END
 785         int main(void) { int i = 1; STMT_TEST; return i; }],
 786         [g_cv_support_dowhile_macros=yes],
 787         [g_cv_support_dowhile_macros=no],
 788         [g_cv_support_dowhile_macros=yes])
 789 ])
 790 if test x$g_cv_support_dowhile_macros = xyes; then
 791   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 792 fi
 793
 794 # check for flavours of varargs macros
 795 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 796 AC_TRY_COMPILE([],[
 797 int a(int p1, int p2, int p3);
 798 #define call_a(...) a(1,__VA_ARGS__)
 799 call_a(2,3);
 800 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 801 AC_MSG_RESULT($g_have_iso_c_varargs)
 802
 803 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 804 AS_IF([test "$CXX" = ""], [
 805 dnl No C++ compiler
 806   g_have_iso_cxx_varargs=no
 807 else
 808   AC_LANG_CPLUSPLUS
 809   AC_TRY_COMPILE([],[
 810 int a(int p1, int p2, int p3);
 811 #define call_a(...) a(1,__VA_ARGS__)
 812 call_a(2,3);
 813 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 814   AC_LANG_C
 815 ])
 816 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 817
 818 AC_MSG_CHECKING(for GNUC varargs macros)
 819 AC_TRY_COMPILE([],[
 820 int a(int p1, int p2, int p3);
 821 #define call_a(params...) a(1,params)
 822 call_a(2,3);
 823 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 824 AC_MSG_RESULT($g_have_gnuc_varargs)
 825
 826 # check for GNUC visibility support
 827 AC_MSG_CHECKING(for GNUC visibility attribute)
 828 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 829 void
 830 __attribute__ ((visibility ("hidden")))
 831      f_hidden (void)
 832 {
 833 }
 834 void
 835 __attribute__ ((visibility ("internal")))
 836      f_internal (void)
 837 {
 838 }
 839 void
 840 __attribute__ ((visibility ("protected")))
 841      f_protected (void)
 842 {
 843 }
 844 void
 845 __attribute__ ((visibility ("default")))
 846      f_default (void)
 847 {
 848 }
 849 int main (void)
 850 {
 851         f_hidden();
 852         f_internal();
 853         f_protected();
 854         f_default();
 855         return 0;
 856 }
 857 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 858 AC_MSG_RESULT($g_have_gnuc_visibility)
 859 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 860
 861 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 862 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 863 #else
 864 # include "error: this is not Sun Studio."
 865 #endif
 866 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 867 AC_MSG_RESULT($g_have_sunstudio_visibility)
 868 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 869
 870 # check for bytesex stuff
 871 AC_C_BIGENDIAN
 872 if test x$ac_cv_c_bigendian = xuniversal ; then
 873 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 874 #else
 875 #error Not a big endian.
 876 #endif],
 877     ac_cv_c_bigendian=yes
 878     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 879 #else
 880 #error Not a little endian.
 881 #endif],
 882     ac_cv_c_bigendian=no
 883     ,AC_MSG_WARN([Could not determine endianness.])))
 884 fi
 885
 886
 887 # check for header files
 888 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 889 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 890 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 891 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 892 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 893 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 894 AC_CHECK_HEADERS([linux/magic.h])
 895 AC_CHECK_HEADERS([sys/prctl.h])
 896
 897 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 898 [#if HAVE_SYS_PARAM_H
 899  #include <sys/param.h>
 900  #endif
 901 ])
 902 AC_CHECK_FUNCS(sysctlbyname)
 903
 904 AC_CHECK_HEADERS([xlocale.h])
 905
 906 # check for structure fields
 907 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 908 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 909 #include <sys/stat.h>
 910 #include <unistd.h>
 911 #ifdef HAVE_SYS_STATFS_H
 912 #include <sys/statfs.h>
 913 #endif
 914 #ifdef HAVE_SYS_PARAM_H
 915 #include <sys/param.h>
 916 #endif
 917 #ifdef HAVE_SYS_MOUNT_H
 918 #include <sys/mount.h>
 919 #endif])
 920 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 921 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 922 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 923 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 924
 925 AC_STRUCT_DIRENT_D_TYPE
 926
 927 # Checks for libcharset
 928 AM_LANGINFO_CODESET
 929 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 930 AC_CHECK_FUNCS(setlocale)
 931
 932 # check additional type sizes
 933 AC_CHECK_SIZEOF(size_t)
 934
 935 dnl Try to figure out whether gsize, gssize should be long or int
 936 AC_MSG_CHECKING([for the appropriate definition for size_t])
 937
 938 case $ac_cv_sizeof_size_t in
 939   $ac_cv_sizeof_short)
 940       glib_size_type=short
 941       ;;
 942   $ac_cv_sizeof_int)
 943       glib_size_type=int
 944       ;;
 945   $ac_cv_sizeof_long)
 946       glib_size_type=long
 947       ;;
 948   $ac_cv_sizeof_long_long)
 949       glib_size_type='long long'
 950       ;;
 951   $ac_cv_sizeof__int64)
 952       glib_size_type='__int64'
 953       ;;
 954   *)  AC_MSG_ERROR([No type matching size_t in size])
 955       ;;
 956 esac
 957
 958 dnl If int/long are the same size, we see which one produces
 959 dnl warnings when used in the location as size_t. (This matters
 960 dnl on AIX with xlc)
 961 dnl
 962 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 963        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 964   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 965 #if defined(_AIX) && !defined(__GNUC__)
 966 #pragma options langlvl=stdc89
 967 #endif
 968 #include <stddef.h>
 969 int main ()
 970 {
 971   size_t s = 1;
 972   unsigned int *size_int = &s;
 973   return (int)*size_int;
 974 }
 975     ]])],glib_size_type=int,
 976       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 977 #if defined(_AIX) && !defined(__GNUC__)
 978 #pragma options langlvl=stdc89
 979 #endif
 980 #include <stddef.h>
 981 int main ()
 982 {
 983    size_t s = 1;
 984    unsigned long *size_long = &s;
 985    return (int)*size_long;
 986 }
 987         ]])],glib_size_type=long)])
 988 ])
 989
 990 AC_MSG_RESULT(unsigned $glib_size_type)
 991
 992 # Check for some functions
 993 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 994 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
 995 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 996 # Check for high-resolution sleep functions
 997 AC_CHECK_FUNCS(splice)
 998 AC_CHECK_FUNCS(prlimit)
 999
1000 # To avoid finding a compatibility unusable statfs, which typically
1001 # successfully compiles, but warns to use the newer statvfs interface:
1002 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1003 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1004
1005 AC_MSG_CHECKING([whether to use statfs or statvfs])
1006 # Some systems have both statfs and statvfs, pick the most "native" for these
1007 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1008    [
1009    # on solaris and irix, statfs doesn't even have the f_bavail field
1010    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1011       [ac_cv_func_statfs=no],
1012    # else, at least on linux, statfs is the actual syscall
1013       [ac_cv_func_statvfs=no])
1014    ])
1015
1016 AS_IF([test x$ac_cv_func_statfs = xyes],
1017       [
1018          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1019          AC_MSG_RESULT([statfs])
1020       ],
1021       [test x$ac_cv_func_statvfs = xyes],
1022       [
1023          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1024          AC_MSG_RESULT([statvfs])
1025       ],
1026       [  AC_MSG_RESULT([neither])])
1027
1028 AC_CHECK_HEADERS(crt_externs.h)
1029 AC_CHECK_FUNCS(_NSGetEnviron)
1030
1031 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1032
1033 AC_FUNC_VSNPRINTF_C99
1034 AC_FUNC_PRINTF_UNIX98
1035
1036 # Internet address families
1037 if test $glib_native_win32 = yes; then
1038   glib_inet_includes=["
1039 #include <winsock2.h>
1040   "]
1041 else
1042   glib_inet_includes=["
1043 #include <sys/types.h>
1044 #include <sys/socket.h>
1045   "]
1046 fi
1047
1048 glib_failed=false
1049 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1050 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1051 # winsock defines this even though it doesn't support it
1052 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1053 if $glib_failed ; then
1054   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1055 fi
1056
1057 glib_failed=false
1058 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1059 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1060 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1061 if $glib_failed ; then
1062   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1063 fi
1064
1065 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1066
1067 AS_IF([test $glib_native_win32 = yes], [
1068   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1069   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1070   # they aren't present at run-time (on Windows 2000).
1071   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1072   AC_SUBST(WSPIAPI_INCLUDE)
1073 ], [
1074   AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1075   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1076                                       #include <arpa/nameser.h>],
1077                                      [int qclass = C_IN;])],
1078                     [AC_MSG_RESULT([no])],
1079                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1080                                                          #include <arpa/nameser.h>
1081                                                          #include <arpa/nameser_compat.h>],
1082                                                         [int qclass = C_IN;])],
1083                                        [AC_MSG_RESULT([yes])
1084                                         NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1085                                        [AC_MSG_ERROR([could not compile test program either way])])])
1086   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1087
1088   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1089   NETWORK_LIBS=""
1090   AC_MSG_CHECKING([for res_query])
1091   AC_TRY_LINK([#include <sys/types.h>
1092                #include <netinet/in.h>
1093                #include <arpa/nameser.h>
1094                #include <resolv.h>
1095               ],[
1096                res_query("test", 0, 0, (void *)0, 0);
1097               ],[AC_MSG_RESULT([yes])],
1098               [save_libs="$LIBS"
1099                LIBS="-lresolv $LIBS"
1100                AC_TRY_LINK([#include <sys/types.h>
1101                             #include <netinet/in.h>
1102                             #include <arpa/nameser.h>
1103                             #include <resolv.h>
1104                            ],[
1105                             res_query("test", 0, 0, (void *)0, 0);
1106                            ],[AC_MSG_RESULT([in -lresolv])
1107                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1108                            [LIBS="-lbind $save_libs"
1109                             AC_TRY_LINK([#include <resolv.h>],
1110                                         [res_query("test", 0, 0, (void *)0, 0);],
1111                                         [AC_MSG_RESULT([in -lbind])
1112                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1113                                         [AC_MSG_ERROR(not found)])])
1114                LIBS="$save_libs"])
1115   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1116                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1117                                         [AC_MSG_ERROR(Could not find socket())]))
1118 ])
1119 AC_SUBST(NETWORK_LIBS)
1120
1121 AC_CHECK_HEADER([linux/netlink.h],
1122                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1123                 [#include <sys/socket.h>])
1124 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1125
1126 AC_CHECK_TYPE([struct ip_mreqn], [
1127               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1128               [#include <netinet/in.h>])
1129
1130 case $host in
1131   *-*-solaris* )
1132      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1133      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1134      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1135      ;;
1136 esac
1137
1138 dnl
1139 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1140 dnl
1141 AS_IF([test "$ac_cv_func_statfs" = yes], [
1142   AC_MSG_CHECKING([number of arguments to statfs()])
1143   AC_TRY_COMPILE([#include <unistd.h>
1144   #ifdef HAVE_SYS_PARAM_H
1145   #include <sys/param.h>
1146   #endif
1147   #ifdef HAVE_SYS_VFS_H
1148   #include <sys/vfs.h>
1149   #endif
1150   #ifdef HAVE_SYS_MOUNT_H
1151   #include <sys/mount.h>
1152   #endif
1153   #ifdef HAVE_SYS_STATFS_H
1154   #include <sys/statfs.h>
1155   #endif], [struct statfs st;
1156   statfs(NULL, &st);],[
1157     AC_MSG_RESULT([2])
1158     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1159     AC_TRY_COMPILE([#include <unistd.h>
1160   #ifdef HAVE_SYS_PARAM_H
1161   #include <sys/param.h>
1162   #endif
1163   #ifdef HAVE_SYS_VFS_H
1164   #include <sys/vfs.h>
1165   #endif
1166   #ifdef HAVE_SYS_MOUNT_H
1167   #include <sys/mount.h>
1168   #endif
1169   #ifdef HAVE_SYS_STATFS_H
1170   #include <sys/statfs.h>
1171   #endif], [struct statfs st;
1172   statfs(NULL, &st, sizeof (st), 0);],[
1173       AC_MSG_RESULT([4])
1174       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1175       AC_MSG_RESULT(unknown)
1176       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1177 ])
1178
1179 #
1180 # Check whether to use an included printf
1181 #
1182
1183 AC_ARG_ENABLE(included-printf,
1184               [AS_HELP_STRING([--enable-included-printf],
1185                               [use included printf [default=auto]])],
1186               enable_included_printf="$enableval")
1187
1188 need_included_printf=no
1189 if test "x$enable_included_printf" = "xyes" ; then
1190   need_included_printf=yes
1191 fi
1192 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1193   need_included_printf=yes
1194 fi
1195 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1196   need_included_printf=yes
1197 fi
1198 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1199    test -z "$glib_cv_long_long_format" ; then
1200   need_included_printf=yes
1201 fi
1202
1203 if test "x$enable_included_printf" = "xno" &&
1204    test "x$need_included_printf" = "xyes" ; then
1205   AC_MSG_ERROR([
1206 *** Your C library's printf doesn't appear to have the features that
1207 *** GLib needs, but you specified --enable-included-printf=no.])
1208 fi
1209
1210 enable_included_printf=$need_included_printf
1211
1212 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1213 AS_IF([test "$enable_included_printf" != "yes"], [
1214   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1215 ], [
1216   if test -z "$glib_cv_long_long_format" ; then
1217     glib_cv_long_long_format="ll"
1218   fi
1219   AC_DEFINE(HAVE_VASPRINTF,1)
1220 ])
1221
1222 # Checks needed for gnulib vasnprintf
1223 bh_C_SIGNED
1224 jm_AC_TYPE_LONG_LONG
1225 gt_TYPE_LONGDOUBLE
1226 gt_TYPE_WCHAR_T
1227 gt_TYPE_WINT_T
1228 AC_TYPE_SIZE_T
1229 AC_CHECK_TYPES(ptrdiff_t)
1230 jm_AC_TYPE_INTMAX_T
1231 AC_CHECK_FUNCS([snprintf wcslen])
1232 AC_FUNC_SNPRINTF_C99
1233
1234 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1235 # The check is borrowed from the PERL Configure script.
1236 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1237   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1238     glib_cv_working_bcopy,[AC_TRY_RUN([
1239       int main() {
1240         char buf[128], abc[128], *b;
1241         int len, off, align;
1242         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1243         for (align = 7; align >= 0; align--) {
1244           for (len = 36; len; len--) {
1245             b = buf+align; bcopy(abc, b, len);
1246             for (off = 1; off <= len; off++) {
1247               bcopy(b, b+off, len); bcopy(b+off, b, len);
1248                 if (bcmp(b, abc, len)) return(1);
1249             }
1250           }
1251         }
1252         return(0);
1253       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1254
1255   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1256   if test "$glib_cv_working_bcopy" = "yes"; then
1257     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1258   fi
1259 ])
1260
1261 # Check if <sys/select.h> needs to be included for fd_set
1262 AC_MSG_CHECKING([for fd_set])
1263 AC_TRY_COMPILE([#include <sys/types.h>],
1264         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1265 AS_IF([test "$gtk_ok" = "yes"], [
1266     AC_MSG_RESULT([yes, found in sys/types.h])
1267 ], [
1268     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1269     if test "$gtk_ok" = "yes"; then
1270         # *** FIXME: give it a different name
1271         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1272         AC_MSG_RESULT([yes, found in sys/select.h])
1273     else
1274         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1275         AC_MSG_RESULT(no)
1276     fi
1277 ])
1278
1279 dnl *** check for sane realloc() ***
1280 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1281         AC_TRY_RUN([#include <stdlib.h>
1282         int main() {
1283           return realloc (0, sizeof (int)) == 0;
1284         }],
1285         [glib_cv_sane_realloc=yes],
1286         [glib_cv_sane_realloc=no],
1287         [glib_cv_sane_realloc=yes])
1288 ])
1289 AS_IF([test x$glib_cv_sane_realloc = xyes], [
1290   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1291 ])
1292
1293 dnl Check for nl_langinfo and CODESET
1294 AC_LANG_SAVE
1295 AC_LANG_C
1296 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1297         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1298                        [char *codeset = nl_langinfo (CODESET);])],
1299                 [glib_cv_langinfo_codeset=yes],
1300                 [glib_cv_langinfo_codeset=no])])
1301 if test x$glib_cv_langinfo_codeset = xyes; then
1302   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1303 fi
1304
1305 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1306 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1307         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1308                  [char *str;
1309                  str = nl_langinfo (PM_STR);
1310                  str = nl_langinfo (D_T_FMT);
1311                  str = nl_langinfo (D_FMT);
1312                  str = nl_langinfo (T_FMT);
1313                  str = nl_langinfo (T_FMT_AMPM);
1314                  str = nl_langinfo (MON_1);
1315                  str = nl_langinfo (ABMON_12);
1316                  str = nl_langinfo (DAY_1);
1317                  str = nl_langinfo (ABDAY_7);])],
1318                 [glib_cv_langinfo_time=yes],
1319                 [glib_cv_langinfo_time=no])])
1320 if test x$glib_cv_langinfo_time = xyes; then
1321   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1322 fi
1323
1324 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1325 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1326         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1327                 [char *str;
1328                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1329                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1330                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1331                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1332                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1333                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1334                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1335                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1336                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1337                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1338                 [glib_cv_langinfo_outdigit=yes],
1339                 [glib_cv_langinfo_outdigit=no])])
1340 if test x$glib_cv_langinfo_outdigit = xyes; then
1341   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1342 fi
1343 AC_LANG_RESTORE
1344
1345 dnl ****************************************
1346 dnl *** posix_memalign                   ***
1347 dnl ****************************************
1348 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1349 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1350     glib_cv_compliant_posix_memalign=0
1351     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1352         AC_TRY_RUN([
1353                 #define _XOPEN_SOURCE 600
1354                 #include <stdlib.h> /* posix_memalign() should be defined here */
1355                 /* some systems break if #include <malloc.h> used */
1356                 static void test_memalign (size_t boundary, size_t size) {
1357                     void *mem = 0;
1358                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1359                         exit (1);
1360                     else
1361                       free (mem);
1362                 }
1363                 int main() {
1364                     test_memalign (  128,   128 - 2 * sizeof (void*));
1365                     test_memalign (  256,   256 - 2 * sizeof (void*));
1366                     test_memalign (  512,   512 - 2 * sizeof (void*));
1367                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1368                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1369                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1370                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1371                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1372                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1373                     exit (0); /* success */
1374                 }
1375                 ],
1376             [glib_cv_compliant_posix_memalign=1], [], [:])
1377       :
1378     fi
1379     ])
1380 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1381     AC_MSG_RESULT(yes)
1382     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1383 ], [
1384     AC_MSG_RESULT(no)
1385 ])
1386
1387
1388 dnl ****************************************
1389 dnl *** strlcpy/strlcat                  ***
1390 dnl ****************************************
1391 # Check for strlcpy
1392 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1393 AC_TRY_RUN([#include <stdlib.h>
1394 #include <string.h>
1395 int main() {
1396   char p[10];
1397   (void) strlcpy (p, "hi", 10);
1398   if (strlcat (p, "bye", 0) != 3)
1399     return 1;
1400   return 0;
1401 }], glib_cv_have_strlcpy=yes,
1402     glib_cv_have_strlcpy=no,
1403     glib_cv_have_strlcpy=no)])
1404 if test "$glib_cv_have_strlcpy" = "yes"; then
1405     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1406 fi
1407
1408
1409 dnl **********************
1410 dnl *** va_copy checks ***
1411 dnl **********************
1412 dnl we currently check for all three va_copy possibilities, so we get
1413 dnl all results in config.log for bug reports.
1414 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1415         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1416 #include <stdlib.h>
1417         void f (int i, ...) {
1418         va_list args1, args2;
1419         va_start (args1, i);
1420         va_copy (args2, args1);
1421         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1422           exit (1);
1423         va_end (args1); va_end (args2);
1424         }
1425         int main() {
1426           f (0, 42);
1427           return 0;
1428         }]])],
1429         [glib_cv_va_copy=yes],
1430         [glib_cv_va_copy=no])
1431 ])
1432 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1433         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1434 #include <stdlib.h>
1435         void f (int i, ...) {
1436         va_list args1, args2;
1437         va_start (args1, i);
1438         __va_copy (args2, args1);
1439         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1440           exit (1);
1441         va_end (args1); va_end (args2);
1442         }
1443         int main() {
1444           f (0, 42);
1445           return 0;
1446         }]])],
1447         [glib_cv___va_copy=yes],
1448         [glib_cv___va_copy=no])
1449 ])
1450
1451 if test "x$glib_cv_va_copy" = "xyes"; then
1452   g_va_copy_func=va_copy
1453 else if test "x$glib_cv___va_copy" = "xyes"; then
1454   g_va_copy_func=__va_copy
1455 fi
1456 fi
1457
1458 if test -n "$g_va_copy_func"; then
1459   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1460 fi
1461
1462 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1463         AC_TRY_RUN([#include <stdarg.h>
1464 #include <stdlib.h>
1465         void f (int i, ...) {
1466         va_list args1, args2;
1467         va_start (args1, i);
1468         args2 = args1;
1469         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1470           exit (1);
1471         va_end (args1); va_end (args2);
1472         }
1473         int main() {
1474           f (0, 42);
1475           return 0;
1476         }],
1477         [glib_cv_va_val_copy=yes],
1478         [glib_cv_va_val_copy=no],
1479         [glib_cv_va_val_copy=yes])
1480 ])
1481
1482 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1483   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1484 ])
1485
1486 dnl ***********************
1487 dnl *** g_module checks ***
1488 dnl ***********************
1489 G_MODULE_LIBS=
1490 G_MODULE_LIBS_EXTRA=
1491 G_MODULE_PLUGIN_LIBS=
1492 if test x"$glib_native_win32" = xyes; then
1493   dnl No use for this on Win32
1494   G_MODULE_LDFLAGS=
1495 else
1496   export SED
1497   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1498 fi
1499 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1500 G_MODULE_NEED_USCORE=0
1501 G_MODULE_BROKEN_RTLD_GLOBAL=0
1502 G_MODULE_HAVE_DLERROR=0
1503 dnl *** force native WIN32 shared lib loader
1504 if test -z "$G_MODULE_IMPL"; then
1505   case "$host" in
1506   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1507   esac
1508 fi
1509 dnl *** force native AIX library loader
1510 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1511 if test -z "$G_MODULE_IMPL"; then
1512   case "$host" in
1513   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1514   esac
1515 fi
1516 dnl *** dlopen() and dlsym() in system libraries
1517 AS_IF([ test -z "$G_MODULE_IMPL"], [
1518         AC_CHECK_FUNC(dlopen,
1519                       [AC_CHECK_FUNC(dlsym,
1520                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1521                       [])
1522 ])
1523 dnl *** load_image (BeOS)
1524 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1525   AC_CHECK_LIB(root, load_image,
1526       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1527       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1528       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1529       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1530       [])
1531 ])
1532 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1533 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1534         AC_CHECK_FUNC(NSLinkModule,
1535                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1536                        G_MODULE_NEED_USCORE=1],
1537                       [])
1538 ])
1539 dnl *** dlopen() and dlsym() in libdl
1540 AS_IF([ test -z "$G_MODULE_IMPL"], [
1541         AC_CHECK_LIB(dl, dlopen,
1542                      [AC_CHECK_LIB(dl, dlsym,
1543                                    [G_MODULE_LIBS=-ldl
1544                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1545                      [])
1546 ])
1547 dnl *** shl_load() in libdld (HP-UX)
1548 AS_IF([ test -z "$G_MODULE_IMPL"], [
1549         AC_CHECK_LIB(dld, shl_load,
1550                 [G_MODULE_LIBS=-ldld
1551                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1552                 [])
1553 ])
1554 dnl *** additional checks for G_MODULE_IMPL_DL
1555 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1556         LIBS_orig="$LIBS"
1557         LDFLAGS_orig="$LDFLAGS"
1558         LIBS="$G_MODULE_LIBS $LIBS"
1559         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1560 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1561         echo "void glib_plugin_test(void) { }" > plugin.c
1562         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1563                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1564         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1565                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1566                 -shrext ".o" -avoid-version plugin.lo \
1567                 -rpath /dont/care >/dev/null 2>&1
1568         eval `./libtool --config | grep ^objdir`
1569         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1570                 glib_cv_rtldglobal_broken,[
1571                 AC_TRY_RUN([
1572 #include <dlfcn.h>
1573 #ifndef RTLD_GLOBAL
1574 #  define RTLD_GLOBAL 0
1575 #endif
1576 #ifndef RTLD_LAZY
1577 #  define RTLD_LAZY 0
1578 #endif
1579 int glib_plugin_test;
1580 int main () {
1581     void *handle, *global, *local;
1582     global = &glib_plugin_test;
1583     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1584     if (!handle) return 0;
1585     local = dlsym (handle, "glib_plugin_test");
1586     return global == local;
1587 }                       ],
1588                         [glib_cv_rtldglobal_broken=no],
1589                         [glib_cv_rtldglobal_broken=yes],
1590                         [glib_cv_rtldglobal_broken=no])
1591                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1592                 rmdir ${objdir} 2>/dev/null
1593         ])
1594         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1595                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1596         else
1597                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1598         fi
1599 dnl *** check whether we need preceeding underscores
1600         AC_CACHE_CHECK([for preceeding underscore in symbols],
1601                 glib_cv_uscore,[
1602                 AC_TRY_RUN([#include <dlfcn.h>
1603                 int glib_underscore_test (void) { return 42; }
1604                 int main() {
1605                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1606                   handle = dlopen ((void*)0, 0);
1607                   if (handle) {
1608                     f1 = dlsym (handle, "glib_underscore_test");
1609                     f2 = dlsym (handle, "_glib_underscore_test");
1610                   } return (!f2 || f1);
1611                 }],
1612                         [glib_cv_uscore=yes],
1613                         [glib_cv_uscore=no],
1614                         [])
1615                 rm -f plugin.c plugin.$ac_objext plugin.lo
1616         ])
1617         GLIB_ASSERT_SET(glib_cv_uscore)
1618         if test "x$glib_cv_uscore" = "xyes"; then
1619                 G_MODULE_NEED_USCORE=1
1620         else
1621                 G_MODULE_NEED_USCORE=0
1622         fi
1623
1624         LDFLAGS="$LDFLAGS_orig"
1625 dnl *** check for having dlerror()
1626         AC_CHECK_FUNC(dlerror,
1627                 [G_MODULE_HAVE_DLERROR=1],
1628                 [G_MODULE_HAVE_DLERROR=0])
1629         LIBS="$LIBS_orig"
1630 ])
1631 dnl *** done, have we got an implementation?
1632 if test -z "$G_MODULE_IMPL"; then
1633         G_MODULE_IMPL=0
1634         G_MODULE_SUPPORTED=false
1635 else
1636         G_MODULE_SUPPORTED=true
1637 fi
1638
1639 AC_MSG_CHECKING(for the suffix of module shared libraries)
1640 export SED
1641 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1642 eval $shrext_cmds
1643 module=yes eval std_shrext=$shrext_cmds
1644 # chop the initial dot
1645 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1646 AC_MSG_RESULT(.$glib_gmodule_suffix)
1647 # any reason it may fail?
1648 if test "x$glib_gmodule_suffix" = x; then
1649         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1650 fi
1651
1652 AC_SUBST(G_MODULE_SUPPORTED)
1653 AC_SUBST(G_MODULE_IMPL)
1654 AC_SUBST(G_MODULE_LIBS)
1655 AC_SUBST(G_MODULE_LIBS_EXTRA)
1656 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1657 AC_SUBST(G_MODULE_LDFLAGS)
1658 AC_SUBST(G_MODULE_HAVE_DLERROR)
1659 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1660 AC_SUBST(G_MODULE_NEED_USCORE)
1661 AC_SUBST(GLIB_DEBUG_FLAGS)
1662
1663 dnl **********************
1664 dnl *** g_spawn checks ***
1665 dnl **********************
1666
1667 AC_MSG_CHECKING(for gspawn implementation)
1668 case "$host" in
1669   *-*-mingw*)
1670     GSPAWN=gspawn-win32.lo
1671     ;;
1672   *)
1673     GSPAWN=gspawn.lo
1674     ;;
1675 esac
1676 AC_MSG_RESULT($GSPAWN)
1677 AC_SUBST(GSPAWN)
1678
1679 dnl *************************
1680 dnl *** GIOChannel checks ***
1681 dnl *************************
1682
1683 AC_MSG_CHECKING(for GIOChannel implementation)
1684 case "$host" in
1685   *-*-mingw*)
1686     GIO=giowin32.lo
1687     ;;
1688   *)
1689     GIO=giounix.lo
1690     ;;
1691 esac
1692 AC_MSG_RESULT($GIO)
1693 AC_SUBST(GIO)
1694
1695 dnl *********************************
1696 dnl *** Directory for GIO modules ***
1697 dnl *********************************
1698
1699 AC_ARG_WITH(gio-module-dir,
1700            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1701                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1702            [],
1703            [with_gio_module_dir='${libdir}/gio/modules'])
1704 GIO_MODULE_DIR=$with_gio_module_dir
1705 AC_SUBST(GIO_MODULE_DIR)
1706
1707 dnl **********************************
1708 dnl *** Check for libselinux (GIO) ***
1709 dnl **********************************
1710 AC_ARG_ENABLE(selinux,
1711               AS_HELP_STRING([--disable-selinux],
1712                              [build without selinux support]))
1713 msg_selinux=no
1714 SELINUX_LIBS=
1715 AS_IF([ test "x$enable_selinux" != "xno"], [
1716
1717  AC_CHECK_LIB(selinux, is_selinux_enabled,
1718    [AC_CHECK_HEADERS(selinux/selinux.h,
1719      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1720        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1721         SELINUX_LIBS="-lselinux"
1722         msg_selinux=yes])
1723      ])
1724    ])
1725 ])
1726 AC_SUBST(SELINUX_LIBS)
1727
1728 dnl *****************************
1729 dnl ** Check for inotify (GIO) **
1730 dnl *****************************
1731 inotify_support=no
1732 AC_CHECK_HEADERS([sys/inotify.h],
1733 [
1734         inotify_support=yes
1735         AC_CHECK_FUNCS(inotify_init1)
1736 ])
1737
1738 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1739
1740 dnl ****************************
1741 dnl ** Check for kqueue (GIO) **
1742 dnl ****************************
1743 kqueue_support=no
1744 AC_CHECK_HEADERS([sys/event.h],
1745 [
1746         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1747 ])
1748
1749 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1750
1751 dnl *********************************
1752 dnl ** Check for Solaris FEN (GIO) **
1753 dnl *********************************
1754 fen_support=no
1755 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1756 #include <port.h>
1757 #ifndef PORT_SOURCE_FILE
1758 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1759 #endif
1760 int main() { return 0; } ]])],
1761 [
1762         fen_support=yes
1763 ],)
1764
1765 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1766
1767 dnl ****************************
1768 dnl *** Checks for FAM (GIO) ***
1769 dnl ****************************
1770
1771 should_disable_fam=no
1772
1773 AC_ARG_ENABLE(fam,
1774               AS_HELP_STRING([--disable-fam],
1775                              [don't use fam for file system monitoring]),
1776                          [
1777                                 if test "x$enable_fam" = "xno"; then
1778                                         should_disable_fam=yes
1779                                 fi
1780                          ]
1781                          )
1782 fam_support=no
1783 FAM_LIBS=
1784 if test "x$should_disable_fam" = "xno"; then
1785 AC_CHECK_LIB(fam, FAMOpen,
1786   [AC_CHECK_HEADERS(fam.h,
1787     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1788      AC_CHECK_LIB(fam, FAMNoExists,
1789                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1790      FAM_LIBS="-lfam"]
1791      fam_support=yes,
1792     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1793   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1794 AC_SUBST(FAM_LIBS)
1795 fi
1796 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1797
1798
1799 dnl *****************************
1800 dnl *** Check for xattr (GIO) ***
1801 dnl *****************************
1802 AC_ARG_ENABLE(xattr,
1803               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1804 msg_xattr=no
1805 XATTR_LIBS=
1806 AS_IF([ test "x$enable_xattr" != "xno"], [
1807
1808 dnl either glibc or libattr can provide xattr support
1809
1810 dnl for both of them, we check for getxattr being in
1811 dnl the library and a valid xattr header.
1812
1813 dnl try glibc
1814  AC_CHECK_LIB(c, getxattr,
1815    [AC_CHECK_HEADERS(sys/xattr.h,
1816      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1817       msg_xattr=yes])
1818    ])
1819
1820   AS_IF([ test "x$msg_xattr" != "xyes"], [
1821 dnl   failure. try libattr
1822    AC_CHECK_LIB(attr, getxattr,
1823       [AC_CHECK_HEADERS(attr/xattr.h,
1824        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1825         XATTR_LIBS="-lattr"
1826         msg_xattr=yes])
1827       ])
1828   ])
1829
1830   AS_IF([ test "x$msg_xattr" = "xyes"], [
1831     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1832     AC_TRY_COMPILE([
1833       #include <stdio.h>
1834       #ifdef HAVE_SYS_TYPES_H
1835       #include <sys/types.h>
1836       #endif
1837       #ifdef HAVE_SYS_XATTR_H
1838       #include <sys/xattr.h>
1839       #elif HAVE_ATTR_XATTR_H
1840       #include <attr/xattr.h>
1841       #endif
1842     ],
1843     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1844     [
1845       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1846       AC_MSG_RESULT([yes])
1847     ],
1848     [AC_MSG_RESULT([no])]
1849     )
1850   ])
1851 ])
1852 AC_SUBST(XATTR_LIBS)
1853
1854 dnl ************************
1855 dnl *** check for libelf ***
1856 dnl ************************
1857 AC_ARG_ENABLE(libelf,
1858               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1859 AS_IF([ test "x$enable_libelf" != "xno"],[
1860 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1861 AS_IF([ test $have_libelf = maybe ], [
1862   glib_save_LIBS=$LIBS
1863   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1864   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1865   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1866   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1867   LIBS=$glib_save_LIBS
1868
1869   if test $have_libelf != no; then
1870     LIBELF_LIBS=-lelf
1871     have_libelf=yes
1872   fi
1873 ])
1874 ])
1875
1876 if test x$have_libelf = xyes; then
1877   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1878 fi
1879
1880 dnl ****************************************
1881 dnl *** platform dependent source checks ***
1882 dnl ****************************************
1883
1884 AC_MSG_CHECKING(for platform-dependent source)
1885 case "$host" in
1886   *-*-cygwin*|*-*-mingw*)
1887     PLATFORMDEP=gwin32.lo
1888     ;;
1889   *)
1890     PLATFORMDEP=
1891     ;;
1892 esac
1893 AC_MSG_RESULT($PLATFORMDEP)
1894 AC_SUBST(PLATFORMDEP)
1895
1896 AC_MSG_CHECKING([whether to compile timeloop])
1897 case "$host" in
1898   *-*-cygwin*|*-*-mingw*|*-*-minix)
1899     enable_timeloop=no
1900     ;;
1901   *)
1902     enable_timeloop=yes
1903     ;;
1904 esac
1905 AC_MSG_RESULT($enable_timeloop)
1906 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1907
1908 AC_MSG_CHECKING([if building for some Win32 platform])
1909 case "$host" in
1910   *-*-mingw*|*-*-cygwin*)
1911     platform_win32=yes
1912     ;;
1913   *)
1914     platform_win32=no
1915     ;;
1916 esac
1917 AC_MSG_RESULT($platform_win32)
1918 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1919
1920 dnl ***********************
1921 dnl *** g_thread checks ***
1922 dnl ***********************
1923
1924 AC_ARG_WITH(threads,
1925            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1926                            [specify a thread implementation to use])],
1927            [],
1928            [with_threads=yes])
1929
1930 dnl error and warning message
1931 dnl *************************
1932
1933 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1934
1935 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1936                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1937                 compilation now, but then your programs might not work.
1938                 Please provide information on how it is done on your system."
1939
1940 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1941                  "
1942
1943 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1944                   provide information on your thread implementation."
1945
1946 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1947                 functions will not be MT-safe during their first call because
1948                 there is no working 'getpwuid_r' on your system."
1949
1950 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1951                 because there is no 'localtime_r' on your system."
1952
1953 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1954                 linking threaded applications. As GLib cannot do that
1955                 automatically, you will get an linkg error everytime you are
1956                 not using the right compiler. In that case you have to relink
1957                 with the right compiler. Ususally just '_r' is appended
1958                 to the compiler name."
1959
1960 dnl determination of thread implementation
1961 dnl ***************************************
1962
1963 AC_MSG_CHECKING(for thread implementation)
1964
1965 have_threads=no
1966 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1967         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1968         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1969         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1970         glib_save_CPPFLAGS="$CPPFLAGS"
1971         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1972         AS_IF([ test "x$have_threads" = xno], [
1973                 AC_TRY_COMPILE([#include <pthread.h>],
1974                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1975                         have_threads=posix)
1976         ])
1977         # Tru64Unix requires -pthread to find pthread.h. See #103020
1978         CPPFLAGS="$CPPFLAGS -pthread"
1979         if test "x$have_threads" = xno; then
1980         AC_TRY_COMPILE([#include <pthread.h>],
1981                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1982                        have_threads=posix)
1983         fi
1984         CPPFLAGS="$glib_save_CPPFLAGS"
1985 ])
1986 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1987         case $host in
1988                 *-*-mingw*)
1989                 have_threads=win32
1990                 ;;
1991         esac
1992 fi
1993
1994 if test "x$have_threads" = xno; then
1995         AC_MSG_RESULT(none available)
1996         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1997 else
1998         AC_MSG_RESULT($have_threads)
1999 fi
2000
2001
2002 dnl determination of G_THREAD_CFLAGS
2003 dnl ********************************
2004
2005 G_THREAD_LIBS=
2006 G_THREAD_LIBS_EXTRA=
2007 G_THREAD_CFLAGS=
2008
2009 dnl
2010 dnl Test program for basic POSIX threads functionality
2011 dnl
2012 m4_define([glib_thread_test],[
2013 #include <pthread.h>
2014 int check_me = 0;
2015 void* func(void* data) {check_me = 42; return &check_me;}
2016 int main()
2017  { pthread_t t;
2018    void *ret;
2019    pthread_create (&t, $1, func, 0);
2020    pthread_join (t, &ret);
2021    return (check_me != 42 || ret != &check_me);
2022 }])
2023
2024 AS_IF([ test x"$have_threads" = xposix], [
2025   # First we test for posix, whether -pthread or -pthreads do the trick as
2026   # both CPPFLAG and LIBS.
2027   # One of them does for most gcc versions and some other platforms/compilers
2028   # too and could be considered as the canonical way to go.
2029   case $host in
2030     *-*-cygwin*|*-*-darwin*)
2031        # skip cygwin and darwin -pthread or -pthreads test
2032        ;;
2033     *-solaris*)
2034       # These compiler/linker flags work with both Sun Studio and gcc
2035       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2036       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2037       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2038       G_THREAD_LIBS="-lpthread -lthread"
2039       ;;
2040     *)
2041       for flag in pthread pthreads mt; do
2042         glib_save_CFLAGS="$CFLAGS"
2043         CFLAGS="$CFLAGS -$flag"
2044         AC_TRY_RUN(glib_thread_test(0),
2045                    glib_flag_works=yes,
2046                    glib_flag_works=no,
2047                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2048                                    glib_flag_works=yes,
2049                                    glib_flag_works=no)])
2050         CFLAGS="$glib_save_CFLAGS"
2051         if test $glib_flag_works = yes ; then
2052            G_THREAD_CFLAGS=-$flag
2053         G_THREAD_LIBS=-$flag
2054         break;
2055         fi
2056       done
2057        ;;
2058   esac
2059 ])
2060
2061 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2062
2063   # The canonical -pthread[s] does not work. Try something different.
2064
2065   case $host in
2066         *-aix*)
2067                 if test x"$GCC" = xyes; then
2068                         # GCC 3.0 and above needs -pthread.
2069                         # Should be coverd by the case above.
2070                         # GCC 2.x and below needs -mthreads
2071                         G_THREAD_CFLAGS="-mthreads"
2072                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2073                 else
2074                         # We are probably using the aix compiler. Normaly a
2075                         # program would have to be compiled with the _r variant
2076                         # of the corresponding compiler, but we as GLib cannot
2077                         # do that: but the good news is that for compiling the
2078                         # only difference is the added -D_THREAD_SAFE compile
2079                         # option. This is according to the "C for AIX User's
2080                         # Guide".
2081                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2082                 fi
2083                 ;;
2084         *-dg-dgux*)  # DG/UX
2085                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2086                 ;;
2087         *-sysv5uw7*) # UnixWare 7
2088                 # We are not using gcc with -pthread. Catched above.
2089                 G_THREAD_CFLAGS="-Kthread"
2090                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2091                 ;;
2092         *-mingw*)
2093                 # No flag needed when using MSVCRT.DLL
2094                 G_THREAD_CFLAGS=""
2095                 ;;
2096         *)
2097                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2098                 ;;
2099   esac
2100 ])
2101
2102 # if we are not finding the localtime_r function, then we probably are
2103 # not using the proper multithread flag
2104
2105 glib_save_CPPFLAGS="$CPPFLAGS"
2106 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2107
2108 # First we test, whether localtime_r is declared in time.h
2109 # directly. Then we test whether a macro localtime_r exists, in
2110 # which case localtime_r in the test program is replaced and thus
2111 # if we still find localtime_r in the output, it is not defined as
2112 # a macro.
2113
2114 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2115   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2116                                                            localtime_r(a,b)],
2117                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2118
2119 CPPFLAGS="$glib_save_CPPFLAGS"
2120
2121 AC_MSG_CHECKING(thread related cflags)
2122 AC_MSG_RESULT($G_THREAD_CFLAGS)
2123 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2124
2125 dnl determination of G_THREAD_LIBS
2126 dnl ******************************
2127
2128 AS_IF([test x$have_threads = xposix], [
2129           glib_save_CPPFLAGS="$CPPFLAGS"
2130           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2131           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2132             case $host in
2133               *-aix*)
2134                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2135                 # probably using the aix compiler.
2136                 AC_MSG_WARN($AIX_COMPILE_INFO)
2137                 ;;
2138               *)
2139                 G_THREAD_LIBS=error
2140                 glib_save_LIBS="$LIBS"
2141                 for thread_lib in "" pthread pthread32 pthreads thread; do
2142                         if test x"$thread_lib" = x; then
2143                                 add_thread_lib=""
2144                                 IN=""
2145                         else
2146                                 add_thread_lib="-l$thread_lib"
2147                                 IN=" in -l$thread_lib"
2148                         fi
2149                         if test x"$have_threads" = xposix; then
2150                                 defattr=0
2151                         else
2152                                 defattr=pthread_attr_default
2153                         fi
2154
2155                         LIBS="$add_thread_lib $glib_save_LIBS"
2156
2157                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2158                         AC_TRY_RUN(glib_thread_test($defattr),
2159                                    glib_result=yes,
2160                                    glib_result=no,
2161                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2162                                                    glib_result=yes,
2163                                                    glib_result=no)])
2164                         AC_MSG_RESULT($glib_result)
2165
2166                         if test "$glib_result" = "yes" ; then
2167                           G_THREAD_LIBS="$add_thread_lib"
2168                           break
2169                         fi
2170                 done
2171                 if test "x$G_THREAD_LIBS" = xerror; then
2172                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2173                 fi
2174                 LIBS="$glib_save_LIBS"
2175                 ;;
2176             esac
2177           ])
2178
2179           g_threads_impl="POSIX"
2180           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2181           CPPFLAGS="$glib_save_CPPFLAGS"
2182 ], [test x$have_threads = xwin32], [
2183            g_threads_impl="WIN32"
2184 ], [
2185            g_threads_impl="NONE"
2186            G_THREAD_LIBS=error
2187 ])
2188
2189 if test "x$G_THREAD_LIBS" = xerror; then
2190         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2191 fi
2192
2193 case $host in
2194   *-*-beos*)
2195     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2196     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2197     ;;
2198   *)
2199     ;;
2200 esac
2201
2202 AC_MSG_CHECKING(thread related libraries)
2203 AC_MSG_RESULT($G_THREAD_LIBS)
2204
2205 dnl check for mt safe function variants and some posix functions
2206 dnl ************************************************************
2207
2208 glib_save_LIBS="$LIBS"
2209 # we are not doing the following for now, as this might require glib
2210 # to always be linked with the thread libs on some platforms.
2211 # LIBS="$LIBS $G_THREAD_LIBS"
2212 AC_CHECK_FUNCS(localtime_r gmtime_r)
2213 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2214         AC_CACHE_CHECK([for posix getpwuid_r],
2215                 ac_cv_func_posix_getpwuid_r,
2216                 [AC_TRY_RUN([
2217 #include <errno.h>
2218 #include <pwd.h>
2219 int main () {
2220     char buffer[10000];
2221     struct passwd pwd, *pwptr = &pwd;
2222     int error;
2223     errno = 0;
2224     error = getpwuid_r (0, &pwd, buffer,
2225                         sizeof (buffer), &pwptr);
2226    return (error < 0 && errno == ENOSYS)
2227            || error == ENOSYS;
2228 }                               ],
2229                         [ac_cv_func_posix_getpwuid_r=yes],
2230                         [ac_cv_func_posix_getpwuid_r=no])])
2231         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2232         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2233                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2234                         [Have POSIX function getpwuid_r])
2235         else
2236                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2237                         ac_cv_func_nonposix_getpwuid_r,
2238                         [AC_TRY_LINK([#include <pwd.h>],
2239                                 [char buffer[10000];
2240                                 struct passwd pwd;
2241                                 getpwuid_r (0, &pwd, buffer,
2242                                                 sizeof (buffer));],
2243                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2244                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2245                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2246                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2247                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2248                                 [Have non-POSIX function getpwuid_r])
2249                 fi
2250         fi
2251 ])
2252 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2253         AC_CACHE_CHECK([for posix getgrgid_r],
2254                 ac_cv_func_posix_getgrgid_r,
2255                 [AC_TRY_RUN([
2256 #include <errno.h>
2257 #include <grp.h>
2258 int main () {
2259     char buffer[10000];
2260     struct group grp, *grpptr = &grp;
2261     int error;
2262     errno = 0;
2263     error = getgrgid_r (0, &grp, buffer,
2264                         sizeof (buffer), &grpptr);
2265    return (error < 0 && errno == ENOSYS)
2266            || error == ENOSYS;
2267 }                              ],
2268                        [ac_cv_func_posix_getgrgid_r=yes],
2269                        [ac_cv_func_posix_getgrgid_r=no])])
2270         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2271         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2272                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2273                         [Have POSIX function getgrgid_r])
2274         ], [
2275                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2276                         ac_cv_func_nonposix_getgrgid_r,
2277                         [AC_TRY_LINK([#include <grp.h>],
2278                                 [char buffer[10000];
2279                                 struct group grp;
2280                                 getgrgid_r (0, &grp, buffer,
2281                                 sizeof (buffer));],
2282                         [ac_cv_func_nonposix_getgrgid_r=yes],
2283                         [ac_cv_func_nonposix_getgrgid_r=no])])
2284                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2285                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2286                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2287                                 [Have non-POSIX function getgrgid_r])
2288                 fi
2289         ])
2290 ])
2291 LIBS="$G_THREAD_LIBS $LIBS"
2292 AS_IF([ test x"$have_threads" = xposix], [
2293         glib_save_CPPFLAGS="$CPPFLAGS"
2294         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2295         # This is not AC_CHECK_FUNC to also work with function
2296         # name mangling in header files.
2297         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2298         AC_LINK_IFELSE(
2299             [AC_LANG_PROGRAM(
2300                 [#include <pthread.h>],
2301                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2302             [AC_MSG_RESULT(yes)
2303              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2304                 [Have function pthread_attr_setstacksize])],
2305             [AC_MSG_RESULT(no)])
2306         AC_MSG_CHECKING(for pthread_condattr_setclock)
2307         AC_LINK_IFELSE(
2308             [AC_LANG_PROGRAM(
2309                 [#include <pthread.h>],
2310                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2311             [AC_MSG_RESULT(yes)
2312              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2313                 [Have function pthread_condattr_setclock])],
2314             [AC_MSG_RESULT(no)])
2315         CPPFLAGS="$glib_save_CPPFLAGS"
2316 ])
2317
2318 LIBS="$glib_save_LIBS"
2319
2320 # now spit out all the warnings.
2321 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2322    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2323         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2324 fi
2325 if test "$ac_cv_func_localtime_r" != "yes"; then
2326         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2327 fi
2328
2329 #
2330 # Hack to deal with:
2331 #
2332 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2333 #     building shared libraries with linux.
2334 #  b) FreeBSD doesn't do this either.
2335 #
2336 case $host in
2337   *-*-freebsd*|*-*-linux*)
2338     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2339     ;;
2340   *-*-openbsd*)
2341     LDFLAGS="$LDFLAGS -pthread"
2342     ;;
2343   *)
2344     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2345     ;;
2346 esac
2347
2348 AC_SUBST(G_THREAD_CFLAGS)
2349 AC_SUBST(G_THREAD_LIBS)
2350 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2351 AC_SUBST(G_THREAD_LIBS_EXTRA)
2352
2353 AC_CHECK_FUNCS(clock_gettime, [], [
2354   AC_CHECK_LIB(rt, clock_gettime, [
2355     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2356     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2357     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2358   ])
2359 ])
2360
2361
2362 dnl ************************
2363 dnl *** g_atomic_* tests ***
2364 dnl ************************
2365
2366 dnl We need to decide at configure time if GLib will use real atomic
2367 dnl operations ("lock free") or emulated ones with a mutex.  This is
2368 dnl because we must put this information in glibconfig.h so we know if
2369 dnl it is safe or not to inline using compiler intrinsics directly from
2370 dnl the header.
2371 dnl
2372 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2373 dnl user is interested in knowing if they can use the atomic ops across
2374 dnl processes.
2375 dnl
2376 dnl We can currently support the atomic ops natively when building GLib
2377 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2378 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2379 dnl we are using GCC (and not mingw*).
2380 dnl
2381 dnl Note that the atomic ops are only available with GCC on x86 when
2382 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2383 dnl not available but would be available given the right flags, we want
2384 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2385 dnl that then to silently fall back on emulated atomic ops just because
2386 dnl the user had the wrong build environment.
2387
2388 dnl We may add other compilers here in the future...
2389
2390 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2391   case $host in
2392     *-*-mingw*)
2393       glib_cv_g_atomic_lock_free=yes
2394       ;;
2395     *)
2396       AC_TRY_COMPILE([],
2397                      [volatile int atomic = 2;\
2398                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2399                      [glib_cv_g_atomic_lock_free=yes],
2400                      [glib_cv_g_atomic_lock_free=no])
2401       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2402         SAVE_CFLAGS="${CFLAGS}"
2403         CFLAGS="-march=i486"
2404         AC_TRY_COMPILE([],
2405                        [volatile int atomic = 2;\
2406                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2407                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2408                        [])
2409         CFLAGS="${SAVE_CFLAGS}"
2410       fi
2411       ;;
2412   esac])
2413
2414
2415 case $host in
2416   *-*-mingw*)
2417     ;;
2418   *)
2419     # Some compilers support atomic operations but do not define
2420     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2421     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2422       AC_TRY_COMPILE([],
2423                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2424                      [],
2425                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2426     fi
2427     ;;
2428  esac
2429
2430 dnl We need a more robust approach here...
2431 case $host_cpu in
2432   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2433     glib_memory_barrier_needed=no
2434     ;;
2435   sparc*|alpha*|powerpc*|ia64)
2436     glib_memory_barrier_needed=yes
2437     ;;
2438   *)
2439     glib_memory_barrier_needed=yes
2440     ;;
2441 esac
2442
2443 dnl ************************
2444 dnl ** Check for futex(2) **
2445 dnl ************************
2446 AC_CACHE_CHECK(for futex(2) system call,
2447     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2448 #include <linux/futex.h>
2449 #include <sys/syscall.h>
2450 #include <unistd.h>
2451 ],[
2452 int
2453 main (void)
2454 {
2455   /* it is not like this actually runs or anything... */
2456   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2457   return 0;
2458 }
2459 ])],glib_cv_futex=yes,glib_cv_futex=no))
2460 if test x"$glib_cv_futex" = xyes; then
2461   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2462 fi
2463
2464 AC_CACHE_CHECK(for eventfd(2) system call,
2465     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2466 #include <sys/eventfd.h>
2467 #include <unistd.h>
2468 ],[
2469 int
2470 main (void)
2471 {
2472   eventfd (0, EFD_CLOEXEC);
2473   return 0;
2474 }
2475 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2476 if test x"$glib_cv_eventfd" = x"yes"; then
2477   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2478 fi
2479 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2480
2481 dnl ****************************************
2482 dnl *** GLib POLL* compatibility defines ***
2483 dnl ****************************************
2484
2485 glib_poll_includes=["
2486 #include <sys/types.h>
2487 #include <sys/poll.h>
2488 "]
2489
2490 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2491    test $ac_cv_header_sys_poll_h = yes ], [
2492   glib_failed=false
2493   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2494   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2495   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2496   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2497   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2498   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2499   if $glib_failed ; then
2500     AC_MSG_ERROR([Could not determine values for POLL* constants])
2501   fi
2502 ], [
2503   glib_cv_value_POLLIN=1
2504   glib_cv_value_POLLOUT=4
2505   glib_cv_value_POLLPRI=2
2506   glib_cv_value_POLLERR=8
2507   glib_cv_value_POLLHUP=16
2508   glib_cv_value_POLLNVAL=32
2509 ])
2510
2511 AC_MSG_CHECKING([for broken poll])
2512 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2513         #include <stdlib.h>
2514         #include <fcntl.h>
2515         #include <poll.h>
2516         #ifdef HAVE_SYS_POLL_H
2517         #include <sys/poll.h>
2518         #endif
2519         int main(void) {
2520           struct pollfd fds[1];
2521           int fd;
2522           fd = open("/dev/null", 1);
2523           fds[0].fd = fd;
2524           fds[0].events = POLLIN;
2525           fds[0].revents = 0;
2526           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2527                 exit(1);  /* Does not work for devices -- fail */
2528           }
2529           exit(0);
2530         }]])],
2531   [broken_poll=no],
2532   [broken_poll=yes
2533    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2534   [broken_poll="no (cross compiling)"])
2535 AC_MSG_RESULT($broken_poll)
2536
2537 dnl *********************
2538 dnl *** GRegex checks ***
2539 dnl *********************
2540
2541 PCRE_REQUIRED_VERSION=8.13
2542
2543 # Check if we should use the internal or the system-supplied pcre
2544 AC_ARG_WITH(pcre,
2545             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2546                             [whether to use system PCRE [default=internal]])])
2547
2548 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2549
2550 AS_IF([ test "x$with_pcre" = xsystem], [
2551   PKG_CHECK_MODULES(PCRE,
2552                     libpcre >= $PCRE_REQUIRED_VERSION)
2553   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2554                   glib_save_CFLAGS="$CFLAGS"
2555                   glib_save_LIBS="$LIBS"
2556                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2557                   AC_TRY_RUN([#include <pcre.h>
2558                               int main () {
2559                                 int support;
2560                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2561                                 if (!support)
2562                                   return 1;
2563                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2564                                 if (!support)
2565                                   return 1;
2566                                 return 0;
2567                               }],
2568                   glib_cv_pcre_has_unicode=yes,
2569                   glib_cv_pcre_has_unicode=no,
2570                   glib_cv_pcre_has_unicode=yes)
2571                   CFLAGS="$glib_save_CFLAGS"
2572                   LIBS="$glib_save_LIBS"
2573       ])
2574   if test "$glib_cv_pcre_has_unicode" = "no"; then
2575     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2576   fi
2577   AC_SUBST(PCRE_CFLAGS)
2578   AC_SUBST(PCRE_LIBS)
2579   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2580   PCRE_REQUIRES=libpcre
2581   AC_SUBST(PCRE_REQUIRES)
2582 ], [
2583   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2584   AS_IF([ test x"$GCC" = xyes], [
2585     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2586     save_CFLAGS="$CFLAGS"
2587     CFLAGS="$CFLAGS -Wno-pointer-sign"
2588     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2589                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2590     CFLAGS="$save_CFLAGS"
2591   ])
2592 ])
2593 AC_SUBST(PCRE_WARN_CFLAGS)
2594
2595 dnl **********************
2596 dnl *** Win32 API libs ***
2597 dnl **********************
2598
2599 case $host in
2600   *-*-cygwin*)
2601         G_LIBS_EXTRA="-luser32 -lkernel32"
2602     ;;
2603   *-*-mingw*)
2604         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2605     ;;
2606   *)
2607         G_LIBS_EXTRA=""
2608     ;;
2609 esac
2610 AC_SUBST(G_LIBS_EXTRA)
2611
2612 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2613 dnl since we need it for g_iconv()
2614
2615 AC_MSG_CHECKING([for EILSEQ])
2616 AC_TRY_COMPILE([
2617 #include <errno.h>
2618 ],
2619 [
2620 int error = EILSEQ;
2621 ], have_eilseq=yes, have_eilseq=no);
2622 AC_MSG_RESULT($have_eilseq)
2623
2624 dnl ******************************************************************
2625 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2626 dnl *** glib-compile-schemas in PATH                               ***
2627 dnl ******************************************************************
2628
2629 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2630
2631 AS_IF([ test $cross_compiling = yes && test x$enable_modular_tests = xyes], [
2632   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2633   if test x$GLIB_GENMARSHAL = xno; then
2634     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2635   fi
2636
2637   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2638   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2639     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2640   fi
2641
2642   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2643   if test x$GLIB_COMPILE_RESOURCES = xno; then
2644     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2645   fi
2646 ])
2647
2648 dnl **************************
2649 dnl *** Checks for gtk-doc ***
2650 dnl **************************
2651 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2652 # it on it's own line.
2653 m4_ifdef([GTK_DOC_CHECK], [
2654 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2655 ],[
2656 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2657 ])
2658
2659 AC_ARG_ENABLE(man,
2660               [AS_HELP_STRING([--enable-man],
2661                               [generate man pages [default=auto]])],,
2662               enable_man=maybe)
2663
2664 AS_IF([test "$enable_man" != no], [
2665   AC_PATH_PROG([XSLTPROC], [xsltproc])
2666   AS_IF([test -z "$XSLTPROC"], [
2667     AS_IF([test "$enable_man" = yes], [
2668       AC_MSG_ERROR([xsltproc is required for --enable-man])
2669     ])
2670     enable_man=no
2671   ])
2672 ])
2673
2674 AS_IF([ test "$enable_man" != no ], [
2675   dnl check for DocBook DTD in the local catalog
2676   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2677      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2678   AS_IF([test "$have_docbook_dtd" != yes], [
2679     AS_IF([test "$enable_man" = yes ], [
2680       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2681     ])
2682     enable_man=no
2683   ])
2684 ])
2685
2686 AS_IF([test "$enable_man" != no], [
2687   dnl check for DocBook XSL stylesheets in the local catalog
2688   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2689      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2690   AS_IF([ test "$have_docbook_dtd" != yes ], [
2691     AS_IF([ test "$enable_man" = yes ], [
2692       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2693     ])
2694     enable_man=no
2695   ])
2696 ])
2697
2698 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2699
2700 AC_MSG_CHECKING([whether to generate man pages])
2701 AS_IF([ test "$enable_man" != no ], [
2702   AC_MSG_RESULT([yes])
2703 ], [
2704   AC_MSG_RESULT([no])
2705 ])
2706
2707 dnl
2708 dnl Tracing
2709 dnl
2710
2711 AC_ARG_ENABLE([dtrace],
2712              [AS_HELP_STRING([--enable-dtrace],
2713                               [include tracing support for dtrace])])
2714 have_dtrace=no
2715 AC_MSG_CHECKING([whether to include dtrace tracing support])
2716 AS_IF([ test "x$enable_dtrace" != xno], [
2717   if test x$glib_have_carbon = xyes; then
2718     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2719   else
2720     AC_MSG_RESULT([yes])
2721     AC_CHECK_PROGS(DTRACE, dtrace)
2722     if test -z "$DTRACE"; then
2723       if test "x$enable_dtrace" = xyes; then
2724         AC_MSG_ERROR([dtrace not found])
2725       fi
2726     else
2727       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2728                       [if test "x$enable_dtrace" = xyes; then
2729                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2730                        fi])
2731     fi
2732   fi
2733 ], [
2734   AC_MSG_RESULT([no])
2735 ])
2736 if test "x$have_dtrace" = xyes; then
2737   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2738 fi
2739 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2740
2741 AC_MSG_CHECKING([whether to include systemtap tracing support])
2742 AC_ARG_ENABLE([systemtap],
2743              [AS_HELP_STRING([--enable-systemtap],
2744                               [include tracing support for systemtap])])
2745 have_systemtap=no
2746 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2747   have_systemtap=yes
2748 fi
2749 AC_MSG_RESULT(${have_systemtap})
2750
2751 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2752
2753 AC_ARG_WITH([tapset-install-dir],
2754             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2755                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2756             [if test "x${withval}" = x; then
2757                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2758              else
2759                ABS_TAPSET_DIR="${withval}"
2760               fi],
2761             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2762 AC_SUBST(ABS_TAPSET_DIR)
2763
2764 dnl ************************************
2765 dnl *** Enable lcov coverage reports ***
2766 dnl ************************************
2767
2768 AC_ARG_ENABLE(gcov,
2769   AS_HELP_STRING([--enable-gcov],
2770                  [enable coverage testing with gcov]),
2771   [use_gcov=$enableval], [use_gcov=no])
2772
2773 AS_IF([ test "x$use_gcov" = "xyes"], [
2774   dnl we need gcc:
2775   if test "$GCC" != "yes"; then
2776     AC_MSG_ERROR([GCC is required for --enable-gcov])
2777   fi
2778
2779   dnl Check if ccache is being used
2780   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2781   case `$SHTOOL path $CC` in
2782     *ccache*[)] gcc_ccache=yes;;
2783     *[)] gcc_ccache=no;;
2784   esac
2785
2786   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2787     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2788   fi
2789
2790   ltp_version_list="1.6 1.7 1.8 1.9"
2791   AC_CHECK_PROG(LTP, lcov, lcov)
2792   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2793
2794   AS_IF([ test "$LTP" ], [
2795     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2796       glib_cv_ltp_version=invalid
2797       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2798       for ltp_check_version in $ltp_version_list; do
2799         if test "$ltp_version" = "$ltp_check_version"; then
2800           glib_cv_ltp_version="$ltp_check_version (ok)"
2801         fi
2802       done
2803     ])
2804   ], [
2805     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2806     AC_MSG_ERROR([$ltp_msg])
2807   ])
2808
2809   case $glib_cv_ltp_version in
2810     ""|invalid[)]
2811       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2812       AC_MSG_ERROR([$ltp_msg])
2813       LTP="exit 0;"
2814       ;;
2815   esac
2816
2817   if test -z "$LTP_GENHTML"; then
2818     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2819   fi
2820
2821   dnl Remove all optimization flags from CFLAGS
2822   changequote({,})
2823   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2824   changequote([,])
2825
2826   dnl Add the special gcc flags
2827   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2828   LDFLAGS="$LDFLAGS -lgcov"
2829 ])
2830
2831 dnl ******************************
2832 dnl *** output the whole stuff ***
2833 dnl ******************************
2834
2835 dnl this section will only be run if config.status is invoked with no
2836 dnl arguments, or with "glib/glibconfig.h" as an argument.
2837 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2838 [
2839         outfile=glib/glibconfig.h-tmp
2840         cat > $outfile <<\_______EOF
2841 /* glibconfig.h
2842  *
2843  * This is a generated file.  Please modify 'configure.ac'
2844  */
2845
2846 #ifndef __GLIBCONFIG_H__
2847 #define __GLIBCONFIG_H__
2848
2849 #include <glib/gmacros.h>
2850
2851 _______EOF
2852
2853         if test x$glib_limits_h = xyes; then
2854           echo '#include <limits.h>' >> $outfile
2855         fi
2856         if test x$glib_float_h = xyes; then
2857           echo '#include <float.h>' >> $outfile
2858         fi
2859         if test x$glib_values_h = xyes; then
2860           echo '#include <values.h>' >> $outfile
2861         fi
2862         if test "$glib_header_alloca_h" = "yes"; then
2863           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2864         fi
2865         if test x$glib_sys_poll_h = xyes; then
2866           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2867         fi
2868         if test x$glib_included_printf != xyes; then
2869           echo "
2870 /* Specifies that GLib's g_print*() functions wrap the
2871  * system printf functions.  This is useful to know, for example,
2872  * when using glibc's register_printf_function().
2873  */" >> $outfile
2874           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2875         fi
2876
2877         cat >> $outfile <<_______EOF
2878
2879 G_BEGIN_DECLS
2880
2881 #define G_MINFLOAT      $glib_mf
2882 #define G_MAXFLOAT      $glib_Mf
2883 #define G_MINDOUBLE     $glib_md
2884 #define G_MAXDOUBLE     $glib_Md
2885 #define G_MINSHORT      $glib_ms
2886 #define G_MAXSHORT      $glib_Ms
2887 #define G_MAXUSHORT     $glib_Mus
2888 #define G_MININT        $glib_mi
2889 #define G_MAXINT        $glib_Mi
2890 #define G_MAXUINT       $glib_Mui
2891 #define G_MINLONG       $glib_ml
2892 #define G_MAXLONG       $glib_Ml
2893 #define G_MAXULONG      $glib_Mul
2894
2895 _______EOF
2896
2897
2898         ### this should always be true in a modern C/C++ compiler
2899         cat >>$outfile <<_______EOF
2900 typedef signed char gint8;
2901 typedef unsigned char guint8;
2902 _______EOF
2903
2904
2905         if test -n "$gint16"; then
2906           cat >>$outfile <<_______EOF
2907 typedef signed $gint16 gint16;
2908 typedef unsigned $gint16 guint16;
2909 #define G_GINT16_MODIFIER $gint16_modifier
2910 #define G_GINT16_FORMAT $gint16_format
2911 #define G_GUINT16_FORMAT $guint16_format
2912 _______EOF
2913         fi
2914
2915
2916         if test -n "$gint32"; then
2917           cat >>$outfile <<_______EOF
2918 typedef signed $gint32 gint32;
2919 typedef unsigned $gint32 guint32;
2920 #define G_GINT32_MODIFIER $gint32_modifier
2921 #define G_GINT32_FORMAT $gint32_format
2922 #define G_GUINT32_FORMAT $guint32_format
2923 _______EOF
2924         fi
2925
2926         cat >>$outfile <<_______EOF
2927 #define G_HAVE_GINT64 1          /* deprecated, always true */
2928
2929 ${glib_extension}typedef signed $gint64 gint64;
2930 ${glib_extension}typedef unsigned $gint64 guint64;
2931
2932 #define G_GINT64_CONSTANT(val)  $gint64_constant
2933 #define G_GUINT64_CONSTANT(val) $guint64_constant
2934 _______EOF
2935
2936         if test x$gint64_format != x ; then
2937           cat >>$outfile <<_______EOF
2938 #define G_GINT64_MODIFIER $gint64_modifier
2939 #define G_GINT64_FORMAT $gint64_format
2940 #define G_GUINT64_FORMAT $guint64_format
2941 _______EOF
2942         else
2943           cat >>$outfile <<_______EOF
2944 #undef G_GINT64_MODIFIER
2945 #undef G_GINT64_FORMAT
2946 #undef G_GUINT64_FORMAT
2947 _______EOF
2948         fi
2949
2950         cat >>$outfile <<_______EOF
2951
2952 #define GLIB_SIZEOF_VOID_P $glib_void_p
2953 #define GLIB_SIZEOF_LONG   $glib_long
2954 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2955
2956 _______EOF
2957
2958         cat >>$outfile <<_______EOF
2959 typedef signed $glib_size_type_define gssize;
2960 typedef unsigned $glib_size_type_define gsize;
2961 #define G_GSIZE_MODIFIER $gsize_modifier
2962 #define G_GSSIZE_FORMAT $gssize_format
2963 #define G_GSIZE_FORMAT $gsize_format
2964
2965 #define G_MAXSIZE       G_MAXU$glib_msize_type
2966 #define G_MINSSIZE      G_MIN$glib_msize_type
2967 #define G_MAXSSIZE      G_MAX$glib_msize_type
2968
2969 typedef gint64 goffset;
2970 #define G_MINOFFSET     G_MININT64
2971 #define G_MAXOFFSET     G_MAXINT64
2972
2973 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2974 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2975 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2976
2977 _______EOF
2978
2979         if test -z "$glib_unknown_void_p"; then
2980           cat >>$outfile <<_______EOF
2981
2982 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2983 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2984
2985 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2986 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2987
2988 typedef signed $glib_intptr_type_define gintptr;
2989 typedef unsigned $glib_intptr_type_define guintptr;
2990
2991 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2992 #define G_GINTPTR_FORMAT        $gintptr_format
2993 #define G_GUINTPTR_FORMAT       $guintptr_format
2994 _______EOF
2995         else
2996           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2997         fi
2998
2999
3000
3001         cat >>$outfile <<_______EOF
3002 $glib_atexit
3003 $glib_memmove
3004 $glib_defines
3005 $glib_os
3006 $glib_static_compilation
3007
3008 $glib_vacopy
3009
3010 #ifdef  __cplusplus
3011 #define G_HAVE_INLINE   1
3012 #else   /* !__cplusplus */
3013 $glib_inline
3014 #endif  /* !__cplusplus */
3015
3016 #ifdef  __cplusplus
3017 #define G_CAN_INLINE    1
3018 _______EOF
3019
3020         if test x$g_can_inline = xyes ; then
3021                 cat >>$outfile <<_______EOF
3022 #else   /* !__cplusplus */
3023 #define G_CAN_INLINE    1
3024 _______EOF
3025         fi
3026
3027         cat >>$outfile <<_______EOF
3028 #endif
3029
3030 _______EOF
3031
3032         if test x$g_have_iso_c_varargs = xyes ; then
3033                 cat >>$outfile <<_______EOF
3034 #ifndef __cplusplus
3035 # define G_HAVE_ISO_VARARGS 1
3036 #endif
3037 _______EOF
3038         fi
3039         if test x$g_have_iso_cxx_varargs = xyes ; then
3040                 cat >>$outfile <<_______EOF
3041 #ifdef __cplusplus
3042 # define G_HAVE_ISO_VARARGS 1
3043 #endif
3044 _______EOF
3045         fi
3046         if test x$g_have_gnuc_varargs = xyes ; then
3047                 cat >>$outfile <<_______EOF
3048
3049 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3050  * is passed ISO vararg support is turned off, and there is no work
3051  * around to turn it on, so we unconditionally turn it off.
3052  */
3053 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3054 #  undef G_HAVE_ISO_VARARGS
3055 #endif
3056
3057 #define G_HAVE_GNUC_VARARGS 1
3058 _______EOF
3059         fi
3060
3061         case x$g_stack_grows in
3062         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3063         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3064         esac
3065
3066
3067         echo >>$outfile
3068         if test x$g_have_eilseq = xno; then
3069                 cat >>$outfile <<_______EOF
3070 #ifndef EILSEQ
3071 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3072  * The correspondence between this and the corresponding definition
3073  * in libiconv is essential.
3074  */
3075 #  define EILSEQ ENOENT
3076 #endif
3077 _______EOF
3078
3079         fi
3080
3081         if test x$g_have_gnuc_visibility = xyes; then
3082                 cat >>$outfile <<_______EOF
3083 #define G_HAVE_GNUC_VISIBILITY 1
3084 _______EOF
3085         fi
3086                 cat >>$outfile <<_______EOF
3087 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3088 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3089 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3090 #define G_GNUC_INTERNAL __hidden
3091 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3092 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3093 #else
3094 #define G_GNUC_INTERNAL
3095 #endif
3096 _______EOF
3097
3098         echo >>$outfile
3099         cat >>$outfile <<_______EOF
3100 #define G_THREADS_ENABLED
3101 #define G_THREADS_IMPL_$g_threads_impl_def
3102 _______EOF
3103
3104         if test x"$g_memory_barrier_needed" != xno; then
3105           echo >>$outfile
3106           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3107         fi
3108         if test x"$g_atomic_lock_free" = xyes; then
3109           echo >>$outfile
3110           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3111         fi
3112         echo >>$outfile
3113         g_bit_sizes="16 32 64"
3114         for bits in $g_bit_sizes; do
3115           cat >>$outfile <<_______EOF
3116 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3117 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3118 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3119 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3120 _______EOF
3121         done
3122
3123         cat >>$outfile <<_______EOF
3124 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3125 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3126 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3127 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3128 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3129 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3130 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3131 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3132 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3133 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3134 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3135 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3136 #define G_BYTE_ORDER $g_byte_order
3137
3138 #define GLIB_SYSDEF_POLLIN =$g_pollin
3139 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3140 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3141 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3142 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3143 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3144
3145 #define G_MODULE_SUFFIX "$g_module_suffix"
3146
3147 typedef $g_pid_type GPid;
3148
3149 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3150 #define GLIB_SYSDEF_AF_INET $g_af_inet
3151 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3152
3153 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3154 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3155 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3156
3157 G_END_DECLS
3158
3159 #endif /* __GLIBCONFIG_H__ */
3160 _______EOF
3161
3162
3163         if cmp -s $outfile glib/glibconfig.h; then
3164           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3165           rm -f $outfile
3166         else
3167           mv $outfile glib/glibconfig.h
3168         fi
3169 ],[
3170
3171 # Note that if two cases are the same, case goes with the first one.
3172 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3173 # on variable expansion in case labels.  Look at the generated config.status
3174 # for a hint.
3175
3176 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3177   glib_header_alloca_h="$ac_cv_working_alloca_h"
3178 else
3179   glib_header_alloca_h="$ac_cv_header_alloca_h"
3180 fi
3181
3182 case xyes in
3183 x$ac_cv_header_float_h)
3184   glib_float_h=yes
3185   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3186   glib_md=DBL_MIN glib_Md=DBL_MAX
3187   ;;
3188 x$ac_cv_header_values_h)
3189   glib_values_h=yes
3190   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3191   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3192   ;;
3193 esac
3194
3195 case xyes in
3196 x$ac_cv_header_limits_h)
3197   glib_limits_h=yes
3198   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3199   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3200   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3201   ;;
3202 x$ac_cv_header_values_h)
3203   glib_values_h=yes
3204   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3205   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3206   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3207   ;;
3208 esac
3209
3210 if test x$ac_cv_header_sys_poll_h = xyes ; then
3211   glib_sys_poll_h=yes
3212 fi
3213
3214 if test x$enable_included_printf = xyes ; then
3215   glib_included_printf=yes
3216 fi
3217
3218 case 2 in
3219 $ac_cv_sizeof_short)
3220   gint16=short
3221   gint16_modifier='"h"'
3222   gint16_format='"hi"'
3223   guint16_format='"hu"'
3224   ;;
3225 $ac_cv_sizeof_int)
3226   gint16=int
3227   gint16_modifier='""'
3228   gint16_format='"i"'
3229   guint16_format='"u"'
3230   ;;
3231 esac
3232 case 4 in
3233 $ac_cv_sizeof_short)
3234   gint32=short
3235   gint32_modifier='"h"'
3236   gint32_format='"hi"'
3237   guint32_format='"hu"'
3238   ;;
3239 $ac_cv_sizeof_int)
3240   gint32=int
3241   gint32_modifier='""'
3242   gint32_format='"i"'
3243   guint32_format='"u"'
3244   ;;
3245 $ac_cv_sizeof_long)
3246   gint32=long
3247   gint32_modifier='"l"'
3248   gint32_format='"li"'
3249   guint32_format='"lu"'
3250   ;;
3251 esac
3252 case 8 in
3253 $ac_cv_sizeof_int)
3254   gint64=int
3255   gint64_modifier='""'
3256   gint64_format='"i"'
3257   guint64_format='"u"'
3258   glib_extension=
3259   gint64_constant='(val)'
3260   guint64_constant='(val)'
3261   ;;
3262 $ac_cv_sizeof_long)
3263   gint64=long
3264   gint64_modifier='"l"'
3265   gint64_format='"li"'
3266   guint64_format='"lu"'
3267   glib_extension=
3268   gint64_constant='(val##L)'
3269   guint64_constant='(val##UL)'
3270   ;;
3271 $ac_cv_sizeof_long_long)
3272   gint64='long long'
3273   if test -n "$glib_cv_long_long_format"; then
3274     gint64_modifier='"'$glib_cv_long_long_format'"'
3275     gint64_format='"'$glib_cv_long_long_format'i"'
3276     guint64_format='"'$glib_cv_long_long_format'u"'
3277   fi
3278   glib_extension='G_GNUC_EXTENSION '
3279   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3280   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3281   ;;
3282 $ac_cv_sizeof___int64)
3283   gint64='__int64'
3284   if test -n "$glib_cv_long_long_format"; then
3285     gint64_modifier='"'$glib_cv_long_long_format'"'
3286     gint64_format='"'$glib_cv_long_long_format'i"'
3287     guint64_format='"'$glib_cv_long_long_format'u"'
3288   fi
3289   glib_extension=
3290   gint64_constant='(val##i64)'
3291   guint64_constant='(val##ui64)'
3292   ;;
3293 esac
3294 glib_size_t=$ac_cv_sizeof_size_t
3295 glib_size_type_define="$glib_size_type"
3296 glib_void_p=$ac_cv_sizeof_void_p
3297 glib_long=$ac_cv_sizeof_long
3298
3299 case "$glib_size_type" in
3300 short)
3301   gsize_modifier='"h"'
3302   gsize_format='"hu"'
3303   gssize_format='"hi"'
3304   glib_msize_type='SHRT'
3305   ;;
3306 int)
3307   gsize_modifier='""'
3308   gsize_format='"u"'
3309   gssize_format='"i"'
3310   glib_msize_type='INT'
3311   ;;
3312 long)
3313   gsize_modifier='"l"'
3314   gsize_format='"lu"'
3315   gssize_format='"li"'
3316   glib_msize_type='LONG'
3317   ;;
3318 "long long"|__int64)
3319   gsize_modifier='"I64"'
3320   gsize_format='"I64u"'
3321   gssize_format='"I64i"'
3322   glib_msize_type='INT64'
3323   ;;
3324 esac
3325
3326 gintbits=`expr $ac_cv_sizeof_int \* 8`
3327 glongbits=`expr $ac_cv_sizeof_long \* 8`
3328 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3329
3330 case $ac_cv_sizeof_void_p in
3331 $ac_cv_sizeof_int)
3332   glib_intptr_type_define=int
3333   gintptr_modifier='""'
3334   gintptr_format='"i"'
3335   guintptr_format='"u"'
3336   glib_gpi_cast='(gint)'
3337   glib_gpui_cast='(guint)'
3338   ;;
3339 $ac_cv_sizeof_long)
3340   glib_intptr_type_define=long
3341   gintptr_modifier='"l"'
3342   gintptr_format='"li"'
3343   guintptr_format='"lu"'
3344   glib_gpi_cast='(glong)'
3345   glib_gpui_cast='(gulong)'
3346   ;;
3347 $ac_cv_sizeof_long_long)
3348   glib_intptr_type_define='long long'
3349   gintptr_modifier='"I64"'
3350   gintptr_format='"I64i"'
3351   guintptr_format='"I64u"'
3352   glib_gpi_cast='(gint64)'
3353   glib_gpui_cast='(guint64)'
3354   ;;
3355 $ac_cv_sizeof___int64)
3356   glib_intptr_type_define=__int64
3357   gintptr_modifier='"I64"'
3358   gintptr_format='"I64i"'
3359   guintptr_format='"I64u"'
3360   glib_gpi_cast='(gint64)'
3361   glib_gpui_cast='(guint64)'
3362   ;;
3363 *)
3364   glib_unknown_void_p=yes
3365   ;;
3366 esac
3367
3368
3369 case xyes in
3370 x$ac_cv_func_atexit)
3371   glib_atexit="
3372 #ifdef NeXT /* @#%@! NeXTStep */
3373 # define g_ATEXIT(proc) (!atexit (proc))
3374 #else
3375 # define g_ATEXIT(proc) (atexit (proc))
3376 #endif"
3377   ;;
3378 x$ac_cv_func_on_exit)
3379   glib_atexit="
3380 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3381   ;;
3382 esac
3383
3384 case xyes in
3385 x$ac_cv_func_memmove)
3386   glib_memmove='
3387 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3388   ;;
3389 x$glib_cv_working_bcopy)
3390   glib_memmove="
3391 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3392 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3393   ;;
3394 *)
3395   glib_memmove="
3396 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3397  * so we have to roll our own copy routine. */
3398 void g_memmove (void* dest, const void * src, unsigned long len);"
3399   ;;
3400 esac
3401
3402 glib_defines="
3403 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3404 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3405 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3406 "
3407
3408 case xyes in
3409 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3410 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3411 *)                      glib_vacopy=''
3412 esac
3413
3414 if test x$glib_cv_va_val_copy = xno; then
3415   glib_vacopy="\$glib_vacopy
3416 #define G_VA_COPY_AS_ARRAY 1"
3417 fi
3418
3419 if test x$glib_cv_hasinline = xyes; then
3420     glib_inline='#define G_HAVE_INLINE 1'
3421 fi
3422 if test x$glib_cv_has__inline = xyes; then
3423     glib_inline="\$glib_inline
3424 #define G_HAVE___INLINE 1"
3425 fi
3426 if test x$glib_cv_has__inline__ = xyes; then
3427     glib_inline="\$glib_inline
3428 #define G_HAVE___INLINE__ 1"
3429 fi
3430
3431 g_have_gnuc_varargs=$g_have_gnuc_varargs
3432 g_have_iso_c_varargs=$g_have_iso_c_varargs
3433 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3434
3435 g_can_inline=$g_can_inline
3436 g_have_gnuc_visibility=$g_have_gnuc_visibility
3437 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3438
3439 if test x$ac_cv_c_bigendian = xyes; then
3440   g_byte_order=G_BIG_ENDIAN
3441   g_bs_native=BE
3442   g_bs_alien=LE
3443 else
3444   g_byte_order=G_LITTLE_ENDIAN
3445   g_bs_native=LE
3446   g_bs_alien=BE
3447 fi
3448
3449 g_pollin=$glib_cv_value_POLLIN
3450 g_pollout=$glib_cv_value_POLLOUT
3451 g_pollpri=$glib_cv_value_POLLPRI
3452 g_pollhup=$glib_cv_value_POLLHUP
3453 g_pollerr=$glib_cv_value_POLLERR
3454 g_pollnval=$glib_cv_value_POLLNVAL
3455
3456 # If a family is not found on the system, define that family to
3457 # a negative value, picking a different one for each undefined
3458 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3459 # This is needed because glib-mkenums doesn't handle optional
3460 # values in enums, and thus we have to have all existing values
3461 # defined in the enum.
3462 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3463   g_af_unix=$glib_cv_value_AF_UNIX
3464 else
3465   g_af_unix=-1
3466 fi
3467 g_af_inet=$glib_cv_value_AF_INET
3468 g_af_inet6=$glib_cv_value_AF_INET6
3469
3470 g_msg_peek=$glib_cv_value_MSG_PEEK
3471 g_msg_oob=$glib_cv_value_MSG_OOB
3472 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3473
3474 g_stack_grows=$glib_cv_stack_grows
3475
3476 g_have_eilseq=$have_eilseq
3477
3478 g_threads_impl_def=$g_threads_impl
3479
3480 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3481 g_memory_barrier_needed="$glib_memory_barrier_needed"
3482 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3483
3484 g_module_suffix="$glib_gmodule_suffix"
3485
3486 g_pid_type="$glib_pid_type"
3487 case $host in
3488   *-*-beos*)
3489     glib_os="#define G_OS_BEOS"
3490     ;;
3491   *-*-cygwin*)
3492     glib_os="#define G_OS_UNIX
3493 #define G_PLATFORM_WIN32
3494 #define G_WITH_CYGWIN"
3495     ;;
3496   *-*-mingw*)
3497     glib_os="#define G_OS_WIN32
3498 #define G_PLATFORM_WIN32"
3499     ;;
3500   *)
3501     glib_os="#define G_OS_UNIX"
3502     ;;
3503 esac
3504 glib_static_compilation=""
3505 if test x$glib_win32_static_compilation = xyes; then
3506   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3507 #define GOBJECT_STATIC_COMPILATION 1"
3508 fi
3509 ])
3510
3511 # Redo enough to get guint32 and guint64 for the alignment checks below
3512 case 4 in
3513 $ac_cv_sizeof_short)
3514   gint32=short
3515   ;;
3516 $ac_cv_sizeof_int)
3517   gint32=int
3518   ;;
3519 $ac_cv_sizeof_long)
3520   gint32=long
3521   ;;
3522 esac
3523 case 8 in
3524 $ac_cv_sizeof_int)
3525   gint64=int
3526   ;;
3527 $ac_cv_sizeof_long)
3528   gint64=long
3529   ;;
3530 $ac_cv_sizeof_long_long)
3531   gint64='long long'
3532   ;;
3533 $ac_cv_sizeof___int64)
3534   gint64='__int64'
3535   ;;
3536 esac
3537
3538 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3539 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3540 typedef unsigned $gint32 guint32;])
3541 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3542 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3543 typedef unsigned $gint64 guint64;])
3544 AC_CHECK_TYPE([unsigned long])
3545 AC_CHECK_ALIGNOF([unsigned long])
3546
3547 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3548 #
3549 # 1.2.14 required for dbus_message_set_serial
3550 AS_IF([ test x$enable_modular_tests = xyes], [
3551    PKG_CHECK_MODULES(DBUS1,
3552                      dbus-1 >= 1.2.14,
3553                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3554                      have_dbus1=no)
3555    AC_SUBST(DBUS1_CFLAGS)
3556    AC_SUBST(DBUS1_LIBS)
3557 ])
3558 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3559
3560 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3561 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3562
3563 dnl
3564 dnl Check for -Bsymbolic-functions linker flag used to avoid
3565 dnl intra-library PLT jumps, if available.
3566 dnl
3567
3568 AC_ARG_ENABLE(Bsymbolic,
3569               [AS_HELP_STRING([--disable-Bsymbolic],
3570                               [avoid linking with -Bsymbolic])],,
3571               [SAVED_LDFLAGS="${LDFLAGS}"
3572                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3573                LDFLAGS=-Wl,-Bsymbolic-functions
3574                AC_TRY_LINK([], [int main (void) { return 0; }],
3575                            AC_MSG_RESULT(yes)
3576                            enable_Bsymbolic=yes,
3577                            AC_MSG_RESULT(no)
3578                            enable_Bsymbolic=no)
3579                LDFLAGS="${SAVED_LDFLAGS}"])
3580
3581 if test "x${enable_Bsymbolic}" = "xyes"; then
3582   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3583 fi
3584
3585 AC_SUBST(GLIB_LINK_FLAGS)
3586
3587 dnl
3588 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3589 dnl visibility attributes for symbol export control
3590 dnl
3591 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3592 case "$host" in
3593   *-*-mingw*)
3594     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3595     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3596               [defines how to decorate public symbols while building])
3597     CFLAGS="${CFLAGS} -fvisibility=hidden"
3598     ;;
3599   *)
3600     dnl on other compilers, check if we can do -fvisibility=hidden
3601     SAVED_CFLAGS="${CFLAGS}"
3602     CFLAGS="-fvisibility=hidden"
3603     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3604     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3605                    AC_MSG_RESULT(yes)
3606                    enable_fvisibility_hidden=yes,
3607                    AC_MSG_RESULT(no)
3608                    enable_fvisibility_hidden=no)
3609     CFLAGS="${SAVED_CFLAGS}"
3610
3611     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3612       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3613                 [defines how to decorate public symbols while building])
3614       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3615     ])
3616     ;;
3617 esac
3618 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3619
3620 dnl Compiler flags; macro originates from systemd
3621 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3622 AC_ARG_ENABLE(compile-warnings,
3623               [AS_HELP_STRING([--disable-compile-warnings],
3624                               [Don't use builtin compiler warnings])],,
3625                               enable_compile_warnings=yes)
3626 AS_IF([test "x$enable_compile_warnings" = xyes], [
3627   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3628    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3629    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3630    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3631    -Werror=format=2 -Werror=missing-include-dirs])
3632 ])
3633 AC_SUBST(GLIB_WARN_CFLAGS)
3634
3635 #
3636 # Define variables corresponding to the correct include paths to use for
3637 # in-tree building.
3638 #
3639
3640 # for config.h:
3641 config_h_INCLUDES='-I$(top_builddir)'
3642 AC_SUBST(config_h_INCLUDES)
3643
3644 # glib:
3645 #   config.h
3646 #   $(top_builddir)/glib: for glibconfig.h
3647 #   $(top_srcdir)/glib:   for glib.h
3648 #   $(top_srcdir):        for everything
3649 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3650 AC_SUBST(glib_INCLUDES)
3651
3652 # gobject:
3653 #   same as glib
3654 gobject_INCLUDES='$(glib_INCLUDES)'
3655 AC_SUBST(gobject_INCLUDES)
3656
3657 # gmodule:
3658 #   glib includes
3659 #   $(top_srcdir)/gmodule: for gmodule.h
3660 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3661 AC_SUBST(gmodule_INCLUDES)
3662
3663 # gio:
3664 #   same as gmodule
3665 gio_INCLUDES='$(gmodule_INCLUDES)'
3666 AC_SUBST(gio_INCLUDES)
3667
3668
3669 AC_CONFIG_FILES([
3670 glib-2.0.pc
3671 gmodule-2.0.pc
3672 gmodule-export-2.0.pc
3673 gmodule-no-export-2.0.pc
3674 gthread-2.0.pc
3675 gobject-2.0.pc
3676 gio-2.0.pc
3677 gio-unix-2.0.pc
3678 gio-windows-2.0.pc
3679 glib-zip
3680 glib-gettextize
3681 Makefile
3682 build/Makefile
3683 build/win32/Makefile
3684 build/win32/dirent/Makefile
3685 build/win32/vs9/Makefile
3686 build/win32/vs10/Makefile
3687 build/win32/vs11/Makefile
3688 glib/Makefile
3689 glib/glib.stp
3690 glib/libcharset/Makefile
3691 glib/gnulib/Makefile
3692 glib/pcre/Makefile
3693 glib/update-pcre/Makefile
3694 glib/tests/Makefile
3695 gmodule/Makefile
3696 gmodule/gmoduleconf.h
3697 gobject/Makefile
3698 gobject/gobject.stp
3699 gobject/glib-mkenums
3700 gobject/tests/Makefile
3701 gthread/Makefile
3702 gio/Makefile
3703 gio/gdbus-2.0/codegen/Makefile
3704 gio/gdbus-2.0/codegen/config.py
3705 gio/gnetworking.h
3706 gio/xdgmime/Makefile
3707 gio/inotify/Makefile
3708 gio/kqueue/Makefile
3709 gio/fen/Makefile
3710 gio/fam/Makefile
3711 gio/win32/Makefile
3712 gio/tests/Makefile
3713 gio/tests/gdbus-object-manager-example/Makefile
3714 gio/tests/services/Makefile
3715 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3716 po/Makefile.in
3717 docs/Makefile
3718 docs/reference/Makefile
3719 docs/reference/glib/Makefile
3720 docs/reference/glib/version.xml
3721 docs/reference/gobject/Makefile
3722 docs/reference/gobject/version.xml
3723 docs/reference/gio/Makefile
3724 docs/reference/gio/gdbus-object-manager-example/Makefile
3725 docs/reference/gio/version.xml
3726 tests/Makefile
3727 tests/gobject/Makefile
3728 tests/refcount/Makefile
3729 m4macros/Makefile
3730 ])
3731
3732 AC_CONFIG_COMMANDS([chmod-scripts],
3733 [chmod 0755 glib-zip
3734 chmod 0755 glib-gettextize
3735 chmod 0755 gobject/glib-mkenums])
3736
3737 # we want to invoke this macro solely so that the config.status script
3738 # and automake generated makefiles know about these generated files.
3739 # They are only needed to distcheck the package
3740 if false; then
3741   AC_CONFIG_FILES([
3742     INSTALL
3743     README
3744     config.h.win32
3745     glib/glibconfig.h.win32
3746     glib/makefile.msc
3747     glib/glib.rc
3748     gmodule/makefile.msc
3749     gmodule/gmodule.rc
3750     gobject/makefile.msc
3751     gobject/gobject.rc
3752     gthread/makefile.msc
3753     gthread/gthread.rc
3754     gio/gio.rc
3755     tests/makefile.msc
3756   ])
3757 fi
3758
3759 AC_OUTPUT