configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 2, 0, 2)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.1.0
  50 GSTPB_REQ=1.1.0
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 AC_CHECK_FUNCS(clock_gettime, [], [
 138   AC_CHECK_LIB(rt, clock_gettime, [
 139     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 140     LIBRT="-lrt"
 141     AC_SUBST([LIBRT])
 142   ])
 143 ])
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/socket.h])
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration.  This check is needed
 162 dnl for the UDP plugin to build on Solaris
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl check if we have GCC inline-asm
 170 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 171 if test x$HAVE_GCC_ASM = xyes ; then
 172   AC_DEFINE(HAVE_GCC_ASM, 1,
 173     [Define if compiler supports gcc inline assembly])
 174 fi
 175 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 176
 177 dnl *** checks for library functions ***
 178
 179 LIBS_SAVE=$LIBS
 180 LIBS="$LIBS $LIBM"
 181 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 182 LIBS=$LIBS_SAVE
 183
 184 dnl Check whether isinf() is defined by math.h
 185 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 187 if test "$ac_cv_have_isinf" = "yes"
 188 then
 189     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 190 fi
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193 AC_FUNC_MMAP
 194 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 195
 196 dnl Check for mmap (needed by electricfence plugin)
 197
 198 AC_CHECK_TYPE([struct ip_mreqn], [
 199               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 200               [#include <netinet/in.h>])
 201
 202 dnl *** checks for dependency libraries ***
 203
 204
 205 dnl GLib
 206 GLIB_REQ=2.32.0
 207 AG_GST_GLIB_CHECK([$GLIB_REQ])
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.17])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK_REQ=3.0.0
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 245   dnl some examples need gtk+-x11
 246   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 252
 253 dnl *** set variables based on configure arguments ***
 254
 255 dnl set license and copyright notice
 256 GST_LICENSE="LGPL"
 257 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 258 AC_SUBST(GST_LICENSE)
 259
 260 dnl set location of plugin directory
 261 AG_GST_SET_PLUGINDIR
 262
 263 dnl set release date/time
 264 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 265   ["${srcdir}/gst-plugins-good.doap"],
 266   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 267
 268 dnl build static plugins or not
 269 AC_MSG_CHECKING([whether to build static plugins or not])
 270 AC_ARG_ENABLE(
 271   static-plugins,
 272   AC_HELP_STRING(
 273     [--enable-static-plugins],
 274     [build static plugins @<:@default=no@:>@]),
 275   [AS_CASE(
 276     [$enableval], [no], [], [yes], [],
 277     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 278   [enable_static_plugins=no])
 279 AC_MSG_RESULT([$enable_static_plugins])
 280 if test "x$enable_static_plugins" = xyes; then
 281   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 282     [Define if static plugins should be built])
 283   GST_PLUGIN_LIBTOOLFLAGS=""
 284 else
 285   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 286 fi
 287 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 288 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 289
 290 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 291 dnl make sure it doesn't complain about unused variables if debugging is disabled
 292 NO_WARNINGS=""
 293 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 294
 295 dnl define an ERROR_CFLAGS Makefile variable
 296 dnl -Wundef: too many broken headers
 297 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 298       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 299       -Wwrite-strings -Wold-style-definition -Waggregate-return
 300       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 301       -Wnested-externs $NO_WARNINGS])
 302
 303 dnl define an ERROR_CXXFLAGS Makefile variable
 304 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 305         -Wmissing-declarations -Wredundant-decls
 306         -Wwrite-strings
 307         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 308         $NO_WARNINGS])
 309
 310 dnl define an ERROR_OBJCFLAGS Makefile variable
 311 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 312       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 313       -Wwrite-strings -Wold-style-definition
 314       -Winit-self -Wmissing-include-dirs -Wno-multichar
 315       -Wnested-externs $NO_WARNINGS])
 316
 317 dnl define correct level for debugging messages
 318 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 319
 320 dnl used in examples
 321 AG_GST_DEFAULT_ELEMENTS
 322
 323 dnl *** plug-ins to include ***
 324
 325 dnl Non ported plugins (non-dependant, then dependant)
 326 dnl Make sure you have a space before and after all plugins
 327 GST_PLUGINS_NONPORTED="osx_audio "
 328 AC_SUBST(GST_PLUGINS_NONPORTED)
 329
 330 dnl these are all the gst plug-ins, compilable without additional libs
 331 dnl videofilter is at the top because others depend on it
 332 AG_GST_CHECK_PLUGIN(alpha)
 333 AG_GST_CHECK_PLUGIN(apetag)
 334 AG_GST_CHECK_PLUGIN(audiofx)
 335 AG_GST_CHECK_PLUGIN(audioparsers)
 336 AG_GST_CHECK_PLUGIN(auparse)
 337 AG_GST_CHECK_PLUGIN(autodetect)
 338 AG_GST_CHECK_PLUGIN(avi)
 339 AG_GST_CHECK_PLUGIN(cutter)
 340 AG_GST_CHECK_PLUGIN(debugutils)
 341 AG_GST_CHECK_PLUGIN(deinterlace)
 342 AG_GST_CHECK_PLUGIN(dtmf)
 343 AG_GST_CHECK_PLUGIN(effectv)
 344 AG_GST_CHECK_PLUGIN(equalizer)
 345 AG_GST_CHECK_PLUGIN(flv)
 346 AG_GST_CHECK_PLUGIN(flx)
 347 AG_GST_CHECK_PLUGIN(goom)
 348 AG_GST_CHECK_PLUGIN(goom2k1)
 349 AG_GST_CHECK_PLUGIN(icydemux)
 350 AG_GST_CHECK_PLUGIN(id3demux)
 351 AG_GST_CHECK_PLUGIN(imagefreeze)
 352 AG_GST_CHECK_PLUGIN(interleave)
 353 AG_GST_CHECK_PLUGIN(isomp4)
 354 AG_GST_CHECK_PLUGIN(law)
 355 AG_GST_CHECK_PLUGIN(level)
 356 AG_GST_CHECK_PLUGIN(matroska)
 357 AG_GST_CHECK_PLUGIN(monoscope)
 358 AG_GST_CHECK_PLUGIN(multifile)
 359 AG_GST_CHECK_PLUGIN(multipart)
 360 AG_GST_CHECK_PLUGIN(replaygain)
 361 AG_GST_CHECK_PLUGIN(rtp)
 362 AG_GST_CHECK_PLUGIN(rtpmanager)
 363 AG_GST_CHECK_PLUGIN(rtsp)
 364 AG_GST_CHECK_PLUGIN(shapewipe)
 365 AG_GST_CHECK_PLUGIN(smpte)
 366 AG_GST_CHECK_PLUGIN(spectrum)
 367 AG_GST_CHECK_PLUGIN(udp)
 368 AG_GST_CHECK_PLUGIN(videobox)
 369 AG_GST_CHECK_PLUGIN(videocrop)
 370 AG_GST_CHECK_PLUGIN(videofilter)
 371 AG_GST_CHECK_PLUGIN(videomixer)
 372 AG_GST_CHECK_PLUGIN(wavenc)
 373 AG_GST_CHECK_PLUGIN(wavparse)
 374 AG_GST_CHECK_PLUGIN(y4m)
 375
 376 dnl disable experimental plug-ins
 377 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 378   AG_GST_DISABLE_PLUGIN(monoscope)
 379 fi
 380
 381 dnl *** sys plug-ins ***
 382
 383 echo
 384 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 385 echo
 386
 387 dnl DirectSound
 388 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 389 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 390   HAVE_DIRECTSOUND="no"
 391   save_CFLAGS="$CFLAGS"
 392   save_LDFLAGS="$LDFLAGS"
 393   save_LIBS="$LIBS"
 394   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 395   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 396   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 397   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 398   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 399 #include <windows.h>
 400 #include <dxerr9.h>
 401 #include <dsound.h>
 402 ]], [[
 403   DXGetErrorString9 (0);
 404   DirectSoundCreate(NULL, NULL, NULL);
 405 ]])
 406 ],
 407     [HAVE_DIRECTSOUND="yes"],
 408     [HAVE_DIRECTSOUND="no"])
 409   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 410   CFLAGS=$save_CFLAGS
 411   LDFLAGS=$save_LDFLAGS
 412   LIBS=$save_LIBS
 413
 414   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 415     dnl this is much more than we want
 416     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 417     AC_SUBST(DIRECTSOUND_CFLAGS)
 418     AC_SUBST(DIRECTSOUND_LDFLAGS)
 419     AC_SUBST(DIRECTSOUND_LIBS)
 420   fi
 421   AC_SUBST(HAVE_DIRECTSOUND)
 422 ])
 423
 424 dnl *** Win32 WaveOut ***
 425 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 426 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 427   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 428 ])
 429
 430 dnl *** OSS audio *** (Linux, *BSD)
 431 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 432 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 433  HAVE_OSS="yes"
 434 dnl Linux and newer BSD versions :
 435  AC_CHECK_HEADER(sys/soundcard.h, [
 436    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 437    ] , [
 438 dnl Some old BSD versions and also newer OpenBSD versions :
 439    AC_CHECK_HEADER(soundcard.h, [
 440      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 441      ], [
 442   dnl Some old BSD versions :
 443      AC_CHECK_HEADER(machine/soundcard.h, [
 444        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 445          [Define if OSS includes are in /machine/])
 446        ], [
 447        HAVE_OSS="no"
 448      ])
 449    ])
 450  ])
 451 ])
 452
 453 dnl *** oss4 ***
 454 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 455 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 456   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 457   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 458       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 459       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 460 ])
 461
 462 dnl *** Sun Audio ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 464 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 465   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 466 ])
 467
 468 dnl *** OSX Audio ***
 469 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 470 have_ios="no"
 471 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 472   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 473     HAVE_OSX_AUDIO="yes",
 474     dnl *** Check for the iOS headers ***
 475     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 476       [HAVE_OSX_AUDIO="YES";have_ios="yes"], HAVE_OSX_AUDIO="no"
 477     )])
 478 ])
 479 if test "x$have_ios" = "xyes"; then
 480   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 481 fi
 482 AM_CONDITIONAL(HAVE_IOS, test "x$have_ios" = "xyes")
 483
 484 dnl *** OS X video ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 486 HAVE_OSX_VIDEO="no"
 487 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 488   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 489 ])
 490 dnl in case header OpenGL/gl.h is found on other platforms
 491 case "$host" in
 492   *-*darwin*)
 493     dnl do nothing
 494     ;;
 495   *)
 496     HAVE_OSX_VIDEO="no"
 497     ;;
 498 esac
 499
 500
 501 dnl *** Video 4 Linux 2 ***
 502 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 503 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 504 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 505 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 506   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 507   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 508 #include <sys/types.h>
 509 #ifdef __sun /* Solaris */
 510 #include <sys/types.h>
 511 #include <sys/videodev2.h>
 512 #elif __FreeBSD__
 513 #include <linux/videodev2.h>
 514 #else /* Linux */
 515 #include <linux/types.h>
 516 #define _LINUX_TIME_H
 517 #define __user
 518 #include <linux/videodev2.h>
 519 #endif
 520 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 521 #error too early v4l2 version or no v4l2 at all
 522 #endif
 523     ]], [[
 524 return 0;
 525     ]])],[
 526       HAVE_GST_V4L2="yes"
 527       AC_MSG_RESULT(yes)
 528     ],[
 529       HAVE_GST_V4L2="no"
 530       AC_MSG_RESULT(no)
 531
 532       HAVE_VIDEODEV=no
 533       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 534       [
 535         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 536       ])
 537
 538       if test "x$HAVE_VIDEODEV" = "xyes"; then
 539         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 540         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 541       else
 542         AC_MSG_WARN([video4linux2 was not found])
 543       fi
 544     ])
 545
 546   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 547     dnl check for missing v4l2_buffer declaration (see #135919)
 548     MISSING_DECL=0
 549     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 550     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 551 #include <sys/types.h>
 552 #ifdef __sun /* Solaris */
 553 #include <sys/types.h>
 554 #include <sys/videodev2.h>
 555 #elif __FreeBSD__
 556 #include <linux/videodev2.h>
 557 #else /* Linux */
 558 #include <linux/types.h>
 559 #define _LINUX_TIME_H
 560 #define __user
 561 #include <linux/videodev2.h>
 562 #endif
 563     ]], [[
 564 struct v4l2_buffer buf;
 565 buf.index = 0;
 566 return 0;
 567     ]])],[ AC_MSG_RESULT(yes) ],[ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 568     if [ test x$MISSING_DECL = x1 ]; then
 569       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 570     fi
 571
 572     dnl check for XOverlay libraries
 573     AG_GST_CHECK_XV
 574   fi
 575 ])
 576
 577 # Optional gudev for device probing
 578 AC_ARG_WITH([gudev],
 579   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 580   [],
 581   [with_gudev=check])
 582 if test x$HAVE_GST_V4L2 = xyes; then
 583   if test x$with_gudev != xno; then
 584       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 585           [ have_gudev=yes
 586             AC_DEFINE(HAVE_GUDEV, 1,
 587                [Whether gudev is available for device detection])
 588             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 589           ], [
 590           have_gudev=no
 591           ])
 592   else
 593     have_gudev=no
 594   fi
 595 fi
 596 AC_SUBST(GUDEV_CFLAGS)
 597 AC_SUBST(GUDEV_LIBS)
 598
 599 # Make libv4l2 non-automagic
 600 AC_ARG_WITH([libv4l2],
 601   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 602   [],
 603   [with_libv4l2=check])
 604 if test x$HAVE_GST_V4L2 = xyes; then
 605   if test x$with_libv4l2 != xno; then
 606       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 607           [ have_libv4l2=yes
 608             AC_DEFINE(HAVE_LIBV4L2, 1,
 609                 [Whether libv4l2 is available for video buffer conversion])
 610           ], [
 611           have_libv4l2=no
 612           ])
 613   else
 614     have_libv4l2=no
 615   fi
 616 fi
 617
 618 # Check if v4l2 support dmabuf
 619 if test x$HAVE_GST_V4L2 = xyes; then
 620         AC_CHECK_DECLS(V4L2_MEMORY_DMABUF,,,[
 621                                         #include <sys/types.h>
 622                                         #ifdef __sun /* Solaris */
 623                                         #include <sys/types.h>
 624                                         #include <sys/videodev2.h>
 625                                         #elif __FreeBSD__
 626                                         #include <linux/videodev2.h>
 627                                         #else /* Linux */
 628                                         #include <linux/types.h>
 629                                         #define _LINUX_TIME_H
 630                                         #define __user
 631                                         #include <linux/videodev2.h>
 632                                         #endif
 633                                         ])
 634 fi
 635
 636 dnl Check for X11
 637 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 638 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 639                   [ximagesrc], [
 640   AC_PATH_XTRA
 641
 642   dnl now try to find the HEADER
 643   ac_cflags_save="$CFLAGS"
 644   ac_cppflags_save="$CPPFLAGS"
 645   CFLAGS="$CFLAGS $X_CFLAGS"
 646   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 647   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 648
 649   if test "x$HAVE_X" = "xno"
 650   then
 651     AC_MSG_NOTICE([cannot find X11 development files])
 652   else
 653     dnl this is much more than we want
 654     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 655     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 656     dnl it does not add the libs; therefore we add them here
 657     X_LIBS="$X_LIBS -lX11"
 658     AC_SUBST(X_CFLAGS)
 659     AC_SUBST(X_LIBS)
 660
 661     dnl check for Xfixes
 662     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 663     if test "x$HAVE_XFIXES" = "xyes"
 664     then
 665         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 666     fi
 667     AC_SUBST(XFIXES_LIBS)
 668     AC_SUBST(XFIXES_CFLAGS)
 669
 670     dnl check for Xdamage
 671     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 672     if test "x$HAVE_XDAMAGE" = "xyes"
 673     then
 674         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 675     fi
 676     AC_SUBST(XDAMAGE_LIBS)
 677     AC_SUBST(XDAMAGE_CFLAGS)
 678   fi
 679   AC_SUBST(HAVE_X)
 680   CFLAGS="$ac_cflags_save"
 681   CPPFLAGS="$ac_cppflags_save"
 682 ])
 683
 684 dnl FIXME: this should be rolled into the test above, it's just an additional
 685 dnl feature of the ximagesrc plug-in
 686 dnl This is the same as in gst-plugins-base
 687 dnl check for X Shm
 688 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 689 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 690   if test x$HAVE_X = xyes; then
 691     AC_CHECK_LIB(Xext, XShmAttach,
 692                  HAVE_XSHM="yes", HAVE_XSHM="no",
 693                  $X_LIBS)
 694     if test "x$HAVE_XSHM" = "xyes"; then
 695       XSHM_LIBS="-lXext"
 696     else
 697       dnl On AIX, it is in XextSam instead, but we still need -lXext
 698       AC_CHECK_LIB(XextSam, XShmAttach,
 699                    HAVE_XSHM="yes", HAVE_XSHM="no",
 700                    $X_LIBS)
 701       if test "x$HAVE_XSHM" = "xyes"; then
 702         XSHM_LIBS="-lXext -lXextSam"
 703       fi
 704     fi
 705   fi
 706 ], ,[
 707   AC_SUBST(HAVE_XSHM)
 708   AC_SUBST(XSHM_LIBS)
 709 ])
 710
 711 dnl for V4L2, we also need to know if we have XVIDEO
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 713 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 714                   [], [
 715   AG_GST_CHECK_XV
 716 ])
 717
 718 dnl *** ext plug-ins ***
 719 dnl keep this list sorted alphabetically !
 720
 721 if test "x$BUILD_EXTERNAL" = "xyes"; then
 722
 723 echo
 724 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 725 echo
 726
 727 dnl *** aalib ***
 728 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 729 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 730   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 731   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 732 ])
 733
 734 dnl *** cairo ***
 735 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 736 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 737   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 738 ])
 739
 740 dnl *** FLAC ***
 741 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 742 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 743   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 744 ])
 745
 746 dnl *** GDK pixbuf ***
 747 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 748 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 749   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 750 ])
 751
 752 dnl *** Jack ***
 753 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 754 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 755   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 756   AC_SUBST(JACK_CFLAGS)
 757   AC_SUBST(JACK_LIBS)
 758
 759   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 760   if test x$HAVE_JACK_0_120_1 = xyes; then
 761     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 762   fi
 763   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 764   if test x$HAVE_JACK_1_9_7 = xyes; then
 765     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 766   fi
 767
 768 ])
 769
 770 dnl *** jpeg ***
 771 dnl FIXME: we could use header checks here as well IMO
 772 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 773 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 774   AC_ARG_WITH(jpeg-mmx,
 775     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 776   OLD_LIBS="$LIBS"
 777   if test x$with_jpeg_mmx != x; then
 778     LIBS="$LIBS -L$with_jpeg_mmx"
 779   fi
 780   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 781   JPEG_LIBS="$LIBS -ljpeg-mmx"
 782   LIBS="$OLD_LIBS"
 783   if test x$HAVE_JPEG != xyes; then
 784     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 785     JPEG_LIBS="-ljpeg"
 786   fi
 787   AC_SUBST(JPEG_LIBS)
 788 ])
 789
 790 dnl *** libcaca ***
 791 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 792 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 793   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 794 ])
 795
 796 dnl *** libdv ***
 797 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 798 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 799   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 800 ])
 801
 802 dnl *** libpng ***
 803 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 804 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 805   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 806 ])
 807
 808 dnl *** pulseaudio ***
 809 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 810 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 811
 812   dnl used in ext/pulse/pulseutil.c
 813   AC_CHECK_HEADERS([process.h])
 814
 815   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 816 ])
 817
 818 dnl *** dv1394 ***
 819 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 820 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 821   dnl first test for libraw1394 >= 2.0.0
 822   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 823   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 824   dnl now see how far we got
 825   if test x$HAVE_RAW1394 = xyes && \
 826      test x$HAVE_LIBIEC61883 = xyes; then
 827        AG_GST_CHECK_LIBHEADER(AVC1394,
 828         avc1394, avc1394_send_command, $RAW1394_LIBS,
 829         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 830        AG_GST_CHECK_LIBHEADER(ROM1394,
 831         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 832         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 833        if test x$HAVE_AVC1394 = xyes && \
 834           test x$HAVE_AVC1394 = xyes && \
 835           test x$HAVE_ROM1394 = xyes; then
 836           HAVE_DV1394=yes
 837           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 838           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 839           AC_SUBST(DV1394_CFLAGS)
 840           AC_SUBST(DV1394_LIBS)
 841         fi
 842   else
 843        if test x$HAVE_RAW1394 = xno; then
 844           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 845           AG_GST_CHECK_LIBHEADER(AVC1394,
 846            avc1394, avc1394_send_command, $RAW1394_LIBS,
 847            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 848           AG_GST_CHECK_LIBHEADER(ROM1394,
 849            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 850            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 851           if test x$HAVE_RAW1394 = xyes && \
 852              test x$HAVE_AVC1394 = xyes && \
 853              test x$HAVE_ROM1394 = xyes; then
 854              HAVE_DV1394=yes
 855              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 856              DV1394_CFLAGS="$RAW1394_CFLAGS"
 857              if test x$HAVE_LIBIEC61883 = xyes; then
 858                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 859                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 860              fi
 861              AC_SUBST(DV1394_CFLAGS)
 862              AC_SUBST(DV1394_LIBS)
 863            fi
 864          fi
 865   fi
 866 ])
 867 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 868
 869 dnl *** shout2 ***
 870 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 871 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 872   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 873 ])
 874
 875 dnl *** soup ***
 876 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 877 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 878   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26.1, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 879   AC_SUBST(SOUP_CFLAGS)
 880   AC_SUBST(SOUP_LIBS)
 881 ])
 882
 883 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 884 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 885 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 886 dnl   speex_jitter.h is 1.1.x only
 887 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 888 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 889   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 890   if test $HAVE_SPEEX = no
 891   then
 892     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 893       AC_CHECK_HEADER(speex/speex_jitter.h, [
 894         dnl speex 1.1.x :
 895         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 896           dnl speex 1.1.5 or + :
 897           HAVE_SPEEX="yes"
 898           SPEEX_LIBS="-lspeex"
 899           AC_SUBST(SPEEX_CFLAGS)
 900           AC_SUBST(SPEEX_LIBS)
 901         ],[
 902           HAVE_SPEEX="no"
 903         ])
 904       ],[
 905         dnl speex 1.0.x :
 906           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 907             dnl speex 1.0.4
 908             HAVE_SPEEX="yes"
 909             SPEEX_LIBS="-lspeex"
 910             AC_SUBST(SPEEX_CFLAGS)
 911             AC_SUBST(SPEEX_LIBS)
 912
 913             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 914               [defined if speex 1.0.x API detected])
 915         ],[
 916             HAVE_SPEEX="no"
 917             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 918         ], [
 919 #include <speex/speex.h>
 920         ])
 921       ])
 922     ])
 923   fi
 924 ])
 925
 926 dnl *** taglib ***
 927 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 928 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 929   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 930   if test "x$HAVE_CXX" != "xyes"; then
 931     USE_TAGLIB=false
 932     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 933   else
 934     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 935     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 936         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 937       ], [
 938         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 939     ])
 940     AC_SUBST(TAGLIB_CXXFLAGS)
 941   fi
 942 ])
 943
 944 dnl *** vpx ***
 945 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 946 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 947   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 948
 949   if test $HAVE_VPX = "yes"; then
 950     OLD_LIBS="$LIBS"
 951     OLD_CFLAGS="$CFLAGS"
 952     CFLAGS="$CFLAGS $VPX_CFLAGS"
 953     LIBS="$LIBS $VPX_LIBS"
 954     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 955       HAVE_VP8=yes
 956       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 957     ])
 958     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 959       HAVE_VP8=yes
 960       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 961     ])
 962     LIBS="$OLD_LIBS"
 963     CFLAGS="$OLD_CFLAGS"
 964   fi
 965   AC_SUBST(VPX_LIBS)
 966   AC_SUBST(VPX_CFLAGS)
 967 ])
 968
 969 dnl *** wavpack ***
 970 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 971 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 972   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 973     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 974       HAVE_WAVPACK=yes
 975       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 976     ],[
 977       HAVE_WAVPACK=no
 978     ])
 979   ])
 980   AC_SUBST(WAVPACK_CFLAGS)
 981   AC_SUBST(WAVPACK_LIBS)
 982 ])
 983
 984 dnl *** qtdemux & matroska prefer to have zlib ***
 985 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 986 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 987   AG_GST_CHECK_LIBHEADER(ZLIB,
 988     z, uncompress,, zlib.h, [
 989     HAVE_ZLIB="yes"
 990     ZLIB_LIBS="-lz"
 991     AC_SUBST(ZLIB_LIBS)
 992   ])
 993 ])
 994
 995 dnl *** matroska prefers to have bz2 ***
 996 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 997 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 998   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 999   AC_SUBST(BZ2_LIBS)
