configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/librygel-core/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1 tar-ustar no-dist-gzip dist-xz -Wno-portability])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 dnl Required versions of library packages
  31 GLIB_REQUIRED=2.31.13
  32 VALA_REQUIRED=0.16.1
  33 VALADOC_REQUIRED=0.2
  34 GSSDP_REQUIRED=0.13.0
  35 GUPNP_REQUIRED=0.19.0
  36 GUPNP_AV_REQUIRED=0.11.0
  37 GUPNP_DLNA_REQUIRED=0.5.0
  38 GSTREAMER_REQUIRED=0.10.36
  39 GSTPBU_REQUIRED=0.10.35
  40 GIO_REQUIRED=2.26
  41 GEE_REQUIRED=0.5.2
  42 UUID_REQUIRED=1.41.3
  43 LIBSOUP_REQUIRED=2.34.0
  44 GTK_REQUIRED=2.90.3
  45
  46 dnl Additional requirements for media-export plugin
  47 GSTREAMER_TAG_REQUIRED=0.10.28
  48 GSTREAMER_APP_REQUIRED=0.10.28
  49 LIBSQLITE3_REQUIRED=3.5
  50
  51 dnl Additional requirements for tracker plugin
  52 TRACKER_SPARQL_REQUIRED_MIN=0.14.0
  53
  54 PKG_CHECK_MODULES(LIBGLIB, glib-2.0 >= $GLIB_REQUIRED)
  55 VALAFLAGS="--target-glib=2.32 $VALAFLAGS"
  56
  57 PKG_CHECK_MODULES(LIBGSSDP, gssdp-1.0 >= $GSSDP_REQUIRED)
  58 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED)
  59 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED)
  60 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  61 PKG_CHECK_MODULES(GEE, gee-1.0 >= $GEE_REQUIRED)
  62 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  63 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED)
  64
  65 dnl Media engine to use
  66 BUILT_ENGINES="librygel-media-engine-simple"
  67
  68 AC_ARG_WITH([media_engine],
  69             AS_HELP_STRING(
  70                 [--with-media-engine=@<:@gstreamer|none@:>@],
  71                 [Media Engine to use]),
  72             [with_media_engine="$withval"],
  73             [with_media_engine="gstreamer"])
  74
  75 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  76       [
  77         PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.0 >= $GUPNP_DLNA_REQUIRED)
  78         PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED)
  79         PKG_CHECK_MODULES(GSTREAMER_BASE, gstreamer-base-0.10 >= $GSTREAMER_REQUIRED)
  80         PKG_CHECK_MODULES(GST_PBU, gstreamer-pbutils-0.10 >= $GSTPBU_REQUIRED)
  81         enable_gstreamer="yes"
  82         BUILT_ENGINES="$BUILT_ENGINES;librygel-media-engine-gst"
  83       ],
  84       [enable_gstreamer="no"])
  85 AM_CONDITIONAL([HAVE_GSTREAMER],[test "x$enable_gstreamer" = "xyes"])
  86 AC_SUBST([BUILT_ENGINES])
  87
  88 dnl Add plugins
  89 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
  90 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
  91 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
  92 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
  93
  94 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  95       [
  96         RYGEL_ADD_PLUGIN([test],[Test],[no])
  97         RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
  98         RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
  99         RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
 100         RYGEL_ADD_STAMP([src/media-engines/gstreamer/librygel_media_engine_gst_la_vala.stamp])
 101         RYGEL_ADD_STAMP([src/librygel-renderer-gst/librygel_renderer_gst_2_0_la_vala.stamp])
 102       ],
 103       [
 104         RYGEL_DISABLE_PLUGIN([test])
 105         RYGEL_DISABLE_PLUGIN([playbin])
 106         RYGEL_DISABLE_PLUGIN([media-export])
 107         RYGEL_DISABLE_PLUGIN([gst-launch])
 108       ])
 109
 110 dnl Example plugins:
 111 AC_ARG_ENABLE([example-plugins],
 112               AS_HELP_STRING([--enable-example-plugins],[enable example plugins]),,
 113               enable_example_plugins=no)
 114 AM_CONDITIONAL([BUILD_EXAMPLE_PLUGINS], [test "x$[]enable_example_plugins" = "xyes"])
 115
 116 dnl Explicitly add stamp files for targets that are not plugins
 117 RYGEL_ADD_STAMP([src/librygel-core/librygel_core_2_0_la_vala.stamp])
 118 RYGEL_ADD_STAMP([src/librygel-server/librygel_server_2_0_la_vala.stamp])
 119 RYGEL_ADD_STAMP([src/librygel-renderer/librygel_renderer_2_0_la_vala.stamp])
 120 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
 121 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
 122 RYGEL_ADD_STAMP([src/media-engines/simple/librygel_media_engine_simple_la_vala.stamp])
 123
 124 RYGEL_CHECK_VALA([$VALA_REQUIRED],
 125                  [gupnp-1.0
 126                   gupnp-av-1.0
 127                   gio-2.0
 128                   gee-1.0
 129                   posix])
 130
 131 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 132       [
 133         RYGEL_CHECK_PACKAGES([gupnp-dlna-1.0 gstreamer-0.10 gstreamer-pbutils-0.10])
 134       ])
 135
 136 dnl Debugging
 137 AC_ARG_ENABLE(debug,
 138         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 139         enable_debug=no)
 140 if test "x$enable_debug" = "xyes"; then
 141         CFLAGS="$CFLAGS -O0 -g"
 142         RYGEL_DEBUG_VALAFLAGS="-g"
 143 fi
 144
 145 AC_SUBST(RYGEL_DEBUG_VALAFLAGS)
 146
 147 dnl Strict compiler
 148 AC_ARG_ENABLE(strict-cc,
 149         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 150         enable_strict_cc=no)
 151 if test "x$enable_strict_cc" = "xyes"; then
 152         CFLAGS="$CFLAGS -Wall -Werror"
 153 else
 154         CFLAGS="$CFLAGS -w"
 155 fi
 156
 157 dnl Run uninstalled
 158 AC_ARG_ENABLE(uninstalled,
 159     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 160         enable_uninstalled=no)
 161 if test "x$enable_uninstalled" = "xyes"; then
 162         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 163 fi
 164 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 165
 166 dnl Check wether user wants to build UIs
 167 AC_ARG_WITH( ui,
 168   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 169   try_ui=$withval, try_ui=yes )
 170
 171 HAVE_GTK=no
 172 if test x$try_ui = xyes ; then
 173     dnl check for gtk
 174     PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQUIRED,
 175       [
 176         RYGEL_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 177       ],
 178       [
 179         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 180         AC_MSG_WARN([UI applications will not be built.])
 181       ])
 182 else
 183     AC_MSG_NOTICE([UI applications disabled.])
 184 fi
 185
 186 AM_CONDITIONAL(BUILD_UI, test "x$HAVE_GTK" = "xyes")
 187
 188 dnl Tests
 189 AC_ARG_ENABLE([tests],
 190               AS_HELP_STRING([--enable-tests],[always build tests]),,
 191               enable_tests=no)
 192 AM_CONDITIONAL([ALWAYS_TEST], [test "x$enable_tests" = "xyes"])
 193
 194 dnl Generate coverage data
 195 AC_ARG_ENABLE([coverage],
 196   AS_HELP_STRING([--enable-coverage],
 197                  [Generate converage reports for unit tests]),
 198   [],
 199   [enable_coverage=no])
 200 AM_CONDITIONAL([ENABLE_COVERAGE],[test "x$enable_coverage" != "xno"])
 201 AS_IF([test "x$enable_coverage" != "xno"],
 202   [
 203     AC_PATH_PROG([LCOV], [lcov])
 204     AC_PATH_PROG([GENHTML], [genhtml])
 205     AC_SUBST([COVERAGE_LIBS],["-lgcov"])
 206     AC_SUBST([COVERAGE_CFLAGS],["-fprofile-arcs -ftest-coverage"])
 207     AC_SUBST(COVERAGE_VALAFLAGS,["-g"])
 208   ]
 209 )
 210
 211 dnl Check additional requirements for MediaExport plugins
 212 if test "x$enable_media_export_plugin" = "xyes";
 213 then
 214     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 215     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-0.10 >= $GSTREAMER_TAG_REQUIRED);
 216     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-0.10 >= $GSTREAMER_APP_REQUIRED);
 217     RYGEL_CHECK_PACKAGES([sqlite3 gstreamer-tag-0.10 gstreamer-app-0.10])
 218     AC_CHECK_HEADER([unistr.h],
 219                     AC_CHECK_LIB([unistring],
 220                                  [u8_strcoll],
 221                                  [have_unistring=yes],[have_unistring=no]))
 222     if test "x$have_unistring" = "xyes"; then
 223         AC_DEFINE([HAVE_UNISTRING],[1],[Use libunistring for collation])
 224         COLLATION_CFLAGS=
 225         COLLATION_LIBS=-lunistring
 226         AC_SUBST([COLLATION_CFLAGS])
 227         AC_SUBST([COLLATION_LIBS])
 228     fi
 229 fi
 230
 231 AS_IF([test "x$enable_tracker_plugin" = "xyes"],
 232   [
 233     PKG_CHECK_MODULES(TRACKER_SPARQL,
 234                       tracker-sparql-0.14 >= $TRACKER_SPARQL_REQUIRED_MIN)
 235     AS_IF([test "x$enable_vala" = "xyes"],
 236           [VALA_CHECK_PACKAGES([tracker-sparql-0.14])])
 237   ])
 238
 239 dnl Gettext
 240 GETTEXT_PACKAGE=rygel
 241 AC_SUBST(GETTEXT_PACKAGE)
 242 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 243   [Define the gettext package to be used])
 244
 245 AM_GLIB_GNU_GETTEXT
 246 IT_PROG_INTLTOOL([0.40.0])
 247
 248 dnl Shave the output
 249 AM_SILENT_RULES([yes])
 250
 251 dnl documenation
 252 AC_PATH_PROG([XSLTPROC], [xsltproc])
 253 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 254
 255 dnl Use valadoc for API documentation:
 256 dnl This is on by default when using autogen.sh
 257 dnl (so it is not on by default when building from a tarball with configure.)
 258 AC_ARG_ENABLE(valadoc,
 259   AS_HELP_STRING([--enable-valadoc[=@<:@no/auto/yes@:>@]], [Enable valadoc support]),,
 260     [enable_valadoc=no])
 261
 262 found_valadoc=no
 263 AS_IF([test "x$enable_valadoc" != "xno"], [
 264     AC_PATH_PROG(VALADOC, valadoc, :)
 265     AS_IF([test -x "$VALADOC"], [
 266       found_valadoc=yes
 267       AC_SUBST(VALADOC)
 268       PKG_CHECK_MODULES([GTKDOC],[gtk-doc >= 1.0])
 269     ], [
 270       AS_IF([test "x$enable_valadoc" == "xyes"], AC_MSG_ERROR([Unable to find valadoc]))
 271     ])
 272   ])
 273
 274 AM_CONDITIONAL(ENABLE_VALADOC, test x$found_valadoc = xyes)
 275
 276 AC_CONFIG_FILES([
 277 Makefile
 278 src/Makefile
 279 src/librygel-core/Makefile
 280 src/librygel-renderer/Makefile
 281 src/librygel-renderer-gst/Makefile
 282 src/librygel-server/Makefile
 283 src/rygel/Makefile
 284 src/ui/Makefile
 285 src/media-engines/Makefile
 286 src/media-engines/gstreamer/Makefile
 287 src/media-engines/simple/Makefile
 288 src/plugins/Makefile
 289 data/Makefile
 290 data/xml/Makefile
 291 data/icons/Makefile
 292 data/icons/32x32/Makefile
 293 data/icons/48x48/Makefile
 294 data/icons/120x120/Makefile
 295 data/icons/128x128/Makefile
 296 data/icons/scalable/Makefile
 297 data/rygel.desktop.in
 298 data/rygel-preferences.desktop.in
 299 doc/Makefile
 300 doc/reference/Makefile
 301 doc/reference/librygel-core/Makefile
 302 doc/reference/librygel-renderer/Makefile
 303 doc/reference/librygel-server/Makefile
 304 doc/reference/librygel-renderer-gst/Makefile
 305 po/Makefile.in
 306 rygel-core-2.0.pc
 307 rygel-renderer-2.0.pc
 308 rygel-server-2.0.pc
 309 rygel-renderer-gst-2.0.pc
 310 tests/Makefile
 311 examples/Makefile
 312 examples/server-plugins/Makefile
 313 examples/server-plugins/vala/Makefile
 314 ])
 315 AC_OUTPUT
 316
 317 echo "
 318
 319                     ${PACKAGE} ${VERSION}
 320                     ============
 321
 322
 323         Prefix:                 ${prefix}
 324         Source code location:   ${srcdir}
 325         Compiler:               ${CC}
 326         CFLAGS:                 ${CFLAGS}
 327         VALAFLAGS:              ${VALAFLAGS}
 328         uninstalled:            ${enable_uninstalled}
 329         preferences ui:         ${HAVE_GTK}
 330         Media Engine:           ${with_media_engine}
 331     Plugins:
 332         examples:               ${enable_example_plugins}
 333         test:                   ${enable_test_plugin}
 334         tracker:                ${enable_tracker_plugin}
 335         mediathek:              ${enable_mediathek_plugin}
 336         media-export            ${enable_media_export_plugin}
 337         external:               ${enable_external_plugin}
 338         MPRIS2:                 ${enable_mpris_plugin}
 339         gst-launch:             ${enable_gst_launch_plugin}
 340         playbin:                ${enable_playbin_plugin}
 341 "