configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.28.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.32
  58 GSTPB_REQ=0.10.32
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for gconftool-2
 134 dnl this macro defines an am conditional, so it needs to be run always
 135 AM_GCONF_SOURCE_2
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl check for libm, for sin()
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used by ext/wavpack
 154 AX_CREATE_STDINT_H
 155
 156 dnl used in gst/rtp/gstasteriskh263.c
 157 AC_CHECK_HEADERS([netinet/in.h])
 158 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 159 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 160
 161 dnl used in gst/udp
 162 AC_CHECK_HEADERS([sys/time.h])
 163
 164 dnl *** checks for types/defines ***
 165
 166 dnl Check for FIONREAD ioctl declaration.  This check is needed
 167 dnl for the UDP plugin to build on Solaris
 168 GST_CHECK_FIONREAD
 169
 170 dnl *** checks for structures ***
 171
 172 dnl *** checks for compiler characteristics ***
 173
 174 dnl check if we have GCC inline-asm
 175 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 176 if test x$HAVE_GCC_ASM = xyes ; then
 177   AC_DEFINE(HAVE_GCC_ASM, 1,
 178     [Define if compiler supports gcc inline assembly])
 179 fi
 180 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 181
 182 dnl *** checks for library functions ***
 183
 184 LIBS_SAVE=$LIBS
 185 LIBS="$LIBS $LIBM"
 186 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 187 LIBS=$LIBS_SAVE
 188
 189 dnl Check whether isinf() is defined by math.h
 190 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 191     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 192 if test "$ac_cv_have_isinf" = "yes"
 193 then
 194     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 195 fi
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198 AC_FUNC_MMAP
 199 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 200
 201 dnl Check for mmap (needed by electricfence plugin)
 202
 203 AC_CHECK_TYPE([struct ip_mreqn], [
 204               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 205               [#include <netinet/in.h>])
 206
 207 dnl *** checks for dependency libraries ***
 208
 209 dnl GLib is required
 210 AG_GST_GLIB_CHECK([2.20])
 211
 212 dnl Orc
 213 ORC_CHECK([0.4.11])
 214
 215 dnl checks for gstreamer
 216 dnl uninstalled is selected preferentially -- see pkg-config(1)
 217 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 222 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 223
 224 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 225 if test -z $GST_TOOLS_DIR; then
 226   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 227 fi
 228 AC_SUBST(GST_TOOLS_DIR)
 229
 230 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 231 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 232
 233 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 234
 235 dnl Check for documentation xrefs
 236 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 237 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 238 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 239 AC_SUBST(GLIB_PREFIX)
 240 AC_SUBST(GST_PREFIX)
 241 AC_SUBST(GSTPB_PREFIX)
 242
 243 dnl GTK is optional and used in examples
 244 HAVE_GTK=no
 245 GTK2_REQ=2.14.0
 246 GTK3_REQ=2.91.3
 247 if test "x$BUILD_EXAMPLES" = "xyes"; then
 248   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 249   AC_ARG_WITH([gtk],
 250     AC_HELP_STRING([--with-gtk=3.0|2.0],
 251                    [which gtk+ version to compile against (default: 2.0)]),
 252     [case "$with_gtk" in
 253         2.0) GTK_REQ=$GTK2_REQ ;;
 254         3.0) GTK_REQ=$GTK3_REQ ;;
 255         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 256     esac],
 257     [with_gtk=2.0
 258      GTK_REQ=$GTK2_REQ])
 259   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 260   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 261   dnl some examples need gtk+-x11
 262   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 263   AC_SUBST(GTK_LIBS)
 264   AC_SUBST(GTK_CFLAGS)
 265 fi
 266 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 267 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 268
 269 dnl should we install schemas ?
 270 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 271 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 272   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 273   if test x$GCONFTOOL = xno; then
 274     AC_MSG_WARN(Not installing GConf schemas)
 275     HAVE_GCONFTOOL="no"
 276   else
 277     HAVE_GCONFTOOL="yes"
 278   fi
 279   AC_SUBST(HAVE_GCONFTOOL)
 280 ])
 281
 282 dnl *** set variables based on configure arguments ***
 283
 284 dnl set license and copyright notice
 285 GST_LICENSE="LGPL"
 286 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 287 AC_SUBST(GST_LICENSE)
 288
 289 dnl set location of plugin directory
 290 AG_GST_SET_PLUGINDIR
 291
 292 dnl set release date/time
 293 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 294   ["${srcdir}/gst-plugins-good.doap"],
 295   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 296
 297 dnl define an ERROR_CFLAGS Makefile variable
 298 dnl -Wundef: too many broken headers
 299 dnl -Waggregate-return: causes problems with ObjC code like in osxvideosink
 300 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 301         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 302         -Wwrite-strings -Wold-style-definition
 303         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 304         -Wnested-externs ])
 305
 306 dnl define an ERROR_CXXFLAGS Makefile variable
 307 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 308         -Wmissing-declarations -Wredundant-decls
 309         -Wwrite-strings
 310         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 311
 312 dnl define correct level for debugging messages
 313 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 314
 315 dnl used in examples
 316 AG_GST_DEFAULT_ELEMENTS
 317
 318 dnl *** plug-ins to include ***
 319
 320 dnl these are all the gst plug-ins, compilable without additional libs
 321 dnl videofilter is at the top because others depend on it
 322 AG_GST_CHECK_PLUGIN(videofilter)
 323 AG_GST_CHECK_PLUGIN(alpha)
 324 AG_GST_CHECK_PLUGIN(apetag)
 325 AG_GST_CHECK_PLUGIN(audiofx)
 326 AG_GST_CHECK_PLUGIN(auparse)
 327 AG_GST_CHECK_PLUGIN(autodetect)
 328 AG_GST_CHECK_PLUGIN(avi)
 329 AG_GST_CHECK_PLUGIN(cutter)
 330 AG_GST_CHECK_PLUGIN(debugutils)
 331 AG_GST_CHECK_PLUGIN(deinterlace)
 332 AG_GST_CHECK_PLUGIN(effectv)
 333 AG_GST_CHECK_PLUGIN(equalizer)
 334 AG_GST_CHECK_PLUGIN(flv)
 335 AG_GST_CHECK_PLUGIN(id3demux)
 336 AG_GST_CHECK_PLUGIN(icydemux)
 337 AG_GST_CHECK_PLUGIN(interleave)
 338 AG_GST_CHECK_PLUGIN(flx)
 339 AG_GST_CHECK_PLUGIN(goom)
 340 AG_GST_CHECK_PLUGIN(goom2k1)
 341 AG_GST_CHECK_PLUGIN(imagefreeze)
 342 AG_GST_CHECK_PLUGIN(law)
 343 AG_GST_CHECK_PLUGIN(level)
 344 AG_GST_CHECK_PLUGIN(matroska)
 345 AG_GST_CHECK_PLUGIN(monoscope)
 346 AG_GST_CHECK_PLUGIN(multifile)
 347 AG_GST_CHECK_PLUGIN(multipart)
 348 AG_GST_CHECK_PLUGIN(qtdemux)
 349 AG_GST_CHECK_PLUGIN(replaygain)
 350 AG_GST_CHECK_PLUGIN(rtp)
 351 AG_GST_CHECK_PLUGIN(rtpmanager)
 352 AG_GST_CHECK_PLUGIN(rtsp)
 353 AG_GST_CHECK_PLUGIN(shapewipe)
 354 AG_GST_CHECK_PLUGIN(smpte)
 355 AG_GST_CHECK_PLUGIN(spectrum)
 356 AG_GST_CHECK_PLUGIN(udp)
 357 AG_GST_CHECK_PLUGIN(videobox)
 358 AG_GST_CHECK_PLUGIN(videocrop)
 359 AG_GST_CHECK_PLUGIN(videomixer)
 360 AG_GST_CHECK_PLUGIN(wavenc)
 361 AG_GST_CHECK_PLUGIN(wavparse)
 362 AG_GST_CHECK_PLUGIN(y4m)
 363
 364 dnl *** checks for socket and nsl libraries ***
 365 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 366
 367 dnl disable gst plugins we might not be able to build on this
 368 dnl platform: udp and rtsp (ugly but minimally invasive)
 369 dnl FIXME: maybe move to sys
 370 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 371 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 372
 373 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 374   AG_GST_DISABLE_PLUGIN(udp)
 375   AG_GST_DISABLE_PLUGIN(rtsp)
 376 fi
 377
 378 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 379   WIN32_LIBS="-lws2_32"
 380   AC_SUBST(WIN32_LIBS)
 381 fi
 382
 383 dnl disable experimental plug-ins
 384 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 385   AG_GST_DISABLE_PLUGIN(monoscope)
 386 fi
 387
 388 dnl *** sys plug-ins ***
 389
 390 echo
 391 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 392 echo
 393
 394 dnl DirectSound
 395 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 396 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 397   HAVE_DIRECTSOUND="no"
 398   save_CFLAGS="$CFLAGS"
 399   save_LDFLAGS="$LDFLAGS"
 400   save_LIBS="$LIBS"
 401   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 402   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 403   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 404   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 405   AC_LINK_IFELSE([
 406 #include <windows.h>
 407 #include <dxerr9.h>
 408 #include <dsound.h>
 409
 410 int main ()
 411 {
 412   DXGetErrorString9 (0);
 413   DirectSoundCreate(NULL, NULL, NULL);
 414
 415   return 0;
 416 }
 417 ],
 418     [HAVE_DIRECTSOUND="yes"],
 419     [HAVE_DIRECTSOUND="no"])
 420   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 421   CFLAGS=$save_CFLAGS
 422   LDFLAGS=$save_LDFLAGS
 423   LIBS=$save_LIBS
 424
 425   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 426     dnl this is much more than we want
 427     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 428     AC_SUBST(DIRECTSOUND_CFLAGS)
 429     AC_SUBST(DIRECTSOUND_LDFLAGS)
 430     AC_SUBST(DIRECTSOUND_LIBS)
 431   fi
 432   AC_SUBST(HAVE_DIRECTSOUND)
 433 ])
 434
 435 dnl *** OSS audio *** (Linux, *BSD)
 436 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 437 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 438  HAVE_OSS="yes"
 439 dnl Linux and newer BSD versions :
 440  AC_CHECK_HEADER(sys/soundcard.h, [
 441    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 442    ] , [
 443 dnl Some old BSD versions and also newer OpenBSD versions :
 444    AC_CHECK_HEADER(soundcard.h, [
 445      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 446      ], [
 447   dnl Some old BSD versions :
 448      AC_CHECK_HEADER(machine/soundcard.h, [
 449        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 450          [Define if OSS includes are in /machine/])
 451        ], [
 452        HAVE_OSS="no"
 453      ])
 454    ])
 455  ])
 456 ])
 457
 458 dnl *** oss4 ***
 459 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 460 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 461   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 462   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 463       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 464       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 465 ])
 466
 467 dnl *** Sun Audio ***
 468 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 469 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 470   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 471 ])
 472
 473 dnl *** OSX Audio ***
 474 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 475 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 476   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 477 ])
 478
 479 dnl *** OS X video ***
 480 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 481 HAVE_OSX_VIDEO="no"
 482 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 483   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 484 ])
 485 dnl in case header OpenGL/gl.h is found on other platforms
 486 case "$host" in
 487   *-*darwin*)
 488     dnl do nothing
 489     ;;
 490   *)
 491     HAVE_OSX_VIDEO="no"
 492     ;;
 493 esac
 494
 495
 496 dnl *** Video 4 Linux 2 ***
 497 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 498 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 499 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 500 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 501   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 502   AC_TRY_COMPILE([
 503 #include <sys/types.h>
 504 #ifdef __sun /* Solaris */
 505 #include <sys/types.h>
 506 #include <sys/videodev2.h>
 507 #else /* Linux */
 508 #include <linux/types.h>
 509 #define _LINUX_TIME_H
 510 #define __user
 511 #include <linux/videodev2.h>
 512 #endif
 513 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 514 #error too early v4l2 version or no v4l2 at all
 515 #endif
 516     ], [
 517 return 0;
 518     ], [
 519       HAVE_GST_V4L2="yes"
 520       AC_MSG_RESULT(yes)
 521     ], [
 522       HAVE_GST_V4L2="no"
 523       AC_MSG_RESULT(no)
 524
 525       HAVE_VIDEODEV=no
 526       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 527       [
 528         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 529       ])
 530
 531       if test "x$HAVE_VIDEODEV" = "xyes"; then
 532         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 533         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 534       else
 535         AC_MSG_WARN([video4linux2 was not found])
 536       fi
 537     ])
 538
 539   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 540     dnl check for missing v4l2_buffer declaration (see #135919)
 541     MISSING_DECL=0
 542     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 543     AC_TRY_COMPILE([
 544 #include <sys/types.h>
 545 #ifdef __sun /* Solaris */
 546 #include <sys/types.h>
 547 #include <sys/videodev2.h>
 548 #else /* Linux */
 549 #include <linux/types.h>
 550 #define _LINUX_TIME_H
 551 #define __user
 552 #include <linux/videodev2.h>
 553 #endif
 554     ],[
 555 struct v4l2_buffer buf;
 556 buf.index = 0;
 557 return 0;
 558     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 559     if [ test x$MISSING_DECL = x1 ]; then
 560       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 561     fi
 562
 563     dnl check for XOverlay libraries
 564     AG_GST_CHECK_XV
 565   fi
 566 ])
 567
 568 # Optional gudev for device probing
 569 AC_ARG_WITH([gudev],
 570   AC_HELP_STRING([--with-gudev],
 571     [device detection with gudev]),
 572   [],
 573   [with_gudev=check])
 574 if test x$HAVE_GST_V4L2 = xyes; then
 575   if test x$with_gudev != xno; then
 576       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 577           [ have_gudev=yes
 578             AC_DEFINE(HAVE_GUDEV, 1,
 579                [Whether gudev is available for device detection])
 580             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 581           ], [
 582           have_gudev=no
 583           ])
 584   else
 585     have_gudev=no
 586   fi
 587 fi
 588 AC_SUBST(GUDEV_CFLAGS)
 589 AC_SUBST(GUDEV_LIBS)
 590
 591 # Make libv4l2 non-automagic
 592 AC_ARG_WITH([libv4l2],
 593   AC_HELP_STRING([--with-libv4l2],
 594     [support video buffer conversion using libv4l2]),
 595   [],
 596   [with_libv4l2=check])
 597 if test x$HAVE_GST_V4L2 = xyes; then
 598   if test x$with_libv4l2 != xno; then
 599       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 600           [ have_libv4l2=yes
 601             AC_DEFINE(HAVE_LIBV4L2, 1,
 602                 [Whether libv4l2 is available for video buffer conversion])
 603           ], [
 604           have_libv4l2=no
 605           ])
 606   else
 607     have_libv4l2=no
 608   fi
 609 fi
 610
 611 dnl Check for X11
 612 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 613 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 614                   [ximagesrc], [
 615   AC_PATH_XTRA
 616
 617   dnl now try to find the HEADER
 618   ac_cflags_save="$CFLAGS"
 619   ac_cppflags_save="$CPPFLAGS"
 620   CFLAGS="$CFLAGS $X_CFLAGS"
 621   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 622   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 623
 624   if test "x$HAVE_X" = "xno"
 625   then
 626     AC_MSG_NOTICE([cannot find X11 development files])
 627   else
 628     dnl this is much more than we want
 629     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 630     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 631     dnl it does not add the libs; therefore we add them here
 632     X_LIBS="$X_LIBS -lX11"
 633     AC_SUBST(X_CFLAGS)
 634     AC_SUBST(X_LIBS)
 635
 636     dnl check for Xfixes
 637     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 638     if test "x$HAVE_XFIXES" = "xyes"
 639     then
 640         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 641     fi
 642     AC_SUBST(XFIXES_LIBS)
 643     AC_SUBST(XFIXES_CFLAGS)
 644
 645     dnl check for Xdamage
 646     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 647     if test "x$HAVE_XDAMAGE" = "xyes"
 648     then
 649         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 650     fi
 651     AC_SUBST(XDAMAGE_LIBS)
 652     AC_SUBST(XDAMAGE_CFLAGS)
 653   fi
 654   AC_SUBST(HAVE_X)
 655   CFLAGS="$ac_cflags_save"
 656   CPPFLAGS="$ac_cppflags_save"
 657 ])
 658
 659 dnl FIXME: this should be rolled into the test above, it's just an additional
 660 dnl feature of the ximagesrc plug-in
 661 dnl This is the same as in gst-plugins-base
 662 dnl check for X Shm
 663 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 664 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 665   if test x$HAVE_X = xyes; then
 666     AC_CHECK_LIB(Xext, XShmAttach,
 667                  HAVE_XSHM="yes", HAVE_XSHM="no",
 668                  $X_LIBS)
 669     if test "x$HAVE_XSHM" = "xyes"; then
 670       XSHM_LIBS="-lXext"
 671     else
 672       dnl On AIX, it is in XextSam instead, but we still need -lXext
 673       AC_CHECK_LIB(XextSam, XShmAttach,
 674                    HAVE_XSHM="yes", HAVE_XSHM="no",
 675                    $X_LIBS)
 676       if test "x$HAVE_XSHM" = "xyes"; then
 677         XSHM_LIBS="-lXext -lXextSam"
 678       fi
 679     fi
 680   fi
 681 ], ,[
 682   AC_SUBST(HAVE_XSHM)
 683   AC_SUBST(XSHM_LIBS)
 684 ])
 685
 686 dnl for V4L2, we also need to know if we have XVIDEO
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 688 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 689                   [], [
 690   AG_GST_CHECK_XV
 691 ])
 692
 693 dnl *** ext plug-ins ***
 694 dnl keep this list sorted alphabetically !
 695
 696 if test "x$BUILD_EXTERNAL" = "xyes"; then
 697
 698 echo
 699 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 700 echo
 701
 702 dnl *** aalib ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 704 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 705   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 706   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 707 ])
 708
 709 dnl *** annodex ***
 710 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 711 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 712   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 713 ])
 714
 715 dnl *** cairo ***
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 717 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 718   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 719 ])
 720
 721 dnl *** cairo-gobject ***
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 723 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 724   [Cairo graphics rendering gobject bindings], cairooverlay, [
 725   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 726 ])
 727
 728 dnl **** ESound ****
 729 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 730 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 731   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 732   if test $HAVE_ESD = no
 733   then
 734     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 735     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 736   fi
 737 ])
 738
 739 dnl *** FLAC ***
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 741 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 742   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 743 ])
 744
 745 dnl *** GConf ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 747 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 748   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 749 ])
 750
 751 dnl *** GDK pixbuf ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 753 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 754   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 755 ])
 756
 757 dnl *** HAL ***
 758 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 759 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 760   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 761 ])
 762
 763 dnl *** Jack ***
 764 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 765 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 766   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 767   AC_SUBST(JACK_CFLAGS)
 768   AC_SUBST(JACK_LIBS)
 769
 770   dnl upcomming jack2 (1.9.7 will have the new api as well
 771   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 772   if test x$HAVE_JACK_0_120_1 = xyes; then
 773     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 774   fi
 775
 776 ])
 777
 778 dnl *** jpeg ***
 779 dnl FIXME: we could use header checks here as well IMO
 780 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 781 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 782   AC_ARG_WITH(jpeg-mmx,
 783     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 784   OLD_LIBS="$LIBS"
 785   if test x$with_jpeg_mmx != x; then
 786     LIBS="$LIBS -L$with_jpeg_mmx"
 787   fi
 788   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 789   JPEG_LIBS="$LIBS -ljpeg-mmx"
 790   LIBS="$OLD_LIBS"
 791   if test x$HAVE_JPEG != xyes; then
 792     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 793     JPEG_LIBS="-ljpeg"
 794   fi
 795   AC_SUBST(JPEG_LIBS)
 796 ])
 797
 798 dnl *** libcaca ***
 799 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 800 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 801   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 802   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 803   if test "x$HAVE_LIBCACA" != "xyes"; then
 804     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 805     dnl see if it compilation works too, might not if we are cross-compiling
 806     if test "x$HAVE_LIBCACA" = "xyes"; then
 807       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 808                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 809     fi
 810   fi
 811 ])
 812
 813 dnl *** libdv ***
 814 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 815 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 816   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 817 ])
 818
 819 dnl *** libpng ***
 820 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 821 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 822   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 823 ])
 824
 825 dnl *** pulseaudio ***
 826 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 827 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 828
 829   dnl used in ext/pulse/pulseutil.c
 830   AC_CHECK_HEADERS([process.h])
 831
 832   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 833   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 834   if test x$HAVE_PULSE_0_9_11 = xyes; then
 835     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 836   fi
 837   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 838   if test x$HAVE_PULSE_0_9_12 = xyes; then
 839     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 840   fi
 841   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 842   if test x$HAVE_PULSE_0_9_13 = xyes; then
 843     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 844   fi
 845   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 846   if test x$HAVE_PULSE_0_9_15 = xyes; then
 847     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 848   fi
 849   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_16, libpulse >= 0.9.16)
 850   if test x$HAVE_PULSE_0_9_16 = xyes; then
 851     AC_DEFINE(HAVE_PULSE_0_9_16, 1, [defined if pulseaudio >= 0.9.16 is available])
 852   fi
 853   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 854   if test x$HAVE_PULSE_0_9_20 = xyes; then
 855     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 856   fi
 857 ])
 858
 859 dnl *** dv1394 ***
 860 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 861 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 862   dnl first test for libraw1394 >= 2.0.0
 863   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 864   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 865   dnl now see how far we got
 866   if test x$HAVE_RAW1394 = xyes && \
 867      test x$HAVE_LIBIEC61883 = xyes; then
 868        AG_GST_CHECK_LIBHEADER(AVC1394,
 869         avc1394, avc1394_send_command, $RAW1394_LIBS,
 870         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 871        AG_GST_CHECK_LIBHEADER(ROM1394,
 872         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 873         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 874        if test x$HAVE_AVC1394 = xyes && \
 875           test x$HAVE_AVC1394 = xyes && \
 876           test x$HAVE_ROM1394 = xyes; then
 877           HAVE_DV1394=yes
 878           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 879           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 880           AC_SUBST(DV1394_CFLAGS)
 881           AC_SUBST(DV1394_LIBS)
 882         fi
 883   else
 884        if test x$HAVE_RAW1394 = xno; then
 885           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 886           AG_GST_CHECK_LIBHEADER(AVC1394,
 887            avc1394, avc1394_send_command, $RAW1394_LIBS,
 888            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 889           AG_GST_CHECK_LIBHEADER(ROM1394,
 890            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 891            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 892           if test x$HAVE_RAW1394 = xyes && \
 893              test x$HAVE_AVC1394 = xyes && \
 894              test x$HAVE_ROM1394 = xyes; then
 895              HAVE_DV1394=yes
 896              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 897              DV1394_CFLAGS="$RAW1394_CFLAGS"
 898              if test x$HAVE_LIBIEC61883 = xyes; then
 899                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 900                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 901              fi
 902              AC_SUBST(DV1394_CFLAGS)
 903              AC_SUBST(DV1394_LIBS)
 904            fi
 905          fi
 906   fi
 907 ])
 908 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 909
 910 dnl *** shout2 ***
 911 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 912 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 913   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 914   if test $HAVE_SHOUT2 = no
 915   then
 916     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 917     AC_SUBST(SHOUT2_CFLAGS)
 918     AC_SUBST(SHOUT2_LIBS)
 919   fi
 920 ])
 921
 922 dnl *** soup ***
 923 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 924 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 925   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 926     HAVE_SOUP="yes"
 927     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 928   ],[
 929     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 930       HAVE_SOUP="no"
 931     ])
 932   ])
 933   AC_SUBST(SOUP_CFLAGS)
 934   AC_SUBST(SOUP_LIBS)
 935 ])
 936
 937 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 938 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 939 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 940 dnl   speex_jitter.h is 1.1.x only
 941 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 942 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 943   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 944   if test $HAVE_SPEEX = no
 945   then
 946     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 947       AC_CHECK_HEADER(speex/speex_jitter.h, [
 948         dnl speex 1.1.x :
 949         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 950           dnl speex 1.1.5 or + :
 951           HAVE_SPEEX="yes"
 952           SPEEX_LIBS="-lspeex"
 953           AC_SUBST(SPEEX_CFLAGS)
 954           AC_SUBST(SPEEX_LIBS)
 955         ],[
 956           HAVE_SPEEX="no"
 957         ])
 958       ],[
 959         dnl speex 1.0.x :
 960           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 961             dnl speex 1.0.4
 962             HAVE_SPEEX="yes"
 963             SPEEX_LIBS="-lspeex"
 964             AC_SUBST(SPEEX_CFLAGS)
 965             AC_SUBST(SPEEX_LIBS)
 966
 967             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 968               [defined if speex 1.0.x API detected])
 969         ],[
 970             HAVE_SPEEX="no"
 971             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 972         ], [
 973 #include <speex/speex.h>
 974         ])
 975       ])
 976     ])
 977   fi
 978 ])
 979
 980 dnl *** taglib ***
 981 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 982 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 983   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 984   if test "x$HAVE_CXX" != "xyes"; then
 985     USE_TAGLIB=false
 986     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 987   else
 988     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 989     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 990         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 991       ], [
 992         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 993     ])
 994     AC_SUBST(TAGLIB_CXXFLAGS)
 995   fi
 996 ])
 997
 998 dnl *** wavpack ***
 999 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