1000 ])
1001
1002 else
1003
1004 dnl not building plugins with external dependencies,
1005 dnl but we still need to set the conditionals
1006 AM_CONDITIONAL(USE_AALIB, false)
1007 AM_CONDITIONAL(USE_BZ2, false)
1008 AM_CONDITIONAL(USE_CAIRO, false)
1009 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1010 AM_CONDITIONAL(USE_DV1394, false)
1011 AM_CONDITIONAL(USE_FLAC, false)
1012 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1013 AM_CONDITIONAL(USE_GST_V4L2, false)
1014 AM_CONDITIONAL(USE_JACK, false)
1015 AM_CONDITIONAL(USE_JPEG, false)
1016 AM_CONDITIONAL(USE_LIBCACA, false)
1017 AM_CONDITIONAL(USE_LIBDV, false)
1018 AM_CONDITIONAL(USE_LIBIEC61883, false)
1019 AM_CONDITIONAL(USE_LIBPNG, false)
1020 AM_CONDITIONAL(USE_OSS, false)
1021 AM_CONDITIONAL(USE_OSS4, false)
1022 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1023 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1024 AM_CONDITIONAL(USE_PULSE, false)
1025 AM_CONDITIONAL(USE_SHOUT2, false)
1026 AM_CONDITIONAL(USE_SOUP, false)
1027 AM_CONDITIONAL(USE_SPEEX, false)
1028 AM_CONDITIONAL(USE_SUNAUDIO, false)
1029 AM_CONDITIONAL(USE_TAGLIB, false)
1030 AM_CONDITIONAL(USE_VPX, false)
1031 AM_CONDITIONAL(USE_WAVEFORM, false)
1032 AM_CONDITIONAL(USE_WAVPACK, false)
1033 AM_CONDITIONAL(USE_X, false)
1034 AM_CONDITIONAL(USE_XSHM, false)
1035 AM_CONDITIONAL(USE_XVIDEO, false)
1036 AM_CONDITIONAL(USE_ZLIB, false)
1037
1038 fi dnl of EXT plugins
1039
1040 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1041
1042 dnl Overview:
1043 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1044 dnl GST_*:              flags shared by all built objects
1045 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1046 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1047 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1048 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1049
1050 dnl GST_OPTION_CFLAGS
1051 if test "x$USE_DEBUG" = xyes; then
1052    PROFILE_CFLAGS="-g"
1053 fi
1054 AC_SUBST(PROFILE_CFLAGS)
1055
1056 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1057   dnl Define _only_ for git (not pre-releases or releases)
1058   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1059 else
1060   DEPRECATED_CFLAGS=""
1061 fi
1062 AC_SUBST(DEPRECATED_CFLAGS)
1063
1064 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
1065 dnl at make time with e.g. make ERROR_CFLAGS=""
1066 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1067 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1068 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1069 AC_SUBST(GST_OPTION_CFLAGS)
1070 AC_SUBST(GST_OPTION_CXXFLAGS)
1071 AC_SUBST(GST_OPTION_OBJCFLAGS)
1072
1073 dnl our libraries need to be versioned correctly
1074 AC_SUBST(GST_LT_LDFLAGS)
1075
1076 dnl FIXME: do we want to rename to GST_ALL_* ?
1077 dnl prefer internal headers to already installed ones
1078 dnl also add builddir include for enumtypes and marshal
1079 dnl add ERROR_CFLAGS, but overridable
1080 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1081 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1082 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1083 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1084 AC_SUBST(GST_CFLAGS)
1085 AC_SUBST(GST_CXXFLAGS)
1086 AC_SUBST(GST_OBJCFLAGS)
1087 AC_SUBST(GST_LIBS)
1088
1089 dnl LDFLAGS really should only contain flags, not libs - they get added before
1090 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1091 GST_ALL_LDFLAGS="-no-undefined"
1092 AC_SUBST(GST_ALL_LDFLAGS)
1093
1094 dnl this really should only contain flags, not libs - they get added before
1095 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1096 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
1097 AC_SUBST(GST_PLUGIN_LDFLAGS)
1098
1099 dnl *** output files ***
1100
1101 dnl keep this alphabetic per directory, please
1102 AC_CONFIG_FILES(
1103 Makefile
1104 gst/Makefile
1105 gst/alpha/Makefile
1106 gst/apetag/Makefile
1107 gst/audiofx/Makefile
1108 gst/audioparsers/Makefile
1109 gst/auparse/Makefile
1110 gst/autodetect/Makefile
1111 gst/avi/Makefile
1112 gst/cutter/Makefile
1113 gst/deinterlace/Makefile
1114 gst/dtmf/Makefile
1115 gst/debugutils/Makefile
1116 gst/effectv/Makefile
1117 gst/equalizer/Makefile
1118 gst/flv/Makefile
1119 gst/goom/Makefile
1120 gst/goom2k1/Makefile
1121 gst/id3demux/Makefile
1122 gst/icydemux/Makefile
1123 gst/imagefreeze/Makefile
1124 gst/interleave/Makefile
1125 gst/isomp4/Makefile
1126 gst/law/Makefile
1127 gst/level/Makefile
1128 gst/matroska/Makefile
1129 gst/monoscope/Makefile
1130 gst/multifile/Makefile
1131 gst/multipart/Makefile
1132 gst/replaygain/Makefile
1133 gst/rtp/Makefile
1134 gst/rtpmanager/Makefile
1135 gst/rtsp/Makefile
1136 gst/shapewipe/Makefile
1137 gst/smpte/Makefile
1138 gst/spectrum/Makefile
1139 gst/udp/Makefile
1140 gst/videobox/Makefile
1141 gst/videocrop/Makefile
1142 gst/videofilter/Makefile
1143 gst/videomixer/Makefile
1144 gst/wavenc/Makefile
1145 gst/wavparse/Makefile
1146 gst/flx/Makefile
1147 gst/y4m/Makefile
1148 ext/Makefile
1149 ext/aalib/Makefile
1150 ext/cairo/Makefile
1151 ext/dv/Makefile
1152 ext/flac/Makefile
1153 ext/gdk_pixbuf/Makefile
1154 ext/jack/Makefile
1155 ext/jpeg/Makefile
1156 ext/libcaca/Makefile
1157 ext/libpng/Makefile
1158 ext/pulse/Makefile
1159 ext/raw1394/Makefile
1160 ext/shout2/Makefile
1161 ext/soup/Makefile
1162 ext/speex/Makefile
1163 ext/taglib/Makefile
1164 ext/vpx/Makefile
1165 ext/wavpack/Makefile
1166 sys/Makefile
1167 sys/directsound/Makefile
1168 sys/oss/Makefile
1169 sys/oss4/Makefile
1170 sys/osxaudio/Makefile
1171 sys/osxvideo/Makefile
1172 sys/sunaudio/Makefile
1173 sys/v4l2/Makefile
1174 sys/waveform/Makefile
1175 sys/ximage/Makefile
1176 po/Makefile.in
1177 tests/Makefile
1178 tests/check/Makefile
1179 tests/examples/Makefile
1180 tests/examples/audiofx/Makefile
1181 tests/examples/cairo/Makefile
1182 tests/examples/equalizer/Makefile
1183 tests/examples/jack/Makefile
1184 tests/examples/level/Makefile
1185 tests/examples/pulse/Makefile
1186 tests/examples/rtp/Makefile
1187 tests/examples/shapewipe/Makefile
1188 tests/examples/spectrum/Makefile
1189 tests/examples/v4l2/Makefile
1190 tests/files/Makefile
1191 tests/icles/Makefile
1192 common/Makefile
1193 common/m4/Makefile
1194 m4/Makefile
1195 docs/Makefile
1196 docs/plugins/Makefile
1197 docs/version.entities
1198 pkgconfig/Makefile
1199 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1200 gst-plugins-good.spec
1201 )
1202
1203 dnl Create the config.h file for Visual Studio builds
1204 dnl Beware of spaces and /'s in some of the shell variable contents.
1205 sed \
1206     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1207     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1208     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1209     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1210     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1211     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1212     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1213     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1214     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1215     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1216     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1217     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1218     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1219     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1220     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1221     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1222     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1223     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1224     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1225     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1226     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1227     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1228     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1229     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1230     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1231     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1232     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1233     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1234     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1235     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1236     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1237     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1238     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1239     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1240     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1241     config.h.in >win32/common/config.h-new
1242
1243 AC_OUTPUT
1244
1245 AG_GST_OUTPUT_PLUGINS
1246 ORC_OUTPUT
1247