configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [39])
  34 m4_define([glib_micro_version], [2])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 dnl
 121
 122 AC_MSG_CHECKING([for Win32])
 123 LIB_EXE_MACHINE_FLAG=X86
 124 case "$host" in
 125   *-*-mingw*)
 126     glib_native_win32=yes
 127     glib_pid_type='void *'
 128     glib_cv_stack_grows=no
 129     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 130     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 131     # (Sorry, I don't know exactly what is the problem, but it is related to
 132     # floating point formatting and decimal point vs. comma.)
 133     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 134     # rigorous enough to notice, though.
 135     # So preset the autoconf cache variables.
 136     ac_cv_func_vsnprintf_c99=no
 137     ac_cv_func_snprintf_c99=no
 138     case "$host" in
 139     x86_64-*-*)
 140       LIB_EXE_MACHINE_FLAG=X64
 141       ;;
 142     esac
 143
 144     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 145     ;;
 146   *)
 147     glib_native_win32=no
 148     glib_pid_type=int
 149     ;;
 150 esac
 151 case $host in
 152   *-*-linux*)
 153     glib_os_linux=yes
 154     ;;
 155 esac
 156
 157 AC_MSG_RESULT([$glib_native_win32])
 158
 159 AC_MSG_CHECKING([for the Android])
 160 case $host in
 161   *android*)
 162     glib_native_android="yes"
 163     ;;
 164   *)
 165     glib_native_android="no"
 166     ;;
 167 esac
 168 AC_MSG_RESULT([$glib_native_android])
 169
 170 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 171
 172 glib_have_carbon=no
 173 AC_MSG_CHECKING([for Mac OS X Carbon support])
 174 AC_TRY_CPP([
 175 #include <Carbon/Carbon.h>
 176 #include <CoreServices/CoreServices.h>
 177 ], glib_have_carbon=yes)
 178
 179 AC_MSG_RESULT([$glib_have_carbon])
 180
 181 glib_have_cocoa=no
 182 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 183 AC_TRY_CPP([
 184 #include <Cocoa/Cocoa.h>
 185 #ifdef GNUSTEP_BASE_VERSION
 186 #error "Detected GNUstep, not Cocoa"
 187 #endif
 188 ], glib_have_cocoa=yes)
 189
 190 AC_MSG_RESULT([$glib_have_cocoa])
 191
 192 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 193 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 194 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 195 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 196 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 197 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 198
 199 AS_IF([test "$glib_native_win32" = "yes"], [
 200   AC_CHECK_TOOL(WINDRES, windres, no)
 201   if test "$WINDRES" = no; then
 202     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 203   fi
 204   AC_CHECK_TOOL(NM, nm, no)
 205   if test "$NM" = no; then
 206     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 207   fi
 208   AC_CHECK_TOOL(RANLIB, ranlib, :)
 209   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 210   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 211 ])
 212 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 213
 214 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 215   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 216   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 217 ])
 218
 219 if test "x$glib_have_cocoa" = "xyes"; then
 220   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 221   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 222 fi
 223
 224 dnl declare --enable-* args and collect ac_help strings
 225 AC_ARG_ENABLE(debug,
 226               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 227                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 228               enable_debug=glib_debug_default)
 229
 230 AC_ARG_ENABLE(gc_friendly,
 231               [AS_HELP_STRING([--enable-gc-friendly],
 232                               [turn on garbage collector friendliness [default=no]])],,
 233               [enable_gc_friendly=no])
 234 AC_ARG_ENABLE(mem_pools,
 235               [AS_HELP_STRING([--disable-mem-pools],
 236                               [disable all glib memory pools])],,
 237               [disable_mem_pools=no])
 238 AC_ARG_ENABLE(rebuilds,
 239               [AS_HELP_STRING([--disable-rebuilds],
 240                               [disable all source autogeneration rules])],,
 241               [enable_rebuilds=yes])
 242
 243 GLIB_TESTS
 244
 245 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 246 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 247   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 248   AC_MSG_RESULT([yes])
 249 ], [ AC_MSG_RESULT([no]) ])
 250
 251 AC_MSG_CHECKING([whether to disable memory pools])
 252 AS_IF([test "x$disable_mem_pools" = "xno"], [
 253   AC_MSG_RESULT([no])
 254 ], [
 255   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 256   AC_MSG_RESULT([yes])
 257 ])
 258
 259 dnl location to install runtime libraries, e.g. ../../lib to install
 260 dnl to /lib if libdir is /usr/lib
 261 AC_ARG_WITH(runtime-libdir,
 262            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 263                            [install runtime libraries relative to libdir])],
 264            [],
 265            [with_runtime_libdir=""])
 266 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 267 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 268 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 269 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 270 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 271
 272 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 273 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 274 AC_LANG_SAVE
 275 AC_LANG_CPLUSPLUS
 276 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 277 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 278 AC_LANG_RESTORE
 279
 280 AM_PROG_CC_C_O
 281 AC_PROG_INSTALL
 282
 283 AC_SYS_LARGEFILE
 284
 285 PKG_PROG_PKG_CONFIG(0.16)
 286
 287 if test "x$enable_debug" = "xyes"; then
 288   if test x$cflags_set != xset ; then
 289       case " $CFLAGS " in
 290       *[[\ \    ]]-g[[\ \       ]]*) ;;
 291       *) CFLAGS="$CFLAGS -g" ;;
 292       esac
 293   fi
 294   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 295 else
 296   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 297
 298   if test "x$enable_debug" = "xno"; then
 299     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 300   fi
 301 fi
 302
 303 # Ensure MSVC-compatible struct packing convention is used when
 304 # compiling for Win32 with gcc.
 305 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 306 # gcc2 uses "-fnative-struct".
 307 if test x"$glib_native_win32" = xyes; then
 308   if test x"$GCC" = xyes; then
 309     msnative_struct=''
 310     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 311     if test -z "$ac_cv_prog_CC"; then
 312       our_gcc="$CC"
 313     else
 314       our_gcc="$ac_cv_prog_CC"
 315     fi
 316     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 317       2.)
 318         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 319           msnative_struct='-fnative-struct'
 320         fi
 321         ;;
 322       *)
 323         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 324           msnative_struct='-mms-bitfields'
 325         fi
 326         ;;
 327     esac
 328     if test x"$msnative_struct" = x ; then
 329       AC_MSG_RESULT([no way])
 330       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 331     else
 332       CFLAGS="$CFLAGS $msnative_struct"
 333       AC_MSG_RESULT([${msnative_struct}])
 334     fi
 335   fi
 336 fi
 337 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 338 AC_SUBST(GLIB_EXTRA_CFLAGS)
 339
 340 AC_EXEEXT
 341
 342 # define a MAINT-like variable REBUILD which is set if Perl
 343 # and awk are found, so autogenerated sources can be rebuilt
 344 AC_PROG_AWK
 345 AC_CHECK_PROGS(PERL, [perl5 perl])
 346 # We would like indent, but don't require it.
 347 AC_CHECK_PROG(INDENT, indent, indent)
 348 REBUILD=\#
 349 if test "x$enable_rebuilds" = "xyes" && \
 350      test -n "$PERL" && \
 351      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 352      test -n "$AWK" ; then
 353   REBUILD=
 354 fi
 355 AC_SUBST(REBUILD)
 356
 357 # Need full path to Perl for glib-mkenums
 358 #
 359 if test "x$PERL" != x ; then
 360   AC_PATH_PROG(PERL_PATH, [$PERL])
 361 fi
 362 if test "x$PERL_PATH" = x ; then
 363   PERL_PATH="/usr/bin/env perl"
 364 fi
 365 AC_SUBST(PERL_PATH)
 366
 367 # option to specify python interpreter to use; this just sets $PYTHON, so that
 368 # we will fallback to reading $PYTHON if --with-python is not given, and
 369 # python.m4 will get the expected input
 370 AC_ARG_WITH(python,
 371             AS_HELP_STRING([--with-python=PATH],
 372                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 373             [PYTHON="$withval"], [])
 374 if test x"$PYTHON" = xyes; then
 375   AC_MSG_ERROR([--with-python option requires a path or program argument])
 376 fi
 377 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 378
 379
 380 dnl ***********************
 381 dnl *** Tests for iconv ***
 382 dnl ***********************
 383 dnl
 384 dnl We do this before the gettext checks, to avoid distortion
 385
 386 dnl On Windows we use a native implementation
 387
 388 AS_IF([ test x"$glib_native_win32" = xyes], [
 389   with_libiconv=native
 390 ], [
 391   AC_ARG_WITH(libiconv,
 392               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 393                               [use the libiconv library])],,
 394               [with_libiconv=maybe])
 395
 396   found_iconv=no
 397   case $with_libiconv in
 398     maybe)
 399       # Check in the C library first
 400       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 401       # Check if we have GNU libiconv
 402       if test $found_iconv = "no"; then
 403         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 404       fi
 405       # Check if we have a iconv in -liconv, possibly from vendor
 406       if test $found_iconv = "no"; then
 407         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 408       fi
 409       ;;
 410     no)
 411       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 412       ;;
 413     gnu|yes)
 414       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 415       ;;
 416     native)
 417       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 418       ;;
 419   esac
 420
 421   if test "x$found_iconv" = "xno" ; then
 422      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 423   fi
 424 ])
 425
 426 dnl
 427 dnl zlib support
 428 dnl
 429 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 430 AS_IF([test "x$found_zlib" = "xno"], [
 431   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 432   if test "x$found_zlib" = "xno" ; then
 433     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 434   fi
 435   ZLIB_LIBS='-lz'
 436   AC_SUBST(ZLIB_LIBS)
 437 ])
 438
 439 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 440 AC_SUBST(LIBFFI_CFLAGS)
 441 AC_SUBST(LIBFFI_LIBS)
 442
 443 dnl
 444 dnl gettext support
 445 dnl
 446
 447 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 448 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 449 GLIB_GNU_GETTEXT
 450
 451 if test "$gt_cv_have_gettext" != "yes" ; then
 452   AC_MSG_ERROR([
 453 *** You must have either have gettext support in your C library, or use the
 454 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 455 ])
 456 fi
 457
 458 LIBS="$INTLLIBS $LIBS"
 459
 460 GETTEXT_PACKAGE=glib20
 461 AC_SUBST(GETTEXT_PACKAGE)
 462 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 463   [Define the gettext package to be used])
 464
 465 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 466
 467 dnl
 468 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 469 dnl
 470
 471 AS_IF([test x"$glib_native_win32" != xyes], [
 472   if test x$with_libiconv != xno ; then
 473     case " $INTLLIBS " in
 474     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 475     *) ICONV_LIBS="-liconv" ;;
 476     esac
 477   fi
 478 ])
 479 AC_SUBST(ICONV_LIBS)
 480
 481 case $with_libiconv in
 482   gnu)
 483     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 484     ;;
 485   native)
 486     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 487     ;;
 488 esac
 489
 490 dnl Initialize libtool
 491 LT_PREREQ([2.2])
 492 LT_INIT([disable-static win32-dll])
 493 dnl when using libtool 2.x create libtool early, because it's used in configure
 494 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 495
 496
 497 AS_IF([test "$glib_native_win32" = "yes"], [
 498   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 499     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 500   fi
 501   if test x$enable_static = xyes; then
 502     glib_win32_static_compilation=yes
 503     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 504 #define GOBJECT_STATIC_COMPILATION 1"
 505     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 506   fi
 507 ])
 508 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 509
 510 # Checks for library functions.
 511 AC_FUNC_ALLOCA
 512 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 513 AC_CHECK_FUNCS(timegm gmtime_r)
 514
 515 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 516   [AC_TRY_LINK([#include <unistd.h>
 517     extern int __libc_enable_secure;],
 518     [return __libc_enable_secure;],
 519    glib_cv_have_libc_enable_secure=yes,
 520    glib_cv_have_libc_enable_secure=no)])
 521 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 522    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 523      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 524 ])
 525
 526 AC_CHECK_SIZEOF(char)
 527 AC_CHECK_SIZEOF(short)
 528 AC_CHECK_SIZEOF(long)
 529 AC_CHECK_SIZEOF(int)
 530 AC_CHECK_SIZEOF(void *)
 531 AC_CHECK_SIZEOF(long long)
 532 AC_CHECK_SIZEOF(__int64)
 533
 534 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 535   [AC_TRY_LINK([#include <signal.h>
 536      #include <sys/types.h>
 537      sig_atomic_t val = 42;],
 538     [return val == 42 ? 0 : 1],
 539    ac_cv_type_sig_atomic_t=yes,
 540    ac_cv_type_sig_atomic_t=no)])
 541 if test x$ac_cv_type_sig_atomic_t = xyes; then
 542    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 543      [Define if you have the 'sig_atomic_t' type.])
 544 fi
 545
 546 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 547   :
 548 else
 549   AC_MSG_ERROR([
 550 *** GLib requires a 64 bit type. You might want to consider
 551 *** using the GNU C compiler.
 552 ])
 553 fi
 554
 555 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 556         # long long is a 64 bit integer.
 557         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 558         AC_CACHE_VAL(glib_cv_long_long_format,[
 559                 for format in ll q I64; do
 560                   AC_TRY_RUN([#include <stdio.h>
 561                         int main()
 562                         {
 563                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 564                           char buffer[1000];
 565                           sprintf (buffer, "%${format}u", a);
 566                           sscanf (buffer, "%${format}u", &b);
 567                           exit (b!=a);
 568                         }
 569                         ],
 570                         [glib_cv_long_long_format=${format}
 571                         break],
 572                         [],[:])
 573                 done])
 574         AS_IF([ test -n "$glib_cv_long_long_format"], [
 575           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 576           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 577           if test x"$glib_cv_long_long_format" = xI64; then
 578             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 579           fi
 580         ], [AC_MSG_RESULT(none)])
 581 ],[ test x$ac_cv_sizeof___int64 = x8], [
 582         # __int64 is a 64 bit integer.
 583         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 584         # We know this is MSVCRT.DLL, and what the formats are
 585         glib_cv_long_long_format=I64
 586         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 587         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 588         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 589 ])
 590
 591 AC_C_CONST
 592
 593 dnl
 594 dnl check in which direction the stack grows
 595 dnl
 596 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 597         AC_TRY_RUN([
 598         volatile int *a = 0, *b = 0;
 599         void foo (void);
 600         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 601         void foo (void) { volatile int x = 5; b = &x; }
 602         ],
 603         glib_cv_stack_grows=no
 604         ,
 605         glib_cv_stack_grows=yes
 606         ,)
 607 ])
 608
 609 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 610 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 611 dnl actually supported.
 612 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 613         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 614         __inline int foo () { return 0; }
 615         int main () { return foo (); }
 616         ]])],
 617         glib_cv_has__inline=yes
 618         ,
 619         glib_cv_has__inline=no
 620         ,)
 621 ])
 622 case x$glib_cv_has__inline in
 623 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 624 esac
 625 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 626         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 627         __inline__ int foo () { return 0; }
 628         int main () { return foo (); }
 629         ]])],
 630         glib_cv_has__inline__=yes
 631         ,
 632         glib_cv_has__inline__=no
 633         ,)
 634 ])
 635 case x$glib_cv_has__inline__ in
 636 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 637 esac
 638 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 639         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 640         #undef inline
 641         inline int foo () { return 0; }
 642         int main () { return foo (); }
 643         ]])],
 644         glib_cv_hasinline=yes
 645         ,
 646         glib_cv_hasinline=no
 647         ,)
 648 ])
 649 case x$glib_cv_hasinline in
 650 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 651 esac
 652
 653 # if we can use inline functions in headers
 654 AC_MSG_CHECKING(if inline functions in headers work)
 655 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 656 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 657 #  undef inline
 658 #  define inline __inline__
 659 #elif !defined (G_HAVE_INLINE)
 660 #  undef inline
 661 #  if defined (G_HAVE___INLINE__)
 662 #    define inline __inline__
 663 #  elif defined (G_HAVE___INLINE)
 664 #    define inline __inline
 665 #  endif
 666 #endif
 667
 668 int glib_test_func2 (int);
 669
 670 static inline int
 671 glib_test_func1 (void) {
 672   return glib_test_func2 (1);
 673 }
 674
 675 int
 676 main (void) {
 677   int i = 1;
 678 }]])],[g_can_inline=yes],[g_can_inline=no])
 679 AC_MSG_RESULT($g_can_inline)
 680
 681 # check for flavours of varargs macros
 682 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 683 AC_TRY_COMPILE([],[
 684 int a(int p1, int p2, int p3);
 685 #define call_a(...) a(1,__VA_ARGS__)
 686 call_a(2,3);
 687 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 688 AC_MSG_RESULT($g_have_iso_c_varargs)
 689
 690 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 691 AS_IF([test "$CXX" = ""], [
 692 dnl No C++ compiler
 693   g_have_iso_cxx_varargs=no
 694 else
 695   AC_LANG_CPLUSPLUS
 696   AC_TRY_COMPILE([],[
 697 int a(int p1, int p2, int p3);
 698 #define call_a(...) a(1,__VA_ARGS__)
 699 call_a(2,3);
 700 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 701   AC_LANG_C
 702 ])
 703 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 704
 705 AC_MSG_CHECKING(for GNUC varargs macros)
 706 AC_TRY_COMPILE([],[
 707 int a(int p1, int p2, int p3);
 708 #define call_a(params...) a(1,params)
 709 call_a(2,3);
 710 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 711 AC_MSG_RESULT($g_have_gnuc_varargs)
 712
 713 # check for GNUC visibility support
 714 AC_MSG_CHECKING(for GNUC visibility attribute)
 715 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 716 void
 717 __attribute__ ((visibility ("hidden")))
 718      f_hidden (void)
 719 {
 720 }
 721 void
 722 __attribute__ ((visibility ("internal")))
 723      f_internal (void)
 724 {
 725 }
 726 void
 727 __attribute__ ((visibility ("protected")))
 728      f_protected (void)
 729 {
 730 }
 731 void
 732 __attribute__ ((visibility ("default")))
 733      f_default (void)
 734 {
 735 }
 736 int main (void)
 737 {
 738         f_hidden();
 739         f_internal();
 740         f_protected();
 741         f_default();
 742         return 0;
 743 }
 744 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 745 AC_MSG_RESULT($g_have_gnuc_visibility)
 746 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 747
 748 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 749 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 750 #else
 751 # include "error: this is not Sun Studio."
 752 #endif
 753 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 754 AC_MSG_RESULT($g_have_sunstudio_visibility)
 755 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 756
 757 # check for bytesex stuff
 758 AC_C_BIGENDIAN
 759 if test x$ac_cv_c_bigendian = xuniversal ; then
 760 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 761 #else
 762 #error Not a big endian.
 763 #endif],
 764     ac_cv_c_bigendian=yes
 765     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 766 #else
 767 #error Not a little endian.
 768 #endif],
 769     ac_cv_c_bigendian=no
 770     ,AC_MSG_WARN([Could not determine endianness.])))
 771 fi
 772
 773
 774 # check for header files
 775 AC_CHECK_HEADERS([dirent.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 776 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h])
 777 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 778 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 779 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 780 AC_CHECK_HEADERS([sys/uio.h])
 781 AC_CHECK_HEADERS([linux/magic.h])
 782 AC_CHECK_HEADERS([sys/prctl.h])
 783
 784 # We don't care about this, but we need to keep including it in
 785 # glibconfig.h for backward compatibility
 786 AC_CHECK_HEADERS([values.h])
 787
 788 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 789 [#if HAVE_SYS_PARAM_H
 790  #include <sys/param.h>
 791  #endif
 792 ])
 793 AC_CHECK_FUNCS(sysctlbyname)
 794
 795 AC_HEADER_MAJOR
 796 AC_CHECK_HEADERS([xlocale.h])
 797
 798 # check for structure fields
 799 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 800 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 801 #include <sys/stat.h>
 802 #include <unistd.h>
 803 #ifdef HAVE_SYS_STATFS_H
 804 #include <sys/statfs.h>
 805 #endif
 806 #ifdef HAVE_SYS_PARAM_H
 807 #include <sys/param.h>
 808 #endif
 809 #ifdef HAVE_SYS_MOUNT_H
 810 #include <sys/mount.h>
 811 #endif])
 812 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 813 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 814 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 815 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 816
 817 AC_STRUCT_DIRENT_D_TYPE
 818
 819 # Checks for libcharset
 820 AM_LANGINFO_CODESET
 821 gl_GLIBC21
 822
 823 # check additional type sizes
 824 AC_CHECK_SIZEOF(size_t)
 825
 826 dnl Try to figure out whether gsize should be long or int
 827 AC_MSG_CHECKING([for the appropriate definition for size_t])
 828
 829 case $ac_cv_sizeof_size_t in
 830   $ac_cv_sizeof_short)
 831       glib_size_type=short
 832       ;;
 833   $ac_cv_sizeof_int)
 834       glib_size_type=int
 835       ;;
 836   $ac_cv_sizeof_long)
 837       glib_size_type=long
 838       ;;
 839   $ac_cv_sizeof_long_long)
 840       glib_size_type='long long'
 841       ;;
 842   $ac_cv_sizeof__int64)
 843       glib_size_type='__int64'
 844       ;;
 845   *)  AC_MSG_ERROR([No type matching size_t in size])
 846       ;;
 847 esac
 848
 849 dnl If int/long are the same size, we see which one produces
 850 dnl warnings when used in the location as size_t. (This matters
 851 dnl on AIX with xlc)
 852 dnl
 853 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 854        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 855   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 856 #if defined(_AIX) && !defined(__GNUC__)
 857 #pragma options langlvl=stdc89
 858 #endif
 859 #include <stddef.h>
 860 int main ()
 861 {
 862   size_t s = 1;
 863   unsigned int *size_int = &s;
 864   return (int)*size_int;
 865 }
 866     ]])],glib_size_type=int,
 867       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 868 #if defined(_AIX) && !defined(__GNUC__)
 869 #pragma options langlvl=stdc89
 870 #endif
 871 #include <stddef.h>
 872 int main ()
 873 {
 874    size_t s = 1;
 875    unsigned long *size_long = &s;
 876    return (int)*size_long;
 877 }
 878         ]])],glib_size_type=long)])
 879 ])
 880
 881 AC_MSG_RESULT(unsigned $glib_size_type)
 882
 883 AC_CHECK_SIZEOF(ssize_t)
 884
 885 dnl Try to figure out whether gssize should be long or int
 886 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 887
 888 case $ac_cv_sizeof_ssize_t in
 889   $ac_cv_sizeof_short)
 890       glib_ssize_type=short
 891       ;;
 892   $ac_cv_sizeof_int)
 893       glib_ssize_type=int
 894       ;;
 895   $ac_cv_sizeof_long)
 896       glib_ssize_type=long
 897       ;;
 898   $ac_cv_sizeof_long_long)
 899       glib_ssize_type='long long'
 900       ;;
 901   $ac_cv_sizeof__int64)
 902       glib_ssize_type='__int64'
 903       ;;
 904   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 905       ;;
 906 esac
 907
 908 dnl If int/long are the same size, we see which one produces
 909 dnl warnings when used in the location as ssize_t. (This matters
 910 dnl on Android where ssize_t is long and size_t is unsigned int)
 911 dnl
 912 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 913        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 914   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 915 #if defined(_AIX) && !defined(__GNUC__)
 916 #pragma options langlvl=stdc89
 917 #endif
 918 #include <stddef.h>
 919 #ifdef HAVE_INTTYPES_H
 920 # include <inttypes.h>
 921 #endif
 922 #ifdef HAVE_STDINT_H
 923 # include <stdint.h>
 924 #endif
 925 #ifdef HAVE_UNISTD_H
 926 # include <unistd.h>
 927 #endif
 928 #ifdef HAVE_SYS_TYPES_H
 929 # include <sys/types.h>
 930 #endif
 931 int main ()
 932 {
 933   ssize_t s = 1;
 934   int *size_int = &s;
 935   return (int)*size_int;
 936 }
 937     ]])],glib_ssize_type=int,
 938       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 939 #if defined(_AIX) && !defined(__GNUC__)
 940 #pragma options langlvl=stdc89
 941 #endif
 942 #include <stddef.h>
 943 #ifdef HAVE_INTTYPES_H
 944 # include <inttypes.h>
 945 #endif
 946 #ifdef HAVE_STDINT_H
 947 # include <stdint.h>
 948 #endif
 949 #ifdef HAVE_UNISTD_H
 950 # include <unistd.h>
 951 #endif
 952 #ifdef HAVE_SYS_TYPES_H
 953 # include <sys/types.h>
 954 #endif
 955 int main ()
 956 {
 957    ssize_t s = 1;
 958    long *size_long = &s;
 959    return (int)*size_long;
 960 }
 961         ]])],glib_ssize_type=long)])
 962 ])
 963
 964 AC_MSG_RESULT($glib_ssize_type)
 965
 966 # Check for some functions
 967 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 968 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
 969 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
 970 # Check for high-resolution sleep functions
 971 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
 972 AC_CHECK_FUNCS(splice)
 973 AC_CHECK_FUNCS(prlimit)
 974
 975 # To avoid finding a compatibility unusable statfs, which typically
 976 # successfully compiles, but warns to use the newer statvfs interface:
 977 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 978 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 979
 980 AC_MSG_CHECKING([whether to use statfs or statvfs])
 981 # Some systems have both statfs and statvfs, pick the most "native" for these
 982 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
 983    [
 984    # on solaris and irix, statfs doesn't even have the f_bavail field
 985    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
 986       [ac_cv_func_statfs=no],
 987    # else, at least on linux, statfs is the actual syscall
 988       [ac_cv_func_statvfs=no])
 989    ])
 990
 991 AS_IF([test x$ac_cv_func_statfs = xyes],
 992       [
 993          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
 994          AC_MSG_RESULT([statfs])
 995       ],
 996       [test x$ac_cv_func_statvfs = xyes],
 997       [
 998          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
 999          AC_MSG_RESULT([statvfs])
1000       ],
1001       [  AC_MSG_RESULT([neither])])
1002
1003 AC_CHECK_HEADERS(crt_externs.h)
1004 AC_CHECK_FUNCS(_NSGetEnviron)
1005
1006 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1007
1008 AC_FUNC_VSNPRINTF_C99
1009 AC_FUNC_PRINTF_UNIX98
1010
1011 # Internet address families
1012 if test $glib_native_win32 = yes; then
1013   glib_inet_includes=["
1014 #include <winsock2.h>
1015   "]
1016 else
1017   glib_inet_includes=["
1018 #include <sys/types.h>
1019 #include <sys/socket.h>
1020   "]
1021 fi
1022
1023 glib_failed=false
1024 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1025 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1026 # winsock defines this even though it doesn't support it
1027 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1028 if $glib_failed ; then
1029   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1030 fi
1031
1032 glib_failed=false
1033 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1034 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1035 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1036 if $glib_failed ; then
1037   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1038 fi
1039
1040 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname)
1041
1042 AS_IF([test $glib_native_win32 = yes], [
1043   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1044   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1045   # they aren't present at run-time (on Windows 2000).
1046   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1047   AC_SUBST(WSPIAPI_INCLUDE)
1048 ], [
1049   # Android does not have C_IN in public headers, we define it wherever necessary
1050   AS_IF([test $glib_native_android != yes], [
1051     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1052     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1053                                         #include <arpa/nameser.h>],
1054                                        [int qclass = C_IN;])],
1055                       [AC_MSG_RESULT([no])],
1056                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1057                                                            #include <arpa/nameser.h>
1058                                                            #include <arpa/nameser_compat.h>],
1059                                                           [int qclass = C_IN;])],
1060                                          [AC_MSG_RESULT([yes])
1061                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1062                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1063   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1064
1065   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1066   NETWORK_LIBS=""
1067   AC_MSG_CHECKING([for res_query])
1068   AC_TRY_LINK([#include <sys/types.h>
1069                #include <netinet/in.h>
1070                #include <arpa/nameser.h>
1071                #include <resolv.h>
1072               ],[
1073                res_query("test", 0, 0, (void *)0, 0);
1074               ],[AC_MSG_RESULT([yes])],
1075               [save_libs="$LIBS"
1076                LIBS="-lresolv $LIBS"
1077                AC_TRY_LINK([#include <sys/types.h>
1078                             #include <netinet/in.h>
1079                             #include <arpa/nameser.h>
1080                             #include <resolv.h>
1081                            ],[
1082                             res_query("test", 0, 0, (void *)0, 0);
1083                            ],[AC_MSG_RESULT([in -lresolv])
1084                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1085                            [LIBS="-lbind $save_libs"
1086                             AC_TRY_LINK([#include <resolv.h>],
1087                                         [res_query("test", 0, 0, (void *)0, 0);],
1088                                         [AC_MSG_RESULT([in -lbind])
1089                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1090                                         [AC_MSG_ERROR(not found)])])
1091                LIBS="$save_libs"])
1092   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1093                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1094                                         [AC_MSG_ERROR(Could not find socket())]))
1095   save_libs="$LIBS"
1096   LIBS="$LIBS $NETWORK_LIBS"
1097   AC_MSG_CHECKING([for res_init])
1098   AC_TRY_LINK([#include <sys/types.h>
1099                #include <netinet/in.h>
1100                #include <arpa/nameser.h>
1101                #include <resolv.h>
1102               ],[
1103                res_init();
1104               ],[AC_MSG_RESULT([yes])
1105                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1106               ],[AC_MSG_RESULT([no])])
1107   LIBS="$save_libs"
1108 ])
1109 AC_SUBST(NETWORK_LIBS)
1110
1111 AC_CHECK_HEADER([linux/netlink.h],
1112                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1113                 [#include <sys/socket.h>])
1114 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1115
1116 AC_CHECK_TYPE([struct ip_mreqn], [
1117               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1118               [#include <netinet/in.h>])
1119
1120 case $host in
1121   *-*-solaris* )
1122      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1123      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1124      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1125      ;;
1126 esac
1127
1128 dnl
1129 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1130 dnl
1131 AS_IF([test "$ac_cv_func_statfs" = yes], [
1132   AC_MSG_CHECKING([number of arguments to statfs()])
1133   AC_TRY_COMPILE([#include <unistd.h>
1134   #ifdef HAVE_SYS_PARAM_H
1135   #include <sys/param.h>
1136   #endif
1137   #ifdef HAVE_SYS_VFS_H
1138   #include <sys/vfs.h>
1139   #endif
1140   #ifdef HAVE_SYS_MOUNT_H
1141   #include <sys/mount.h>
1142   #endif
1143   #ifdef HAVE_SYS_STATFS_H
1144   #include <sys/statfs.h>
1145   #endif], [struct statfs st;
1146   statfs(NULL, &st);],[
1147     AC_MSG_RESULT([2])
1148     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1149     AC_TRY_COMPILE([#include <unistd.h>
1150   #ifdef HAVE_SYS_PARAM_H
1151   #include <sys/param.h>
1152   #endif
1153   #ifdef HAVE_SYS_VFS_H
1154   #include <sys/vfs.h>
1155   #endif
1156   #ifdef HAVE_SYS_MOUNT_H
1157   #include <sys/mount.h>
1158   #endif
1159   #ifdef HAVE_SYS_STATFS_H
1160   #include <sys/statfs.h>
1161   #endif], [struct statfs st;
1162   statfs(NULL, &st, sizeof (st), 0);],[
1163       AC_MSG_RESULT([4])
1164       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1165       AC_MSG_RESULT(unknown)
1166       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1167 ])
1168
1169 dnl
1170 dnl open takes O_DIRECTORY as an option
1171 dnl
1172 AC_MSG_CHECKING([open() option O_DIRECTORY])
1173 AC_TRY_COMPILE([#include <fcntl.h>
1174 #include <sys/types.h>
1175 #include <sys/stat.h>],
1176 [open(0, O_DIRECTORY, 0);],[
1177         AC_MSG_RESULT([yes])
1178         AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1179         AC_MSG_RESULT([no])])
1180
1181 #
1182 # Check whether to use an included printf
1183 #
1184
1185 AC_ARG_ENABLE(included-printf,
1186               [AS_HELP_STRING([--enable-included-printf],
1187                               [use included printf [default=auto]])],
1188               enable_included_printf="$enableval")
1189
1190 need_included_printf=no
1191 if test "x$enable_included_printf" = "xyes" ; then
1192   need_included_printf=yes
1193 fi
1194 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1195   need_included_printf=yes
1196 fi
1197 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1198   need_included_printf=yes
1199 fi
1200 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1201    test -z "$glib_cv_long_long_format" ; then
1202   need_included_printf=yes
1203 fi
1204
1205 if test "x$enable_included_printf" = "xno" &&
1206    test "x$need_included_printf" = "xyes" ; then
1207   AC_MSG_ERROR([
1208 *** Your C library's printf doesn't appear to have the features that
1209 *** GLib needs, but you specified --enable-included-printf=no.])
1210 fi
1211
1212 enable_included_printf=$need_included_printf
1213
1214 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1215 AS_IF([test "$enable_included_printf" != "yes"], [
1216   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1217 ], [
1218   if test -z "$glib_cv_long_long_format" ; then
1219     glib_cv_long_long_format="ll"
1220   fi
1221   AC_DEFINE(HAVE_VASPRINTF,1)
1222 ])
1223
1224 # Checks needed for gnulib vasnprintf
1225 bh_C_SIGNED
1226 jm_AC_TYPE_LONG_LONG
1227 gt_TYPE_LONGDOUBLE
1228 gt_TYPE_WCHAR_T
1229 gt_TYPE_WINT_T
1230 AC_TYPE_SIZE_T
1231 AC_CHECK_TYPES(ptrdiff_t)
1232 jm_AC_TYPE_INTMAX_T
1233 AC_CHECK_FUNCS([snprintf wcslen])
1234 AC_FUNC_SNPRINTF_C99
1235
1236 # Check if <sys/select.h> needs to be included for fd_set
1237 AC_MSG_CHECKING([for fd_set])
1238 AC_TRY_COMPILE([#include <sys/types.h>],
1239         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1240 AS_IF([test "$gtk_ok" = "yes"], [
1241     AC_MSG_RESULT([yes, found in sys/types.h])
1242 ], [
1243     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1244     if test "$gtk_ok" = "yes"; then
1245         # *** FIXME: give it a different name
1246         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1247         AC_MSG_RESULT([yes, found in sys/select.h])
1248     else
1249         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1250         AC_MSG_RESULT(no)
1251     fi
1252 ])
1253
1254 dnl Check for nl_langinfo and CODESET
1255 AC_LANG_SAVE
1256 AC_LANG_C
1257 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1258         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1259                        [char *codeset = nl_langinfo (CODESET);])],
1260                 [glib_cv_langinfo_codeset=yes],
1261                 [glib_cv_langinfo_codeset=no])])
1262 if test x$glib_cv_langinfo_codeset = xyes; then
1263   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1264 fi
1265
1266 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1267 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1268         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1269                  [char *str;
1270                  str = nl_langinfo (PM_STR);
1271                  str = nl_langinfo (D_T_FMT);
1272                  str = nl_langinfo (D_FMT);
1273                  str = nl_langinfo (T_FMT);
1274                  str = nl_langinfo (T_FMT_AMPM);
1275                  str = nl_langinfo (MON_1);
1276                  str = nl_langinfo (ABMON_12);
1277                  str = nl_langinfo (DAY_1);
1278                  str = nl_langinfo (ABDAY_7);])],
1279                 [glib_cv_langinfo_time=yes],
1280                 [glib_cv_langinfo_time=no])])
1281 if test x$glib_cv_langinfo_time = xyes; then
1282   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1283 fi
1284
1285 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1286 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1287         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1288                 [char *str;
1289                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1290                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1291                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1292                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1293                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1294                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1295                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1296                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1297                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1298                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1299                 [glib_cv_langinfo_outdigit=yes],
1300                 [glib_cv_langinfo_outdigit=no])])
1301 if test x$glib_cv_langinfo_outdigit = xyes; then
1302   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1303 fi
1304 AC_LANG_RESTORE
1305
1306 dnl ****************************************
1307 dnl *** posix_memalign                   ***
1308 dnl ****************************************
1309 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1310 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1311     glib_cv_compliant_posix_memalign=0
1312     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1313         AC_TRY_RUN([
1314                 #define _XOPEN_SOURCE 600
1315                 #include <stdlib.h> /* posix_memalign() should be defined here */
1316                 /* some systems break if #include <malloc.h> used */
1317                 static void test_memalign (size_t boundary, size_t size) {
1318                     void *mem = 0;
1319                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1320                         exit (1);
1321                     else
1322                       free (mem);
1323                 }
1324                 int main() {
1325                     test_memalign (  128,   128 - 2 * sizeof (void*));
1326                     test_memalign (  256,   256 - 2 * sizeof (void*));
1327                     test_memalign (  512,   512 - 2 * sizeof (void*));
1328                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1329                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1330                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1331                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1332                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1333                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1334                     exit (0); /* success */
1335                 }
1336                 ],
1337             [glib_cv_compliant_posix_memalign=1], [], [:])
1338       :
1339     fi
1340     ])
1341 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1342     AC_MSG_RESULT(yes)
1343     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1344 ], [
1345     AC_MSG_RESULT(no)
1346 ])
1347
1348
1349 dnl ****************************************
1350 dnl *** strlcpy/strlcat                  ***
1351 dnl ****************************************
1352 # Check for strlcpy
1353 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1354 AC_TRY_RUN([#include <stdlib.h>
1355 #include <string.h>
1356 int main() {
1357   char p[10];
1358   (void) strlcpy (p, "hi", 10);
1359   if (strlcat (p, "bye", 0) != 3)
1360     return 1;
1361   return 0;
1362 }], glib_cv_have_strlcpy=yes,
1363     glib_cv_have_strlcpy=no,
1364     glib_cv_have_strlcpy=no)])
1365 if test "$glib_cv_have_strlcpy" = "yes"; then
1366     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1367 fi
1368
1369
1370 dnl **********************
1371 dnl *** va_copy checks ***
1372 dnl **********************
1373 dnl we currently check for all three va_copy possibilities, so we get
1374 dnl all results in config.log for bug reports.
1375 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1376         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1377 #include <stdlib.h>
1378         void f (int i, ...) {
1379         va_list args1, args2;
1380         va_start (args1, i);
1381         va_copy (args2, args1);
1382         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1383           exit (1);
1384         va_end (args1); va_end (args2);
1385         }
1386         int main() {
1387           f (0, 42);
1388           return 0;
1389         }]])],
1390         [glib_cv_va_copy=yes],
1391         [glib_cv_va_copy=no])
1392 ])
1393 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1394         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1395 #include <stdlib.h>
1396         void f (int i, ...) {
1397         va_list args1, args2;
1398         va_start (args1, i);
1399         __va_copy (args2, args1);
1400         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1401           exit (1);
1402         va_end (args1); va_end (args2);
1403         }
1404         int main() {
1405           f (0, 42);
1406           return 0;
1407         }]])],
1408         [glib_cv___va_copy=yes],
1409         [glib_cv___va_copy=no])
1410 ])
1411
1412 if test "x$glib_cv_va_copy" = "xyes"; then
1413   g_va_copy_func=va_copy
1414 else if test "x$glib_cv___va_copy" = "xyes"; then
1415   g_va_copy_func=__va_copy
1416 fi
1417 fi
1418
1419 if test -n "$g_va_copy_func"; then
1420   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1421 fi
1422
1423 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1424         AC_TRY_RUN([#include <stdarg.h>
1425 #include <stdlib.h>
1426         void f (int i, ...) {
1427         va_list args1, args2;
1428         va_start (args1, i);
1429         args2 = args1;
1430         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1431           exit (1);
1432         va_end (args1); va_end (args2);
1433         }
1434         int main() {
1435           f (0, 42);
1436           return 0;
1437         }],
1438         [glib_cv_va_val_copy=yes],
1439         [glib_cv_va_val_copy=no],
1440         [glib_cv_va_val_copy=yes])
1441 ])
1442
1443 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1444   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1445 ])
1446
1447 dnl ***********************
1448 dnl *** g_module checks ***
1449 dnl ***********************
1450 G_MODULE_LIBS=
1451 G_MODULE_LIBS_EXTRA=
1452 G_MODULE_PLUGIN_LIBS=
1453 if test x"$glib_native_win32" = xyes; then
1454   dnl No use for this on Win32
1455   G_MODULE_LDFLAGS=
1456 else
1457   export SED
1458   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1459 fi
1460 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1461 G_MODULE_NEED_USCORE=0
1462 G_MODULE_BROKEN_RTLD_GLOBAL=0
1463 G_MODULE_HAVE_DLERROR=0
1464 dnl *** force native WIN32 shared lib loader
1465 if test -z "$G_MODULE_IMPL"; then
1466   case "$host" in
1467   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1468   esac
1469 fi
1470 dnl *** force native AIX library loader
1471 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1472 if test -z "$G_MODULE_IMPL"; then
1473   case "$host" in
1474   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1475   esac
1476 fi
1477 dnl *** dlopen() and dlsym() in system libraries
1478 AS_IF([ test -z "$G_MODULE_IMPL"], [
1479         AC_CHECK_FUNC(dlopen,
1480                       [AC_CHECK_FUNC(dlsym,
1481                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1482                       [])
1483 ])
1484 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1485 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1486         AC_CHECK_FUNC(NSLinkModule,
1487                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1488                        G_MODULE_NEED_USCORE=1],
1489                       [])
1490 ])
1491 dnl *** dlopen() and dlsym() in libdl
1492 AS_IF([ test -z "$G_MODULE_IMPL"], [
1493         AC_CHECK_LIB(dl, dlopen,
1494                      [AC_CHECK_LIB(dl, dlsym,
1495                                    [G_MODULE_LIBS=-ldl
1496                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1497                      [])
1498 ])
1499 dnl *** additional checks for G_MODULE_IMPL_DL
1500 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1501         LIBS_orig="$LIBS"
1502         LDFLAGS_orig="$LDFLAGS"
1503         LIBS="$G_MODULE_LIBS $LIBS"
1504         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1505 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1506         echo "void glib_plugin_test(void) { }" > plugin.c
1507         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1508                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1509         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1510                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1511                 -shrext ".o" -avoid-version plugin.lo \
1512                 -rpath /dont/care >/dev/null 2>&1
1513         eval `./libtool --config | grep ^objdir`
1514         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1515                 glib_cv_rtldglobal_broken,[
1516                 AC_TRY_RUN([
1517 #include <dlfcn.h>
1518 #ifndef RTLD_GLOBAL
1519 #  define RTLD_GLOBAL 0
1520 #endif
1521 #ifndef RTLD_LAZY
1522 #  define RTLD_LAZY 0
1523 #endif
1524 int glib_plugin_test;
1525 int main () {
1526     void *handle, *global, *local;
1527     global = &glib_plugin_test;
1528     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1529     if (!handle) return 0;
1530     local = dlsym (handle, "glib_plugin_test");
1531     return global == local;
1532 }                       ],
1533                         [glib_cv_rtldglobal_broken=no],
1534                         [glib_cv_rtldglobal_broken=yes],
1535                         [glib_cv_rtldglobal_broken=no])
1536                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1537                 rmdir ${objdir} 2>/dev/null
1538         ])
1539         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1540                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1541         else
1542                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1543         fi
1544 dnl *** check whether we need preceeding underscores
1545         AC_CACHE_CHECK([for preceeding underscore in symbols],
1546                 glib_cv_uscore,[
1547                 AC_TRY_RUN([#include <dlfcn.h>
1548                 int glib_underscore_test (void) { return 42; }
1549                 int main() {
1550                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1551                   handle = dlopen ((void*)0, 0);
1552                   if (handle) {
1553                     f1 = dlsym (handle, "glib_underscore_test");
1554                     f2 = dlsym (handle, "_glib_underscore_test");
1555                   } return (!f2 || f1);
1556                 }],
1557                         [glib_cv_uscore=yes],
1558                         [glib_cv_uscore=no],
1559                         [])
1560                 rm -f plugin.c plugin.$ac_objext plugin.lo
1561         ])
1562         GLIB_ASSERT_SET(glib_cv_uscore)
1563         if test "x$glib_cv_uscore" = "xyes"; then
1564                 G_MODULE_NEED_USCORE=1
1565         else
1566                 G_MODULE_NEED_USCORE=0
1567         fi
1568
1569         LDFLAGS="$LDFLAGS_orig"
1570 dnl *** check for having dlerror()
1571         AC_CHECK_FUNC(dlerror,
1572                 [G_MODULE_HAVE_DLERROR=1],
1573                 [G_MODULE_HAVE_DLERROR=0])
1574         LIBS="$LIBS_orig"
1575 ])
1576 dnl *** done, have we got an implementation?
1577 if test -z "$G_MODULE_IMPL"; then
1578         G_MODULE_IMPL=0
1579         G_MODULE_SUPPORTED=false
1580 else
1581         G_MODULE_SUPPORTED=true
1582 fi
1583
1584 AC_MSG_CHECKING(for the suffix of module shared libraries)
1585 export SED
1586 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1587 eval $shrext_cmds
1588 module=yes eval std_shrext=$shrext_cmds
1589 # chop the initial dot
1590 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1591 AC_MSG_RESULT(.$glib_gmodule_suffix)
1592 # any reason it may fail?
1593 if test "x$glib_gmodule_suffix" = x; then
1594         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1595 fi
1596
1597 AC_SUBST(G_MODULE_SUPPORTED)
1598 AC_SUBST(G_MODULE_IMPL)
1599 AC_SUBST(G_MODULE_LIBS)
1600 AC_SUBST(G_MODULE_LIBS_EXTRA)
1601 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1602 AC_SUBST(G_MODULE_LDFLAGS)
1603 AC_SUBST(G_MODULE_HAVE_DLERROR)
1604 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1605 AC_SUBST(G_MODULE_NEED_USCORE)
1606 AC_SUBST(GLIB_DEBUG_FLAGS)
1607
1608 dnl **********************
1609 dnl *** g_spawn checks ***
1610 dnl **********************
1611
1612 AC_MSG_CHECKING(for gspawn implementation)
1613 case "$host" in
1614   *-*-mingw*)
1615     GSPAWN=gspawn-win32.lo
1616     ;;
1617   *)
1618     GSPAWN=gspawn.lo
1619     ;;
1620 esac
1621 AC_MSG_RESULT($GSPAWN)
1622 AC_SUBST(GSPAWN)
1623
1624 dnl *************************
1625 dnl *** GIOChannel checks ***
1626 dnl *************************
1627
1628 AC_MSG_CHECKING(for GIOChannel implementation)
1629 case "$host" in
1630   *-*-mingw*)
1631     GIO=giowin32.lo
1632     ;;
1633   *)
1634     GIO=giounix.lo
1635     ;;
1636 esac
1637 AC_MSG_RESULT($GIO)
1638 AC_SUBST(GIO)
1639
1640 dnl *********************************
1641 dnl *** Directory for GIO modules ***
1642 dnl *********************************
1643
1644 AC_ARG_WITH(gio-module-dir,
1645            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1646                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1647            [],
1648            [with_gio_module_dir='${libdir}/gio/modules'])
1649 GIO_MODULE_DIR=$with_gio_module_dir
1650 AC_SUBST(GIO_MODULE_DIR)
1651
1652 dnl **********************************
1653 dnl *** Check for libselinux (GIO) ***
1654 dnl **********************************
1655 AC_ARG_ENABLE(selinux,
1656               AS_HELP_STRING([--disable-selinux],
1657                              [build without selinux support]))
1658 msg_selinux=no
1659 SELINUX_LIBS=
1660 AS_IF([ test "x$enable_selinux" != "xno"], [
1661
1662  AC_CHECK_LIB(selinux, is_selinux_enabled,
1663    [AC_CHECK_HEADERS(selinux/selinux.h,
1664      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1665        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1666         SELINUX_LIBS="-lselinux"
1667         msg_selinux=yes])
1668      ])
1669    ])
1670 ])
1671 AC_SUBST(SELINUX_LIBS)
1672
1673 dnl *****************************
1674 dnl ** Check for inotify (GIO) **
1675 dnl *****************************
1676 inotify_support=no
1677 AC_CHECK_HEADERS([sys/inotify.h],
1678 [
1679         inotify_support=yes
1680         AC_CHECK_FUNCS(inotify_init1)
1681 ])
1682
1683 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1684
1685 dnl ****************************
1686 dnl ** Check for kqueue (GIO) **
1687 dnl ****************************
1688 kqueue_support=no
1689 AC_CHECK_HEADERS([sys/event.h],
1690 [
1691         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1692 ])
1693
1694 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1695
1696 dnl *********************************
1697 dnl ** Check for Solaris FEN (GIO) **
1698 dnl *********************************
1699 fen_support=no
1700 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1701 #include <port.h>
1702 #ifndef PORT_SOURCE_FILE
1703 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1704 #endif
1705 int main() { return 0; } ]])],
1706 [
1707         fen_support=yes
1708 ],)
1709
1710 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1711
1712 dnl ****************************
1713 dnl *** Checks for FAM (GIO) ***
1714 dnl ****************************
1715
1716 should_disable_fam=no
1717
1718 AC_ARG_ENABLE(fam,
1719               AS_HELP_STRING([--disable-fam],
1720                              [don't use fam for file system monitoring]),
1721                          [
1722                                 if test "x$enable_fam" = "xno"; then
1723                                         should_disable_fam=yes
1724                                 fi
1725                          ]
1726                          )
1727 fam_support=no
1728 FAM_LIBS=
1729 if test "x$should_disable_fam" = "xno"; then
1730 AC_CHECK_LIB(fam, FAMOpen,
1731   [AC_CHECK_HEADERS(fam.h,
1732     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1733      AC_CHECK_LIB(fam, FAMNoExists,
1734                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1735      FAM_LIBS="-lfam"]
1736      fam_support=yes,
1737     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1738   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1739 AC_SUBST(FAM_LIBS)
1740 fi
1741 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1742
1743
1744 dnl *****************************
1745 dnl *** Check for xattr (GIO) ***
1746 dnl *****************************
1747 AC_ARG_ENABLE(xattr,
1748               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1749 msg_xattr=no
1750 XATTR_LIBS=
1751 AS_IF([ test "x$enable_xattr" != "xno"], [
1752
1753 dnl either glibc or libattr can provide xattr support
1754
1755 dnl for both of them, we check for getxattr being in
1756 dnl the library and a valid xattr header.
1757
1758 dnl try glibc
1759  AC_CHECK_LIB(c, getxattr,
1760    [AC_CHECK_HEADERS(sys/xattr.h,
1761      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1762       msg_xattr=yes])
1763    ])
1764
1765   AS_IF([ test "x$msg_xattr" != "xyes"], [
1766 dnl   failure. try libattr
1767    AC_CHECK_LIB(attr, getxattr,
1768       [AC_CHECK_HEADERS(attr/xattr.h,
1769        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1770         XATTR_LIBS="-lattr"
1771         msg_xattr=yes])
1772       ])
1773   ])
1774
1775   AS_IF([ test "x$msg_xattr" = "xyes"], [
1776     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1777     AC_TRY_COMPILE([
1778       #include <stdio.h>
1779       #ifdef HAVE_SYS_TYPES_H
1780       #include <sys/types.h>
1781       #endif
1782       #ifdef HAVE_SYS_XATTR_H
1783       #include <sys/xattr.h>
1784       #elif HAVE_ATTR_XATTR_H
1785       #include <attr/xattr.h>
1786       #endif
1787     ],
1788     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1789     [
1790       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1791       AC_MSG_RESULT([yes])
1792     ],
1793     [AC_MSG_RESULT([no])]
1794     )
1795   ])
1796 ])
1797 AC_SUBST(XATTR_LIBS)
1798
1799 dnl ************************
1800 dnl *** check for libelf ***
1801 dnl ************************
1802 AC_ARG_ENABLE(libelf,
1803               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1804 AS_IF([ test "x$enable_libelf" != "xno"],[
1805 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1806 AS_IF([ test $have_libelf = maybe ], [
1807   glib_save_LIBS=$LIBS
1808   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1809   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1810   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1811   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1812   LIBS=$glib_save_LIBS
1813
1814   if test $have_libelf != no; then
1815     LIBELF_LIBS=-lelf
1816     have_libelf=yes
1817   fi
1818 ])
1819 ])
1820
1821 if test x$have_libelf = xyes; then
1822   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1823 fi
1824
1825 dnl ****************************************
1826 dnl *** platform dependent source checks ***
1827 dnl ****************************************
1828
1829 AC_MSG_CHECKING(for platform-dependent source)
1830 case "$host" in
1831   *-*-cygwin*|*-*-mingw*)
1832     PLATFORMDEP=gwin32.lo
1833     ;;
1834   *)
1835     PLATFORMDEP=
1836     ;;
1837 esac
1838 AC_MSG_RESULT($PLATFORMDEP)
1839 AC_SUBST(PLATFORMDEP)
1840
1841 AC_MSG_CHECKING([whether to compile timeloop])
1842 case "$host" in
1843   *-*-cygwin*|*-*-mingw*|*-*-minix)
1844     enable_timeloop=no
1845     ;;
1846   *)
1847     enable_timeloop=yes
1848     ;;
1849 esac
1850 AC_MSG_RESULT($enable_timeloop)
1851 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1852
1853 AC_MSG_CHECKING([if building for some Win32 platform])
1854 case "$host" in
1855   *-*-mingw*|*-*-cygwin*)
1856     platform_win32=yes
1857     ;;
1858   *)
1859     platform_win32=no
1860     ;;
1861 esac
1862 AC_MSG_RESULT($platform_win32)
1863 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1864
1865 dnl ***********************
1866 dnl *** g_thread checks ***
1867 dnl ***********************
1868
1869 AC_ARG_WITH(threads,
1870            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1871                            [specify a thread implementation to use])],
1872            [],
1873            [with_threads=yes])
1874
1875 dnl error and warning message
1876 dnl *************************
1877
1878 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1879
1880 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1881                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1882                 compilation now, but then your programs might not work.
1883                 Please provide information on how it is done on your system."
1884
1885 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1886                  "
1887
1888 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1889                   provide information on your thread implementation."
1890
1891 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1892                 functions will not be MT-safe during their first call because
1893                 there is no working 'getpwuid_r' on your system."
1894
1895 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1896                 because there is no 'localtime_r' on your system."
1897
1898 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1899                 linking threaded applications. As GLib cannot do that
1900                 automatically, you will get an linkg error everytime you are
1901                 not using the right compiler. In that case you have to relink
1902                 with the right compiler. Ususally just '_r' is appended
1903                 to the compiler name."
1904
1905 dnl determination of thread implementation
1906 dnl ***************************************
1907
1908 AC_MSG_CHECKING(for thread implementation)
1909
1910 have_threads=no
1911 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1912         AS_IF([ test "x$have_threads" = xno], [
1913                 AC_TRY_COMPILE([#include <pthread.h>],
1914                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1915                         have_threads=posix)
1916         ])
1917         # Tru64Unix requires -pthread to find pthread.h. See #103020
1918         if test "x$have_threads" = xno; then
1919                 glib_save_CPPFLAGS="$CPPFLAGS"
1920                 CPPFLAGS="$CPPFLAGS -pthread"
1921                 AC_TRY_COMPILE([#include <pthread.h>],
1922                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1923                        have_threads=posix)
1924                 CPPFLAGS="$glib_save_CPPFLAGS"
1925         fi
1926 ])
1927 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1928         case $host in
1929                 *-*-mingw*)
1930                 have_threads=win32
1931                 ;;
1932         esac
1933 fi
1934
1935 if test "x$have_threads" = xno; then
1936         AC_MSG_RESULT(none available)
1937         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1938 else
1939         AC_MSG_RESULT($have_threads)
1940 fi
1941
1942
1943 dnl determination of G_THREAD_CFLAGS
1944 dnl ********************************
1945
1946 G_THREAD_LIBS=
1947 G_THREAD_LIBS_EXTRA=
1948 G_THREAD_CFLAGS=
1949
1950 dnl
1951 dnl Test program for basic POSIX threads functionality
1952 dnl
1953 m4_define([glib_thread_test],[
1954 #include <pthread.h>
1955 int check_me = 0;
1956 void* func(void* data) {check_me = 42; return &check_me;}
1957 int main()
1958  { pthread_t t;
1959    void *ret;
1960    pthread_create (&t, $1, func, 0);
1961    pthread_join (t, &ret);
1962    return (check_me != 42 || ret != &check_me);
1963 }])
1964
1965 AS_IF([ test x"$have_threads" = xposix], [
1966   # First we test for posix, whether -pthread or -pthreads do the trick as
1967   # both CPPFLAG and LIBS.
1968   # One of them does for most gcc versions and some other platforms/compilers
1969   # too and could be considered as the canonical way to go.
1970   case $host in
1971     *-*-cygwin*|*-*-darwin*)
1972        # skip cygwin and darwin -pthread or -pthreads test
1973        ;;
1974     *-solaris*)
1975       # These compiler/linker flags work with both Sun Studio and gcc
1976       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1977       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1978       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1979       G_THREAD_LIBS="-lpthread -lthread"
1980       ;;
1981     *)
1982       for flag in pthread pthreads mt; do
1983         glib_save_CFLAGS="$CFLAGS"
1984         CFLAGS="$CFLAGS -$flag"
1985         AC_TRY_RUN(glib_thread_test(0),
1986                    glib_flag_works=yes,
1987                    glib_flag_works=no,
1988                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1989                                    glib_flag_works=yes,
1990                                    glib_flag_works=no)])
1991         CFLAGS="$glib_save_CFLAGS"
1992         if test $glib_flag_works = yes ; then
1993            G_THREAD_CFLAGS=-$flag
1994         G_THREAD_LIBS=-$flag
1995         break;
1996         fi
1997       done
1998        ;;
1999   esac
2000 ])
2001
2002 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2003
2004   # The canonical -pthread[s] does not work. Try something different.
2005
2006   case $host in
2007         *-aix*)
2008                 if test x"$GCC" = xyes; then
2009                         # GCC 3.0 and above needs -pthread.
2010                         # Should be coverd by the case above.
2011                         # GCC 2.x and below needs -mthreads
2012                         G_THREAD_CFLAGS="-mthreads"
2013                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2014                 else
2015                         # We are probably using the aix compiler. Normaly a
2016                         # program would have to be compiled with the _r variant
2017                         # of the corresponding compiler, but we as GLib cannot
2018                         # do that: but the good news is that for compiling the
2019                         # only difference is the added -D_THREAD_SAFE compile
2020                         # option. This is according to the "C for AIX User's
2021                         # Guide".
2022                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2023                 fi
2024                 ;;
2025         *-sysv5uw7*) # UnixWare 7
2026                 # We are not using gcc with -pthread. Catched above.
2027                 G_THREAD_CFLAGS="-Kthread"
2028                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2029                 ;;
2030         *-mingw*)
2031                 # No flag needed when using MSVCRT.DLL
2032                 G_THREAD_CFLAGS=""
2033                 ;;
2034         *)
2035                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2036                 ;;
2037   esac
2038 ])
2039
2040 # if we are not finding the localtime_r function, then we probably are
2041 # not using the proper multithread flag
2042
2043 glib_save_CPPFLAGS="$CPPFLAGS"
2044 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2045
2046 # First we test, whether localtime_r is declared in time.h
2047 # directly. Then we test whether a macro localtime_r exists, in
2048 # which case localtime_r in the test program is replaced and thus
2049 # if we still find localtime_r in the output, it is not defined as
2050 # a macro.
2051
2052 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2053   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2054                                                            localtime_r(a,b)],
2055                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2056
2057 CPPFLAGS="$glib_save_CPPFLAGS"
2058
2059 AC_MSG_CHECKING(thread related cflags)
2060 AC_MSG_RESULT($G_THREAD_CFLAGS)
2061 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2062
2063 dnl determination of G_THREAD_LIBS
2064 dnl ******************************
2065
2066 AS_IF([test x$have_threads = xposix], [
2067           glib_save_CPPFLAGS="$CPPFLAGS"
2068           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2069           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2070             case $host in
2071               *-aix*)
2072                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2073                 # probably using the aix compiler.
2074                 AC_MSG_WARN($AIX_COMPILE_INFO)
2075                 ;;
2076               *)
2077                 G_THREAD_LIBS=error
2078                 glib_save_LIBS="$LIBS"
2079                 for thread_lib in "" pthread pthread32 pthreads thread; do
2080                         if test x"$thread_lib" = x; then
2081                                 add_thread_lib=""
2082                                 IN=""
2083                         else
2084                                 add_thread_lib="-l$thread_lib"
2085                                 IN=" in -l$thread_lib"
2086                         fi
2087                         if test x"$have_threads" = xposix; then
2088                                 defattr=0
2089                         else
2090                                 defattr=pthread_attr_default
2091                         fi
2092
2093                         LIBS="$add_thread_lib $glib_save_LIBS"
2094
2095                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2096                         AC_TRY_RUN(glib_thread_test($defattr),
2097                                    glib_result=yes,
2098                                    glib_result=no,
2099                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2100                                                    glib_result=yes,
2101                                                    glib_result=no)])
2102                         AC_MSG_RESULT($glib_result)
2103
2104                         if test "$glib_result" = "yes" ; then
2105                           G_THREAD_LIBS="$add_thread_lib"
2106                           break
2107                         fi
2108                 done
2109                 if test "x$G_THREAD_LIBS" = xerror; then
2110                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2111                 fi
2112                 LIBS="$glib_save_LIBS"
2113                 ;;
2114             esac
2115           ])
2116
2117           g_threads_impl="POSIX"
2118           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2119           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2120           CPPFLAGS="$glib_save_CPPFLAGS"
2121 ], [test x$have_threads = xwin32], [
2122            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2123            g_threads_impl="WIN32"
2124 ], [
2125            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2126            g_threads_impl="NONE"
2127            G_THREAD_LIBS=error
2128 ])
2129 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2130 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2131 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2132
2133 if test "x$G_THREAD_LIBS" = xerror; then
2134         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2135 fi
2136
2137 AC_MSG_CHECKING(thread related libraries)
2138 AC_MSG_RESULT($G_THREAD_LIBS)
2139
2140 dnl check for mt safe function variants and some posix functions
2141 dnl ************************************************************
2142
2143 glib_save_LIBS="$LIBS"
2144 # we are not doing the following for now, as this might require glib
2145 # to always be linked with the thread libs on some platforms.
2146 # LIBS="$LIBS $G_THREAD_LIBS"
2147 AC_CHECK_FUNCS(localtime_r gmtime_r)
2148 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2149         AC_CACHE_CHECK([for posix getpwuid_r],
2150                 ac_cv_func_posix_getpwuid_r,
2151                 [AC_TRY_RUN([
2152 #include <errno.h>
2153 #include <pwd.h>
2154 int main () {
2155     char buffer[10000];
2156     struct passwd pwd, *pwptr = &pwd;
2157     int error;
2158     errno = 0;
2159     error = getpwuid_r (0, &pwd, buffer,
2160                         sizeof (buffer), &pwptr);
2161    return (error < 0 && errno == ENOSYS)
2162            || error == ENOSYS;
2163 }                               ],
2164                         [ac_cv_func_posix_getpwuid_r=yes],
2165                         [ac_cv_func_posix_getpwuid_r=no])])
2166         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2167         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2168                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2169                         [Have POSIX function getpwuid_r])
2170         else
2171                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2172                         ac_cv_func_nonposix_getpwuid_r,
2173                         [AC_TRY_LINK([#include <pwd.h>],
2174                                 [char buffer[10000];
2175                                 struct passwd pwd;
2176                                 getpwuid_r (0, &pwd, buffer,
2177                                                 sizeof (buffer));],
2178                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2179                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2180                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2181                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2182                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2183                                 [Have non-POSIX function getpwuid_r])
2184                 fi
2185         fi
2186 ])
2187 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2188         AC_CACHE_CHECK([for posix getgrgid_r],
2189                 ac_cv_func_posix_getgrgid_r,
2190                 [AC_TRY_RUN([
2191 #include <errno.h>
2192 #include <grp.h>
2193 int main () {
2194     char buffer[10000];
2195     struct group grp, *grpptr = &grp;
2196     int error;
2197     errno = 0;
2198     error = getgrgid_r (0, &grp, buffer,
2199                         sizeof (buffer), &grpptr);
2200    return (error < 0 && errno == ENOSYS)
2201            || error == ENOSYS;
2202 }                              ],
2203                        [ac_cv_func_posix_getgrgid_r=yes],
2204                        [ac_cv_func_posix_getgrgid_r=no])])
2205         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2206         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2207                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2208                         [Have POSIX function getgrgid_r])
2209         ], [
2210                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2211                         ac_cv_func_nonposix_getgrgid_r,
2212                         [AC_TRY_LINK([#include <grp.h>],
2213                                 [char buffer[10000];
2214                                 struct group grp;
2215                                 getgrgid_r (0, &grp, buffer,
2216                                 sizeof (buffer));],
2217                         [ac_cv_func_nonposix_getgrgid_r=yes],
2218                         [ac_cv_func_nonposix_getgrgid_r=no])])
2219                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2220                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2221                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2222                                 [Have non-POSIX function getgrgid_r])
2223                 fi
2224         ])
2225 ])
2226 LIBS="$G_THREAD_LIBS $LIBS"
2227 AS_IF([ test x"$have_threads" = xposix], [
2228         glib_save_CPPFLAGS="$CPPFLAGS"
2229         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2230         # This is not AC_CHECK_FUNC to also work with function
2231         # name mangling in header files.
2232         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2233         AC_LINK_IFELSE(
2234             [AC_LANG_PROGRAM(
2235                 [#include <pthread.h>],
2236                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2237             [AC_MSG_RESULT(yes)
2238              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2239                 [Have function pthread_attr_setstacksize])],
2240             [AC_MSG_RESULT(no)])
2241         AC_MSG_CHECKING(for pthread_condattr_setclock)
2242         AC_LINK_IFELSE(
2243             [AC_LANG_PROGRAM(
2244                 [#include <pthread.h>],
2245                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2246             [AC_MSG_RESULT(yes)
2247              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2248                 [Have function pthread_condattr_setclock])],
2249             [AC_MSG_RESULT(no)])
2250         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic)
2251         AC_LINK_IFELSE(
2252             [AC_LANG_PROGRAM(
2253                 [#include <pthread.h>],
2254                 [pthread_cond_timedwait_monotonic(NULL, NULL, NULL)])],
2255             [AC_MSG_RESULT(yes)
2256              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC,1,
2257                 [Have function pthread_cond_timedwait_monotonic])],
2258             [AC_MSG_RESULT(no)])
2259         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic_np)
2260         AC_LINK_IFELSE(
2261             [AC_LANG_PROGRAM(
2262                 [#include <pthread.h>],
2263                 [pthread_cond_timedwait_monotonic_np(NULL, NULL, NULL)])],
2264             [AC_MSG_RESULT(yes)
2265              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC_NP,1,
2266                 [Have function pthread_cond_timedwait_monotonic_np])],
2267             [AC_MSG_RESULT(no)])
2268         CPPFLAGS="$glib_save_CPPFLAGS"
2269 ])
2270
2271 LIBS="$glib_save_LIBS"
2272
2273 # now spit out all the warnings.
2274 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2275    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2276         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2277 fi
2278 if test "$ac_cv_func_localtime_r" != "yes"; then
2279         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2280 fi
2281
2282 #
2283 # Hack to deal with:
2284 #
2285 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2286 #     building shared libraries with linux.
2287 #  b) FreeBSD doesn't do this either.
2288 #
2289 case $host in
2290   *android*)
2291     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2292     ;;
2293   *-*-freebsd*|*-*-linux*)
2294     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2295     ;;
2296   *-*-openbsd*)
2297     LDFLAGS="$LDFLAGS -pthread"
2298     ;;
2299   *)
2300     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2301     ;;
2302 esac
2303
2304 AC_SUBST(G_THREAD_CFLAGS)
2305 AC_SUBST(G_THREAD_LIBS)
2306 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2307 AC_SUBST(G_THREAD_LIBS_EXTRA)
2308
2309 AC_CHECK_FUNCS(clock_gettime, [], [
2310   AC_CHECK_LIB(rt, clock_gettime, [
2311     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2312     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2313     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2314   ])
2315 ])
2316
2317
2318 dnl ************************
2319 dnl *** g_atomic_* tests ***
2320 dnl ************************
2321
2322 dnl We need to decide at configure time if GLib will use real atomic
2323 dnl operations ("lock free") or emulated ones with a mutex.  This is
2324 dnl because we must put this information in glibconfig.h so we know if
2325 dnl it is safe or not to inline using compiler intrinsics directly from
2326 dnl the header.
2327 dnl
2328 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2329 dnl user is interested in knowing if they can use the atomic ops across
2330 dnl processes.
2331 dnl
2332 dnl We can currently support the atomic ops natively when building GLib
2333 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2334 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2335 dnl we are using GCC (and not mingw*).
2336 dnl
2337 dnl Note that the atomic ops are only available with GCC on x86 when
2338 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2339 dnl not available but would be available given the right flags, we want
2340 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2341 dnl that then to silently fall back on emulated atomic ops just because
2342 dnl the user had the wrong build environment.
2343
2344 dnl We may add other compilers here in the future...
2345
2346 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2347   case $host in
2348     *-*-mingw*)
2349       glib_cv_g_atomic_lock_free=yes
2350       ;;
2351     *)
2352       AC_TRY_LINK([],
2353                      [volatile int atomic = 2;\
2354                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2355                      [glib_cv_g_atomic_lock_free=yes],
2356                      [glib_cv_g_atomic_lock_free=no])
2357       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2358         SAVE_CFLAGS="${CFLAGS}"
2359         CFLAGS="-march=i486"
2360         AC_TRY_LINK([],
2361                        [volatile int atomic = 2;\
2362                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2363                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2364                        [])
2365         CFLAGS="${SAVE_CFLAGS}"
2366       fi
2367       ;;
2368   esac])
2369
2370
2371 case $host in
2372   *-*-mingw*)
2373     ;;
2374   *)
2375     # Some compilers support atomic operations but do not define
2376     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2377     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2378       AC_TRY_LINK([],
2379                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2380                      [],
2381                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2382     fi
2383     ;;
2384  esac
2385
2386 dnl We need a more robust approach here...
2387 case $host_cpu in
2388   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2389     glib_memory_barrier_needed=no
2390     ;;
2391   sparc*|alpha*|powerpc*|ia64)
2392     glib_memory_barrier_needed=yes
2393     ;;
2394   *)
2395     glib_memory_barrier_needed=yes
2396     ;;
2397 esac
2398
2399 dnl ************************
2400 dnl ** Check for futex(2) **
2401 dnl ************************
2402 AC_CACHE_CHECK(for futex(2) system call,
2403     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2404 #include <linux/futex.h>
2405 #include <sys/syscall.h>
2406 #include <unistd.h>
2407 ],[
2408 int
2409 main (void)
2410 {
2411   /* it is not like this actually runs or anything... */
2412   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2413   return 0;
2414 }
2415 ])],glib_cv_futex=yes,glib_cv_futex=no))
2416 if test x"$glib_cv_futex" = xyes; then
2417   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2418 fi
2419
2420 AC_CACHE_CHECK(for eventfd(2) system call,
2421     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2422 #include <sys/eventfd.h>
2423 #include <unistd.h>
2424 ],[
2425 int
2426 main (void)
2427 {
2428   eventfd (0, EFD_CLOEXEC);
2429   return 0;
2430 }
2431 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2432 if test x"$glib_cv_eventfd" = x"yes"; then
2433   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2434 fi
2435 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2436
2437 dnl ****************************************
2438 dnl *** GLib POLL* compatibility defines ***
2439 dnl ****************************************
2440
2441 glib_poll_includes=["
2442 #include <sys/types.h>
2443 #include <sys/poll.h>
2444 "]
2445
2446 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2447    test $ac_cv_header_sys_poll_h = yes ], [
2448   glib_failed=false
2449   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2450   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2451   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2452   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2453   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2454   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2455   if $glib_failed ; then
2456     AC_MSG_ERROR([Could not determine values for POLL* constants])
2457   fi
2458 ], [
2459   glib_cv_value_POLLIN=1
2460   glib_cv_value_POLLOUT=4
2461   glib_cv_value_POLLPRI=2
2462   glib_cv_value_POLLERR=8
2463   glib_cv_value_POLLHUP=16
2464   glib_cv_value_POLLNVAL=32
2465 ])
2466
2467 AC_MSG_CHECKING([for broken poll])
2468 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2469         #include <stdlib.h>
2470         #include <fcntl.h>
2471         #include <poll.h>
2472         #ifdef HAVE_SYS_POLL_H
2473         #include <sys/poll.h>
2474         #endif
2475         int main(void) {
2476           struct pollfd fds[1];
2477           int fd;
2478           fd = open("/dev/null", 1);
2479           fds[0].fd = fd;
2480           fds[0].events = POLLIN;
2481           fds[0].revents = 0;
2482           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2483                 exit(1);  /* Does not work for devices -- fail */
2484           }
2485           exit(0);
2486         }]])],
2487   [broken_poll=no],
2488   [broken_poll=yes
2489    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2490   [broken_poll="no (cross compiling)"])
2491 AC_MSG_RESULT($broken_poll)
2492
2493 dnl *********************
2494 dnl *** GRegex checks ***
2495 dnl *********************
2496
2497 PCRE_REQUIRED_VERSION=8.13
2498
2499 # Check if we should use the internal or the system-supplied pcre
2500 AC_ARG_WITH(pcre,
2501             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2502                             [whether to use system PCRE [default=internal]])])
2503
2504 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2505
2506 AS_IF([ test "x$with_pcre" = xsystem], [
2507   PKG_CHECK_MODULES(PCRE,
2508                     libpcre >= $PCRE_REQUIRED_VERSION)
2509   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2510                   glib_save_CFLAGS="$CFLAGS"
2511                   glib_save_LIBS="$LIBS"
2512                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2513                   AC_TRY_RUN([#include <pcre.h>
2514                               int main () {
2515                                 int support;
2516                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2517                                 if (!support)
2518                                   return 1;
2519                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2520                                 if (!support)
2521                                   return 1;
2522                                 return 0;
2523                               }],
2524                   glib_cv_pcre_has_unicode=yes,
2525                   glib_cv_pcre_has_unicode=no,
2526                   glib_cv_pcre_has_unicode=yes)
2527                   CFLAGS="$glib_save_CFLAGS"
2528                   LIBS="$glib_save_LIBS"
2529       ])
2530   if test "$glib_cv_pcre_has_unicode" = "no"; then
2531     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2532   fi
2533   AC_SUBST(PCRE_CFLAGS)
2534   AC_SUBST(PCRE_LIBS)
2535   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2536   PCRE_REQUIRES=libpcre
2537   AC_SUBST(PCRE_REQUIRES)
2538 ], [
2539   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2540   AS_IF([ test x"$GCC" = xyes], [
2541     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2542     save_CFLAGS="$CFLAGS"
2543     CFLAGS="$CFLAGS -Wno-pointer-sign"
2544     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2545                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2546     CFLAGS="$save_CFLAGS"
2547   ])
2548 ])
2549 AC_SUBST(PCRE_WARN_CFLAGS)
2550
2551 dnl **********************
2552 dnl *** Win32 API libs ***
2553 dnl **********************
2554
2555 case $host in
2556   *-*-cygwin*)
2557         G_LIBS_EXTRA="-luser32 -lkernel32"
2558     ;;
2559   *-*-mingw*)
2560         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2561     ;;
2562   *)
2563         G_LIBS_EXTRA=""
2564     ;;
2565 esac
2566 AC_SUBST(G_LIBS_EXTRA)
2567
2568 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2569 dnl since we need it for g_iconv()
2570
2571 AC_MSG_CHECKING([for EILSEQ])
2572 AC_TRY_COMPILE([
2573 #include <errno.h>
2574 ],
2575 [
2576 int error = EILSEQ;
2577 ], have_eilseq=yes, have_eilseq=no);
2578 AC_MSG_RESULT($have_eilseq)
2579
2580 dnl ******************************************************************
2581 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2582 dnl *** glib-compile-schemas in PATH                               ***
2583 dnl ******************************************************************
2584
2585 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2586
2587 AS_IF([ test $cross_compiling = yes ], [
2588   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2589   if test x$GLIB_GENMARSHAL = xno; then
2590     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2591   fi
2592
2593   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2594   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2595     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2596   fi
2597
2598   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2599   if test x$GLIB_COMPILE_RESOURCES = xno; then
2600     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2601   fi
2602 ])
2603
2604 dnl **************************
2605 dnl *** Checks for gtk-doc ***
2606 dnl **************************
2607 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2608 # it on it's own line.
2609 m4_ifdef([GTK_DOC_CHECK], [
2610 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2611 ],[
2612 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2613 ])
2614
2615 AC_ARG_ENABLE(man,
2616               [AS_HELP_STRING([--enable-man],
2617                               [generate man pages [default=auto]])],,
2618               enable_man=maybe)
2619
2620 AS_IF([test "$enable_man" != no], [
2621   AC_PATH_PROG([XSLTPROC], [xsltproc])
2622   AS_IF([test -z "$XSLTPROC"], [
2623     AS_IF([test "$enable_man" = yes], [
2624       AC_MSG_ERROR([xsltproc is required for --enable-man])
2625     ])
2626     enable_man=no
2627   ])
2628 ])
2629
2630 AS_IF([ test "$enable_man" != no ], [
2631   dnl check for DocBook DTD in the local catalog
2632   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2633      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2634   AS_IF([test "$have_docbook_dtd" != yes], [
2635     AS_IF([test "$enable_man" = yes ], [
2636       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2637     ])
2638     enable_man=no
2639   ])
2640 ])
2641
2642 AS_IF([test "$enable_man" != no], [
2643   dnl check for DocBook XSL stylesheets in the local catalog
2644   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2645      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2646   AS_IF([ test "$have_docbook_dtd" != yes ], [
2647     AS_IF([ test "$enable_man" = yes ], [
2648       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2649     ])
2650     enable_man=no
2651   ])
2652 ])
2653
2654 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2655
2656 AC_MSG_CHECKING([whether to generate man pages])
2657 AS_IF([ test "$enable_man" != no ], [
2658   AC_MSG_RESULT([yes])
2659 ], [
2660   AC_MSG_RESULT([no])
2661 ])
2662
2663 dnl
2664 dnl Tracing
2665 dnl
2666
2667 AC_ARG_ENABLE([dtrace],
2668              [AS_HELP_STRING([--enable-dtrace],
2669                               [include tracing support for dtrace])])
2670 have_dtrace=no
2671 AC_MSG_CHECKING([whether to include dtrace tracing support])
2672 AS_IF([ test "x$enable_dtrace" != xno], [
2673   if test x$glib_have_carbon = xyes; then
2674     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2675   else
2676     AC_MSG_RESULT([yes])
2677     AC_CHECK_PROGS(DTRACE, dtrace)
2678     if test -z "$DTRACE"; then
2679       if test "x$enable_dtrace" = xyes; then
2680         AC_MSG_ERROR([dtrace not found])
2681       fi
2682     else
2683       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2684                       [if test "x$enable_dtrace" = xyes; then
2685                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2686                        fi])
2687     fi
2688   fi
2689 ], [
2690   AC_MSG_RESULT([no])
2691 ])
2692 if test "x$have_dtrace" = xyes; then
2693   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2694 fi
2695 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2696
2697 AC_MSG_CHECKING([whether to include systemtap tracing support])
2698 AC_ARG_ENABLE([systemtap],
2699              [AS_HELP_STRING([--enable-systemtap],
2700                               [include tracing support for systemtap])])
2701 have_systemtap=no
2702 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2703   have_systemtap=yes
2704 fi
2705 AC_MSG_RESULT(${have_systemtap})
2706
2707 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2708
2709 AC_ARG_WITH([tapset-install-dir],
2710             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2711                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2712             [if test "x${withval}" = x; then
2713                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2714              else
2715                ABS_TAPSET_DIR="${withval}"
2716               fi],
2717             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2718 AC_SUBST(ABS_TAPSET_DIR)
2719
2720 dnl ************************************
2721 dnl *** Enable lcov coverage reports ***
2722 dnl ************************************
2723
2724 AC_ARG_ENABLE(gcov,
2725   AS_HELP_STRING([--enable-gcov],
2726                  [enable coverage testing with gcov]),
2727   [use_gcov=$enableval], [use_gcov=no])
2728
2729 AS_IF([ test "x$use_gcov" = "xyes"], [
2730   dnl we need gcc:
2731   if test "$GCC" != "yes"; then
2732     AC_MSG_ERROR([GCC is required for --enable-gcov])
2733   fi
2734
2735   dnl Check if ccache is being used
2736   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2737   case `$SHTOOL path $CC` in
2738     *ccache*[)] gcc_ccache=yes;;
2739     *[)] gcc_ccache=no;;
2740   esac
2741
2742   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2743     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2744   fi
2745
2746   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2747   AC_CHECK_PROG(LTP, lcov, lcov)
2748   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2749
2750   AS_IF([ test "$LTP" ], [
2751     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2752       glib_cv_ltp_version=invalid
2753       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2754       for ltp_check_version in $ltp_version_list; do
2755         if test "$ltp_version" = "$ltp_check_version"; then
2756           glib_cv_ltp_version="$ltp_check_version (ok)"
2757         fi
2758       done
2759     ])
2760   ], [
2761     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2762     AC_MSG_ERROR([$ltp_msg])
2763   ])
2764
2765   case $glib_cv_ltp_version in
2766     ""|invalid[)]
2767       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2768       AC_MSG_ERROR([$ltp_msg])
2769       LTP="exit 0;"
2770       ;;
2771   esac
2772
2773   if test -z "$LTP_GENHTML"; then
2774     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2775   fi
2776
2777   dnl Remove all optimization flags from CFLAGS
2778   changequote({,})
2779   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2780   changequote([,])
2781
2782   dnl Add the special gcc flags
2783   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2784   LDFLAGS="$LDFLAGS -lgcov"
2785 ])
2786
2787 dnl ******************************
2788 dnl *** output the whole stuff ***
2789 dnl ******************************
2790
2791 dnl this section will only be run if config.status is invoked with no
2792 dnl arguments, or with "glib/glibconfig.h" as an argument.
2793 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2794 [
2795         outfile=glib/glibconfig.h-tmp
2796         cat > $outfile <<\_______EOF
2797 /* glibconfig.h
2798  *
2799  * This is a generated file.  Please modify 'configure.ac'
2800  */
2801
2802 #ifndef __GLIBCONFIG_H__
2803 #define __GLIBCONFIG_H__
2804
2805 #include <glib/gmacros.h>
2806
2807 _______EOF
2808
2809         echo '#include <limits.h>' >> $outfile
2810         echo '#include <float.h>' >> $outfile
2811         if test x$glib_values_h = xyes; then
2812           echo '#include <values.h>' >> $outfile
2813         fi
2814         if test "$glib_header_alloca_h" = "yes"; then
2815           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2816         fi
2817         if test x$glib_sys_poll_h = xyes; then
2818           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2819         fi
2820         if test x$glib_included_printf != xyes; then
2821           echo "
2822 /* Specifies that GLib's g_print*() functions wrap the
2823  * system printf functions.  This is useful to know, for example,
2824  * when using glibc's register_printf_function().
2825  */" >> $outfile
2826           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2827         fi
2828
2829         cat >> $outfile <<_______EOF
2830
2831 G_BEGIN_DECLS
2832
2833 #define G_MINFLOAT      FLT_MIN
2834 #define G_MAXFLOAT      FLT_MAX
2835 #define G_MINDOUBLE     DBL_MIN
2836 #define G_MAXDOUBLE     DBL_MAX
2837 #define G_MINSHORT      SHRT_MIN
2838 #define G_MAXSHORT      SHRT_MAX
2839 #define G_MAXUSHORT     USHRT_MAX
2840 #define G_MININT        INT_MIN
2841 #define G_MAXINT        INT_MAX
2842 #define G_MAXUINT       UINT_MAX
2843 #define G_MINLONG       LONG_MIN
2844 #define G_MAXLONG       LONG_MAX
2845 #define G_MAXULONG      ULONG_MAX
2846
2847 _______EOF
2848
2849
2850         ### this should always be true in a modern C/C++ compiler
2851         cat >>$outfile <<_______EOF
2852 typedef signed char gint8;
2853 typedef unsigned char guint8;
2854 _______EOF
2855
2856
2857         if test -n "$gint16"; then
2858           cat >>$outfile <<_______EOF
2859 typedef signed $gint16 gint16;
2860 typedef unsigned $gint16 guint16;
2861 #define G_GINT16_MODIFIER $gint16_modifier
2862 #define G_GINT16_FORMAT $gint16_format
2863 #define G_GUINT16_FORMAT $guint16_format
2864 _______EOF
2865         fi
2866
2867
2868         if test -n "$gint32"; then
2869           cat >>$outfile <<_______EOF
2870 typedef signed $gint32 gint32;
2871 typedef unsigned $gint32 guint32;
2872 #define G_GINT32_MODIFIER $gint32_modifier
2873 #define G_GINT32_FORMAT $gint32_format
2874 #define G_GUINT32_FORMAT $guint32_format
2875 _______EOF
2876         fi
2877
2878         cat >>$outfile <<_______EOF
2879 #define G_HAVE_GINT64 1          /* deprecated, always true */
2880
2881 ${glib_extension}typedef signed $gint64 gint64;
2882 ${glib_extension}typedef unsigned $gint64 guint64;
2883
2884 #define G_GINT64_CONSTANT(val)  $gint64_constant
2885 #define G_GUINT64_CONSTANT(val) $guint64_constant
2886 _______EOF
2887
2888         if test x$gint64_format != x ; then
2889           cat >>$outfile <<_______EOF
2890 #define G_GINT64_MODIFIER $gint64_modifier
2891 #define G_GINT64_FORMAT $gint64_format
2892 #define G_GUINT64_FORMAT $guint64_format
2893 _______EOF
2894         else
2895           cat >>$outfile <<_______EOF
2896 #undef G_GINT64_MODIFIER
2897 #undef G_GINT64_FORMAT
2898 #undef G_GUINT64_FORMAT
2899 _______EOF
2900         fi
2901
2902         cat >>$outfile <<_______EOF
2903
2904 #define GLIB_SIZEOF_VOID_P $glib_void_p
2905 #define GLIB_SIZEOF_LONG   $glib_long
2906 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2907 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2908
2909 _______EOF
2910
2911         cat >>$outfile <<_______EOF
2912 typedef signed $glib_ssize_type_define gssize;
2913 typedef unsigned $glib_size_type_define gsize;
2914 #define G_GSIZE_MODIFIER $gsize_modifier
2915 #define G_GSSIZE_MODIFIER $gssize_modifier
2916 #define G_GSIZE_FORMAT $gsize_format
2917 #define G_GSSIZE_FORMAT $gssize_format
2918
2919 #define G_MAXSIZE       G_MAXU$glib_msize_type
2920 #define G_MINSSIZE      G_MIN$glib_mssize_type
2921 #define G_MAXSSIZE      G_MAX$glib_mssize_type
2922
2923 typedef gint64 goffset;
2924 #define G_MINOFFSET     G_MININT64
2925 #define G_MAXOFFSET     G_MAXINT64
2926
2927 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2928 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2929 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2930
2931 _______EOF
2932
2933         if test -z "$glib_unknown_void_p"; then
2934           cat >>$outfile <<_______EOF
2935
2936 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2937 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2938
2939 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2940 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2941
2942 typedef signed $glib_intptr_type_define gintptr;
2943 typedef unsigned $glib_intptr_type_define guintptr;
2944
2945 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2946 #define G_GINTPTR_FORMAT        $gintptr_format
2947 #define G_GUINTPTR_FORMAT       $guintptr_format
2948 _______EOF
2949         else
2950           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2951         fi
2952
2953
2954
2955         cat >>$outfile <<_______EOF
2956 #ifndef G_DISABLE_DEPRECATED
2957 #define g_ATEXIT(proc)  (atexit (proc))
2958 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2959 #endif
2960 $glib_defines
2961 $glib_os
2962 $glib_static_compilation
2963
2964 $glib_vacopy
2965
2966 #ifdef  __cplusplus
2967 #define G_HAVE_INLINE   1
2968 #else   /* !__cplusplus */
2969 $glib_inline
2970 #endif  /* !__cplusplus */
2971
2972 #ifdef  __cplusplus
2973 #define G_CAN_INLINE    1
2974 _______EOF
2975
2976         if test x$g_can_inline = xyes ; then
2977                 cat >>$outfile <<_______EOF
2978 #else   /* !__cplusplus */
2979 #define G_CAN_INLINE    1
2980 _______EOF
2981         fi
2982
2983         cat >>$outfile <<_______EOF
2984 #endif
2985
2986 _______EOF
2987
2988         if test x$g_have_iso_c_varargs = xyes ; then
2989                 cat >>$outfile <<_______EOF
2990 #ifndef __cplusplus
2991 # define G_HAVE_ISO_VARARGS 1
2992 #endif
2993 _______EOF
2994         fi
2995         if test x$g_have_iso_cxx_varargs = xyes ; then
2996                 cat >>$outfile <<_______EOF
2997 #ifdef __cplusplus
2998 # define G_HAVE_ISO_VARARGS 1
2999 #endif
3000 _______EOF
3001         fi
3002         if test x$g_have_gnuc_varargs = xyes ; then
3003                 cat >>$outfile <<_______EOF
3004
3005 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3006  * is passed ISO vararg support is turned off, and there is no work
3007  * around to turn it on, so we unconditionally turn it off.
3008  */
3009 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3010 #  undef G_HAVE_ISO_VARARGS
3011 #endif
3012
3013 #define G_HAVE_GNUC_VARARGS 1
3014 _______EOF
3015         fi
3016
3017         case x$g_stack_grows in
3018         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3019         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3020         esac
3021
3022
3023         echo >>$outfile
3024         if test x$g_have_eilseq = xno; then
3025                 cat >>$outfile <<_______EOF
3026 #ifndef EILSEQ
3027 /* On some pre-C99 systems, EILSEQ is not defined.
3028  * The correspondence between this and the corresponding definition
3029  * in libiconv is essential.
3030  */
3031 #  define EILSEQ ENOENT
3032 #endif
3033 _______EOF
3034
3035         fi
3036
3037         if test x$g_have_gnuc_visibility = xyes; then
3038                 cat >>$outfile <<_______EOF
3039 #define G_HAVE_GNUC_VISIBILITY 1
3040 _______EOF
3041         fi
3042                 cat >>$outfile <<_______EOF
3043 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3044 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3045 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3046 #define G_GNUC_INTERNAL __hidden
3047 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3048 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3049 #else
3050 #define G_GNUC_INTERNAL
3051 #endif
3052 _______EOF
3053
3054         echo >>$outfile
3055         cat >>$outfile <<_______EOF
3056 #define G_THREADS_ENABLED
3057 #define G_THREADS_IMPL_$g_threads_impl_def
3058 _______EOF
3059
3060         if test x"$g_memory_barrier_needed" != xno; then
3061           echo >>$outfile
3062           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3063         fi
3064         if test x"$g_atomic_lock_free" = xyes; then
3065           echo >>$outfile
3066           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3067         fi
3068         echo >>$outfile
3069         g_bit_sizes="16 32 64"
3070         for bits in $g_bit_sizes; do
3071           cat >>$outfile <<_______EOF
3072 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3073 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3074 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3075 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3076 _______EOF
3077         done
3078
3079         cat >>$outfile <<_______EOF
3080 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3081 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3082 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3083 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3084 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3085 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3086 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3087 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3088 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3089 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3090 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3091 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3092 #define G_BYTE_ORDER $g_byte_order
3093
3094 #define GLIB_SYSDEF_POLLIN =$g_pollin
3095 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3096 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3097 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3098 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3099 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3100
3101 #define G_MODULE_SUFFIX "$g_module_suffix"
3102
3103 typedef $g_pid_type GPid;
3104
3105 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3106 #define GLIB_SYSDEF_AF_INET $g_af_inet
3107 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3108
3109 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3110 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3111 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3112
3113 G_END_DECLS
3114
3115 #endif /* __GLIBCONFIG_H__ */
3116 _______EOF
3117
3118
3119         if cmp -s $outfile glib/glibconfig.h; then
3120           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3121           rm -f $outfile
3122         else
3123           mv $outfile glib/glibconfig.h
3124         fi
3125 ],[
3126
3127 # Note that if two cases are the same, case goes with the first one.
3128 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3129 # on variable expansion in case labels.  Look at the generated config.status
3130 # for a hint.
3131
3132 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3133   glib_header_alloca_h="$ac_cv_working_alloca_h"
3134 else
3135   glib_header_alloca_h="$ac_cv_header_alloca_h"
3136 fi
3137
3138 if test x$ac_cv_header_sys_poll_h = xyes ; then
3139   glib_sys_poll_h=yes
3140 fi
3141
3142 if test x$enable_included_printf = xyes ; then
3143   glib_included_printf=yes
3144 fi
3145
3146 case 2 in
3147 $ac_cv_sizeof_short)
3148   gint16=short
3149   gint16_modifier='"h"'
3150   gint16_format='"hi"'
3151   guint16_format='"hu"'
3152   ;;
3153 $ac_cv_sizeof_int)
3154   gint16=int
3155   gint16_modifier='""'
3156   gint16_format='"i"'
3157   guint16_format='"u"'
3158   ;;
3159 esac
3160 case 4 in
3161 $ac_cv_sizeof_short)
3162   gint32=short
3163   gint32_modifier='"h"'
3164   gint32_format='"hi"'
3165   guint32_format='"hu"'
3166   ;;
3167 $ac_cv_sizeof_int)
3168   gint32=int
3169   gint32_modifier='""'
3170   gint32_format='"i"'
3171   guint32_format='"u"'
3172   ;;
3173 $ac_cv_sizeof_long)
3174   gint32=long
3175   gint32_modifier='"l"'
3176   gint32_format='"li"'
3177   guint32_format='"lu"'
3178   ;;
3179 esac
3180 case 8 in
3181 $ac_cv_sizeof_int)
3182   gint64=int
3183   gint64_modifier='""'
3184   gint64_format='"i"'
3185   guint64_format='"u"'
3186   glib_extension=
3187   gint64_constant='(val)'
3188   guint64_constant='(val)'
3189   ;;
3190 $ac_cv_sizeof_long)
3191   gint64=long
3192   gint64_modifier='"l"'
3193   gint64_format='"li"'
3194   guint64_format='"lu"'
3195   glib_extension=
3196   gint64_constant='(val##L)'
3197   guint64_constant='(val##UL)'
3198   ;;
3199 $ac_cv_sizeof_long_long)
3200   gint64='long long'
3201   if test -n "$glib_cv_long_long_format"; then
3202     gint64_modifier='"'$glib_cv_long_long_format'"'
3203     gint64_format='"'$glib_cv_long_long_format'i"'
3204     guint64_format='"'$glib_cv_long_long_format'u"'
3205   fi
3206   glib_extension='G_GNUC_EXTENSION '
3207   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3208   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3209   ;;
3210 $ac_cv_sizeof___int64)
3211   gint64='__int64'
3212   if test -n "$glib_cv_long_long_format"; then
3213     gint64_modifier='"'$glib_cv_long_long_format'"'
3214     gint64_format='"'$glib_cv_long_long_format'i"'
3215     guint64_format='"'$glib_cv_long_long_format'u"'
3216   fi
3217   glib_extension=
3218   gint64_constant='(val##i64)'
3219   guint64_constant='(val##ui64)'
3220   ;;
3221 esac
3222 glib_size_t=$ac_cv_sizeof_size_t
3223 glib_ssize_t=$ac_cv_sizeof_ssize_t
3224 glib_size_type_define="$glib_size_type"
3225 glib_ssize_type_define="$glib_ssize_type"
3226 glib_void_p=$ac_cv_sizeof_void_p
3227 glib_long=$ac_cv_sizeof_long
3228
3229 case "$glib_size_type" in
3230 short)
3231   gsize_modifier='"h"'
3232   gsize_format='"hu"'
3233   glib_msize_type='SHRT'
3234   ;;
3235 int)
3236   gsize_modifier='""'
3237   gsize_format='"u"'
3238   glib_msize_type='INT'
3239   ;;
3240 long)
3241   gsize_modifier='"l"'
3242   gsize_format='"lu"'
3243   glib_msize_type='LONG'
3244   ;;
3245 "long long"|__int64)
3246   gsize_modifier='"I64"'
3247   gsize_format='"I64u"'
3248   glib_msize_type='INT64'
3249   ;;
3250 esac
3251
3252 case "$glib_ssize_type" in
3253 short)
3254   gssize_modifier='"h"'
3255   gssize_format='"hi"'
3256   glib_mssize_type='SHRT'
3257   ;;
3258 int)
3259   gssize_modifier='""'
3260   gssize_format='"i"'
3261   glib_mssize_type='INT'
3262   ;;
3263 long)
3264   gssize_modifier='"l"'
3265   gssize_format='"li"'
3266   glib_mssize_type='LONG'
3267   ;;
3268 "long long"|__int64)
3269   gssize_modifier='"I64"'
3270   gssize_format='"I64i"'
3271   glib_mssize_type='INT64'
3272   ;;
3273 esac
3274
3275 gintbits=`expr $ac_cv_sizeof_int \* 8`
3276 glongbits=`expr $ac_cv_sizeof_long \* 8`
3277 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3278 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3279
3280 case $ac_cv_sizeof_void_p in
3281 $ac_cv_sizeof_int)
3282   glib_intptr_type_define=int
3283   gintptr_modifier='""'
3284   gintptr_format='"i"'
3285   guintptr_format='"u"'
3286   glib_gpi_cast='(gint)'
3287   glib_gpui_cast='(guint)'
3288   ;;
3289 $ac_cv_sizeof_long)
3290   glib_intptr_type_define=long
3291   gintptr_modifier='"l"'
3292   gintptr_format='"li"'
3293   guintptr_format='"lu"'
3294   glib_gpi_cast='(glong)'
3295   glib_gpui_cast='(gulong)'
3296   ;;
3297 $ac_cv_sizeof_long_long)
3298   glib_intptr_type_define='long long'
3299   gintptr_modifier='"I64"'
3300   gintptr_format='"I64i"'
3301   guintptr_format='"I64u"'
3302   glib_gpi_cast='(gint64)'
3303   glib_gpui_cast='(guint64)'
3304   ;;
3305 $ac_cv_sizeof___int64)
3306   glib_intptr_type_define=__int64
3307   gintptr_modifier='"I64"'
3308   gintptr_format='"I64i"'
3309   guintptr_format='"I64u"'
3310   glib_gpi_cast='(gint64)'
3311   glib_gpui_cast='(guint64)'
3312   ;;
3313 *)
3314   glib_unknown_void_p=yes
3315   ;;
3316 esac
3317
3318
3319 glib_defines="
3320 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3321 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3322 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3323 "
3324
3325 case xyes in
3326 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3327 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3328 *)                      glib_vacopy=''
3329 esac
3330
3331 if test x$glib_cv_va_val_copy = xno; then
3332   glib_vacopy="\$glib_vacopy
3333 #define G_VA_COPY_AS_ARRAY 1"
3334 fi
3335
3336 if test x$glib_cv_hasinline = xyes; then
3337     glib_inline='#define G_HAVE_INLINE 1'
3338 fi
3339 if test x$glib_cv_has__inline = xyes; then
3340     glib_inline="\$glib_inline
3341 #define G_HAVE___INLINE 1"
3342 fi
3343 if test x$glib_cv_has__inline__ = xyes; then
3344     glib_inline="\$glib_inline
3345 #define G_HAVE___INLINE__ 1"
3346 fi
3347
3348 g_have_gnuc_varargs=$g_have_gnuc_varargs
3349 g_have_iso_c_varargs=$g_have_iso_c_varargs
3350 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3351
3352 g_can_inline=$g_can_inline
3353 g_have_gnuc_visibility=$g_have_gnuc_visibility
3354 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3355
3356 if test x$ac_cv_c_bigendian = xyes; then
3357   g_byte_order=G_BIG_ENDIAN
3358   g_bs_native=BE
3359   g_bs_alien=LE
3360 else
3361   g_byte_order=G_LITTLE_ENDIAN
3362   g_bs_native=LE
3363   g_bs_alien=BE
3364 fi
3365
3366 g_pollin=$glib_cv_value_POLLIN
3367 g_pollout=$glib_cv_value_POLLOUT
3368 g_pollpri=$glib_cv_value_POLLPRI
3369 g_pollhup=$glib_cv_value_POLLHUP
3370 g_pollerr=$glib_cv_value_POLLERR
3371 g_pollnval=$glib_cv_value_POLLNVAL
3372
3373 # If a family is not found on the system, define that family to
3374 # a negative value, picking a different one for each undefined
3375 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3376 # This is needed because glib-mkenums doesn't handle optional
3377 # values in enums, and thus we have to have all existing values
3378 # defined in the enum.
3379 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3380   g_af_unix=$glib_cv_value_AF_UNIX
3381 else
3382   g_af_unix=-1
3383 fi
3384 g_af_inet=$glib_cv_value_AF_INET
3385 g_af_inet6=$glib_cv_value_AF_INET6
3386
3387 g_msg_peek=$glib_cv_value_MSG_PEEK
3388 g_msg_oob=$glib_cv_value_MSG_OOB
3389 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3390
3391 g_stack_grows=$glib_cv_stack_grows
3392
3393 g_have_eilseq=$have_eilseq
3394
3395 g_threads_impl_def=$g_threads_impl
3396
3397 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3398 g_memory_barrier_needed="$glib_memory_barrier_needed"
3399 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3400
3401 g_module_suffix="$glib_gmodule_suffix"
3402
3403 g_pid_type="$glib_pid_type"
3404 case $host in
3405   *-*-cygwin*)
3406     glib_os="#define G_OS_UNIX
3407 #define G_PLATFORM_WIN32
3408 #define G_WITH_CYGWIN"
3409     ;;
3410   *-*-mingw*)
3411     glib_os="#define G_OS_WIN32
3412 #define G_PLATFORM_WIN32"
3413     ;;
3414   *)
3415     glib_os="#define G_OS_UNIX"
3416     ;;
3417 esac
3418 glib_static_compilation=""
3419 if test x$glib_win32_static_compilation = xyes; then
3420   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3421 #define GOBJECT_STATIC_COMPILATION 1"
3422 fi
3423 ])
3424
3425 # Redo enough to get guint32 and guint64 for the alignment checks below
3426 case 4 in
3427 $ac_cv_sizeof_short)
3428   gint32=short
3429   ;;
3430 $ac_cv_sizeof_int)
3431   gint32=int
3432   ;;
3433 $ac_cv_sizeof_long)
3434   gint32=long
3435   ;;
3436 esac
3437 case 8 in
3438 $ac_cv_sizeof_int)
3439   gint64=int
3440   ;;
3441 $ac_cv_sizeof_long)
3442   gint64=long
3443   ;;
3444 $ac_cv_sizeof_long_long)
3445   gint64='long long'
3446   ;;
3447 $ac_cv_sizeof___int64)
3448   gint64='__int64'
3449   ;;
3450 esac
3451
3452 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3453 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3454 typedef unsigned $gint32 guint32;])
3455 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3456 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3457 typedef unsigned $gint64 guint64;])
3458 AC_CHECK_TYPE([unsigned long])
3459 AC_CHECK_ALIGNOF([unsigned long])
3460
3461 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3462 #
3463 # 1.2.14 required for dbus_message_set_serial
3464 PKG_CHECK_MODULES(DBUS1,
3465      dbus-1 >= 1.2.14,
3466      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3467      have_dbus1=no)
3468 AC_SUBST(DBUS1_CFLAGS)
3469 AC_SUBST(DBUS1_LIBS)
3470 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3471
3472 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3473 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3474
3475 dnl
3476 dnl Check for -Bsymbolic-functions linker flag used to avoid
3477 dnl intra-library PLT jumps, if available.
3478 dnl
3479
3480 AC_ARG_ENABLE(Bsymbolic,
3481               [AS_HELP_STRING([--disable-Bsymbolic],
3482                               [avoid linking with -Bsymbolic])],,
3483               [SAVED_LDFLAGS="${LDFLAGS}"
3484                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3485                LDFLAGS=-Wl,-Bsymbolic-functions
3486                AC_TRY_LINK([], [int main (void) { return 0; }],
3487                            AC_MSG_RESULT(yes)
3488                            enable_Bsymbolic=yes,
3489                            AC_MSG_RESULT(no)
3490                            enable_Bsymbolic=no)
3491                LDFLAGS="${SAVED_LDFLAGS}"])
3492
3493 if test "x${enable_Bsymbolic}" = "xyes"; then
3494   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3495 fi
3496
3497 AC_SUBST(GLIB_LINK_FLAGS)
3498
3499 dnl
3500 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3501 dnl visibility attributes for symbol export control
3502 dnl
3503 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3504 case "$host" in
3505   *-*-mingw*)
3506     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3507     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3508               [defines how to decorate public symbols while building])
3509     CFLAGS="${CFLAGS} -fvisibility=hidden"
3510     ;;
3511   *)
3512     dnl on other compilers, check if we can do -fvisibility=hidden
3513     SAVED_CFLAGS="${CFLAGS}"
3514     CFLAGS="-fvisibility=hidden"
3515     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3516     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3517                    AC_MSG_RESULT(yes)
3518                    enable_fvisibility_hidden=yes,
3519                    AC_MSG_RESULT(no)
3520                    enable_fvisibility_hidden=no)
3521     CFLAGS="${SAVED_CFLAGS}"
3522
3523     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3524       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3525                 [defines how to decorate public symbols while building])
3526       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3527     ])
3528     ;;
3529 esac
3530 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3531
3532 dnl Compiler flags; macro originates from systemd
3533 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3534 AC_ARG_ENABLE(compile-warnings,
3535               [AS_HELP_STRING([--disable-compile-warnings],
3536                               [Don't use builtin compiler warnings])],,
3537                               enable_compile_warnings=yes)
3538 AS_IF([test "x$enable_compile_warnings" = xyes], [
3539   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3540    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3541    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3542    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3543    -Werror=format=2 -Werror=missing-include-dirs])
3544 ])
3545 AC_SUBST(GLIB_WARN_CFLAGS)
3546
3547 #
3548 # Define variables corresponding to the correct include paths to use for
3549 # in-tree building.
3550 #
3551
3552 # for config.h:
3553 config_h_INCLUDES='-I$(top_builddir)'
3554 AC_SUBST(config_h_INCLUDES)
3555
3556 # glib:
3557 #   config.h
3558 #   $(top_builddir)/glib: for glibconfig.h
3559 #   $(top_srcdir)/glib:   for glib.h
3560 #   $(top_srcdir):        for everything
3561 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3562 AC_SUBST(glib_INCLUDES)
3563
3564 # gobject:
3565 #   same as glib
3566 gobject_INCLUDES='$(glib_INCLUDES)'
3567 AC_SUBST(gobject_INCLUDES)
3568
3569 # gmodule:
3570 #   glib includes
3571 #   $(top_srcdir)/gmodule: for gmodule.h
3572 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3573 AC_SUBST(gmodule_INCLUDES)
3574
3575 # gio:
3576 #   same as gmodule
3577 gio_INCLUDES='$(gmodule_INCLUDES)'
3578 AC_SUBST(gio_INCLUDES)
3579
3580
3581 AC_CONFIG_FILES([
3582 glib-2.0.pc
3583 gmodule-2.0.pc
3584 gmodule-export-2.0.pc
3585 gmodule-no-export-2.0.pc
3586 gthread-2.0.pc
3587 gobject-2.0.pc
3588 gio-2.0.pc
3589 gio-unix-2.0.pc
3590 gio-windows-2.0.pc
3591 glib-zip
3592 glib-gettextize
3593 Makefile
3594 build/Makefile
3595 build/win32/Makefile
3596 build/win32/dirent/Makefile
3597 build/win32/vs9/Makefile
3598 build/win32/vs10/Makefile
3599 build/win32/vs11/Makefile
3600 glib/Makefile
3601 glib/glib.stp
3602 glib/libcharset/Makefile
3603 glib/gnulib/Makefile
3604 glib/pcre/Makefile
3605 glib/update-pcre/Makefile
3606 glib/tests/Makefile
3607 gmodule/Makefile
3608 gmodule/gmoduleconf.h
3609 gobject/Makefile
3610 gobject/gobject.stp
3611 gobject/glib-mkenums
3612 gobject/tests/Makefile
3613 gthread/Makefile
3614 gio/Makefile
3615 gio/gdbus-2.0/codegen/Makefile
3616 gio/gdbus-2.0/codegen/config.py
3617 gio/gnetworking.h
3618 gio/xdgmime/Makefile
3619 gio/inotify/Makefile
3620 gio/kqueue/Makefile
3621 gio/fen/Makefile
3622 gio/fam/Makefile
3623 gio/win32/Makefile
3624 gio/tests/Makefile
3625 gio/tests/gdbus-object-manager-example/Makefile
3626 gio/tests/services/Makefile
3627 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3628 po/Makefile.in
3629 docs/Makefile
3630 docs/reference/Makefile
3631 docs/reference/glib/Makefile
3632 docs/reference/glib/version.xml
3633 docs/reference/gobject/Makefile
3634 docs/reference/gobject/version.xml
3635 docs/reference/gio/Makefile
3636 docs/reference/gio/gdbus-object-manager-example/Makefile
3637 docs/reference/gio/version.xml
3638 tests/Makefile
3639 tests/gobject/Makefile
3640 tests/refcount/Makefile
3641 m4macros/Makefile
3642 ])
3643
3644 AC_CONFIG_COMMANDS([chmod-scripts],
3645 [chmod 0755 glib-zip
3646 chmod 0755 glib-gettextize
3647 chmod 0755 gobject/glib-mkenums])
3648
3649 # we want to invoke this macro solely so that the config.status script
3650 # and automake generated makefiles know about these generated files.
3651 # They are only needed to distcheck the package
3652 if false; then
3653   AC_CONFIG_FILES([
3654     INSTALL
3655     README
3656     config.h.win32
3657     glib/glibconfig.h.win32
3658     glib/makefile.msc
3659     glib/glib.rc
3660     gmodule/makefile.msc
3661     gmodule/gmodule.rc
3662     gobject/makefile.msc
3663     gobject/gobject.rc
3664     gthread/makefile.msc
3665     gthread/gthread.rc
3666     gio/gio.rc
3667     tests/makefile.msc
3668   ])
3669 fi
3670
3671 AC_OUTPUT