configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.69])
  19 AC_INIT([GNU Automake], [1.13.0a], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([dist-xz filename-length-max=99 color-tests
  43                   no-define no-dependencies])
  44
  45 ## Keep this on a line of its own, since it must be found and processed
  46 ## by the 'update-copyright' rule in our Makefile.
  47 RELEASE_YEAR=2012
  48 AC_SUBST([RELEASE_YEAR])
  49
  50 # The API version is the base version.  We must guarantee
  51 # compatibility for all releases with the same API version.
  52 # Our current rule is that:
  53 # * All releases, including the prereleases, in an X.Y series
  54 #   are compatible.  So 1.5.1c is compatible with 1.5.
  55 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  56 #   aren't the same.
  57 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  58 AC_SUBST([APIVERSION])
  59
  60 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  61 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  62 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  63 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  64 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  65
  66 # Our build system is bootstrapped with the bleeding-edge versions of
  67 # aclocal and automake, hence the remake rules must use those versions
  68 # as well.  The extra quoting is to cater to cases when the build
  69 # directory contains whitespace or shell metacharacters.
  70 ACLOCAL="\"`pwd`/t/wrap/aclocal-$APIVERSION\""
  71 AUTOMAKE="\"`pwd`/t/wrap/automake-$APIVERSION\""
  72
  73 AC_PROG_LN_S
  74
  75 AC_PATH_PROG([PERL], [perl])
  76 if test -z "$PERL"; then
  77    AC_MSG_ERROR([perl not found])
  78 fi
  79 # Save details about the selected perl interpreter in config.log.
  80 AM_RUN_LOG([$PERL --version])
  81 $PERL -e 'require 5.006;' || {
  82    AC_MSG_ERROR(
  83 [perl 5.6 or better is required; perl 5.8.2 or better
  84 is recommended.  If you have several perl versions
  85 installed, select the one Automake should use using
  86   ./configure PERL=/path/to/perl])
  87 }
  88
  89 # We require ithreads support, and version 5.7.2 for CLONE.
  90 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  91 [if $PERL -e '
  92     require 5.007_002;
  93     use Config;
  94     if ($Config{useithreads})
  95       {
  96         require threads;
  97         import threads;
  98         require Thread::Queue;
  99         import Thread::Queue;
 100         exit 0;
 101       }
 102     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
 103 then
 104   am_cv_prog_PERL_ithreads=yes
 105 else
 106   am_cv_prog_PERL_ithreads=no
 107 fi])
 108 if test $am_cv_prog_PERL_ithreads = yes; then
 109   PERL_THREADS=1;
 110 else
 111   PERL_THREADS=0;
 112 fi
 113 AC_SUBST([PERL_THREADS])
 114
 115 # The test suite will skip some tests if tex is absent.
 116 AC_CHECK_PROG([TEX], [tex], [tex])
 117 # Save details about the selected TeX program in config.log.
 118 # Redirect input from /dev/null, as TeX might otherwise hang waiting
 119 # for input from the terminal.
 120 AM_RUN_LOG([$TEX --version </dev/null])
 121
 122 # The test suite will skip some tests if no lex or yacc program is
 123 # available.
 124 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
 125 #  1. we don't want flex (resp. bison) to be preferred to system lex
 126 #     (resp. system yacc);
 127 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 128 #     by default;
 129 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 130 #     LEXLIB to be calculated and/or AC_SUBST'd;
 131 #  4. we prefer that the YACC and LEX variables are not reported in the
 132 #     configure help screen.
 133 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 134 AC_CHECK_PROGS([LEX], [lex flex], [false])
 135
 136 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 137 # deletion of any files created (such as those added to
 138 # autom4te.cache).  We used to perform only the last of the three
 139 # following tests, but some users were unable to figure out that their
 140 # installation was broken since --version appeared to work.
 141
 142 required_autoconf_version=2.65
 143 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 144 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 145 then
 146   am_cv_autoconf_installed=yes
 147 else
 148   am_cv_autoconf_installed=no
 149 fi])
 150 if test "$am_cv_autoconf_installed" = no; then
 151   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 152     Please make sure it is installed and in your PATH.])
 153 fi
 154
 155 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 156 [mkdir conftest
 157 echo 'AC''_INIT' > conftest/conftest.ac
 158 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 159 then
 160   am_cv_autoconf_works=yes
 161 else
 162   am_cv_autoconf_works=no
 163 fi
 164 rm -rf conftest])
 165 if test "$am_cv_autoconf_works" = no; then
 166   AC_MSG_ERROR([The installed version of autoconf does not work.
 167     Please check config.log for error messages before this one.])
 168 fi
 169
 170 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 171 [mkdir conftest
 172 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 173 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 174 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 175 then
 176   am_cv_autoconf_version=yes
 177 else
 178   am_cv_autoconf_version=no
 179 fi
 180 rm -rf conftest])
 181 if test "$am_cv_autoconf_version" = no; then
 182   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 183 fi
 184
 185 # Test for ln.  We need use it to install the versioned binaries.
 186 AC_MSG_CHECKING([whether ln works])
 187 AC_CACHE_VAL([am_cv_prog_ln], [
 188 rm -f conftest conftest.file
 189 : >conftest.file
 190 if ln conftest.file conftest 2>/dev/null; then
 191   am_cv_prog_ln=ln
 192 else
 193   am_cv_prog_ln='cp -p'
 194 fi
 195 rm -f conftest conftest.file])
 196 AC_SUBST([LN], [$am_cv_prog_ln])
 197 result=no
 198 test "x$am_cv_prog_ln" = xln && result=yes
 199 AC_MSG_RESULT([$result])
 200
 201 # The amount we should wait after modifying files depends on the platform.
 202 # On Windows '95, '98 and ME, files modifications have 2-seconds
 203 # granularity and can be up to 3 seconds in the future w.r.t. the
 204 # system clock.  When it is important to ensure one file is older
 205 # than another we wait at least 5 seconds between creations.
 206 case $build in
 207   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 208   *)               MODIFICATION_DELAY=2;;
 209 esac
 210 AC_SUBST([MODIFICATION_DELAY])
 211
 212 ## ------------------------------------------- ##
 213 ##  Test for things needed by the test suite.  ##
 214 ## ------------------------------------------- ##
 215
 216 AC_PROG_EGREP
 217 AC_PROG_FGREP
 218
 219 dnl FIXME: could we extract this in a simpler way through autoconf
 220 dnl FIXME: idioms or internals?
 221 AC_DEFUN(
 222   [_AM_INIT_BOURNE_COMPATIBLE_VAR],
 223   [am_bourne_compatible="AS_ESCAPE(_m4_expand([AS_BOURNE_COMPATIBLE]))"])
 224
 225 dnl
 226 dnl Arguments to this macro:
 227 dnl
 228 dnl   $1 - shell to test
 229 dnl   $2 - description of the tested feature
 230 dnl   $3 - shell code used to check the feature; to indicate success,
 231 dnl        it can either exit with status 77, or have the last command
 232 dnl        returning with exit status of zero
 233 dnl   $4 - shell code to execute if the check on the shell is successful
 234 dnl        (defaults to nothing)
 235 dnl   $5 - shell code to execute if the check on the shell is not
 236 dnl        successful (defaults to nothing)
 237 dnl
 238 AC_DEFUN([_AM_CHECK_SHELL_FEATURE],
 239   [AC_REQUIRE([_AM_INIT_BOURNE_COMPATIBLE_VAR])
 240   AC_MSG_CHECKING([whether $1 $2])
 241   if { $1 -c "$am_bourne_compatible
 242 AS_ESCAPE([$3])
 243 test \$? -eq 0 || exit 1
 244 # Use 77 to indicate success (rather than 0), in case some shell
 245 # acts like Solaris 10's /bin/sh, exiting successfully on some
 246 # syntax errors.
 247 exit 77" >&AS_MESSAGE_LOG_FD 2>&1; test $? -eq 77; }
 248   then
 249     AC_MSG_RESULT([yes])
 250     $4
 251   else
 252     AC_MSG_RESULT([no])
 253     $5
 254   fi])
 255
 256 # AM_CHECK_CANDIDATE_TEST_SHELL(SHELL-PATH)
 257 # -----------------------------------------
 258 #
 259 # Check if the given shell is good enough to run our test scripts.
 260 # Inspired to gnulib's 'tests/init.sh'.
 261 #
 262 # We require POSIX and XSI features (e.g., '$(...)' for command
 263 # substitutions, '$((...))' for shell arithmetic, and support for
 264 # '${var#...}' and '${var%...}' parameter expansions).
 265 #
 266 # We require that the shell can correctly trap EXIT when 'set -e' is in
 267 # effect (OSF1/Tru64 sh failed to do so, see commit v1.10b-52-g9fe8259).
 268 #
 269 # We want to able to define shell aliases with the same name of shell
 270 # builtins.
 271 #
 272 # We also prefer shells that, when 'set -x' is in effect, do not also
 273 # redirect traces upon stderr redirections.  For example,
 274 #  $ set -x; echo x 2>file
 275 # would emit "+ echo x" into file with older zsh versions.  Similarly,
 276 #   $ set -x; P=1 true 2>file
 277 # would emit "P=1" into file with /usr/xpg4/bin/sh from Solaris 10 and
 278 # /bin/sh from SunOS 5.11 and OpenBSD 4.7.
 279 #
 280 # Finally, we look for weird bugs and portability problems mentioned in
 281 # the Autoconf manual, and reject shells that suffers from them. (TODO)
 282 #
 283 # Use '$am_score' to indicate the degree of acceptability of the shell.
 284 # A score of "10" means that the shell is good enough for our needs;
 285 # a score of "9" means that the shell has some minor bugs or limitation,
 286 # but is still (barely) acceptable for our uses.  Any other score means
 287 # that the shell is broken or unfit.
 288 #
 289 AC_DEFUN([_AM_CHECK_CANDIDATE_SHELL],
 290   [am_score=10
 291   while :; do
 292
 293     _AM_CHECK_SHELL_FEATURE([$1],
 294       [supports \$(cmd)],
 295       [test "$(echo x)" = x],
 296       [], [am_score=1; break])
 297
 298     _AM_CHECK_SHELL_FEATURE([$1],
 299       [supports \$((expr))],
 300       [test $((1 + 2 * 3)) = 7],
 301       [], [am_score=1; break])
 302
 303     _AM_CHECK_SHELL_FEATURE([$1],
 304       [supports \${@%:@var}],
 305       [zero='' one='x' twelve=' foobar baz!' \
 306         && test ${@%:@zero} -eq 0 \
 307         && test ${@%:@one} -eq 1 \
 308         && test ${@%:@twelve} -eq 12],
 309       [], [am_score=1; break])
 310
 311     _AM_CHECK_SHELL_FEATURE([$1],
 312       [supports \${var@%:@glob} and \${var%glob}],
 313       [v=a/b/c \
 314         && test ${v@%:@*/} = b/c \
 315         && test ${v@%:@@%:@*/} = c \
 316         && test ${v%/*} = a/b \
 317         && test ${v%%/*} = a],
 318       [], [am_score=1; break])
 319
 320     _AM_CHECK_SHELL_FEATURE([$1],
 321       [preserves exit traps with "set -e"],
 322       [set -e; trap 'exit $?' 0; (exit 77); exit 77],
 323       [], [am_score=1; break])
 324
 325     _AM_CHECK_SHELL_FEATURE([$1],
 326       [can define exit traps in a shell function],
 327       [fail=0 && foo() { trap 'fail=1' 0; } && foo && test $fail = 0],
 328       [], [am_score=1; break])
 329
 330     _AM_CHECK_SHELL_FEATURE([$1],
 331       [corrupts stderr with "set -x"],
 332       [(set -x; P=1 true 2>&3) 3>&1 2>/dev/null | grep P=1],
 333       [am_score=9], [])
 334
 335     echo 'return 34' > conftest-return.sh
 336     echo 'ok=no' >> conftest-return.sh
 337     _AM_CHECK_SHELL_FEATURE([$1],
 338       [can return early from "dot-sourced" files],
 339       [ok=yes; . ./conftest-return.sh; test $? -eq 34 && test $ok = yes],
 340       [rm -f conftest-return.sh],
 341       [rm -f conftest-return.sh; am_score=1; break])
 342
 343     echo 'alias false=echo' > conftest-alias.sh
 344     echo 'false && test "$(false 97)" = 97' >> conftest-alias.sh
 345     _AM_CHECK_SHELL_FEATURE([$1],
 346       [supports alias named like shell builtins],
 347       [. ./conftest-alias.sh],
 348       [rm -f conftest-alias.sh],
 349       [rm -f conftest-alias.sh; am_score=1; break])
 350
 351     _AM_CHECK_SHELL_FEATURE([$1],
 352       [supports "test -e"],
 353       [test -e config.log && test -e . && test ! -e nonesuch],
 354       [], [am_score=1; break])
 355
 356     break
 357   done])
 358
 359 # These messages only goes to the config.log file.
 360 AC_MSG_NOTICE([will now look for a sturdy POSIX shell, for our testsuite])
 361
 362 AC_CACHE_VAL(
 363   [ac_cv_AM_TEST_RUNNER_SHELL],
 364   [if test "$AM_TEST_RUNNER_SHELL"; then
 365     # Let the user override it.
 366     ac_cv_AM_TEST_RUNNER_SHELL=$AM_TEST_RUNNER_SHELL
 367   else
 368     ac_cv_AM_TEST_RUNNER_SHELL=no
 369     am_candidate_shells=${CONFIG_SHELL-}
 370     # For the benefit of Solaris.
 371     am_PATH=$PATH$PATH_SEPARATOR/usr/xpg6/bin$PATH_SEPARATOR/usr/xpg4/bin
 372     for am_sh in sh sh5 dash ash bash zsh ksh pdksh; do
 373       AC_PATH_PROG([am_candidate_sh], [$am_sh], [], [$am_PATH])
 374       if test -n "$am_candidate_sh"; then
 375         am_candidate_shells="$am_candidate_shells $am_candidate_sh"
 376       fi
 377       AM_SUBST_NOTMAKE([am_candidate_sh])
 378       # Must nullify these in order not to interfere with the checks in
 379       # the next loop.
 380       AS_UNSET([am_candidate_sh])
 381       AS_UNSET([ac_cv_path_am_candidate_sh])
 382     done
 383     AS_UNSET([am_PATH]) # Not required anymore
 384     for am_sh in $am_candidate_shells; do
 385       am_score=0
 386       _AM_CHECK_CANDIDATE_SHELL([$am_sh])
 387       if test $am_score -eq 9; then
 388         # The shell is barely acceptable for our needs.  We might
 389         # still find one that is even better, so continue looking.
 390         AC_MSG_NOTICE([shell $am_sh is acceptable, but we might do better])
 391         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 392       elif test $am_score -eq 10; then
 393         AC_MSG_NOTICE([shell $am_sh is good enough, stop looking])
 394         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 395         break
 396       fi
 397     done
 398   fi
 399   AM_TEST_RUNNER_SHELL=$ac_cv_AM_TEST_RUNNER_SHELL])
 400
 401 if test $AM_TEST_RUNNER_SHELL = no; then
 402   AC_MSG_FAILURE([m4_normalize([no POSIX shell found that is good
 403                                 enough to be used in our testsuite])])
 404 else
 405   AC_MSG_NOTICE([will use $AM_TEST_RUNNER_SHELL as the testsuite shell])
 406 fi
 407
 408 AC_ARG_VAR([AM_TEST_RUNNER_SHELL],
 409            [a sturdy POSIX shell for our testsuite])
 410
 411
 412 ###########################################################################
 413
 414 # Look for C, C++ and fortran compilers to be used in the testsuite.
 415
 416 dnl We don't want to abort our configuration script if no C compiler is
 417 dnl available, as such a compiler is only required to run part of the
 418 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 419 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 420 dnl easy way to obtain this behaviour, so we'll need a few hacks.
 421
 422 dnl We want the body of this macro to expand as a single shell statement,
 423 dnl thus we wrap it into { ... } brackets.
 424 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 425   AC_MSG_WARN([$1])
 426   am__failed=yes
 427   break
 428 } ])
 429
 430 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 431   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 432   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 433   am__failed=no
 434   while :; do
 435      $1
 436      break
 437   done
 438   AS_IF([test $am__failed = yes], [$2])
 439   # We have to clear these cache variables, so that future checks on
 440   # compilers for different languages won't be confused.
 441   unset ac_cv_objext ac_cv_exeext
 442   # We also need to meddle with the autoconf internals to ensure that
 443   # checks to find object and executable extensions will be run anew.
 444   # FIXME: In the long run, the better thing to do would be to fix
 445   # FIXME: autoconf instead ...
 446   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 447   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 448   m4_popdef([AC_MSG_FAILURE])
 449   m4_popdef([AC_MSG_ERROR])
 450 ])
 451
 452 AC_DEFUN([_AM_SKIP_COMP_TESTS],
 453   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
 454
 455 # Prefer generic compilers to GNU ones when possible.  This will ensure
 456 # more testsuite coverage "in the wild".
 457 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 458 # deliberate; for more discussion and rationale, see:
 459 # <http://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 460
 461 AC_MSG_NOTICE([will now look for generic compilers])
 462
 463 # C compiler.
 464 _AM_COMPILER_CAN_FAIL(dnl
 465   [AC_PROG_CC([cc gcc])],
 466   [CC=false; _AM_SKIP_COMP_TESTS([C])])
 467
 468 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 469
 470 # On case-insensitive file systems (seen e.g. on Cygwin and Mac OS X)
 471 # we must avoid looking for 'CC', because that would be the same as
 472 # 'cc', and could cause $CXX to point to the C compiler, instead of
 473 # to a C++ compiler as expected.  See automake bugs #11893 and #10766.
 474 if test -f /bIn/rMdIr || test -f /uSr/bIn/rMdIr; then
 475   # Case-insensitive file system, don't look for CC.
 476   am_CC=
 477 else
 478   am_CC=CC
 479 fi
 480
 481 # The list of C++ compilers here has been copied, pasted and edited
 482 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 483 # Keep it in sync, or better again, find out a way to avoid this code
 484 # duplication.
 485 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 486   [aCC $am_CC FCC KCC RCC xlC_r xlC c++ cxx cc++ gpp g++])],
 487   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
 488
 489 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 490
 491 # The lists of Fortran compilers here has been copied, pasted and edited
 492 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
 493 # Keep it in sync, or better again, find out a way to avoid this code
 494 # duplication.
 495
 496 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 497   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 498   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
 499   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
 500
 501 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 502
 503 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 504   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
 505   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
 506
 507 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 508
 509 # Some tests will need the GNU compilers.  Searching for them here would
 510 # be overkill, since our testsuite already handles their search and setup
 511 # pretty well.  But in case the compilers already found are the GNU ones,
 512 # we want to use them in the testsuite where GNU compilers are required.
 513 # Also, in case the compilers detected above (at configure time) are not
 514 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
 515 # FFLAGS detected for them with the GNU compilers too, since it's likely
 516 # they won't be compatible.  So we allow the user to define variants of
 517 # these variables for the GNU compilers separately.
 518
 519 AC_MSG_NOTICE([will now look for GNU compilers])
 520
 521 # GNU C compiler.
 522 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
 523 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 524 if test $am_CC_is_GNU = yes; then
 525   AC_MSG_NOTICE([$CC is already a GNU C compiler])
 526   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 527 else
 528   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
 529 fi
 530 if test "$GNU_CC" != false; then
 531   AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
 532         [AC_MSG_WARN([botched installation for GNU C compiler])
 533          _AM_SKIP_COMP_TESTS([GNU C])])
 534 fi
 535
 536 # GNU C++ compiler.
 537 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
 538 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 539 if test $am_CXX_is_GNU = yes; then
 540   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
 541   GNU_CXX=$CXX
 542   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 543 else
 544   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
 545 fi
 546 if test "$GNU_CXX" != false; then
 547   AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
 548         [AC_MSG_WARN([botched installation for GNU C++ compiler])
 549          _AM_SKIP_COMP_TESTS([GNU C++])])
 550 fi
 551
 552 # GNU Fortran compiler.
 553 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
 554 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 555 if test $am_FC_is_GNU = yes; then
 556   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
 557   GNU_FC=$FC
 558   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 559 else
 560   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
 561 fi
 562 if test "$GNU_FC" != false; then
 563   AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
 564         [AC_MSG_WARN([botched installation for GNU Fortran compiler])
 565          _AM_SKIP_COMP_TESTS([GNU Fortran])])
 566 fi
 567
 568 # GNU Fortran 77 compiler.
 569 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
 570 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 571 if test $am_F77_is_GNU = yes; then
 572   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
 573   GNU_F77=$F77
 574   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 575 else
 576   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
 577 fi
 578 if test "$GNU_F77" != false; then
 579   AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
 580         [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
 581         _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
 582 fi
 583
 584 # GNU Java compiler.
 585 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
 586 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
 587 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
 588 if test "$GNU_GCJ" != false; then
 589   AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
 590         [AC_MSG_WARN([botched installation for GNU Java compiler])
 591         _AM_SKIP_COMP_TESTS([GNU Java])])
 592 fi
 593
 594 # If we have been able to find at least a working compiler above, we
 595 # know what the object and executable extensions for this platform are.
 596 OBJEXT=${ac_cv_objext-UNKNOWN}
 597 EXEEXT=${ac_cv_exeext-UNKNOWN}
 598 AC_SUBST([OBJEXT])
 599 AC_SUBST([EXEEXT])
 600
 601 ###########################################################################
 602
 603 ## ---------------------- ##
 604 ##  Create output files.  ##
 605 ## ---------------------- ##
 606
 607 AC_CONFIG_FILES([Makefile])
 608 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 609
 610 AC_CONFIG_FILES([t/wrap/aclocal-${APIVERSION}:t/wrap/aclocal.in],
 611                 [chmod +x t/wrap/aclocal-${APIVERSION}],
 612                 [APIVERSION=$APIVERSION])
 613 AC_CONFIG_FILES([t/wrap/automake-${APIVERSION}:t/wrap/automake.in],
 614                 [chmod +x t/wrap/automake-${APIVERSION}],
 615                 [APIVERSION=$APIVERSION])
 616
 617 AC_OUTPUT
 618
 619 # Inform the user if this version of automake is a beta release or
 620 # a development snapshot.
 621 # According to HACKING, the version of a development snapshot should
 622 # end with an "odd" letter (a, c, ...), the version of a test release
 623 # should end wit an "even" letter (b, d, ...).
 624
 625 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 626 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 627
 628 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 629   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 630   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 631   { print \"development snapshot\"; }"]`
 632
 633 # '$silent' is set to yes if configure is passed the '--quiet' option.
 634 test "$am_release_type" = stable || test "$silent" = yes || cat <<EOF
 635
 636 WARNING: You are about to use a $am_release_type of automake.
 637 WARNING: It might easily suffer from new bugs or regressions.
 638 WARNING: You are strongly advised not to use it in production code.
 639
 640 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>.
 641 EOF
 642
 643 AS_EXIT([0])