configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [32])
  34 m4_define([glib_micro_version], [1])
  35 m4_define([glib_interface_age], [1])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADER([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     glib_native_win32=no
 156     glib_pid_type=int
 157     ;;
 158 esac
 159 case $host in
 160   *-*-linux*)
 161     glib_os_linux=yes
 162     ;;
 163 esac
 164
 165 AC_MSG_RESULT([$glib_native_win32])
 166
 167 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 168
 169 glib_have_carbon=no
 170 AC_MSG_CHECKING([for Mac OS X Carbon support])
 171 AC_TRY_CPP([
 172 #include <Carbon/Carbon.h>
 173 #include <CoreServices/CoreServices.h>
 174 ], glib_have_carbon=yes)
 175
 176 AC_MSG_RESULT([$glib_have_carbon])
 177
 178 glib_have_cocoa=no
 179 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 180 AC_TRY_CPP([
 181 #include <Foundation/Foundation.h>
 182 ], glib_have_cocoa=yes)
 183
 184 AC_MSG_RESULT([$glib_have_cocoa])
 185
 186 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 187 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 188 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 189 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 190 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 191 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 192
 193 if test "$glib_native_win32" = "yes"; then
 194   AC_CHECK_TOOL(WINDRES, windres, no)
 195   if test "$WINDRES" = no; then
 196     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 197   fi
 198   AC_CHECK_TOOL(NM, nm, no)
 199   if test "$NM" = no; then
 200     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 201   fi
 202   AC_CHECK_TOOL(RANLIB, ranlib, :)
 203   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 204 fi
 205 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 206
 207 if test "$glib_native_win32" != yes; then
 208     # libtool option to control which symbols are exported
 209     # right now, symbols starting with _ are not exported
 210     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 211 else
 212     # We currently use .def files on Windows
 213     LIBTOOL_EXPORT_OPTIONS=
 214 fi
 215 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 216
 217 if test "x$glib_have_carbon" = "xyes"; then
 218   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 219   LDFLAGS="$LDFLAGS -framework Carbon"
 220 fi
 221
 222 if test "x$glib_have_cocoa" = "xyes"; then
 223   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 224   LDFLAGS="$LDFLAGS -framework Foundation"
 225 fi
 226
 227 gl_GLIBC21
 228 if test "x$GLIBC21" = "xyes"; then
 229   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 230 fi
 231
 232 dnl declare --enable-* args and collect ac_help strings
 233 AC_ARG_ENABLE(debug,
 234               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 235                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 236               enable_debug=glib_debug_default)
 237
 238 AC_ARG_ENABLE(gc_friendly,
 239               [AC_HELP_STRING([--enable-gc-friendly],
 240                               [turn on garbage collector friendliness [default=no]])],,
 241               [enable_gc_friendly=no])
 242 AC_ARG_ENABLE(mem_pools,
 243               [AC_HELP_STRING([--disable-mem-pools],
 244                               [disable all glib memory pools])],,
 245               [disable_mem_pools=no])
 246 AC_ARG_ENABLE(rebuilds,
 247               [AC_HELP_STRING([--disable-rebuilds],
 248                               [disable all source autogeneration rules])],,
 249               [enable_rebuilds=yes])
 250
 251 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 252 if test "x$enable_gc_friendly" = "xyes"; then
 253   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 254   AC_MSG_RESULT([yes])
 255 else
 256   AC_MSG_RESULT([no])
 257 fi
 258
 259 AC_MSG_CHECKING([whether to disable memory pools])
 260 if test "x$disable_mem_pools" = "xno"; then
 261   AC_MSG_RESULT([no])
 262 else
 263   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 264   AC_MSG_RESULT([yes])
 265 fi
 266
 267 dnl location to install runtime libraries, e.g. ../../lib to install
 268 dnl to /lib if libdir is /usr/lib
 269 AC_ARG_WITH(runtime-libdir,
 270            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 271                            [install runtime libraries relative to libdir])],
 272            [],
 273            [with_runtime_libdir=""])
 274 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 275 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 276 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 277 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 278 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 279
 280 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 281 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 282 AC_LANG_SAVE
 283 AC_LANG_CPLUSPLUS
 284 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 285 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 286 AC_LANG_RESTORE
 287
 288 AM_PROG_CC_STDC
 289 AM_PROG_CC_C_O
 290 AC_PROG_INSTALL
 291
 292 AC_SYS_LARGEFILE
 293
 294 PKG_PROG_PKG_CONFIG(0.16)
 295
 296 if test "x$enable_debug" = "xyes"; then
 297   if test x$cflags_set != xset ; then
 298       case " $CFLAGS " in
 299       *[[\ \    ]]-g[[\ \       ]]*) ;;
 300       *) CFLAGS="$CFLAGS -g" ;;
 301       esac
 302   fi
 303   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 304 else
 305   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 306
 307   if test "x$enable_debug" = "xno"; then
 308     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 309   fi
 310 fi
 311
 312 # Ensure MSVC-compatible struct packing convention is used when
 313 # compiling for Win32 with gcc.
 314 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 315 # gcc2 uses "-fnative-struct".
 316 if test x"$glib_native_win32" = xyes; then
 317   if test x"$GCC" = xyes; then
 318     msnative_struct=''
 319     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 320     if test -z "$ac_cv_prog_CC"; then
 321       our_gcc="$CC"
 322     else
 323       our_gcc="$ac_cv_prog_CC"
 324     fi
 325     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 326       2.)
 327         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 328           msnative_struct='-fnative-struct'
 329         fi
 330         ;;
 331       *)
 332         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 333           msnative_struct='-mms-bitfields'
 334         fi
 335         ;;
 336     esac
 337     if test x"$msnative_struct" = x ; then
 338       AC_MSG_RESULT([no way])
 339       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 340     else
 341       CFLAGS="$CFLAGS $msnative_struct"
 342       AC_MSG_RESULT([${msnative_struct}])
 343     fi
 344   fi
 345 fi
 346 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 347 AC_SUBST(GLIB_EXTRA_CFLAGS)
 348
 349 AC_EXEEXT
 350
 351 # define a MAINT-like variable REBUILD which is set if Perl
 352 # and awk are found, so autogenerated sources can be rebuilt
 353 AC_PROG_AWK
 354 AC_CHECK_PROGS(PERL, [perl5 perl])
 355 # We would like indent, but don't require it.
 356 AC_CHECK_PROG(INDENT, indent, indent)
 357 REBUILD=\#
 358 if test "x$enable_rebuilds" = "xyes" && \
 359      test -n "$PERL" && \
 360      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 361      test -n "$AWK" ; then
 362   REBUILD=
 363 fi
 364 AC_SUBST(REBUILD)
 365
 366 # Need full path to Perl for glib-mkenums
 367 #
 368 if test "x$PERL" != x ; then
 369   AC_PATH_PROG(PERL_PATH, [$PERL])
 370 fi
 371 if test "x$PERL_PATH" = x ; then
 372   PERL_PATH="/usr/bin/env perl"
 373 fi
 374 AC_SUBST(PERL_PATH)
 375
 376 # Need suitable python path for greport
 377 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 378
 379
 380 dnl ***********************
 381 dnl *** Tests for iconv ***
 382 dnl ***********************
 383 dnl
 384 dnl We do this before the gettext checks, to avoid distortion
 385
 386 dnl On Windows we use a native implementation
 387
 388 if test x"$glib_native_win32" = xyes; then
 389   with_libiconv=native
 390 else
 391   AC_ARG_WITH(libiconv,
 392               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 393                               [use the libiconv library])],,
 394               [with_libiconv=maybe])
 395
 396   found_iconv=no
 397   case $with_libiconv in
 398     maybe)
 399       # Check in the C library first
 400       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 401       # Check if we have GNU libiconv
 402       if test $found_iconv = "no"; then
 403         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 404       fi
 405       # Check if we have a iconv in -liconv, possibly from vendor
 406       if test $found_iconv = "no"; then
 407         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 408       fi
 409       ;;
 410     no)
 411       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 412       ;;
 413     gnu|yes)
 414       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 415       ;;
 416     native)
 417       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 418       ;;
 419   esac
 420
 421   if test "x$found_iconv" = "xno" ; then
 422      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 423   fi
 424 fi
 425
 426 AC_ARG_ENABLE(iconv-cache,
 427               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 428                               [cache iconv descriptors [default=auto]])],,
 429               [enable_iconv_cache=auto])
 430
 431 AC_MSG_CHECKING([whether to cache iconv descriptors])
 432 case $enable_iconv_cache in
 433   auto)
 434     if test $ac_cv_gnu_library_2_1 = yes; then
 435       enable_iconv_cache=no
 436     else
 437       enable_iconv_cache=yes
 438     fi
 439   ;;
 440   yes|no)
 441   ;;
 442   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 443   ;;
 444 esac
 445
 446 if test $enable_iconv_cache = yes; then
 447    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 448 fi
 449
 450 AC_MSG_RESULT($enable_iconv_cache)
 451
 452
 453 dnl
 454 dnl zlib support
 455 dnl
 456 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 457 if test "x$found_zlib" = "xno" ; then
 458   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 459   if test "x$found_zlib" = "xno" ; then
 460     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 461   fi
 462   ZLIB_LIBS='-lz'
 463   AC_SUBST(ZLIB_LIBS)
 464 fi
 465
 466 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 467 AC_SUBST(LIBFFI_CFLAGS)
 468 AC_SUBST(LIBFFI_LIBS)
 469
 470 dnl
 471 dnl gettext support
 472 dnl
 473
 474 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 475 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 476 GLIB_GNU_GETTEXT
 477
 478 if test "$gt_cv_have_gettext" != "yes" ; then
 479   AC_MSG_ERROR([
 480 *** You must have either have gettext support in your C library, or use the
 481 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 482 ])
 483 fi
 484
 485 LIBS="$INTLLIBS $LIBS"
 486
 487 GETTEXT_PACKAGE=glib20
 488 AC_SUBST(GETTEXT_PACKAGE)
 489 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 490   [Define the gettext package to be used])
 491
 492 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 493
 494 dnl
 495 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 496 dnl
 497
 498 if test x"$glib_native_win32" != xyes; then
 499   if test x$with_libiconv != xno ; then
 500     case " $INTLLIBS " in
 501     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 502     *) ICONV_LIBS="-liconv" ;;
 503     esac
 504   fi
 505 fi
 506 AC_SUBST(ICONV_LIBS)
 507
 508 case $with_libiconv in
 509   gnu)
 510     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 511     ;;
 512   native)
 513     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 514     ;;
 515 esac
 516
 517 dnl Initialize libtool
 518 LT_PREREQ([2.2])
 519 LT_INIT([disable-static win32-dll])
 520 dnl when using libtool 2.x create libtool early, because it's used in configure
 521 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 522
 523
 524 if test "x$GCC" = "xyes"; then
 525   case " $CFLAGS " in
 526   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 527   *) CFLAGS="$CFLAGS -Wall" ;;
 528   esac
 529 fi
 530
 531 if test "$glib_native_win32" = "yes"; then
 532   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 533     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 534   fi
 535   if test x$enable_static = xyes; then
 536     glib_win32_static_compilation=yes
 537     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 538 #define GOBJECT_STATIC_COMPILATION 1"
 539     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 540   fi
 541 fi
 542 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 543
 544 dnl
 545 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 546 dnl
 547 if test $cross_compiling != yes ; then
 548     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 549     glib_save_LIBS=$LIBS
 550     LIBS="$LIBS -lm"
 551     AC_TRY_RUN([#include <math.h>
 552                  int main (void) { return (log(1) != log(1.)); }],
 553          AC_MSG_RESULT(none needed),
 554          glib_save_CFLAGS=$CFLAGS
 555          CFLAGS="$CFLAGS -std1"
 556          AC_TRY_RUN([#include <math.h>
 557                      int main (void) { return (log(1) != log(1.)); }],
 558              AC_MSG_RESULT(-std1),
 559              AC_MSG_RESULT()
 560              CFLAGS=$glib_save_CFLAGS
 561              AC_MSG_WARN(
 562                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 563          )
 564     )
 565     LIBS=$glib_save_LIBS
 566 fi
 567
 568 dnl NeXTStep cc seems to need this
 569 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 570 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 571   AC_MSG_RESULT(none needed),
 572   glib_save_CFLAGS=$CFLAGS
 573   CFLAGS="$CFLAGS -posix"
 574   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 575     AC_MSG_RESULT(-posix),
 576     AC_MSG_RESULT()
 577     CFLAGS=$glib_save_CFLAGS
 578     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 579
 580 # Checks for library functions.
 581 AC_FUNC_VPRINTF
 582 AC_FUNC_ALLOCA
 583 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 584 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 585
 586 AC_CHECK_SIZEOF(char)
 587 AC_CHECK_SIZEOF(short)
 588 AC_CHECK_SIZEOF(long)
 589 AC_CHECK_SIZEOF(int)
 590 AC_CHECK_SIZEOF(void *)
 591 AC_CHECK_SIZEOF(long long)
 592 AC_CHECK_SIZEOF(__int64)
 593
 594 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 595   [AC_TRY_LINK([#include <signal.h>
 596      #include <sys/types.h>
 597      sig_atomic_t val = 42;],
 598     [return val == 42 ? 0 : 1],
 599    ac_cv_type_sig_atomic_t=yes,
 600    ac_cv_type_sig_atomic_t=no)])
 601 if test x$ac_cv_type_sig_atomic_t = xyes; then
 602    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 603      [Define if you have the 'sig_atomic_t' type.])
 604 fi
 605
 606 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 607   :
 608 else
 609   AC_MSG_ERROR([
 610 *** GLib requires a 64 bit type. You might want to consider
 611 *** using the GNU C compiler.
 612 ])
 613 fi
 614
 615 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 616         # long long is a 64 bit integer.
 617         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 618         AC_CACHE_VAL(glib_cv_long_long_format,[
 619                 for format in ll q I64; do
 620                   AC_TRY_RUN([#include <stdio.h>
 621                         int main()
 622                         {
 623                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 624                           char buffer[1000];
 625                           sprintf (buffer, "%${format}u", a);
 626                           sscanf (buffer, "%${format}u", &b);
 627                           exit (b!=a);
 628                         }
 629                         ],
 630                         [glib_cv_long_long_format=${format}
 631                         break],
 632                         [],[:])
 633                 done])
 634         if test -n "$glib_cv_long_long_format"; then
 635           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 636           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 637           if test x"$glib_cv_long_long_format" = xI64; then
 638             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 639           fi
 640         else
 641           AC_MSG_RESULT(none)
 642         fi
 643 elif test x$ac_cv_sizeof___int64 = x8; then
 644         # __int64 is a 64 bit integer.
 645         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 646         # We know this is MSVCRT.DLL, and what the formats are
 647         glib_cv_long_long_format=I64
 648         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 649         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 650         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 651 fi
 652
 653 AC_C_CONST
 654
 655 dnl ok, here we try to check whether the systems prototypes for
 656 dnl malloc and friends actually match the prototypes provided
 657 dnl by gmem.h (keep in sync). i currently only know how to check
 658 dnl this reliably with gcc (-Werror), improvements for other
 659 dnl compilers are apprechiated.
 660 SANE_MALLOC_PROTOS=no
 661 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 662 glib_save_CFLAGS=$CFLAGS
 663 if test "x$GCC" = "xyes"; then
 664   CFLAGS="$CFLAGS -Werror"
 665   AC_TRY_COMPILE([#include <stdlib.h>], [
 666     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 667     void* (*my_malloc_p)  (size_t)         = malloc;
 668     void  (*my_free_p)    (void*)          = free;
 669     void* (*my_realloc_p) (void*, size_t)  = realloc;
 670     my_calloc_p = 0;
 671     my_malloc_p = 0;
 672     my_free_p = 0;
 673     my_realloc_p = 0;
 674   ],
 675     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 676       [Define if you have correct malloc prototypes])
 677     SANE_MALLOC_PROTOS=yes)
 678 fi
 679 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 680 CFLAGS=$glib_save_CFLAGS
 681
 682 dnl
 683 dnl check in which direction the stack grows
 684 dnl
 685 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 686         AC_TRY_RUN([
 687         volatile int *a = 0, *b = 0;
 688         void foo (void);
 689         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 690         void foo (void) { volatile int x = 5; b = &x; }
 691         ],
 692         glib_cv_stack_grows=no
 693         ,
 694         glib_cv_stack_grows=yes
 695         ,)
 696 ])
 697
 698 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 699 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 700 dnl actually supported.
 701 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 702         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 703         __inline int foo () { return 0; }
 704         int main () { return foo (); }
 705         ]])],
 706         glib_cv_has__inline=yes
 707         ,
 708         glib_cv_has__inline=no
 709         ,)
 710 ])
 711 case x$glib_cv_has__inline in
 712 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 713 esac
 714 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 715         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 716         __inline__ int foo () { return 0; }
 717         int main () { return foo (); }
 718         ]])],
 719         glib_cv_has__inline__=yes
 720         ,
 721         glib_cv_has__inline__=no
 722         ,)
 723 ])
 724 case x$glib_cv_has__inline__ in
 725 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 726 esac
 727 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 728         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 729         #undef inline
 730         inline int foo () { return 0; }
 731         int main () { return foo (); }
 732         ]])],
 733         glib_cv_hasinline=yes
 734         ,
 735         glib_cv_hasinline=no
 736         ,)
 737 ])
 738 case x$glib_cv_hasinline in
 739 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 740 esac
 741
 742 # if we can use inline functions in headers
 743 AC_MSG_CHECKING(if inline functions in headers work)
 744 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 745 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 746 #  undef inline
 747 #  define inline __inline__
 748 #elif !defined (G_HAVE_INLINE)
 749 #  undef inline
 750 #  if defined (G_HAVE___INLINE__)
 751 #    define inline __inline__
 752 #  elif defined (G_HAVE___INLINE)
 753 #    define inline __inline
 754 #  endif
 755 #endif
 756
 757 int glib_test_func2 (int);
 758
 759 static inline int
 760 glib_test_func1 (void) {
 761   return glib_test_func2 (1);
 762 }
 763
 764 int
 765 main (void) {
 766   int i = 1;
 767 }]])],[g_can_inline=yes],[g_can_inline=no])
 768 AC_MSG_RESULT($g_can_inline)
 769
 770 dnl *** check for working do while(0) macros ***
 771 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 772         AC_TRY_COMPILE([],[
 773         #define STMT_START do
 774         #define STMT_END while(0)
 775         #define STMT_TEST STMT_START { i = 0; } STMT_END
 776         int main(void) { int i = 1; STMT_TEST; return i; }],
 777         [g_cv_support_dowhile_macros=yes],
 778         [g_cv_support_dowhile_macros=no],
 779         [g_cv_support_dowhile_macros=yes])
 780 ])
 781 if test x$g_cv_support_dowhile_macros = xyes; then
 782   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 783 fi
 784
 785 # check for flavours of varargs macros
 786 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 787 AC_TRY_COMPILE([],[
 788 int a(int p1, int p2, int p3);
 789 #define call_a(...) a(1,__VA_ARGS__)
 790 call_a(2,3);
 791 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 792 AC_MSG_RESULT($g_have_iso_c_varargs)
 793
 794 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 795 if test "$CXX" = ""; then
 796 dnl No C++ compiler
 797   g_have_iso_cxx_varargs=no
 798 else
 799   AC_LANG_CPLUSPLUS
 800   AC_TRY_COMPILE([],[
 801 int a(int p1, int p2, int p3);
 802 #define call_a(...) a(1,__VA_ARGS__)
 803 call_a(2,3);
 804 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 805   AC_LANG_C
 806 fi
 807 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 808
 809 AC_MSG_CHECKING(for GNUC varargs macros)
 810 AC_TRY_COMPILE([],[
 811 int a(int p1, int p2, int p3);
 812 #define call_a(params...) a(1,params)
 813 call_a(2,3);
 814 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 815 AC_MSG_RESULT($g_have_gnuc_varargs)
 816
 817 # check for GNUC visibility support
 818 AC_MSG_CHECKING(for GNUC visibility attribute)
 819 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 820 void
 821 __attribute__ ((visibility ("hidden")))
 822      f_hidden (void)
 823 {
 824 }
 825 void
 826 __attribute__ ((visibility ("internal")))
 827      f_internal (void)
 828 {
 829 }
 830 void
 831 __attribute__ ((visibility ("protected")))
 832      f_protected (void)
 833 {
 834 }
 835 void
 836 __attribute__ ((visibility ("default")))
 837      f_default (void)
 838 {
 839 }
 840 int main (int argc, char **argv)
 841 {
 842         f_hidden();
 843         f_internal();
 844         f_protected();
 845         f_default();
 846         return 0;
 847 }
 848 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 849 AC_MSG_RESULT($g_have_gnuc_visibility)
 850 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 851
 852 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 853 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 854 #else
 855 # include "error: this is not Sun Studio."
 856 #endif
 857 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 858 AC_MSG_RESULT($g_have_sunstudio_visibility)
 859 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 860
 861 # check for bytesex stuff
 862 AC_C_BIGENDIAN
 863 if test x$ac_cv_c_bigendian = xuniversal ; then
 864 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 865 #else
 866 #error Not a big endian.
 867 #endif],
 868     ac_cv_c_bigendian=yes
 869     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 870 #else
 871 #error Not a little endian.
 872 #endif],
 873     ac_cv_c_bigendian=no
 874     ,AC_MSG_WARN([Could not determine endianness.])))
 875 fi
 876
 877
 878 # check for header files
 879 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 880 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 881 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 882 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 883 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 884 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 885 AC_CHECK_HEADERS([linux/magic.h])
 886 AC_CHECK_HEADERS([sys/prctl.h])
 887
 888 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 889 [#if HAVE_SYS_PARAM_H
 890  #include <sys/param.h>
 891  #endif
 892 ])
 893
 894 AC_CHECK_HEADERS([xlocale.h])
 895
 896 # check for structure fields
 897 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 898 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 899 #include <sys/stat.h>
 900 #include <unistd.h>
 901 #ifdef HAVE_SYS_STATFS_H
 902 #include <sys/statfs.h>
 903 #endif
 904 #ifdef HAVE_SYS_PARAM_H
 905 #include <sys/param.h>
 906 #endif
 907 #ifdef HAVE_SYS_MOUNT_H
 908 #include <sys/mount.h>
 909 #endif])
 910 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 911 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 912 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 913 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 914
 915 AC_STRUCT_DIRENT_D_TYPE
 916
 917 # Checks for libcharset
 918 AM_LANGINFO_CODESET
 919 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 920 AC_CHECK_FUNCS(setlocale)
 921
 922 # check additional type sizes
 923 AC_CHECK_SIZEOF(size_t)
 924
 925 dnl Try to figure out whether gsize, gssize should be long or int
 926 AC_MSG_CHECKING([for the appropriate definition for size_t])
 927
 928 case $ac_cv_sizeof_size_t in
 929   $ac_cv_sizeof_short)
 930       glib_size_type=short
 931       ;;
 932   $ac_cv_sizeof_int)
 933       glib_size_type=int
 934       ;;
 935   $ac_cv_sizeof_long)
 936       glib_size_type=long
 937       ;;
 938   $ac_cv_sizeof_long_long)
 939       glib_size_type='long long'
 940       ;;
 941   $ac_cv_sizeof__int64)
 942       glib_size_type='__int64'
 943       ;;
 944   *)  AC_MSG_ERROR([No type matching size_t in size])
 945       ;;
 946 esac
 947
 948 dnl If int/long are the same size, we see which one produces
 949 dnl warnings when used in the location as size_t. (This matters
 950 dnl on AIX with xlc)
 951 dnl
 952 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 953    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 954   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 955 #if defined(_AIX) && !defined(__GNUC__)
 956 #pragma options langlvl=stdc89
 957 #endif
 958 #include <stddef.h>
 959 int main ()
 960 {
 961   size_t s = 1;
 962   unsigned int *size_int = &s;
 963   return (int)*size_int;
 964 }
 965     ]])],glib_size_type=int,
 966       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 967 #if defined(_AIX) && !defined(__GNUC__)
 968 #pragma options langlvl=stdc89
 969 #endif
 970 #include <stddef.h>
 971 int main ()
 972 {
 973    size_t s = 1;
 974    unsigned long *size_long = &s;
 975    return (int)*size_long;
 976 }
 977         ]])],glib_size_type=long)])
 978 fi
 979
 980 AC_MSG_RESULT(unsigned $glib_size_type)
 981
 982 # Check for some functions
 983 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 984 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
 985 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 986 # Check for high-resolution sleep functions
 987 AC_CHECK_FUNCS(splice)
 988 AC_CHECK_FUNCS(prlimit)
 989
 990 # To avoid finding a compatibility unusable statfs, which typically
 991 # successfully compiles, but warns to use the newer statvfs interface:
 992 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 993 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 994
 995 AC_MSG_CHECKING([whether to use statfs or statvfs])
 996 # Some systems have both statfs and statvfs, pick the most "native" for these
 997 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
 998    [
 999    # on solaris and irix, statfs doesn't even have the f_bavail field
1000    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1001       [ac_cv_func_statfs=no],
1002    # else, at least on linux, statfs is the actual syscall
1003       [ac_cv_func_statvfs=no])
1004    ])
1005
1006 AS_IF([test x$ac_cv_func_statfs = xyes],
1007       [
1008          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1009          AC_MSG_RESULT([statfs])
1010       ],
1011       [test x$ac_cv_func_statvfs = xyes],
1012       [
1013          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1014          AC_MSG_RESULT([statvfs])
1015       ],
1016       [  AC_MSG_RESULT([neither])])
1017
1018 AC_CHECK_HEADERS(crt_externs.h)
1019 AC_CHECK_FUNCS(_NSGetEnviron)
1020
1021 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1022
1023 AC_FUNC_VSNPRINTF_C99
1024 AC_FUNC_PRINTF_UNIX98
1025
1026 # Internet address families
1027 if test $glib_native_win32 = yes; then
1028   glib_inet_includes=["
1029 #include <winsock2.h>
1030   "]
1031 else
1032   glib_inet_includes=["
1033 #include <sys/types.h>
1034 #include <sys/socket.h>
1035   "]
1036 fi
1037
1038 glib_failed=false
1039 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1040 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1041 # winsock defines this even though it doesn't support it
1042 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1043 if $glib_failed ; then
1044   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1045 fi
1046
1047 glib_failed=false
1048 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1049 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1050 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1051 if $glib_failed ; then
1052   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1053 fi
1054
1055 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1056 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1057
1058 if test $glib_native_win32 = no; then
1059   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1060   NETWORK_LIBS=""
1061   AC_MSG_CHECKING([for res_query])
1062   AC_TRY_LINK([#include <sys/types.h>
1063                #include <netinet/in.h>
1064                #include <arpa/nameser.h>
1065                #include <resolv.h>
1066               ],[
1067                res_query("test", 0, 0, (void *)0, 0);
1068               ],[AC_MSG_RESULT([yes])],
1069               [save_libs="$LIBS"
1070                LIBS="-lresolv $LIBS"
1071                AC_TRY_LINK([#include <sys/types.h>
1072                             #include <netinet/in.h>
1073                             #include <arpa/nameser.h>
1074                             #include <resolv.h>
1075                            ],[
1076                             res_query("test", 0, 0, (void *)0, 0);
1077                            ],[AC_MSG_RESULT([in -lresolv])
1078                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1079                            [LIBS="-lbind $save_libs"
1080                             AC_TRY_LINK([#include <resolv.h>],
1081                                         [res_query("test", 0, 0, (void *)0, 0);],
1082                                         [AC_MSG_RESULT([in -lbind])
1083                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1084                                         [AC_MSG_ERROR(not found)])])
1085                LIBS="$save_libs"])
1086   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1087                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1088                                         [AC_MSG_ERROR(Could not find socket())]))
1089 fi
1090 AC_SUBST(NETWORK_LIBS)
1091
1092 AC_CHECK_HEADER([linux/netlink.h],
1093                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1094                 [#include <sys/socket.h>])
1095 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1096
1097 AC_CHECK_TYPE([struct ip_mreqn], [
1098               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1099               [#include <netinet/in.h>])
1100
1101 case $host in
1102   *-*-solaris* )
1103      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1104      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1105      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1106      ;;
1107 esac
1108
1109 dnl
1110 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1111 dnl
1112 if test "$ac_cv_func_statfs" = yes ; then
1113   AC_MSG_CHECKING([number of arguments to statfs()])
1114   AC_TRY_COMPILE([#include <unistd.h>
1115   #ifdef HAVE_SYS_PARAM_H
1116   #include <sys/param.h>
1117   #endif
1118   #ifdef HAVE_SYS_VFS_H
1119   #include <sys/vfs.h>
1120   #endif
1121   #ifdef HAVE_SYS_MOUNT_H
1122   #include <sys/mount.h>
1123   #endif
1124   #ifdef HAVE_SYS_STATFS_H
1125   #include <sys/statfs.h>
1126   #endif], [struct statfs st;
1127   statfs(NULL, &st);],[
1128     AC_MSG_RESULT([2])
1129     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1130     AC_TRY_COMPILE([#include <unistd.h>
1131   #ifdef HAVE_SYS_PARAM_H
1132   #include <sys/param.h>
1133   #endif
1134   #ifdef HAVE_SYS_VFS_H
1135   #include <sys/vfs.h>
1136   #endif
1137   #ifdef HAVE_SYS_MOUNT_H
1138   #include <sys/mount.h>
1139   #endif
1140   #ifdef HAVE_SYS_STATFS_H
1141   #include <sys/statfs.h>
1142   #endif], [struct statfs st;
1143   statfs(NULL, &st, sizeof (st), 0);],[
1144       AC_MSG_RESULT([4])
1145       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1146       AC_MSG_RESULT(unknown)
1147       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1148 fi
1149
1150 #
1151 # Check whether to use an included printf
1152 #
1153
1154 AC_ARG_ENABLE(included-printf,
1155               [AC_HELP_STRING([--enable-included-printf],
1156                               [use included printf [default=auto]])],
1157               enable_included_printf="$enableval")
1158
1159 need_included_printf=no
1160 if test "x$enable_included_printf" = "xyes" ; then
1161   need_included_printf=yes
1162 fi
1163 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1164   need_included_printf=yes
1165 fi
1166 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1167   need_included_printf=yes
1168 fi
1169 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1170    test -z "$glib_cv_long_long_format" ; then
1171   need_included_printf=yes
1172 fi
1173
1174 if test "x$enable_included_printf" = "xno" &&
1175    test "x$need_included_printf" = "xyes" ; then
1176   AC_MSG_ERROR([
1177 *** Your C library's printf doesn't appear to have the features that
1178 *** GLib needs, but you specified --enable-included-printf=no.])
1179 fi
1180
1181 enable_included_printf=$need_included_printf
1182
1183 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1184 if test "$enable_included_printf" != "yes" ; then
1185   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1186 else
1187   if test -z "$glib_cv_long_long_format" ; then
1188     glib_cv_long_long_format="ll"
1189   fi
1190   AC_DEFINE(HAVE_VASPRINTF,1)
1191 fi
1192
1193 # Checks needed for gnulib vasnprintf
1194 bh_C_SIGNED
1195 jm_AC_TYPE_LONG_LONG
1196 gt_TYPE_LONGDOUBLE
1197 gt_TYPE_WCHAR_T
1198 gt_TYPE_WINT_T
1199 AC_TYPE_SIZE_T
1200 AC_CHECK_TYPES(ptrdiff_t)
1201 jm_AC_TYPE_INTMAX_T
1202 AC_CHECK_FUNCS([snprintf wcslen])
1203 AC_FUNC_SNPRINTF_C99
1204
1205 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1206 # The check is borrowed from the PERL Configure script.
1207 if test "$ac_cv_func_memmove" != "yes"; then
1208   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1209     glib_cv_working_bcopy,[AC_TRY_RUN([
1210       int main() {
1211         char buf[128], abc[128], *b;
1212         int len, off, align;
1213         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1214         for (align = 7; align >= 0; align--) {
1215           for (len = 36; len; len--) {
1216             b = buf+align; bcopy(abc, b, len);
1217             for (off = 1; off <= len; off++) {
1218               bcopy(b, b+off, len); bcopy(b+off, b, len);
1219                 if (bcmp(b, abc, len)) return(1);
1220             }
1221           }
1222         }
1223         return(0);
1224       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1225
1226   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1227   if test "$glib_cv_working_bcopy" = "yes"; then
1228     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1229   fi
1230 fi
1231
1232 # Check if <sys/select.h> needs to be included for fd_set
1233 AC_MSG_CHECKING([for fd_set])
1234 AC_TRY_COMPILE([#include <sys/types.h>],
1235         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1236 if test "$gtk_ok" = "yes"; then
1237     AC_MSG_RESULT([yes, found in sys/types.h])
1238 else
1239     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1240     if test "$gtk_ok" = "yes"; then
1241         # *** FIXME: give it a different name
1242         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1243         AC_MSG_RESULT([yes, found in sys/select.h])
1244     else
1245         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1246         AC_MSG_RESULT(no)
1247     fi
1248 fi
1249
1250 dnl *** check for sane realloc() ***
1251 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1252         AC_TRY_RUN([#include <stdlib.h>
1253         int main() {
1254           return realloc (0, sizeof (int)) == 0;
1255         }],
1256         [glib_cv_sane_realloc=yes],
1257         [glib_cv_sane_realloc=no],
1258         [glib_cv_sane_realloc=yes])
1259 ])
1260 if test x$glib_cv_sane_realloc = xyes; then
1261   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1262 fi
1263
1264 dnl Check for nl_langinfo and CODESET
1265 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1266         AC_TRY_COMPILE([#include <langinfo.h>],
1267                 [char *codeset = nl_langinfo (CODESET);],
1268                 [glib_cv_langinfo_codeset=yes],
1269                 [glib_cv_langinfo_codeset=no])])
1270 if test x$glib_cv_langinfo_codeset = xyes; then
1271   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1272 fi
1273
1274 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1275 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1276         AC_TRY_COMPILE([#include <langinfo.h>],
1277                 [char *str;
1278                  str = nl_langinfo (PM_STR);
1279                  str = nl_langinfo (D_T_FMT);
1280                  str = nl_langinfo (D_FMT);
1281                  str = nl_langinfo (T_FMT);
1282                  str = nl_langinfo (T_FMT_AMPM);
1283                  str = nl_langinfo (MON_1);
1284                  str = nl_langinfo (ABMON_12);
1285                  str = nl_langinfo (DAY_1);
1286                  str = nl_langinfo (ABDAY_7);],
1287                 [glib_cv_langinfo_time=yes],
1288                 [glib_cv_langinfo_time=no])])
1289 if test x$glib_cv_langinfo_time = xyes; then
1290   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1291 fi
1292
1293 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1294 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1295         AC_TRY_COMPILE([#include <langinfo.h>],
1296                 [char *str;
1297                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1298                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1299                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1300                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1301                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1302                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1303                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1304                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1305                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1306                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1307                 [glib_cv_langinfo_outdigit=yes],
1308                 [glib_cv_langinfo_outdigit=no])])
1309 if test x$glib_cv_langinfo_outdigit = xyes; then
1310   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1311 fi
1312
1313 dnl ****************************************
1314 dnl *** posix_memalign                   ***
1315 dnl ****************************************
1316 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1317 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1318     glib_cv_compliant_posix_memalign=0
1319     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1320         AC_TRY_RUN([
1321                 #define _XOPEN_SOURCE 600
1322                 #include <stdlib.h> /* posix_memalign() should be defined here */
1323                 /* some systems break if #include <malloc.h> used */
1324                 static void test_memalign (size_t boundary, size_t size) {
1325                     void *mem = 0;
1326                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1327                         exit (1);
1328                     else
1329                       free (mem);
1330                 }
1331                 int main() {
1332                     test_memalign (  128,   128 - 2 * sizeof (void*));
1333                     test_memalign (  256,   256 - 2 * sizeof (void*));
1334                     test_memalign (  512,   512 - 2 * sizeof (void*));
1335                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1336                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1337                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1338                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1339                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1340                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1341                     exit (0); /* success */
1342                 }
1343                 ],
1344             [glib_cv_compliant_posix_memalign=1], [], [:])
1345       :
1346     fi
1347     ])
1348 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1349     AC_MSG_RESULT(yes)
1350     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1351 else
1352     AC_MSG_RESULT(no)
1353 fi
1354
1355
1356 dnl ****************************************
1357 dnl *** strlcpy/strlcat                  ***
1358 dnl ****************************************
1359 # Check for strlcpy
1360 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1361 AC_TRY_RUN([#include <stdlib.h>
1362 #include <string.h>
1363 int main() {
1364   char p[10];
1365   (void) strlcpy (p, "hi", 10);
1366   if (strlcat (p, "bye", 0) != 3)
1367     return 1;
1368   return 0;
1369 }], glib_cv_have_strlcpy=yes,
1370     glib_cv_have_strlcpy=no,
1371     glib_cv_have_strlcpy=no)])
1372 if test "$glib_cv_have_strlcpy" = "yes"; then
1373     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1374 fi
1375
1376
1377 dnl **********************
1378 dnl *** va_copy checks ***
1379 dnl **********************
1380 dnl we currently check for all three va_copy possibilities, so we get
1381 dnl all results in config.log for bug reports.
1382 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1383         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1384 #include <stdlib.h>
1385         void f (int i, ...) {
1386         va_list args1, args2;
1387         va_start (args1, i);
1388         va_copy (args2, args1);
1389         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1390           exit (1);
1391         va_end (args1); va_end (args2);
1392         }
1393         int main() {
1394           f (0, 42);
1395           return 0;
1396         }]])],
1397         [glib_cv_va_copy=yes],
1398         [glib_cv_va_copy=no])
1399 ])
1400 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1401         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1402 #include <stdlib.h>
1403         void f (int i, ...) {
1404         va_list args1, args2;
1405         va_start (args1, i);
1406         __va_copy (args2, args1);
1407         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1408           exit (1);
1409         va_end (args1); va_end (args2);
1410         }
1411         int main() {
1412           f (0, 42);
1413           return 0;
1414         }]])],
1415         [glib_cv___va_copy=yes],
1416         [glib_cv___va_copy=no])
1417 ])
1418
1419 if test "x$glib_cv_va_copy" = "xyes"; then
1420   g_va_copy_func=va_copy
1421 else if test "x$glib_cv___va_copy" = "xyes"; then
1422   g_va_copy_func=__va_copy
1423 fi
1424 fi
1425
1426 if test -n "$g_va_copy_func"; then
1427   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1428 fi
1429
1430 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1431         AC_TRY_RUN([#include <stdarg.h>
1432 #include <stdlib.h>
1433         void f (int i, ...) {
1434         va_list args1, args2;
1435         va_start (args1, i);
1436         args2 = args1;
1437         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1438           exit (1);
1439         va_end (args1); va_end (args2);
1440         }
1441         int main() {
1442           f (0, 42);
1443           return 0;
1444         }],
1445         [glib_cv_va_val_copy=yes],
1446         [glib_cv_va_val_copy=no],
1447         [glib_cv_va_val_copy=yes])
1448 ])
1449
1450 if test "x$glib_cv_va_val_copy" = "xno"; then
1451   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1452 fi
1453
1454 dnl ***********************
1455 dnl *** g_module checks ***
1456 dnl ***********************
1457 G_MODULE_LIBS=
1458 G_MODULE_LIBS_EXTRA=
1459 G_MODULE_PLUGIN_LIBS=
1460 if test x"$glib_native_win32" = xyes; then
1461   dnl No use for this on Win32
1462   G_MODULE_LDFLAGS=
1463 else
1464   export SED
1465   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1466 fi
1467 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1468 G_MODULE_NEED_USCORE=0
1469 G_MODULE_BROKEN_RTLD_GLOBAL=0
1470 G_MODULE_HAVE_DLERROR=0
1471 dnl *** force native WIN32 shared lib loader
1472 if test -z "$G_MODULE_IMPL"; then
1473   case "$host" in
1474   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1475   esac
1476 fi
1477 dnl *** force native AIX library loader
1478 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1479 if test -z "$G_MODULE_IMPL"; then
1480   case "$host" in
1481   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1482   esac
1483 fi
1484 dnl *** dlopen() and dlsym() in system libraries
1485 if test -z "$G_MODULE_IMPL"; then
1486         AC_CHECK_FUNC(dlopen,
1487                       [AC_CHECK_FUNC(dlsym,
1488                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1489                       [])
1490 fi
1491 dnl *** load_image (BeOS)
1492 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1493   AC_CHECK_LIB(root, load_image,
1494       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1495       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1496       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1497       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1498       [])
1499 fi
1500 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1501 if test -z "$G_MODULE_IMPL"; then
1502         AC_CHECK_FUNC(NSLinkModule,
1503                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1504                        G_MODULE_NEED_USCORE=1],
1505                       [])
1506 fi
1507 dnl *** dlopen() and dlsym() in libdl
1508 if test -z "$G_MODULE_IMPL"; then
1509         AC_CHECK_LIB(dl, dlopen,
1510                      [AC_CHECK_LIB(dl, dlsym,
1511                                    [G_MODULE_LIBS=-ldl
1512                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1513                      [])
1514 fi
1515 dnl *** shl_load() in libdld (HP-UX)
1516 if test -z "$G_MODULE_IMPL"; then
1517         AC_CHECK_LIB(dld, shl_load,
1518                 [G_MODULE_LIBS=-ldld
1519                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1520                 [])
1521 fi
1522 dnl *** additional checks for G_MODULE_IMPL_DL
1523 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1524         LIBS_orig="$LIBS"
1525         LDFLAGS_orig="$LDFLAGS"
1526         LIBS="$G_MODULE_LIBS $LIBS"
1527         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1528 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1529         echo "void glib_plugin_test(void) { }" > plugin.c
1530         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1531                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1532         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1533                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1534                 -shrext ".o" -avoid-version plugin.lo \
1535                 -rpath /dont/care >/dev/null 2>&1
1536         eval `./libtool --config | grep ^objdir`
1537         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1538                 glib_cv_rtldglobal_broken,[
1539                 AC_TRY_RUN([
1540 #include <dlfcn.h>
1541 #ifndef RTLD_GLOBAL
1542 #  define RTLD_GLOBAL 0
1543 #endif
1544 #ifndef RTLD_LAZY
1545 #  define RTLD_LAZY 0
1546 #endif
1547 int glib_plugin_test;
1548 int main () {
1549     void *handle, *global, *local;
1550     global = &glib_plugin_test;
1551     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1552     if (!handle) return 0;
1553     local = dlsym (handle, "glib_plugin_test");
1554     return global == local;
1555 }                       ],
1556                         [glib_cv_rtldglobal_broken=no],
1557                         [glib_cv_rtldglobal_broken=yes],
1558                         [glib_cv_rtldglobal_broken=no])
1559                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1560                 rmdir ${objdir} 2>/dev/null
1561         ])
1562         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1563                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1564         else
1565                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1566         fi
1567 dnl *** check whether we need preceeding underscores
1568         AC_CACHE_CHECK([for preceeding underscore in symbols],
1569                 glib_cv_uscore,[
1570                 AC_TRY_RUN([#include <dlfcn.h>
1571                 int glib_underscore_test (void) { return 42; }
1572                 int main() {
1573                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1574                   handle = dlopen ((void*)0, 0);
1575                   if (handle) {
1576                     f1 = dlsym (handle, "glib_underscore_test");
1577                     f2 = dlsym (handle, "_glib_underscore_test");
1578                   } return (!f2 || f1);
1579                 }],
1580                         [glib_cv_uscore=yes],
1581                         [glib_cv_uscore=no],
1582                         [])
1583                 rm -f plugin.c plugin.$ac_objext plugin.lo
1584         ])
1585         GLIB_ASSERT_SET(glib_cv_uscore)
1586         if test "x$glib_cv_uscore" = "xyes"; then
1587                 G_MODULE_NEED_USCORE=1
1588         else
1589                 G_MODULE_NEED_USCORE=0
1590         fi
1591
1592         LDFLAGS="$LDFLAGS_orig"
1593 dnl *** check for having dlerror()
1594         AC_CHECK_FUNC(dlerror,
1595                 [G_MODULE_HAVE_DLERROR=1],
1596                 [G_MODULE_HAVE_DLERROR=0])
1597         LIBS="$LIBS_orig"
1598 fi
1599 dnl *** done, have we got an implementation?
1600 if test -z "$G_MODULE_IMPL"; then
1601         G_MODULE_IMPL=0
1602         G_MODULE_SUPPORTED=false
1603 else
1604         G_MODULE_SUPPORTED=true
1605 fi
1606
1607 AC_MSG_CHECKING(for the suffix of module shared libraries)
1608 export SED
1609 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1610 eval $shrext_cmds
1611 module=yes eval std_shrext=$shrext_cmds
1612 # chop the initial dot
1613 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1614 AC_MSG_RESULT(.$glib_gmodule_suffix)
1615 # any reason it may fail?
1616 if test "x$glib_gmodule_suffix" = x; then
1617         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1618 fi
1619
1620 AC_SUBST(G_MODULE_SUPPORTED)
1621 AC_SUBST(G_MODULE_IMPL)
1622 AC_SUBST(G_MODULE_LIBS)
1623 AC_SUBST(G_MODULE_LIBS_EXTRA)
1624 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1625 AC_SUBST(G_MODULE_LDFLAGS)
1626 AC_SUBST(G_MODULE_HAVE_DLERROR)
1627 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1628 AC_SUBST(G_MODULE_NEED_USCORE)
1629 AC_SUBST(GLIB_DEBUG_FLAGS)
1630
1631 dnl **********************
1632 dnl *** g_spawn checks ***
1633 dnl **********************
1634
1635 AC_MSG_CHECKING(for gspawn implementation)
1636 case "$host" in
1637   *-*-mingw*)
1638     GSPAWN=gspawn-win32.lo
1639     ;;
1640   *)
1641     GSPAWN=gspawn.lo
1642     ;;
1643 esac
1644 AC_MSG_RESULT($GSPAWN)
1645 AC_SUBST(GSPAWN)
1646
1647 dnl *************************
1648 dnl *** GIOChannel checks ***
1649 dnl *************************
1650
1651 AC_MSG_CHECKING(for GIOChannel implementation)
1652 case "$host" in
1653   *-*-mingw*)
1654     GIO=giowin32.lo
1655     ;;
1656   *)
1657     GIO=giounix.lo
1658     ;;
1659 esac
1660 AC_MSG_RESULT($GIO)
1661 AC_SUBST(GIO)
1662
1663 dnl *********************************
1664 dnl *** Directory for GIO modules ***
1665 dnl *********************************
1666
1667 AC_ARG_WITH(gio-module-dir,
1668            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1669                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1670            [],
1671            [with_gio_module_dir='${libdir}/gio/modules'])
1672 GIO_MODULE_DIR=$with_gio_module_dir
1673 AC_SUBST(GIO_MODULE_DIR)
1674
1675 dnl **********************************
1676 dnl *** Check for libselinux (GIO) ***
1677 dnl **********************************
1678 AC_ARG_ENABLE(selinux,
1679               AC_HELP_STRING([--disable-selinux],
1680                              [build without selinux support]))
1681 msg_selinux=no
1682 SELINUX_LIBS=
1683 if test "x$enable_selinux" != "xno"; then
1684
1685  AC_CHECK_LIB(selinux, is_selinux_enabled,
1686    [AC_CHECK_HEADERS(selinux/selinux.h,
1687      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1688        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1689         SELINUX_LIBS="-lselinux"
1690         msg_selinux=yes])
1691      ])
1692    ])
1693 fi
1694 AC_SUBST(SELINUX_LIBS)
1695
1696 dnl *****************************
1697 dnl ** Check for inotify (GIO) **
1698 dnl *****************************
1699 inotify_support=no
1700 AC_CHECK_HEADERS([sys/inotify.h],
1701 [
1702         inotify_support=yes
1703         AC_CHECK_FUNCS(inotify_init1)
1704 ])
1705
1706 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1707
1708 dnl *********************************
1709 dnl ** Check for Solaris FEN (GIO) **
1710 dnl *********************************
1711 fen_support=no
1712 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1713 #include <port.h>
1714 #ifndef PORT_SOURCE_FILE
1715 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1716 #endif
1717 int main() { return 0; } ]])],
1718 [
1719         fen_support=yes
1720 ],)
1721
1722 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1723
1724 dnl ****************************
1725 dnl *** Checks for FAM (GIO) ***
1726 dnl ****************************
1727
1728 should_disable_fam=no
1729
1730 AC_ARG_ENABLE(fam,
1731               AC_HELP_STRING([--disable-fam],
1732                              [don't use fam for file system monitoring]),
1733                          [
1734                                 if test "x$enable_fam" = "xno"; then
1735                                         should_disable_fam=yes
1736                                 fi
1737                          ]
1738                          )
1739 fam_support=no
1740 FAM_LIBS=
1741 if test "x$should_disable_fam" = "xno"; then
1742 AC_CHECK_LIB(fam, FAMOpen,
1743   [AC_CHECK_HEADERS(fam.h,
1744     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1745      AC_CHECK_LIB(fam, FAMNoExists,
1746                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1747      FAM_LIBS="-lfam"]
1748      fam_support=yes,
1749     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1750   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1751 AC_SUBST(FAM_LIBS)
1752 fi
1753 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1754
1755
1756 dnl *****************************
1757 dnl *** Check for xattr (GIO) ***
1758 dnl *****************************
1759 AC_ARG_ENABLE(xattr,
1760               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1761 msg_xattr=no
1762 XATTR_LIBS=
1763 if test "x$enable_xattr" != "xno"; then
1764
1765 dnl either glibc or libattr can provide xattr support
1766
1767 dnl for both of them, we check for getxattr being in
1768 dnl the library and a valid xattr header.
1769
1770 dnl try glibc
1771  AC_CHECK_LIB(c, getxattr,
1772    [AC_CHECK_HEADERS(sys/xattr.h,
1773      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1774       msg_xattr=yes])
1775    ])
1776
1777   if test "x$msg_xattr" != "xyes"; then
1778 dnl   failure. try libattr
1779    AC_CHECK_LIB(attr, getxattr,
1780       [AC_CHECK_HEADERS(attr/xattr.h,
1781        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1782         XATTR_LIBS="-lattr"
1783         msg_xattr=yes])
1784       ])
1785   fi
1786
1787   if test "x$msg_xattr" = "xyes"; then
1788     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1789     AC_TRY_COMPILE([
1790       #include <stdio.h>
1791       #ifdef HAVE_SYS_TYPES_H
1792       #include <sys/types.h>
1793       #endif
1794       #ifdef HAVE_SYS_XATTR_H
1795       #include <sys/xattr.h>
1796       #elif HAVE_ATTR_XATTR_H
1797       #include <attr/xattr.h>
1798       #endif
1799     ],
1800     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1801     [
1802       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1803       AC_MSG_RESULT([yes])
1804     ],
1805     [AC_MSG_RESULT([no])]
1806     )
1807   fi
1808
1809 fi
1810 AC_SUBST(XATTR_LIBS)
1811
1812 dnl ************************
1813 dnl *** check for libelf ***
1814 dnl ************************
1815
1816 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=maybe])
1817
1818 if test $have_libelf = maybe; then
1819   AC_CHECK_LIB([elf], [elf_begin], , [have_libelf=no])
1820   AC_CHECK_LIB([elf], [elf_getshdrstrndx], , [have_libelf=no])
1821   AC_CHECK_LIB([elf], [elf_getshdrnum], , [have_libelf=no])
1822   AC_CHECK_HEADER([libelf.h], , [have_libelf=no])
1823
1824   if test $have_libelf != no; then
1825     LIBELF_LIBS=-lelf
1826     have_libelf = yes
1827   fi
1828 fi
1829
1830 if test $have_libelf = yes; then
1831   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1832 fi
1833
1834 dnl ****************************************
1835 dnl *** platform dependent source checks ***
1836 dnl ****************************************
1837
1838 AC_MSG_CHECKING(for platform-dependent source)
1839 case "$host" in
1840   *-*-cygwin*|*-*-mingw*)
1841     PLATFORMDEP=gwin32.lo
1842     ;;
1843   *)
1844     PLATFORMDEP=
1845     ;;
1846 esac
1847 AC_MSG_RESULT($PLATFORMDEP)
1848 AC_SUBST(PLATFORMDEP)
1849
1850 AC_MSG_CHECKING([whether to compile timeloop])
1851 case "$host" in
1852   *-*-cygwin*|*-*-mingw*|*-*-minix)
1853     enable_timeloop=no
1854     ;;
1855   *)
1856     enable_timeloop=yes
1857     ;;
1858 esac
1859 AC_MSG_RESULT($enable_timeloop)
1860 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1861
1862 AC_MSG_CHECKING([if building for some Win32 platform])
1863 case "$host" in
1864   *-*-mingw*|*-*-cygwin*)
1865     platform_win32=yes
1866     ;;
1867   *)
1868     platform_win32=no
1869     ;;
1870 esac
1871 AC_MSG_RESULT($platform_win32)
1872 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1873
1874 dnl ***********************
1875 dnl *** g_thread checks ***
1876 dnl ***********************
1877
1878 AC_ARG_WITH(threads,
1879            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1880                            [specify a thread implementation to use])],
1881            [],
1882            [with_threads=yes])
1883
1884 dnl error and warning message
1885 dnl *************************
1886
1887 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1888
1889 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1890                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1891                 compilation now, but then your programs might not work.
1892                 Please provide information on how it is done on your system."
1893
1894 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1895                  "
1896
1897 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1898                   provide information on your thread implementation."
1899
1900 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1901                 functions will not be MT-safe during their first call because
1902                 there is no working 'getpwuid_r' on your system."
1903
1904 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1905                 because there is no 'localtime_r' on your system."
1906
1907 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1908                 linking threaded applications. As GLib cannot do that
1909                 automatically, you will get an linkg error everytime you are
1910                 not using the right compiler. In that case you have to relink
1911                 with the right compiler. Ususally just '_r' is appended
1912                 to the compiler name."
1913
1914 dnl determination of thread implementation
1915 dnl ***************************************
1916
1917 AC_MSG_CHECKING(for thread implementation)
1918
1919 have_threads=no
1920 if test "x$with_threads" = xyes || test "x$with_threads" = xposix; then
1921         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1922         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1923         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1924         glib_save_CPPFLAGS="$CPPFLAGS"
1925         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1926         if test "x$have_threads" = xno; then
1927                 AC_TRY_COMPILE([#include <pthread.h>],
1928                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1929                         have_threads=posix)
1930         fi
1931         # Tru64Unix requires -pthread to find pthread.h. See #103020
1932         CPPFLAGS="$CPPFLAGS -pthread"
1933         if test "x$have_threads" = xno; then
1934         AC_TRY_COMPILE([#include <pthread.h>],
1935                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1936                        have_threads=posix)
1937         fi
1938         CPPFLAGS="$glib_save_CPPFLAGS"
1939 fi
1940 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1941         case $host in
1942                 *-*-mingw*)
1943                 have_threads=win32
1944                 ;;
1945         esac
1946 fi
1947
1948 if test "x$have_threads" = xno; then
1949         AC_MSG_RESULT(none available)
1950         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1951 else
1952         AC_MSG_RESULT($have_threads)
1953 fi
1954
1955
1956 dnl determination of G_THREAD_CFLAGS
1957 dnl ********************************
1958
1959 G_THREAD_LIBS=
1960 G_THREAD_LIBS_EXTRA=
1961 G_THREAD_CFLAGS=
1962
1963 dnl
1964 dnl Test program for basic POSIX threads functionality
1965 dnl
1966 m4_define([glib_thread_test],[
1967 #include <pthread.h>
1968 int check_me = 0;
1969 void* func(void* data) {check_me = 42; return &check_me;}
1970 int main()
1971  { pthread_t t;
1972    void *ret;
1973    pthread_create (&t, $1, func, 0);
1974    pthread_join (t, &ret);
1975    return (check_me != 42 || ret != &check_me);
1976 }])
1977
1978 if test x"$have_threads" = xposix; then
1979   # First we test for posix, whether -pthread or -pthreads do the trick as
1980   # both CPPFLAG and LIBS.
1981   # One of them does for most gcc versions and some other platforms/compilers
1982   # too and could be considered as the canonical way to go.
1983   case $host in
1984     *-*-cygwin*|*-*-darwin*)
1985        # skip cygwin and darwin -pthread or -pthreads test
1986        ;;
1987     *-solaris*)
1988       # These compiler/linker flags work with both Sun Studio and gcc
1989       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1990       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1991       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1992       G_THREAD_LIBS="-lpthread -lthread"
1993       ;;
1994     *)
1995       for flag in pthread pthreads mt; do
1996         glib_save_CFLAGS="$CFLAGS"
1997         CFLAGS="$CFLAGS -$flag"
1998         AC_TRY_RUN(glib_thread_test(0),
1999                    glib_flag_works=yes,
2000                    glib_flag_works=no,
2001                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2002                                    glib_flag_works=yes,
2003                                    glib_flag_works=no)])
2004         CFLAGS="$glib_save_CFLAGS"
2005         if test $glib_flag_works = yes ; then
2006            G_THREAD_CFLAGS=-$flag
2007         G_THREAD_LIBS=-$flag
2008         break;
2009         fi
2010       done
2011        ;;
2012   esac
2013 fi
2014
2015 if test x"$G_THREAD_CFLAGS" = x; then
2016
2017   # The canonical -pthread[s] does not work. Try something different.
2018
2019   case $host in
2020         *-aix*)
2021                 if test x"$GCC" = xyes; then
2022                         # GCC 3.0 and above needs -pthread.
2023                         # Should be coverd by the case above.
2024                         # GCC 2.x and below needs -mthreads
2025                         G_THREAD_CFLAGS="-mthreads"
2026                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2027                 else
2028                         # We are probably using the aix compiler. Normaly a
2029                         # program would have to be compiled with the _r variant
2030                         # of the corresponding compiler, but we as GLib cannot
2031                         # do that: but the good news is that for compiling the
2032                         # only difference is the added -D_THREAD_SAFE compile
2033                         # option. This is according to the "C for AIX User's
2034                         # Guide".
2035                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2036                 fi
2037                 ;;
2038         *-dg-dgux*)  # DG/UX
2039                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2040                 ;;
2041         *-sysv5uw7*) # UnixWare 7
2042                 # We are not using gcc with -pthread. Catched above.
2043                 G_THREAD_CFLAGS="-Kthread"
2044                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2045                 ;;
2046         *-mingw*)
2047                 # No flag needed when using MSVCRT.DLL
2048                 G_THREAD_CFLAGS=""
2049                 ;;
2050         *)
2051                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2052                 ;;
2053   esac
2054
2055 fi
2056
2057 # if we are not finding the localtime_r function, then we probably are
2058 # not using the proper multithread flag
2059
2060 glib_save_CPPFLAGS="$CPPFLAGS"
2061 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2062
2063 # First we test, whether localtime_r is declared in time.h
2064 # directly. Then we test whether a macro localtime_r exists, in
2065 # which case localtime_r in the test program is replaced and thus
2066 # if we still find localtime_r in the output, it is not defined as
2067 # a macro.
2068
2069 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2070   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2071                                                            localtime_r(a,b)],
2072                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2073
2074 CPPFLAGS="$glib_save_CPPFLAGS"
2075
2076 AC_MSG_CHECKING(thread related cflags)
2077 AC_MSG_RESULT($G_THREAD_CFLAGS)
2078 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2079
2080 dnl determination of G_THREAD_LIBS
2081 dnl ******************************
2082
2083 case $have_threads in
2084         posix)
2085           glib_save_CPPFLAGS="$CPPFLAGS"
2086           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2087           if test x"$G_THREAD_LIBS" = x; then
2088             case $host in
2089               *-aix*)
2090                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2091                 # probably using the aix compiler.
2092                 AC_MSG_WARN($AIX_COMPILE_INFO)
2093                 ;;
2094               *)
2095                 G_THREAD_LIBS=error
2096                 glib_save_LIBS="$LIBS"
2097                 for thread_lib in "" pthread pthread32 pthreads thread; do
2098                         if test x"$thread_lib" = x; then
2099                                 add_thread_lib=""
2100                                 IN=""
2101                         else
2102                                 add_thread_lib="-l$thread_lib"
2103                                 IN=" in -l$thread_lib"
2104                         fi
2105                         if test x"$have_threads" = xposix; then
2106                                 defattr=0
2107                         else
2108                                 defattr=pthread_attr_default
2109                         fi
2110
2111                         LIBS="$add_thread_lib $glib_save_LIBS"
2112
2113                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2114                         AC_TRY_RUN(glib_thread_test($defattr),
2115                                    glib_result=yes,
2116                                    glib_result=no,
2117                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2118                                                    glib_result=yes,
2119                                                    glib_result=no)])
2120                         AC_MSG_RESULT($glib_result)
2121
2122                         if test "$glib_result" = "yes" ; then
2123                           G_THREAD_LIBS="$add_thread_lib"
2124                           break
2125                         fi
2126                 done
2127                 if test "x$G_THREAD_LIBS" = xerror; then
2128                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2129                 fi
2130                 LIBS="$glib_save_LIBS"
2131                 ;;
2132             esac
2133           fi
2134
2135           g_threads_impl="POSIX"
2136           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2137           CPPFLAGS="$glib_save_CPPFLAGS"
2138           ;;
2139         win32)
2140            g_threads_impl="WIN32"
2141            ;;
2142         *)
2143            g_threads_impl="NONE"
2144            G_THREAD_LIBS=error
2145            ;;
2146 esac
2147
2148 if test "x$G_THREAD_LIBS" = xerror; then
2149         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2150 fi
2151
2152 case $host in
2153   *-*-beos*)
2154     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2155     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2156     ;;
2157   *)
2158     ;;
2159 esac
2160
2161 AC_MSG_CHECKING(thread related libraries)
2162 AC_MSG_RESULT($G_THREAD_LIBS)
2163
2164 dnl check for mt safe function variants and some posix functions
2165 dnl ************************************************************
2166
2167 glib_save_LIBS="$LIBS"
2168 # we are not doing the following for now, as this might require glib
2169 # to always be linked with the thread libs on some platforms.
2170 # LIBS="$LIBS $G_THREAD_LIBS"
2171 AC_CHECK_FUNCS(localtime_r gmtime_r)
2172 if test "$ac_cv_header_pwd_h" = "yes"; then
2173         AC_CACHE_CHECK([for posix getpwuid_r],
2174                 ac_cv_func_posix_getpwuid_r,
2175                 [AC_TRY_RUN([
2176 #include <errno.h>
2177 #include <pwd.h>
2178 int main () {
2179     char buffer[10000];
2180     struct passwd pwd, *pwptr = &pwd;
2181     int error;
2182     errno = 0;
2183     error = getpwuid_r (0, &pwd, buffer,
2184                         sizeof (buffer), &pwptr);
2185    return (error < 0 && errno == ENOSYS)
2186            || error == ENOSYS;
2187 }                               ],
2188                         [ac_cv_func_posix_getpwuid_r=yes],
2189                         [ac_cv_func_posix_getpwuid_r=no])])
2190         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2191         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2192                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2193                         [Have POSIX function getpwuid_r])
2194         else
2195                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2196                         ac_cv_func_nonposix_getpwuid_r,
2197                         [AC_TRY_LINK([#include <pwd.h>],
2198                                 [char buffer[10000];
2199                                 struct passwd pwd;
2200                                 getpwuid_r (0, &pwd, buffer,
2201                                                 sizeof (buffer));],
2202                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2203                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2204                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2205                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2206                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2207                                 [Have non-POSIX function getpwuid_r])
2208                 fi
2209         fi
2210 fi
2211 if test "$ac_cv_header_grp_h" = "yes"; then
2212         AC_CACHE_CHECK([for posix getgrgid_r],
2213                 ac_cv_func_posix_getgrgid_r,
2214                 [AC_TRY_RUN([
2215 #include <errno.h>
2216 #include <grp.h>
2217 int main () {
2218     char buffer[10000];
2219     struct group grp, *grpptr = &grp;
2220     int error;
2221     errno = 0;
2222     error = getgrgid_r (0, &grp, buffer,
2223                         sizeof (buffer), &grpptr);
2224    return (error < 0 && errno == ENOSYS)
2225            || error == ENOSYS;
2226 }                              ],
2227                        [ac_cv_func_posix_getgrgid_r=yes],
2228                        [ac_cv_func_posix_getgrgid_r=no])])
2229         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2230         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2231                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2232                         [Have POSIX function getgrgid_r])
2233         else
2234                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2235                         ac_cv_func_nonposix_getgrgid_r,
2236                         [AC_TRY_LINK([#include <grp.h>],
2237                                 [char buffer[10000];
2238                                 struct group grp;
2239                                 getgrgid_r (0, &grp, buffer,
2240                                 sizeof (buffer));],
2241                         [ac_cv_func_nonposix_getgrgid_r=yes],
2242                         [ac_cv_func_nonposix_getgrgid_r=no])])
2243                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2244                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2245                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2246                                 [Have non-POSIX function getgrgid_r])
2247                 fi
2248         fi
2249 fi
2250 LIBS="$G_THREAD_LIBS $LIBS"
2251 if test x"$have_threads" = xposix; then
2252         glib_save_CPPFLAGS="$CPPFLAGS"
2253         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2254         # This is not AC_CHECK_FUNC to also work with function
2255         # name mangling in header files.
2256         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2257         AC_LINK_IFELSE(
2258             [AC_LANG_PROGRAM(
2259                 [#include <pthread.h>],
2260                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2261             [AC_MSG_RESULT(yes)
2262              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2263                 [Have function pthread_attr_setstacksize])],
2264             [AC_MSG_RESULT(no)])
2265         AC_MSG_CHECKING(for pthread_condattr_setclock)
2266         AC_LINK_IFELSE(
2267             [AC_LANG_PROGRAM(
2268                 [#include <pthread.h>],
2269                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2270             [AC_MSG_RESULT(yes)
2271              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2272                 [Have function pthread_condattr_setclock])],
2273             [AC_MSG_RESULT(no)])
2274         CPPFLAGS="$glib_save_CPPFLAGS"
2275 fi
2276
2277 LIBS="$glib_save_LIBS"
2278
2279 # now spit out all the warnings.
2280 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2281    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2282         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2283 fi
2284 if test "$ac_cv_func_localtime_r" != "yes"; then
2285         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2286 fi
2287
2288 #
2289 # Hack to deal with:
2290 #
2291 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2292 #     building shared libraries with linux.
2293 #  b) FreeBSD doesn't do this either.
2294 #
2295 case $host in
2296   *-*-freebsd*|*-*-linux*)
2297     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2298     ;;
2299   *-*-openbsd*)
2300     LDFLAGS="$LDFLAGS -pthread"
2301     ;;
2302   *)
2303     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2304     ;;
2305 esac
2306
2307 AC_SUBST(G_THREAD_CFLAGS)
2308 AC_SUBST(G_THREAD_LIBS)
2309 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2310 AC_SUBST(G_THREAD_LIBS_EXTRA)
2311
2312 AC_CHECK_FUNCS(clock_gettime, [], [
2313   AC_CHECK_LIB(rt, clock_gettime, [
2314     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2315     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2316     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2317   ])
2318 ])
2319
2320
2321 dnl ************************
2322 dnl *** g_atomic_* tests ***
2323 dnl ************************
2324
2325 dnl We need to decide at configure time if GLib will use real atomic
2326 dnl operations ("lock free") or emulated ones with a mutex.  This is
2327 dnl because we must put this information in glibconfig.h so we know if
2328 dnl it is safe or not to inline using compiler intrinsics directly from
2329 dnl the header.
2330 dnl
2331 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2332 dnl user is interested in knowing if they can use the atomic ops across
2333 dnl processes.
2334 dnl
2335 dnl We can currently support the atomic ops natively when building GLib
2336 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2337 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2338 dnl we are using GCC.
2339 dnl
2340 dnl Note that the atomic ops are only available with GCC on x86 when
2341 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2342 dnl not available but would be available given the right flags, we want
2343 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2344 dnl that then to silently fall back on emulated atomic ops just because
2345 dnl the user had the wrong build environment.
2346
2347 dnl We may add other compilers here in the future...
2348
2349 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2350   AC_TRY_COMPILE([],
2351                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2352                  [glib_cv_g_atomic_lock_free=yes],
2353                  [glib_cv_g_atomic_lock_free=no])])
2354
2355 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2356   SAVE_CFLAGS="${CFLAGS}"
2357   CFLAGS="-march=i486"
2358   AC_TRY_COMPILE([],
2359                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2360                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2361                  [])
2362   CFLAGS="${SAVE_CFLAGS}"
2363 fi
2364
2365 dnl We need a more robust approach here...
2366 case $host_cpu in
2367   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2368     glib_memory_barrier_needed=no
2369     ;;
2370   sparc*|alpha*|powerpc*|ia64)
2371     glib_memory_barrier_needed=yes
2372     ;;
2373   *)
2374     glib_memory_barrier_needed=yes
2375     ;;
2376 esac
2377
2378 dnl ************************
2379 dnl ** Check for futex(2) **
2380 dnl ************************
2381 AC_CACHE_CHECK(for futex(2) system call,
2382     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2383 #include <linux/futex.h>
2384 #include <sys/syscall.h>
2385 #include <unistd.h>
2386 ],[
2387 int
2388 main (void)
2389 {
2390   /* it is not like this actually runs or anything... */
2391   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2392   return 0;
2393 }
2394 ])],glib_cv_futex=yes,glib_cv_futex=no))
2395 if test x"$glib_cv_futex" = xyes; then
2396   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2397 fi
2398
2399 AC_CACHE_CHECK(for eventfd(2) system call,
2400     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2401 #include <sys/eventfd.h>
2402 #include <unistd.h>
2403 ],[
2404 int
2405 main (void)
2406 {
2407   eventfd (0, EFD_CLOEXEC);
2408   return 0;
2409 }
2410 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2411 if test x"$glib_cv_eventfd" = x"yes"; then
2412   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2413 fi
2414 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2415
2416 dnl ****************************************
2417 dnl *** GLib POLL* compatibility defines ***
2418 dnl ****************************************
2419
2420 glib_poll_includes=["
2421 #include <sys/types.h>
2422 #include <sys/poll.h>
2423 "]
2424
2425 if test $ac_cv_header_sys_types_h = yes &&
2426    test $ac_cv_header_sys_poll_h = yes ; then
2427   glib_failed=false
2428   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2429   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2430   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2431   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2432   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2433   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2434   if $glib_failed ; then
2435     AC_MSG_ERROR([Could not determine values for POLL* constants])
2436   fi
2437 else
2438   glib_cv_value_POLLIN=1
2439   glib_cv_value_POLLOUT=4
2440   glib_cv_value_POLLPRI=2
2441   glib_cv_value_POLLERR=8
2442   glib_cv_value_POLLHUP=16
2443   glib_cv_value_POLLNVAL=32
2444 fi
2445
2446 AC_MSG_CHECKING([for broken poll])
2447 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2448         #include <stdlib.h>
2449         #include <fcntl.h>
2450         #include <poll.h>
2451         #ifdef HAVE_SYS_POLL_H
2452         #include <sys/poll.h>
2453         #endif
2454         int main(void) {
2455           struct pollfd fds[1];
2456           int fd;
2457           fd = open("/dev/null", 1);
2458           fds[0].fd = fd;
2459           fds[0].events = POLLIN;
2460           fds[0].revents = 0;
2461           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2462                 exit(1);  /* Does not work for devices -- fail */
2463           }
2464           exit(0);
2465         }]])],
2466   [broken_poll=no],
2467   [broken_poll=yes
2468    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2469   [broken_poll="no (cross compiling)"])
2470 AC_MSG_RESULT($broken_poll)
2471
2472 dnl *********************
2473 dnl *** GRegex checks ***
2474 dnl *********************
2475
2476 PCRE_REQUIRED_VERSION=8.11
2477
2478 # Check if we should use the internal or the system-supplied pcre
2479 AC_ARG_WITH(pcre,
2480             [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2481                             [whether to use system PCRE [default=internal]])])
2482
2483 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2484
2485 if test "x$with_pcre" = xsystem; then
2486   PKG_CHECK_MODULES(PCRE,
2487                     libpcre >= $PCRE_REQUIRED_VERSION)
2488   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2489                   glib_save_CFLAGS="$CFLAGS"
2490                   glib_save_LIBS="$LIBS"
2491                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2492                   AC_TRY_RUN([#include <pcre.h>
2493                               int main () {
2494                                 int support;
2495                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2496                                 if (!support)
2497                                   return 1;
2498                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2499                                 if (!support)
2500                                   return 1;
2501                                 return 0;
2502                               }],
2503                   glib_cv_pcre_has_unicode=yes,
2504                   glib_cv_pcre_has_unicode=no,
2505                   glib_cv_pcre_has_unicode=yes)
2506                   CFLAGS="$glib_save_CFLAGS"
2507                   LIBS="$glib_save_LIBS"
2508       ])
2509   if test "$glib_cv_pcre_has_unicode" = "no"; then
2510     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2511   fi
2512   AC_SUBST(PCRE_CFLAGS)
2513   AC_SUBST(PCRE_LIBS)
2514   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2515   PCRE_REQUIRES=libpcre
2516   AC_SUBST(PCRE_REQUIRES)
2517 else
2518   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2519   if test x"$GCC" = xyes; then
2520     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2521     save_CFLAGS="$CFLAGS"
2522     CFLAGS="$CFLAGS -Wno-pointer-sign"
2523     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2524                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2525     CFLAGS="$save_CFLAGS"
2526   fi
2527 fi
2528 AC_SUBST(PCRE_WARN_CFLAGS)
2529
2530 dnl **********************
2531 dnl *** Win32 API libs ***
2532 dnl **********************
2533
2534 case $host in
2535   *-*-cygwin*)
2536         G_LIBS_EXTRA="-luser32 -lkernel32"
2537     ;;
2538   *-*-mingw*)
2539         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2540     ;;
2541   *)
2542         G_LIBS_EXTRA=""
2543     ;;
2544 esac
2545 AC_SUBST(G_LIBS_EXTRA)
2546
2547 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2548 dnl since we need it for g_iconv()
2549
2550 AC_MSG_CHECKING([for EILSEQ])
2551 AC_TRY_COMPILE([
2552 #include <errno.h>
2553 ],
2554 [
2555 int error = EILSEQ;
2556 ], have_eilseq=yes, have_eilseq=no);
2557 AC_MSG_RESULT($have_eilseq)
2558
2559 dnl ******************************************************************
2560 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2561 dnl *** glib-compile-schemas in PATH                               ***
2562 dnl ******************************************************************
2563
2564 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2565
2566 if test $cross_compiling = yes; then
2567   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2568   if test x$GLIB_GENMARSHAL = xno; then
2569     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2570   fi
2571
2572   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2573   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2574     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2575   fi
2576
2577   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2578   if test x$GLIB_COMPILE_RESOURCES = xno; then
2579     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2580   fi
2581 fi
2582
2583 dnl **************************
2584 dnl *** Checks for gtk-doc ***
2585 dnl **************************
2586
2587 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2588
2589 AC_ARG_ENABLE(man,
2590               [AC_HELP_STRING([--enable-man],
2591                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2592               enable_man=no)
2593
2594 if test "${enable_man}" != no; then
2595 dnl
2596 dnl Check for xsltproc
2597 dnl
2598 AC_PATH_PROG([XSLTPROC], [xsltproc])
2599   if test -z "$XSLTPROC"; then
2600     enable_man=no
2601   fi
2602
2603   dnl check for DocBook DTD and stylesheets in the local catalog.
2604   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2605      [DocBook XML DTD V4.1.2],,enable_man=no)
2606   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2607      [DocBook XSL Stylesheets],,enable_man=no)
2608 fi
2609
2610 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2611
2612 dnl
2613 dnl Tracing
2614 dnl
2615
2616 AC_ARG_ENABLE([dtrace],
2617              [AS_HELP_STRING([--enable-dtrace],
2618                               [include tracing support for dtrace])])
2619 have_dtrace=no
2620 AC_MSG_CHECKING([whether to include dtrace tracing support])
2621 if test "x$enable_dtrace" != xno; then
2622   if test x$glib_have_carbon = xyes; then
2623     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2624   else
2625     AC_MSG_RESULT([yes])
2626     AC_CHECK_PROGS(DTRACE, dtrace)
2627     if test -z "$DTRACE"; then
2628       if test "x$enable_dtrace" = xyes; then
2629         AC_MSG_ERROR([dtrace not found])
2630       fi
2631     else
2632       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2633                       [if test "x$enable_dtrace" = xyes; then
2634                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2635                        fi])
2636     fi
2637   fi
2638 else
2639   AC_MSG_RESULT([no])
2640 fi
2641 if test "x$have_dtrace" = xyes; then
2642   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2643 fi
2644 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2645
2646 AC_MSG_CHECKING([whether to include systemtap tracing support])
2647 AC_ARG_ENABLE([systemtap],
2648              [AS_HELP_STRING([--enable-systemtap],
2649                               [include tracing support for systemtap])])
2650 have_systemtap=no
2651 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2652   have_systemtap=yes
2653 fi
2654 AC_MSG_RESULT(${have_systemtap})
2655
2656 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2657
2658 AC_ARG_WITH([tapset-install-dir],
2659             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2660                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2661             [if test "x${withval}" = x; then
2662                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2663              else
2664                ABS_TAPSET_DIR="${withval}"
2665               fi],
2666             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2667 AC_SUBST(ABS_TAPSET_DIR)
2668
2669 dnl ************************************
2670 dnl *** Enable lcov coverage reports ***
2671 dnl ************************************
2672
2673 AC_ARG_ENABLE(gcov,
2674   AS_HELP_STRING([--enable-gcov],
2675                  [enable coverage testing with gcov]),
2676   [use_gcov=$enableval], [use_gcov=no])
2677
2678 if test "x$use_gcov" = "xyes"; then
2679   dnl we need gcc:
2680   if test "$GCC" != "yes"; then
2681     AC_MSG_ERROR([GCC is required for --enable-gcov])
2682   fi
2683
2684   dnl Check if ccache is being used
2685   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2686   case `$SHTOOL path $CC` in
2687     *ccache*[)] gcc_ccache=yes;;
2688     *[)] gcc_ccache=no;;
2689   esac
2690
2691   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2692     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2693   fi
2694
2695   ltp_version_list="1.6 1.7 1.8 1.9"
2696   AC_CHECK_PROG(LTP, lcov, lcov)
2697   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2698
2699   if test "$LTP"; then
2700     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2701       glib_cv_ltp_version=invalid
2702       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2703       for ltp_check_version in $ltp_version_list; do
2704         if test "$ltp_version" = "$ltp_check_version"; then
2705           glib_cv_ltp_version="$ltp_check_version (ok)"
2706         fi
2707       done
2708     ])
2709   else
2710     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2711     AC_MSG_ERROR([$ltp_msg])
2712   fi
2713
2714   case $glib_cv_ltp_version in
2715     ""|invalid[)]
2716       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2717       AC_MSG_ERROR([$ltp_msg])
2718       LTP="exit 0;"
2719       ;;
2720   esac
2721
2722   if test -z "$LTP_GENHTML"; then
2723     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2724   fi
2725
2726   dnl Remove all optimization flags from CFLAGS
2727   changequote({,})
2728   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2729   changequote([,])
2730
2731   dnl Add the special gcc flags
2732   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2733   LDFLAGS="$LDFLAGS -lgcov"
2734 fi
2735
2736 dnl ******************************
2737 dnl *** output the whole stuff ***
2738 dnl ******************************
2739
2740 dnl this section will only be run if config.status is invoked with no
2741 dnl arguments, or with "glib/glibconfig.h" as an argument.
2742 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2743 [
2744         outfile=glib/glibconfig.h-tmp
2745         cat > $outfile <<\_______EOF
2746 /* glibconfig.h
2747  *
2748  * This is a generated file.  Please modify 'configure.ac'
2749  */
2750
2751 #ifndef __GLIBCONFIG_H__
2752 #define __GLIBCONFIG_H__
2753
2754 #include <glib/gmacros.h>
2755
2756 _______EOF
2757
2758         if test x$glib_limits_h = xyes; then
2759           echo '#include <limits.h>' >> $outfile
2760         fi
2761         if test x$glib_float_h = xyes; then
2762           echo '#include <float.h>' >> $outfile
2763         fi
2764         if test x$glib_values_h = xyes; then
2765           echo '#include <values.h>' >> $outfile
2766         fi
2767         if test "$glib_header_alloca_h" = "yes"; then
2768           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2769         fi
2770         if test x$glib_sys_poll_h = xyes; then
2771           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2772         fi
2773         if test x$glib_included_printf != xyes; then
2774           echo "
2775 /* Specifies that GLib's g_print*() functions wrap the
2776  * system printf functions.  This is useful to know, for example,
2777  * when using glibc's register_printf_function().
2778  */" >> $outfile
2779           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2780         fi
2781
2782         cat >> $outfile <<_______EOF
2783
2784 G_BEGIN_DECLS
2785
2786 #define G_MINFLOAT      $glib_mf
2787 #define G_MAXFLOAT      $glib_Mf
2788 #define G_MINDOUBLE     $glib_md
2789 #define G_MAXDOUBLE     $glib_Md
2790 #define G_MINSHORT      $glib_ms
2791 #define G_MAXSHORT      $glib_Ms
2792 #define G_MAXUSHORT     $glib_Mus
2793 #define G_MININT        $glib_mi
2794 #define G_MAXINT        $glib_Mi
2795 #define G_MAXUINT       $glib_Mui
2796 #define G_MINLONG       $glib_ml
2797 #define G_MAXLONG       $glib_Ml
2798 #define G_MAXULONG      $glib_Mul
2799
2800 _______EOF
2801
2802
2803         ### this should always be true in a modern C/C++ compiler
2804         cat >>$outfile <<_______EOF
2805 typedef signed char gint8;
2806 typedef unsigned char guint8;
2807 _______EOF
2808
2809
2810         if test -n "$gint16"; then
2811           cat >>$outfile <<_______EOF
2812 typedef signed $gint16 gint16;
2813 typedef unsigned $gint16 guint16;
2814 #define G_GINT16_MODIFIER $gint16_modifier
2815 #define G_GINT16_FORMAT $gint16_format
2816 #define G_GUINT16_FORMAT $guint16_format
2817 _______EOF
2818         fi
2819
2820
2821         if test -n "$gint32"; then
2822           cat >>$outfile <<_______EOF
2823 typedef signed $gint32 gint32;
2824 typedef unsigned $gint32 guint32;
2825 #define G_GINT32_MODIFIER $gint32_modifier
2826 #define G_GINT32_FORMAT $gint32_format
2827 #define G_GUINT32_FORMAT $guint32_format
2828 _______EOF
2829         fi
2830
2831         cat >>$outfile <<_______EOF
2832 #define G_HAVE_GINT64 1          /* deprecated, always true */
2833
2834 ${glib_extension}typedef signed $gint64 gint64;
2835 ${glib_extension}typedef unsigned $gint64 guint64;
2836
2837 #define G_GINT64_CONSTANT(val)  $gint64_constant
2838 #define G_GUINT64_CONSTANT(val) $guint64_constant
2839 _______EOF
2840
2841         if test x$gint64_format != x ; then
2842           cat >>$outfile <<_______EOF
2843 #define G_GINT64_MODIFIER $gint64_modifier
2844 #define G_GINT64_FORMAT $gint64_format
2845 #define G_GUINT64_FORMAT $guint64_format
2846 _______EOF
2847         else
2848           cat >>$outfile <<_______EOF
2849 #undef G_GINT64_MODIFIER
2850 #undef G_GINT64_FORMAT
2851 #undef G_GUINT64_FORMAT
2852 _______EOF
2853         fi
2854
2855         cat >>$outfile <<_______EOF
2856
2857 #define GLIB_SIZEOF_VOID_P $glib_void_p
2858 #define GLIB_SIZEOF_LONG   $glib_long
2859 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2860
2861 _______EOF
2862
2863         cat >>$outfile <<_______EOF
2864 typedef signed $glib_size_type_define gssize;
2865 typedef unsigned $glib_size_type_define gsize;
2866 #define G_GSIZE_MODIFIER $gsize_modifier
2867 #define G_GSSIZE_FORMAT $gssize_format
2868 #define G_GSIZE_FORMAT $gsize_format
2869
2870 #define G_MAXSIZE       G_MAXU$glib_msize_type
2871 #define G_MINSSIZE      G_MIN$glib_msize_type
2872 #define G_MAXSSIZE      G_MAX$glib_msize_type
2873
2874 typedef gint64 goffset;
2875 #define G_MINOFFSET     G_MININT64
2876 #define G_MAXOFFSET     G_MAXINT64
2877
2878 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2879 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2880 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2881
2882 _______EOF
2883
2884         if test -z "$glib_unknown_void_p"; then
2885           cat >>$outfile <<_______EOF
2886
2887 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2888 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2889
2890 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2891 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2892
2893 typedef signed $glib_intptr_type_define gintptr;
2894 typedef unsigned $glib_intptr_type_define guintptr;
2895
2896 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2897 #define G_GINTPTR_FORMAT        $gintptr_format
2898 #define G_GUINTPTR_FORMAT       $guintptr_format
2899 _______EOF
2900         else
2901           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2902         fi
2903
2904
2905
2906         cat >>$outfile <<_______EOF
2907 $glib_atexit
2908 $glib_memmove
2909 $glib_defines
2910 $glib_os
2911 $glib_static_compilation
2912
2913 $glib_vacopy
2914
2915 #ifdef  __cplusplus
2916 #define G_HAVE_INLINE   1
2917 #else   /* !__cplusplus */
2918 $glib_inline
2919 #endif  /* !__cplusplus */
2920
2921 #ifdef  __cplusplus
2922 #define G_CAN_INLINE    1
2923 _______EOF
2924
2925         if test x$g_can_inline = xyes ; then
2926                 cat >>$outfile <<_______EOF
2927 #else   /* !__cplusplus */
2928 #define G_CAN_INLINE    1
2929 _______EOF
2930         fi
2931
2932         cat >>$outfile <<_______EOF
2933 #endif
2934
2935 _______EOF
2936
2937         if test x$g_have_iso_c_varargs = xyes ; then
2938                 cat >>$outfile <<_______EOF
2939 #ifndef __cplusplus
2940 # define G_HAVE_ISO_VARARGS 1
2941 #endif
2942 _______EOF
2943         fi
2944         if test x$g_have_iso_cxx_varargs = xyes ; then
2945                 cat >>$outfile <<_______EOF
2946 #ifdef __cplusplus
2947 # define G_HAVE_ISO_VARARGS 1
2948 #endif
2949 _______EOF
2950         fi
2951         if test x$g_have_gnuc_varargs = xyes ; then
2952                 cat >>$outfile <<_______EOF
2953
2954 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2955  * is passed ISO vararg support is turned off, and there is no work
2956  * around to turn it on, so we unconditionally turn it off.
2957  */
2958 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2959 #  undef G_HAVE_ISO_VARARGS
2960 #endif
2961
2962 #define G_HAVE_GNUC_VARARGS 1
2963 _______EOF
2964         fi
2965
2966         case x$g_stack_grows in
2967         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2968         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2969         esac
2970
2971
2972         echo >>$outfile
2973         if test x$g_have_eilseq = xno; then
2974                 cat >>$outfile <<_______EOF
2975 #ifndef EILSEQ
2976 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2977  * The correspondence between this and the corresponding definition
2978  * in libiconv is essential.
2979  */
2980 #  define EILSEQ ENOENT
2981 #endif
2982 _______EOF
2983
2984         fi
2985
2986         if test x$g_have_gnuc_visibility = xyes; then
2987                 cat >>$outfile <<_______EOF
2988 #define G_HAVE_GNUC_VISIBILITY 1
2989 _______EOF
2990         fi
2991                 cat >>$outfile <<_______EOF
2992 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2993 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2994 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2995 #define G_GNUC_INTERNAL __hidden
2996 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2997 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2998 #else
2999 #define G_GNUC_INTERNAL
3000 #endif
3001 _______EOF
3002
3003         echo >>$outfile
3004         cat >>$outfile <<_______EOF
3005 #define G_THREADS_ENABLED
3006 #define G_THREADS_IMPL_$g_threads_impl_def
3007 _______EOF
3008
3009         if test x"$g_memory_barrier_needed" != xno; then
3010           echo >>$outfile
3011           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3012         fi
3013         if test x"$g_atomic_lock_free" = xyes; then
3014           echo >>$outfile
3015           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3016         fi
3017         echo >>$outfile
3018         g_bit_sizes="16 32 64"
3019         for bits in $g_bit_sizes; do
3020           cat >>$outfile <<_______EOF
3021 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3022 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3023 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3024 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3025 _______EOF
3026         done
3027
3028         cat >>$outfile <<_______EOF
3029 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3030 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3031 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3032 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3033 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3034 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3035 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3036 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3037 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3038 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3039 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3040 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3041 #define G_BYTE_ORDER $g_byte_order
3042
3043 #define GLIB_SYSDEF_POLLIN =$g_pollin
3044 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3045 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3046 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3047 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3048 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3049
3050 #define G_MODULE_SUFFIX "$g_module_suffix"
3051
3052 typedef $g_pid_type GPid;
3053
3054 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3055 #define GLIB_SYSDEF_AF_INET $g_af_inet
3056 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3057
3058 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3059 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3060 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3061
3062 G_END_DECLS
3063
3064 #endif /* __GLIBCONFIG_H__ */
3065 _______EOF
3066
3067
3068         if cmp -s $outfile glib/glibconfig.h; then
3069           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3070           rm -f $outfile
3071         else
3072           mv $outfile glib/glibconfig.h
3073         fi
3074 ],[
3075
3076 # Note that if two cases are the same, case goes with the first one.
3077 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3078 # on variable expansion in case labels.  Look at the generated config.status
3079 # for a hint.
3080
3081 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3082   glib_header_alloca_h="$ac_cv_working_alloca_h"
3083 else
3084   glib_header_alloca_h="$ac_cv_header_alloca_h"
3085 fi
3086
3087 case xyes in
3088 x$ac_cv_header_float_h)
3089   glib_float_h=yes
3090   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3091   glib_md=DBL_MIN glib_Md=DBL_MAX
3092   ;;
3093 x$ac_cv_header_values_h)
3094   glib_values_h=yes
3095   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3096   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3097   ;;
3098 esac
3099
3100 case xyes in
3101 x$ac_cv_header_limits_h)
3102   glib_limits_h=yes
3103   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3104   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3105   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3106   ;;
3107 x$ac_cv_header_values_h)
3108   glib_values_h=yes
3109   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3110   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3111   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3112   ;;
3113 esac
3114
3115 if test x$ac_cv_header_sys_poll_h = xyes ; then
3116   glib_sys_poll_h=yes
3117 fi
3118
3119 if test x$enable_included_printf = xyes ; then
3120   glib_included_printf=yes
3121 fi
3122
3123 case 2 in
3124 $ac_cv_sizeof_short)
3125   gint16=short
3126   gint16_modifier='"h"'
3127   gint16_format='"hi"'
3128   guint16_format='"hu"'
3129   ;;
3130 $ac_cv_sizeof_int)
3131   gint16=int
3132   gint16_modifier='""'
3133   gint16_format='"i"'
3134   guint16_format='"u"'
3135   ;;
3136 esac
3137 case 4 in
3138 $ac_cv_sizeof_short)
3139   gint32=short
3140   gint32_modifier='"h"'
3141   gint32_format='"hi"'
3142   guint32_format='"hu"'
3143   ;;
3144 $ac_cv_sizeof_int)
3145   gint32=int
3146   gint32_modifier='""'
3147   gint32_format='"i"'
3148   guint32_format='"u"'
3149   ;;
3150 $ac_cv_sizeof_long)
3151   gint32=long
3152   gint32_modifier='"l"'
3153   gint32_format='"li"'
3154   guint32_format='"lu"'
3155   ;;
3156 esac
3157 case 8 in
3158 $ac_cv_sizeof_int)
3159   gint64=int
3160   gint64_modifier='""'
3161   gint64_format='"i"'
3162   guint64_format='"u"'
3163   glib_extension=
3164   gint64_constant='(val)'
3165   guint64_constant='(val)'
3166   ;;
3167 $ac_cv_sizeof_long)
3168   gint64=long
3169   gint64_modifier='"l"'
3170   gint64_format='"li"'
3171   guint64_format='"lu"'
3172   glib_extension=
3173   gint64_constant='(val##L)'
3174   guint64_constant='(val##UL)'
3175   ;;
3176 $ac_cv_sizeof_long_long)
3177   gint64='long long'
3178   if test -n "$glib_cv_long_long_format"; then
3179     gint64_modifier='"'$glib_cv_long_long_format'"'
3180     gint64_format='"'$glib_cv_long_long_format'i"'
3181     guint64_format='"'$glib_cv_long_long_format'u"'
3182   fi
3183   glib_extension='G_GNUC_EXTENSION '
3184   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3185   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3186   ;;
3187 $ac_cv_sizeof___int64)
3188   gint64='__int64'
3189   if test -n "$glib_cv_long_long_format"; then
3190     gint64_modifier='"'$glib_cv_long_long_format'"'
3191     gint64_format='"'$glib_cv_long_long_format'i"'
3192     guint64_format='"'$glib_cv_long_long_format'u"'
3193   fi
3194   glib_extension=
3195   gint64_constant='(val##i64)'
3196   guint64_constant='(val##ui64)'
3197   ;;
3198 esac
3199 glib_size_t=$ac_cv_sizeof_size_t
3200 glib_size_type_define="$glib_size_type"
3201 glib_void_p=$ac_cv_sizeof_void_p
3202 glib_long=$ac_cv_sizeof_long
3203
3204 case "$glib_size_type" in
3205 short)
3206   gsize_modifier='"h"'
3207   gsize_format='"hu"'
3208   gssize_format='"hi"'
3209   glib_msize_type='SHRT'
3210   ;;
3211 int)
3212   gsize_modifier='""'
3213   gsize_format='"u"'
3214   gssize_format='"i"'
3215   glib_msize_type='INT'
3216   ;;
3217 long)
3218   gsize_modifier='"l"'
3219   gsize_format='"lu"'
3220   gssize_format='"li"'
3221   glib_msize_type='LONG'
3222   ;;
3223 "long long"|__int64)
3224   gsize_modifier='"I64"'
3225   gsize_format='"I64u"'
3226   gssize_format='"I64i"'
3227   glib_msize_type='INT64'
3228   ;;
3229 esac
3230
3231 gintbits=`expr $ac_cv_sizeof_int \* 8`
3232 glongbits=`expr $ac_cv_sizeof_long \* 8`
3233 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3234
3235 case $ac_cv_sizeof_void_p in
3236 $ac_cv_sizeof_int)
3237   glib_intptr_type_define=int
3238   gintptr_modifier='""'
3239   gintptr_format='"i"'
3240   guintptr_format='"u"'
3241   glib_gpi_cast='(gint)'
3242   glib_gpui_cast='(guint)'
3243   ;;
3244 $ac_cv_sizeof_long)
3245   glib_intptr_type_define=long
3246   gintptr_modifier='"l"'
3247   gintptr_format='"li"'
3248   guintptr_format='"lu"'
3249   glib_gpi_cast='(glong)'
3250   glib_gpui_cast='(gulong)'
3251   ;;
3252 $ac_cv_sizeof_long_long)
3253   glib_intptr_type_define='long long'
3254   gintptr_modifier='"I64"'
3255   gintptr_format='"I64i"'
3256   guintptr_format='"I64u"'
3257   glib_gpi_cast='(gint64)'
3258   glib_gpui_cast='(guint64)'
3259   ;;
3260 $ac_cv_sizeof___int64)
3261   glib_intptr_type_define=__int64
3262   gintptr_modifier='"I64"'
3263   gintptr_format='"I64i"'
3264   guintptr_format='"I64u"'
3265   glib_gpi_cast='(gint64)'
3266   glib_gpui_cast='(guint64)'
3267   ;;
3268 *)
3269   glib_unknown_void_p=yes
3270   ;;
3271 esac
3272
3273
3274 case xyes in
3275 x$ac_cv_func_atexit)
3276   glib_atexit="
3277 #ifdef NeXT /* @#%@! NeXTStep */
3278 # define g_ATEXIT(proc) (!atexit (proc))
3279 #else
3280 # define g_ATEXIT(proc) (atexit (proc))
3281 #endif"
3282   ;;
3283 x$ac_cv_func_on_exit)
3284   glib_atexit="
3285 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3286   ;;
3287 esac
3288
3289 case xyes in
3290 x$ac_cv_func_memmove)
3291   glib_memmove='
3292 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3293   ;;
3294 x$glib_cv_working_bcopy)
3295   glib_memmove="
3296 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3297 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3298   ;;
3299 *)
3300   glib_memmove="
3301 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3302  * so we have to roll our own copy routine. */
3303 void g_memmove (void* dest, const void * src, unsigned long len);"
3304   ;;
3305 esac
3306
3307 glib_defines="
3308 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3309 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3310 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3311 "
3312
3313 case xyes in
3314 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3315 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3316 *)                      glib_vacopy=''
3317 esac
3318
3319 if test x$glib_cv_va_val_copy = xno; then
3320   glib_vacopy="\$glib_vacopy
3321 #define G_VA_COPY_AS_ARRAY 1"
3322 fi
3323
3324 if test x$glib_cv_hasinline = xyes; then
3325     glib_inline='#define G_HAVE_INLINE 1'
3326 fi
3327 if test x$glib_cv_has__inline = xyes; then
3328     glib_inline="\$glib_inline
3329 #define G_HAVE___INLINE 1"
3330 fi
3331 if test x$glib_cv_has__inline__ = xyes; then
3332     glib_inline="\$glib_inline
3333 #define G_HAVE___INLINE__ 1"
3334 fi
3335
3336 g_have_gnuc_varargs=$g_have_gnuc_varargs
3337 g_have_iso_c_varargs=$g_have_iso_c_varargs
3338 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3339
3340 g_can_inline=$g_can_inline
3341 g_have_gnuc_visibility=$g_have_gnuc_visibility
3342 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3343
3344 if test x$ac_cv_c_bigendian = xyes; then
3345   g_byte_order=G_BIG_ENDIAN
3346   g_bs_native=BE
3347   g_bs_alien=LE
3348 else
3349   g_byte_order=G_LITTLE_ENDIAN
3350   g_bs_native=LE
3351   g_bs_alien=BE
3352 fi
3353
3354 g_pollin=$glib_cv_value_POLLIN
3355 g_pollout=$glib_cv_value_POLLOUT
3356 g_pollpri=$glib_cv_value_POLLPRI
3357 g_pollhup=$glib_cv_value_POLLHUP
3358 g_pollerr=$glib_cv_value_POLLERR
3359 g_pollnval=$glib_cv_value_POLLNVAL
3360
3361 # If a family is not found on the system, define that family to
3362 # a negative value, picking a different one for each undefined
3363 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3364 # This is needed because glib-mkenums doesn't handle optional
3365 # values in enums, and thus we have to have all existing values
3366 # defined in the enum.
3367 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3368   g_af_unix=$glib_cv_value_AF_UNIX
3369 else
3370   g_af_unix=-1
3371 fi
3372 g_af_inet=$glib_cv_value_AF_INET
3373 g_af_inet6=$glib_cv_value_AF_INET6
3374
3375 g_msg_peek=$glib_cv_value_MSG_PEEK
3376 g_msg_oob=$glib_cv_value_MSG_OOB
3377 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3378
3379 g_stack_grows=$glib_cv_stack_grows
3380
3381 g_have_eilseq=$have_eilseq
3382
3383 g_threads_impl_def=$g_threads_impl
3384
3385 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3386 g_memory_barrier_needed="$glib_memory_barrier_needed"
3387 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3388
3389 g_module_suffix="$glib_gmodule_suffix"
3390
3391 g_pid_type="$glib_pid_type"
3392 case $host in
3393   *-*-beos*)
3394     glib_os="#define G_OS_BEOS"
3395     ;;
3396   *-*-cygwin*)
3397     glib_os="#define G_OS_UNIX
3398 #define G_PLATFORM_WIN32
3399 #define G_WITH_CYGWIN"
3400     ;;
3401   *-*-mingw*)
3402     glib_os="#define G_OS_WIN32
3403 #define G_PLATFORM_WIN32"
3404     ;;
3405   *)
3406     glib_os="#define G_OS_UNIX"
3407     ;;
3408 esac
3409 glib_static_compilation=""
3410 if test x$glib_win32_static_compilation = xyes; then
3411   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3412 #define GOBJECT_STATIC_COMPILATION 1"
3413 fi
3414 ])
3415
3416 # Redo enough to get guint32 and guint64 for the alignment checks below
3417 case 4 in
3418 $ac_cv_sizeof_short)
3419   gint32=short
3420   ;;
3421 $ac_cv_sizeof_int)
3422   gint32=int
3423   ;;
3424 $ac_cv_sizeof_long)
3425   gint32=long
3426   ;;
3427 esac
3428 case 8 in
3429 $ac_cv_sizeof_int)
3430   gint64=int
3431   ;;
3432 $ac_cv_sizeof_long)
3433   gint64=long
3434   ;;
3435 $ac_cv_sizeof_long_long)
3436   gint64='long long'
3437   ;;
3438 $ac_cv_sizeof___int64)
3439   gint64='__int64'
3440   ;;
3441 esac
3442
3443 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3444 typedef unsigned $gint32 guint32;])
3445 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3446 typedef unsigned $gint64 guint64;])
3447 AC_CHECK_ALIGNOF([unsigned long])
3448
3449 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3450 #
3451 # 1.2.14 required for dbus_message_set_serial
3452 PKG_CHECK_MODULES(DBUS1,
3453                   dbus-1 >= 1.2.14,
3454                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3455                   have_dbus1=no)
3456 AC_SUBST(DBUS1_CFLAGS)
3457 AC_SUBST(DBUS1_LIBS)
3458 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3459
3460 dnl
3461 dnl Check for -Bsymbolic-functions linker flag used to avoid
3462 dnl intra-library PLT jumps, if available.
3463 dnl
3464
3465 AC_ARG_ENABLE(Bsymbolic,
3466               [AC_HELP_STRING([--disable-Bsymbolic],
3467                               [avoid linking with -Bsymbolic])],,
3468               [SAVED_LDFLAGS="${LDFLAGS}"
3469                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3470                LDFLAGS=-Wl,-Bsymbolic-functions
3471                AC_TRY_LINK([], [int main (void) { return 0; }],
3472                            AC_MSG_RESULT(yes)
3473                            enable_Bsymbolic=yes,
3474                            AC_MSG_RESULT(no)
3475                            enable_Bsymbolic=no)
3476                LDFLAGS="${SAVED_LDFLAGS}"])
3477
3478 if test "x${enable_Bsymbolic}" = "xyes"; then
3479   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3480 fi
3481
3482 AC_SUBST(GLIB_LINK_FLAGS)
3483
3484 #
3485 # Define variables corresponding to the correct include paths to use for
3486 # in-tree building.
3487 #
3488
3489 # for config.h:
3490 config_h_INCLUDES='-I$(top_builddir)'
3491 AC_SUBST(config_h_INCLUDES)
3492
3493 # glib:
3494 #   config.h
3495 #   $(top_builddir)/glib: for glibconfig.h
3496 #   $(top_srcdir)/glib:   for glib.h
3497 #   $(top_srcdir):        for everything
3498 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3499 AC_SUBST(glib_INCLUDES)
3500
3501 # gthread:
3502 #   same as glib
3503 gthread_INCLUDES='$(glib_INCLUDES)'
3504 AC_SUBST(gthread_INCLUDES)
3505
3506 # gobject:
3507 #   same as gthread
3508 gobject_INCLUDES='$(gthread_INCLUDES)'
3509 AC_SUBST(gobject_INCLUDES)
3510
3511 # gmodule:
3512 #   glib includes
3513 #   $(top_srcdir)/gmodule: for gmodule.h
3514 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3515 AC_SUBST(gmodule_INCLUDES)
3516
3517 # gio:
3518 #   same as gmodule
3519 gio_INCLUDES='$(gmodule_INCLUDES)'
3520 AC_SUBST(gio_INCLUDES)
3521
3522
3523 AC_CONFIG_FILES([
3524 glib-2.0.pc
3525 gmodule-2.0.pc
3526 gmodule-export-2.0.pc
3527 gmodule-no-export-2.0.pc
3528 gthread-2.0.pc
3529 gobject-2.0.pc
3530 gio-2.0.pc
3531 gio-unix-2.0.pc
3532 gio-windows-2.0.pc
3533 glib-zip
3534 glib-gettextize
3535 Makefile
3536 build/Makefile
3537 build/win32/Makefile
3538 build/win32/dirent/Makefile
3539 build/win32/vs9/Makefile
3540 build/win32/vs10/Makefile
3541 glib/Makefile
3542 glib/glib.stp
3543 glib/libcharset/Makefile
3544 glib/gnulib/Makefile
3545 glib/pcre/Makefile
3546 glib/update-pcre/Makefile
3547 glib/tests/Makefile
3548 gmodule/Makefile
3549 gmodule/gmoduleconf.h
3550 gobject/Makefile
3551 gobject/gobject.stp
3552 gobject/glib-mkenums
3553 gobject/tests/Makefile
3554 gthread/Makefile
3555 gio/Makefile
3556 gio/gdbus-2.0/codegen/Makefile
3557 gio/gdbus-2.0/codegen/config.py
3558 gio/xdgmime/Makefile
3559 gio/inotify/Makefile
3560 gio/fen/Makefile
3561 gio/fam/Makefile
3562 gio/win32/Makefile
3563 gio/tests/Makefile
3564 gio/tests/gdbus-object-manager-example/Makefile
3565 po/Makefile.in
3566 docs/Makefile
3567 docs/reference/Makefile
3568 docs/reference/glib/Makefile
3569 docs/reference/glib/version.xml
3570 docs/reference/gobject/Makefile
3571 docs/reference/gobject/version.xml
3572 docs/reference/gio/Makefile
3573 docs/reference/gio/gdbus-object-manager-example/Makefile
3574 docs/reference/gio/version.xml
3575 tests/Makefile
3576 tests/gobject/Makefile
3577 tests/refcount/Makefile
3578 m4macros/Makefile
3579 ])
3580
3581 AC_CONFIG_COMMANDS([chmod-scripts],
3582 [chmod 0755 glib-zip
3583 chmod 0755 glib-gettextize
3584 chmod 0755 gobject/glib-mkenums])
3585
3586 # we want to invoke this macro solely so that the config.status script
3587 # and automake generated makefiles know about these generated files.
3588 # They are only needed to distcheck the package
3589 if false; then
3590   AC_CONFIG_FILES([
3591     INSTALL
3592     README
3593     config.h.win32
3594     glib/glibconfig.h.win32
3595     glib/makefile.msc
3596     glib/glib.rc
3597     gmodule/makefile.msc
3598     gmodule/gmodule.rc
3599     gobject/makefile.msc
3600     gobject/gobject.rc
3601     gthread/makefile.msc
3602     gthread/gthread.rc
3603     gio/gio.rc
3604     tests/makefile.msc
3605   ])
3606 fi
3607
3608 AC_OUTPUT