configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [7])
   6 m4_define([dbus_micro_version], [3])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22 # By default, rebuild autotools files on demand; only use ./missing if the
  23 # user says --disable-maintainer-mode (some distributions like to do this)
  24 AM_MAINTAINER_MODE([enable])
  25
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  29
  30 # libtool versioning - this applies to libdbus
  31 #
  32 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  33 #
  34
  35 ## increment if the interface has additions, changes, removals.
  36 LT_CURRENT=11
  37
  38 ## increment any time the source changes; set to
  39 ##  0 if you increment CURRENT
  40 LT_REVISION=1
  41
  42 ## increment if any interfaces have been added; set to 0
  43 ## if any interfaces have been changed or removed. removal has
  44 ## precedence over adding, so set to 0 if both happened.
  45 LT_AGE=8
  46
  47 AC_SUBST(LT_CURRENT)
  48 AC_SUBST(LT_REVISION)
  49 AC_SUBST(LT_AGE)
  50
  51 DBUS_MAJOR_VERSION=dbus_major_version
  52 DBUS_MINOR_VERSION=dbus_minor_version
  53 DBUS_MICRO_VERSION=dbus_micro_version
  54 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  55
  56 AC_SUBST(DBUS_MAJOR_VERSION)
  57 AC_SUBST(DBUS_MINOR_VERSION)
  58 AC_SUBST(DBUS_MICRO_VERSION)
  59 AC_SUBST(DBUS_VERSION)
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_CXX
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_ISC_POSIX
  66 AC_HEADER_STDC
  67 AC_C_INLINE
  68 AM_PROG_LIBTOOL
  69 AC_PROG_MKDIR_P
  70 COMPILER_COVERAGE
  71 COMPILER_OPTIMISATIONS
  72 PKG_PROG_PKG_CONFIG
  73
  74 # Initialize libtool
  75 LT_INIT([win32-dll])
  76 LT_LANG([Windows Resource])
  77
  78 # Set some internal variables depending on the platform for later use.
  79 dbus_win=no
  80 dbus_cygwin=no
  81 dbus_unix=no
  82 case "${host}" in
  83     *-mingw32ce*)
  84         dbus_win=yes
  85         dbus_wince=yes
  86         ;;
  87     *-mingw32*)
  88         dbus_win=yes
  89         ;;
  90     *-cygwin*)
  91         dbus_cygwin=yes
  92         dbus_unix=yes
  93         ;;
  94     *)
  95         dbus_unix=yes
  96        ;;
  97 esac
  98
  99 # Special defines for certain platforms
 100 if test "$dbus_win" = yes; then
 101     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 102     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 103     AC_SUBST(BUILD_TIMESTAMP)
 104     # Assume DBUS_VERSION is always three numbers
 105     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 106     AC_SUBST(BUILD_FILEVERSION)
 107     AC_CHECK_TOOL(WINDRES, windres, no)
 108     if test "$WINDRES" = no; then
 109       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 110     fi
 111     if test "$dbus_wince" = yes; then
 112       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 113       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 114     fi
 115 else
 116     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 117 fi
 118 if test "$dbus_cygwin" = yes; then
 119     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 120 fi
 121
 122 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 123 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 124 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 125 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 126
 127 # this must come first: other options use this to set their defaults
 128 AC_ARG_ENABLE([developer],
 129   [AS_HELP_STRING([--enable-developer],
 130     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
 131   [],
 132   [enable_developer=no])
 133
 134 DBUS_STATIC_BUILD_CPPFLAGS=
 135 if test "x$enable_shared" = xno; then
 136     # On Windows, linking against the static library requires special effort
 137     # to turn off DLL import/export processing. We normally link some things
 138     # against the dynamic library, but if we're not building that, we'll
 139     # have to link everything statically.
 140     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 141 fi
 142 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 143
 144 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 145 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 146 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 147 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 148 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 149 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 150 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 151 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 152 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 153 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 154 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 155 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 156 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 157 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 158 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 159 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 160
 161 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 162 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 163 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 164 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 165 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 166 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 167 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 168 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 169 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 170 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 171
 172 AC_ARG_ENABLE([embedded-tests],
 173   AS_HELP_STRING([--enable-embedded-tests],
 174     [enable unit test code in the library and binaries]),
 175   [], [enable_embedded_tests=$enable_developer])
 176 AC_ARG_ENABLE([modular-tests],
 177   AS_HELP_STRING([--enable-modular-tests],
 178     [enable modular regression tests (requires GLib)]),
 179   [], [enable_modular_tests=auto])
 180 # --enable-tests overrides both --enable-embedded-tests and
 181 # --enable-modular-tests
 182 AC_ARG_ENABLE([tests],
 183   AS_HELP_STRING([--enable-tests],
 184     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 185   [
 186   if test "x$enableval" = xyes; then
 187     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 188     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 189   fi
 190   enable_embedded_tests=$enableval
 191   enable_modular_tests=$enableval
 192   ],
 193   [])
 194
 195 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 196 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 197 # name for this.
 198 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 199 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 200   [test "x$enable_embedded_tests" = xyes])
 201 if test "x$enable_embedded_tests" = xyes; then
 202     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 203       [Define to build test code into the library and binaries])
 204     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 205       [Define to build test code into the library and binaries])
 206 fi
 207
 208 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 209 # These use GTest, from GLib, because life's too short. They're enabled by
 210 # default (unless you don't have GLib), because they don't bloat the library
 211 # or binaries.
 212
 213 AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_26], [Ignore post-2.26 deprecations])
 214 AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [GLIB_VERSION_2_32], [Prevent post-2.32 APIs])
 215
 216 with_glib=yes
 217
 218 if test "x$enable_modular_tests" != xno; then
 219   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 220     [],
 221     [if test "x$enable_modular_tests" = xyes; then
 222       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 223       AC_MSG_ERROR([$GLIB_ERRORS])
 224     else # assumed to be "auto"
 225       with_glib=no
 226     fi])
 227   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 228   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 229     [],
 230     [if test "x$enable_modular_tests" = xyes; then
 231       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 232       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 233     else # assumed to be "auto"
 234       with_glib=no
 235     fi])
 236 fi
 237 if test "x$enable_modular_tests" != xno; then
 238   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 239     [Define to build independent test binaries])
 240 fi
 241 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 242   [test "x$enable_modular_tests" != xno])
 243
 244 if test "x$with_glib" != xno; then
 245   AC_DEFINE([DBUS_WITH_GLIB], [1],
 246     [Define if GLib, GObject, GIO are available])
 247 fi
 248 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 249
 250 AC_ARG_ENABLE([installed-tests],
 251   AS_HELP_STRING([--enable-installed-tests],
 252     [enable unit test code in the library and binaries]),
 253   [], [enable_installed_tests=no])
 254 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 255   [test "x$enable_installed_tests" = xyes])
 256
 257 if test "x$enable_tests" = xyes; then
 258   # full test coverage is required, Python is a hard dependency
 259   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 260   AM_PATH_PYTHON([2.6])
 261   AC_MSG_CHECKING([for Python modules for full test coverage])
 262   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 263     AC_MSG_RESULT([yes])
 264   else
 265     AC_MSG_RESULT([no])
 266     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 267   fi
 268 else
 269   # --enable-tests not given: do not abort if Python is missing
 270   AM_PATH_PYTHON([2.6], [], [:])
 271 fi
 272
 273 if test x$enable_verbose_mode = xyes; then
 274     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 275 fi
 276
 277 if test x$enable_asserts = xno; then
 278     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 279     DISABLE_UNUSED_WARNINGS="unused-label"
 280     R_DYNAMIC_LDFLAG=""
 281 else
 282     # -rdynamic is needed for glibc's backtrace_symbols to work.
 283     # No clue how much overhead this adds, but it's useful
 284     # to do this on any assertion failure,
 285     # so for now it's enabled anytime asserts are (currently not
 286     # in production builds).
 287
 288     # To get -rdynamic you pass -export-dynamic to libtool.
 289     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 290     R_DYNAMIC_LDFLAG=-export-dynamic
 291 fi
 292 AC_SUBST(R_DYNAMIC_LDFLAG)
 293
 294 if test x$enable_checks = xno; then
 295     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 296     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 297     DISABLE_UNUSED_WARNINGS="unused-label"
 298 fi
 299
 300 if test x$enable_userdb_cache = xyes; then
 301     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 302 fi
 303
 304 if test x$enable_compiler_coverage = xyes; then
 305      ## so that config.h changes when you toggle gcov support
 306      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 307 fi
 308
 309 # glibc21.m4 serial 3
 310 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 311 dnl This file is free software; the Free Software Foundation
 312 dnl gives unlimited permission to copy and/or distribute it,
 313 dnl with or without modifications, as long as this notice is preserved.
 314
 315 # Test for the GNU C Library, version 2.1 or newer.
 316 # From Bruno Haible.
 317
 318 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 319   ac_cv_gnu_library_2_1,
 320   [AC_EGREP_CPP([Lucky GNU user],
 321     [
 322 #include <features.h>
 323 #ifdef __GNU_LIBRARY__
 324  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 325   Lucky GNU user
 326  #endif
 327 #endif
 328     ],
 329     ac_cv_gnu_library_2_1=yes,
 330     ac_cv_gnu_library_2_1=no)
 331   ]
 332 )
 333
 334 #### Integer sizes
 335
 336 AC_CHECK_SIZEOF(char)
 337 AC_CHECK_SIZEOF(short)
 338 AC_CHECK_SIZEOF(long)
 339 AC_CHECK_SIZEOF(int)
 340 AC_CHECK_SIZEOF(void *)
 341 AC_CHECK_SIZEOF(long long)
 342 AC_CHECK_SIZEOF(__int64)
 343
 344 AC_ARG_WITH([64-bit],
 345   [AS_HELP_STRING([--without-64-bit],
 346     [If you have to use this option, please report it as a bug])],
 347   [],
 348   [with_64_bit=yes])
 349
 350 ### See what our 64 bit type is called
 351 AC_MSG_CHECKING([64-bit integer type])
 352
 353 case 8 in
 354 $ac_cv_sizeof_int)
 355   dbusint64=int
 356   dbusint64_constant='(val)'
 357   dbusuint64_constant='(val)'
 358   dbusint64_printf_modifier='""'
 359   ;;
 360 $ac_cv_sizeof_long)
 361   dbusint64=long
 362   dbusint64_constant='(val##L)'
 363   dbusuint64_constant='(val##UL)'
 364   dbusint64_printf_modifier='"l"'
 365   ;;
 366 $ac_cv_sizeof_long_long)
 367   dbusint64='long long'
 368   dbusint64_constant='(val##LL)'
 369   dbusuint64_constant='(val##ULL)'
 370   # Ideally we discover what the format is, but this is
 371   # only used in verbose mode, so eh...
 372   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 373     dbusint64_printf_modifier='"ll"'
 374   fi
 375   ;;
 376 $ac_cv_sizeof___int64)
 377   dbusint64=__int64
 378   dbusint64_constant='(val##i64)'
 379   dbusuint64_constant='(val##ui64)'
 380   # See above case
 381   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 382     dbusint64_printf_modifier='"ll"'
 383   fi
 384   ;;
 385 esac
 386
 387 AS_IF(
 388   [test "x$with_64_bit" = xno],
 389   [
 390         DBUS_INT64_TYPE="no_int64_type_detected"
 391         DBUS_HAVE_INT64=0
 392         DBUS_INT64_CONSTANT=
 393         DBUS_UINT64_CONSTANT=
 394         AC_MSG_RESULT([disabled via --without-64-bit])
 395   ],
 396   dnl else if
 397   [test -z "$dbusint64"],
 398   [AC_MSG_RESULT([not found])
 399   AC_MSG_ERROR([Could not find a 64-bit integer type.
 400
 401 Please report a bug here with details of your platform and compiler:
 402
 403     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 404
 405 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 406 the option "--without-64-bit".
 407
 408 This option is likely to be removed in future, unless you report that your
 409 platform needs it.])
 410   ],
 411   dnl else
 412   [
 413         DBUS_INT64_TYPE="$dbusint64"
 414         DBUS_HAVE_INT64=1
 415         DBUS_INT64_CONSTANT="$dbusint64_constant"
 416         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 417         if test x"$dbusint64_printf_modifier" != x; then
 418                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 419         fi
 420         AC_MSG_RESULT($DBUS_INT64_TYPE)
 421   ])
 422
 423 AC_SUBST(DBUS_INT64_TYPE)
 424 AC_SUBST(DBUS_INT64_CONSTANT)
 425 AC_SUBST(DBUS_UINT64_CONSTANT)
 426 AC_SUBST(DBUS_HAVE_INT64)
 427
 428 ### see what 32-bit int is called
 429 AC_MSG_CHECKING([32-bit integer type])
 430
 431 case 4 in
 432 $ac_cv_sizeof_short)
 433   dbusint32=short
 434   ;;
 435 $ac_cv_sizeof_int)
 436   dbusint32=int
 437   ;;
 438 $ac_cv_sizeof_long)
 439   dbusint32=long
 440   ;;
 441 esac
 442
 443 if test -z "$dbusint32" ; then
 444         DBUS_INT32_TYPE="no_int32_type_detected"
 445         AC_MSG_ERROR([No 32-bit integer type found])
 446 else
 447         DBUS_INT32_TYPE="$dbusint32"
 448         AC_MSG_RESULT($DBUS_INT32_TYPE)
 449 fi
 450
 451 AC_SUBST(DBUS_INT32_TYPE)
 452
 453 ### see what 16-bit int is called
 454 AC_MSG_CHECKING([16-bit integer type])
 455
 456 case 2 in
 457 $ac_cv_sizeof_short)
 458   dbusint16=short
 459   ;;
 460 $ac_cv_sizeof_int)
 461   dbusint16=int
 462   ;;
 463 esac
 464
 465 if test -z "$dbusint16" ; then
 466         DBUS_INT16_TYPE="no_int16_type_detected"
 467         AC_MSG_ERROR([No 16-bit integer type found])
 468 else
 469         DBUS_INT16_TYPE="$dbusint16"
 470         AC_MSG_RESULT($DBUS_INT16_TYPE)
 471 fi
 472
 473 AC_SUBST(DBUS_INT16_TYPE)
 474
 475 ## byte order
 476 case $host_os in
 477         darwin*)
 478                 # check at compile-time, so that it is possible to build universal
 479                 # (with multiple architectures at once on the compile line)
 480                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 481                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 482                         #if defined(__BIG_ENDIAN__)
 483                         #define WORDS_BIGENDIAN 1
 484                         #endif
 485                 ])
 486                 ;;
 487         *)
 488                 AC_C_BIGENDIAN
 489                 ;;
 490 esac
 491
 492 dnl **********************************
 493 dnl *** va_copy checks (from GLib) ***
 494 dnl **********************************
 495 dnl we currently check for all three va_copy possibilities, so we get
 496 dnl all results in config.log for bug reports.
 497 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 498         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 499 #include <stdlib.h>
 500         static void f (int i, ...) {
 501         va_list args1, args2;
 502         va_start (args1, i);
 503         va_copy (args2, args1);
 504         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 505           exit (1);
 506         va_end (args1); va_end (args2);
 507         }
 508         int main() {
 509           f (0, 42);
 510           return 0;
 511         }])],
 512         [dbus_cv_va_copy=yes],
 513         [dbus_cv_va_copy=no])
 514 ])
 515 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 516         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 517 #include <stdlib.h>
 518         static void f (int i, ...) {
 519         va_list args1, args2;
 520         va_start (args1, i);
 521         __va_copy (args2, args1);
 522         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 523           exit (1);
 524         va_end (args1); va_end (args2);
 525         }
 526         int main() {
 527           f (0, 42);
 528           return 0;
 529         }])],
 530         [dbus_cv___va_copy=yes],
 531         [dbus_cv___va_copy=no])
 532 ])
 533
 534 if test "x$dbus_cv_va_copy" = "xyes"; then
 535   dbus_va_copy_func=va_copy
 536 else if test "x$dbus_cv___va_copy" = "xyes"; then
 537   dbus_va_copy_func=__va_copy
 538 fi
 539 fi
 540
 541 if test -n "$dbus_va_copy_func"; then
 542   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 543 fi
 544
 545 AC_LANG_PUSH(C)
 546 AC_CACHE_CHECK([whether va_lists can be copied by value],
 547         dbus_cv_va_val_copy,
 548         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 549 [[
 550         #include <stdarg.h>
 551         #include <stdlib.h>
 552 ]],
 553 [[
 554         static void f (int i, ...) {
 555         va_list args1, args2;
 556         va_start (args1, i);
 557         args2 = args1;
 558         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 559           exit (1);
 560         va_end (args1); va_end (args2);
 561         }
 562         int main() {
 563           f (0, 42);
 564           return 0;
 565         }
 566 ]])],
 567         [dbus_cv_va_val_copy=yes],
 568         [dbus_cv_va_val_copy=no],
 569         [dbus_cv_va_val_copy=yes])
 570 ])
 571 AC_LANG_POP(C)
 572
 573 if test "x$dbus_cv_va_val_copy" = "xno"; then
 574   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 575 fi
 576
 577
 578 #### Atomic integers
 579
 580 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 581   dbus_cv_sync_sub_and_fetch,
 582   [AC_LINK_IFELSE([
 583      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 584      [dbus_cv_sync_sub_and_fetch=yes],
 585      [dbus_cv_sync_sub_and_fetch=no])
 586   ])
 587
 588 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 589    have_sync=1
 590 else
 591    have_sync=0
 592 fi
 593
 594 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 595
 596 #### Various functions
 597 AC_SEARCH_LIBS(socket,[socket network])
 598 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 599
 600 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid)
 601
 602 AC_CHECK_HEADERS([syslog.h])
 603 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 604   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 605 fi
 606
 607 #### Check for broken poll; taken from Glib's configure
 608
 609 AC_MSG_CHECKING([for broken poll])
 610 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 611     #include <stdlib.h>
 612     #include <fcntl.h>
 613     #include <poll.h>
 614     #ifdef HAVE_SYS_POLL_H
 615     #include <sys/poll.h>
 616     #endif
 617     int main(void) {
 618       struct pollfd fds[1];
 619       int fd;
 620       fd = open("/dev/null", 1);
 621       fds[0].fd = fd;
 622       fds[0].events = POLLIN;
 623       fds[0].revents = 0;
 624       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 625             exit(1);  /* Does not work for devices -- fail */
 626       }
 627       exit(0);
 628     }]])],
 629   [broken_poll=no],
 630   [broken_poll=yes
 631    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 632   [broken_poll="no (cross compiling)"])
 633 AC_MSG_RESULT($broken_poll)
 634
 635 AC_MSG_CHECKING(for dirfd)
 636 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 637 #include <sys/types.h>
 638 #include <dirent.h>
 639 ]], [[
 640 DIR *dirp;
 641 dirp = opendir(".");
 642 dirfd(dirp);
 643 closedir(dirp);
 644 ]])],
 645 [dbus_have_dirfd=yes],
 646 [dbus_have_dirfd=no])
 647 AC_MSG_RESULT($dbus_have_dirfd)
 648 if test "$dbus_have_dirfd" = yes; then
 649         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 650 else
 651         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 652         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 653 #include <sys/types.h>
 654 #include <dirent.h>
 655         ]], [[
 656 DIR *dirp;
 657 int fd;
 658 dirp = opendir(".");
 659 fd = dirp->dd_fd;
 660 closedir(dirp);
 661         ]])],
 662         [dbus_have_ddfd=yes],
 663         [dbus_have_ddfd=no])
 664         AC_MSG_RESULT($dbus_have_ddfd)
 665         if test "$dbus_have_ddfd" = yes; then
 666                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 667         fi
 668 fi
 669
 670 AC_CHECK_HEADERS(sys/resource.h)
 671
 672 AC_CHECK_HEADERS(dirent.h)
 673
 674 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 675
 676 AC_CHECK_HEADERS(errno.h)
 677
 678 AC_CHECK_HEADERS(signal.h)
 679
 680 AC_CHECK_HEADERS(locale.h)
 681
 682 AC_CHECK_HEADERS(byteswap.h)
 683
 684 AC_CHECK_HEADERS(unistd.h)
 685
 686 AC_CHECK_HEADERS(ws2tcpip.h)
 687
 688 AC_CHECK_HEADERS(wspiapi.h)
 689
 690 AC_CHECK_HEADERS(alloca.h)
 691
 692 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 693 #
 694 case $host_os in
 695     solaris*)
 696        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 697 esac
 698
 699 # checking for a posix version of getpwnam_r
 700 # if we are cross compiling and can not run the test
 701 # assume getpwnam_r is the posix version
 702 # it is up to the person cross compiling to change
 703 # this behavior if desired
 704 AC_LANG_PUSH(C)
 705 AC_CACHE_CHECK([for posix getpwnam_r],
 706                 ac_cv_func_posix_getpwnam_r,
 707                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 708 [[
 709 #include <errno.h>
 710 #include <pwd.h>
 711 ]],
 712 [[
 713     char buffer[10000];
 714     struct passwd pwd, *pwptr = &pwd;
 715     int error;
 716     errno = 0;
 717     error = getpwnam_r ("", &pwd, buffer,
 718                         sizeof (buffer), &pwptr);
 719    return (error < 0 && errno == ENOSYS)
 720            || error == ENOSYS;
 721 ]])],
 722         [ac_cv_func_posix_getpwnam_r=yes],
 723         [ac_cv_func_posix_getpwnam_r=no],
 724         [ac_cv_func_posix_getpwnam_r=yes]
 725 )])
 726 AC_LANG_POP(C)
 727
 728 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 729         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 730                 [Have POSIX function getpwnam_r])
 731 else
 732         AC_CACHE_CHECK([for nonposix getpwnam_r],
 733                 ac_cv_func_nonposix_getpwnam_r,
 734                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 735                         struct passwd pwd;
 736                         getpwnam_r ("", &pwd, buffer,
 737                                         sizeof (buffer));]])],
 738                         [ac_cv_func_nonposix_getpwnam_r=yes],
 739                         [ac_cv_func_nonposix_getpwnam_r=no])])
 740                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 741                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 742                         [Have non-POSIX function getpwnam_r])
 743         fi
 744 fi
 745
 746 dnl check for socklen_t
 747 AC_MSG_CHECKING(whether socklen_t is defined)
 748 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 749 #include <sys/types.h>
 750 #include <sys/socket.h>
 751 #include <netdb.h>
 752 ]], [[
 753 socklen_t foo;
 754 foo = 1;
 755 ]])],
 756 [dbus_have_socklen_t=yes],
 757 [dbus_have_socklen_t=no])
 758 AC_MSG_RESULT($dbus_have_socklen_t)
 759
 760 if test "x$dbus_have_socklen_t" = "xyes"; then
 761     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 762 fi
 763
 764 dnl check for writev header and writev function so we're
 765 dnl good to go if HAVE_WRITEV gets defined.
 766 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 767
 768 dnl needed on darwin for NAME_MAX
 769 AC_CHECK_HEADERS(sys/syslimits.h)
 770
 771 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 772 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 773 #include <sys/socket.h> ]])
 774
 775 dnl check for flavours of varargs macros (test from GLib)
 776 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 777 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 778 int a(int p1, int p2, int p3);
 779 #define call_a(...) a(1,__VA_ARGS__)
 780 call_a(2,3);
 781 ]])],
 782 [dbus_have_iso_c_varargs=yes],
 783 [dbus_have_iso_c_varargs=no])
 784 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 785
 786 AC_MSG_CHECKING(for GNUC varargs macros)
 787 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 788 int a(int p1, int p2, int p3);
 789 #define call_a(params...) a(1,params)
 790 call_a(2,3);
 791 ]])],
 792 [dbus_have_gnuc_varargs=yes],
 793 [dbus_have_gnuc_varargs=no])
 794 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 795
 796 dnl Output varargs tests
 797 if test x$dbus_have_iso_c_varargs = xyes; then
 798     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 799 fi
 800 if test x$dbus_have_gnuc_varargs = xyes; then
 801     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 802 fi
 803
 804 dnl Check for various credentials.
 805 AC_MSG_CHECKING(for struct cmsgcred)
 806 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 807 #include <sys/types.h>
 808 #include <sys/socket.h>
 809 ]], [[
 810 struct cmsgcred cred;
 811
 812 cred.cmcred_pid = 0;
 813 ]])],
 814 [dbus_have_struct_cmsgcred=yes],
 815 [dbus_have_struct_cmsgcred=no])
 816 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 817
 818 if test x$dbus_have_struct_cmsgcred = xyes; then
 819     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 820 fi
 821
 822 AC_CHECK_FUNCS(getpeerucred getpeereid)
 823
 824 AC_CHECK_FUNCS(pipe2 accept4)
 825
 826 #### Abstract sockets
 827
 828 if test x$enable_abstract_sockets = xauto; then
 829 AC_LANG_PUSH(C)
 830 warn_on_xcompile=no
 831 AC_CACHE_CHECK([abstract socket namespace],
 832                 ac_cv_have_abstract_sockets,
 833                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 834 [[
 835 #include <sys/types.h>
 836 #include <stdlib.h>
 837 #include <string.h>
 838 #include <stdio.h>
 839 #include <sys/socket.h>
 840 #include <sys/un.h>
 841 #include <errno.h>
 842 ]],
 843 [[
 844   size_t slen;
 845   int listen_fd;
 846   struct sockaddr_un addr;
 847
 848   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 849
 850   if (listen_fd < 0)
 851     {
 852       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 853       exit (1);
 854     }
 855
 856   memset (&addr, '\0', sizeof (addr));
 857   addr.sun_family = AF_UNIX;
 858   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 859   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 860    * beginning.
 861    */
 862   slen = SUN_LEN(&addr);
 863   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 864
 865   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 866     {
 867        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 868                 strerror (errno));
 869        exit (1);
 870     }
 871   else
 872     exit (0);
 873 ]])],
 874               [ac_cv_have_abstract_sockets=yes],
 875               [ac_cv_have_abstract_sockets=no],
 876               [
 877                 ac_cv_have_abstract_sockets=no
 878                 warn_on_xcompile=yes
 879               ]
 880 )])
 881 if test x$warn_on_xcompile = xyes ; then
 882   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 883 fi
 884 AC_LANG_POP(C)
 885 fi
 886
 887 if test x$enable_abstract_sockets = xyes; then
 888     if test x$ac_cv_have_abstract_sockets = xno; then
 889         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 890     fi
 891 fi
 892
 893 if test x$enable_abstract_sockets = xno; then
 894    ac_cv_have_abstract_sockets=no;
 895 fi
 896
 897 if test x$ac_cv_have_abstract_sockets = xyes ; then
 898    DBUS_PATH_OR_ABSTRACT=abstract
 899    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 900 else
 901    DBUS_PATH_OR_ABSTRACT=path
 902 fi
 903
 904 # this is used in addresses to prefer abstract, e.g.
 905 # unix:path=/foo or unix:abstract=/foo
 906 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 907
 908 PKG_PROG_PKG_CONFIG
 909
 910 #### Sort out XML library
 911
 912 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 913              [ AC_CHECK_HEADERS(expat.h, [],
 914                                 [AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])]) ],
 915              [ AC_MSG_ERROR([Explicitly requested expat but expat not found]) ])
 916
 917 XML_LIBS=-lexpat
 918 XML_CFLAGS=
 919 AC_SUBST([XML_CFLAGS])
 920 AC_SUBST([XML_LIBS])
 921
 922 # Thread lib detection
 923 AC_ARG_VAR([THREAD_LIBS])
 924 save_libs="$LIBS"
 925 LIBS="$LIBS $THREAD_LIBS"
 926
 927 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 928
 929 # Don't do these automatic checks if the user set THREAD_LIBS on the
 930 # configure command-line. If they did, we assume they're right.
 931 #
 932 # We also don't do these checks on Windows, because you don't need magical
 933 # linker flags to have threading support there.
 934 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 935   [
 936     # Mandatory pthread functions. In principle, some of these could be made
 937     # optional if there are platforms that don't have them.
 938     #
 939     # Currently, we only look in -lpthread.
 940     # In principle we might need to look in -lpthreads, -lthreads, ...
 941     # as well - please file a bug if your platform needs this.
 942     AC_SEARCH_LIBS([pthread_cond_timedwait],
 943         [pthread],
 944         [THREAD_LIBS="$LIBS"],
 945         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 946         [])
 947     AC_SEARCH_LIBS([pthread_mutexattr_init],
 948         [pthread],
 949         [THREAD_LIBS="$LIBS"],
 950         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 951         [])
 952     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 953         [pthread],
 954         [THREAD_LIBS="$LIBS"],
 955         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 956         [])
 957
 958     # Optional, for monotonic clocks. Because it's optional, this check
 959     # is non-fatal if we don't find it.
 960     AC_SEARCH_LIBS([pthread_condattr_setclock],
 961         [pthread],
 962         [THREAD_LIBS="$LIBS"])
 963
 964     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
 965       [
 966         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
 967         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 968         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 969 [[#include <time.h>
 970 #include <pthread.h>
 971 ]], [[
 972 struct timespec monotonic_timer;
 973 pthread_condattr_t attr;
 974 pthread_condattr_init (&attr);
 975 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 976 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 977 ]])],
 978             [have_clock_monotonic=true],
 979             [have_clock_monotonic=false])
 980         AS_IF([test x$have_clock_monotonic = xtrue],
 981           [
 982             AC_MSG_RESULT([found])
 983             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 984           ],
 985           [AC_MSG_RESULT([not found])])
 986       ]) dnl have pthread_condattr_setclock
 987   ]) dnl on Unix
 988
 989 LIBS="$save_libs"
 990
 991 AC_SUBST([THREAD_LIBS])
 992
 993 # SELinux detection
 994 if test x$enable_selinux = xno ; then
 995     have_selinux=no;
 996 else
 997     # See if we have SELinux library
 998     AC_CHECK_LIB(selinux, is_selinux_enabled,
 999                  have_selinux=yes, have_selinux=no)
