configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl ------------------------------------------------
   4 dnl Initialization and Versioning
   5 dnl ------------------------------------------------
   6
   7
   8 AC_INIT([libvorbis],[1.2.1svn],[vorbis-dev@xiph.org])
   9
  10 AC_CONFIG_SRCDIR([lib/mdct.c])
  11
  12 AC_CANONICAL_TARGET([])
  13
  14 AM_INIT_AUTOMAKE($PACKAGE_NAME,$PACKAGE_VERSION)
  15 AM_CONFIG_HEADER([config.h])
  16
  17 dnl Add parameters for aclocal
  18 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4")
  19
  20 dnl Library versioning
  21 dnl - library source changed -> increment REVISION
  22 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  23 dnl - interfaces added -> increment AGE
  24 dnl - interfaces removed -> AGE = 0
  25
  26 V_LIB_CURRENT=4
  27 V_LIB_REVISION=1
  28 V_LIB_AGE=4
  29 VF_LIB_CURRENT=6
  30 VF_LIB_REVISION=0
  31 VF_LIB_AGE=3
  32 VE_LIB_CURRENT=2
  33 VE_LIB_REVISION=4
  34 VE_LIB_AGE=0
  35 AC_SUBST(V_LIB_CURRENT)
  36 AC_SUBST(V_LIB_REVISION)
  37 AC_SUBST(V_LIB_AGE)
  38 AC_SUBST(VF_LIB_CURRENT)
  39 AC_SUBST(VF_LIB_REVISION)
  40 AC_SUBST(VF_LIB_AGE)
  41 AC_SUBST(VE_LIB_CURRENT)
  42 AC_SUBST(VE_LIB_REVISION)
  43 AC_SUBST(VE_LIB_AGE)
  44
  45 dnl --------------------------------------------------
  46 dnl Check for programs
  47 dnl --------------------------------------------------
  48
  49 dnl save $CFLAGS since AC_PROG_CC likes to insert "-g -O2"
  50 dnl if $CFLAGS is blank
  51 cflags_save="$CFLAGS"
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 CFLAGS="$cflags_save"
  55
  56 AC_C_INLINE
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AC_PROG_LIBTOOL
  60 AM_PROG_CC_C_O
  61
  62 dnl docbook xml transform and processing tools
  63 AC_ARG_ENABLE(docs,
  64   [  --enable-docs           build the documentation],
  65   [case "${enableval}" in
  66     yes) build_docs=true;;
  67     no)  build_docs=false;;
  68     *)   AC_MSG_ERROR(unknown value ${enableval} for --enable-docs);;
  69   esac],[build_docs=false])
  70
  71 dnl ideally we'd look for other tools and support them
  72 if test x$build_docs = xtrue; then
  73   AC_CHECK_PROGS([XSLTPROC], xsltproc, [/bin/false])
  74   AC_CHECK_PROGS([PDFXMLTEX], pdfxmltex, [/bin/false])
  75   if test "x$XSLTPROC" = "x/bin/false" || test "x$PDFXMLTEX" = "x/bin/false"; then
  76     build_docs=false
  77     AC_MSG_WARN([Documentation will not be built!])
  78   fi
  79 fi
  80
  81 AM_CONDITIONAL(BUILD_DOCS, [test x$build_docs = xtrue])
  82
  83 dnl --------------------------------------------------
  84 dnl Set build flags based on environment
  85 dnl --------------------------------------------------
  86
  87 dnl Set some target options
  88
  89 cflags_save="$CFLAGS"
  90 if test -z "$GCC"; then
  91         case $host in
  92         *-*-irix*)
  93                 dnl If we're on IRIX, we wanna use cc even if gcc
  94                 dnl is there (unless the user has overriden us)...
  95                 if test -z "$CC"; then
  96                         CC=cc
  97                 fi
  98                 DEBUG="-g -signed"
  99                 CFLAGS="-O2 -w -signed"
 100                 PROFILE="-p -g3 -O2 -signed" ;;
 101         sparc-sun-solaris*)
 102                 DEBUG="-v -g"
 103                 CFLAGS="-xO4 -fast -w -fsimple -native -xcg92"
 104                 PROFILE="-v -xpg -g -xO4 -fast -native -fsimple -xcg92 -Dsuncc" ;;
 105         *)
 106                 DEBUG="-g"
 107                 CFLAGS="-O"
 108                 PROFILE="-g -p" ;;
 109         esac
 110 else
 111
 112         AC_MSG_CHECKING([GCC version])
 113         GCC_VERSION=`$CC -dumpversion`
 114         AC_MSG_RESULT([$GCC_VERSION])
 115         case $host in
 116         *86-*-linux*)
 117                 DEBUG="-g -Wall -Wextra -D_REENTRANT -D__NO_MATH_INLINES -fsigned-char"
 118                 CFLAGS="-O20 -ffast-math -mno-ieee-fp -D_REENTRANT -fsigned-char"
 119 #               PROFILE="-Wall -Wextra -pg -g -O20 -ffast-math -D_REENTRANT -fsigned-char -fno-inline -static"
 120                 PROFILE="-Wall -Wextra -pg -g -O20 -ffast-math -mno-ieee-fp -D_REENTRANT -fsigned-char -fno-inline"
 121
 122                 # glibc < 2.1.3 has a serious FP bug in the math inline header
 123                 # that will cripple Vorbis.  Look to see if the magic FP stack
 124                 # clobber is missing in the mathinline header, thus indicating
 125                 # the buggy version
 126
 127                 AC_EGREP_CPP(log10.*fldlg2.*fxch,[
 128                                 #define __LIBC_INTERNAL_MATH_INLINES 1
 129                                 #define __OPTIMIZE__
 130                                 #include <math.h>
 131                                 ],bad=maybe,bad=no)
 132                 if test ${bad} = "maybe" ;then
 133                       AC_EGREP_CPP(log10.*fldlg2.*fxch.*st\([[0123456789]]*\),
 134                                         [
 135                                         #define __LIBC_INTERNAL_MATH_INLINES 1
 136                                         #define __OPTIMIZE__
 137                                         #include <math.h>
 138                                         ],bad=no,bad=yes)
 139                 fi
 140                 if test ${bad} = "yes" ;then
 141  AC_MSG_WARN([                                                        ])
 142  AC_MSG_WARN([********************************************************])
 143  AC_MSG_WARN([* The glibc headers on this machine have a serious bug *])
 144  AC_MSG_WARN([* in /usr/include/bits/mathinline.h  This bug affects  *])
 145  AC_MSG_WARN([* all floating point code, not just Ogg, built on this *])
 146  AC_MSG_WARN([* machine.  Upgrading to glibc 2.1.3 is strongly urged *])
 147  AC_MSG_WARN([* to correct the problem.  Note that upgrading glibc   *])
 148  AC_MSG_WARN([* will not fix any previously built programs; this is  *])
 149  AC_MSG_WARN([* a compile-time time bug.                             *])
 150  AC_MSG_WARN([* To work around the problem for this build of Ogg,    *])
 151  AC_MSG_WARN([* autoconf is disabling all math inlining.  This will  *])
 152  AC_MSG_WARN([* hurt Ogg performace but is necessary for an Ogg that *])
 153  AC_MSG_WARN([* will actually work.  Once glibc is upgraded, rerun   *])
 154  AC_MSG_WARN([* configure and make to build with inlining.           *])
 155  AC_MSG_WARN([********************************************************])
 156  AC_MSG_WARN([                                                        ])
 157
 158                 CFLAGS=${OPT}" -D__NO_MATH_INLINES"
 159                 PROFILE=${PROFILE}" -D__NO_MATH_INLINES"
 160                 fi;;
 161         powerpc-*-linux*)
 162                 DEBUG="-g -Wall -Wextra -D_REENTRANT -D__NO_MATH_INLINES"
 163                 CFLAGS="-O3 -Wall -Wextra -ffast-math -mfused-madd -mcpu=750 -D_REENTRANT"
 164                 PROFILE="-pg -g -O3 -ffast-math -mfused-madd -mcpu=750 -D_REENTRANT";;
 165         *-*-linux*)
 166                 DEBUG="-g -Wall -Wextra -D_REENTRANT -D__NO_MATH_INLINES -fsigned-char"
 167                 CFLAGS="-O20 -Wall -Wextra -ffast-math -D_REENTRANT -fsigned-char"
 168                 PROFILE="-pg -g -O20 -ffast-math -D_REENTRANT -fsigned-char";;
 169         sparc-sun-*)
 170                 DEBUG="-g -Wall -Wextra -D__NO_MATH_INLINES -fsigned-char -mv8"
 171                 CFLAGS="-O20 -Wall -Wextra -ffast-math -D__NO_MATH_INLINES -fsigned-char -mv8"
 172                 PROFILE="-pg -g -O20 -D__NO_MATH_INLINES -fsigned-char -mv8" ;;
 173         *-*-darwin*)
 174                 DEBUG="-DDARWIN -fno-common -force_cpusubtype_ALL -Wall -g -O0 -fsigned-char"
 175                 CFLAGS="-DDARWIN -fno-common -force_cpusubtype_ALL -Wall -g -O4 -ffast-math -fsigned-char"
 176                 PROFILE="-DDARWIN -fno-common -force_cpusubtype_ALL -Wall -g -pg -O4 -ffast-math -fsigned-char";;
 177         *-*-os2*)
 178                 # Use -W instead of -Wextra because gcc on OS/2 is an old version.
 179                 DEBUG="-g -Wall -W -D_REENTRANT -D__NO_MATH_INLINES -fsigned-char"
 180                 CFLAGS="-O20 -Wall -W -ffast-math -D_REENTRANT -fsigned-char"
 181                 PROFILE="-pg -g -O20 -ffast-math -D_REENTRANT -fsigned-char";;
 182         *)
 183                 DEBUG="-g -Wall -Wextra -D__NO_MATH_INLINES -fsigned-char"
 184                 CFLAGS="-O20 -Wall -Wextra -D__NO_MATH_INLINES -fsigned-char"
 185                 PROFILE="-O20 -g -pg -D__NO_MATH_INLINES -fsigned-char" ;;
 186         esac
 187
 188         AC_ADD_CFLAGS([-Wdeclaration-after-statement])
 189 fi
 190 CFLAGS="$CFLAGS $cflags_save"
 191
 192 dnl --------------------------------------------------
 193 dnl Check for headers
 194 dnl --------------------------------------------------
 195
 196 AC_CHECK_HEADER(memory.h,CFLAGS="$CFLAGS -DUSE_MEMORY_H",:)
 197
 198 dnl --------------------------------------------------
 199 dnl Check for typedefs, structures, etc
 200 dnl --------------------------------------------------
 201
 202 dnl none
 203
 204 dnl --------------------------------------------------
 205 dnl Check for libraries
 206 dnl --------------------------------------------------
 207
 208 AC_CHECK_LIB(m, cos, VORBIS_LIBS="-lm", VORBIS_LIBS="")
 209 AC_CHECK_LIB(pthread, pthread_create, pthread_lib="-lpthread", :)
 210
 211 HAVE_OGG=no
 212 PKG_CHECK_MODULES(OGG, ogg >= 1.0, HAVE_OGG=yes, HAVE_OGG=no)
 213 if test "x$HAVE_OGG" = "xno"
 214 then
 215   dnl fall back to the old school test
 216   XIPH_PATH_OGG(, AC_MSG_ERROR(must have Ogg installed!))
 217   libs_save=$LIBS
 218   LIBS="$OGG_LIBS $VORBIS_LIBS"
 219   AC_CHECK_FUNC(oggpack_writealign, , AC_MSG_ERROR(Ogg >= 1.0 required !))
 220   LIBS=$libs_save
 221 fi
 222
 223 dnl --------------------------------------------------
 224 dnl Check for library functions
 225 dnl --------------------------------------------------
 226
 227 AC_FUNC_ALLOCA
 228 AC_FUNC_MEMCMP
 229
 230 dnl --------------------------------------------------
 231 dnl Do substitutions
 232 dnl --------------------------------------------------
 233
 234 AC_SUBST(VORBIS_LIBS)
 235 AC_SUBST(DEBUG)
 236 AC_SUBST(PROFILE)
 237 AC_SUBST(pthread_lib)
 238
 239 dnl The following line causes the libtool distributed with the source
 240 dnl to be replaced if the build system has a more recent version.
 241 AC_SUBST(LIBTOOL_DEPS)
 242
 243 AC_OUTPUT([
 244 Makefile
 245 m4/Makefile
 246 lib/Makefile
 247 lib/modes/Makefile
 248 lib/books/Makefile
 249 lib/books/coupled/Makefile
 250 lib/books/uncoupled/Makefile
 251 lib/books/floor/Makefile
 252 doc/Makefile doc/vorbisfile/Makefile doc/vorbisenc/Makefile
 253 include/Makefile include/vorbis/Makefile
 254 examples/Makefile
 255 test/Makefile
 256 vq/Makefile
 257 libvorbis.spec
 258 vorbis.pc
 259 vorbisenc.pc
 260 vorbisfile.pc
 261 vorbis-uninstalled.pc
 262 vorbisenc-uninstalled.pc
 263 vorbisfile-uninstalled.pc
 264 ])