configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.1.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 26, 0, 0)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.11.1
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.3])
 161 AS_PATH_PYTHON([2.1])
 162 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 AC_CHECK_LIBM
 168 AC_SUBST(LIBM)
 169
 170 dnl *** checks for header files ***
 171
 172 dnl check if we have ANSI C header files
 173 AC_HEADER_STDC
 174
 175 ac_cppflags_save="$CPPFLAGS"
 176 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 177 AC_COMPILE_IFELSE(
 178   AC_LANG_PROGRAM([
 179 #include <libxml/HTMLparser.h>
 180                      ],[
 181 #ifndef LIBXML_HTML_ENABLED
 182 #error libxml2 has no HTML support
 183 #endif /* LIBXML_HTML_ENABLED */
 184                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 185 CPPFLAGS="$ac_cppflags_save"
 186 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 187
 188 dnl used in gst-libs/gst/pbutils and associated unit test
 189 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 190
 191 dnl also, Windows does not have long long
 192 AX_CREATE_STDINT_H
 193
 194 dnl *** checks for functions ***
 195 AC_CHECK_FUNCS([localtime_r gmtime_r])
 196
 197 dnl *** checks for math functions ***
 198 LIBS_SAVE=$LIBS
 199 LIBS="$LIBS $LIBM"
 200 AC_CHECK_FUNCS(log2)
 201 LIBS=$LIBS_SAVE
 202
 203 dnl *** checks for types/defines ***
 204
 205 dnl *** checks for structures ***
 206
 207 dnl *** checks for compiler characteristics ***
 208
 209 dnl *** checks for library functions ***
 210
 211 dnl check for fseeko()
 212 AC_FUNC_FSEEKO
 213
 214 dnl Check for fast float to int casting as defined in C99
 215 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 216 save_libs=$LIBS
 217 LIBS="$LIBS $LIBM"
 218 AC_C99_FUNC_LRINT
 219 AC_C99_FUNC_LRINTF
 220 LIBS=$save_libs
 221
 222 dnl Check for a way to display the function name in debug output
 223 AG_GST_CHECK_FUNCTION
 224
 225 dnl *** checks for dependency libraries ***
 226
 227 dnl GLib
 228 GLIB_REQ=2.31.10
 229 AG_GST_GLIB_CHECK([$GLIB_REQ])
 230
 231 ORC_CHECK([0.4.11])
 232
 233 dnl checks for gstreamer
 234 dnl uninstalled is selected preferentially -- see pkg-config(1)
 235 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 236 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 237 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 238 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 239 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 240
 241 dnl Check for documentation xrefs
 242 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 243 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 244 AC_SUBST(GLIB_PREFIX)
 245 AC_SUBST(GST_PREFIX)
 246
 247 dnl GTK is optional and only used in examples
 248 HAVE_GTK=no
 249 HAVE_GTK_X11=no
 250 GTK_REQ=3.0.0
 251 if test "x$BUILD_EXAMPLES" = "xyes"; then
 252   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 253   dnl some examples need gtk+-x11
 254   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 255   AC_SUBST(GTK_LIBS)
 256   AC_SUBST(GTK_CFLAGS)
 257 fi
 258 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 259 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 260
 261 dnl QT is optional and only used in examples
 262 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 263   HAVE_QT_GV=yes
 264   HAVE_QT=yes
 265 ], [
 266   HAVE_QT_GV=no
 267   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 268 ])
 269 if test "x$HAVE_QT" = "xyes"; then
 270   AC_MSG_CHECKING([Qt moc])
 271   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 272   AC_MSG_RESULT($QT4_MOC)
 273   AC_SUBST(QT4_MOC)
 274 fi
 275 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 276 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 277
 278 dnl chck for linux headers needed by the joystick seek example
 279 AC_COMPILE_IFELSE(
 280 [
 281   AC_LANG_PROGRAM([
 282     #include <linux/input.h>
 283     #include <linux/joystick.h>
 284   ],[
 285     struct js_event js;
 286     js.type = JS_EVENT_AXIS;
 287   ])
 288 ], [
 289   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 290 ], [
 291   HAVE_LINUX_JOYSTICK_HEADERS="no"
 292 ])
 293 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 294
 295 dnl Check for -Bsymbolic-functions linker flag used to avoid
 296 dnl intra-library PLT jumps, if available.
 297 AC_ARG_ENABLE(Bsymbolic,
 298               [AC_HELP_STRING([--disable-Bsymbolic],
 299                               [avoid linking with -Bsymbolic])],,
 300               [SAVED_LDFLAGS="${LDFLAGS}"
 301                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 302                LDFLAGS=-Wl,-Bsymbolic-functions
 303                AC_TRY_LINK([], [int main (void) { return 0; }],
 304                            AC_MSG_RESULT(yes)
 305                            enable_Bsymbolic=yes,
 306                            AC_MSG_RESULT(no)
 307                            enable_Bsymbolic=no)
 308                LDFLAGS="${SAVED_LDFLAGS}"])
 309
 310
 311 dnl *** set variables based on configure arguments ***
 312
 313 dnl set license and copyright notice
 314 GST_LICENSE="LGPL"
 315 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 316 AC_SUBST(GST_LICENSE)
 317
 318 dnl set location of plugin directory
 319 AG_GST_SET_PLUGINDIR
 320
 321 dnl set release date/time
 322 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 323   ["${srcdir}/gst-plugins-base.doap"],
 324   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 325
 326 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 327 dnl make sure it doesn't complain about unused variables if debugging is disabled
 328 NO_WARNINGS=""
 329 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 330
 331 dnl define an ERROR_CFLAGS Makefile variable
 332 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 333 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 334     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 335     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 336     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 337     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 338
 339 dnl define an ERROR_CXXFLAGS Makefile variable
 340 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 341     -Wmissing-declarations -Wredundant-decls -Wundef
 342     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 343     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 344     -Wno-multichar $NO_WARNINGS])
 345
 346 dnl define correct level for debugging messages
 347 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 348
 349 dnl used in examples
 350 AG_GST_DEFAULT_ELEMENTS
 351
 352 dnl needed for encoding-target
 353 GST_DATADIR="$GST_PREFIX/share"
 354 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 355 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 356
 357 dnl behaviour of speex based audio resampler
 358 AC_MSG_CHECKING(which audio resample format to use for integer)
 359 AC_ARG_WITH([audioresample_format],
 360         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 361         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 362 AC_MSG_RESULT($ac_cv_audioresample_format)
 363 case $ac_cv_audioresample_format in
 364   int)
 365     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 366     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 367   ;;
 368   float)
 369     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 370     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 371   ;;
 372   auto)
 373     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 374     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 375 esac
 376
 377 dnl *** plug-ins to include ***
 378
 379 dnl these are all the gst plug-ins, compilable without additional libs
 380 AG_GST_CHECK_PLUGIN(adder)
 381 AG_GST_CHECK_PLUGIN(app)
 382 AG_GST_CHECK_PLUGIN(audioconvert)
 383 AG_GST_CHECK_PLUGIN(audiorate)
 384 AG_GST_CHECK_PLUGIN(audiotestsrc)
 385 AG_GST_CHECK_PLUGIN(encoding)
 386 AG_GST_CHECK_PLUGIN(videoconvert)
 387 AG_GST_CHECK_PLUGIN(gdp)
 388 AG_GST_CHECK_PLUGIN(gio)
 389 AG_GST_CHECK_PLUGIN(playback)
 390 AG_GST_CHECK_PLUGIN(audioresample)
 391 AG_GST_CHECK_PLUGIN(subparse)
 392 AG_GST_CHECK_PLUGIN(tcp)
 393 AG_GST_CHECK_PLUGIN(typefind)
 394 AG_GST_CHECK_PLUGIN(videotestsrc)
 395 AG_GST_CHECK_PLUGIN(videorate)
 396 AG_GST_CHECK_PLUGIN(videoscale)
 397 AG_GST_CHECK_PLUGIN(volume)
 398
 399 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 400 AM_CONDITIONAL(USE_XML, false)
 401 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 402
 403 dnl disable plug-ins that require libxml2's HTML support if it is not available
 404 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 405   AG_GST_DISABLE_PLUGIN(subparse)
 406 fi
 407
 408 dnl iso-codes is optional, used by libgsttag
 409 AC_ARG_ENABLE(iso-codes,
 410 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 411 [case "${enableval}" in
 412   yes) enable_iso_codes=yes ;;
 413   no)  enable_iso_codes=no ;;
 414   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 415 esac
 416 ],
 417 [enable_iso_codes=yes]) dnl Default value
 418
 419 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 420 if test "x$enable_iso_codes" = "xyes"; then
 421   AC_MSG_RESULT([yes])
 422   have_iso_codes=no
 423   AC_MSG_CHECKING([whether iso-codes are available on this system])
 424   if $PKG_CONFIG iso-codes; then
 425     AC_MSG_RESULT([yes])
 426     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 427     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 428       AC_MSG_RESULT([yes])
 429       AC_MSG_CHECKING([for iso-codes prefix])
 430       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 431       if test -d "$ISO_CODES_PREFIX"; then
 432         AC_MSG_RESULT([yes])
 433         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 434         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 435         ISO_639_DOMAIN="iso_639"
 436         AC_MSG_CHECKING([ISO_639_DOMAIN])
 437         AC_MSG_RESULT([$ISO_639_DOMAIN])
 438         have_iso_codes=yes
 439         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 440         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 441         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 442         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 443       else
 444         AC_MSG_RESULT([no])
 445       fi
 446     else
 447       AC_MSG_RESULT([no])
 448     fi
 449   else
 450     AC_MSG_RESULT([no])
 451   fi
 452   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 453 else
 454   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 455   AM_CONDITIONAL(USE_ISO_CODES, false)
 456 fi
 457
 458 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 459 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 460 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 461   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 462       HAVE_ZLIB="yes"
 463     ], [
 464       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 465         HAVE_ZLIB="yes"
 466         ZLIB_LIBS="-lz"
 467         AC_SUBST(ZLIB_LIBS)
 468       ])
 469     ])
 470 ])
 471
 472 dnl *** sys plug-ins ***
 473
 474 echo
 475 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 476 echo
 477
 478 dnl *** X11 ***
 479 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 480 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 481                   [ximagesink], [
 482   AC_PATH_XTRA
 483   ac_cflags_save="$CFLAGS"
 484   ac_cppflags_save="$CPPFLAGS"
 485   CFLAGS="$CFLAGS $X_CFLAGS"
 486   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 487
 488   dnl now try to find the HEADER
 489   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 490
 491   if test "x$HAVE_X" = "xno"
 492   then
 493     AC_MSG_NOTICE([cannot find X11 development files])
 494   else
 495     dnl this is much more than we want
 496     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 497     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 498     dnl it does not add the libs; therefore we add them here
 499     X_LIBS="$X_LIBS -lX11"
 500     AC_SUBST(X_CFLAGS)
 501     AC_SUBST(X_LIBS)
 502   fi
 503   AC_SUBST(HAVE_X)
 504   CFLAGS="$ac_cflags_save"
 505   CPPFLAGS="$ac_cppflags_save"
 506 ])
 507
 508 dnl Check for Xv extension
 509 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 510 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 511                   [xvimagesink], [
 512   AG_GST_CHECK_XV
 513 ])
 514
 515 dnl check for X Shm
 516 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 517 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 518   if test x$HAVE_X = xyes; then
 519     AC_CHECK_LIB(Xext, XShmAttach,
 520                  HAVE_XSHM="yes", HAVE_XSHM="no",
 521                  $X_LIBS)
 522     if test "x$HAVE_XSHM" = "xyes"; then
 523       XSHM_LIBS="-lXext"
 524     else
 525       dnl On AIX, it is in XextSam instead, but we still need -lXext
 526       AC_CHECK_LIB(XextSam, XShmAttach,
 527                    HAVE_XSHM="yes", HAVE_XSHM="no",
 528                    $X_LIBS)
 529       if test "x$HAVE_XSHM" = "xyes"; then
 530         XSHM_LIBS="-lXext -lXextSam"
 531       fi
 532     fi
 533   fi
 534 ], , [
 535   AC_SUBST(HAVE_XSHM)
 536   AC_SUBST(XSHM_LIBS)
 537 ])
 538
 539 dnl *** ext plug-ins ***
 540 dnl keep this list sorted alphabetically !
 541
 542 if test "x$BUILD_EXTERNAL" = "xyes"; then
 543
 544 echo
 545 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 546 echo
 547
 548 dnl *** alsa ***
 549 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 550 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 551   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 552     HAVE_ALSA="yes"
 553     AC_SUBST(ALSA_CFLAGS)
 554     AC_SUBST(ALSA_LIBS)
 555   ], [
 556     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 557   ])
 558 ])
 559
 560 dnl *** CDParanoia ***
 561 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 562 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 563 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 564   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 565     HAVE_CDPARANOIA="yes"
 566   ], [
 567     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 568                         cdda_open, -lm,
 569                         cdda_interface.h,
 570                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 571                         HEADER_DIR="no"
 572                         FOUND_CDPARANOIA="yes")
 573     if test "x$FOUND_CDPARANOIA" != "xyes";
 574     then
 575       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 576                           cdda_open, -lm,
 577                           cdda/cdda_interface.h,
 578                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 579                           HEADER_DIR="yes"
 580                           FOUND_CDPARANOIA="yes")
 581     fi
 582     if test "x$HEADER_DIR" = "xyes";
 583     then
 584       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 585                          defined if cdda headers are in a cdda/ directory)
 586     fi
 587     if test "x$FOUND_CDPARANOIA" = "xyes";
 588     then
 589       AC_CHECK_LIB(cdda_paranoia,
 590                    paranoia_cachemodel_size,
 591                    : ,
 592                    HAVE_CDPARANOIA=no,
 593                  [-lcdda_interface])
 594     fi
 595
 596     AC_SUBST(CDPARANOIA_LIBS)
 597   ])
 598 ])
 599 dnl FIXME : add second check somehow if that is necessary
 600 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 601 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 602
 603 dnl *** ivorbis ***
 604 dnl AM_PATH_IVORBIS only takes two options
 605 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 606 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 607   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 608   if test $HAVE_IVORBIS = no
 609   then
 610     IVORBIS_LIBS=
 611     IVORBIS_CFLAGS=
 612     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 613       [IVORBIS_LIBS=-lvorbisidec
 614       HAVE_IVORBIS=yes
 615       case $host in
 616       arm-*-*)
 617         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 618       esac
 619       ],
 620       HAVE_IVORBIS=no)
 621     AC_SUBST(IVORBIS_LIBS)
 622     AC_SUBST(IVORBIS_CFLAGS)
 623   else
 624     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 625       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 626       USE_TREMOLO=no)
 627   fi
 628 ])
 629
 630 dnl *** libvisual ***
 631 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 632 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 633   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 634   if test $HAVE_LIBVISUAL = no
 635   then
 636     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 637     if test x$HAVE_LIBVISUAL = xyes; then
 638       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 639     fi
 640   else
 641     if test x$HAVE_LIBVISUAL = xyes; then
 642       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 643     fi
 644   fi
 645   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 646   if test x$LIBVIS_PLUGINSDIR != x; then
 647     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 648         "$LIBVIS_PLUGINSDIR",
 649         [directory in which the detected libvisual's plugins are located])
 650   fi
 651 ])
 652
 653 dnl *** ogg ***
 654 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 655 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 656   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 657   if test $HAVE_OGG = no
 658   then
 659     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 660     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 661   fi
 662 ])
 663
 664 dnl *** pango ***
 665 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 666 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 667   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 668 ])
 669
 670 dnl *** theora ***
 671 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 672 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 673   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 674 ])
 675
 676 dnl *** vorbis ***
 677 dnl AM_PATH_VORBIS only takes two options
 678 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 679 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 680   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 681   if test $HAVE_VORBIS = no
 682   then
 683     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 684     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 685   fi
 686 ])
 687
 688 if test "x$HAVE_VORBIS" = "xyes"; then
 689   ac_cflags_save="$CFLAGS"
 690   AC_COMPILE_IFELSE(
 691     AC_LANG_PROGRAM([
 692 #include <vorbis/codec.h>
 693                      ],[
 694 vorbis_dsp_state *v;
 695
 696 vorbis_synthesis_restart (v);
 697                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 698   if test "x$HAVE_VSR" = "xyes"; then
 699     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 700                        [defined if vorbis_synthesis_restart is present])
 701   fi
 702   CFLAGS="$ac_cflags_save"
 703 fi
 704
 705 else
 706
 707 dnl not building plugins with external dependencies,
 708 dnl but we still need to set the conditionals
 709 AM_CONDITIONAL(USE_ALSA, false)
 710 AM_CONDITIONAL(USE_CDPARANOIA, false)
 711 AM_CONDITIONAL(USE_IVORBIS, false)
 712 AM_CONDITIONAL(USE_LIBVISUAL, false)
 713 AM_CONDITIONAL(USE_OGG, false)
 714 AM_CONDITIONAL(USE_PANGO, false)
 715 AM_CONDITIONAL(USE_THEORA, false)
 716 AM_CONDITIONAL(USE_VORBIS, false)
 717
 718 fi dnl of EXT plugins
 719
 720 dnl seeking needs freetype, so check for it here
 721 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 722   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 723 ])
 724 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 725 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 726 AC_SUBST(FT2_CFLAGS)
 727 AC_SUBST(FT2_LIBS)
 728
 729 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 730
 731 dnl Overview:
 732 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 733 dnl GST_*:              flags shared by built objects to link against GStreamer
 734 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 735 dnl                          (compare to other modules) or for i18n
 736 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 737 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 738 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 739 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 740
 741 dnl GST_OPTION_CFLAGS
 742 if test "x$USE_DEBUG" = xyes; then
 743    PROFILE_CFLAGS="-g"
 744 fi
 745 AC_SUBST(PROFILE_CFLAGS)
 746
 747 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 748   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 749   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 750 else
 751   DEPRECATED_CFLAGS=""
 752 fi
 753 AC_SUBST(DEPRECATED_CFLAGS)
 754
 755 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 756 dnl at make time with e.g. make ERROR_CFLAGS=""
 757 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 758 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 759 AC_SUBST(GST_OPTION_CFLAGS)
 760 AC_SUBST(GST_OPTION_CXXFLAGS)
 761
 762 dnl our libraries need to be versioned correctly
 763 AC_SUBST(GST_LT_LDFLAGS)
 764
 765 dnl GST_PLUGINS_BASE_CFLAGS
 766 dnl prefer internal headers to already installed ones
 767 dnl also add builddir include for enumtypes and marshal
 768 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 769 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 770
 771 dnl FIXME: do we want to rename to GST_ALL_* ?
 772 dnl add GST_OPTION_CFLAGS, but overridable
 773 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 774 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 775 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 776 AC_SUBST(GST_CFLAGS)
 777 AC_SUBST(GST_CXXFLAGS)
 778 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 779 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 780 AC_SUBST(GST_LIBS)
 781
 782 dnl LDFLAGS really should only contain flags, not libs - they get added before
 783 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 784 GST_ALL_LDFLAGS="-no-undefined"
 785 if test "x${enable_Bsymbolic}" = "xyes"; then
 786   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 787 fi
 788 AC_SUBST(GST_ALL_LDFLAGS)
 789
 790 dnl GST_LIB_LDFLAGS
 791 dnl linker flags shared by all libraries
 792 dnl LDFLAGS modifier defining exported symbols from built libraries
 793 dnl (export _gst_foo but not __gst_foo)
 794 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 795 AC_SUBST(GST_LIB_LDFLAGS)
 796
 797 dnl this really should only contain flags, not libs - they get added before
 798 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 799 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 800 AC_SUBST(GST_PLUGIN_LDFLAGS)
 801
 802 dnl *** output files ***
 803
 804 AC_CONFIG_FILES(
 805 Makefile
 806 gst-plugins-base.spec
 807 gst/Makefile
 808 gst/adder/Makefile
 809 gst/app/Makefile
 810 gst/audioconvert/Makefile
 811 gst/audiorate/Makefile
 812 gst/audiotestsrc/Makefile
 813 gst/encoding/Makefile
 814 gst/videoconvert/Makefile
 815 gst/gdp/Makefile
 816 gst/gio/Makefile
 817 gst/playback/Makefile
 818 gst/audioresample/Makefile
 819 gst/subparse/Makefile
 820 gst/tcp/Makefile
 821 gst/typefind/Makefile
 822 gst/videotestsrc/Makefile
 823 gst/videorate/Makefile
 824 gst/videoscale/Makefile
 825 gst/volume/Makefile
 826 sys/Makefile
 827 sys/ximage/Makefile
 828 sys/xvimage/Makefile
 829 ext/Makefile
 830 ext/alsa/Makefile
 831 ext/cdparanoia/Makefile
 832 ext/libvisual/Makefile
 833 ext/ogg/Makefile
 834 ext/pango/Makefile
 835 ext/theora/Makefile
 836 ext/vorbis/Makefile
 837 gst-libs/Makefile
 838 gst-libs/gst/Makefile
 839 gst-libs/gst/audio/Makefile
 840 gst-libs/gst/app/Makefile
 841 gst-libs/gst/fft/Makefile
 842 gst-libs/gst/interfaces/Makefile
 843 gst-libs/gst/riff/Makefile
 844 gst-libs/gst/rtp/Makefile
 845 gst-libs/gst/rtsp/Makefile
 846 gst-libs/gst/sdp/Makefile
 847 gst-libs/gst/tag/Makefile
 848 gst-libs/gst/pbutils/Makefile
 849 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 850 gst-libs/gst/video/Makefile
 851 tools/Makefile
 852 pkgconfig/Makefile
 853 pkgconfig/gstreamer-audio.pc
 854 pkgconfig/gstreamer-audio-uninstalled.pc
 855 pkgconfig/gstreamer-app.pc
 856 pkgconfig/gstreamer-app-uninstalled.pc
 857 pkgconfig/gstreamer-fft.pc
 858 pkgconfig/gstreamer-fft-uninstalled.pc
 859 pkgconfig/gstreamer-interfaces.pc
 860 pkgconfig/gstreamer-interfaces-uninstalled.pc
 861 pkgconfig/gstreamer-pbutils.pc
 862 pkgconfig/gstreamer-pbutils-uninstalled.pc
 863 pkgconfig/gstreamer-riff.pc
 864 pkgconfig/gstreamer-riff-uninstalled.pc
 865 pkgconfig/gstreamer-rtp.pc
 866 pkgconfig/gstreamer-rtp-uninstalled.pc
 867 pkgconfig/gstreamer-rtsp.pc
 868 pkgconfig/gstreamer-rtsp-uninstalled.pc
 869 pkgconfig/gstreamer-sdp.pc
 870 pkgconfig/gstreamer-sdp-uninstalled.pc
 871 pkgconfig/gstreamer-tag.pc
 872 pkgconfig/gstreamer-tag-uninstalled.pc
 873 pkgconfig/gstreamer-video.pc
 874 pkgconfig/gstreamer-video-uninstalled.pc
 875 pkgconfig/gstreamer-plugins-base.pc
 876 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 877 tests/Makefile
 878 tests/check/Makefile
 879 tests/examples/Makefile
 880 tests/examples/app/Makefile
 881 tests/examples/audio/Makefile
 882 tests/examples/dynamic/Makefile
 883 tests/examples/encoding/Makefile
 884 tests/examples/fft/Makefile
 885 tests/examples/gio/Makefile
 886 tests/examples/overlay/Makefile
 887 tests/examples/seek/Makefile
 888 tests/examples/snapshot/Makefile
 889 tests/examples/playrec/Makefile
 890 tests/files/Makefile
 891 tests/icles/Makefile
 892 tests/icles/playback/Makefile
 893 docs/Makefile
 894 docs/design/Makefile
 895 docs/libs/Makefile
 896 docs/plugins/Makefile
 897 docs/version.entities
 898 po/Makefile.in
 899 common/Makefile
 900 common/m4/Makefile
 901 m4/Makefile
 902 )
 903
 904 dnl Create the config.h file for Visual Studio builds
 905 dnl Beware of spaces and /'s in some of the shell variable contents.
 906 sed \
 907     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 908     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 909     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 910     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 911     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 912     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 913     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 914     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 915     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 916     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 917     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 918     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 919     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 920     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 921     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 922     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 923     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 924     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 925     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 926     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 927     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 928     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 929     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 930     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 931     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 932     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 933     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 934     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 935     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 936     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 937     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 938     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 939     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 940     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 941     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 942     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 943     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 944     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 945     config.h.in >win32/common/config.h-new
 946
 947
 948
 949 AC_OUTPUT
 950
 951 AG_GST_OUTPUT_PLUGINS
 952 ORC_OUTPUT
 953