configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/librygel-core/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1 tar-ustar no-dist-gzip dist-xz -Wno-portability])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 dnl Required versions of library packages
  31 dnl Not all of these are actually used, depending on the configure options.
  32 GLIB_REQUIRED=2.31.13
  33 LIBXML_REQUIRED=2.7
  34 VALA_REQUIRED=0.18.0
  35 VALADOC_REQUIRED=0.2
  36 GSSDP_REQUIRED=0.13.0
  37 GUPNP_REQUIRED=0.19.0
  38 GUPNP_AV_REQUIRED=0.11.4
  39 GUPNP_DLNA_REQUIRED=0.7.0
  40 GSTREAMER_REQUIRED=1.0
  41 GSTPBU_REQUIRED=1.0
  42 GIO_REQUIRED=2.26
  43 GEE_REQUIRED=0.8.0
  44 UUID_REQUIRED=1.41.3
  45 LIBSOUP_REQUIRED=2.34.0
  46 GTK_REQUIRED=2.90.3
  47
  48 dnl Additional requirements for media-export plugin
  49 GSTREAMER_TAG_REQUIRED=1.0
  50 GSTREAMER_APP_REQUIRED=1.0
  51 LIBSQLITE3_REQUIRED=3.5
  52
  53 dnl Additional requirements for tracker plugin
  54 TRACKER_SPARQL_REQUIRED_MIN=0.14.0
  55
  56 VALAFLAGS="--target-glib=2.32 $VALAFLAGS"
  57
  58 RYGEL_BASE_MODULES='gupnp-1.0 >= $GUPNP_REQUIRED gee-0.8 >= $GEE_REQUIRED'
  59 PKG_CHECK_MODULES([LIBRYGEL_CORE_DEPS], [$RYGEL_BASE_MODULES uuid >= $UUID_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gio-2.0 >= $GIO_REQUIRED])
  60 RYGEL_BASE_MODULES_VALAFLAGS='--pkg gupnp-1.0 --pkg gee-0.8'
  61 LIBRYGEL_CORE_DEPS_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gssdp-1.0 --pkg gio-2.0 --pkg gmodule-2.0"
  62 AC_SUBST([LIBRYGEL_CORE_DEPS_VALAFLAGS])
  63
  64 RYGEL_COMMON_MODULES="$RYGEL_BASE_MODULES gupnp-av-1.0 >= $GUPNP_AV_REQUIRED"
  65 PKG_CHECK_MODULES([LIBRYGEL_SERVER_DEPS], [$RYGEL_COMMON_MODULES uuid >= $UUID_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gio-2.0 >= $GIO_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
  66 RYGEL_COMMON_MODULES_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gupnp-av-1.0"
  67 LIBRYGEL_SERVER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gssdp-1.0 --pkg gio-2.0 --pkg libsoup-2.4 --pkg gmodule-2.0"
  68 AC_SUBST([LIBRYGEL_SERVER_DEPS_VALAFLAGS])
  69
  70 PKG_CHECK_MODULES([LIBRYGEL_RENDERER_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
  71 LIBRYGEL_RENDERER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg libsoup-2.4"
  72 AC_SUBST([LIBRYGEL_RENDERER_DEPS_VALAFLAGS])
  73
  74 PKG_CHECK_MODULES([RYGEL_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED])
  75
  76 # Not all tests use all of these dependencies,
  77 # but having one set of dependencies keeps things simple.
  78 PKG_CHECK_MODULES([TEST_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED])
  79 TEST_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg gssdp-1.0 --pkg libsoup-2.4 --pkg libxml-2.0 --pkg gmodule-2.0"
  80 AC_SUBST([TEST_DEPS_VALAFLAGS])
  81
  82 PKG_CHECK_MODULES([EXAMPLE_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED])
  83
  84
  85
  86 dnl Media engine to use
  87 BUILT_ENGINES="librygel-media-engine-simple"
  88
  89 dnl Disabling the gstreamer media_engine also disables
  90 dnl anything else that uses gstreamer.
  91 AC_ARG_WITH([media_engine],
  92             AS_HELP_STRING(
  93                 [--with-media-engine=@<:@gstreamer|simple@:>@],
  94                 [Media Engine to use]),
  95             [with_media_engine="$withval"],
  96             [with_media_engine="gstreamer"])
  97
  98 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  99       [
 100         enable_gstreamer="yes"
 101         BUILT_ENGINES="$BUILT_ENGINES;librygel-media-engine-gst"
 102
 103         PKG_CHECK_MODULES([RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS],
 104                           [$RYGEL_COMMON_MODULES
 105                            gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED
 106                            gupnp-dlna-1.1 >= $GUPNP_DLNA_REQUIRED
 107                            gio-2.0 >= GIO_REQUIRED])
 108         RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-base-1.0 --pkg gstreamer-pbutils-1.0 --pkg gupnp-dlna-1.1"
 109         AC_SUBST([RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS_VALAFLAGS])
 110
 111         PKG_CHECK_MODULES([LIBRYGEL_RENDERER_GST_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_REQUIRED])
 112         LIBRYGEL_RENDERER_GST_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-1.0"
 113         AC_SUBST([LIBRYGEL_RENDERER_GST_DEPS_VALAFLAGS])
 114       ],
 115       [enable_gstreamer="no"])
 116 AM_CONDITIONAL([HAVE_GSTREAMER],[test "x$enable_gstreamer" = "xyes"])
 117 AC_SUBST([BUILT_ENGINES])
 118
 119 dnl Add plugins
 120 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
 121 AS_IF([test "x$enable_external_plugin" = "xyes"],
 122   [
 123     PKG_CHECK_MODULES([RYGEL_PLUGIN_EXTERNAL_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 124   ])
 125
 126 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
 127 AS_IF([test "x$enable_mpris_plugin" = "xyes"],
 128   [
 129     PKG_CHECK_MODULES([RYGEL_PLUGIN_MPRIS_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 130   ])
 131
 132 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
 133 AS_IF([test "x$enable_mediathek_plugin" = "xyes"],
 134   [
 135     PKG_CHECK_MODULES([RYGEL_PLUGIN_MEDIATHEK_DEPS],
 136                       [$RYGEL_COMMON_MODULES
 137                        gio-2.0 >= $GIO_REQUIRED
 138                        libsoup-2.4 >= $LIBSOUP_REQUIRED
 139                        libxml-2.0 >= $LIBXML_REQUIRED])
 140   ])
 141
 142 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 143       [
 144         RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
 145         AS_IF([test "x$enable_playbin_plugin" = "xyes"],
 146           [
 147             PKG_CHECK_MODULES([RYGEL_PLUGIN_PLAYBIN_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_TAG_REQUIRED])
 148           ])
 149
 150         RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
 151         AS_IF([test "x$enable_media_export_plugin" = "xyes"],
 152           [
 153             PKG_CHECK_MODULES([RYGEL_PLUGIN_MEDIA_EXPORT_DEPS],
 154                               [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED
 155                                gupnp-dlna-1.1 >= $GUPNP_DLNA_REQUIRED
 156                                gstreamer-tag-1.0 >= $GSTREAMER_TAG_REQUIRED
 157                                gstreamer-app-1.0 >= $GSTREAMER_TAG_REQUIRED
 158                                gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED
 159                                sqlite3 >= $LIBSQLITE3_REQUIRED
 160                                uuid])
 161             RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gupnp-dlna-1.1 --pkg gstreamer-tag-1.0 --pkg gstreamer-app-1.0 --pkg sqlite3"
 162             AC_SUBST([RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_VALAFLAGS])
 163           ])
 164
 165         RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
 166         AS_IF([test "x$enable_gst_launch_plugin" = "xyes"],
 167           [
 168             PKG_CHECK_MODULES([RYGEL_PLUGIN_GST_LAUNCH_DEPS], [$RYGEL_COMMON_MODULES])
 169             RYGEL_PLUGIN_GST_LAUNCH_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS"
 170             AC_SUBST([RYGEL_PLUGIN_GST_LAUNCH_DEPS_VALAFLAGS])
 171           ])
 172
 173         RYGEL_ADD_STAMP([src/media-engines/gstreamer/librygel_media_engine_gst_la_vala.stamp])
 174         RYGEL_ADD_STAMP([src/librygel-renderer-gst/librygel_renderer_gst_2_0_la_vala.stamp])
 175       ],
 176       [
 177         RYGEL_DISABLE_PLUGIN([playbin])
 178         RYGEL_DISABLE_PLUGIN([media-export])
 179         RYGEL_DISABLE_PLUGIN([gst-launch])
 180       ])
 181
 182 dnl Example plugins:
 183 AC_ARG_ENABLE([example-plugins],
 184               AS_HELP_STRING([--enable-example-plugins],[enable example plugins]),,
 185               enable_example_plugins=no)
 186 AM_CONDITIONAL([BUILD_EXAMPLE_PLUGINS], [test "x$[]enable_example_plugins" = "xyes"])
 187
 188 dnl Explicitly add stamp files for targets that are not plugins
 189 RYGEL_ADD_STAMP([src/librygel-core/librygel_core_2_0_la_vala.stamp])
 190 RYGEL_ADD_STAMP([src/librygel-server/librygel_server_2_0_la_vala.stamp])
 191 RYGEL_ADD_STAMP([src/librygel-renderer/librygel_renderer_2_0_la_vala.stamp])
 192 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
 193 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
 194 RYGEL_ADD_STAMP([src/media-engines/simple/librygel_media_engine_simple_la_vala.stamp])
 195
 196 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 197       [
 198         RYGEL_CHECK_PACKAGES([gupnp-dlna-1.1 gstreamer-1.0
 199                               gstreamer-pbutils-1.0])
 200       ])
 201
 202 dnl Debugging
 203 AC_ARG_ENABLE(debug,
 204         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 205         enable_debug=no)
 206 if test "x$enable_debug" = "xyes"; then
 207         CFLAGS="$CFLAGS -O0 -g"
 208         RYGEL_DEBUG_VALAFLAGS="-g"
 209 fi
 210
 211 AC_SUBST(RYGEL_DEBUG_VALAFLAGS)
 212
 213 dnl Strict compiler
 214 AC_ARG_ENABLE(strict-cc,
 215         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 216         enable_strict_cc=no)
 217 if test "x$enable_strict_cc" = "xyes"; then
 218         CFLAGS="$CFLAGS -Wall -Werror"
 219 else
 220         CFLAGS="$CFLAGS -w"
 221 fi
 222
 223 dnl Run uninstalled
 224 AC_ARG_ENABLE(uninstalled,
 225     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 226         enable_uninstalled=no)
 227 if test "x$enable_uninstalled" = "xyes"; then
 228         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 229 fi
 230 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 231
 232 dnl Check wether user wants to build UIs
 233 AC_ARG_WITH( ui,
 234   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 235   try_ui=$withval, try_ui=yes )
 236
 237 HAVE_GTK=no
 238 if test x$try_ui = xyes ; then
 239     dnl check for gtk
 240     PKG_CHECK_MODULES([RYGEL_UI_DEPS], [$RYGEL_BASE_MODULES gtk+-3.0 >= $GTK_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gee-0.8 >= $GEE_REQUIRED],
 241       [
 242         RYGEL_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 243         RYGEL_UI_DEPS_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gtk+-3.0 --pkg gssdp-1.0 --pkg gee-0.8"
 244         AC_SUBST([RYGEL_UI_DEPS_VALAFLAGS])
 245
 246         PKG_CHECK_MODULES([EXAMPLE_UI_DEPS],
 247                           [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED
 248                            gssdp-1.0 >= $GSSDP_REQUIRED
 249                            gstreamer-video-1.0 >= $GSTREAMER_REQUIRED
 250                            gtk+-3.0 >= $GTK_REQUIRED])
 251       ],
 252       [
 253         AC_MSG_WARN([UI dependencies not found.])
 254         AC_MSG_WARN([UI applications will not be built.])
 255       ])
 256
 257 else
 258     AC_MSG_NOTICE([UI applications disabled.])
 259 fi
 260
 261 AM_CONDITIONAL(BUILD_UI, test "x$HAVE_GTK" = "xyes")
 262
 263 dnl Tests
 264 AC_ARG_ENABLE([tests],
 265               AS_HELP_STRING([--enable-tests],[always build tests]),,
 266               enable_tests=no)
 267 AM_CONDITIONAL([ALWAYS_TEST], [test "x$enable_tests" = "xyes"])
 268
 269 dnl Generate coverage data
 270 AC_ARG_ENABLE([coverage],
 271   AS_HELP_STRING([--enable-coverage],
 272                  [Generate converage reports for unit tests]),
 273   [],
 274   [enable_coverage=no])
 275 AM_CONDITIONAL([ENABLE_COVERAGE],[test "x$enable_coverage" != "xno"])
 276 AS_IF([test "x$enable_coverage" != "xno"],
 277   [
 278     AC_PATH_PROG([LCOV], [lcov])
 279     AC_PATH_PROG([GENHTML], [genhtml])
 280     AC_SUBST([COVERAGE_LIBS],["-lgcov"])
 281     AC_SUBST([COVERAGE_CFLAGS],["-fprofile-arcs -ftest-coverage"])
 282     AC_SUBST(COVERAGE_VALAFLAGS,["-g"])
 283   ]
 284 )
 285
 286 dnl Check additional requirements for MediaExport plugins
 287 if test "x$enable_media_export_plugin" = "xyes";
 288 then
 289     RYGEL_CHECK_PACKAGES([sqlite3 gstreamer-tag-1.0 gstreamer-app-1.0])
 290     AC_CHECK_HEADER([unistr.h],
 291                     AC_CHECK_LIB([unistring],
 292                                  [u8_strcoll],
 293                                  [have_unistring=yes],[have_unistring=no]))
 294     if test "x$have_unistring" = "xyes"; then
 295         AC_DEFINE([HAVE_UNISTRING],[1],[Use libunistring for collation])
 296         COLLATION_CFLAGS=
 297         COLLATION_LIBS=-lunistring
 298         AC_SUBST([COLLATION_CFLAGS])
 299         AC_SUBST([COLLATION_LIBS])
 300     fi
 301 fi
 302
 303
 304 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
 305 AS_IF([test "x$enable_tracker_plugin" = "xyes"],
 306   [
 307     PKG_CHECK_MODULES([RYGEL_PLUGIN_TRACKER_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 308
 309     tracker_api_version="0.14"
 310     PKG_CHECK_MODULES(TRACKER_SPARQL,
 311                       tracker-sparql-0.14 >= $TRACKER_SPARQL_REQUIRED_MIN,
 312                       [tracker_api_version="0.14"],
 313                       [tracker_api_version=""])
 314     AS_IF([test "x$[]tracker_api_version" = "x"],
 315           [
 316             PKG_CHECK_MODULES(TRACKER_SPARQL,
 317                               tracker-sparql-0.15 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 318                               [tracker_api_version="0.15"],
 319                               [tracker_api_version=""])
 320           ])
 321     AS_IF([test "x$[]tracker_api_version" = "x"],
 322           [
 323             PKG_CHECK_MODULES(TRACKER_SPARQL,
 324                               tracker-sparql-0.16 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 325                               [tracker_api_version="0.16"],
 326                               [])
 327           ])
 328     AS_IF([test "x$enable_vala" = "xyes"],
 329           [VALA_CHECK_PACKAGES([tracker-sparql-$tracker_api_version])])
 330
 331     RYGEL_PLUGIN_TRACKER_DEPS_VALAFLAGS="--pkg tracker-sparql-$tracker_api_version"
 332     AC_SUBST([RYGEL_PLUGIN_TRACKER_DEPS_VALAFLAGS])
 333   ])
 334
 335 # This should be called only after all RYGEL_CHECK_VALA() and RYGEL_ADD_PLUGIN() calls:
 336 RYGEL_CHECK_VALA([$VALA_REQUIRED],
 337                  [gupnp-1.0
 338                   gupnp-av-1.0
 339                   gio-2.0
 340                   gee-0.8
 341                   posix])
 342
 343 dnl Gettext
 344 GETTEXT_PACKAGE=rygel
 345 AC_SUBST(GETTEXT_PACKAGE)
 346 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 347   [Define the gettext package to be used])
 348
 349 AM_GLIB_GNU_GETTEXT
 350 IT_PROG_INTLTOOL([0.40.0])
 351
 352 dnl Shave the output
 353 AM_SILENT_RULES([yes])
 354
 355 dnl documenation
 356 AC_PATH_PROG([XSLTPROC], [xsltproc])
 357 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 358
 359 dnl Use valadoc for API documentation:
 360 dnl This is on by default when using autogen.sh
 361 dnl (so it is not on by default when building from a tarball with configure.)
 362 AC_ARG_ENABLE(valadoc,
 363   AS_HELP_STRING([--enable-valadoc[=@<:@no/auto/yes@:>@]], [Enable valadoc support]),,
 364     [enable_valadoc=no])
 365
 366 found_valadoc=no
 367 AS_IF([test "x$enable_valadoc" != "xno"], [
 368     AC_PATH_PROG(VALADOC, valadoc, :)
 369     AS_IF([test -x "$VALADOC"], [
 370       found_valadoc=yes
 371       AC_SUBST(VALADOC)
 372       PKG_CHECK_MODULES([GTKDOC],[gtk-doc >= 1.0])
 373     ], [
 374       AS_IF([test "x$enable_valadoc" == "xyes"], AC_MSG_ERROR([Unable to find valadoc]))
 375     ])
 376   ])
 377
 378 AM_CONDITIONAL(ENABLE_VALADOC, test x$found_valadoc = xyes)
 379
 380 AC_CONFIG_FILES([
 381 Makefile
 382 src/Makefile
 383 src/librygel-core/Makefile
 384 src/librygel-renderer/Makefile
 385 src/librygel-renderer-gst/Makefile
 386 src/librygel-server/Makefile
 387 src/rygel/Makefile
 388 src/ui/Makefile
 389 src/media-engines/Makefile
 390 src/media-engines/gstreamer/Makefile
 391 src/media-engines/simple/Makefile
 392 src/plugins/Makefile
 393 data/Makefile
 394 data/xml/Makefile
 395 data/xml/MediaServer3.xml.in
 396 data/xml/MediaRenderer2.xml.in
 397 data/icons/Makefile
 398 data/icons/32x32/Makefile
 399 data/icons/48x48/Makefile
 400 data/icons/120x120/Makefile
 401 data/icons/128x128/Makefile
 402 data/icons/scalable/Makefile
 403 data/rygel.desktop.in
 404 data/rygel-preferences.desktop.in
 405 doc/Makefile
 406 doc/reference/Makefile
 407 doc/reference/librygel-core/Makefile
 408 doc/reference/librygel-renderer/Makefile
 409 doc/reference/librygel-server/Makefile
 410 doc/reference/librygel-renderer-gst/Makefile
 411 po/Makefile.in
 412 rygel-core-2.0.pc
 413 rygel-renderer-2.0.pc
 414 rygel-server-2.0.pc
 415 rygel-renderer-gst-2.0.pc
 416 tests/Makefile
 417 examples/Makefile
 418 examples/renderer-plugins/Makefile
 419 examples/renderer-plugins/vala/Makefile
 420 examples/renderer-plugins/C/Makefile
 421 examples/server-plugins/Makefile
 422 examples/server-plugins/vala/Makefile
 423 examples/server-plugins/C/Makefile
 424 ])
 425 AC_OUTPUT
 426
 427 echo "
 428
 429                     ${PACKAGE} ${VERSION}
 430                     ============
 431
 432
 433         Prefix:                 ${prefix}
 434         Source code location:   ${srcdir}
 435         Compiler:               ${CC}
 436         CFLAGS:                 ${CFLAGS}
 437         VALAFLAGS:              ${VALAFLAGS}
 438         uninstalled:            ${enable_uninstalled}
 439         preferences ui:         ${HAVE_GTK}
 440         Media Engine:           ${with_media_engine}
 441     Plugins:
 442         examples:               ${enable_example_plugins}
 443         tracker:                ${enable_tracker_plugin}
 444             version:            ${tracker_api_version}
 445         mediathek:              ${enable_mediathek_plugin}
 446         media-export            ${enable_media_export_plugin}
 447         external:               ${enable_external_plugin}
 448         MPRIS2:                 ${enable_mpris_plugin}
 449         gst-launch:             ${enable_gst_launch_plugin}
 450         playbin:                ${enable_playbin_plugin}
 451 "