configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.7.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AM_PROG_LIBTOOL
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=0.10.17
  50 GSTPB_REQ=0.10.17
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.11.5])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DEBUG
  69 AG_GST_ARG_PROFILING
  70 AG_GST_ARG_VALGRIND
  71 AG_GST_ARG_GCOV
  72
  73 AG_GST_ARG_EXAMPLES
  74
  75 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  76 AG_GST_ARG_WITH_PACKAGE_NAME
  77 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  78
  79 dnl these are all the gst plug-ins, compilable without additional libs
  80 dnl videofilter is at the top because others depend on it
  81 GST_PLUGINS_ALL="\
  82                 videofilter \
  83                 alpha \
  84                 apetag \
  85                 audiofx \
  86                 auparse \
  87                 autodetect \
  88                 avi \
  89                 cutter \
  90                 debug \
  91                 effectv \
  92                 equalizer \
  93                 id3demux \
  94                 icydemux \
  95                 flx \
  96                 goom \
  97                 goom2k1 \
  98                 law \
  99                 level \
 100                 matroska \
 101                 monoscope \
 102                 multifile \
 103                 multipart \
 104                 qtdemux \
 105                 rtp     \
 106                 rtsp    \
 107                 smpte   \
 108                 spectrum \
 109                 udp     \
 110                 videobox \
 111                 videocrop \
 112                 videomixer \
 113                 wavenc \
 114                 wavparse \
 115                 "
 116 AC_SUBST(GST_PLUGINS_ALL)
 117
 118 GST_PLUGINS_SELECTED=""
 119 AG_GST_ARG_WITH_PLUGINS
 120
 121 dnl disable gst plugins we might not be able to build on this
 122 dnl platform: udp and rtsp (ugly but minimally invasive)
 123 dnl FIXME: maybe move to sys
 124 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 125 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 126
 127 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 128   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/udp//`
 129   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/rtsp//`
 130 fi
 131
 132 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 133   WIN32_LIBS="-lws2_32"
 134   AC_SUBST(WIN32_LIBS)
 135 fi
 136
 137 AG_GST_ARG_ENABLE_EXTERNAL
 138
 139 AG_GST_ARG_ENABLE_EXPERIMENTAL
 140 USE_GST_V4L2=$BUILD_EXPERIMENTAL
 141 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 142         GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/monoscope//`
 143 fi
 144
 145 AC_SUBST(GST_PLUGINS_SELECTED)
 146
 147 dnl *** checks for platform ***
 148
 149 dnl * hardware/architecture *
 150
 151 dnl common/m4/gst-arch.m4
 152 dnl check CPU type
 153 AG_GST_ARCH
 154
 155 dnl Determine endianness
 156 AC_C_BIGENDIAN
 157
 158 dnl *** checks for programs ***
 159
 160 dnl find a compiler
 161 AC_PROG_CC
 162
 163 dnl determine c++ compiler
 164 AC_PROG_CXX
 165 dnl determine if c++ is available on this system
 166 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 167
 168 dnl determine c++ preprocessor
 169 dnl FIXME: do we need this ?
 170 AC_PROG_CXXCPP
 171
 172 AS_PROG_OBJC
 173
 174 dnl check if the compiler supports '-c' and '-o' options
 175 AM_PROG_CC_C_O
 176
 177 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 178 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 179
 180 dnl check for gconftool-2
 181 dnl this macro defines an am conditional, so it needs to be run always
 182 AM_GCONF_SOURCE_2
 183
 184 dnl check for documentation tools
 185 GTK_DOC_CHECK([1.3])
 186 AS_PATH_PYTHON([2.1])
 187 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 188
 189 dnl *** checks for libraries ***
 190
 191 dnl check for libm, for sin()
 192 AC_CHECK_LIBM
 193 AC_SUBST(LIBM)
 194
 195 dnl *** checks for header files ***
 196
 197 dnl check if we have ANSI C header files
 198 AC_HEADER_STDC
 199
 200 dnl used by ext/wavpack
 201 AX_CREATE_STDINT_H
 202
 203 dnl used in gst/rtp/gstasteriskh263.c
 204 AC_CHECK_HEADERS([netinet/in.h])
 205 AC_CHECK_HEADERS([winsock2.h])
 206 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 207
 208 dnl used in gst/udp
 209 AC_CHECK_HEADERS([sys/time.h])
 210
 211 dnl *** checks for types/defines ***
 212
 213 dnl Check for FIONREAD ioctl declaration.  This check is needed
 214 dnl for the UDP plugin to build on Solaris
 215 GST_CHECK_FIONREAD
 216
 217 dnl *** checks for structures ***
 218
 219 dnl *** checks for compiler characteristics ***
 220
 221 dnl FIXME: check if this is used; was used for floatcast.h in base
 222 dnl Check for fast float to int casting as defined in C99
 223 AC_C99_FUNC_LRINT
 224 AC_C99_FUNC_LRINTF
 225
 226 dnl *** checks for library functions ***
 227
 228 LIBS_SAVE=$LIBS
 229 LIBS="$LIBS $LIBM"
 230 AC_CHECK_FUNCS(rint)
 231 LIBS=$LIBS_SAVE
 232
 233 dnl Check for mmap (needed by electricfence plugin)
 234 AC_FUNC_MMAP
 235 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 236
 237 dnl *** checks for dependency libraries ***
 238
 239 dnl GLib is required
 240 AG_GST_GLIB_CHECK([2.6])
 241
 242 dnl liboil is required
 243 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 244 if test "x${HAVE_LIBOIL}" != xyes ; then
 245   AC_ERROR([liboil-0.3.8 or later is required])
 246 fi
 247
 248 dnl checks for gstreamer
 249 dnl uninstalled is selected preferentially -- see pkg-config(1)
 250 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 251 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 252 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 253 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 254 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 255 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ])
 256
 257 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 258 if test -z $GST_TOOLS_DIR; then
 259   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 260 fi
 261 AC_SUBST(GST_TOOLS_DIR)
 262
 263 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 264 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 265
 266 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 267
 268 dnl Check for documentation xrefs
 269 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 270 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 271 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 272 AC_SUBST(GLIB_PREFIX)
 273 AC_SUBST(GST_PREFIX)
 274 AC_SUBST(GSTPB_PREFIX)
 275
 276 dnl GTK is optional and used in examples
 277 HAVE_GTK=NO
 278 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 279 if test "x$HAVE_GTK_22" = "xyes"; then
 280   HAVE_GTK=yes
 281   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 282   AC_SUBST(GTK_VERSION)
 283   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 284   AC_SUBST(GTK_BASE_DIR)
 285   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 286   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 287   AC_SUBST(GTK_BASE_DIR)
 288 else
 289   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 290 fi
 291 if test "x$HAVE_GTK_20" = "xyes"; then
 292   HAVE_GTK=yes
 293 fi
 294 GTK_CFLAGS=$GTK2_CFLAGS
 295 GTK_LIBS=$GTK2_LIBS
 296 AC_SUBST(GTK_LIBS)
 297 AC_SUBST(GTK_CFLAGS)
 298 AC_SUBST(HAVE_GTK)
 299 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 300
 301 dnl should we install schemas ?
 302 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 303 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 304   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 305   if test x$GCONFTOOL = xno; then
 306     AC_MSG_WARN(Not installing GConf schemas)
 307     HAVE_GCONFTOOL="no"
 308   else
 309     HAVE_GCONFTOOL="yes"
 310   fi
 311   AC_SUBST(HAVE_GCONFTOOL)
 312 ])
 313
 314 dnl *** set variables based on configure arguments ***
 315
 316 dnl set license and copyright notice
 317 GST_LICENSE="LGPL"
 318 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 319 AC_SUBST(GST_LICENSE)
 320
 321 dnl set location of plugin directory
 322 AG_GST_SET_PLUGINDIR
 323
 324 dnl define an ERROR_CFLAGS Makefile variable
 325 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 326
 327 dnl define correct level for debugging messages
 328 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 329
 330 dnl used in examples
 331 AG_GST_DEFAULT_ELEMENTS
 332
 333 dnl Check for Yacc and Lex for the goom plugin
 334 AG_GST_BISON_CHECK
 335 AG_GST_FLEX_CHECK
 336 AM_PROG_AS
 337
 338 dnl *** sys plug-ins ***
 339
 340 echo
 341 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 342 echo
 343
 344 dnl DirectDraw
 345 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 346 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 347   HAVE_DIRECTDRAW="no"
 348   save_CFLAGS="$CFLAGS"
 349   save_LDFLAGS="$LDFLAGS"
 350   save_LIBS="$LIBS"
 351   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 352   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 353   LIBS="$LIBS -lddraw -lgdi32"
 354   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 355   AC_LINK_IFELSE([
 356 #include <windows.h>
 357 #include <ddraw.h>
 358
 359 int main ()
 360 {
 361   GetStockObject(0);
 362   DirectDrawCreate(NULL, NULL, NULL);
 363
 364   return 0;
 365 }
 366 ],
 367     [HAVE_DIRECTDRAW="yes"],
 368     [HAVE_DIRECTDRAW="no"])
 369   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 370   CFLAGS=$save_CFLAGS
 371   LDFLAGS=$save_LDFLAGS
 372   LIBS=$save_LIBS
 373
 374   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 375     dnl this is much more than we want
 376     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 377     AC_SUBST(DIRECTDRAW_CFLAGS)
 378     AC_SUBST(DIRECTDRAW_LDFLAGS)
 379     AC_SUBST(DIRECTDRAW_LIBS)
 380   fi
 381   AC_SUBST(HAVE_DIRECTDRAW)
 382 ])
 383
 384 dnl DirectSound
 385 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 386 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 387   HAVE_DIRECTSOUND="no"
 388   save_CFLAGS="$CFLAGS"
 389   save_LDFLAGS="$LDFLAGS"
 390   save_LIBS="$LIBS"
 391   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 392   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 393   LIBS="$LIBS -ldsound -ldxerr9"
 394   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 395   AC_LINK_IFELSE([
 396 #include <windows.h>
 397 #include <dxerr9.h>
 398 #include <dsound.h>
 399
 400 int main ()
 401 {
 402   DXGetErrorString9 (0);
 403   DirectSoundCreate(NULL, NULL, NULL);
 404
 405   return 0;
 406 }
 407 ],
 408     [HAVE_DIRECTSOUND="yes"],
 409     [HAVE_DIRECTSOUND="no"])
 410   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 411   CFLAGS=$save_CFLAGS
 412   LDFLAGS=$save_LDFLAGS
 413   LIBS=$save_LIBS
 414
 415   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 416     dnl this is much more than we want
 417     DIRECTSOUND_LIBS="-ldsound -ldxerr9"
 418     AC_SUBST(DIRECTSOUND_CFLAGS)
 419     AC_SUBST(DIRECTSOUND_LDFLAGS)
 420     AC_SUBST(DIRECTSOUND_LIBS)
 421   fi
 422   AC_SUBST(HAVE_DIRECTSOUND)
 423 ])
 424
 425 dnl *** OSS audio *** (Linux, *BSD)
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 427 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 428  HAVE_OSS="yes"
 429 dnl Linux and newer BSD versions :
 430  AC_CHECK_HEADER(sys/soundcard.h, [
 431    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 432    ] , [
 433 dnl Some old BSD versions and also newer OpenBSD versions :
 434    AC_CHECK_HEADER(soundcard.h, [
 435      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 436      ], [
 437   dnl Some old BSD versions :
 438      AC_CHECK_HEADER(machine/soundcard.h, [
 439        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 440          [Define if OSS includes are in /machine/])
 441        ], [
 442        HAVE_OSS="no"
 443      ])
 444    ])
 445  ])
 446 ])
 447
 448 dnl *** Sun Audio ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 450 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 451   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 452 ])
 453
 454 dnl *** OSX Audio ***
 455 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 456 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 457   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 458 ])
 459
 460 dnl *** OS X video ***
 461 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 462 HAVE_OSX_VIDEO="no"
 463 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 464   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 465 ])
 466 dnl in case header OpenGL/gl.h is found on other platforms
 467 case "$host" in
 468   *-*darwin*)
 469     dnl do nothing
 470     ;;
 471   *)
 472     HAVE_OSX_VIDEO="no"
 473     ;;
 474 esac
 475
 476
 477 dnl *** Video 4 Linux 2 ***
 478 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 479 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 480 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 481 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 482   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 483   AC_TRY_COMPILE([
 484 #include <sys/types.h>
 485 #ifdef __sun /* Solaris */
 486 #include <sys/types.h>
 487 #include <sys/videodev2.h>
 488 #else /* Linux */
 489 #include <linux/types.h>
 490 #define _LINUX_TIME_H
 491 #define __user
 492 #include <linux/videodev2.h>
 493 #endif
 494 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 495 #error too early v4l2 version or no v4l2 at all
 496 #endif
 497     ], [
 498 return 0;
 499     ], [
 500       HAVE_GST_V4L2="yes"
 501       AC_MSG_RESULT(yes)
 502     ], [
 503       HAVE_GST_V4L2="no"
 504       AC_MSG_RESULT(no)
 505
 506       HAVE_VIDEODEV=no
 507       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 508       [
 509         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 510       ])
 511
 512       if test "x$HAVE_VIDEODEV" = "xyes"; then
 513         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 514         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 515       else
 516         AC_MSG_WARN([video4linux2 was not found])
 517       fi
 518     ])
 519
 520   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 521     dnl check for missing v4l2_buffer declaration (see #135919)
 522     MISSING_DECL=0
 523     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 524     AC_TRY_COMPILE([
 525 #include <sys/types.h>
 526 #ifdef __sun /* Solaris */
 527 #include <sys/types.h>
 528 #include <sys/videodev2.h>
 529 #else /* Linux */
 530 #include <linux/types.h>
 531 #define _LINUX_TIME_H
 532 #define __user
 533 #include <linux/videodev2.h>
 534 #endif
 535     ],[
 536 struct v4l2_buffer buf;
 537 buf.index = 0;
 538 return 0;
 539     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 540     if [ test x$MISSING_DECL = x1 ]; then
 541       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 542     fi
 543
 544     dnl check for XOverlay libraries
 545     AG_GST_CHECK_XV
 546   fi
 547 ])
 548
 549 dnl Check for X11
 550 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 551 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 552                   [ximagesrc], [
 553   AC_PATH_XTRA
 554
 555   dnl now try to find the HEADER
 556   ac_cflags_save="$CFLAGS"
 557   ac_cppflags_save="$CPPFLAGS"
 558   CFLAGS="$CFLAGS $X_CFLAGS"
 559   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 560   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 561
 562   if test "x$HAVE_X" = "xno"
 563   then
 564     AC_MSG_NOTICE([cannot find X11 development files])
 565   else
 566     dnl this is much more than we want
 567     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 568     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 569     dnl it does not add the libs; therefore we add them here
 570     X_LIBS="$X_LIBS -lX11"
 571     AC_SUBST(X_CFLAGS)
 572     AC_SUBST(X_LIBS)
 573
 574     dnl check for Xfixes
 575     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 576     if test "x$HAVE_XFIXES" = "xyes"
 577     then
 578         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 579     fi
 580     AC_SUBST(XFIXES_LIBS)
 581     AC_SUBST(XFIXES_CFLAGS)
 582
 583     dnl check for Xdamage
 584     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 585     if test "x$HAVE_XDAMAGE" = "xyes"
 586     then
 587         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 588     fi
 589     AC_SUBST(XDAMAGE_LIBS)
 590     AC_SUBST(XDAMAGE_CFLAGS)
 591   fi
 592   AC_SUBST(HAVE_X)
 593   CFLAGS="$ac_cflags_save"
 594   CPPFLAGS="$ac_cppflags_save"
 595 ])
 596
 597 dnl FIXME: this should be rolled into the test above, it's just an additional
 598 dnl feature of the ximagesrc plug-in
 599 dnl This is the same as in gst-plugins-base
 600 dnl check for X Shm
 601 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 602 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 603   if test x$HAVE_X = xyes; then
 604     AC_CHECK_LIB(Xext, XShmAttach,
 605                  HAVE_XSHM="yes", HAVE_XSHM="no",
 606                  $X_LIBS)
 607     if test "x$HAVE_XSHM" = "xyes"; then
 608       XSHM_LIBS="-lXext"
 609     else
 610       dnl On AIX, it is in XextSam instead, but we still need -lXext
 611       AC_CHECK_LIB(XextSam, XShmAttach,
 612                    HAVE_XSHM="yes", HAVE_XSHM="no",
 613                    $X_LIBS)
 614       if test "x$HAVE_XSHM" = "xyes"; then
 615         XSHM_LIBS="-lXext -lXextSam"
 616       fi
 617     fi
 618   fi
 619 ], ,[
 620   AC_SUBST(HAVE_XSHM)
 621   AC_SUBST(XSHM_LIBS)
 622 ])
 623
 624 dnl for V4L2, we also need to know if we have XVIDEO
 625 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 626 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 627                   [], [
 628   AG_GST_CHECK_XV
 629 ])
 630
 631 dnl *** ext plug-ins ***
 632 dnl keep this list sorted alphabetically !
 633
 634 if test "x$BUILD_EXTERNAL" = "xyes"; then
 635
 636 echo
 637 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 638 echo
 639
 640 dnl *** aalib ***
 641 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 642 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 643   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 644   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 645 ])
 646
 647 dnl *** annodex ***
 648 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 649 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 650   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 651 ])
 652
 653 dnl *** cairo ***
 654 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 655 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 656   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 657 ])
 658
 659 dnl *** cdio ***
 660 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 661 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 662   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.71)
 663 ])
 664
 665 dnl **** ESound ****
 666 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 667 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 668   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 669   if test $HAVE_ESD = no
 670   then
 671     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 672     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 673   fi
 674 ])
 675
 676 dnl *** FLAC ***
 677 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 678 AC_TRY_COMPILE([#include <FLAC/export.h>], [
 679   #if FLAC_API_VERSION_CURRENT < 8
 680   #error "legacy flac API"
 681   #endif
 682   ], [ legacy_flac=no ], [ legacy_flac=yes ], [ legacy_flac=no ])
 683
 684 if test "x$legacy_flac" = "xyes"; then
 685 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 686   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 687   dnl API change in FLAC 1.1.1, so require that...
 688   dnl (this check will also fail with FLAC 1.1.3 which changed API again)
 689   if test x$HAVE_FLAC = xyes; then
 690     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 691                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 692 #include <FLAC/seekable_stream_encoder.h>
 693                   ])
 694   fi
 695   AC_SUBST(FLAC_LIBS)
 696 ])
 697 else
 698 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 699   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 700   dnl API change in FLAC 1.1.3, so require that...
 701   if test x$HAVE_FLAC = xyes; then
 702     AC_CHECK_DECL(FLAC__STREAM_ENCODER_TELL_STATUS_ERROR,
 703                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 704 #include <FLAC/stream_encoder.h>
 705                   ])
 706   fi
 707   AC_SUBST(FLAC_LIBS)
 708 ])
 709 fi
 710
 711 dnl *** GConf ***
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 713 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 714   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 715 ])
 716
 717 dnl *** GDK pixbuf ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 719 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 720   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 721 ])
 722
 723 dnl *** HAL ***
 724 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 725 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 726   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 727 ])
 728
 729 dnl *** jpeg ***
 730 dnl FIXME: we could use header checks here as well IMO
 731 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 732 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 733   AC_ARG_WITH(jpeg-mmx,
 734     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 735   OLD_LIBS="$LIBS"
 736   if test x$with_jpeg_mmx != x; then
 737     LIBS="$LIBS -L$with_jpeg_mmx"
 738   fi
 739   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 740   JPEG_LIBS="$LIBS -ljpeg-mmx"
 741   LIBS="$OLD_LIBS"
 742   if test x$HAVE_JPEG != xyes; then
 743     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 744     JPEG_LIBS="-ljpeg"
 745   fi
 746   AC_SUBST(JPEG_LIBS)
 747 ])
 748
 749 dnl *** ladspa ***
 750 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 751 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 752   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 753 ], disabled)
 754
 755 dnl *** libcaca ***
 756 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 757 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 758   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 759   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 760   if test "x$HAVE_LIBCACA" != "xyes"; then
 761     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 762     dnl see if it compilation works too, might not if we are cross-compiling
 763     if test "x$HAVE_LIBCACA" = "xyes"; then
 764       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 765                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 766     fi
 767   fi
 768 ])
 769
 770 dnl *** libdv ***
 771 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 772 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 773   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 774 ])
 775
 776 dnl *** libpng ***
 777 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 778 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 779   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 780 ])
 781
 782 dnl *** dv1394 ***
 783 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 784 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 785   dnl first test for libraw1394 >= 1.2.1
 786   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 787   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 788   dnl now see how far we got
 789   if test x$HAVE_RAW1394 = xyes && \
 790      test x$HAVE_LIBIEC61883 = xyes; then
 791        AG_GST_CHECK_LIBHEADER(AVC1394,
 792         avc1394, avc1394_send_command, $RAW1394_LIBS,
 793         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 794        AG_GST_CHECK_LIBHEADER(ROM1394,
 795         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 796         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 797        if test x$HAVE_AVC1394 = xyes && \
 798           test x$HAVE_AVC1394 = xyes && \
 799           test x$HAVE_ROM1394 = xyes; then
 800           HAVE_DV1394=yes
 801           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 802           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 803           AC_SUBST(DV1394_CFLAGS)
 804           AC_SUBST(DV1394_LIBS)
 805         fi
 806   else
 807        if test x$HAVE_RAW1394 = xno; then
 808           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 809           AG_GST_CHECK_LIBHEADER(AVC1394,
 810            avc1394, avc1394_send_command, $RAW1394_LIBS,
 811            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 812           AG_GST_CHECK_LIBHEADER(ROM1394,
 813            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 814            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 815           if test x$HAVE_RAW1394 = xyes && \
 816              test x$HAVE_AVC1394 = xyes && \
 817              test x$HAVE_ROM1394 = xyes; then
 818              HAVE_DV1394=yes
 819              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 820              DV1394_CFLAGS="$RAW1394_CFLAGS"
 821              if test x$HAVE_LIBIEC61883 = xyes; then
 822                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 823                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 824              fi
 825              AC_SUBST(DV1394_CFLAGS)
 826              AC_SUBST(DV1394_LIBS)
 827            fi
 828          fi
 829   fi
 830 ])
 831
 832 dnl *** shout2 ***
 833 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 834 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 835   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 836   if test $HAVE_SHOUT2 = no
 837   then
 838     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 839     AC_SUBST(SHOUT2_CFLAGS)
 840     AC_SUBST(SHOUT2_LIBS)
 841   fi
 842 ])
 843
 844 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 845 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 846 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 847 dnl   speex_jitter.h is 1.1.x only
 848 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 849 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 850   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 851   if test $HAVE_SPEEX = no
 852   then
 853     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 854       AC_CHECK_HEADER(speex/speex_jitter.h, [
 855         dnl speex 1.1.x :
 856         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 857           dnl speex 1.1.5 or + :
 858           HAVE_SPEEX="yes"
 859           SPEEX_LIBS="-lspeex"
 860           AC_SUBST(SPEEX_CFLAGS)
 861           AC_SUBST(SPEEX_LIBS)
 862         ],[
 863           HAVE_SPEEX="no"
 864         ])
 865       ],[
 866         dnl speex 1.0.x :
 867           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 868             dnl speex 1.0.4
 869             HAVE_SPEEX="yes"
 870             SPEEX_LIBS="-lspeex"
 871             AC_SUBST(SPEEX_CFLAGS)
 872             AC_SUBST(SPEEX_LIBS)
 873
 874             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 875               [defined if speex 1.0.x API detected])
 876         ],[
 877             HAVE_SPEEX="no"
 878             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 879         ], [
 880 #include <speex/speex.h>
 881         ])
 882       ])
 883     ])
 884   fi
 885 ])
 886
 887 dnl *** taglib ***
 888 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 889 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 890   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 891   if test "x$HAVE_CXX" != "xyes"; then
 892     USE_TAGLIB=false
 893     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 894   fi
 895 ])
 896
 897 dnl *** wavpack ***
 898 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 899 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 900   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 901     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 902       HAVE_WAVPACK=yes
 903       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 904     ],[
 905       HAVE_WAVPACK=no
 906       AC_MSG_RESULT(no)
 907     ])
 908   ])
 909   AC_SUBST(WAVPACK_CFLAGS)
 910   AC_SUBST(WAVPACK_LIBS)
 911 ])
 912
 913 dnl *** qtdemux & id3demux prefer to have zlib ***
 914 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 915 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux],, [
 916   AG_GST_CHECK_LIBHEADER(ZLIB,
 917     z, uncompress,, zlib.h, [
 918     HAVE_ZLIB="yes"
 919     ZLIB_LIBS="-lz"
 920     AC_SUBST(ZLIB_LIBS)
 921   ])
 922 ])
 923
 924 else
 925
 926 dnl not building plugins with external dependencies,
 927 dnl but we still need to set the conditionals
 928 AM_CONDITIONAL(USE_GCONFTOOL, false)
 929 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 930 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 931 AM_CONDITIONAL(USE_OSS, false)
 932 AM_CONDITIONAL(USE_SUNAUDIO, false)
 933 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 934 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 935 AM_CONDITIONAL(USE_X, false)
 936 AM_CONDITIONAL(USE_XSHM, false)
 937 AM_CONDITIONAL(USE_AALIB, false)
 938 AM_CONDITIONAL(USE_ANNODEX, false)
 939 AM_CONDITIONAL(USE_CAIRO, false)
 940 AM_CONDITIONAL(USE_CDIO, false)
 941 AM_CONDITIONAL(USE_ESD, false)
 942 AM_CONDITIONAL(USE_FLAC, false)
 943 AM_CONDITIONAL(USE_GCONF, false)
 944 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 945 AM_CONDITIONAL(USE_HAL, false)
 946 AM_CONDITIONAL(USE_JPEG, false)
 947 AM_CONDITIONAL(USE_LADSPA, false)
 948 AM_CONDITIONAL(USE_LIBCACA, false)
 949 AM_CONDITIONAL(USE_LIBDV, false)
 950 AM_CONDITIONAL(USE_LIBPNG, false)
 951 AM_CONDITIONAL(USE_DV1394, false)
 952 AM_CONDITIONAL(USE_SHOUT2, false)
 953 AM_CONDITIONAL(USE_SPEEX, false)
 954 AM_CONDITIONAL(USE_TAGLIB, false)
 955 AM_CONDITIONAL(USE_WAVPACK, false)
 956 AM_CONDITIONAL(USE_ZLIB, false)
 957
 958 fi dnl of EXT plugins
 959
 960 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 961
 962 dnl Overview:
 963 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 964 dnl GST_*:              flags shared by all built objects
 965 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 966 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 967 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 968 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 969
 970 dnl GST_OPTION_CFLAGS
 971 if test "x$USE_DEBUG" = xyes; then
 972    PROFILE_CFLAGS="-g"
 973 fi
 974 AC_SUBST(PROFILE_CFLAGS)
 975
 976 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 977   dnl Define _only_ during CVS (not pre-releases or releases)
 978   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 979 else
 980   DEPRECATED_CFLAGS=""
 981 fi
 982 AC_SUBST(DEPRECATED_CFLAGS)
 983
 984 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 985 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 986 AC_SUBST(GST_OPTION_CFLAGS)
 987
 988 dnl our libraries need to be versioned correctly
 989 AC_SUBST(GST_LT_LDFLAGS)
 990
 991 dnl FIXME: do we want to rename to GST_ALL_* ?
 992 dnl prefer internal headers to already installed ones
 993 dnl also add builddir include for enumtypes and marshal
 994 dnl add ERROR_CFLAGS, but overridable
 995 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 996 AC_SUBST(GST_CFLAGS)
 997 AC_SUBST(GST_LIBS)
 998
 999 dnl LDFLAGS really should only contain flags, not libs - they get added before
