configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.6.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AM_PROG_LIBTOOL
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=0.10.13
  50 GSTPB_REQ=0.10.13
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.11.5])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DEBUG
  69 AG_GST_ARG_PROFILING
  70 AG_GST_ARG_VALGRIND
  71 AG_GST_ARG_GCOV
  72
  73 AG_GST_ARG_EXAMPLES
  74
  75 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  76 AG_GST_ARG_WITH_PACKAGE_NAME
  77 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  78
  79 dnl these are all the gst plug-ins, compilable without additional libs
  80 dnl videofilter is at the top because others depend on it
  81 GST_PLUGINS_ALL="\
  82                 videofilter \
  83                 alpha \
  84                 apetag \
  85                 audiofx \
  86                 auparse \
  87                 autodetect \
  88                 avi \
  89                 cutter \
  90                 debug \
  91                 effectv \
  92                 id3demux \
  93                 icydemux \
  94                 flx \
  95                 goom \
  96                 law \
  97                 level \
  98                 matroska \
  99                 monoscope \
 100                 multipart \
 101                 qtdemux \
 102                 rtp     \
 103                 rtsp    \
 104                 smpte   \
 105                 udp     \
 106                 videobox \
 107                 videocrop \
 108                 videomixer \
 109                 wavenc \
 110                 wavparse \
 111                 "
 112 AC_SUBST(GST_PLUGINS_ALL)
 113
 114 GST_PLUGINS_SELECTED=""
 115
 116 AC_ARG_WITH(plugins,
 117     AC_HELP_STRING([--with-plugins],
 118       [comma-separated list of plug-ins to compile]),
 119     [for i in `echo $withval | tr , ' '`; do
 120         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 121         then
 122             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 123         else
 124             echo "plug-in $i not recognized, ignoring..."
 125         fi
 126     done],
 127     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 128
 129 dnl disable gst plugins we might not be able to build on this
 130 dnl platform: udp and rtsp (ugly but minimally invasive)
 131 dnl FIXME: maybe move to sys
 132 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 133 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 134
 135 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 136   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/udp//`
 137   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/rtsp//`
 138 fi
 139
 140 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 141   WIN32_LIBS="-lws2_32"
 142   AC_SUBST(WIN32_LIBS)
 143 fi
 144
 145 dnl ext plug-ins; plug-ins that have external dependencies
 146 AG_GST_CHECK_FEATURE(EXTERNAL, [building of plug-ins with external deps],,
 147   [HAVE_EXTERNAL=yes], enabled,
 148   [
 149     AC_MSG_NOTICE(building external plug-ins)
 150     BUILD_EXTERNAL="yes"
 151   ],[
 152     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 153     BUILD_EXTERNAL="no"
 154   ])
 155 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 156
 157 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
 158 AG_GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
 159 [HAVE_EXPERIMENTAL=yes],disabled,
 160 [
 161   AC_MSG_WARN(building experimental plug-ins)
 162   USE_GST_V4L2="yes"
 163 ],[
 164   AC_MSG_NOTICE(not building experimental plug-ins)
 165   USE_GST_V4L2="no"
 166   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/monoscope//`
 167 ])
 168
 169 AC_SUBST(GST_PLUGINS_SELECTED)
 170
 171 dnl *** checks for platform ***
 172
 173 dnl * hardware/architecture *
 174
 175 dnl common/m4/gst-arch.m4
 176 dnl check CPU type
 177 AG_GST_ARCH
 178
 179 dnl Determine endianness
 180 AC_C_BIGENDIAN
 181
 182 dnl *** checks for programs ***
 183
 184 dnl find a compiler
 185 AC_PROG_CC
 186
 187 dnl determine c++ compiler
 188 AC_PROG_CXX
 189 dnl determine if c++ is available on this system
 190 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 191
 192 dnl determine c++ preprocessor
 193 dnl FIXME: do we need this ?
 194 AC_PROG_CXXCPP
 195
 196 AS_PROG_OBJC
 197
 198 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 199 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 200
 201 dnl check for gconftool-2
 202 dnl this macro defines an am conditional, so it needs to be run always
 203 AM_GCONF_SOURCE_2
 204
 205 dnl check for documentation tools
 206 GTK_DOC_CHECK([1.3])
 207 AS_PATH_PYTHON([2.1])
 208 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 209
 210 dnl *** checks for libraries ***
 211
 212 dnl check for libm, for sin()
 213 AC_CHECK_LIBM
 214 AC_SUBST(LIBM)
 215
 216 dnl *** checks for header files ***
 217
 218 dnl check if we have ANSI C header files
 219 AC_HEADER_STDC
 220
 221 dnl used by ext/wavpack
 222 AX_CREATE_STDINT_H
 223
 224 dnl used in gst/rtp/gstasteriskh263.c
 225 AC_CHECK_HEADERS([netinet/in.h])
 226 AC_CHECK_HEADERS([winsock2.h])
 227 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 228
 229 dnl *** checks for types/defines ***
 230
 231 dnl Check for FIONREAD ioctl declaration.  This check is needed
 232 dnl for the UDP plugin to build on Solaris
 233 GST_CHECK_FIONREAD
 234
 235 dnl *** checks for structures ***
 236
 237 dnl *** checks for compiler characteristics ***
 238
 239 dnl FIXME: check if this is used; was used for floatcast.h in base
 240 dnl Check for fast float to int casting as defined in C99
 241 AC_C99_FUNC_LRINT
 242 AC_C99_FUNC_LRINTF
 243
 244 dnl *** checks for library functions ***
 245
 246 dnl Check for mmap (needed by electricfence plugin)
 247 AC_FUNC_MMAP
 248 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 249
 250 dnl *** checks for dependency libraries ***
 251
 252 dnl GLib is required
 253 AG_GST_GLIB_CHECK([2.6])
 254
 255 dnl liboil is required
 256 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.2, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 257 if test "x${HAVE_LIBOIL}" != xyes ; then
 258   AC_ERROR([liboil-0.3 is required])
 259 fi
 260
 261 dnl checks for gstreamer
 262 dnl uninstalled is selected preferentially -- see pkg-config(1)
 263 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 264 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 265 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 266 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 267 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 268 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ])
 269
 270 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 271 if test -z $GST_TOOLS_DIR; then
 272   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 273 fi
 274 AC_SUBST(GST_TOOLS_DIR)
 275
 276 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 277 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 278
 279 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 280 dnl check for "check", unit testing library/header
 281 PKG_CHECK_MODULES(CHECK, check >= 0.9.2,
 282   AM_CONDITIONAL(HAVE_CHECK, true),
 283   AM_CONDITIONAL(HAVE_CHECK, false)
 284 )
 285 dnl Check for documentation xrefs
 286 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 287 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 288 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 289 AC_SUBST(GLIB_PREFIX)
 290 AC_SUBST(GST_PREFIX)
 291 AC_SUBST(GSTPB_PREFIX)
 292
 293 dnl GTK is optional and used in examples
 294 HAVE_GTK=NO
 295 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 296 if test "x$HAVE_GTK_22" = "xyes"; then
 297   HAVE_GTK=yes
 298   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 299   AC_SUBST(GTK_VERSION)
 300   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 301   AC_SUBST(GTK_BASE_DIR)
 302   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 303   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 304   AC_SUBST(GTK_BASE_DIR)
 305 else
 306   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 307 fi
 308 if test "x$HAVE_GTK_20" = "xyes"; then
 309   HAVE_GTK=yes
 310 fi
 311 GTK_CFLAGS=$GTK2_CFLAGS
 312 GTK_LIBS=$GTK2_LIBS
 313 AC_SUBST(GTK_LIBS)
 314 AC_SUBST(GTK_CFLAGS)
 315 AC_SUBST(HAVE_GTK)
 316 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 317
 318 dnl should we install schemas ?
 319 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 320 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 321   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 322   if test x$GCONFTOOL = xno; then
 323     AC_MSG_WARN(Not installing GConf schemas)
 324     HAVE_GCONFTOOL="no"
 325   else
 326     HAVE_GCONFTOOL="yes"
 327   fi
 328   AC_SUBST(HAVE_GCONFTOOL)
 329 ])
 330
 331 dnl *** set variables based on configure arguments ***
 332
 333 dnl set license and copyright notice
 334 GST_LICENSE="LGPL"
 335 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 336 AC_SUBST(GST_LICENSE)
 337
 338 dnl set location of plugin directory
 339 AG_GST_SET_PLUGINDIR
 340
 341 dnl define an ERROR_CFLAGS Makefile variable
 342 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 343
 344 dnl define correct level for debugging messages
 345 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 346
 347 dnl used in examples
 348 AG_GST_DEFAULT_ELEMENTS
 349
 350 dnl *** sys plug-ins ***
 351
 352 echo
 353 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 354 echo
 355
 356 dnl DirectDraw
 357 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 358 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 359   HAVE_DIRECTDRAW="no"
 360   save_CFLAGS="$CFLAGS"
 361   save_LDFLAGS="$LDFLAGS"
 362   save_LIBS="$LIBS"
 363   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 364   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 365   LIBS="$LIBS -lddraw -lgdi32"
 366   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 367   AC_LINK_IFELSE([
 368 #include <windows.h>
 369 #include <ddraw.h>
 370
 371 int main ()
 372 {
 373   GetStockObject(0);
 374   DirectDrawCreate(NULL, NULL, NULL);
 375
 376   return 0;
 377 }
 378 ],
 379     [HAVE_DIRECTDRAW="yes"],
 380     [HAVE_DIRECTDRAW="no"])
 381   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 382   CFLAGS=$save_CFLAGS
 383   LDFLAGS=$save_LDFLAGS
 384   LIBS=$save_LIBS
 385
 386   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 387     dnl this is much more than we want
 388     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 389     AC_SUBST(DIRECTDRAW_CFLAGS)
 390     AC_SUBST(DIRECTDRAW_LDFLAGS)
 391     AC_SUBST(DIRECTDRAW_LIBS)
 392   fi
 393   AC_SUBST(HAVE_DIRECTDRAW)
 394 ])
 395
 396 dnl DirectSound
 397 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 398 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 399   HAVE_DIRECTSOUND="no"
 400   save_CFLAGS="$CFLAGS"
 401   save_LDFLAGS="$LDFLAGS"
 402   save_LIBS="$LIBS"
 403   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 404   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 405   LIBS="$LIBS -ldsound -ldxerr9"
 406   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 407   AC_LINK_IFELSE([
 408 #include <windows.h>
 409 #include <dxerr9.h>
 410 #include <dsound.h>
 411
 412 int main ()
 413 {
 414   DXGetErrorString9 (0);
 415   DirectSoundCreate(NULL, NULL, NULL);
 416
 417   return 0;
 418 }
 419 ],
 420     [HAVE_DIRECTSOUND="yes"],
 421     [HAVE_DIRECTSOUND="no"])
 422   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 423   CFLAGS=$save_CFLAGS
 424   LDFLAGS=$save_LDFLAGS
 425   LIBS=$save_LIBS
 426
 427   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 428     dnl this is much more than we want
 429     DIRECTSOUND_LIBS="-ldsound -ldxerr9"
 430     AC_SUBST(DIRECTSOUND_CFLAGS)
 431     AC_SUBST(DIRECTSOUND_LDFLAGS)
 432     AC_SUBST(DIRECTSOUND_LIBS)
 433   fi
 434   AC_SUBST(HAVE_DIRECTSOUND)
 435 ])
 436
 437 dnl *** OSS audio *** (Linux, *BSD)
 438 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 439 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 440  HAVE_OSS="yes"
 441 dnl Linux and newer BSD versions :
 442  AC_CHECK_HEADER(sys/soundcard.h, [
 443    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 444    ] , [
 445 dnl Some old BSD versions and also newer OpenBSD versions :
 446    AC_CHECK_HEADER(soundcard.h, [
 447      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 448      ], [
 449   dnl Some old BSD versions :
 450      AC_CHECK_HEADER(machine/soundcard.h, [
 451        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 452          [Define if OSS includes are in /machine/])
 453        ], [
 454        HAVE_OSS="no"
 455      ])
 456    ])
 457  ])
 458 ])
 459
 460 dnl *** Sun Audio ***
 461 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 462 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 463   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 464 ])
 465
 466 dnl *** OSX Audio ***
 467 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 468 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 469   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 470 ])
 471
 472 dnl *** OS X video ***
 473 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 474 HAVE_OSX_VIDEO="no"
 475 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 476   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 477 ])
 478 dnl in case header OpenGL/gl.h is found on other platforms
 479 case "$host" in
 480   *-*darwin*)
 481     dnl do nothing
 482     ;;
 483   *)
 484     HAVE_OSX_VIDEO="no"
 485     ;;
 486 esac
 487
 488
 489 dnl *** Video 4 Linux 2 ***
 490 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 491 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 493 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 494   AC_MSG_CHECKING([Checking for uptodate v4l2 installation])
 495   AC_TRY_COMPILE([
 496 #include <sys/types.h>
 497 #include <linux/types.h>
 498 #define _LINUX_TIME_H
 499 #define __user
 500 #include <linux/videodev2.h>
 501 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 502 #error too early v4l2 version or no v4l2 at all
 503 #endif
 504     ], [
 505 return 0;
 506     ], [
 507       HAVE_GST_V4L2="yes"
 508       AC_MSG_RESULT(yes)
 509     ], [
 510       HAVE_GST_V4L2="no"
 511       AC_MSG_RESULT(no)
 512       AC_CHECK_HEADER(linux/videodev2.h,
 513       [
 514         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 515         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 516       ], [
 517         AC_MSG_WARN([video4linux2 was not found])
 518       ])
 519     ])
 520
 521   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 522     dnl check for missing v4l2_buffer declaration (see #135919)
 523     MISSING_DECL=0
 524     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 525     AC_TRY_COMPILE([
 526 #include <sys/types.h>
 527 #include <linux/types.h>
 528 #define _LINUX_TIME_H
 529 #define __user
 530 #include <linux/videodev2.h>
 531     ],[
 532 struct v4l2_buffer buf;
 533 buf.index = 0;
 534 return 0;
 535     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 536     if [ test x$MISSING_DECL = x1 ]; then
 537       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 538     fi
 539
 540     dnl check for XOverlay libraries
 541     AG_GST_CHECK_XV
 542   fi
 543 ])
 544
 545 dnl Check for X11
 546 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 547 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 548                   [ximagesrc], [
 549   AC_PATH_XTRA
 550
 551   dnl now try to find the HEADER
 552   ac_cflags_save="$CFLAGS"
 553   ac_cppflags_save="$CPPFLAGS"
 554   CFLAGS="$CFLAGS $X_CFLAGS"
 555   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 556   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 557
 558   if test "x$HAVE_X" = "xno"
 559   then
 560     AC_MSG_NOTICE([cannot find X11 development files])
 561   else
 562     dnl this is much more than we want
 563     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 564     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 565     dnl it does not add the libs; therefore we add them here
 566     X_LIBS="$X_LIBS -lX11"
 567     AC_SUBST(X_CFLAGS)
 568     AC_SUBST(X_LIBS)
 569
 570     dnl check for Xfixes
 571     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 572     if test "x$HAVE_XFIXES" = "xyes"
 573     then
 574         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 575     fi
 576     AC_SUBST(XFIXES_LIBS)
 577     AC_SUBST(XFIXES_CFLAGS)
 578
 579     dnl check for Xdamage
 580     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 581     if test "x$HAVE_XDAMAGE" = "xyes"
 582     then
 583         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 584     fi
 585     AC_SUBST(XDAMAGE_LIBS)
 586     AC_SUBST(XDAMAGE_CFLAGS)
 587   fi
 588   AC_SUBST(HAVE_X)
 589   CFLAGS="$ac_cflags_save"
 590   CPPFLAGS="$ac_cppflags_save"
 591 ])
 592
 593 dnl FIXME: this should be rolled into the test above, it's just an additional
 594 dnl feature of the ximagesrc plug-in
 595 dnl This is the same as in gst-plugins-base
 596 dnl check for X Shm
 597 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 598 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 599   if test x$HAVE_X = xyes; then
 600     AC_CHECK_LIB(Xext, XShmAttach,
 601                  HAVE_XSHM="yes", HAVE_XSHM="no",
 602                  $X_LIBS)
 603     if test "x$HAVE_XSHM" = "xyes"; then
 604       XSHM_LIBS="-lXext"
 605     else
 606       dnl On AIX, it is in XextSam instead, but we still need -lXext
 607       AC_CHECK_LIB(XextSam, XShmAttach,
 608                    HAVE_XSHM="yes", HAVE_XSHM="no",
 609                    $X_LIBS)
 610       if test "x$HAVE_XSHM" = "xyes"; then
 611         XSHM_LIBS="-lXext -lXextSam"
 612       fi
 613     fi
 614   fi
 615 ], ,[
 616   AC_SUBST(HAVE_XSHM)
 617   AC_SUBST(XSHM_LIBS)
 618 ])
 619
 620 dnl for V4L2, we also need to know if we have XVIDEO
 621 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 622 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 623                   [], [
 624   AG_GST_CHECK_XV
 625 ])
 626
 627 dnl *** ext plug-ins ***
 628 dnl keep this list sorted alphabetically !
 629
 630 if test "x$BUILD_EXTERNAL" = "xyes"; then
 631
 632 echo
 633 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 634 echo
 635
 636 dnl *** aalib ***
 637 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 638 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 639   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 640   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 641 ])
 642
 643 dnl *** annodex ***
 644 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 645 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 646   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 647 ])
 648
 649 dnl *** cairo ***
 650 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 651 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 652   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 653 ])
 654
 655 dnl *** cdio ***
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 657 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 658   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.71)
 659 ])
 660
 661 dnl **** ESound ****
 662 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 663 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 664   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 665   if test $HAVE_ESD = no
 666   then
 667     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 668     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 669   fi
 670 ])
 671
 672 dnl *** FLAC ***
 673 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 674 AC_TRY_RUN([
 675 #include <FLAC/export.h>
 676 int main () { return FLAC_API_VERSION_CURRENT<8; }
 677 ],legacy_flac=no,legacy_flac=yes,legacy_flac=no)
 678
 679 if test "x$legacy_flac" = "xyes"; then
 680 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 681   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 682   dnl API change in FLAC 1.1.1, so require that...
 683   dnl (this check will also fail with FLAC 1.1.3 which changed API again)
 684   if test x$HAVE_FLAC = xyes; then
 685     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 686                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 687 #include <FLAC/seekable_stream_encoder.h>
 688                   ])
 689   fi
 690   AC_SUBST(FLAC_LIBS)
 691 ])
 692 else
 693 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 694   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 695   dnl API change in FLAC 1.1.3, so require that...
 696   if test x$HAVE_FLAC = xyes; then
 697     AC_CHECK_DECL(FLAC__STREAM_ENCODER_TELL_STATUS_ERROR,
 698                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 699 #include <FLAC/stream_encoder.h>
 700                   ])
 701   fi
 702   AC_SUBST(FLAC_LIBS)
 703 ])
 704 fi
 705
 706 dnl *** GConf ***
 707 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 708 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 709   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 710 ])
 711
 712 dnl *** GDK pixbuf ***
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 714 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 715   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 716 ])
 717
 718 dnl *** HAL ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 720 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 721   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 722 ])
 723
 724 dnl *** jpeg ***
 725 dnl FIXME: we could use header checks here as well IMO
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 727 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 728   AC_ARG_WITH(jpeg-mmx,
 729     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 730   OLD_LIBS="$LIBS"
 731   if test x$with_jpeg_mmx != x; then
 732     LIBS="$LIBS -L$with_jpeg_mmx"
 733   fi
 734   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 735   JPEG_LIBS="$LIBS -ljpeg-mmx"
 736   LIBS="$OLD_LIBS"
 737   if test x$HAVE_JPEG != xyes; then
 738     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 739     JPEG_LIBS="-ljpeg"
 740   fi
 741   AC_SUBST(JPEG_LIBS)
 742 ])
 743
 744 dnl *** ladspa ***
 745 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 746 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 747   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 748 ], disabled)
 749
 750 dnl *** libcaca ***
 751 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 752 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 753   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 754   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 755   if test "x$HAVE_LIBCACA" != "xyes"; then
 756     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 757     dnl see if it compilation works too, might not if we are cross-compiling
 758     if test "x$HAVE_LIBCACA" = "xyes"; then
 759       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 760                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 761     fi
 762   fi
 763 ])
 764
 765 dnl *** libdv ***
 766 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 767 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 768   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 769 ])
 770
 771 dnl *** libpng ***
 772 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 773 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 774   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 775 ])
 776
 777 dnl *** dv1394 ***
 778 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 779 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 780   dnl first test for libraw1394 >= 1.2.1
 781   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 782   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 783   dnl now see how far we got
 784   if test x$HAVE_RAW1394 = xyes && \
 785      test x$HAVE_LIBIEC61883 = xyes; then
 786        AG_GST_CHECK_LIBHEADER(AVC1394,
 787         avc1394, avc1394_send_command, $RAW1394_LIBS,
 788         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 789        AG_GST_CHECK_LIBHEADER(ROM1394,
 790         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 791         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 792        if test x$HAVE_AVC1394 = xyes && \
 793           test x$HAVE_AVC1394 = xyes && \
 794           test x$HAVE_ROM1394 = xyes; then
 795           HAVE_DV1394=yes
 796           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 797           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 798           AC_SUBST(DV1394_CFLAGS)
 799           AC_SUBST(DV1394_LIBS)
 800         fi
 801   else
 802        if test x$HAVE_RAW1394 = xno; then
 803           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 804           AG_GST_CHECK_LIBHEADER(AVC1394,
 805            avc1394, avc1394_send_command, $RAW1394_LIBS,
 806            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 807           AG_GST_CHECK_LIBHEADER(ROM1394,
 808            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 809            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 810           if test x$HAVE_RAW1394 = xyes && \
 811              test x$HAVE_AVC1394 = xyes && \
 812              test x$HAVE_ROM1394 = xyes; then
 813              HAVE_DV1394=yes
 814              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 815              DV1394_CFLAGS="$RAW1394_CFLAGS"
 816              if test x$HAVE_LIBIEC61883 = xyes; then
 817                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 818                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 819              fi
 820              AC_SUBST(DV1394_CFLAGS)
 821              AC_SUBST(DV1394_LIBS)
 822            fi
 823          fi
 824   fi
 825 ])
 826
 827 dnl *** shout2 ***
 828 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 829 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 830   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 831   if test $HAVE_SHOUT2 = no
 832   then
 833     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 834     AC_SUBST(SHOUT2_CFLAGS)
 835     AC_SUBST(SHOUT2_LIBS)
 836   fi
 837 ])
 838
 839 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 840 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 841 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 842 dnl   speex_jitter.h is 1.1.x only
 843 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 844 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 845   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 846   if test $HAVE_SPEEX = no
 847   then
 848     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 849       AC_CHECK_HEADER(speex/speex_jitter.h, [
 850         dnl speex 1.1.x :
 851         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 852           dnl speex 1.1.5 or + :
 853           HAVE_SPEEX="yes"
 854           SPEEX_LIBS="-lspeex"
 855           AC_SUBST(SPEEX_CFLAGS)
 856           AC_SUBST(SPEEX_LIBS)
 857         ],[
 858           HAVE_SPEEX="no"
 859         ])
 860       ],[
 861         dnl speex 1.0.x :
 862           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 863             dnl speex 1.0.4
 864             HAVE_SPEEX="yes"
 865             SPEEX_LIBS="-lspeex"
 866             AC_SUBST(SPEEX_CFLAGS)
 867             AC_SUBST(SPEEX_LIBS)
 868
 869             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 870               [defined if speex 1.0.x API detected])
 871         ],[
 872             HAVE_SPEEX="no"
 873             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 874         ], [
 875 #include <speex/speex.h>
 876         ])
 877       ])
 878     ])
 879   fi
 880 ])
 881
 882 dnl *** taglib ***
 883 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 884 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 885   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 886   if test "x$HAVE_CXX" != "xyes"; then
 887     USE_TAGLIB=false
 888     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 889   fi
 890 ])
 891
 892 dnl *** wavpack ***
 893 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 894 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 895   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 896     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 897       HAVE_WAVPACK=yes
 898       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 899     ],[
 900       HAVE_WAVPACK=no
 901       AC_MSG_RESULT(no)
 902     ])
 903   ])
 904   AC_SUBST(WAVPACK_CFLAGS)
 905   AC_SUBST(WAVPACK_LIBS)
 906 ])
 907
 908 dnl *** qtdemux & id3demux prefer to have zlib ***
 909 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 910 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux],, [
 911   AG_GST_CHECK_LIBHEADER(ZLIB,
 912     z, uncompress,, zlib.h, [
 913     HAVE_ZLIB="yes"
 914     ZLIB_LIBS="-lz"
 915     AC_SUBST(ZLIB_LIBS)
 916   ])
 917 ])
 918
 919 else
 920
 921 dnl not building plugins with external dependencies,
 922 dnl but we still need to set the conditionals
 923 AM_CONDITIONAL(USE_GCONFTOOL, false)
 924 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 925 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 926 AM_CONDITIONAL(USE_OSS, false)
 927 AM_CONDITIONAL(USE_SUNAUDIO, false)
 928 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 929 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 930 AM_CONDITIONAL(USE_X, false)
 931 AM_CONDITIONAL(USE_XSHM, false)
 932 AM_CONDITIONAL(USE_AALIB, false)
 933 AM_CONDITIONAL(USE_ANNODEX, false)
 934 AM_CONDITIONAL(USE_CAIRO, false)
 935 AM_CONDITIONAL(USE_CDIO, false)
 936 AM_CONDITIONAL(USE_ESD, false)
 937 AM_CONDITIONAL(USE_FLAC, false)
 938 AM_CONDITIONAL(USE_GCONF, false)
 939 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 940 AM_CONDITIONAL(USE_HAL, false)
 941 AM_CONDITIONAL(USE_JPEG, false)
 942 AM_CONDITIONAL(USE_LADSPA, false)
 943 AM_CONDITIONAL(USE_LIBCACA, false)
 944 AM_CONDITIONAL(USE_LIBDV, false)
 945 AM_CONDITIONAL(USE_LIBPNG, false)
 946 AM_CONDITIONAL(USE_DV1394, false)
 947 AM_CONDITIONAL(USE_SHOUT2, false)
 948 AM_CONDITIONAL(USE_SPEEX, false)
 949 AM_CONDITIONAL(USE_TAGLIB, false)
 950 AM_CONDITIONAL(USE_WAVPACK, false)
 951 AM_CONDITIONAL(USE_ZLIB, false)
 952
 953 fi dnl of EXT plugins
 954
 955 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 956
 957 dnl Overview:
 958 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 959 dnl GST_*:              flags shared by all built objects
 960 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 961 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 962 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 963 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 964
 965 dnl GST_OPTION_CFLAGS
 966 if test "x$USE_DEBUG" = xyes; then
 967    PROFILE_CFLAGS="-g"
 968 fi
 969 AC_SUBST(PROFILE_CFLAGS)
 970
 971 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 972 AC_SUBST(DEPRECATED_CFLAGS)
 973
 974 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 975 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 976 AC_SUBST(GST_OPTION_CFLAGS)
 977
 978 dnl our libraries need to be versioned correctly
 979 AC_SUBST(GST_LT_LDFLAGS)
 980
 981 dnl FIXME: do we want to rename to GST_ALL_* ?
 982 dnl prefer internal headers to already installed ones
 983 dnl also add builddir include for enumtypes and marshal
 984 dnl add ERROR_CFLAGS, but overridable
 985 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 986 AC_SUBST(GST_CFLAGS)
 987 AC_SUBST(GST_LIBS)
 988
 989 dnl LDFLAGS really should only contain flags, not libs - they get added before
 990 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 991 GST_ALL_LDFLAGS="-no-undefined"
 992 AC_SUBST(GST_ALL_LDFLAGS)
 993
 994 dnl this really should only contain flags, not libs - they get added before
 995 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 996 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 997 AC_SUBST(GST_PLUGIN_LDFLAGS)
 998
 999 dnl *** output files ***