1000 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
1001   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
1002     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
1003       HAVE_WAVPACK=yes
1004       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
1005     ],[
1006       HAVE_WAVPACK=no
1007     ])
1008   ])
1009   AC_SUBST(WAVPACK_CFLAGS)
1010   AC_SUBST(WAVPACK_LIBS)
1011 ])
1012
1013 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
1014 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
1015 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
1016   AG_GST_CHECK_LIBHEADER(ZLIB,
1017     z, uncompress,, zlib.h, [
1018     HAVE_ZLIB="yes"
1019     ZLIB_LIBS="-lz"
1020     AC_SUBST(ZLIB_LIBS)
1021   ])
1022 ])
1023
1024 dnl *** matroska prefers to have bz2 ***
1025 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
1026 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
1027   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
1028   AC_SUBST(BZ2_LIBS)
1029 ])
1030
1031 else
1032
1033 dnl not building plugins with external dependencies,
1034 dnl but we still need to set the conditionals
1035 AM_CONDITIONAL(USE_AALIB, false)
1036 AM_CONDITIONAL(USE_ANNODEX, false)
1037 AM_CONDITIONAL(USE_BZ2, false)
1038 AM_CONDITIONAL(USE_CAIRO, false)
1039 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
1040 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1041 AM_CONDITIONAL(USE_DV1394, false)
1042 AM_CONDITIONAL(USE_ESD, false)
1043 AM_CONDITIONAL(USE_FLAC, false)
1044 AM_CONDITIONAL(USE_GCONF, false)
1045 AM_CONDITIONAL(USE_GCONFTOOL, false)
1046 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1047 AM_CONDITIONAL(USE_GST_V4L2, false)
1048 AM_CONDITIONAL(USE_HAL, false)
1049 AM_CONDITIONAL(USE_JACK, false)
1050 AM_CONDITIONAL(USE_JPEG, false)
1051 AM_CONDITIONAL(USE_LIBCACA, false)
1052 AM_CONDITIONAL(USE_LIBDV, false)
1053 AM_CONDITIONAL(USE_LIBIEC61883, false)
1054 AM_CONDITIONAL(USE_LIBPNG, false)
1055 AM_CONDITIONAL(USE_OSS, false)
1056 AM_CONDITIONAL(USE_OSS4, false)
1057 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1058 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1059 AM_CONDITIONAL(USE_PULSE, false)
1060 AM_CONDITIONAL(USE_SHOUT2, false)
1061 AM_CONDITIONAL(USE_SOUP, false)
1062 AM_CONDITIONAL(USE_SPEEX, false)
1063 AM_CONDITIONAL(USE_SUNAUDIO, false)
1064 AM_CONDITIONAL(USE_TAGLIB, false)
1065 AM_CONDITIONAL(USE_WAVPACK, false)
1066 AM_CONDITIONAL(USE_X, false)
1067 AM_CONDITIONAL(USE_XSHM, false)
1068 AM_CONDITIONAL(USE_XVIDEO, false)
1069 AM_CONDITIONAL(USE_ZLIB, false)
1070
1071 fi dnl of EXT plugins
1072
1073 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1074
1075 dnl Overview:
1076 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1077 dnl GST_*:              flags shared by all built objects
1078 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1079 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1080 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1081 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1082
1083 dnl GST_OPTION_CFLAGS
1084 if test "x$USE_DEBUG" = xyes; then
1085    PROFILE_CFLAGS="-g"
1086 fi
1087 AC_SUBST(PROFILE_CFLAGS)
1088
1089 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1090   dnl Define _only_ for git (not pre-releases or releases)
1091   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1092 else
1093   DEPRECATED_CFLAGS=""
1094 fi
1095 AC_SUBST(DEPRECATED_CFLAGS)
1096
1097 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1098 dnl at make time with e.g. make ERROR_CFLAGS=""
1099 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1100 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1101 AC_SUBST(GST_OPTION_CFLAGS)
1102 AC_SUBST(GST_OPTION_CXXFLAGS)
1103
1104 dnl our libraries need to be versioned correctly
1105 AC_SUBST(GST_LT_LDFLAGS)
1106
1107 dnl FIXME: do we want to rename to GST_ALL_* ?
1108 dnl prefer internal headers to already installed ones
1109 dnl also add builddir include for enumtypes and marshal
1110 dnl add ERROR_CFLAGS, but overridable
1111 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1112 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1113 AC_SUBST(GST_CFLAGS)
1114 AC_SUBST(GST_CXXFLAGS)
1115 AC_SUBST(GST_LIBS)
1116
1117 dnl LDFLAGS really should only contain flags, not libs - they get added before
1118 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1119 GST_ALL_LDFLAGS="-no-undefined"
1120 AC_SUBST(GST_ALL_LDFLAGS)
1121
1122 dnl this really should only contain flags, not libs - they get added before
1123 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1124 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1125 AC_SUBST(GST_PLUGIN_LDFLAGS)
1126
1127 dnl *** output files ***
1128
1129 dnl keep this alphabetic per directory, please
1130 AC_CONFIG_FILES(
1131 Makefile
1132 gst/Makefile
1133 gst/alpha/Makefile
1134 gst/apetag/Makefile
1135 gst/audiofx/Makefile
1136 gst/auparse/Makefile
1137 gst/autodetect/Makefile
1138 gst/avi/Makefile
1139 gst/cutter/Makefile
1140 gst/deinterlace/Makefile
1141 gst/debugutils/Makefile
1142 gst/effectv/Makefile
1143 gst/equalizer/Makefile
1144 gst/flv/Makefile
1145 gst/id3demux/Makefile
1146 gst/icydemux/Makefile
1147 gst/imagefreeze/Makefile
1148 gst/interleave/Makefile
1149 gst/goom/Makefile
1150 gst/goom2k1/Makefile
1151 gst/law/Makefile
1152 gst/level/Makefile
1153 gst/matroska/Makefile
1154 gst/monoscope/Makefile
1155 gst/multifile/Makefile
1156 gst/multipart/Makefile
1157 gst/qtdemux/Makefile
1158 gst/replaygain/Makefile
1159 gst/rtp/Makefile
1160 gst/rtpmanager/Makefile
1161 gst/rtsp/Makefile
1162 gst/shapewipe/Makefile
1163 gst/smpte/Makefile
1164 gst/spectrum/Makefile
1165 gst/udp/Makefile
1166 gst/videobox/Makefile
1167 gst/videocrop/Makefile
1168 gst/videofilter/Makefile
1169 gst/videomixer/Makefile
1170 gst/wavenc/Makefile
1171 gst/wavparse/Makefile
1172 gst/flx/Makefile
1173 gst/y4m/Makefile
1174 ext/Makefile
1175 ext/aalib/Makefile
1176 ext/annodex/Makefile
1177 ext/cairo/Makefile
1178 ext/dv/Makefile
1179 ext/esd/Makefile
1180 ext/flac/Makefile
1181 ext/gconf/Makefile
1182 ext/gdk_pixbuf/Makefile
1183 ext/hal/Makefile
1184 ext/jack/Makefile
1185 ext/jpeg/Makefile
1186 ext/libcaca/Makefile
1187 ext/libpng/Makefile
1188 ext/pulse/Makefile
1189 ext/raw1394/Makefile
1190 ext/shout2/Makefile
1191 ext/soup/Makefile
1192 ext/speex/Makefile
1193 ext/taglib/Makefile
1194 ext/wavpack/Makefile
1195 sys/Makefile
1196 sys/directsound/Makefile
1197 sys/oss/Makefile
1198 sys/oss4/Makefile
1199 sys/osxaudio/Makefile
1200 sys/osxvideo/Makefile
1201 sys/sunaudio/Makefile
1202 sys/v4l2/Makefile
1203 sys/waveform/Makefile
1204 sys/ximage/Makefile
1205 po/Makefile.in
1206 tests/Makefile
1207 tests/check/Makefile
1208 tests/examples/Makefile
1209 tests/examples/audiofx/Makefile
1210 tests/examples/cairo/Makefile
1211 tests/examples/equalizer/Makefile
1212 tests/examples/jack/Makefile
1213 tests/examples/level/Makefile
1214 tests/examples/pulse/Makefile
1215 tests/examples/rtp/Makefile
1216 tests/examples/shapewipe/Makefile
1217 tests/examples/spectrum/Makefile
1218 tests/examples/v4l2/Makefile
1219 tests/files/Makefile
1220 tests/icles/Makefile
1221 gconf/Makefile
1222 gconf/gstreamer.schemas
1223 common/Makefile
1224 common/m4/Makefile
1225 m4/Makefile
1226 docs/Makefile
1227 docs/plugins/Makefile
1228 docs/version.entities
1229 pkgconfig/Makefile
1230 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1231 gst-plugins-good.spec
1232 )
1233
1234 dnl Create the config.h file for Visual Studio builds
1235 dnl Beware of spaces and /'s in some of the shell variable contents.
1236 sed \
1237     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1238     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1239     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1240     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1241     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1242     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1243     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1244     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1245     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1246     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1247     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1248     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1249     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1250     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1251     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1252     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1253     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1254     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1255     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1256     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1257     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1258     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1259     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1260     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1261     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1262     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1263     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1264     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1265     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1266     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1267     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1268     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1269     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1270     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1271     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1272     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1273     config.h.in >win32/common/config.h-new
1274
1275 AC_OUTPUT
1276
1277 AG_GST_OUTPUT_PLUGINS
1278 ORC_OUTPUT
1279