configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.38
  32 LIBDRM_INTEL_REQUIRED=2.4.37
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  35 DRI2PROTO_REQUIRED=2.6
  36 GLPROTO_REQUIRED=1.4.14
  37 LIBDRM_XORG_REQUIRED=2.4.24
  38 LIBKMS_XORG_REQUIRED=1.0.0
  39
  40 dnl Check for progs
  41 AC_PROG_CPP
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44 AM_PROG_CC_C_O
  45 AM_PROG_AS
  46 AC_CHECK_PROGS([MAKE], [gmake make])
  47 AC_CHECK_PROGS([PYTHON2], [python2 python])
  48 AC_PROG_SED
  49 AC_PROG_MKDIR_P
  50 AC_PATH_PROG([MKDEP], [makedepend])
  51
  52 if test "x$MKDEP" = "x"; then
  53     AC_MSG_ERROR([makedepend is required to build Mesa])
  54 fi
  55
  56 AC_PROG_YACC
  57 AC_PATH_PROG([YACC_INST], $YACC)
  58 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"; then
  59     if test -z "$YACC_INST"; then
  60         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  61     fi
  62 fi
  63 AC_PROG_LEX
  64
  65 AC_PATH_PROG([PERL], [perl])
  66
  67 AC_CHECK_PROG(INDENT, indent, indent, cat)
  68 if test "x$INDENT" != "xcat"; then
  69     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  70 fi
  71
  72 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  73 dnl configuration in that case.
  74 AC_PROG_INSTALL
  75 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  76
  77 dnl We need a POSIX shell for parts of the build. Assume we have one
  78 dnl in most cases.
  79 case "$host_os" in
  80 solaris*)
  81     # Solaris /bin/sh is too old/non-POSIX compliant
  82     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  83     SHELL="$POSIX_SHELL"
  84     ;;
  85 esac
  86
  87 dnl clang is mostly GCC-compatible, but its version is much lower,
  88 dnl so we have to check for it.
  89 AC_MSG_CHECKING([if compiling with clang])
  90
  91 AC_COMPILE_IFELSE(
  92 [AC_LANG_PROGRAM([], [[
  93 #ifndef __clang__
  94        not clang
  95 #endif
  96 ]])],
  97 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  98
  99 AC_MSG_RESULT([$acv_mesa_CLANG])
 100
 101 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 102 dnl versions are explictly not supported.
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120 fi
 121
 122
 123 MKDEP_OPTIONS=-fdepend
 124 dnl Ask gcc where it's keeping its secret headers
 125 if test "x$GCC" = xyes; then
 126     for dir in include include-fixed; do
 127         GCC_INCLUDES=`$CC -print-file-name=$dir`
 128         if test "x$GCC_INCLUDES" != x && \
 129            test "$GCC_INCLUDES" != "$dir" && \
 130            test -d "$GCC_INCLUDES"; then
 131             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 132         fi
 133     done
 134 fi
 135 AC_SUBST([MKDEP_OPTIONS])
 136
 137 dnl Make sure the pkg-config macros are defined
 138 m4_ifndef([PKG_PROG_PKG_CONFIG],
 139     [m4_fatal([Could not locate the pkg-config autoconf macros.
 140   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 141   are in a different location, try setting the environment variable
 142   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 143 PKG_PROG_PKG_CONFIG()
 144
 145 dnl LIB_DIR - library basename
 146 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 147 AC_SUBST([LIB_DIR])
 148
 149 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 150 _SAVE_LDFLAGS="$LDFLAGS"
 151 _SAVE_CPPFLAGS="$CPPFLAGS"
 152
 153 dnl Compiler macros
 154 DEFINES=""
 155 AC_SUBST([DEFINES])
 156 case "$host_os" in
 157 linux*|*-gnu*|gnu*)
 158     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 159     ;;
 160 solaris*)
 161     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 162     ;;
 163 cygwin*)
 164     DEFINES="$DEFINES -DPTHREADS"
 165     ;;
 166 esac
 167
 168 dnl Add flags for gcc and g++
 169 if test "x$GCC" = xyes; then
 170     CFLAGS="$CFLAGS -Wall -std=c99"
 171
 172     # Enable -Werror=implicit-function-declaration and
 173     # -Werror=missing-prototypes, if available, or otherwise, just
 174     # -Wmissing-prototypes.  This is particularly useful to avoid
 175     # generating a loadable driver module that has undefined symbols.
 176     save_CFLAGS="$CFLAGS"
 177     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 178     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 179     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 180     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 181                    AC_MSG_RESULT([yes]),
 182                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 183                     AC_MSG_RESULT([no])]);
 184
 185     # Enable -fvisibility=hidden if using a gcc that supports it
 186     save_CFLAGS="$CFLAGS"
 187     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 188     VISIBILITY_CFLAGS="-fvisibility=hidden"
 189     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 190     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 191                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 192
 193     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 194     CFLAGS=$save_CFLAGS
 195
 196     # Work around aliasing bugs - developers should comment this out
 197     CFLAGS="$CFLAGS -fno-strict-aliasing"
 198
 199     # gcc's builtin memcmp is slower than glibc's
 200     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 201     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 202 fi
 203 if test "x$GXX" = xyes; then
 204     CXXFLAGS="$CXXFLAGS -Wall"
 205
 206     # Enable -fvisibility=hidden if using a gcc that supports it
 207     save_CXXFLAGS="$CXXFLAGS"
 208     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 209     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 210     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 211     AC_LANG_PUSH([C++])
 212     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 213                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 214     AC_LANG_POP([C++])
 215
 216     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 217     CXXFLAGS=$save_CXXFLAGS
 218
 219     # Work around aliasing bugs - developers should comment this out
 220     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 221
 222     # gcc's builtin memcmp is slower than glibc's
 223     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 224     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 225 fi
 226
 227 dnl even if the compiler appears to support it, using visibility attributes isn't
 228 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 229 case "$host_os" in
 230 cygwin*)
 231     VISIBILITY_CFLAGS=""
 232     VISIBILITY_CXXFLAGS=""
 233     ;;
 234 esac
 235
 236 AC_SUBST([VISIBILITY_CFLAGS])
 237 AC_SUBST([VISIBILITY_CXXFLAGS])
 238
 239 dnl
 240 dnl Hacks to enable 32 or 64 bit build
 241 dnl
 242 AC_ARG_ENABLE([32-bit],
 243     [AS_HELP_STRING([--enable-32-bit],
 244         [build 32-bit libraries @<:@default=auto@:>@])],
 245     [enable_32bit="$enableval"],
 246     [enable_32bit=auto]
 247 )
 248 if test "x$enable_32bit" = xyes; then
 249     if test "x$GCC" = xyes; then
 250         CFLAGS="$CFLAGS -m32"
 251         CCASFLAGS="$CCASFLAGS -m32"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -m32"
 255     fi
 256 fi
 257 AC_ARG_ENABLE([64-bit],
 258     [AS_HELP_STRING([--enable-64-bit],
 259         [build 64-bit libraries @<:@default=auto@:>@])],
 260     [enable_64bit="$enableval"],
 261     [enable_64bit=auto]
 262 )
 263 if test "x$enable_64bit" = xyes; then
 264     if test "x$GCC" = xyes; then
 265         CFLAGS="$CFLAGS -m64"
 266     fi
 267     if test "x$GXX" = xyes; then
 268         CXXFLAGS="$CXXFLAGS -m64"
 269     fi
 270 fi
 271
 272 dnl Can't have static and shared libraries, default to static if user
 273 dnl explicitly requested. If both disabled, set to static since shared
 274 dnl was explicitly requested.
 275 case "x$enable_static$enable_shared" in
 276 xyesyes )
 277     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 278     enable_shared=no
 279     ;;
 280 xnono )
 281     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 282     enable_static=yes
 283     ;;
 284 esac
 285
 286 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 287
 288 dnl
 289 dnl mklib options
 290 dnl
 291 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 292 if test "$enable_static" = yes; then
 293     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 294 fi
 295 AC_SUBST([MKLIB_OPTIONS])
 296
 297 dnl
 298 dnl other compiler options
 299 dnl
 300 AC_ARG_ENABLE([debug],
 301     [AS_HELP_STRING([--enable-debug],
 302         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 303     [enable_debug="$enableval"],
 304     [enable_debug=no]
 305 )
 306 if test "x$enable_debug" = xyes; then
 307     DEFINES="$DEFINES -DDEBUG"
 308     if test "x$GCC" = xyes; then
 309         CFLAGS="$CFLAGS -g"
 310     fi
 311     if test "x$GXX" = xyes; then
 312         CXXFLAGS="$CXXFLAGS -g"
 313     fi
 314 fi
 315
 316 dnl
 317 dnl library names
 318 dnl
 319 LIB_PREFIX_GLOB='lib'
 320 LIB_VERSION_SEPARATOR='.'
 321 if test "$enable_static" = yes; then
 322     LIB_EXTENSION='a'
 323 else
 324     case "$host_os" in
 325     darwin* )
 326         LIB_EXTENSION='dylib' ;;
 327     cygwin* )
 328         dnl prefix can be 'cyg' or 'lib'
 329         LIB_PREFIX_GLOB='???'
 330         LIB_VERSION_SEPARATOR='-'
 331         LIB_EXTENSION='dll' ;;
 332     aix* )
 333         LIB_EXTENSION='a' ;;
 334     * )
 335         LIB_EXTENSION='so' ;;
 336     esac
 337 fi
 338 AC_ARG_WITH([gl-lib-name],
 339   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 340     [specify GL library name @<:@default=GL@:>@])],
 341   [GL_LIB=$withval],
 342   [GL_LIB=GL])
 343 AC_ARG_WITH([glu-lib-name],
 344   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 345     [specify GLU library name @<:@default=GLU@:>@])],
 346   [GLU_LIB=$withval],
 347   [GLU_LIB=GLU])
 348 AC_ARG_WITH([osmesa-lib-name],
 349   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 350     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 351   [OSMESA_LIB=$withval],
 352   [OSMESA_LIB=OSMesa])
 353 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 354 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 355 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 356
 357 dnl
 358 dnl Mangled Mesa support
 359 dnl
 360 AC_ARG_ENABLE([mangling],
 361   [AS_HELP_STRING([--enable-mangling],
 362     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 363   [enable_mangling="${enableval}"],
 364   [enable_mangling=no]
 365 )
 366 if test "x${enable_mangling}" = "xyes" ; then
 367   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 368   GL_LIB="Mangled${GL_LIB}"
 369   GLU_LIB="Mangled${GLU_LIB}"
 370   OSMESA_LIB="Mangled${OSMESA_LIB}"
 371 fi
 372 AC_SUBST([GL_LIB])
 373 AC_SUBST([GLU_LIB])
 374 AC_SUBST([OSMESA_LIB])
 375
 376 dnl
 377 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 378 dnl
 379 AC_ARG_ENABLE([texture-float],
 380     [AS_HELP_STRING([--enable-texture-float],
 381         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 382     [enable_texture_float="$enableval"],
 383     [enable_texture_float=no]
 384 )
 385 if test "x$enable_texture_float" = xyes; then
 386     AC_MSG_WARN([Floating-point textures enabled.])
 387     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 388     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 389 fi
 390
 391 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 392 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 393 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 394 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 395 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 396 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 397 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 398 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 399
 400 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408
 409 AC_SUBST([GL_LIB_NAME])
 410 AC_SUBST([GLU_LIB_NAME])
 411 AC_SUBST([OSMESA_LIB_NAME])
 412 AC_SUBST([EGL_LIB_NAME])
 413 AC_SUBST([GLESv1_CM_LIB_NAME])
 414 AC_SUBST([GLESv2_LIB_NAME])
 415 AC_SUBST([VG_LIB_NAME])
 416 AC_SUBST([GLAPI_LIB_NAME])
 417
 418 AC_SUBST([GL_LIB_GLOB])
 419 AC_SUBST([GLU_LIB_GLOB])
 420 AC_SUBST([EGL_LIB_GLOB])
 421 AC_SUBST([GLESv1_CM_LIB_GLOB])
 422 AC_SUBST([GLESv2_LIB_GLOB])
 423 AC_SUBST([VG_LIB_GLOB])
 424 AC_SUBST([GLAPI_LIB_GLOB])
 425
 426 dnl
 427 dnl Arch/platform-specific settings
 428 dnl
 429 AC_ARG_ENABLE([asm],
 430     [AS_HELP_STRING([--disable-asm],
 431         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 432     [enable_asm="$enableval"],
 433     [enable_asm=yes]
 434 )
 435 asm_arch=""
 436 MESA_ASM_FILES=""
 437 AC_MSG_CHECKING([whether to enable assembly])
 438 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 439 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 440 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 441     case "$host_cpu" in
 442     i?86 | x86_64)
 443         enable_asm=no
 444         AC_MSG_RESULT([no, cross compiling])
 445         ;;
 446     esac
 447 fi
 448 # check for supported arches
 449 if test "x$enable_asm" = xyes; then
 450     case "$host_cpu" in
 451     i?86)
 452         case "$host_os" in
 453         linux* | *freebsd* | dragonfly* | *netbsd*)
 454             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 455             ;;
 456         esac
 457         ;;
 458     x86_64)
 459         case "$host_os" in
 460         linux* | *freebsd* | dragonfly* | *netbsd*)
 461             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 462             ;;
 463         esac
 464         ;;
 465     sparc*)
 466         case "$host_os" in
 467         linux*)
 468             asm_arch=sparc
 469             ;;
 470         esac
 471         ;;
 472     esac
 473
 474     case "$asm_arch" in
 475     x86)
 476         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 477         MESA_ASM_FILES='$(X86_FILES)'
 478         AC_MSG_RESULT([yes, x86])
 479         ;;
 480     x86_64)
 481         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 482         MESA_ASM_FILES='$(X86_64_FILES)'
 483         AC_MSG_RESULT([yes, x86_64])
 484         ;;
 485     sparc)
 486         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 487         MESA_ASM_FILES='$(SPARC_FILES)'
 488         AC_MSG_RESULT([yes, sparc])
 489         ;;
 490     *)
 491         AC_MSG_RESULT([no, platform not supported])
 492         ;;
 493     esac
 494 fi
 495 AC_SUBST([MESA_ASM_FILES])
 496
 497 dnl PIC code macro
 498 MESA_PIC_FLAGS
 499
 500 dnl Check to see if dlopen is in default libraries (like Solaris, which
 501 dnl has it in libc), or if libdl is needed to get it.
 502 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 503     [AC_CHECK_LIB([dl], [dlopen],
 504        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 505 AC_SUBST([DLOPEN_LIBS])
 506
 507 dnl See if posix_memalign is available
 508 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 509
 510 dnl SELinux awareness.
 511 AC_ARG_ENABLE([selinux],
 512     [AS_HELP_STRING([--enable-selinux],
 513         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 514     [MESA_SELINUX="$enableval"],
 515     [MESA_SELINUX=no])
 516 if test "x$enable_selinux" = "xyes"; then
 517     AC_CHECK_HEADER([selinux/selinux.h],[],
 518                     [AC_MSG_ERROR([SELinux headers not found])])
 519     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 520                  [AC_MSG_ERROR([SELinux library not found])])
 521     SELINUX_LIBS="-lselinux"
 522     DEFINES="$DEFINES -DMESA_SELINUX"
 523 fi
 524
 525 dnl Options for APIs
 526 AC_ARG_ENABLE([opengl],
 527     [AS_HELP_STRING([--disable-opengl],
 528         [disable support for standard OpenGL API @<:@default=no@:>@])],
 529     [enable_opengl="$enableval"],
 530     [enable_opengl=yes])
 531 AC_ARG_ENABLE([gles1],
 532     [AS_HELP_STRING([--enable-gles1],
 533         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 534     [enable_gles1="$enableval"],
 535     [enable_gles1=no])
 536 AC_ARG_ENABLE([gles2],
 537     [AS_HELP_STRING([--enable-gles2],
 538         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 539     [enable_gles2="$enableval"],
 540     [enable_gles2=no])
 541 AC_ARG_ENABLE([openvg],
 542     [AS_HELP_STRING([--enable-openvg],
 543         [enable support for OpenVG API @<:@default=no@:>@])],
 544     [enable_openvg="$enableval"],
 545     [enable_openvg=no])
 546
 547 AC_ARG_ENABLE([dri],
 548     [AS_HELP_STRING([--enable-dri],
 549         [enable DRI modules @<:@default=enabled@:>@])],
 550     [enable_dri="$enableval"],
 551     [enable_dri=yes])
 552 AC_ARG_ENABLE([glx],
 553     [AS_HELP_STRING([--enable-glx],
 554         [enable GLX library @<:@default=enabled@:>@])],
 555     [enable_glx="$enableval"],
 556     [enable_glx=yes])
 557 AC_ARG_ENABLE([osmesa],
 558     [AS_HELP_STRING([--enable-osmesa],
 559         [enable OSMesa library @<:@default=disabled@:>@])],
 560     [enable_osmesa="$enableval"],
 561     [enable_osmesa=no])
 562 AC_ARG_ENABLE([egl],
 563     [AS_HELP_STRING([--disable-egl],
 564         [disable EGL library @<:@default=enabled@:>@])],
 565     [enable_egl="$enableval"],
 566     [enable_egl=yes])
 567
 568 AC_ARG_ENABLE([xorg],
 569     [AS_HELP_STRING([--enable-xorg],
 570         [enable support for X.Org DDX API @<:@default=no@:>@])],
 571     [enable_xorg="$enableval"],
 572     [enable_xorg=no])
 573 AC_ARG_ENABLE([xa],
 574     [AS_HELP_STRING([--enable-xa],
 575         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 576     [enable_xa="$enableval"],
 577     [enable_xa=no])
 578 AC_ARG_ENABLE([d3d1x],
 579     [AS_HELP_STRING([--enable-d3d1x],
 580         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 581     [enable_d3d1x="$enableval"],
 582     [enable_d3d1x=no])
 583 AC_ARG_ENABLE([gbm],
 584    [AS_HELP_STRING([--enable-gbm],
 585          [enable gbm library @<:@default=auto@:>@])],
 586    [enable_gbm="$enableval"],
 587    [enable_gbm=auto])
 588
 589 AC_ARG_ENABLE([xvmc],
 590    [AS_HELP_STRING([--enable-xvmc],
 591          [enable xvmc library @<:@default=auto@:>@])],
 592    [enable_xvmc="$enableval"],
 593    [enable_xvmc=auto])
 594 AC_ARG_ENABLE([vdpau],
 595    [AS_HELP_STRING([--enable-vdpau],
 596          [enable vdpau library @<:@default=auto@:>@])],
 597    [enable_vdpau="$enableval"],
 598    [enable_vdpau=auto])
 599 AC_ARG_ENABLE([va],
 600    [AS_HELP_STRING([--enable-va],
 601          [enable va library @<:@default=auto@:>@])],
 602    [enable_va="$enableval"],
 603    [enable_va=auto])
 604 AC_ARG_ENABLE([opencl],
 605    [AS_HELP_STRING([--enable-opencl],
 606          [enable OpenCL library @<:@default=no@:>@])],
 607    [enable_opencl="$enableval"],
 608    [enable_opencl=no])
 609 AC_ARG_ENABLE([xlib_glx],
 610     [AS_HELP_STRING([--enable-xlib-glx],
 611         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 612     [enable_xlib_glx="$enableval"],
 613     [enable_xlib_glx=no])
 614 AC_ARG_ENABLE([gallium_egl],
 615     [AS_HELP_STRING([--enable-gallium-egl],
 616         [enable optional EGL state tracker (not required
 617          for EGL support in Gallium with OpenGL and OpenGL ES)
 618          @<:@default=disable@:>@])],
 619     [enable_gallium_egl="$enableval"],
 620     [enable_gallium_egl=no])
 621 AC_ARG_ENABLE([gallium_gbm],
 622     [AS_HELP_STRING([--enable-gallium-gbm],
 623         [enable optional gbm state tracker (not required for
 624          gbm support in Gallium)
 625          @<:@default=auto@:>@])],
 626     [enable_gallium_gbm="$enableval"],
 627     [enable_gallium_gbm=auto])
 628
 629 AC_ARG_ENABLE([r600-llvm-compiler],
 630     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 631         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 632     [enable_r600_llvm="$enableval"],
 633     [enable_r600_llvm=no])
 634
 635 AC_ARG_ENABLE([gallium_tests],
 636     [AS_HELP_STRING([--enable-gallium-tests],
 637         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 638     [enable_gallium_tests="$enableval"],
 639     [enable_gallium_tests=no])
 640
 641 # Option for Gallium drivers
 642 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 643
 644 AC_ARG_WITH([gallium-drivers],
 645     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 646         [comma delimited Gallium drivers list, e.g.
 647         "i915,nouveau,r300,r600,svga,swrast"
 648         @<:@default=r300,r600,swrast@:>@])],
 649     [with_gallium_drivers="$withval"],
 650     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 651
 652 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 653 # here so that the script doesn't choke on an unknown driver name later.
 654 case "$with_gallium_drivers" in
 655     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 656     no) with_gallium_drivers='' ;;
 657 esac
 658
 659 if test "x$enable_opengl" = xno -a \
 660         "x$enable_gles1" = xno -a \
 661         "x$enable_gles2" = xno -a \
 662         "x$enable_openvg" = xno -a \
 663         "x$enable_xorg" = xno -a \
 664         "x$enable_xa" = xno -a \
 665         "x$enable_d3d1x" = xno -a \
 666         "x$enable_xvmc" = xno -a \
 667         "x$enable_vdpau" = xno -a \
 668         "x$enable_va" = xno -a \
 669         "x$enable_opencl" = xno; then
 670     AC_MSG_ERROR([at least one API should be enabled])
 671 fi
 672
 673 API_DEFINES=""
 674 if test "x$enable_opengl" = xno; then
 675     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 676 else
 677     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 678 fi
 679 if test "x$enable_gles1" = xyes; then
 680     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 681 fi
 682 if test "x$enable_gles2" = xyes; then
 683     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 684 fi
 685 AC_SUBST([API_DEFINES])
 686
 687 if test "x$enable_glx" = xno; then
 688     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 689     enable_xlib_glx=no
 690 fi
 691
 692 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 693     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 694 fi
 695
 696 # Disable GLX if DRI and Xlib-GLX are not enabled
 697 if test "x$enable_glx" = xyes -a \
 698         "x$enable_dri" = xno -a \
 699         "x$enable_xlib_glx" = xno; then
 700     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 701     enable_glx=no
 702 fi
 703
 704 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 705 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 706                                   "x$enable_osmesa" = xyes)
 707
 708 AC_ARG_ENABLE([shared-glapi],
 709     [AS_HELP_STRING([--enable-shared-glapi],
 710         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 711     [enable_shared_glapi="$enableval"],
 712     [enable_shared_glapi="$enable_dri"])
 713
 714 # Shared GLAPI is only useful for DRI
 715 if test "x$enable_dri" = xno; then
 716     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 717     enable_shared_glapi=no
 718 fi
 719
 720 # TODO: Get rid of SHARED_GLAPI variable
 721 SHARED_GLAPI="0"
 722 if test "x$enable_shared_glapi" = xyes; then
 723     SHARED_GLAPI="1"
 724     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 725     # the remap table)
 726     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 727     CORE_DIRS="mapi/shared-glapi"
 728 fi
 729 AC_SUBST([SHARED_GLAPI])
 730 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 731
 732 dnl
 733 dnl Driver specific build directories
 734 dnl
 735 SRC_DIRS="gtest"
 736 GALLIUM_DIRS="auxiliary drivers state_trackers"
 737 GALLIUM_TARGET_DIRS=""
 738 GALLIUM_WINSYS_DIRS="sw"
 739 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 740 GALLIUM_STATE_TRACKERS_DIRS=""
 741
 742 # build glapi if OpenGL is enabled
 743 if test "x$enable_opengl" = xyes; then
 744     CORE_DIRS="$CORE_DIRS mapi/glapi"
 745 fi
 746
 747 # build es1api if OpenGL ES 1.x is enabled
 748 if test "x$enable_gles1" = xyes; then
 749     CORE_DIRS="$CORE_DIRS mapi/es1api"
 750 fi
 751
 752 # build es2api if OpenGL ES 2.x is enabled
 753 if test "x$enable_gles2" = xyes; then
 754     CORE_DIRS="$CORE_DIRS mapi/es2api"
 755 fi
 756
 757 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 758 case "x$enable_opengl$enable_gles1$enable_gles2" in
 759 x*yes*)
 760     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 761     ;;
 762 esac
 763
 764 case "x$enable_glx$enable_xlib_glx" in
 765 xyesyes)
 766     DRIVER_DIRS="$DRIVER_DIRS x11"
 767     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 768     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 769     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 770     HAVE_WINSYS_XLIB="yes"
 771     ;;
 772 xyesno)
 773     # DRI-based GLX
 774     SRC_DIRS="$SRC_DIRS glx"
 775     ;;
 776 esac
 777
 778 if test "x$enable_dri" = xyes; then
 779     DRIVER_DIRS="$DRIVER_DIRS dri"
 780
 781     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 782     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 783     HAVE_ST_DRI="yes"
 784 fi
 785
 786 if test "x$enable_osmesa" = xyes; then
 787     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 788 fi
 789
 790 AC_SUBST([SRC_DIRS])
 791 AC_SUBST([DRIVER_DIRS])
 792 AC_SUBST([GALLIUM_DIRS])
 793 AC_SUBST([GALLIUM_TARGET_DIRS])
 794 AC_SUBST([GALLIUM_WINSYS_DIRS])
 795 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 796 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 797 AC_SUBST([MESA_LLVM])
 798
 799 # Check for libdrm
 800 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 801                   [have_libdrm=yes], [have_libdrm=no])
 802
 803 if test "x$enable_dri" = xyes; then
 804     # DRI must be shared, I think
 805     if test "$enable_static" = yes; then
 806         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 807     fi
 808
 809     # not a hard requirement as swrast does not depend on it
 810     if test "x$have_libdrm" = xyes; then
 811         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 812     fi
 813 fi
 814
 815 dnl Find out if X is available.
 816 PKG_CHECK_MODULES([X11], [x11])
 817
 818 dnl Try to tell the user that the --x-* options are only used when
 819 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 820 m4_divert_once([HELP_BEGIN],
 821 [These options are only used when the X libraries cannot be found by the
 822 pkg-config utility.])
 823
 824 dnl We need X for xlib and dri, so bomb now if it's not found
 825 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 826     AC_MSG_ERROR([X11 development libraries needed for GLX])
 827 fi
 828
 829 if test "x$enable_glx" = xyes; then
 830     DEFINES="$DEFINES -DUSE_XCB"
 831 fi
 832
 833 dnl Direct rendering or just indirect rendering
 834 case "$host_os" in
 835 gnu*)
 836     dnl Disable by default on GNU/Hurd
 837     driglx_direct_default="no"
 838     ;;
 839 cygwin*)
 840     dnl Disable by default on cygwin
 841     driglx_direct_default="no"
 842     ;;
 843 *)
 844     driglx_direct_default="yes"
 845     ;;
 846 esac
 847 AC_ARG_ENABLE([driglx-direct],
 848     [AS_HELP_STRING([--disable-driglx-direct],
 849         [enable direct rendering in GLX and EGL for DRI \
 850             @<:@default=auto@:>@])],
 851     [driglx_direct="$enableval"],
 852     [driglx_direct="$driglx_direct_default"])
 853
 854 dnl
 855 dnl libGL configuration per driver
 856 dnl
 857 case "x$enable_glx$enable_xlib_glx" in
 858 xyesyes)
 859     # Xlib-based GLX
 860     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 861     GL_PC_REQ_PRIV="x11 xext"
 862     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 863     GL_LIB_DEPS="$XLIBGL_LIBS"
 864     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 865     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 866     ;;
 867 xyesno)
 868     # DRI-based GLX
 869     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 870     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 871     if test x"$driglx_direct" = xyes; then
 872         if test "x$have_libdrm" != xyes; then
 873             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 874         fi
 875         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 876         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 877     fi
 878
 879     # find the DRI deps for libGL
 880     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1"
 881
 882     # add xf86vidmode if available
 883     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 884     if test "$HAVE_XF86VIDMODE" = yes ; then
 885         dri_modules="$dri_modules xxf86vm"
 886     fi
 887
 888     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 889     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 890     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 891     GL_LIB_DEPS="$DRIGL_LIBS"
 892
 893     # need DRM libs, -lpthread, etc.
 894     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 895     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 896     ;;
 897 esac
 898
 899 # This is outside the case (above) so that it is invoked even for non-GLX
 900 # builds.
 901 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 902
 903 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 904 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 905 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 906 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 907
 908 AC_SUBST([GL_LIB_DEPS])
 909 AC_SUBST([GL_PC_REQ_PRIV])
 910 AC_SUBST([GL_PC_LIB_PRIV])
 911 AC_SUBST([GL_PC_CFLAGS])
 912 AC_SUBST([DRI_PC_REQ_PRIV])
 913 AC_SUBST([GLESv1_CM_LIB_DEPS])
 914 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 915 AC_SUBST([GLESv2_LIB_DEPS])
 916 AC_SUBST([GLESv2_PC_LIB_PRIV])
 917
 918 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
 919 AC_SUBST([GLAPI_LIB_DEPS])
 920
 921
 922 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 923 GALLIUM_DRI_LIB_DEPS="\$(TOP)/\$(LIB_DIR)/libdricore${VERSION}.so"
 924
 925 AC_SUBST([HAVE_XF86VIDMODE])
 926
 927 dnl
 928 dnl More GLX setup
 929 dnl
 930 case "x$enable_glx$enable_xlib_glx" in
 931 xyesyes)
 932     DEFINES="$DEFINES -DUSE_XSHM"
 933     ;;
 934 xyesno)
 935     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 936     if test "x$driglx_direct" = xyes; then
 937         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 938     fi
 939     ;;
 940 esac
 941
 942 dnl
 943 dnl TLS detection
 944 dnl
 945
 946 AC_ARG_ENABLE([glx-tls],
 947     [AS_HELP_STRING([--enable-glx-tls],
 948         [enable TLS support in GLX @<:@default=disabled@:>@])],
 949     [GLX_USE_TLS="$enableval"],
 950     [GLX_USE_TLS=no])
 951 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 952
 953 AS_IF([test "x$GLX_USE_TLS" = xyes],
 954       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
 955
 956 dnl
 957 dnl More DRI setup
 958 dnl
 959 dnl Directory for DRI drivers
 960 AC_ARG_WITH([dri-driverdir],
 961     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 962         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 963     [DRI_DRIVER_INSTALL_DIR="$withval"],
 964     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 965 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 966 dnl Extra search path for DRI drivers
 967 AC_ARG_WITH([dri-searchpath],
 968     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 969         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 970     [DRI_DRIVER_SEARCH_DIR="$withval"],
 971     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 972 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 973 dnl Which drivers to build - default is chosen by platform
 974 AC_ARG_WITH([dri-drivers],
 975     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 976         [comma delimited DRI drivers list, e.g.
 977         "swrast,i965,radeon" @<:@default=auto@:>@])],
 978     [with_dri_drivers="$withval"],
 979     [with_dri_drivers=yes])
 980 if test "x$with_dri_drivers" = x; then
 981     with_dri_drivers=no
 982 fi
 983
 984 dnl If $with_dri_drivers is yes, directories will be added through
 985 dnl platform checks
 986 DRI_DIRS=""
 987 case "$with_dri_drivers" in
 988 no) ;;
 989 yes)
 990     # classic DRI drivers require FEATURE_GL to build
 991     if test "x$enable_opengl" = xyes; then
 992         DRI_DIRS="yes"
 993     fi
 994     ;;
 995 *)
 996     # verify the requested driver directories exist
 997     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 998     for driver in $dri_drivers; do
 999         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1000             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1001     done
1002     DRI_DIRS="$dri_drivers"
1003     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1004         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1005     fi
1006     ;;
1007 esac
1008
1009 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1010 if test "x$enable_dri" = xyes; then
1011     # Platform specific settings and drivers to build
1012     case "$host_os" in
1013     linux*)
1014         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1015         DEFINES="$DEFINES -DHAVE_ALIAS"
1016
1017         case "$host_cpu" in
1018         x86_64)
1019             if test "x$DRI_DIRS" = "xyes"; then
1020                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1021             fi
1022             ;;
1023         powerpc*)
1024             # Build only the drivers for cards that exist on PowerPC.
1025             if test "x$DRI_DIRS" = "xyes"; then
1026                 DRI_DIRS="r200 radeon swrast"
1027             fi
1028             ;;
1029         sparc*)
1030             # Build only the drivers for cards that exist on sparc
1031             if test "x$DRI_DIRS" = "xyes"; then
1032                 DRI_DIRS="r200 radeon swrast"
1033             fi
1034             ;;
1035         esac
1036         ;;
1037     freebsd* | dragonfly* | *netbsd*)
1038         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1039         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1040
1041         if test "x$DRI_DIRS" = "xyes"; then
1042             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1043         fi
1044         ;;
1045     gnu*)
1046         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1047         DEFINES="$DEFINES -DHAVE_ALIAS"
1048         ;;
1049     solaris*)
1050         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1051         ;;
1052     cygwin*)
1053         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1054         if test "x$DRI_DIRS" = "xyes"; then
1055             DRI_DIRS="swrast"
1056         fi
1057         ;;
1058     esac
1059
1060     # default drivers
1061     if test "x$DRI_DIRS" = "xyes"; then
1062         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1063     fi
1064
1065     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1066
1067     # Check for expat
1068     if test "x$enable_dri" = xyes; then
1069         EXPAT_INCLUDES=""
1070         EXPAT_LIB=-lexpat
1071         AC_ARG_WITH([expat],
1072             [AS_HELP_STRING([--with-expat=DIR],
1073                 [expat install directory])],[
1074             EXPAT_INCLUDES="-I$withval/include"
1075             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1076             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1077             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1078             ])
1079         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1080         save_LIBS="$LIBS"
1081         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1082             [AC_MSG_ERROR([Expat required for DRI.])])
1083         LIBS="$save_LIBS"
1084     fi
1085
1086     # if we are building any dri driver other than swrast ...
1087     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1088         # ... libdrm is required
1089         if test "x$have_libdrm" != xyes; then
1090             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1091         fi
1092         # ... and build dricommon
1093         HAVE_COMMON_DRI=yes
1094     fi
1095
1096     # put all the necessary libs together
1097     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1098     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1099 fi
1100 AC_SUBST([DRI_DIRS])
1101 AC_SUBST([EXPAT_INCLUDES])
1102 AC_SUBST([DRI_LIB_DEPS])
1103 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1104
1105 case $DRI_DIRS in
1106 *i915*|*i965*)
1107     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1108
1109     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1110         case $d in
1111         i915)
1112             HAVE_I915_DRI=yes;
1113             ;;
1114         i965)
1115             HAVE_I965_DRI=yes;
1116             ;;
1117         esac
1118     done
1119
1120     ;;
1121 esac
1122
1123 case $DRI_DIRS in
1124 *nouveau*)
1125     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1126     HAVE_NOUVEAU_DRI=yes;
1127     ;;
1128 esac
1129
1130 case $DRI_DIRS in
1131 *radeon*|*r200*)
1132     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1133
1134     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1135         case $d in
1136         radeon)
1137             HAVE_RADEON_DRI=yes;
1138             ;;
1139         r200)
1140             HAVE_R200_DRI=yes;
1141             ;;
1142         esac
1143     done
1144
1145     ;;
1146 esac
1147
1148 case $DRI_DIRS in
1149 *swrast*)
1150     HAVE_SWRAST_DRI=yes;
1151     ;;
1152 esac
1153
1154 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1155 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1156 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1157 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1158 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1159 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1160 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1161
1162 dnl
1163 dnl OSMesa configuration
1164 dnl
1165
1166 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1167 AC_ARG_WITH([osmesa-bits],
1168     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1169         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1170     [osmesa_bits="$withval"],
1171     [osmesa_bits=8])
1172 if test "x$osmesa_bits" != x8; then
1173     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1174         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1175         osmesa_bits=8
1176     fi
1177 fi
1178 case "x$osmesa_bits" in
1179 x8)
1180     OSMESA_LIB="${OSMESA_LIB}"
1181     ;;
1182 x16|x32)
1183     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1184     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1185     ;;
1186 *)
1187     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1188     ;;
1189 esac
1190
1191 if test "x$enable_osmesa" = xyes; then
1192     # only link libraries with osmesa if shared
1193     if test "$enable_static" = no; then
1194         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1195     else
1196         OSMESA_LIB_DEPS=""
1197     fi
1198     OSMESA_MESA_DEPS=""
1199     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1200 fi
1201
1202 AC_SUBST([OSMESA_LIB_DEPS])
1203 AC_SUBST([OSMESA_MESA_DEPS])
1204 AC_SUBST([OSMESA_PC_REQ])
1205 AC_SUBST([OSMESA_PC_LIB_PRIV])
1206
1207 dnl
1208 dnl gbm configuration
1209 dnl
1210 if test "x$enable_gbm" = xauto; then
1211     case "$with_egl_platforms" in
1212         *drm*)
1213             enable_gbm=yes ;;
1214          *)
1215             enable_gbm=no ;;
1216     esac
1217 fi
1218 if test "x$enable_gbm" = xyes; then
1219     SRC_DIRS="$SRC_DIRS gbm"
1220
1221     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1222                       AC_MSG_ERROR([gbm needs udev]))
1223
1224     if test "x$enable_dri" = xyes; then
1225         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1226         if test "x$enable_shared_glapi" = xno; then
1227             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1228         fi
1229     fi
1230 fi
1231 GBM_PC_REQ_PRIV="libudev"
1232 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1233 AC_SUBST([GBM_PC_REQ_PRIV])
1234 AC_SUBST([GBM_PC_LIB_PRIV])
1235
1236 dnl
1237 dnl EGL configuration
1238 dnl
1239 EGL_CLIENT_APIS=""
1240
1241 if test "x$enable_egl" = xyes; then
1242     SRC_DIRS="$SRC_DIRS egl"
1243     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1244
1245     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1246
1247     if test "$enable_static" != yes; then
1248         # build egl_glx when libGL is built
1249         if test "x$enable_glx" = xyes; then
1250             HAVE_EGL_DRIVER_GLX=1
1251         fi
1252
1253         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1254                           [have_libudev=yes],[have_libudev=no])
1255         if test "$have_libudev" = yes; then
1256             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1257         fi
1258
1259         if test "x$enable_dri" = xyes; then
1260             HAVE_EGL_DRIVER_DRI2=1
1261         fi
1262
1263     fi
1264 fi
1265 AC_SUBST([EGL_LIB_DEPS])
1266
1267 dnl
1268 dnl EGL Gallium configuration
1269 dnl
1270 if test "x$enable_gallium_egl" = xyes; then
1271     if test "x$with_gallium_drivers" = x; then
1272         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1273     fi
1274     if test "x$enable_egl" = xno; then
1275         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1276     fi
1277     if test "x$have_libdrm" != xyes; then
1278         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1279     fi
1280
1281     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1282     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1283     HAVE_ST_EGL="yes"
1284 fi
1285
1286 dnl
1287 dnl gbm Gallium configuration
1288 dnl
1289 if test "x$enable_gallium_gbm" = xauto; then
1290     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1291         yesyesyes*drm*)
1292             enable_gallium_gbm=yes ;;
1293          *)
1294             enable_gallium_gbm=no ;;
1295     esac
1296 fi
1297 if test "x$enable_gallium_gbm" = xyes; then
1298     if test "x$with_gallium_drivers" = x; then
1299         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1300     fi
1301     if test "x$enable_gbm" = xno; then
1302         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1303     fi
1304     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1305     if test "x$enable_dri" = xno; then
1306         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1307     fi
1308
1309     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1310     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1311     HAVE_ST_GBM="yes"
1312     enable_gallium_loader=yes
1313 fi
1314
1315 dnl
1316 dnl X.Org DDX configuration
1317 dnl
1318 if test "x$enable_xorg" = xyes; then
1319     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1320     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1321     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1322     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1323         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1324         HAVE_XEXTPROTO_71="no")
1325     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1326     HAVE_ST_XORG=yes
1327 fi
1328
1329 dnl
1330 dnl XA configuration
1331 dnl
1332 if test "x$enable_xa" = xyes; then
1333 AC_PROG_AWK
1334 AC_PROG_GREP
1335 AC_CHECK_PROG(NM, nm, "nm")
1336 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1337 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1338 enable_xa=no
1339 fi
1340 fi
1341 if test "x$enable_xa" = xyes; then
1342     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1343     HAVE_ST_XA=yes
1344     AC_SUBST(AWK)
1345     AC_SUBST(GREP)
1346     AC_SUBST(NM)
1347 fi
1348
1349 dnl
1350 dnl OpenVG configuration
1351 dnl
1352 VG_LIB_DEPS=""
1353
1354 if test "x$enable_openvg" = xyes; then
1355     if test "x$enable_egl" = xno; then
1356         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1357     fi
1358     if test "x$with_gallium_drivers" = x; then
1359         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1360     fi
1361     if test "x$enable_gallium_egl" = xno; then
1362         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1363     fi
1364
1365     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1366     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1367     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1368     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1369     HAVE_ST_VEGA=yes
1370 fi
1371
1372 dnl
1373 dnl D3D1X configuration
1374 dnl
1375
1376 if test "x$enable_d3d1x" = xyes; then
1377     if test "x$with_gallium_drivers" = x; then
1378         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1379     fi
1380
1381     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1382     HAVE_ST_D3D1X=yes
1383 fi
1384
1385 dnl
1386 dnl Gallium G3DVL configuration
1387 dnl
1388 AC_ARG_ENABLE([gallium-g3dvl],
1389     [AS_HELP_STRING([--enable-gallium-g3dvl],
1390         [build gallium g3dvl @<:@default=disabled@:>@])],
1391     [enable_gallium_g3dvl="$enableval"],
1392     [enable_gallium_g3dvl=no])
1393 if test "x$enable_gallium_g3dvl" = xyes; then
1394     if test "x$with_gallium_drivers" = x; then
1395         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1396     fi
1397
1398     if test "x$enable_xvmc" = xauto; then
1399         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1400     fi
1401
1402     if test "x$enable_vdpau" = xauto; then
1403         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1404     fi
1405
1406     if test "x$enable_va" = xauto; then
1407         #don't enable vaapi state tracker even if package exists
1408         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1409         enable_va=no
1410     fi
1411 fi
1412
1413 if test "x$enable_xvmc" = xyes; then
1414     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1415     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1416     HAVE_ST_XVMC="yes"
1417 fi
1418
1419 if test "x$enable_vdpau" = xyes; then
1420     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1421     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1422     HAVE_ST_VDPAU="yes"
1423 fi
1424
1425 if test "x$enable_va" = xyes; then
1426     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1427     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1428     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1429     HAVE_ST_VA="yes"
1430 fi
1431
1432 dnl
1433 dnl OpenCL configuration
1434 dnl
1435
1436 AC_ARG_WITH([libclc-path],
1437    [AS_HELP_STRING([--with-libclc-path],
1438          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1439    [LIBCLC_PATH="$withval"],
1440    [LIBCLC_PATH=""])
1441
1442 AC_ARG_WITH([clang-libdir],
1443    [AS_HELP_STRING([--with-clang-libdir],
1444          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1445    [CLANG_LIBDIR="$withval"],
1446    [CLANG_LIBDIR=""])
1447
1448 AC_SUBST([LIBCLC_PATH])
1449
1450 if test "x$enable_opencl" = xyes; then
1451     if test "x$with_gallium_drivers" = x; then
1452         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1453     fi
1454
1455     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1456         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1457     fi
1458
1459     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1460     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1461     enable_gallium_loader=yes
1462 fi
1463
1464 dnl
1465 dnl GLU configuration
1466 dnl
1467 AC_ARG_ENABLE([glu],
1468     [AS_HELP_STRING([--disable-glu],
1469         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1470     [enable_glu="$enableval"],
1471     [enable_glu=yes])
1472
1473 if test "x$enable_glu" = xyes; then
1474     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1475         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1476         enable_glu=no
1477     fi
1478 fi
1479
1480 if test "x$enable_glu" = xyes; then
1481     SRC_DIRS="$SRC_DIRS glu"
1482
1483     if test "x$enable_glx" = xno; then
1484         # Link libGLU to libOSMesa instead of libGL
1485         GLU_LIB_DEPS=""
1486         GLU_PC_REQ="osmesa"
1487         if test "$enable_static" = no; then
1488             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1489         else
1490             GLU_MESA_DEPS=""
1491         fi
1492     else
1493         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1494         GLU_PC_REQ="gl"
1495         GLU_PC_LIB_PRIV="-lm"
1496         if test "$enable_static" = no; then
1497             GLU_LIB_DEPS="-lm"
1498             GLU_MESA_DEPS='-l$(GL_LIB)'
1499         else
1500             GLU_LIB_DEPS=""
1501             GLU_MESA_DEPS=""
1502         fi
1503     fi
1504 fi
1505 if test "$enable_static" = no; then
1506     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1507 fi
1508 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1509 AC_SUBST([GLU_LIB_DEPS])
1510 AC_SUBST([GLU_MESA_DEPS])
1511 AC_SUBST([GLU_PC_REQ])
1512 AC_SUBST([GLU_PC_REQ_PRIV])
1513 AC_SUBST([GLU_PC_LIB_PRIV])
1514 AC_SUBST([GLU_PC_CFLAGS])
1515
1516 AC_SUBST([PROGRAM_DIRS])
1517
1518 dnl
1519 dnl Gallium configuration
1520 dnl
1521 if test "x$with_gallium_drivers" != x; then
1522     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1523 fi
1524 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1525
1526 AC_SUBST([LLVM_BINDIR])
1527 AC_SUBST([LLVM_CFLAGS])
1528 AC_SUBST([LLVM_CPPFLAGS])
1529 AC_SUBST([LLVM_CXXFLAGS])
1530 AC_SUBST([LLVM_LIBDIR])
1531 AC_SUBST([LLVM_LIBS])
1532 AC_SUBST([LLVM_LDFLAGS])
1533 AC_SUBST([LLVM_INCLUDEDIR])
1534 AC_SUBST([LLVM_VERSION])
1535 AC_SUBST([CLANG_RESOURCE_DIR])
1536
1537 case "x$enable_opengl$enable_gles1$enable_gles2" in
1538 x*yes*)
1539     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1540     ;;
1541 esac
1542
1543 AC_SUBST([VG_LIB_DEPS])
1544 AC_SUBST([EGL_CLIENT_APIS])
1545
1546 dnl
1547 dnl EGL Platforms configuration
1548 dnl
1549 AC_ARG_WITH([egl-platforms],
1550     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1551         [comma delimited native platforms libEGL supports, e.g.
1552         "x11,drm" @<:@default=auto@:>@])],
1553     [with_egl_platforms="$withval"],
1554     [if test "x$enable_egl" = xyes; then
1555         with_egl_platforms="x11"
1556     else
1557         with_egl_platforms=""
1558     fi])
1559
1560 EGL_PLATFORMS=""
1561
1562 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1563     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1564 fi
1565
1566 # Do per-EGL platform setups and checks
1567 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1568 for plat in $egl_platforms; do
1569         case "$plat" in
1570         fbdev|null)
1571                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1572                 ;;
1573
1574         wayland)
1575                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1576                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1577                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1578
1579                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1580                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1581                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1582                 ;;
1583
1584         x11)
1585                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1586                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1587                 save_LIBS="$LIBS"
1588                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1589                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1590                 LIBS="$save_LIBS"
1591                 ;;
1592
1593         drm)
1594                 test "x$enable_gbm" = "xno" &&
1595                         AC_MSG_ERROR([EGL platform drm needs gbm])
1596                 ;;
1597
1598         android|gdi)
1599                 ;;
1600
1601         *)
1602                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1603                 ;;
1604         esac
1605
1606         case "$plat$have_libudev" in
1607                 waylandno|drmno)
1608                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1609         esac
1610 done
1611
1612 # libEGL wants to default to the first platform specified in
1613 # ./configure.  parse that here.
1614 if test "x$egl_platforms" != "x"; then
1615     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1616     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1617 else
1618     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1619 fi
1620
1621 EGL_PLATFORMS="$egl_platforms"
1622
1623 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1624 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1625 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1626 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1627 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1628
1629 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1630 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1631
1632 AC_SUBST([EGL_NATIVE_PLATFORM])
1633 AC_SUBST([EGL_PLATFORMS])
1634 AC_SUBST([EGL_CFLAGS])
1635
1636 AC_ARG_WITH([egl-driver-dir],
1637     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1638                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1639     [EGL_DRIVER_INSTALL_DIR="$withval"],
1640     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1641 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1642
1643 AC_ARG_WITH([xorg-driver-dir],
1644     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1645                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1646     [XORG_DRIVER_INSTALL_DIR="$withval"],
1647     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1648 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1649
1650 AC_ARG_WITH([max-width],
1651     [AS_HELP_STRING([--with-max-width=N],
1652                     [Maximum framebuffer width (4096)])],
1653     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1654      AS_IF([test "${withval}" -gt "4096"],
1655            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1656 )
1657 AC_ARG_WITH([max-height],
1658     [AS_HELP_STRING([--with-max-height=N],
1659                     [Maximum framebuffer height (4096)])],
1660     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1661      AS_IF([test "${withval}" -gt "4096"],
1662            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1663 )
1664
1665 dnl
1666 dnl Gallium LLVM
1667 dnl
1668 AC_ARG_ENABLE([gallium-llvm],
1669     [AS_HELP_STRING([--enable-gallium-llvm],
1670         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1671     [enable_gallium_llvm="$enableval"],
1672     [enable_gallium_llvm=auto])
1673
1674 AC_ARG_WITH([llvm-shared-libs],
1675     [AS_HELP_STRING([--with-llvm-shared-libs],
1676         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1677     [with_llvm_shared_libs=yes],
1678     [with_llvm_shared_libs=no])
1679
1680 AC_ARG_WITH([llvm-prefix],
1681     [AS_HELP_STRING([--with-llvm-prefix],
1682         [Prefix for LLVM installations in non-standard locations])],
1683     [llvm_prefix="$withval"],
1684     [llvm_prefix=""])
1685
1686
1687 if test "x$with_gallium_drivers" = x; then
1688     enable_gallium_llvm=no
1689 fi
1690 if test "x$enable_gallium_llvm" = xauto; then
1691     case "$host_cpu" in
1692     i*86|x86_64) enable_gallium_llvm=yes;;
1693     esac
1694 fi
1695 if test "x$enable_gallium_llvm" = xyes; then
1696     if test "x$llvm_prefix" != x; then
1697         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1698     else
1699         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1700     fi
1701
1702     if test "x$LLVM_CONFIG" != xno; then
1703         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1704         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1705         if test "x$with_llvm_shared_libs" = xyes; then
1706             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1707             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1708         else
1709             LLVM_COMPONENTS="engine bitwriter"
1710             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1711                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1712             fi
1713             if test "x$enable_opencl" = xyes; then
1714                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1715             fi
1716             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1717         fi
1718         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1719         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1720         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1721         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1722         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1723         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1724         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1725         MESA_LLVM=1
1726
1727         dnl Check for Clang interanl headers
1728         if test "x$enable_opencl" = xyes; then
1729             if test "x$CLANG_LIBDIR" = x; then
1730                 CLANG_LIBDIR=${LLVM_LIBDIR}
1731             fi
1732             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1733             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1734                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1735         fi
1736     else
1737         MESA_LLVM=0
1738     fi
1739 else
1740     MESA_LLVM=0
1741 fi
1742
1743 dnl Directory for XVMC libs
1744 AC_ARG_WITH([xvmc-libdir],
1745     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1746         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1747     [XVMC_LIB_INSTALL_DIR="$withval"],
1748     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1749 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1750
1751 dnl
1752 dnl Gallium Tests
1753 dnl
1754 if test "x$enable_gallium_tests" = xyes; then
1755     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1756     enable_gallium_loader=yes
1757 fi
1758
1759 dnl Directory for VDPAU libs
1760 AC_ARG_WITH([vdpau-libdir],
1761     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1762         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1763     [VDPAU_LIB_INSTALL_DIR="$withval"],
1764     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1765 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1766
1767 dnl Directory for VA libs
1768 AC_ARG_WITH([va-libdir],
1769     [AS_HELP_STRING([--with-va-libdir=DIR],
1770         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1771     [VA_LIB_INSTALL_DIR="$withval"],
1772     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1773 AC_SUBST([VA_LIB_INSTALL_DIR])
1774
1775 dnl Directory for OpenCL libs
1776 AC_ARG_WITH([opencl-libdir],
1777     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1778         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1779     [OPENCL_LIB_INSTALL_DIR="$withval"],
1780     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1781 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1782
1783 dnl
1784 dnl Gallium helper functions
1785 dnl
1786 gallium_check_st() {
1787     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1788          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1789          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1790          if test "x$have_libdrm" != xyes; then
1791             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1792          fi
1793          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1794     fi
1795     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1796          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1797     fi
1798     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1799          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1800     fi
1801     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1802          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1803     fi
1804     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1805          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1806     fi
1807     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1808          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1809     fi
1810     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1811          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1812     fi
1813 }
1814
1815 gallium_require_llvm() {
1816     if test "x$MESA_LLVM" = x0; then
1817         case "$host_cpu" in
1818         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1819         esac
1820     fi
1821 }
1822
1823 gallium_require_drm_loader() {
1824     if test "x$enable_gallium_loader" = xyes; then
1825         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1826                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1827         if test "x$have_libdrm" != xyes; then
1828             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1829         fi
1830         enable_gallium_drm_loader=yes
1831     fi
1832 }
1833
1834 dnl Gallium drivers
1835 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1836 if test "x$with_gallium_drivers" != x; then
1837     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1838     for driver in $gallium_drivers; do
1839         case "x$driver" in
1840         xsvga)
1841             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1842             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1843             ;;
1844         xi915)
1845             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1846             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1847             if test "x$MESA_LLVM" = x1; then
1848                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1849             fi
1850             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1851             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1852             ;;
1853         xr300)
1854             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1855             gallium_require_llvm "Gallium R300"
1856             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1857             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1858             ;;
1859         xr600)
1860             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1861             gallium_require_drm_loader
1862             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1863             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1864                 if test "x$LLVM_VERSION" != "x3.1"; then
1865                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1866                 fi
1867                 NEED_RADEON_GALLIUM=yes;
1868             fi
1869             if test "x$enable_r600_llvm" = xyes; then
1870                 USE_R600_LLVM_COMPILER=yes;
1871             fi
1872             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1873                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1874             fi
1875             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1876             ;;
1877         xradeonsi)
1878             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1879             gallium_require_drm_loader
1880             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1881             if test "x$LLVM_VERSION" != "x3.1"; then
1882                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1883             fi
1884             NEED_RADEON_GALLIUM=yes;
1885             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1886             ;;
1887         xnouveau)
1888             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1889             gallium_require_drm_loader
1890             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1891             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1892             ;;
1893         xswrast)
1894             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1895             if test "x$MESA_LLVM" = x1; then
1896                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1897             fi
1898
1899             if test "x$HAVE_ST_DRI" = xyes; then
1900                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1901             fi
1902             if test "x$HAVE_ST_VDPAU" = xyes; then
1903                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1904             fi
1905             if test "x$HAVE_ST_XVMC" = xyes; then
1906                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1907             fi
1908             if test "x$HAVE_ST_VA" = xyes; then
1909                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1910             fi
1911             if test "x$HAVE_ST_VDPAU" = xyes ||
1912                test "x$HAVE_ST_XVMC" = xyes ||
1913                test "x$HAVE_ST_VA" = xyes; then
1914                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1915                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1916                fi
1917             fi
1918             ;;
1919         *)
1920             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1921             ;;
1922         esac
1923     done
1924 fi
1925
1926 if test "x$enable_gallium_loader" = xyes; then
1927     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1928     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1929     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1930     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1931
1932     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1933         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1934         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1935     fi
1936
1937     if test "x$enable_gallium_drm_loader" = xyes; then
1938         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1939         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1940                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1941         if test "x$pipe_loader_have_xcb" = xyes; then
1942             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1943             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1944         fi
1945     fi
1946
1947     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1948     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1949 fi
1950
1951 dnl Tell Automake which drivers to build
1952 for driver in $GALLIUM_DRIVERS_DIRS; do
1953     case "x$driver" in
1954         xgalahad)
1955             HAVE_GALAHAD_GALLIUM=yes;
1956             ;;
1957         xidentity)
1958             HAVE_IDENTITY_GALLIUM=yes;
1959             ;;
1960         xnoop)
1961             HAVE_NOOP_GALLIUM=yes;
1962             ;;
1963         *)
1964             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1965             ;;
1966     esac
1967 done
1968
1969 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1970 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1971 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1972 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1973 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1974 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1975 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1976 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1977 AC_SUBST([GALLIUM_MAKE_DIRS])
1978
1979 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
1980
1981 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1982 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1983 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1984
1985 # To pass as an argument to libtool's -version-number flag
1986 VERSION_NUMBER=`echo "$VERSION" | $SED 's/\./:/g'`
1987 AC_SUBST([VERSION_NUMBER])
1988
1989 dnl prepend CORE_DIRS to SRC_DIRS
1990 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1991
1992 dnl Restore LDFLAGS and CPPFLAGS
1993 LDFLAGS="$_SAVE_LDFLAGS"
1994 CPPFLAGS="$_SAVE_CPPFLAGS"
1995
1996 dnl Add user CFLAGS and CXXFLAGS
1997 CFLAGS="$CFLAGS $USER_CFLAGS"
1998 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1999
2000 dnl Substitute the config
2001 AC_CONFIG_FILES([configs/current
2002                 Makefile
2003                 src/egl/Makefile
2004                 src/egl/drivers/Makefile
2005                 src/egl/drivers/dri2/Makefile
2006                 src/egl/drivers/glx/Makefile
2007                 src/egl/main/Makefile
2008                 src/egl/main/egl.pc
2009                 src/egl/wayland/Makefile
2010                 src/egl/wayland/wayland-drm/Makefile
2011                 src/egl/wayland/wayland-egl/Makefile
2012                 src/egl/wayland/wayland-egl/wayland-egl.pc
2013                 src/gallium/Makefile
2014                 src/gallium/auxiliary/pipe-loader/Makefile
2015                 src/gallium/drivers/Makefile
2016                 src/gallium/drivers/r300/Makefile
2017                 src/gallium/drivers/r600/Makefile
2018                 src/gallium/state_trackers/clover/Makefile
2019                 src/gallium/targets/opencl/Makefile
2020                 src/gbm/Makefile
2021                 src/gbm/main/gbm.pc
2022                 src/glsl/Makefile
2023                 src/glsl/glcpp/Makefile
2024                 src/glsl/tests/Makefile
2025                 src/glx/Makefile
2026                 src/glx/tests/Makefile
2027                 src/gtest/Makefile
2028                 src/Makefile
2029                 src/mapi/es1api/Makefile
2030                 src/mapi/es1api/glesv1_cm.pc
2031                 src/mapi/es2api/Makefile
2032                 src/mapi/es2api/glesv2.pc
2033                 src/mapi/glapi/Makefile
2034                 src/mapi/glapi/gen/Makefile
2035                 src/mapi/glapi/tests/Makefile
2036                 src/mapi/shared-glapi/Makefile
2037                 src/mapi/shared-glapi/tests/Makefile
2038                 src/mesa/Makefile
2039                 src/mesa/gl.pc
2040                 src/mesa/drivers/Makefile
2041                 src/mesa/drivers/dri/dri.pc
2042                 src/mesa/drivers/dri/common/Makefile
2043                 src/mesa/drivers/dri/i915/Makefile
2044                 src/mesa/drivers/dri/i965/Makefile
2045                 src/mesa/drivers/dri/Makefile
2046                 src/mesa/drivers/dri/nouveau/Makefile
2047                 src/mesa/drivers/dri/r200/Makefile
2048                 src/mesa/drivers/dri/radeon/Makefile
2049                 src/mesa/drivers/dri/swrast/Makefile
2050                 src/mesa/drivers/osmesa/Makefile
2051                 src/mesa/drivers/osmesa/osmesa.pc
2052                 src/mesa/drivers/x11/Makefile
2053                 src/mesa/libdricore/Makefile
2054                 src/mesa/main/tests/Makefile
2055                 src/mesa/x86-64/Makefile
2056                 src/mesa/x86/Makefile])
2057
2058 dnl Sort the dirs alphabetically
2059 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2060 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2061 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2062 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2063 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2064
2065 AC_OUTPUT
2066
2067 dnl
2068 dnl Output some configuration info for the user
2069 dnl
2070 echo ""
2071 echo "        prefix:          $prefix"
2072 echo "        exec_prefix:     $exec_prefix"
2073 echo "        libdir:          $libdir"
2074 echo "        includedir:      $includedir"
2075
2076 dnl API info
2077 echo ""
2078 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2079 echo "        OpenVG:          $enable_openvg"
2080
2081 dnl Driver info
2082 echo ""
2083 if test "x$enable_osmesa" != xno; then
2084         echo "        OSMesa:          lib$OSMESA_LIB"
2085 else
2086         echo "        OSMesa:          no"
2087 fi
2088
2089 if test "x$enable_dri" != xno; then
2090         # cleanup the drivers var
2091         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2092         if test "x$DRI_DIRS" = x; then
2093             echo "        DRI drivers:     no"
2094         else
2095             echo "        DRI drivers:     $dri_dirs"
2096         fi
2097         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2098 fi
2099
2100 case "x$enable_glx$enable_xlib_glx" in
2101 xyesyes)
2102     echo "        GLX:             Xlib-based"
2103     ;;
2104 xyesno)
2105     echo "        GLX:             DRI-based"
2106     ;;
2107 *)
2108     echo "        GLX:             $enable_glx"
2109     ;;
2110 esac
2111
2112 echo ""
2113 echo "        GLU:             $enable_glu"
2114
2115 dnl EGL
2116 echo ""
2117 echo "        EGL:             $enable_egl"
2118 if test "$enable_egl" = yes; then
2119     echo "        EGL platforms:   $EGL_PLATFORMS"
2120
2121     egl_drivers=""
2122     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2123         egl_drivers="$egl_drivers builtin:egl_glx"
2124     fi
2125     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2126         egl_drivers="$egl_drivers builtin:egl_dri2"
2127     fi
2128
2129     if test "x$HAVE_ST_EGL" = xyes; then
2130         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2131         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2132     else
2133         echo "        EGL drivers:    $egl_drivers"
2134     fi
2135 fi
2136
2137 echo ""
2138 if test "x$MESA_LLVM" = x1; then
2139     echo "        llvm:            yes"
2140     echo "        llvm-config:     $LLVM_CONFIG"
2141     echo "        llvm-version:    $LLVM_VERSION"
2142 else
2143     echo "        llvm:            no"
2144 fi
2145
2146 echo ""
2147 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2148     echo "        Gallium:         yes"
2149     echo "        Gallium dirs:    $GALLIUM_DIRS"
2150     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2151     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2152     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2153     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2154 else
2155     echo "        Gallium:         no"
2156 fi
2157
2158
2159 dnl Libraries
2160 echo ""
2161 echo "        Shared libs:     $enable_shared"
2162 echo "        Static libs:     $enable_static"
2163 echo "        Shared-glapi:    $enable_shared_glapi"
2164
2165 dnl Compiler options
2166 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2167 cflags=`echo $CFLAGS $PIC_FLAGS | \
2168     $SED 's/^ *//;s/  */ /;s/ *$//'`
2169 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2170     $SED 's/^ *//;s/  */ /;s/ *$//'`
2171 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2172 echo ""
2173 echo "        CFLAGS:          $cflags"
2174 echo "        CXXFLAGS:        $cxxflags"
2175 echo "        Macros:          $defines"
2176 echo ""
2177 echo "        PYTHON2:         $PYTHON2"
2178
2179 echo ""
2180 echo "        Run '${MAKE-make}' to build Mesa"
2181 echo ""