1000
1001 dnl keep this alphabetic per directory, please
1002 AC_CONFIG_FILES(
1003 Makefile
1004 gst/Makefile
1005 gst/alpha/Makefile
1006 gst/apetag/Makefile
1007 gst/audiofx/Makefile
1008 gst/auparse/Makefile
1009 gst/autodetect/Makefile
1010 gst/avi/Makefile
1011 gst/cutter/Makefile
1012 gst/debug/Makefile
1013 gst/effectv/Makefile
1014 gst/id3demux/Makefile
1015 gst/icydemux/Makefile
1016 gst/goom/Makefile
1017 gst/law/Makefile
1018 gst/level/Makefile
1019 gst/matroska/Makefile
1020 gst/monoscope/Makefile
1021 gst/multipart/Makefile
1022 gst/qtdemux/Makefile
1023 gst/rtp/Makefile
1024 gst/rtsp/Makefile
1025 gst/smpte/Makefile
1026 gst/udp/Makefile
1027 gst/videobox/Makefile
1028 gst/videocrop/Makefile
1029 gst/videofilter/Makefile
1030 gst/videomixer/Makefile
1031 gst/wavenc/Makefile
1032 gst/wavparse/Makefile
1033 gst/flx/Makefile
1034 ext/jpeg/Makefile
1035 ext/Makefile
1036 ext/aalib/Makefile
1037 ext/annodex/Makefile
1038 ext/cairo/Makefile
1039 ext/cdio/Makefile
1040 ext/dv/Makefile
1041 ext/esd/Makefile
1042 ext/flac/Makefile
1043 ext/gconf/Makefile
1044 ext/gdk_pixbuf/Makefile
1045 ext/hal/Makefile
1046 ext/ladspa/Makefile
1047 ext/libcaca/Makefile
1048 ext/libpng/Makefile
1049 ext/raw1394/Makefile
1050 ext/shout2/Makefile
1051 ext/speex/Makefile
1052 ext/taglib/Makefile
1053 ext/wavpack/Makefile
1054 sys/Makefile
1055 sys/directdraw/Makefile
1056 sys/directsound/Makefile
1057 sys/oss/Makefile
1058 sys/sunaudio/Makefile
1059 sys/osxaudio/Makefile
1060 sys/osxvideo/Makefile
1061 sys/v4l2/Makefile
1062 sys/waveform/Makefile
1063 sys/ximage/Makefile
1064 po/Makefile.in
1065 tests/Makefile
1066 tests/check/Makefile
1067 tests/examples/Makefile
1068 tests/examples/level/Makefile
1069 tests/files/Makefile
1070 tests/icles/Makefile
1071 gconf/Makefile
1072 gconf/gstreamer.schemas
1073 common/Makefile
1074 common/m4/Makefile
1075 m4/Makefile
1076 docs/Makefile
1077 docs/plugins/Makefile
1078 docs/version.entities
1079 win32/common/config.h
1080 pkgconfig/Makefile
1081 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1082 gst-plugins-good.spec
1083 )
1084 AC_OUTPUT
1085
1086 AG_GST_OUTPUT_PLUGINS