1000 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1001 GST_ALL_LDFLAGS="-no-undefined"
1002 AC_SUBST(GST_ALL_LDFLAGS)
1003
1004 dnl this really should only contain flags, not libs - they get added before
1005 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1006 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1007 AC_SUBST(GST_PLUGIN_LDFLAGS)
1008
1009 dnl *** output files ***
1010
1011 dnl keep this alphabetic per directory, please
1012 AC_CONFIG_FILES(
1013 Makefile
1014 gst/Makefile
1015 gst/alpha/Makefile
1016 gst/apetag/Makefile
1017 gst/audiofx/Makefile
1018 gst/auparse/Makefile
1019 gst/autodetect/Makefile
1020 gst/avi/Makefile
1021 gst/cutter/Makefile
1022 gst/debug/Makefile
1023 gst/effectv/Makefile
1024 gst/equalizer/Makefile
1025 gst/id3demux/Makefile
1026 gst/icydemux/Makefile
1027 gst/goom/Makefile
1028 gst/goom2k1/Makefile
1029 gst/law/Makefile
1030 gst/level/Makefile
1031 gst/matroska/Makefile
1032 gst/monoscope/Makefile
1033 gst/multifile/Makefile
1034 gst/multipart/Makefile
1035 gst/qtdemux/Makefile
1036 gst/rtp/Makefile
1037 gst/rtsp/Makefile
1038 gst/smpte/Makefile
1039 gst/spectrum/Makefile
1040 gst/udp/Makefile
1041 gst/videobox/Makefile
1042 gst/videocrop/Makefile
1043 gst/videofilter/Makefile
1044 gst/videomixer/Makefile
1045 gst/wavenc/Makefile
1046 gst/wavparse/Makefile
1047 gst/flx/Makefile
1048 ext/jpeg/Makefile
1049 ext/Makefile
1050 ext/aalib/Makefile
1051 ext/annodex/Makefile
1052 ext/cairo/Makefile
1053 ext/cdio/Makefile
1054 ext/dv/Makefile
1055 ext/esd/Makefile
1056 ext/flac/Makefile
1057 ext/gconf/Makefile
1058 ext/gdk_pixbuf/Makefile
1059 ext/hal/Makefile
1060 ext/ladspa/Makefile
1061 ext/libcaca/Makefile
1062 ext/libpng/Makefile
1063 ext/raw1394/Makefile
1064 ext/shout2/Makefile
1065 ext/speex/Makefile
1066 ext/taglib/Makefile
1067 ext/wavpack/Makefile
1068 sys/Makefile
1069 sys/directdraw/Makefile
1070 sys/directsound/Makefile
1071 sys/oss/Makefile
1072 sys/sunaudio/Makefile
1073 sys/osxaudio/Makefile
1074 sys/osxvideo/Makefile
1075 sys/v4l2/Makefile
1076 sys/waveform/Makefile
1077 sys/ximage/Makefile
1078 po/Makefile.in
1079 tests/Makefile
1080 tests/check/Makefile
1081 tests/examples/Makefile
1082 tests/examples/equalizer/Makefile
1083 tests/examples/level/Makefile
1084 tests/examples/rtp/Makefile
1085 tests/examples/spectrum/Makefile
1086 tests/files/Makefile
1087 tests/icles/Makefile
1088 gconf/Makefile
1089 gconf/gstreamer.schemas
1090 common/Makefile
1091 common/m4/Makefile
1092 m4/Makefile
1093 docs/Makefile
1094 docs/plugins/Makefile
1095 docs/version.entities
1096 win32/common/config.h
1097 pkgconfig/Makefile
1098 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1099 gst-plugins-good.spec
1100 )
1101 AC_OUTPUT
1102
1103 AG_GST_OUTPUT_PLUGINS