1000
1001     # see if we have the SELinux header with the new D-Bus stuff in it
1002     if test x$have_selinux = xyes ; then
1003         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
1004         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
1005                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
1006                             #else
1007                             #error DBUS__ACQUIRE_SVC not defined
1008                             #endif]])],
1009                           [have_selinux=yes],
1010                           [have_selinux=no])
1011         AC_MSG_RESULT($have_selinux)
1012     fi
1013
1014     if test x$enable_selinux = xauto ; then
1015         if test x$have_selinux = xno ; then
1016                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1017         fi
1018     else
1019         if test x$have_selinux = xno ; then
1020                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1021         fi
1022     fi
1023 fi
1024
1025 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1026
1027 if test x$have_selinux = xyes ; then
1028     # the selinux code creates threads
1029     # which requires libpthread even on linux
1030     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1031                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1032
1033     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1034     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1035 else
1036     SELINUX_LIBS=
1037 fi
1038
1039 # inotify checks
1040 if test x$enable_inotify = xno ; then
1041     have_inotify=no;
1042 else
1043     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1044 fi
1045
1046 dnl check if inotify backend is enabled
1047 if test x$have_inotify = xyes; then
1048    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1049    AC_CHECK_FUNCS(inotify_init1)
1050 fi
1051
1052 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1053
1054 # dnotify checks
1055 if test x$enable_dnotify = xno ; then
1056     have_dnotify=no;
1057 else
1058     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
1059         have_dnotify=yes;
1060     else
1061         have_dnotify=no;
1062     fi
1063 fi
1064
1065 dnl check if dnotify backend is enabled
1066 if test x$have_dnotify = xyes; then
1067    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
1068 fi
1069
1070 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
1071
1072 # For simplicity, we require the userland API for epoll_create1 at
1073 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1074 # not to have it at runtime.
1075 AC_ARG_ENABLE([epoll],
1076               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1077               [enable_epoll=$enableval], [enable_epoll=auto])
1078 if test x$enable_epoll = xno; then
1079     have_linux_epoll=no
1080 else
1081     AC_MSG_CHECKING([for Linux epoll(4)])
1082     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1083         [
1084         #ifndef __linux__
1085         #error This is not Linux
1086         #endif
1087         #include <sys/epoll.h>
1088         ],
1089         [epoll_create1 (EPOLL_CLOEXEC);])],
1090         [have_linux_epoll=yes],
1091         [have_linux_epoll=no])
1092     AC_MSG_RESULT([$have_linux_epoll])
1093 fi
1094 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1095     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1096 fi
1097 if test x$have_linux_epoll = xyes; then
1098   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1099 fi
1100 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1101
1102 # kqueue checks
1103 if test x$enable_kqueue = xno ; then
1104     have_kqueue=no
1105 else
1106     have_kqueue=yes
1107     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1108     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1109
1110     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1111         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1112     fi
1113 fi
1114
1115 dnl check if kqueue backend is enabled
1116 if test x$have_kqueue = xyes; then
1117    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1118 fi
1119
1120 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1121
1122 # launchd checks
1123 if test x$enable_launchd = xno ; then
1124     have_launchd=no
1125 else
1126     have_launchd=yes
1127     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1128     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1129     if test "x$LAUNCHCTL" = "x"; then
1130         have_launchd=no
1131     fi
1132
1133     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1134         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1135     fi
1136 fi
1137
1138 dnl check if launchd is enabled
1139 if test x$have_launchd = xyes; then
1140     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1141 fi
1142
1143 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1144
1145 #### Directory to place launchd agent file
1146 if test "x$with_launchd_agent_dir" = "x"; then
1147    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1148 else
1149    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1150 fi
1151
1152 AC_SUBST(LAUNCHD_AGENT_DIR)
1153
1154 dnl console owner file
1155 if test x$enable_console_owner_file = xno ; then
1156     have_console_owner_file=no;
1157 else
1158     case $host_os in
1159     solaris*)
1160         have_console_owner_file=yes;
1161         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1162         ;;
1163     *)
1164         have_console_owner_file=no;;
1165     esac
1166 fi
1167
1168 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1169
1170 dnl systemd detection
1171 if test x$enable_systemd = xno ; then
1172     have_systemd=no;
1173 else
1174     PKG_CHECK_MODULES(SYSTEMD,
1175         [libsystemd-login >= 32, libsystemd-daemon >= 32],
1176         have_systemd=yes,
1177         have_systemd=no)
1178 fi
1179
1180 if test x$have_systemd = xyes; then
1181     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1182 fi
1183
1184 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1185     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1186 fi
1187
1188 # libaudit detection
1189 if test x$enable_libaudit = xno ; then
1190     have_libaudit=no;
1191 else
1192     # See if we have audit daemon & capabilities library
1193     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1194                  have_libaudit=yes, have_libaudit=no)
1195     if test x$have_libaudit = xyes ; then
1196         AC_CHECK_LIB(cap-ng, capng_clear,
1197                  have_libaudit=yes, have_libaudit=no)
1198     fi
1199 fi
1200
1201 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1202
1203 if test x$have_libaudit = xyes ; then
1204     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1205     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1206 fi
1207
1208 AC_SUBST([SELINUX_LIBS])
1209
1210 # Check for ADT API (Solaris Basic Security Mode auditing)
1211 AC_MSG_CHECKING(for ADT API)
1212 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1213 #include <bsm/adt.h>
1214 adt_user_context = ADT_USER;
1215 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1216
1217 if test ${check_adt_audit} = yes
1218 then
1219    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1220    ADT_LIBS="-lbsm"
1221    LIBS="-lbsm $LIBS"
1222    AC_MSG_RESULT(yes)
1223 else
1224    AC_MSG_RESULT(no)
1225 fi
1226 AC_SUBST([ADT_LIBS])
1227
1228 # Check for SCM_RIGHTS
1229 AC_MSG_CHECKING([for SCM_RIGHTS])
1230 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1231 #include <sys/types.h>
1232 #include <sys/socket.h>
1233 #include <sys/un.h>
1234 static int x = SCM_RIGHTS;
1235 ]], [[]])],
1236 [ AC_MSG_RESULT([supported])
1237   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1238 [ AC_MSG_RESULT([not supported]) ])
1239
1240 NETWORK_libs=
1241 if test x$dbus_win = xyes ; then
1242   if test x$dbus_wince = xyes ; then
1243     NETWORK_libs="-lws2"
1244   else
1245     NETWORK_libs="-lws2_32 -liphlpapi"
1246   fi
1247 fi
1248
1249 AC_SUBST([NETWORK_libs])
1250
1251 AC_ARG_WITH([valgrind],
1252   [AS_HELP_STRING([--with-valgrind],
1253      [Add instrumentation to help valgrind to understand our allocator])],
1254   [],
1255   [with_valgrind=no])
1256
1257 if test x$with_valgrind != xno; then
1258   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1259   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1260 fi
1261
1262 # Determine maximum number of Unix fds which may be passed
1263 AS_CASE([$host_os],
1264   [*qnx*],
1265     [DEFAULT_MESSAGE_UNIX_FDS=256],
1266   [*],
1267     [DEFAULT_MESSAGE_UNIX_FDS=1024])
1268 AC_DEFINE_UNQUOTED([DBUS_DEFAULT_MESSAGE_UNIX_FDS],
1269   [$DEFAULT_MESSAGE_UNIX_FDS],
1270   [Default for dbus_connection_get_max_message_unix_fds()])
1271 AC_SUBST([DEFAULT_MESSAGE_UNIX_FDS])
1272
1273 #### Set up final flags
1274 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1275 AC_SUBST([LIBDBUS_LIBS])
1276
1277 ### X11 detection
1278 DBUS_X_LIBS=
1279 DBUS_X_CFLAGS=
1280
1281 AC_ARG_ENABLE([x11-autolaunch],
1282   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1283   [], [enable_x11_autolaunch=auto])
1284
1285 if test "x$dbus_win" = xyes; then
1286     if test "x$enable_x11_autolaunch" = xyes; then
1287         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1288     fi
1289
1290     enable_x11_autolaunch=no
1291     have_x11=no
1292 else
1293     AC_PATH_XTRA
1294
1295     if test "x$no_x" = xyes; then
1296         have_x11=no
1297     else
1298         have_x11=yes
1299         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1300         DBUS_X_CFLAGS="$X_CFLAGS"
1301     fi
1302 fi
1303
1304 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1305     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1306 else
1307     # move from "auto" to "yes" or "no" if necessary
1308     if test "x$enable_x11_autolaunch" != xno; then
1309         enable_x11_autolaunch="$have_x11"
1310     fi
1311 fi
1312
1313 if test "x$have_x11" = xyes ; then
1314    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1315 fi
1316
1317 if test "x$enable_x11_autolaunch" = xyes ; then
1318    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1319 fi
1320
1321 AC_SUBST([DBUS_X_CFLAGS])
1322 AC_SUBST([DBUS_X_LIBS])
1323
1324 #### gcc warning flags
1325
1326 cc_supports_flag() {
1327   AC_MSG_CHECKING(whether $CC supports "$*")
1328   save_CFLAGS="$CFLAGS"
1329   CFLAGS="$*"
1330   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1331   CFLAGS="$save_CFLAGS"
1332   AC_MSG_RESULT([$rc])
1333   test "x$rc" = xyes
1334 }
1335
1336 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1337   dnl Use -Werror by default if:
1338   dnl - we're not on Windows (too many warnings), and
1339   dnl - we're in developer mode (a D-Bus developer, not a distro or end-user)
1340   dnl Override with --enable-Werror or --disable-Werror
1341   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$enable_developer = xyes],
1342
1343   dnl Enable these warnings if possible:
1344   [all \
1345    extra \
1346    char-subscripts \
1347    missing-declarations \
1348    missing-prototypes \
1349    nested-externs \
1350    pointer-arith \
1351    cast-align \
1352    no-address \
1353    float-equal \
1354    declaration-after-statement \
1355   ],
1356
1357   dnl Disable these warnings if possible, make them non-fatal if possible,
1358   dnl and don't enable -Werror unless we succeeded.
1359   dnl
1360   dnl Intentional:
1361   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1362   dnl   checking or not asserting
1363   dnl - missing field initializers being 0 is a C feature, not a bug
1364   dnl - unused-parameter is to make writing callbacks less annoying
1365   dnl
1366   dnl To be fixed one day:
1367   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1368   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1369   dnl   is better than nothing
1370   [$DISABLE_UNUSED_WARNINGS \
1371    missing-field-initializers \
1372    unused-parameter \
1373    sign-compare \
1374    pointer-sign \
1375    type-limits \
1376   ])
1377
1378 if test "x$GCC" = "xyes"; then
1379   # We're treating -fno-common like a warning: it makes the linker more
1380   # strict, because on some systems the linker is *always* this strict
1381   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1382
1383   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1384   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1385
1386   if test "x$enable_ansi" = "xyes"; then
1387     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1388       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1389   fi
1390 fi
1391
1392 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1393 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1394 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1395 dnl is the next best thing
1396 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1397
1398 case $host_os in
1399     solaris*)
1400         # Solaris' C library apparently needs these runes to be threadsafe...
1401         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1402         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1403         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1404         # ... and this opt-in to get file descriptor passing support
1405         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1406         ;;
1407 esac
1408
1409 ### Doxygen Documentation
1410
1411 AC_PATH_PROG(DOXYGEN, doxygen, no)
1412
1413 AC_MSG_CHECKING([whether to build Doxygen documentation])
1414
1415 if test x$DOXYGEN = xno ; then
1416     have_doxygen=no
1417 else
1418     have_doxygen=yes
1419 fi
1420
1421 if test x$enable_doxygen_docs = xauto ; then
1422     if test x$have_doxygen = xno ; then
1423         enable_doxygen_docs=no
1424     else
1425         enable_doxygen_docs=yes
1426     fi
1427 fi
1428
1429 if test x$enable_doxygen_docs = xyes; then
1430     if test x$have_doxygen = xno; then
1431         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1432     fi
1433 fi
1434
1435 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1436 AC_MSG_RESULT($enable_doxygen_docs)
1437
1438 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1439 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1440
1441 ### XML Documentation
1442
1443 AC_PATH_PROG(XMLTO, xmlto, no)
1444
1445 AC_MSG_CHECKING([whether to build XML documentation])
1446
1447 if test x$XMLTO = xno ; then
1448     have_xmlto=no
1449 else
1450     have_xmlto=yes
1451 fi
1452
1453 if test x$enable_xml_docs = xauto ; then
1454     if test x$have_xmlto = xno ; then
1455         enable_xml_docs=no
1456     else
1457         enable_xml_docs=yes
1458     fi
1459 fi
1460
1461 if test x$enable_xml_docs = xyes; then
1462     if test x$have_xmlto = xno; then
1463         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1464     fi
1465 fi
1466
1467 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1468 AC_MSG_RESULT($enable_xml_docs)
1469
1470 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1471     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes])
1472
1473 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1474
1475 #### find the actual value for $prefix that we'll end up with
1476 ##   (I know this is broken and should be done in the Makefile, but
1477 ##    that's a major pain and almost nobody actually seems to care)
1478 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1479 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1480 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1481 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1482 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1483 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1484 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1485
1486 #### Check our operating system
1487 operating_system=unknown
1488 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1489    operating_system=redhat
1490 fi
1491
1492 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1493    operating_system=slackware
1494 fi
1495
1496 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1497    operating_system=cygwin
1498 fi
1499
1500 #### Sort out init scripts
1501
1502 if test x$with_init_scripts = x; then
1503     case x$operating_system in
1504         xredhat)        with_init_scripts=redhat ;;
1505         xslackware)     with_init_scripts=slackware ;;
1506         xcygwin)        with_init_scripts=cygwin ;;
1507         *)                      with_init_scripts=none ;;
1508     esac
1509 fi
1510
1511 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1512 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1513 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1514
1515 ##### systemd unit files
1516 AC_ARG_WITH([systemdsystemunitdir],
1517 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1518     [],
1519     [
1520     PKG_CHECK_EXISTS([systemd],
1521       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1522       [with_systemdsystemunitdir=no])
1523     ])
1524 if test "x$with_systemdsystemunitdir" != xno; then
1525    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1526 fi
1527 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1528
1529 ##### Set up location for system bus socket
1530 if ! test -z "$with_system_socket"; then
1531    DBUS_SYSTEM_SOCKET=$with_system_socket
1532 else
1533    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1534 fi
1535
1536 AC_SUBST(DBUS_SYSTEM_SOCKET)
1537 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1538
1539 ## System bus only listens on local domain sockets, and never
1540 ## on an abstract socket (so only root can create the socket).
1541 ##
1542 ## This won't work on Windows. It's not meant to - the system bus is
1543 ## meaningless on Windows anyway.
1544 ##
1545 ## This has to be suitable for hard-coding in client libraries as well as
1546 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1547 ## and also to connect to. If this ever changes, it'll need to be split into
1548 ## two variables, one for the listening address and one for the connecting
1549 ## address.
1550 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1551 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1552 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1553
1554 #### Set up the pid file
1555 if ! test -z "$with_system_pid_file"; then
1556    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1557 elif test x$with_init_scripts = xredhat ; then
1558    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1559 else
1560    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1561 fi
1562
1563 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1564
1565 #### Directory to check for console ownership
1566 if ! test -z "$with_console_auth_dir"; then
1567    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1568 else
1569    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1570 fi
1571
1572 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1573 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1574
1575 #### File to check for console ownership
1576 if test x$have_console_owner_file = xyes; then
1577    if ! test -z "$with_console_owner_file"; then
1578       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1579    else
1580       DBUS_CONSOLE_OWNER_FILE=/dev/console
1581    fi
1582 else
1583   DBUS_CONSOLE_OWNER_FILE=
1584 fi
1585
1586 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1587 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1588
1589 #### User to start the system bus as
1590 if test -z "$with_dbus_user" ; then
1591     DBUS_USER=messagebus
1592 else
1593     DBUS_USER=$with_dbus_user
1594 fi
1595 AC_SUBST(DBUS_USER)
1596 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1597
1598 #### Prefix to install into
1599 DBUS_PREFIX=$EXPANDED_PREFIX
1600 AC_SUBST(DBUS_PREFIX)
1601 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1602
1603 #### Direcotry to install data files into
1604 DBUS_DATADIR=$EXPANDED_DATADIR
1605 AC_SUBST(DBUS_DATADIR)
1606 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1607
1608 #### Directory to install dbus-daemon
1609 if test -z "$with_dbus_daemondir" ; then
1610     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1611 else
1612     DBUS_DAEMONDIR=$with_dbus_daemondir
1613 fi
1614 AC_SUBST(DBUS_DAEMONDIR)
1615 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1616
1617 #### Directory to install the other binaries
1618 DBUS_BINDIR="$EXPANDED_BINDIR"
1619 AC_SUBST(DBUS_BINDIR)
1620 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1621
1622 #### Directory to install the libexec binaries
1623 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1624 AC_SUBST(DBUS_LIBEXECDIR)
1625 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1626
1627 #### Tell tests where to find certain stuff in builddir
1628
1629 DBUS_PWD=`pwd`
1630 # Useful in a cross-compilation environment, where the tests are run on the host system.
1631 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1632                            DBUS_PWD=$withval)
1633
1634 DBUS_TEST_EXEC="$DBUS_PWD/test"
1635 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1636
1637 AC_SUBST([DBUS_TEST_DATA])
1638 AC_SUBST([DBUS_TEST_EXEC])
1639
1640 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1641                    [Full path to the daemon in the builddir])
1642 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1643                    [Extension for executables, typically empty or .exe])
1644
1645 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, ["$DBUS_PWD/bus/dbus-daemon$EXEEXT"],
1646                    [Full path to the daemon in the builddir])
1647 AC_SUBST(TEST_BUS_BINARY)
1648
1649 ## Export the non-setuid external helper
1650 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1651 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1652 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1653                    [Full path to the launch helper test program in the builddir])
1654
1655 #### Find socket directories
1656 if ! test -z "$TMPDIR" ; then
1657    DEFAULT_SOCKET_DIR=$TMPDIR
1658 elif ! test -z "$TEMP" ; then
1659    DEFAULT_SOCKET_DIR=$TEMP
1660 elif ! test -z "$TMP" ; then
1661    DEFAULT_SOCKET_DIR=$TMP
1662 else
1663    DEFAULT_SOCKET_DIR=/tmp
1664 fi
1665
1666 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1667
1668 if ! test -z "$with_test_socket_dir" ; then
1669    TEST_SOCKET_DIR="$with_test_socket_dir"
1670 else
1671    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1672 fi
1673 AC_SUBST(TEST_SOCKET_DIR)
1674 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1675
1676 if test "x$dbus_unix" = xyes; then
1677   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1678 else
1679   TEST_LISTEN="tcp:host=localhost"
1680 fi
1681 AC_SUBST([TEST_LISTEN])
1682 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1683   [Listening address for regression tests])
1684
1685 if ! test -z "$with_session_socket_dir" ; then
1686    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1687 else
1688    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1689 fi
1690 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1691 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1692
1693 # This must be a listening address. It doesn't necessarily need to be an
1694 # address you can connect to - it can be something vague like
1695 # "nonce-tcp:".
1696 #
1697 # The default varies by platform.
1698 AC_ARG_WITH([dbus_session_bus_listen_address],
1699             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1700                            [default address for a session bus to listen on (see configure.ac)]),
1701             [with_dbus_session_bus_listen_address=$withval],
1702             [with_dbus_session_bus_listen_address=])
1703
1704 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1705         # the user specified something, trust them
1706         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1707 elif test x$dbus_win = xyes; then
1708         # On Windows, you can (and should) listen on autolaunch addresses,
1709         # because autolaunching is different.
1710         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1711         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1712 elif test x$have_launchd = xyes; then
1713         # Mac OS X default is to use launchd
1714         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1715 else
1716         # The default on all other Unix platforms (notably Linux)
1717         # is to create a randomly named socket in /tmp or similar
1718         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1719 fi
1720 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1721
1722 # This must be an address you can connect to. It doesn't necessarily
1723 # need to be an address you can listen on - it can be "autolaunch:",
1724 # even on Unix.
1725 #
1726 # The default varies by platform.
1727 AC_ARG_WITH([dbus_session_bus_connect_address],
1728             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1729                            [fallback address for a session bus client to connect to (see configure.ac)]),
1730             [with_dbus_session_bus_connect_address=$withval],
1731             [with_dbus_session_bus_connect_address=])
1732
1733 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1734         # the user specified something, trust them
1735         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1736 elif test x$dbus_win = xyes; then
1737         # Windows autolaunching is a bit different; leaving it in its own
1738         # branch of the conditional because the default might conceivably
1739         # change (see #38201)
1740         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1741 else
1742         # The default on all other Unix platforms (notably Linux)
1743         # is to use auto-launching - this works a bit differently on Mac OS X
1744         # but comes out basically the same in the end
1745         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1746 fi
1747 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1748 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1749   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1750   [Fallback address for session bus clients])
1751
1752 # darwin needs this to initialize the environment
1753 AC_CHECK_HEADERS(crt_externs.h)
1754 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1755 AH_VERBATIM(_DARWIN_ENVIRON,
1756 [
1757 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1758 # include <sys/time.h>
1759 # include <crt_externs.h>
1760 # define environ (*_NSGetEnviron())
1761 #endif
1762 ])
1763
1764 AC_ARG_ENABLE([stats],
1765   [AS_HELP_STRING([--enable-stats],
1766     [enable bus daemon usage statistics])],
1767   [], [enable_stats=no])
1768 if test "x$enable_stats" = xyes; then
1769   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1770     [Define to enable bus daemon usage statistics])
1771 fi
1772
1773 AC_CONFIG_FILES([
1774 Doxyfile
1775 dbus/versioninfo.rc
1776 dbus/dbus-arch-deps.h
1777 bus/system.conf
1778 bus/session.conf
1779 bus/messagebus
1780 bus/messagebus-config
1781 bus/org.freedesktop.dbus-session.plist
1782 bus/rc.messagebus
1783 bus/dbus.service
1784 bus/dbus.socket
1785 Makefile
1786 dbus/Makefile
1787 bus/Makefile
1788 tools/Makefile
1789 test/Makefile
1790 test/name-test/Makefile
1791 doc/Makefile
1792 doc/dbus-cleanup-sockets.1.xml
1793 doc/dbus-daemon.1.xml
1794 doc/dbus-launch.1.xml
1795 doc/dbus-monitor.1.xml
1796 doc/dbus-run-session.1.xml
1797 doc/dbus-send.1.xml
1798 doc/dbus-uuidgen.1.xml
1799 dbus-1.pc
1800 dbus-1-uninstalled.pc
1801 test/data/valid-config-files/debug-allow-all.conf
1802 test/data/valid-config-files/debug-allow-all-sha1.conf
1803 test/data/valid-config-files-system/debug-allow-all-pass.conf
1804 test/data/valid-config-files-system/debug-allow-all-fail.conf
1805 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1806 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1807 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1808 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1809 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1810 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1811 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1812 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1813 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1814 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1815 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1816 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1817 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1818 ])
1819 AC_OUTPUT
1820
1821 dnl ==========================================================================
1822 echo "
1823                     D-Bus $VERSION
1824                   ==============
1825
1826         prefix:                   ${EXPANDED_PREFIX}
1827         exec_prefix:              ${exec_prefix}
1828         libdir:                   ${EXPANDED_LIBDIR}
1829         libexecdir:               ${EXPANDED_LIBEXECDIR}
1830         bindir:                   ${EXPANDED_BINDIR}
1831         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1832         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1833         datadir:                  ${EXPANDED_DATADIR}
1834         source code location:     ${srcdir}
1835         compiler:                 ${CC}
1836         cflags:                   ${CFLAGS}
1837         cppflags:                 ${CPPFLAGS}
1838         cxxflags:                 ${CXXFLAGS}
1839         64-bit int:               ${DBUS_INT64_TYPE}
1840         32-bit int:               ${DBUS_INT32_TYPE}
1841         16-bit int:               ${DBUS_INT16_TYPE}
1842         Doxygen:                  ${DOXYGEN:-not found}
1843         xmlto:                    ${XMLTO:-not found}"
1844
1845 echo "
1846         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1847         gcc coverage profiling:   ${enable_compiler_coverage}
1848         Building embedded tests:  ${enable_embedded_tests}
1849         Building modular tests:   ${enable_modular_tests}
1850             - with GLib:          ${with_glib}
1851         Building verbose mode:    ${enable_verbose_mode}
1852         Building assertions:      ${enable_asserts}
1853         Building checks:          ${enable_checks}
1854         Building bus stats API:   ${enable_stats}
1855         Building SELinux support: ${have_selinux}
1856         Building inotify support: ${have_inotify}
1857         Building dnotify support: ${have_dnotify}
1858         Building kqueue support:  ${have_kqueue}
1859         Building systemd support: ${have_systemd}
1860         Building X11 code:        ${have_x11}
1861         Building Doxygen docs:    ${enable_doxygen_docs}
1862         Building XML docs:        ${enable_xml_docs}
1863         Building cache support:   ${enable_userdb_cache}
1864         Building launchd support: ${have_launchd}
1865         Init scripts style:       ${with_init_scripts}
1866         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1867         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1868         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1869         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1870         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1871         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1872         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1873         Console owner file:       ${have_console_owner_file}
1874         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1875         System bus user:          ${DBUS_USER}
1876         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1877         'make check' socket dir:  ${TEST_SOCKET_DIR}
1878 "
1879 if test x$have_launchd = xyes; then
1880         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1881 fi
1882 echo
1883
1884 if test x$enable_embedded_tests = xyes; then
1885         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1886 fi
1887 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1888         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1889 fi
1890 if test x$enable_compiler_coverage = xyes; then
1891         echo "NOTE: building with coverage profiling is definitely for developers only."
1892 fi
1893 if test x$enable_verbose_mode = xyes; then
1894         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1895 fi
1896 if test x$enable_asserts = xyes; then
1897         echo "NOTE: building with assertions increases library size and decreases performance."
1898 fi
1899 if test x$enable_checks = xno; then
1900         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1901 fi
1902
1903 if test "x$DBUS_HAVE_INT64" = x0; then
1904   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1905
1906   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1907   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1908   used if your compiler lacks support for 64-bit integers. Please report a bug
1909   with details of your platform and compiler.
1910
1911   This option is likely to be removed in future, unless the D-Bus developers
1912   receive reports that it is still needed.
1913   ])
1914 fi