configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.25.3,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.30.2
  56 GSTPB_REQ=0.10.30.2
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 dnl *** checks for platform ***
  92
  93 dnl * hardware/architecture *
  94
  95 dnl common/m4/gst-arch.m4
  96 dnl check CPU type
  97 AG_GST_ARCH
  98
  99 dnl Determine endianness
 100 AC_C_BIGENDIAN
 101
 102 dnl *** checks for programs ***
 103
 104 dnl find a compiler
 105 AC_PROG_CC
 106 AC_PROG_CC_STDC
 107
 108 dnl determine c++ compiler
 109 AC_PROG_CXX
 110 dnl determine if c++ is available on this system
 111 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 112
 113 dnl determine c++ preprocessor
 114 dnl FIXME: do we need this ?
 115 AC_PROG_CXXCPP
 116
 117 AS_PROG_OBJC
 118
 119 dnl check if the compiler supports '-c' and '-o' options
 120 AM_PROG_CC_C_O
 121
 122 dnl find an assembler
 123 AM_PROG_AS
 124
 125 dnl check if the compiler supports do while(0) macros
 126 AG_GST_CHECK_DOWHILE_MACROS
 127
 128 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 129 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 130
 131 dnl check for gconftool-2
 132 dnl this macro defines an am conditional, so it needs to be run always
 133 AM_GCONF_SOURCE_2
 134
 135 dnl check for documentation tools
 136 GTK_DOC_CHECK([1.3])
 137 AS_PATH_PYTHON([2.1])
 138 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 139
 140 dnl *** checks for libraries ***
 141
 142 dnl check for libm, for sin()
 143 AC_CHECK_LIBM
 144 AC_SUBST(LIBM)
 145
 146 dnl *** checks for header files ***
 147
 148 dnl check if we have ANSI C header files
 149 AC_HEADER_STDC
 150
 151 dnl used by ext/wavpack
 152 AX_CREATE_STDINT_H
 153
 154 dnl used in gst/rtp/gstasteriskh263.c
 155 AC_CHECK_HEADERS([netinet/in.h])
 156 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 157 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 158
 159 dnl used in gst/udp
 160 AC_CHECK_HEADERS([sys/time.h])
 161
 162 dnl *** checks for types/defines ***
 163
 164 dnl Check for FIONREAD ioctl declaration.  This check is needed
 165 dnl for the UDP plugin to build on Solaris
 166 GST_CHECK_FIONREAD
 167
 168 dnl *** checks for structures ***
 169
 170 dnl *** checks for compiler characteristics ***
 171
 172 dnl check if we have GCC inline-asm
 173 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 174 if test x$HAVE_GCC_ASM = xyes ; then
 175   AC_DEFINE(HAVE_GCC_ASM, 1,
 176     [Define if compiler supports gcc inline assembly])
 177 fi
 178 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 179
 180 dnl *** checks for library functions ***
 181
 182 LIBS_SAVE=$LIBS
 183 LIBS="$LIBS $LIBM"
 184 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 185 LIBS=$LIBS_SAVE
 186
 187 dnl Check whether isinf() is defined by math.h
 188 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 189     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 190 if test "$ac_cv_have_isinf" = "yes"
 191 then
 192     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 193 fi
 194
 195 dnl Check for mmap (needed by electricfence plugin)
 196 AC_FUNC_MMAP
 197 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 198
 199 dnl Check for mmap (needed by electricfence plugin)
 200
 201 AC_CHECK_TYPE([struct ip_mreqn], [
 202               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 203               [#include <netinet/in.h>])
 204
 205 dnl *** checks for dependency libraries ***
 206
 207 dnl GLib is required
 208 AG_GST_GLIB_CHECK([2.18])
 209
 210 dnl Orc
 211 ORC_CHECK([0.4.11])
 212
 213 dnl checks for gstreamer
 214 dnl uninstalled is selected preferentially -- see pkg-config(1)
 215 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 220 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 221
 222 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 223 if test -z $GST_TOOLS_DIR; then
 224   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 225 fi
 226 AC_SUBST(GST_TOOLS_DIR)
 227
 228 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 229 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 230
 231 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 232
 233 dnl Check for documentation xrefs
 234 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 235 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 236 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 237 AC_SUBST(GLIB_PREFIX)
 238 AC_SUBST(GST_PREFIX)
 239 AC_SUBST(GSTPB_PREFIX)
 240
 241 dnl GTK is optional and used in examples
 242 if test "x$BUILD_EXAMPLES" = "xyes"; then
 243   PKG_CHECK_MODULES(GTK, gtk+-3.0, HAVE_GTK=yes,
 244   [PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.14.0, HAVE_GTK=yes, HAVE_GTK=no)])
 245   AC_SUBST(GTK_LIBS)
 246   AC_SUBST(GTK_CFLAGS)
 247 fi
 248 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 249
 250 dnl should we install schemas ?
 251 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 252 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 253   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 254   if test x$GCONFTOOL = xno; then
 255     AC_MSG_WARN(Not installing GConf schemas)
 256     HAVE_GCONFTOOL="no"
 257   else
 258     HAVE_GCONFTOOL="yes"
 259   fi
 260   AC_SUBST(HAVE_GCONFTOOL)
 261 ])
 262
 263 dnl *** set variables based on configure arguments ***
 264
 265 dnl set license and copyright notice
 266 GST_LICENSE="LGPL"
 267 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 268 AC_SUBST(GST_LICENSE)
 269
 270 dnl set location of plugin directory
 271 AG_GST_SET_PLUGINDIR
 272
 273 dnl set release date/time
 274 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 275   ["${srcdir}/gst-plugins-good.doap"],
 276   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 277
 278 dnl define an ERROR_CFLAGS Makefile variable
 279 dnl -Wundef: too many broken headers
 280 dnl -Waggregate-return: causes problems with ObjC code like in osxvideosink
 281 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 282         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 283         -Wwrite-strings -Wold-style-definition
 284         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 285         -Wnested-externs ])
 286
 287 dnl define an ERROR_CXXFLAGS Makefile variable
 288 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 289         -Wmissing-declarations -Wredundant-decls
 290         -Wwrite-strings
 291         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 292
 293 dnl define correct level for debugging messages
 294 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 295
 296 dnl used in examples
 297 AG_GST_DEFAULT_ELEMENTS
 298
 299 dnl *** plug-ins to include ***
 300
 301 dnl these are all the gst plug-ins, compilable without additional libs
 302 dnl videofilter is at the top because others depend on it
 303 AG_GST_CHECK_PLUGIN(videofilter)
 304 AG_GST_CHECK_PLUGIN(alpha)
 305 AG_GST_CHECK_PLUGIN(apetag)
 306 AG_GST_CHECK_PLUGIN(audiofx)
 307 AG_GST_CHECK_PLUGIN(auparse)
 308 AG_GST_CHECK_PLUGIN(autodetect)
 309 AG_GST_CHECK_PLUGIN(avi)
 310 AG_GST_CHECK_PLUGIN(cutter)
 311 AG_GST_CHECK_PLUGIN(debugutils)
 312 AG_GST_CHECK_PLUGIN(deinterlace)
 313 AG_GST_CHECK_PLUGIN(effectv)
 314 AG_GST_CHECK_PLUGIN(equalizer)
 315 AG_GST_CHECK_PLUGIN(flv)
 316 AG_GST_CHECK_PLUGIN(id3demux)
 317 AG_GST_CHECK_PLUGIN(icydemux)
 318 AG_GST_CHECK_PLUGIN(interleave)
 319 AG_GST_CHECK_PLUGIN(flx)
 320 AG_GST_CHECK_PLUGIN(goom)
 321 AG_GST_CHECK_PLUGIN(goom2k1)
 322 AG_GST_CHECK_PLUGIN(imagefreeze)
 323 AG_GST_CHECK_PLUGIN(law)
 324 AG_GST_CHECK_PLUGIN(level)
 325 AG_GST_CHECK_PLUGIN(matroska)
 326 AG_GST_CHECK_PLUGIN(monoscope)
 327 AG_GST_CHECK_PLUGIN(multifile)
 328 AG_GST_CHECK_PLUGIN(multipart)
 329 AG_GST_CHECK_PLUGIN(qtdemux)
 330 AG_GST_CHECK_PLUGIN(replaygain)
 331 AG_GST_CHECK_PLUGIN(rtp)
 332 AG_GST_CHECK_PLUGIN(rtpmanager)
 333 AG_GST_CHECK_PLUGIN(rtsp)
 334 AG_GST_CHECK_PLUGIN(shapewipe)
 335 AG_GST_CHECK_PLUGIN(smpte)
 336 AG_GST_CHECK_PLUGIN(spectrum)
 337 AG_GST_CHECK_PLUGIN(udp)
 338 AG_GST_CHECK_PLUGIN(videobox)
 339 AG_GST_CHECK_PLUGIN(videocrop)
 340 AG_GST_CHECK_PLUGIN(videomixer)
 341 AG_GST_CHECK_PLUGIN(wavenc)
 342 AG_GST_CHECK_PLUGIN(wavparse)
 343 AG_GST_CHECK_PLUGIN(y4m)
 344
 345 dnl *** checks for socket and nsl libraries ***
 346 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 347
 348 dnl disable gst plugins we might not be able to build on this
 349 dnl platform: udp and rtsp (ugly but minimally invasive)
 350 dnl FIXME: maybe move to sys
 351 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 352 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 353
 354 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 355   AG_GST_DISABLE_PLUGIN(udp)
 356   AG_GST_DISABLE_PLUGIN(rtsp)
 357 fi
 358
 359 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 360   WIN32_LIBS="-lws2_32"
 361   AC_SUBST(WIN32_LIBS)
 362 fi
 363
 364 dnl disable experimental plug-ins
 365 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 366   AG_GST_DISABLE_PLUGIN(monoscope)
 367 fi
 368
 369 dnl *** sys plug-ins ***
 370
 371 echo
 372 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 373 echo
 374
 375 dnl DirectSound
 376 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 377 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 378   HAVE_DIRECTSOUND="no"
 379   save_CFLAGS="$CFLAGS"
 380   save_LDFLAGS="$LDFLAGS"
 381   save_LIBS="$LIBS"
 382   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 383   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 384   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 385   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 386   AC_LINK_IFELSE([
 387 #include <windows.h>
 388 #include <dxerr9.h>
 389 #include <dsound.h>
 390
 391 int main ()
 392 {
 393   DXGetErrorString9 (0);
 394   DirectSoundCreate(NULL, NULL, NULL);
 395
 396   return 0;
 397 }
 398 ],
 399     [HAVE_DIRECTSOUND="yes"],
 400     [HAVE_DIRECTSOUND="no"])
 401   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 402   CFLAGS=$save_CFLAGS
 403   LDFLAGS=$save_LDFLAGS
 404   LIBS=$save_LIBS
 405
 406   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 407     dnl this is much more than we want
 408     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 409     AC_SUBST(DIRECTSOUND_CFLAGS)
 410     AC_SUBST(DIRECTSOUND_LDFLAGS)
 411     AC_SUBST(DIRECTSOUND_LIBS)
 412   fi
 413   AC_SUBST(HAVE_DIRECTSOUND)
 414 ])
 415
 416 dnl *** OSS audio *** (Linux, *BSD)
 417 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 418 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 419  HAVE_OSS="yes"
 420 dnl Linux and newer BSD versions :
 421  AC_CHECK_HEADER(sys/soundcard.h, [
 422    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 423    ] , [
 424 dnl Some old BSD versions and also newer OpenBSD versions :
 425    AC_CHECK_HEADER(soundcard.h, [
 426      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 427      ], [
 428   dnl Some old BSD versions :
 429      AC_CHECK_HEADER(machine/soundcard.h, [
 430        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 431          [Define if OSS includes are in /machine/])
 432        ], [
 433        HAVE_OSS="no"
 434      ])
 435    ])
 436  ])
 437 ])
 438
 439 dnl *** oss4 ***
 440 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 441 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 442   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 443   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 444       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 445       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 446 ])
 447
 448 dnl *** Sun Audio ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 450 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 451   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 452 ])
 453
 454 dnl *** OSX Audio ***
 455 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 456 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 457   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 458 ])
 459
 460 dnl *** OS X video ***
 461 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 462 HAVE_OSX_VIDEO="no"
 463 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 464   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 465 ])
 466 dnl in case header OpenGL/gl.h is found on other platforms
 467 case "$host" in
 468   *-*darwin*)
 469     dnl do nothing
 470     ;;
 471   *)
 472     HAVE_OSX_VIDEO="no"
 473     ;;
 474 esac
 475
 476
 477 dnl *** Video 4 Linux 2 ***
 478 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 479 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 480 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 481 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 482   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 483   AC_TRY_COMPILE([
 484 #include <sys/types.h>
 485 #ifdef __sun /* Solaris */
 486 #include <sys/types.h>
 487 #include <sys/videodev2.h>
 488 #else /* Linux */
 489 #include <linux/types.h>
 490 #define _LINUX_TIME_H
 491 #define __user
 492 #include <linux/videodev2.h>
 493 #endif
 494 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 495 #error too early v4l2 version or no v4l2 at all
 496 #endif
 497     ], [
 498 return 0;
 499     ], [
 500       HAVE_GST_V4L2="yes"
 501       AC_MSG_RESULT(yes)
 502     ], [
 503       HAVE_GST_V4L2="no"
 504       AC_MSG_RESULT(no)
 505
 506       HAVE_VIDEODEV=no
 507       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 508       [
 509         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 510       ])
 511
 512       if test "x$HAVE_VIDEODEV" = "xyes"; then
 513         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 514         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 515       else
 516         AC_MSG_WARN([video4linux2 was not found])
 517       fi
 518     ])
 519
 520   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 521     dnl check for missing v4l2_buffer declaration (see #135919)
 522     MISSING_DECL=0
 523     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 524     AC_TRY_COMPILE([
 525 #include <sys/types.h>
 526 #ifdef __sun /* Solaris */
 527 #include <sys/types.h>
 528 #include <sys/videodev2.h>
 529 #else /* Linux */
 530 #include <linux/types.h>
 531 #define _LINUX_TIME_H
 532 #define __user
 533 #include <linux/videodev2.h>
 534 #endif
 535     ],[
 536 struct v4l2_buffer buf;
 537 buf.index = 0;
 538 return 0;
 539     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 540     if [ test x$MISSING_DECL = x1 ]; then
 541       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 542     fi
 543
 544     dnl check for XOverlay libraries
 545     AG_GST_CHECK_XV
 546   fi
 547 ])
 548
 549 # Optional gudev for device probing
 550 AC_ARG_WITH([gudev],
 551   AC_HELP_STRING([--with-gudev],
 552     [device detection with gudev]),
 553   [],
 554   [with_gudev=check])
 555 if test x$HAVE_GST_V4L2 = xyes; then
 556   if test x$with_gudev != xno; then
 557       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 558           [ have_gudev=yes
 559             AC_DEFINE(HAVE_GUDEV, 1,
 560                [Whether gudev is available for device detection])
 561             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 562           ], [
 563           have_gudev=no
 564           ])
 565   else
 566     have_gudev=no
 567   fi
 568 fi
 569 AC_SUBST(GUDEV_CFLAGS)
 570 AC_SUBST(GUDEV_LIBS)
 571
 572 # Make libv4l2 non-automagic
 573 AC_ARG_WITH([libv4l2],
 574   AC_HELP_STRING([--with-libv4l2],
 575     [support video buffer conversion using libv4l2]),
 576   [],
 577   [with_libv4l2=check])
 578 if test x$HAVE_GST_V4L2 = xyes; then
 579   if test x$with_libv4l2 != xno; then
 580       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 581           [ have_libv4l2=yes
 582             AC_DEFINE(HAVE_LIBV4L2, 1,
 583                 [Whether libv4l2 is available for video buffer conversion])
 584           ], [
 585           have_libv4l2=no
 586           ])
 587   else
 588     have_libv4l2=no
 589   fi
 590 fi
 591
 592 dnl Check for X11
 593 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 594 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 595                   [ximagesrc], [
 596   AC_PATH_XTRA
 597
 598   dnl now try to find the HEADER
 599   ac_cflags_save="$CFLAGS"
 600   ac_cppflags_save="$CPPFLAGS"
 601   CFLAGS="$CFLAGS $X_CFLAGS"
 602   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 603   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 604
 605   if test "x$HAVE_X" = "xno"
 606   then
 607     AC_MSG_NOTICE([cannot find X11 development files])
 608   else
 609     dnl this is much more than we want
 610     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 611     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 612     dnl it does not add the libs; therefore we add them here
 613     X_LIBS="$X_LIBS -lX11"
 614     AC_SUBST(X_CFLAGS)
 615     AC_SUBST(X_LIBS)
 616
 617     dnl check for Xfixes
 618     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 619     if test "x$HAVE_XFIXES" = "xyes"
 620     then
 621         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 622     fi
 623     AC_SUBST(XFIXES_LIBS)
 624     AC_SUBST(XFIXES_CFLAGS)
 625
 626     dnl check for Xdamage
 627     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 628     if test "x$HAVE_XDAMAGE" = "xyes"
 629     then
 630         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 631     fi
 632     AC_SUBST(XDAMAGE_LIBS)
 633     AC_SUBST(XDAMAGE_CFLAGS)
 634   fi
 635   AC_SUBST(HAVE_X)
 636   CFLAGS="$ac_cflags_save"
 637   CPPFLAGS="$ac_cppflags_save"
 638 ])
 639
 640 dnl FIXME: this should be rolled into the test above, it's just an additional
 641 dnl feature of the ximagesrc plug-in
 642 dnl This is the same as in gst-plugins-base
 643 dnl check for X Shm
 644 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 645 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 646   if test x$HAVE_X = xyes; then
 647     AC_CHECK_LIB(Xext, XShmAttach,
 648                  HAVE_XSHM="yes", HAVE_XSHM="no",
 649                  $X_LIBS)
 650     if test "x$HAVE_XSHM" = "xyes"; then
 651       XSHM_LIBS="-lXext"
 652     else
 653       dnl On AIX, it is in XextSam instead, but we still need -lXext
 654       AC_CHECK_LIB(XextSam, XShmAttach,
 655                    HAVE_XSHM="yes", HAVE_XSHM="no",
 656                    $X_LIBS)
 657       if test "x$HAVE_XSHM" = "xyes"; then
 658         XSHM_LIBS="-lXext -lXextSam"
 659       fi
 660     fi
 661   fi
 662 ], ,[
 663   AC_SUBST(HAVE_XSHM)
 664   AC_SUBST(XSHM_LIBS)
 665 ])
 666
 667 dnl for V4L2, we also need to know if we have XVIDEO
 668 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 669 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 670                   [], [
 671   AG_GST_CHECK_XV
 672 ])
 673
 674 dnl *** ext plug-ins ***
 675 dnl keep this list sorted alphabetically !
 676
 677 if test "x$BUILD_EXTERNAL" = "xyes"; then
 678
 679 echo
 680 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 681 echo
 682
 683 dnl *** aalib ***
 684 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 685 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 686   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 687   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 688 ])
 689
 690 dnl *** annodex ***
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 692 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 693   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 694 ])
 695
 696 dnl *** cairo ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 698 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 699   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 700 ])
 701
 702 dnl **** ESound ****
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 704 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 705   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 706   if test $HAVE_ESD = no
 707   then
 708     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 709     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 710   fi
 711 ])
 712
 713 dnl *** FLAC ***
 714 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 715 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 716   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 717 ])
 718
 719 dnl *** GConf ***
 720 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 721 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 722   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 723 ])
 724
 725 dnl *** GDK pixbuf ***
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 727 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 728   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 729 ])
 730
 731 dnl *** HAL ***
 732 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 733 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 734   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 735 ])
 736
 737 dnl *** jpeg ***
 738 dnl FIXME: we could use header checks here as well IMO
 739 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 740 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 741   AC_ARG_WITH(jpeg-mmx,
 742     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 743   OLD_LIBS="$LIBS"
 744   if test x$with_jpeg_mmx != x; then
 745     LIBS="$LIBS -L$with_jpeg_mmx"
 746   fi
 747   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 748   JPEG_LIBS="$LIBS -ljpeg-mmx"
 749   LIBS="$OLD_LIBS"
 750   if test x$HAVE_JPEG != xyes; then
 751     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 752     JPEG_LIBS="-ljpeg"
 753   fi
 754   AC_SUBST(JPEG_LIBS)
 755 ])
 756
 757 dnl *** libcaca ***
 758 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 759 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 760   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 761   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 762   if test "x$HAVE_LIBCACA" != "xyes"; then
 763     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 764     dnl see if it compilation works too, might not if we are cross-compiling
 765     if test "x$HAVE_LIBCACA" = "xyes"; then
 766       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 767                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 768     fi
 769   fi
 770 ])
 771
 772 dnl *** libdv ***
 773 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 774 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 775   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 776 ])
 777
 778 dnl *** libpng ***
 779 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 780 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 781   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 782 ])
 783
 784 dnl *** pulseaudio ***
 785 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 786 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 787
 788   dnl used in ext/pulse/pulseutil.c
 789   AC_CHECK_HEADERS([process.h])
 790
 791   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 792   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 793   if test x$HAVE_PULSE_0_9_11 = xyes; then
 794     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 795   fi
 796   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 797   if test x$HAVE_PULSE_0_9_12 = xyes; then
 798     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 799   fi
 800   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 801   if test x$HAVE_PULSE_0_9_13 = xyes; then
 802     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 803   fi
 804   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 805   if test x$HAVE_PULSE_0_9_15 = xyes; then
 806     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 807   fi
 808   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_16, libpulse >= 0.9.16)
 809   if test x$HAVE_PULSE_0_9_16 = xyes; then
 810     AC_DEFINE(HAVE_PULSE_0_9_16, 1, [defined if pulseaudio >= 0.9.16 is available])
 811   fi
 812   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 813   if test x$HAVE_PULSE_0_9_20 = xyes; then
 814     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 815   fi
 816 ])
 817
 818 dnl *** dv1394 ***
 819 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 820 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 821   dnl first test for libraw1394 >= 2.0.0
 822   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 823   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 824   dnl now see how far we got
 825   if test x$HAVE_RAW1394 = xyes && \
 826      test x$HAVE_LIBIEC61883 = xyes; then
 827        AG_GST_CHECK_LIBHEADER(AVC1394,
 828         avc1394, avc1394_send_command, $RAW1394_LIBS,
 829         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 830        AG_GST_CHECK_LIBHEADER(ROM1394,
 831         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 832         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 833        if test x$HAVE_AVC1394 = xyes && \
 834           test x$HAVE_AVC1394 = xyes && \
 835           test x$HAVE_ROM1394 = xyes; then
 836           HAVE_DV1394=yes
 837           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 838           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 839           AC_SUBST(DV1394_CFLAGS)
 840           AC_SUBST(DV1394_LIBS)
 841         fi
 842   else
 843        if test x$HAVE_RAW1394 = xno; then
 844           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 845           AG_GST_CHECK_LIBHEADER(AVC1394,
 846            avc1394, avc1394_send_command, $RAW1394_LIBS,
 847            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 848           AG_GST_CHECK_LIBHEADER(ROM1394,
 849            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 850            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 851           if test x$HAVE_RAW1394 = xyes && \
 852              test x$HAVE_AVC1394 = xyes && \
 853              test x$HAVE_ROM1394 = xyes; then
 854              HAVE_DV1394=yes
 855              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 856              DV1394_CFLAGS="$RAW1394_CFLAGS"
 857              if test x$HAVE_LIBIEC61883 = xyes; then
 858                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 859                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 860              fi
 861              AC_SUBST(DV1394_CFLAGS)
 862              AC_SUBST(DV1394_LIBS)
 863            fi
 864          fi
 865   fi
 866 ])
 867 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 868
 869 dnl *** shout2 ***
 870 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 871 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 872   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 873   if test $HAVE_SHOUT2 = no
 874   then
 875     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 876     AC_SUBST(SHOUT2_CFLAGS)
 877     AC_SUBST(SHOUT2_LIBS)
 878   fi
 879 ])
 880
 881 dnl *** soup ***
 882 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 883 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 884   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 885     HAVE_SOUP="yes"
 886     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 887   ],[
 888     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 889       HAVE_SOUP="no"
 890       AC_MSG_RESULT(no)
 891     ])
 892   ])
 893   AC_SUBST(SOUP_CFLAGS)
 894   AC_SUBST(SOUP_LIBS)
 895 ])
 896
 897 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 898 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 899 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 900 dnl   speex_jitter.h is 1.1.x only
 901 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 902 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 903   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 904   if test $HAVE_SPEEX = no
 905   then
 906     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 907       AC_CHECK_HEADER(speex/speex_jitter.h, [
 908         dnl speex 1.1.x :
 909         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 910           dnl speex 1.1.5 or + :
 911           HAVE_SPEEX="yes"
 912           SPEEX_LIBS="-lspeex"
 913           AC_SUBST(SPEEX_CFLAGS)
 914           AC_SUBST(SPEEX_LIBS)
 915         ],[
 916           HAVE_SPEEX="no"
 917         ])
 918       ],[
 919         dnl speex 1.0.x :
 920           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 921             dnl speex 1.0.4
 922             HAVE_SPEEX="yes"
 923             SPEEX_LIBS="-lspeex"
 924             AC_SUBST(SPEEX_CFLAGS)
 925             AC_SUBST(SPEEX_LIBS)
 926
 927             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 928               [defined if speex 1.0.x API detected])
 929         ],[
 930             HAVE_SPEEX="no"
 931             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 932         ], [
 933 #include <speex/speex.h>
 934         ])
 935       ])
 936     ])
 937   fi
 938 ])
 939
 940 dnl *** taglib ***
 941 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 942 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 943   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 944   if test "x$HAVE_CXX" != "xyes"; then
 945     USE_TAGLIB=false
 946     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 947   else
 948     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 949     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 950         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 951       ], [
 952         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 953     ])
 954     AC_SUBST(TAGLIB_CXXFLAGS)
 955   fi
 956 ])
 957
 958 dnl *** wavpack ***
 959 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 960 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 961   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 962     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 963       HAVE_WAVPACK=yes
 964       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 965     ],[
 966       HAVE_WAVPACK=no
 967       AC_MSG_RESULT(no)
 968     ])
 969   ])
 970   AC_SUBST(WAVPACK_CFLAGS)
 971   AC_SUBST(WAVPACK_LIBS)
 972 ])
 973
 974 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 975 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 976 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 977   AG_GST_CHECK_LIBHEADER(ZLIB,
 978     z, uncompress,, zlib.h, [
 979     HAVE_ZLIB="yes"
 980     ZLIB_LIBS="-lz"
 981     AC_SUBST(ZLIB_LIBS)
 982   ])
 983 ])
 984
 985 dnl *** matroska prefers to have bz2 ***
 986 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 987 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 988   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 989   AC_SUBST(BZ2_LIBS)
 990 ])
 991
 992 else
 993
 994 dnl not building plugins with external dependencies,
 995 dnl but we still need to set the conditionals
 996 AM_CONDITIONAL(USE_AALIB, false)
 997 AM_CONDITIONAL(USE_ANNODEX, false)
 998 AM_CONDITIONAL(USE_BZ2, false)
 999 AM_CONDITIONAL(USE_CAIRO, false)
