configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-09])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])],
  15 [m4_define([v_ver], [v_maj.v_min.v_mic])])
  16 m4_define([lt_rev], m4_eval(v_maj + v_min))
  17 m4_define([lt_cur], v_mic)
  18 m4_define([lt_age], v_min)
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  21
  22 AC_INIT([elementary], [v_ver]-alpha, [enlightenment-devel@lists.sourceforge.net])
  23 AC_PREREQ(2.52)
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_MACRO_DIR([m4])
  26 AC_CANONICAL_BUILD
  27 AC_CANONICAL_HOST
  28
  29 AC_CONFIG_HEADERS([elementary_config.h])
  30 AH_TOP([
  31 #ifndef EFL_CONFIG_H__
  32 #define EFL_CONFIG_H__
  33 ])
  34 AH_BOTTOM([
  35 #endif /* EFL_CONFIG_H__ */
  36 ])
  37
  38 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  40
  41 AC_GNU_SOURCE
  42
  43 AC_C_BIGENDIAN
  44 AC_ISC_POSIX
  45 AC_PROG_CC
  46 AC_PROG_CC_STDC
  47 AC_HEADER_STDC
  48 AC_C_CONST
  49 AC_C___ATTRIBUTE__
  50 AC_FUNC_ALLOCA
  51
  52 AC_LIBTOOL_WIN32_DLL
  53 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  54 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  55 AC_PROG_LIBTOOL
  56
  57 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  58 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  59 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  60 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  61 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  62 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  63 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  64 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  65 version_info="lt_rev:lt_cur:lt_age"
  66 release_info="v_rel"
  67 AC_SUBST(version_info)
  68 AC_SUBST(release_info)
  69 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  70 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  71 VMAJ=v_maj
  72 VMIN=v_min
  73 AC_SUBST(VMAJ)
  74 AC_SUBST(VMIN)
  75
  76 # pkg-config
  77 PKG_PROG_PKG_CONFIG
  78 EDJE_VERSION=`$PKG_CONFIG edje --modversion | awk -F . '{printf("%s.0.0", $1);}'`
  79
  80 case "$host_os" in
  81   mingw32ce* | cegcc*)
  82     MODULE_ARCH="$host_os-$host_cpu"
  83     MODULE_EDJE="$host_os-$host_cpu"
  84     ;;
  85   *)
  86     MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  87     MODULE_EDJE="$host_os-$host_cpu-${EDJE_VERSION}"
  88     ;;
  89 esac
  90 AC_SUBST(release_info)
  91 AC_SUBST(MODULE_ARCH)
  92 AC_DEFINE_UNQUOTED(MODULE_ARCH, "$MODULE_ARCH", "Module architecture")
  93 AC_SUBST(MODULE_EDJE)
  94 AC_DEFINE_UNQUOTED(MODULE_EDJE, "$MODULE_EDJE", "Edje module architecture")
  95
  96 EFL_SHARED_EXTENSION="${shrext_cmds}"
  97 AC_DEFINE_UNQUOTED(EFL_SHARED_EXTENSION, "${EFL_SHARED_EXTENSION}", "Shared extension")
  98
  99 requirement_elm=""
 100
 101 PKG_PROG_PKG_CONFIG
 102
 103 # Check whether pkg-config supports Requires.private
 104 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 105    pkgconfig_requires_private="Requires.private"
 106 else
 107    pkgconfig_requires_private="Requires"
 108 fi
 109 AC_SUBST(pkgconfig_requires_private)
 110
 111 #================================================
 112 if test "x${prefix}" = "xNONE"; then
 113   LOCALE_DIR="${ac_default_prefix}/share/locale"
 114 else
 115   LOCALE_DIR="${prefix}/share/locale"
 116 fi
 117 AC_SUBST(LOCALE_DIR)
 118 #================================================
 119
 120 lt_enable_auto_import=""
 121 ELM_UNIX_DEF="#undef"
 122 ELM_WIN32_DEF="#undef"
 123 ELM_WINCE_DEF="#undef"
 124 have_windows="no"
 125 have_dlopen="no"
 126 case "$host_os" in
 127    mingw32ce*)
 128       PKG_CHECK_MODULES([EVIL], [evil])
 129       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if evil package is installed.])
 130       lt_enable_auto_import="-Wl,--enable-auto-import"
 131       ELM_WINCE_DEF="#define"
 132       have_windows="yes"
 133 dnl managed by evil
 134       AC_DEFINE(HAVE_DLADDR)
 135       have_dlopen="yes"
 136       dlopen_libs=-ldl
 137       requirement_elm="evil"
 138       have_socket="no"
 139     ;;
 140    mingw*)
 141       PKG_CHECK_MODULES([EVIL], [evil])
 142       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if evil package is installed.])
 143       lt_enable_auto_import="-Wl,--enable-auto-import"
 144       ELM_WIN32_DEF="#define"
 145       have_windows="yes"
 146 dnl managed by evil
 147       AC_DEFINE(HAVE_DLADDR)
 148       have_dlopen="yes"
 149       dlopen_libs=-ldl
 150       requirement_elm="evil"
 151       have_socket="no"
 152       ;;
 153    *solaris*)
 154       ELM_UNIX_DEF="#define"
 155       have_socket="yes"
 156       have_dlopen="yes"
 157       AC_CHECK_LIB([socket], [connect], [], [have_socket="no"])
 158       ;;
 159    darwin*)
 160       ELM_UNIX_DEF="#define"
 161       have_socket="yes"
 162       have_dlopen="yes"
 163       AC_CHECK_HEADERS([crt_externs.h])
 164       AC_DEFINE([environ], [(*_NSGetEnviron())], ["apple doesn't follow POSIX in this case."])
 165       ;;
 166    *)
 167       ELM_UNIX_DEF="#define"
 168       AC_CHECK_FUNCS(dlopen, res=yes, res=no)
 169       if test "x$res" = "xyes"; then
 170         AC_CHECK_FUNCS(dladdr, AC_DEFINE(HAVE_DLADDR))
 171         have_dlopen="yes"
 172       else
 173         AC_CHECK_LIB(dl, dlopen, res=yes, res=no)
 174         if test "x$res" = "xyes"; then
 175           AC_CHECK_LIB(dl, dladdr, AC_DEFINE(HAVE_DLADDR))
 176           dlopen_libs=-ldl
 177           have_dlopen="yes"
 178         fi
 179       fi
 180       have_socket="yes"
 181       ;;
 182 esac
 183 AM_CONDITIONAL([BUILD_RUN], [test "x$have_socket" = "xyes"])
 184 AM_CONDITIONAL([BUILD_MODULES], [test "x$have_dlopen" = "xyes"])
 185
 186 m4_ifdef([v_mic],
 187    [
 188     EFL_COMPILER_FLAG([-Wshadow])
 189     EFL_COMPILER_FLAG([-Wall])
 190     EFL_COMPILER_FLAG([-W])
 191    ])
 192
 193 have_fork="no"
 194 want_quicklaunch="auto"
 195 AC_ARG_ENABLE([quick-launch],
 196         [AC_HELP_STRING([--disable-quick-launch], [disable quick-launch support, @<:@default=detect@:>@])],
 197         [want_quicklaunch=$enableval], [])
 198
 199 if test "x$want_quicklaunch" != "xno"; then
 200    AC_CHECK_FUNCS(fork, [
 201         have_fork="yes"
 202         AC_DEFINE(HAVE_FORK)
 203    ])
 204 fi
 205 AM_CONDITIONAL([BUILD_QUICKLAUNCH], [test "x$have_fork" = "xyes" && test "x$have_dlopen" = "xyes"])
 206
 207 AC_SUBST(dlopen_libs)
 208 AC_SUBST(lt_enable_auto_import)
 209 AC_SUBST(ELM_UNIX_DEF)
 210 AC_SUBST(ELM_WIN32_DEF)
 211 AC_SUBST(ELM_WINCE_DEF)
 212
 213 AM_CONDITIONAL([ELEMENTARY_WINDOWS_BUILD], [test "x${have_windows}" = "xyes"])
 214
 215 PKG_CHECK_MODULES([ELEMENTARY],
 216    [
 217     eina >= 1.2.0
 218     eet >= 1.6.0
 219     evas >= 1.2.0
 220     ecore >= 1.2.0
 221     ecore-evas >= 1.2.0
 222     ecore-file >= 1.2.0
 223     edje >= 1.2.0
 224    ]
 225 )
 226
 227 requirement_elm="edje >= 1.2.0 ecore-file >= 1.2.0 ecore-evas >= 1.2.0 ecore >= 1.2.0 evas >= 1.2.0 eet >= 1.6.0 eina >= 1.2.0 ${requirement_elm}"
 228
 229 PKG_CHECK_MODULES([ELEMENTARY_ECORE_IMF],
 230    [ecore-imf >= 1.2.0],
 231    [
 232     ELEMENTARY_ECORE_IMF_INC="#include <Ecore_IMF.h>"
 233     AC_DEFINE(HAVE_ELEMENTARY_ECORE_IMF, 1, [Have Ecore_IMF support])
 234     have_ecore_imf="yes"
 235     requirement_elm="ecore-imf >= 1.2.0 ${requirement_elm}"
 236    ],
 237    [have_ecore_imf="no"])
 238 AC_SUBST(ELEMENTARY_ECORE_IMF_INC)
 239
 240 AM_CONDITIONAL([HAVE_ECORE_IMF], [test "x${have_ecore_imf}" = "xyes"])
 241
 242 PKG_CHECK_MODULES([ELEMENTARY_ECORE_CON],
 243    [ecore-con >= 1.2.0],
 244    [
 245     ELEMENTARY_ECORE_CON_INC="#include <Ecore_Con.h>"
 246     AC_DEFINE(HAVE_ELEMENTARY_ECORE_CON, 1, [Have Ecore_Con support])
 247     have_ecore_con="yes"
 248     requirement_elm="ecore-con >= 1.2.0 ${requirement_elm}"
 249    ],
 250    [have_ecore_con="no"])
 251 AC_SUBST(ELEMENTARY_ECORE_CON_INC)
 252
 253 AM_CONDITIONAL([HAVE_ECORE_CON], [test "x${have_ecore_con}" = "xyes"])
 254
 255 PKG_CHECK_MODULES([EIO],
 256         [eio],
 257         [
 258          have_eio="yes"
 259          AC_DEFINE(HAVE_EIO, 1, [Use EIO for asynchronous file access])
 260          requirement_elm="eio ${requirement_elm}"
 261         ],
 262         [have_eio="no"])
 263
 264 AM_CONDITIONAL([HAVE_EIO], [test "x${have_eio}" = "xyes"])
 265
 266 have_emotion="no"
 267 want_elementary_emotion="yes"
 268 AC_ARG_ENABLE([emotion],
 269    [AC_HELP_STRING([--disable-emotion], [disable emotion support. @<:@default=enabled@:>@])],
 270    [want_elementary_emotion=$enableval], [])
 271
 272 if test "x$want_elementary_emotion" != "xno"; then
 273    PKG_CHECK_MODULES([EMOTION],
 274         [emotion],
 275         [
 276          have_emotion="yes"
 277          AC_DEFINE(HAVE_EMOTION, 1, [Use Emotion for asynchronous file access])
 278          requirement_elm="emotion ${requirement_elm}"
 279         ],
 280         [have_emotion="no"])
 281 fi
 282
 283 AM_CONDITIONAL([HAVE_EMOTION], [test "x${have_emotion}" = "xyes"])
 284
 285 have_elementary_x="no"
 286 want_elementary_x="auto"
 287 AC_ARG_ENABLE([ecore-x],
 288    [AC_HELP_STRING([--disable-ecore-x], [disable ecore-x support. @<:@default=detect@:>@])],
 289    [want_elementary_x=$enableval], [])
 290
 291 if test "x$want_elementary_x" != "xno"; then
 292    PKG_CHECK_MODULES([ELEMENTARY_X],
 293       [ecore-x >= 1.2.0],
 294       [
 295        AC_DEFINE(HAVE_ELEMENTARY_X, 1, [X11 support for Elementary])
 296        have_elementary_x="yes"
 297        requirement_elm="ecore-x >= 1.2.0 ${requirement_elm}"
 298       ],
 299       [have_elementary_x="no"]
 300    )
 301 else
 302     have_elementary_x="no"
 303 fi
 304 if test "x$want_elementary_x" = "xyes" -a "x$have_elementary_x" = "xno"; then
 305     AC_MSG_ERROR([ecore-x support requested, but not found by pkg-config.])
 306 fi
 307
 308
 309 have_elementary_fb="no"
 310 want_elementary_fb="auto"
 311 AC_ARG_ENABLE([ecore-fb],
 312    [AC_HELP_STRING([--disable-ecore-fb], [disable ecore-fb support. @<:@default=detect@:>@])],
 313    [want_elementary_fb=$enableval], [])
 314
 315 if test "x$want_elementary_fb" != "xno"; then
 316    PKG_CHECK_MODULES([ELEMENTARY_FB],
 317       [ecore-fb >= 1.2.0],
 318       [
 319        AC_DEFINE(HAVE_ELEMENTARY_FB, 1, [FB support for Elementary])
 320        have_elementary_fb="yes"
 321        requirement_elm="ecore-fb >= 1.2.0 ${requirement_elm}"
 322       ],
 323       [have_elementary_fb="no"]
 324    )
 325 else
 326     have_elementary_fb="no"
 327 fi
 328 if test "x$want_elementary_fb" = "xyes" -a "x$have_elementary_fb" = "xno"; then
 329     AC_MSG_ERROR([ecore-fb support requested, but not found by pkg-config.])
 330 fi
 331
 332 have_elementary_psl1ght="no"
 333 want_elementary_psl1ght="auto"
 334 AC_ARG_ENABLE([ecore-psl1ght],
 335    [AC_HELP_STRING([--disable-ecore-psl1ght], [disable ecore-psl1ght support. @<:@default=detect@:>@])],
 336    [want_elementary_psl1ght=$enableval], [])
 337
 338 if test "x$want_elementary_psl1ght" != "xno"; then
 339    PKG_CHECK_MODULES([ELEMENTARY_PSL1GHT],
 340       [ecore-psl1ght >= 1.2.0],
 341       [
 342        AC_DEFINE(HAVE_ELEMENTARY_PSL1GHT, 1, [PSL1GHT support for Elementary])
 343        have_elementary_psl1ght="yes"
 344        requirement_elm="ecore-psl1ght >= 1.2.0 ${requirement_elm}"
 345       ],
 346       [have_elementary_psl1ght="no"]
 347    )
 348 else
 349     have_elementary_psl1ght="no"
 350 fi
 351 if test "x$want_elementary_psl1ght" = "xyes" -a "x$have_elementary_psl1ght" = "xno"; then
 352     AC_MSG_ERROR([ecore-psl1ght support requested, but not found by pkg-config.])
 353 fi
 354
 355 have_elementary_sdl="no"
 356 want_elementary_sdl="auto"
 357 AC_ARG_ENABLE([ecore-sdl],
 358    [AC_HELP_STRING([--disable-ecore-sdl], [disable ecore-sdl support. @<:@default=detect@:>@])],
 359    [want_elementary_sdl=$enableval], [])
 360
 361 if test "x$want_elementary_sdl" != "xno"; then
 362    PKG_CHECK_MODULES([ELEMENTARY_SDL],
 363       [ecore-sdl >= 1.2.0],
 364       [
 365        AC_DEFINE(HAVE_ELEMENTARY_SDL, 1, [SDL support for Elementary])
 366        have_elementary_sdl="yes"
 367        requirement_elm="ecore-sdl >= 1.2.0 ${requirement_elm}"
 368       ],
 369       [have_elementary_sdl="no"]
 370    )
 371 else
 372     have_elementary_sdl="no"
 373 fi
 374 if test "x$want_elementary_sdl" = "xyes" -a "x$have_elementary_sdl" = "xno"; then
 375     AC_MSG_ERROR([ecore-sdl support requested, but not found by pkg-config.])
 376 fi
 377
 378 have_elementary_cocoa="no"
 379 want_elementary_cocoa="auto"
 380 AC_ARG_ENABLE([ecore-cocoa],
 381    [AC_HELP_STRING([--disable-ecore-cocoa], [disable ecore-cocoa support. @<:@default=detect@:>@])],
 382    [want_elementary_cocoa=$enableval], [])
 383
 384 if test "x$want_elementary_cocoa" != "xno"; then
 385    PKG_CHECK_MODULES([ELEMENTARY_COCOA],
 386       [ecore-cocoa >= 1.2.0],
 387       [
 388        AC_DEFINE(HAVE_ELEMENTARY_COCOA, 1, [COCOA support for Elementary])
 389        have_elementary_cocoa="yes"
 390        requirement_elm="ecore-cocoa >= 1.2.0 ${requirement_elm}"
 391       ],
 392       [have_elementary_cocoa="no"]
 393    )
 394 else
 395     have_elementary_cocoa="no"
 396 fi
 397 if test "x$want_elementary_cocoa" = "xyes" -a "x$have_elementary_cocoa" = "xno"; then
 398     AC_MSG_ERROR([ecore-cocoa support requested, but not found by pkg-config.])
 399 fi
 400
 401 have_elementary_win32="no"
 402 want_elementary_win32="auto"
 403 AC_ARG_ENABLE([ecore-win32],
 404    [AC_HELP_STRING([--disable-ecore-win32], [disable ecore-win32 support. @<:@default=detect@:>@])],
 405    [want_elementary_win32=$enableval], [])
 406
 407 if test "x$want_elementary_win32" != "xno"; then
 408    PKG_CHECK_MODULES([ELEMENTARY_WIN32],
 409       [ecore-win32 >= 1.2.0],
 410       [
 411        AC_DEFINE(HAVE_ELEMENTARY_WIN32, 1, [Windows XP support for Elementary])
 412        have_elementary_win32="yes"
 413        requirement_elm="ecore-win32 >= 1.2.0 ${requirement_elm}"
 414       ],
 415       [have_elementary_win32="no"]
 416    )
 417 else
 418     have_elementary_win32="no"
 419 fi
 420 if test "x$want_elementary_win32" = "xyes" -a "x$have_elementary_win32" = "xno"; then
 421     AC_MSG_ERROR([ecore-win32 support requested, but not found by pkg-config.])
 422 fi
 423
 424 have_elementary_wince="no"
 425 want_elementary_wince="auto"
 426 AC_ARG_ENABLE([ecore-wince],
 427    [AC_HELP_STRING([--disable-ecore-wince], [disable ecore-wince support. @<:@default=detect@:>@])],
 428    [want_elementary_wince=$enableval], [])
 429
 430 if test "x$want_elementary_wince" != "xno"; then
 431    PKG_CHECK_MODULES([ELEMENTARY_WINCE],
 432       [ecore-wince >= 1.2.0],
 433       [
 434        AC_DEFINE(HAVE_ELEMENTARY_WINCE, 1, [Windows CE support for Elementary])
 435        have_elementary_wince="yes"
 436        requirement_elm="ecore-wince >= 1.2.0 ${requirement_elm}"
 437       ],
 438       [have_elementary_wince="no"]
 439    )
 440 else
 441     have_elementary_wince="no"
 442 fi
 443 if test "x$want_elementary_wince" = "xyes" -a "x$have_elementary_wince" = "xno"; then
 444     AC_MSG_ERROR([ecore-wince support requested, but not found by pkg-config.])
 445 fi
 446
 447 ELM_EDBUS_DEF="#undef"
 448 have_elementary_edbus="no"
 449 want_elementary_edbus="auto"
 450 AC_ARG_ENABLE([edbus],
 451    [AC_HELP_STRING([--disable-edbus], [disable edbus support. @<:@default=detect@:>@])],
 452    [want_elementary_edbus=$enableval], [])
 453
 454 if test "x$want_elementary_edbus" != "xno"; then
 455     PKG_CHECK_MODULES([ELEMENTARY_EDBUS],
 456        [
 457         edbus >= 1.2.0
 458        ],
 459        [
 460         AC_DEFINE(HAVE_ELEMENTARY_EDBUS, 1, [EDBus support for Elementary])
 461         have_elementary_edbus="yes"
 462         ELM_EDBUS_DEF="#define"
 463         requirement_elm="edbus >= 1.2.0 ${requirement_elm}"
 464        ],
 465        [have_elementary_edbus="no"]
 466     )
 467 else
 468     have_elementary_edbus="no"
 469 fi
 470 if test "x$want_elementary_edbus" = "xyes" -a "x$have_elementary_edbus" = "xno"; then
 471     AC_MSG_ERROR([E_DBus support requested, but no e_dbus found by pkg-config.])
 472 fi
 473 AC_SUBST(ELM_EDBUS_DEF)
 474
 475 ELM_EFREET_DEF="#undef"
 476 have_elementary_efreet="no"
 477 want_elementary_efreet="auto"
 478 AC_ARG_ENABLE([efreet],
 479    [AC_HELP_STRING([--disable-efreet], [disable efreet support. @<:@default=detect@:>@])],
 480    [want_elementary_efreet=$enableval], [])
 481
 482 if test "x$want_elementary_efreet" != "xno"; then
 483     PKG_CHECK_MODULES([ELEMENTARY_EFREET],
 484        [
 485         efreet >= 1.2.0
 486         efreet-mime >= 1.2.0
 487         efreet-trash >= 1.2.0
 488        ],
 489        [
 490         AC_DEFINE(HAVE_ELEMENTARY_EFREET, 1, [Efreet support for Elementary])
 491         have_elementary_efreet="yes"
 492         ELM_EFREET_DEF="#define"
 493         requirement_elm="efreet >= 1.2.0 efreet-mime >= 1.2.0 efreet-trash >= 1.2.0 ${requirement_elm}"
 494        ],
 495        [have_elementary_efreet="no"]
 496     )
 497 else
 498     have_elementary_efreet="no"
 499 fi
 500 if test "x$want_elementary_efreet" = "xyes" -a "x$have_elementary_efreet" = "xno"; then
 501     AC_MSG_ERROR([Efreet support requested, but no efreet/efreet-mime/efreet-trash found by pkg-config.])
 502 fi
 503 AC_SUBST(ELM_EFREET_DEF)
 504
 505 ELM_EWEATHER_DEF="#undef"
 506 have_elementary_eweather="no"
 507 want_elementary_eweather="auto"
 508 AC_ARG_ENABLE([eweather],
 509    [AC_HELP_STRING([--disable-eweather], [disable eweather support. @<:@default=detect@:>@])],
 510    [want_elementary_eweather=$enableval], [])
 511
 512 if test "x$want_elementary_eweather" != "xno"; then
 513     PKG_CHECK_MODULES([ELEMENTARY_EWEATHER],
 514        [
 515         eweather
 516        ],
 517        [
 518         AC_DEFINE(HAVE_ELEMENTARY_EWEATHER, 1, [EWeather support for Elementary])
 519         have_elementary_eweather="yes"
 520         ELM_EWEATHER_DEF="#define"
 521         requirement_elm="eweather ${requirement_elm}"
 522        ],
 523        [have_elementary_eweather="no"]
 524     )
 525 else
 526     have_elementary_eweather="no"
 527 fi
 528 if test "x$want_elementary_eweather" = "xyes" -a "x$have_elementary_eweather" = "xno"; then
 529     AC_MSG_ERROR([Eweather support requested, but no eweather found by pkg-config.])
 530 fi
 531 AC_SUBST(ELM_EWEATHER_DEF)
 532
 533 ELM_EMAP_DEF="#undef"
 534 have_elementary_emap="no"
 535 want_elementary_emap="auto"
 536 AC_ARG_ENABLE([emap],
 537    [AC_HELP_STRING([--disable-emap], [disable emap support. @<:@default=detect@:>@])],
 538    [want_elementary_emap=$enableval], [])
 539
 540 if test "x$want_elementary_emap" != "xno"; then
 541     PKG_CHECK_MODULES([ELEMENTARY_EMAP],
 542        [
 543         emap
 544        ],
 545        [
 546         AC_DEFINE(HAVE_ELEMENTARY_EMAP, 1, [EMap support for Elementary])
 547         have_elementary_emap="yes"
 548         ELM_EMAP_DEF="#define"
 549         requirement_elm="emap ${requirement_elm}"
 550        ],
 551        [have_elementary_emap="no"]
 552     )
 553 else
 554     have_elementary_emap="no"
 555 fi
 556 if test "x$want_elementary_emap" = "xyes" -a "x$have_elementary_emap" = "xno"; then
 557     AC_MSG_ERROR([Emap support requested, but no emap found by pkg-config.])
 558 fi
 559 AC_SUBST(ELM_EMAP_DEF)
 560
 561
 562
 563 ELM_ETHUMB_DEF="#undef"
 564 have_elementary_ethumb="no"
 565 want_elementary_ethumb="auto"
 566 AC_ARG_ENABLE([ethumb],
 567    [AC_HELP_STRING([--disable-ethumb], [disable ethumb support. @<:@default=detect@:>@])],
 568    [want_elementary_ethumb=$enableval], [])
 569
 570 if test "x$want_elementary_ethumb" != "xno"; then
 571     PKG_CHECK_MODULES([ELEMENTARY_ETHUMB],
 572        [
 573         ethumb_client
 574        ],
 575        [
 576         AC_DEFINE(HAVE_ELEMENTARY_ETHUMB, 1, [Ethumb support for Elementary])
 577         have_elementary_ethumb="yes"
 578         ELM_ETHUMB_DEF="#define"
 579         requirement_elm="ethumb_client ${requirement_elm}"
 580        ],
 581        [have_elementary_ethumb="no"]
 582     )
 583 else
 584     have_elementary_ethumb="no"
 585 fi
 586 if test "x$want_elementary_ethumb" = "xyes" -a "x$have_elementary_ethumb" = "xno"; then
 587     AC_MSG_ERROR([Ethumb support requested, but no ethumb found by pkg-config.])
 588 fi
 589 AC_SUBST(ELM_ETHUMB_DEF)
 590
 591 ELM_WEB_DEF="#undef"
 592 have_elementary_web="no"
 593 want_elementary_web="auto"
 594 AC_ARG_ENABLE([web],
 595    [AC_HELP_STRING([--disable-web], [disable web (WebKit) support. @<:@default=detect@:>@])],
 596    [want_elementary_web=$enableval], [])
 597
 598 if test "x$want_elementary_web" != "xno"; then
 599     PKG_CHECK_MODULES([ELEMENTARY_WEB],
 600        [
 601         ewebkit
 602        ],
 603        [
 604         AC_DEFINE(HAVE_ELEMENTARY_WEB, 1, [Web support for Elementary])
 605         webkit_datadir=$($PKG_CONFIG ewebkit --variable=datadir)
 606         AC_DEFINE_UNQUOTED(WEBKIT_DATADIR,
 607                            "$webkit_datadir",
 608                            "WebKit's data dir")
 609         have_elementary_web="yes"
 610         ELM_WEB_DEF="#define"
 611 ## web_client? how about ewebkit? at least in current upstreak webkit
 612 ## there is no web_client.pc
 613 #        requirement_elm="web_client ${requirement_elm}"
 614         requirement_elm="ewebkit ${requirement_elm}"
 615        ],
 616        [have_elementary_web="no"]
 617     )
 618 else
 619     have_elementary_web="no"
 620 fi
 621 if test "x$want_elementary_web" = "xyes" -a "x$have_elementary_web" = "xno"; then
 622     AC_MSG_ERROR([Web support requested, but no ewebkit found by pkg-config.])
 623 fi
 624 AC_SUBST(ELM_WEB_DEF)
 625
 626 ELM_DEBUG_DEF="#undef"
 627 want_elementary_debug="no"
 628 AC_ARG_ENABLE([debug],
 629    [AC_HELP_STRING([--enable-debug], [enable elementary debug support. @<:@default=disabled@:>@])],
 630    [want_elementary_debug=$enableval], [])
 631
 632 if test "x$want_elementary_debug" = "xyes"; then
 633         AC_DEFINE(HAVE_ELEMENTARY_DEBUG, 1, [Elementary debug.])
 634         ELM_DEBUG_DEF="#define"
 635 fi
 636 AC_SUBST(ELM_DEBUG_DEF)
 637
 638 ELM_ALLOCA_H_DEF="#undef"
 639 AC_CHECK_HEADER(alloca.h, [ELM_ALLOCA_H_DEF="#define"])
 640 AC_SUBST(ELM_ALLOCA_H_DEF)
 641
 642 ELM_LIBINTL_H_DEF="#undef"
 643 AC_CHECK_HEADER(libintl.h, [ELM_LIBINTL_H_DEF="#define"])
 644 AC_SUBST(ELM_LIBINTL_H_DEF)
 645
 646 ELM_DIRENT_H_DEF="#undef"
 647 AC_CHECK_HEADER(dirent.h, [ELM_DIRENT_H_DEF="#define"])
 648 AC_SUBST(ELM_DIRENT_H_DEF)
 649
 650 AC_CHECK_HEADER(sys/mman.h, [have_mman="yes"], [have_mman="no"])
 651 if test "x${have_mman}" = "xyes"; then
 652    AC_DEFINE(HAVE_MMAN_H, 1, [Have sys/mman.h header file])
 653 fi
 654
 655 AC_CHECK_HEADERS([locale.h langinfo.h])
 656
 657 my_libs="-lm"
 658 AC_SUBST(my_libs)
 659 AC_SUBST(requirement_elm)
 660
 661 EFL_WITH_BIN([eet], [eet-eet], [eet])
 662 EFL_WITH_BIN([edje], [edje-cc], [edje_cc])
 663
 664 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 665
 666 EFL_ENABLE_BIN([elementary-test])
 667 EFL_ENABLE_BIN([elementary-config])
 668
 669 m4_ifdef([AM_GNU_GETTEXT_VERSION], [
 670 AM_GNU_GETTEXT_VERSION([0.17])
 671 ])
 672
 673 m4_ifdef([AM_GNU_GETTEXT], [
 674 AM_GNU_GETTEXT([external])
 675 po_makefile_in=po/Makefile.in
 676 have_po="yes"
 677 ],[
 678 have_po="no"
 679 ])
 680 AC_SUBST(LTLIBINTL)
 681
 682 if test "x${POSUB}" = "x" ; then
 683    have_po="no"
 684 fi
 685
 686 AM_CONDITIONAL([HAVE_PO], [test "x${have_po}" = "xyes"])
 687
 688 EFL_CHECK_PATH_MAX
 689
 690 elementary_base_dir=".elementary"
 691 AC_ARG_WITH([elementary-base-dir],
 692    [AC_HELP_STRING([--with-elementary-base-dir=PATH], [specify the subdirectory for all elementary data @<:@default=${elementary_base_dir}@:>@])],
 693    [elementary_base_dir=${withval}],
 694    [elementary_base_dir=".elementary"])
 695
 696 AC_MSG_NOTICE([ELEMENTARY_BASE_DIR set to ${elementary_base_dir}])
 697 AC_DEFINE_UNQUOTED(ELEMENTARY_BASE_DIR, "${elementary_base_dir}", "subdirectory for all elementary data")
 698
 699 ### Build and install examples
 700 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
 701 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
 702
 703
 704 AC_OUTPUT([
 705 Makefile
 706 elementary.spec
 707 elementary.pc
 708 doc/Makefile
 709 doc/Doxyfile
 710 doc/widgets/Makefile
 711 src/Makefile
 712 src/lib/Makefile
 713 src/lib/Elementary.h
 714 src/bin/Makefile
 715 src/modules/Makefile
 716 src/modules/access_output/Makefile
 717 src/modules/datetime_input_ctxpopup/Makefile
 718 src/modules/test_entry/Makefile
 719 src/modules/test_map/Makefile
 720 src/edje_externals/Makefile
 721 src/examples/Makefile
 722 data/Makefile
 723 data/themes/Makefile
 724 data/images/Makefile
 725 data/objects/Makefile
 726 data/desktop/Makefile
 727 data/edje_externals/Makefile
 728 config/Makefile
 729 config/default/Makefile
 730 config/standard/Makefile
 731 config/illume/Makefile
 732 $po_makefile_in
 733 ])
 734
 735 #####################################################################
 736 ## Info
 737
 738 echo
 739 echo
 740 echo
 741 echo "------------------------------------------------------------------------"
 742 echo "$PACKAGE $VERSION"
 743 echo "------------------------------------------------------------------------"
 744 echo
 745 echo "Configuration Options Summary:"
 746 echo
 747 echo "  Engines:"
 748 echo "    X11....................: ${have_elementary_x}"
 749 echo "    Framebuffer............: ${have_elementary_fb}"
 750 echo "    PSL1GHT................: ${have_elementary_psl1ght}"
 751 echo "    SDL....................: ${have_elementary_sdl}"
 752 echo "    Cocoa..................: ${have_elementary_cocoa}"
 753 echo "    Windows XP.............: ${have_elementary_win32}"
 754 echo "    Windows CE.............: ${have_elementary_wince}"
 755 echo
 756 echo "  Features:"
 757 echo "    Ecore_IMF..............: ${have_ecore_imf}"
 758 echo "    Ecore_Con..............: ${have_ecore_con}"
 759 echo "    EDBus..................: ${have_elementary_edbus}"
 760 echo "    EFreet.................: ${have_elementary_efreet}"
 761 echo "    EWeather...............: ${have_elementary_eweather}"
 762 echo "    EMap...................: ${have_elementary_emap}"
 763 echo "    Ethumb.................: ${have_elementary_ethumb}"
 764 echo "    Web (WebKit)...........: ${have_elementary_web}"
 765 echo "    Quick Launch...........: ${have_fork}"
 766 echo "    EIO....................: ${have_eio}"
 767 echo "    Emotion................: ${have_emotion}"
 768 echo
 769 echo "  eet......................: ${eet_eet}"
 770 echo "  edje_cc..................: ${edje_cc}"
 771 echo
 772 echo "  Build elementary_test....: ${have_elementary_test}"
 773 echo "  Examples.................: ${enable_build_examples}"
 774 echo "  Examples installed.......: ${enable_install_examples}"
 775 echo "  Build elementary_config..: ${have_elementary_config}"
 776 echo
 777 echo "Compilation................: make (or gmake)"
 778 echo "  CPPFLAGS.................: $CPPFLAGS"
 779 echo "  CFLAGS...................: $CFLAGS"
 780 echo "  LDFLAGS..................: $LDFLAGS"
 781 echo
 782 echo "Installation...............: make install (as root if needed, with 'su' or 'sudo')"
 783 echo "  prefix...................: $prefix"
 784 echo