configure.ac

   1 dnl These m4 macros are whitespace sensitive and break if moved around much.
   2 m4_define([LU_VERSION_H], m4_include([libusb/version.h]))
   3 m4_define([LU_DEFINE_VERSION_ATOM],
   4         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   5         [^#define\s*$1\s*\([0-9]*\).*], [\1]))])
   6 m4_define([LU_DEFINE_VERSION_RC_ATOM],
   7         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   8         [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))])
   9 dnl The m4_bregexp() returns (only) the numbers following the #define named
  10 dnl in the first macro parameter. m4_define() then defines the name for use
  11 dnl in AC_INIT().
  12
  13 LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR])
  14 LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR])
  15 LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO])
  16 LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC])
  17
  18 AC_INIT([libusbx], LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC, [libusbx-devel@lists.sourceforge.net], [libusbx], [http://www.libusbx.org/])
  19
  20 # Library versioning
  21 # These numbers should be tweaked on every release. Read carefully:
  22 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  23 # http://sourceware.org/autobook/autobook/autobook_91.html
  24 lt_current="1"
  25 lt_revision="0"
  26 lt_age="1"
  27 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_CONFIG_SRCDIR([libusb/core.c])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 AM_CONFIG_HEADER([config.h])
  35 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  36
  37 AC_PREREQ([2.50])
  38 AC_PROG_CC
  39 AC_PROG_LIBTOOL
  40 LT_LANG([Windows Resource])
  41 AC_C_INLINE
  42 AM_PROG_CC_C_O
  43 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  44
  45 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  46
  47 AC_MSG_CHECKING([operating system])
  48 case $host in
  49 *-linux*)
  50         AC_DEFINE(OS_LINUX, 1, [Linux backend])
  51         AC_SUBST(OS_LINUX)
  52         AC_MSG_RESULT([Linux])
  53         backend="linux"
  54         AC_CHECK_LIB(rt, clock_gettime, PC_LIBS_PRIVATE="-lrt")
  55         threads="posix"
  56         THREAD_CFLAGS="-pthread"
  57         PC_LIBS_PRIVATE="${PC_LIBS_PRIVATE} -pthread"
  58         AC_CHECK_HEADERS([poll.h])
  59         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
  60         ;;
  61 *-darwin*)
  62         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
  63         AC_SUBST(OS_DARWIN)
  64         AC_MSG_RESULT([Darwin/Mac OS X])
  65         backend="darwin"
  66         threads="posix"
  67         PC_LIBS_PRIVATE="-lobjc -Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
  68         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
  69         AC_CHECK_HEADERS([poll.h])
  70         AC_CHECK_TYPE([nfds_t],
  71                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
  72                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
  73                 [#include <poll.h>])
  74         ;;
  75 *-openbsd*)
  76         AC_DEFINE(OS_OPENBSD, 1, [OpenBSD backend])
  77         AC_SUBST(OS_OPENBSD)
  78         AC_MSG_RESULT([OpenBSD])
  79         backend="openbsd"
  80         threads="posix"
  81         THREAD_CFLAGS="-pthread"
  82         PC_LIBS_PRIVATE="-pthread"
  83         AC_CHECK_HEADERS([poll.h])
  84         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
  85         ;;
  86 *-mingw*)
  87         AC_MSG_RESULT([Windows])
  88         backend="windows"
  89         ;;
  90 *-cygwin*)
  91         AC_MSG_RESULT([Cygwin (using Windows backend)])
  92         backend="windows"
  93         threads="posix"
  94         ;;
  95 *)
  96         AC_MSG_ERROR([unsupported operating system])
  97 esac
  98 if test "$backend" = windows; then
  99         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
 100         AC_SUBST(OS_WINDOWS)
 101         PC_LIBS_PRIVATE=""
 102         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
 103         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
 104 fi
 105 AC_SUBST(THREAD_CFLAGS)
 106 AC_SUBST(PC_LIBS_PRIVATE)
 107 LIBS="${LIBS} ${PC_LIBS_PRIVATE}"
 108
 109 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
 110 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
 111 AM_CONDITIONAL(OS_OPENBSD, test "x$backend" = xopenbsd)
 112 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
 113 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
 114 if test "$threads" = posix; then
 115         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
 116 fi
 117
 118 # timerfd
 119 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 120 AC_ARG_ENABLE([timerfd],
 121         [AS_HELP_STRING([--enable-timerfd],
 122                 [use timerfd for timing (default auto)])],
 123         [use_timerfd=$enableval], [use_timerfd='auto'])
 124
 125 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 126         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 127 fi
 128
 129 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 130 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 131         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 132 fi
 133
 134 AC_MSG_CHECKING([whether to use timerfd for timing])
 135 if test "x$use_timerfd" = "xno"; then
 136         AC_MSG_RESULT([no (disabled by user)])
 137 else
 138         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 139                 AC_MSG_RESULT([yes])
 140                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 141         else
 142                 AC_MSG_RESULT([no (header not available)])
 143         fi
 144 fi
 145
 146 AC_CHECK_TYPES(struct timespec)
 147
 148 # Message logging
 149 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 150         [log_enabled=$enableval],
 151         [log_enabled='yes'])
 152 if test "x$log_enabled" != "xno"; then
 153         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 154 fi
 155
 156 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 157         [enable debug logging (default n)])],
 158         [debug_log_enabled=$enableval],
 159         [debug_log_enabled='no'])
 160 if test "x$debug_log_enabled" != "xno"; then
 161         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
 162 fi
 163
 164 # Examples build
 165 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 166         [build example applications (default n)])],
 167         [build_examples=$enableval],
 168         [build_examples='no'])
 169 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 170
 171 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 172 saved_cflags="$CFLAGS"
 173 # -Werror required for cygwin
 174 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 175 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 176         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 177          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 178         [ VISIBILITY_CFLAGS=""
 179          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 180         ])
 181 CFLAGS="$saved_cflags"
 182
 183 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 184 saved_cflags="$CFLAGS"
 185 CFLAGS="$CFLAGS -Wno-pointer-sign"
 186 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 187         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 188 CFLAGS="$saved_cflags"
 189
 190 # sigaction not available on MinGW
 191 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 192 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 193
 194 # headers not available on all platforms but required on others
 195 AC_CHECK_HEADERS([sys/time.h])
 196
 197 AM_CFLAGS="-std=gnu99 -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
 198
 199 AC_SUBST(VISIBILITY_CFLAGS)
 200 AC_SUBST(AM_CFLAGS)
 201 AC_SUBST(LTLDFLAGS)
 202
 203 AC_CONFIG_FILES([libusb-1.0.pc])
 204 AC_CONFIG_FILES([Makefile])
 205 AC_CONFIG_FILES([libusb/Makefile])
 206 AC_CONFIG_FILES([examples/Makefile])
 207 AC_CONFIG_FILES([doc/Makefile])
 208 AC_CONFIG_FILES([doc/doxygen.cfg])
 209 AC_OUTPUT