configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/rygel/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 dnl Required versions of library packages
  31 VALA_REQUIRED=0.11.6
  32 GSSDP_MAX_VERSION=0.10.9999
  33 GSSDP_REQUIRED=0.9.2
  34 GUPNP_MAX_VERSION=0.16.9999
  35 GUPNP_REQUIRED=0.13.4
  36 GUPNP_AV_MAX_VERSION=0.8.9999
  37 GUPNP_AV_REQUIRED=0.7.0
  38 GUPNP_DLNA_MAX_VERSION=0.6.9999
  39 GUPNP_DLNA_REQUIRED=0.5.0
  40 GUPNP_VALA_REQUIRED=0.7.5
  41 GSTREAMER_REQUIRED=0.10.23
  42 GIO_REQUIRED=2.26
  43 GEE_MAX_VERSION=0.6.9999
  44 GEE_REQUIRED=0.5.2
  45 UUID_REQUIRED=1.41.3
  46 LIBSOUP_MAX_VERSION=2.34.9999
  47 LIBSOUP_REQUIRED=2.26.0
  48 GTK_REQUIRED=2.90.3
  49
  50 dnl Additional requirements for media-export plugin
  51 GSTREAMER_TAG_REQUIRED=0.10.28
  52 GSTREAMER_APP_REQUIRED=0.10.28
  53 LIBSQLITE3_REQUIRED=3.5
  54
  55 PKG_CHECK_MODULES(LIBGSSDP, gssdp-1.0 >= $GSSDP_REQUIRED
  56                             gssdp-1.0 <= $GSSDP_MAX_VERSION)
  57 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED
  58                             gupnp-1.0 <= $GUPNP_MAX_VERSION)
  59 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED
  60                                gupnp-av-1.0 <= $GUPNP_AV_MAX_VERSION)
  61 PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.0 >= $GUPNP_DLNA_REQUIRED
  62                                  gupnp-dlna-1.0 <= $GUPNP_DLNA_MAX_VERSION)
  63 PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED)
  64 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  65 PKG_CHECK_MODULES(GEE, gee-1.0 >= $GEE_REQUIRED)
  66 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  67 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED
  68                            libsoup-2.4 <= $LIBSOUP_MAX_VERSION)
  69
  70 dnl glib-genmarshal
  71 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
  72 AC_SUBST(GLIB_GENMARSHAL)
  73
  74 AC_ARG_ENABLE(sql-debugging,
  75     AS_HELP_STRING([--enable-sql-debugging],[enable SQL statement debugging]),,
  76         enable_sql_debugging=no)
  77 AS_IF([test x$enable_sql_debugging = xyes],
  78       [RYGEL_ADD_VALAFLAGS([-D RYGEL_DEBUG_SQL])])
  79
  80 dnl Add plugins
  81 RYGEL_ADD_PLUGIN([test],[Test],[no])
  82 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
  83 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
  84 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
  85 RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
  86 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
  87 RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
  88 RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
  89
  90 dnl Explicitly add stamp files for targets that are not plugins
  91 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
  92 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
  93
  94 RYGEL_CHECK_VALA([$VALA_REQUIRED],
  95                  [gupnp-1.0
  96                   gupnp-av-1.0
  97                   gupnp-dlna-1.0
  98                   gstreamer-0.10
  99                   gstreamer-pbutils-0.10
 100                   gio-2.0
 101                   gee-1.0
 102                   posix])
 103
 104 dnl Debugging
 105 AC_ARG_ENABLE(debug,
 106         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 107         enable_debug=no)
 108 if test "x$enable_debug" = "xyes"; then
 109         CFLAGS="$CFLAGS -O0 -g"
 110 fi
 111
 112 dnl Strict compiler
 113 AC_ARG_ENABLE(strict-cc,
 114         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 115         enable_strict_cc=no)
 116 if test "x$enable_strict_cc" = "xyes"; then
 117         CFLAGS="$CFLAGS -Wall -Werror"
 118 else
 119         CFLAGS="$CFLAGS -w"
 120 fi
 121
 122 dnl Run uninstalled
 123 AC_ARG_ENABLE(uninstalled,
 124     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 125         enable_uninstalled=no)
 126 if test "x$enable_uninstalled" = "xyes"; then
 127         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 128 fi
 129 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 130
 131 dnl Check wether user wants to build UIs
 132 AC_ARG_WITH( ui,
 133   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 134   try_ui=$withval, try_ui=yes )
 135
 136 HAVE_GTK=no
 137 if test x$try_ui = xyes ; then
 138     dnl check for gtk
 139     PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQUIRED,
 140       [
 141         if test x$enable_vala = xyes ; then
 142                 VALA_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 143         else
 144                 HAVE_GTK=yes
 145         fi
 146       ],
 147       [
 148         HAVE_GTK=no
 149         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 150         AC_MSG_WARN([UI applications will not be built.])
 151       ])
 152 else
 153     AC_MSG_NOTICE([UI applications disabled.])
 154 fi
 155
 156 if test x$HAVE_GTK = xno; then
 157   BUILD_UI=no
 158 else
 159   BUILD_UI=yes
 160   AC_DEFINE(HAVE_GTK, , [Build UI applications])
 161 fi
 162
 163 AC_SUBST(HAVE_GTK)
 164 AM_CONDITIONAL(BUILD_UI, test x$BUILD_UI = xyes)
 165
 166 dnl Check additional requirements for MediaExport plugins
 167 if test "x$enable_media_export_plugin" = "xyes";
 168 then
 169     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 170     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-0.10 >= $GSTREAMER_TAG_REQUIRED);
 171     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-0.10 >= $GSTREAMER_APP_REQUIRED);
 172     if test x$enable_vala = xyes ; then
 173         VALA_CHECK_PACKAGES([sqlite3
 174                              gstreamer-tag-0.10
 175                              gstreamer-app-0.10])
 176     fi
 177 fi
 178
 179 dnl Gettext
 180 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 181 AC_SUBST(GETTEXT_PACKAGE)
 182 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 183   [Define the gettext package to be used])
 184
 185 AM_GLIB_GNU_GETTEXT
 186 IT_PROG_INTLTOOL([0.40.0])
 187
 188 dnl Shave the output
 189 AM_SILENT_RULES([yes])
 190
 191 dnl documenation
 192 AC_PATH_PROG([XSLTPROC], [xsltproc])
 193 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 194
 195
 196 AC_CONFIG_FILES([
 197 Makefile
 198 src/Makefile
 199 src/rygel/Makefile
 200 src/ui/Makefile
 201 src/plugins/Makefile
 202 data/Makefile
 203 data/xml/Makefile
 204 data/icons/Makefile
 205 data/icons/32x32/Makefile
 206 data/icons/48x48/Makefile
 207 data/icons/120x120/Makefile
 208 data/icons/scalable/Makefile
 209 data/rygel.desktop.in
 210 data/rygel-preferences.desktop.in
 211 doc/Makefile
 212 po/Makefile.in
 213 rygel-1.0.pc
 214 tests/Makefile
 215 ])
 216 AC_OUTPUT
 217
 218 echo "
 219
 220                     ${PACKAGE} ${VERSION}
 221                     ============
 222
 223
 224         Prefix:                 ${prefix}
 225         Source code location:   ${srcdir}
 226         Compiler:               ${CC}
 227         CFLAGS:                 ${CFLAGS}
 228         VALAFLAGS:              ${VALAFLAGS}
 229         uninstalled:            ${enable_uninstalled}
 230         preferences ui:         ${BUILD_UI}
 231         SQL debugging:          ${enable_sql_debugging}
 232     Plugins:
 233         test:                   ${enable_test_plugin}
 234         tracker:                ${enable_tracker_plugin}
 235         mediathek:              ${enable_mediathek_plugin}
 236         media-export            ${enable_media_export_plugin}
 237         external:               ${enable_external_plugin}
 238         MPRIS2:                 ${enable_mpris_plugin}
 239         gst-launch:             ${enable_gst_launch_plugin}
 240         playbin:                ${enable_playbin_plugin}
 241 "