1000 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1001 AM_CONDITIONAL(USE_DV1394, false)
1002 AM_CONDITIONAL(USE_ESD, false)
1003 AM_CONDITIONAL(USE_FLAC, false)
1004 AM_CONDITIONAL(USE_GCONF, false)
1005 AM_CONDITIONAL(USE_GCONFTOOL, false)
1006 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1007 AM_CONDITIONAL(USE_GST_V4L2, false)
1008 AM_CONDITIONAL(USE_HAL, false)
1009 AM_CONDITIONAL(USE_JPEG, false)
1010 AM_CONDITIONAL(USE_LIBCACA, false)
1011 AM_CONDITIONAL(USE_LIBDV, false)
1012 AM_CONDITIONAL(USE_LIBIEC61883, false)
1013 AM_CONDITIONAL(USE_LIBPNG, false)
1014 AM_CONDITIONAL(USE_OSS, false)
1015 AM_CONDITIONAL(USE_OSS4, false)
1016 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1017 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1018 AM_CONDITIONAL(USE_PULSE, false)
1019 AM_CONDITIONAL(USE_SHOUT2, false)
1020 AM_CONDITIONAL(USE_SOUP, false)
1021 AM_CONDITIONAL(USE_SPEEX, false)
1022 AM_CONDITIONAL(USE_SUNAUDIO, false)
1023 AM_CONDITIONAL(USE_TAGLIB, false)
1024 AM_CONDITIONAL(USE_WAVPACK, false)
1025 AM_CONDITIONAL(USE_X, false)
1026 AM_CONDITIONAL(USE_XSHM, false)
1027 AM_CONDITIONAL(USE_XVIDEO, false)
1028 AM_CONDITIONAL(USE_ZLIB, false)
1029
1030 fi dnl of EXT plugins
1031
1032 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1033
1034 dnl Overview:
1035 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1036 dnl GST_*:              flags shared by all built objects
1037 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1038 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1039 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1040 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1041
1042 dnl GST_OPTION_CFLAGS
1043 if test "x$USE_DEBUG" = xyes; then
1044    PROFILE_CFLAGS="-g"
1045 fi
1046 AC_SUBST(PROFILE_CFLAGS)
1047
1048 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1049   dnl Define _only_ for git (not pre-releases or releases)
1050   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1051 else
1052   DEPRECATED_CFLAGS=""
1053 fi
1054 AC_SUBST(DEPRECATED_CFLAGS)
1055
1056 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1057 dnl at make time with e.g. make ERROR_CFLAGS=""
1058 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1059 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1060 AC_SUBST(GST_OPTION_CFLAGS)
1061 AC_SUBST(GST_OPTION_CXXFLAGS)
1062
1063 dnl our libraries need to be versioned correctly
1064 AC_SUBST(GST_LT_LDFLAGS)
1065
1066 dnl FIXME: do we want to rename to GST_ALL_* ?
1067 dnl prefer internal headers to already installed ones
1068 dnl also add builddir include for enumtypes and marshal
1069 dnl add ERROR_CFLAGS, but overridable
1070 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1071 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1072 AC_SUBST(GST_CFLAGS)
1073 AC_SUBST(GST_CXXFLAGS)
1074 AC_SUBST(GST_LIBS)
1075
1076 dnl LDFLAGS really should only contain flags, not libs - they get added before
1077 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1078 GST_ALL_LDFLAGS="-no-undefined"
1079 AC_SUBST(GST_ALL_LDFLAGS)
1080
1081 dnl this really should only contain flags, not libs - they get added before
1082 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1083 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1084 AC_SUBST(GST_PLUGIN_LDFLAGS)
1085
1086 dnl *** output files ***
1087
1088 dnl keep this alphabetic per directory, please
1089 AC_CONFIG_FILES(
1090 Makefile
1091 gst/Makefile
1092 gst/alpha/Makefile
1093 gst/apetag/Makefile
1094 gst/audiofx/Makefile
1095 gst/auparse/Makefile
1096 gst/autodetect/Makefile
1097 gst/avi/Makefile
1098 gst/cutter/Makefile
1099 gst/deinterlace/Makefile
1100 gst/debugutils/Makefile
1101 gst/effectv/Makefile
1102 gst/equalizer/Makefile
1103 gst/flv/Makefile
1104 gst/id3demux/Makefile
1105 gst/icydemux/Makefile
1106 gst/imagefreeze/Makefile
1107 gst/interleave/Makefile
1108 gst/goom/Makefile
1109 gst/goom2k1/Makefile
1110 gst/law/Makefile
1111 gst/level/Makefile
1112 gst/matroska/Makefile
1113 gst/monoscope/Makefile
1114 gst/multifile/Makefile
1115 gst/multipart/Makefile
1116 gst/qtdemux/Makefile
1117 gst/replaygain/Makefile
1118 gst/rtp/Makefile
1119 gst/rtpmanager/Makefile
1120 gst/rtsp/Makefile
1121 gst/shapewipe/Makefile
1122 gst/smpte/Makefile
1123 gst/spectrum/Makefile
1124 gst/udp/Makefile
1125 gst/videobox/Makefile
1126 gst/videocrop/Makefile
1127 gst/videofilter/Makefile
1128 gst/videomixer/Makefile
1129 gst/wavenc/Makefile
1130 gst/wavparse/Makefile
1131 gst/flx/Makefile
1132 gst/y4m/Makefile
1133 ext/jpeg/Makefile
1134 ext/Makefile
1135 ext/aalib/Makefile
1136 ext/annodex/Makefile
1137 ext/cairo/Makefile
1138 ext/dv/Makefile
1139 ext/esd/Makefile
1140 ext/flac/Makefile
1141 ext/gconf/Makefile
1142 ext/gdk_pixbuf/Makefile
1143 ext/hal/Makefile
1144 ext/libcaca/Makefile
1145 ext/libpng/Makefile
1146 ext/pulse/Makefile
1147 ext/raw1394/Makefile
1148 ext/shout2/Makefile
1149 ext/soup/Makefile
1150 ext/speex/Makefile
1151 ext/taglib/Makefile
1152 ext/wavpack/Makefile
1153 sys/Makefile
1154 sys/directsound/Makefile
1155 sys/oss/Makefile
1156 sys/oss4/Makefile
1157 sys/osxaudio/Makefile
1158 sys/osxvideo/Makefile
1159 sys/sunaudio/Makefile
1160 sys/v4l2/Makefile
1161 sys/waveform/Makefile
1162 sys/ximage/Makefile
1163 po/Makefile.in
1164 tests/Makefile
1165 tests/check/Makefile
1166 tests/examples/Makefile
1167 tests/examples/audiofx/Makefile
1168 tests/examples/equalizer/Makefile
1169 tests/examples/level/Makefile
1170 tests/examples/pulse/Makefile
1171 tests/examples/rtp/Makefile
1172 tests/examples/shapewipe/Makefile
1173 tests/examples/spectrum/Makefile
1174 tests/examples/v4l2/Makefile
1175 tests/files/Makefile
1176 tests/icles/Makefile
1177 gconf/Makefile
1178 gconf/gstreamer.schemas
1179 common/Makefile
1180 common/m4/Makefile
1181 m4/Makefile
1182 docs/Makefile
1183 docs/plugins/Makefile
1184 docs/version.entities
1185 pkgconfig/Makefile
1186 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1187 gst-plugins-good.spec
1188 )
1189
1190 dnl Create the config.h file for Visual Studio builds
1191 dnl Beware of spaces and /'s in some of the shell variable contents.
1192 sed \
1193     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1194     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1195     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1196     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1197     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1198     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1199     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1200     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1201     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1202     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1203     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1204     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1205     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1206     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1207     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1208     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1209     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1210     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1211     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1212     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1213     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1214     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1215     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1216     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1217     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1218     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1219     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1220     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1221     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1222     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1223     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1224     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1225     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1226     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1227     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1228     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1229     config.h.in >win32/common/config.h-new
1230
1231 AC_OUTPUT
1232
1233 AG_GST_OUTPUT_PLUGINS
1234 ORC_OUTPUT
1235