configure.ac

   1 AC_PREREQ(2.60)
   2 dnl initialize autoconf
   3 dnl when going to/from release please set the nano (fourth number) right !
   4 dnl releases only do Wall, cvs and prerelease does Werror too
   5 AC_INIT(Gst-RTSP, 0.10.7.1,
   6     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   7     gst-rtsp)
   8 AG_GST_INIT
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/rtsp-server/rtsp-server.c])
  21
  22 dnl define the output header for config
  23 AM_CONFIG_HEADER([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_MAJORMINOR=0.10
  40 AC_SUBST(GST_MAJORMINOR)
  41
  42 AM_PROG_LIBTOOL
  43
  44 dnl *** required versions of GStreamer stuff ***
  45 GST_REQ=0.10.29
  46 GSTPB_REQ=0.10.29
  47
  48 dnl *** autotools stuff ****
  49
  50 dnl allow for different autotools
  51 AS_AUTOTOOLS_ALTERNATE
  52
  53 dnl Add parameters for aclocal
  54 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  55
  56 dnl set up gettext
  57 dnl the version check needs to stay here because autopoint greps for it
  58 AM_GNU_GETTEXT_VERSION([0.17])
  59 AM_GNU_GETTEXT([external])
  60 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  61
  62 dnl *** check for arguments to configure ***
  63
  64 AG_GST_ARG_DEBUG
  65 AG_GST_ARG_VALGRIND
  66 AG_GST_ARG_GCOV
  67 AG_GST_ARG_WITH_PACKAGE_NAME
  68 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  69
  70 AG_GST_PKG_CONFIG_PATH
  71
  72 dnl *** checks for platform ***
  73
  74 dnl * hardware/architecture *
  75
  76 dnl *** checks for programs ***
  77
  78 dnl find a compiler
  79 AC_PROG_CC
  80 AM_PROG_CC_C_O
  81
  82 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  83 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  84
  85 dnl check for gobject-introspection
  86 GOBJECT_INTROSPECTION_CHECK([0.6.3])
  87
  88 dnl check for documentation tools
  89 AG_GST_DOCBOOK_CHECK
  90 GTK_DOC_CHECK([1.3])
  91
  92 dnl check for python
  93 AM_PATH_PYTHON
  94 AC_MSG_CHECKING(for python >= 2.3)
  95 prog="
  96 import sys, string
  97 minver = (2,3,0,'final',0)
  98 if sys.version_info < minver:
  99   sys.exit(1)
 100 sys.exit(0)"
 101
 102 if $PYTHON -c "$prog" 1>&AC_FD_CC 2>&AC_FD_CC
 103 then
 104   HAVE_PYTHON=yes
 105   AC_MSG_RESULT(okay)
 106 else
 107   HAVE_PYTHON=no
 108   AC_MSG_RESULT(no python)
 109 fi
 110
 111 AM_CHECK_PYTHON_HEADERS([HAVE_PYTHON_HEADERS=yes],[HAVE_PYTHON_HEADERS=no])
 112
 113 dnl check for pygobject (optional, used in the bindings)
 114 PKG_CHECK_MODULES(PYGOBJECT, pygobject-2.0 >= $PYGOBJECT_REQ,
 115   [HAVE_PYGOBJECT="yes"], [HAVE_PYGOBJECT="no"])
 116 AC_SUBST(PYGOBJECT_CFLAGS)
 117 AC_SUBST(PYGOBJECT_REQ, 2.11.2)
 118
 119 dnl check for gst-python
 120 PKG_CHECK_MODULES(PYGST, gst-python-0.10,
 121   [HAVE_PYGST="yes"], [HAVE_PYGST="no"])
 122
 123 if test "x$HAVE_PYGST" = "xyes"; then
 124   PYGST_DEFSDIR=`pkg-config gst-python-0.10 --variable=defsdir`
 125 fi
 126 AC_SUBST(PYGST_DEFSDIR, $PYGST_DEFSDIR)
 127
 128 if test \
 129     "x$HAVE_PYTHON" = "xyes" -a \
 130     "x$HAVE_PYTHON_HEADERS" = "xyes" -a \
 131     "x$HAVE_PYGOBJECT" = "xyes" -a \
 132     "x$HAVE_PYGST" = "xyes"; then
 133   HAVE_PYTHON_BINDINGS="yes"
 134 else
 135   HAVE_PYTHON_BINDINGS="no"
 136 fi
 137
 138 AM_CONDITIONAL(WITH_PYTHON, [test "x$HAVE_PYTHON_BINDINGS" = "xyes"])
 139
 140 dnl Check for Vala
 141 AC_ARG_ENABLE([vala],
 142   AC_HELP_STRING([--enable-vala],[enable Vala bindings (default=yes)]),
 143   [case "${enableval}" in
 144     yes) enable_vala=yes ;;
 145     no)  enable_vala=no ;;
 146     *) AC_MSG_ERROR(bad value ${enableval} for --enable-vala) ;;
 147    esac
 148   ],
 149   [enable_vala=yes]) dnl Default value
 150 AM_CONDITIONAL(WITH_VALA, [test "x$enable_vala" = "xyes"])
 151
 152 dnl *** checks for libraries ***
 153
 154 dnl *** checks for header files ***
 155
 156 dnl *** checks for types/defines ***
 157
 158 dnl *** checks for structures ***
 159
 160 dnl *** checks for compiler characteristics ***
 161
 162 dnl *** checks for library functions ***
 163
 164 dnl *** checks for dependancy libraries ***
 165
 166 dnl GLib is required (GStreamer is ok with GLib-2.8, but we want at least 2.10)
 167 GLIB_REQ=2.10.0
 168 AC_SUBST([GLIB_REQ])
 169 AG_GST_GLIB_CHECK([$GLIB_REQ])
 170
 171 dnl checks for gstreamer
 172 dnl uninstalled is selected preferentially -- see pkg-config(1)
 173 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], [yes])
 174
 175 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 176 if test -z $GST_TOOLS_DIR; then
 177   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 178 fi
 179 AC_SUBST(GST_TOOLS_DIR)
 180
 181 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 182 AC_SUBST(GST_PLUGINS_DIR)
 183 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 184
 185 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], [yes])
 186
 187 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], [yes])
 188 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_MAJORMINOR --variable pluginsdir`
 189 AC_SUBST(GSTPB_PLUGINS_DIR)
 190 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 191
 192 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 193
 194 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 195 dnl check for "check", unit testing library/header
 196 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 197 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 198
 199 dnl *** set variables based on configure arguments ***
 200
 201 dnl set license and copyright notice
 202 GST_LICENSE="LGPL"
 203 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 204 AC_SUBST(GST_LICENSE)
 205
 206 dnl set location of plugin directory
 207 AG_GST_SET_PLUGINDIR
 208
 209 dnl define an ERROR_CFLAGS Makefile variable
 210 AG_GST_SET_ERROR_CFLAGS($GST_GIT)
 211
 212 dnl define correct level for debugging messages
 213 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 214
 215 dnl used in examples
 216 AG_GST_DEFAULT_ELEMENTS
 217
 218 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 219
 220 dnl Overview:
 221 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 222 dnl GST_*:              flags shared by built objects to link against GStreamer
 223 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 224 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 225 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 226 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 227
 228 dnl GST_OPTION_CFLAGS
 229 if test "x$USE_DEBUG" = xyes; then
 230    PROFILE_CFLAGS="-g"
 231 fi
 232 AC_SUBST(PROFILE_CFLAGS)
 233
 234 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 235 AC_SUBST(DEPRECATED_CFLAGS)
 236
 237 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 238 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 239 AC_SUBST(GST_OPTION_CFLAGS)
 240
 241 dnl FIXME: do we want to rename to GST_ALL_* ?
 242 dnl prefer internal headers to already installed ones
 243 dnl add GST_OPTION_CFLAGS, but overridable
 244 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 245 AC_SUBST(GST_CFLAGS)
 246 AC_SUBST(GST_LIBS)
 247
 248 dnl GST_ALL_*
 249 dnl vars common to for all internal objects (core libs, elements, applications)
 250 dnl CFLAGS:
 251 dnl - src and build dirs need to be added because every piece that gets built
 252 dnl   will need the GStreamer source and generated headers
 253 GST_ALL_CFLAGS="-I\$(top_srcdir) -I\$(top_builddir) $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 254 AC_SUBST([GST_ALL_CFLAGS])
 255
 256 dnl FIXME: check if LTLIBINTL is needed everywhere
 257 dnl I presume it is given that it contains the symbols that _() stuff maps to
 258 GST_ALL_LIBS="$GST_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 259 AC_SUBST([GST_ALL_LIBS])
 260
 261 dnl LDFLAGS really should only contain flags, not libs - they get added before
 262 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 263 GST_ALL_LDFLAGS="-no-undefined"
 264 AC_SUBST(GST_ALL_LDFLAGS)
 265
 266 dnl GST_OBJ_*
 267 dnl default vars for all internal objects built on libgstphonon
 268 dnl includes GST_ALL_*
 269 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 270 AC_SUBST([GST_OBJ_CFLAGS])
 271 GST_OBJ_LIBS="\$(top_builddir)/gst-phonon/libgstphonon.la \$(GST_ALL_LIBS)"
 272 AC_SUBST([GST_OBJ_LIBS])
 273
 274 dnl this really should only contain flags, not libs - they get added before
 275 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 276
 277 dnl *** output files ***
 278
 279 dnl keep this alphabetic per directory, please
 280 AC_CONFIG_FILES([
 281 Makefile
 282 gst-rtsp.spec
 283 common/Makefile
 284 common/m4/Makefile
 285 m4/Makefile
 286 gst/Makefile
 287 gst/rtsp-server/Makefile
 288 examples/Makefile
 289 bindings/Makefile
 290 bindings/python/Makefile
 291 bindings/python/codegen/Makefile
 292 bindings/vala/Makefile
 293 pkgconfig/Makefile
 294 pkgconfig/gst-rtsp-server.pc
 295 pkgconfig/gst-rtsp-server-uninstalled.pc
 296 docs/Makefile
 297 docs/version.entities
 298 docs/libs/Makefile
 299 ])
 300 AC_OUTPUT
 301
 302 echo "
 303
 304 Configuration
 305         Version                    : ${VERSION}
 306         Source code location       : ${srcdir}
 307         Prefix                     : ${prefix}
 308         Compiler                   : ${CC}
 309         Vala bindings              : ${enable_vala}
 310         Python bindings:           : ${HAVE_PYTHON_BINDINGS}
 311
 312 Gst-rtsp-server configured. Type 'make' to build.
 313 "