configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.1.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 26, 0, 0)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.11.1
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.3])
 161 AS_PATH_PYTHON([2.1])
 162 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 AC_CHECK_LIBM
 168 AC_SUBST(LIBM)
 169
 170 dnl *** checks for header files ***
 171
 172 dnl check if we have ANSI C header files
 173 AC_HEADER_STDC
 174
 175 ac_cppflags_save="$CPPFLAGS"
 176 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 177 AC_COMPILE_IFELSE(
 178   AC_LANG_PROGRAM([
 179 #include <libxml/HTMLparser.h>
 180                      ],[
 181 #ifndef LIBXML_HTML_ENABLED
 182 #error libxml2 has no HTML support
 183 #endif /* LIBXML_HTML_ENABLED */
 184                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 185 CPPFLAGS="$ac_cppflags_save"
 186 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 187
 188 dnl used in gst-libs/gst/rtsp
 189 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 190 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 191   WIN32_LIBS="-lws2_32"
 192   AC_SUBST(WIN32_LIBS)
 193 fi
 194
 195 dnl check for hstrerror, for gst-libs/gst/rtsp
 196 save_libs="$LIBS"
 197 AC_CHECK_FUNC(hstrerror, ,
 198     AC_CHECK_LIB(resolv, hstrerror, ,
 199         [AC_DEFINE(NO_HSTRERROR, 1,
 200              [Define if you have no native hstrerror() function.])]))
 201 HSTRERROR_LIBS=$LIBS
 202 AC_SUBST(HSTRERROR_LIBS)
 203 LIBS="$save_libs"
 204
 205 dnl used in gst-libs/gst/pbutils and associated unit test
 206 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 207
 208 dnl also, Windows does not have long long
 209 AX_CREATE_STDINT_H
 210
 211 dnl *** checks for functions ***
 212 AC_CHECK_FUNCS([localtime_r gmtime_r])
 213
 214 dnl *** checks for math functions ***
 215 LIBS_SAVE=$LIBS
 216 LIBS="$LIBS $LIBM"
 217 AC_CHECK_FUNCS(log2)
 218 LIBS=$LIBS_SAVE
 219
 220 dnl *** checks for types/defines ***
 221
 222 dnl *** checks for structures ***
 223
 224 dnl *** checks for compiler characteristics ***
 225
 226 dnl *** checks for library functions ***
 227
 228 dnl check for fseeko()
 229 AC_FUNC_FSEEKO
 230
 231 dnl Check for fast float to int casting as defined in C99
 232 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 233 save_libs=$LIBS
 234 LIBS="$LIBS $LIBM"
 235 AC_C99_FUNC_LRINT
 236 AC_C99_FUNC_LRINTF
 237 LIBS=$save_libs
 238
 239 dnl Check for a way to display the function name in debug output
 240 AG_GST_CHECK_FUNCTION
 241
 242 dnl *** checks for socket and nsl libraries ***
 243 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 244 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 245
 246 dnl *** checks for dependency libraries ***
 247
 248 dnl GLib is required
 249 AG_GST_GLIB_CHECK([2.26])
 250
 251 ORC_CHECK([0.4.11])
 252
 253 dnl checks for gstreamer
 254 dnl uninstalled is selected preferentially -- see pkg-config(1)
 255 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 256 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 257 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 258 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 259 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 260
 261 dnl Check for documentation xrefs
 262 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 263 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 264 AC_SUBST(GLIB_PREFIX)
 265 AC_SUBST(GST_PREFIX)
 266
 267 dnl GTK is optional and only used in examples
 268 HAVE_GTK=no
 269 HAVE_GTK_X11=no
 270 GTK_REQ=3.0.0
 271 if test "x$BUILD_EXAMPLES" = "xyes"; then
 272   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 273   dnl some examples need gtk+-x11
 274   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 275   AC_SUBST(GTK_LIBS)
 276   AC_SUBST(GTK_CFLAGS)
 277 fi
 278 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 279 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 280
 281 dnl QT is optional and only used in examples
 282 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 283   HAVE_QT_GV=yes
 284   HAVE_QT=yes
 285 ], [
 286   HAVE_QT_GV=no
 287   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 288 ])
 289 if test "x$HAVE_QT" = "xyes"; then
 290   AC_MSG_CHECKING([Qt moc])
 291   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 292   AC_MSG_RESULT($QT4_MOC)
 293   AC_SUBST(QT4_MOC)
 294 fi
 295 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 296 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 297
 298 dnl chck for linux headers needed by the joystick seek example
 299 AC_COMPILE_IFELSE(
 300 [
 301   AC_LANG_PROGRAM([
 302     #include <linux/input.h>
 303     #include <linux/joystick.h>
 304   ],[
 305     struct js_event js;
 306     js.type = JS_EVENT_AXIS;
 307   ])
 308 ], [
 309   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 310 ], [
 311   HAVE_LINUX_JOYSTICK_HEADERS="no"
 312 ])
 313 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 314
 315 dnl Check for -Bsymbolic-functions linker flag used to avoid
 316 dnl intra-library PLT jumps, if available.
 317 AC_ARG_ENABLE(Bsymbolic,
 318               [AC_HELP_STRING([--disable-Bsymbolic],
 319                               [avoid linking with -Bsymbolic])],,
 320               [SAVED_LDFLAGS="${LDFLAGS}"
 321                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 322                LDFLAGS=-Wl,-Bsymbolic-functions
 323                AC_TRY_LINK([], [int main (void) { return 0; }],
 324                            AC_MSG_RESULT(yes)
 325                            enable_Bsymbolic=yes,
 326                            AC_MSG_RESULT(no)
 327                            enable_Bsymbolic=no)
 328                LDFLAGS="${SAVED_LDFLAGS}"])
 329
 330
 331 dnl *** set variables based on configure arguments ***
 332
 333 dnl set license and copyright notice
 334 GST_LICENSE="LGPL"
 335 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 336 AC_SUBST(GST_LICENSE)
 337
 338 dnl set location of plugin directory
 339 AG_GST_SET_PLUGINDIR
 340
 341 dnl set release date/time
 342 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 343   ["${srcdir}/gst-plugins-base.doap"],
 344   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 345
 346 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 347 dnl make sure it doesn't complain about unused variables if debugging is disabled
 348 NO_WARNINGS=""
 349 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 350
 351 dnl define an ERROR_CFLAGS Makefile variable
 352 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 353 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 354     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 355     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 356     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 357     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 358
 359 dnl define an ERROR_CXXFLAGS Makefile variable
 360 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 361     -Wmissing-declarations -Wredundant-decls -Wundef
 362     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 363     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 364     -Wno-multichar $NO_WARNINGS])
 365
 366 dnl define correct level for debugging messages
 367 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 368
 369 dnl used in examples
 370 AG_GST_DEFAULT_ELEMENTS
 371
 372 dnl needed for encoding-target
 373 GST_DATADIR="$GST_PREFIX/share"
 374 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 375 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 376
 377 dnl behaviour of speex based audio resampler
 378 AC_MSG_CHECKING(which audio resample format to use for integer)
 379 AC_ARG_WITH([audioresample_format],
 380         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 381         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 382 AC_MSG_RESULT($ac_cv_audioresample_format)
 383 case $ac_cv_audioresample_format in
 384   int)
 385     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 386     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 387   ;;
 388   float)
 389     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 390     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 391   ;;
 392   auto)
 393     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 394     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 395 esac
 396
 397 dnl *** plug-ins to include ***
 398
 399 dnl these are all the gst plug-ins, compilable without additional libs
 400 AG_GST_CHECK_PLUGIN(adder)
 401 AG_GST_CHECK_PLUGIN(app)
 402 AG_GST_CHECK_PLUGIN(audioconvert)
 403 AG_GST_CHECK_PLUGIN(audiorate)
 404 AG_GST_CHECK_PLUGIN(audiotestsrc)
 405 AG_GST_CHECK_PLUGIN(encoding)
 406 AG_GST_CHECK_PLUGIN(videoconvert)
 407 AG_GST_CHECK_PLUGIN(gdp)
 408 AG_GST_CHECK_PLUGIN(playback)
 409 AG_GST_CHECK_PLUGIN(audioresample)
 410 AG_GST_CHECK_PLUGIN(subparse)
 411 AG_GST_CHECK_PLUGIN(tcp)
 412 AG_GST_CHECK_PLUGIN(typefind)
 413 AG_GST_CHECK_PLUGIN(videotestsrc)
 414 AG_GST_CHECK_PLUGIN(videorate)
 415 AG_GST_CHECK_PLUGIN(videoscale)
 416 AG_GST_CHECK_PLUGIN(volume)
 417
 418 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 419 AM_CONDITIONAL(USE_XML, false)
 420 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 421
 422 dnl disable plug-ins that require libxml2's HTML support if it is not available
 423 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 424   AG_GST_DISABLE_PLUGIN(subparse)
 425 fi
 426
 427 dnl iso-codes is optional, used by libgsttag
 428 AC_ARG_ENABLE(iso-codes,
 429 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 430 [case "${enableval}" in
 431   yes) enable_iso_codes=yes ;;
 432   no)  enable_iso_codes=no ;;
 433   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 434 esac
 435 ],
 436 [enable_iso_codes=yes]) dnl Default value
 437
 438 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 439 if test "x$enable_iso_codes" = "xyes"; then
 440   AC_MSG_RESULT([yes])
 441   have_iso_codes=no
 442   AC_MSG_CHECKING([whether iso-codes are available on this system])
 443   if $PKG_CONFIG iso-codes; then
 444     AC_MSG_RESULT([yes])
 445     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 446     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 447       AC_MSG_RESULT([yes])
 448       AC_MSG_CHECKING([for iso-codes prefix])
 449       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 450       if test -d "$ISO_CODES_PREFIX"; then
 451         AC_MSG_RESULT([yes])
 452         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 453         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 454         ISO_639_DOMAIN="iso_639"
 455         AC_MSG_CHECKING([ISO_639_DOMAIN])
 456         AC_MSG_RESULT([$ISO_639_DOMAIN])
 457         have_iso_codes=yes
 458         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 459         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 460         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 461         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 462       else
 463         AC_MSG_RESULT([no])
 464       fi
 465     else
 466       AC_MSG_RESULT([no])
 467     fi
 468   else
 469     AC_MSG_RESULT([no])
 470   fi
 471   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 472 else
 473   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 474   AM_CONDITIONAL(USE_ISO_CODES, false)
 475 fi
 476
 477 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 478 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 479 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 480   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 481       HAVE_ZLIB="yes"
 482     ], [
 483       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 484         HAVE_ZLIB="yes"
 485         ZLIB_LIBS="-lz"
 486         AC_SUBST(ZLIB_LIBS)
 487       ])
 488     ])
 489 ])
 490
 491 dnl *** sys plug-ins ***
 492
 493 echo
 494 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 495 echo
 496
 497 dnl *** X11 ***
 498 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 499 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 500                   [ximagesink], [
 501   AC_PATH_XTRA
 502   ac_cflags_save="$CFLAGS"
 503   ac_cppflags_save="$CPPFLAGS"
 504   CFLAGS="$CFLAGS $X_CFLAGS"
 505   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 506
 507   dnl now try to find the HEADER
 508   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 509
 510   if test "x$HAVE_X" = "xno"
 511   then
 512     AC_MSG_NOTICE([cannot find X11 development files])
 513   else
 514     dnl this is much more than we want
 515     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 516     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 517     dnl it does not add the libs; therefore we add them here
 518     X_LIBS="$X_LIBS -lX11"
 519     AC_SUBST(X_CFLAGS)
 520     AC_SUBST(X_LIBS)
 521   fi
 522   AC_SUBST(HAVE_X)
 523   CFLAGS="$ac_cflags_save"
 524   CPPFLAGS="$ac_cppflags_save"
 525 ])
 526
 527 dnl Check for Xv extension
 528 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 529 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 530                   [xvimagesink], [
 531   AG_GST_CHECK_XV
 532 ])
 533
 534 dnl check for X Shm
 535 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 536 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 537   if test x$HAVE_X = xyes; then
 538     AC_CHECK_LIB(Xext, XShmAttach,
 539                  HAVE_XSHM="yes", HAVE_XSHM="no",
 540                  $X_LIBS)
 541     if test "x$HAVE_XSHM" = "xyes"; then
 542       XSHM_LIBS="-lXext"
 543     else
 544       dnl On AIX, it is in XextSam instead, but we still need -lXext
 545       AC_CHECK_LIB(XextSam, XShmAttach,
 546                    HAVE_XSHM="yes", HAVE_XSHM="no",
 547                    $X_LIBS)
 548       if test "x$HAVE_XSHM" = "xyes"; then
 549         XSHM_LIBS="-lXext -lXextSam"
 550       fi
 551     fi
 552   fi
 553 ], , [
 554   AC_SUBST(HAVE_XSHM)
 555   AC_SUBST(XSHM_LIBS)
 556 ])
 557
 558 dnl *** ext plug-ins ***
 559 dnl keep this list sorted alphabetically !
 560
 561 if test "x$BUILD_EXTERNAL" = "xyes"; then
 562
 563 echo
 564 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 565 echo
 566
 567 dnl *** alsa ***
 568 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 569 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 570   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 571     HAVE_ALSA="yes"
 572     AC_SUBST(ALSA_CFLAGS)
 573     AC_SUBST(ALSA_LIBS)
 574   ], [
 575     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 576   ])
 577 ])
 578
 579 dnl *** CDParanoia ***
 580 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 581 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 582 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 583   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 584     HAVE_CDPARANOIA="yes"
 585   ], [
 586     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 587                         cdda_open, -lm,
 588                         cdda_interface.h,
 589                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 590                         HEADER_DIR="no"
 591                         FOUND_CDPARANOIA="yes")
 592     if test "x$FOUND_CDPARANOIA" != "xyes";
 593     then
 594       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 595                           cdda_open, -lm,
 596                           cdda/cdda_interface.h,
 597                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 598                           HEADER_DIR="yes"
 599                           FOUND_CDPARANOIA="yes")
 600     fi
 601     if test "x$HEADER_DIR" = "xyes";
 602     then
 603       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 604                          defined if cdda headers are in a cdda/ directory)
 605     fi
 606     if test "x$FOUND_CDPARANOIA" = "xyes";
 607     then
 608       AC_CHECK_LIB(cdda_paranoia,
 609                    paranoia_cachemodel_size,
 610                    : ,
 611                    HAVE_CDPARANOIA=no,
 612                  [-lcdda_interface])
 613     fi
 614
 615     AC_SUBST(CDPARANOIA_LIBS)
 616   ])
 617 ])
 618 dnl FIXME : add second check somehow if that is necessary
 619 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 620 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 621
 622 dnl *** ivorbis ***
 623 dnl AM_PATH_IVORBIS only takes two options
 624 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 625 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 626   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 627   if test $HAVE_IVORBIS = no
 628   then
 629     IVORBIS_LIBS=
 630     IVORBIS_CFLAGS=
 631     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 632       [IVORBIS_LIBS=-lvorbisidec
 633       HAVE_IVORBIS=yes
 634       case $host in
 635       arm-*-*)
 636         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 637       esac
 638       ],
 639       HAVE_IVORBIS=no)
 640     AC_SUBST(IVORBIS_LIBS)
 641     AC_SUBST(IVORBIS_CFLAGS)
 642   else
 643     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 644       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 645       USE_TREMOLO=no)
 646   fi
 647 ])
 648
 649 dnl *** libgio ***
 650 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 651 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 652   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 653     HAVE_GIO="yes"
 654     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 655     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 656            [The GIO modules directory.])
 657     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 658     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 659            [The GIO library directory.])
 660   ], [
 661     HAVE_GIO="no"
 662   ])
 663   AC_SUBST(GIO_CFLAGS)
 664   AC_SUBST(GIO_LIBS)
 665   AC_SUBST(GIO_LDFLAGS)
 666 ])
 667
 668 dnl *** libvisual ***
 669 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 670 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 671   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 672   if test $HAVE_LIBVISUAL = no
 673   then
 674     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 675     if test x$HAVE_LIBVISUAL = xyes; then
 676       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 677     fi
 678   else
 679     if test x$HAVE_LIBVISUAL = xyes; then
 680       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 681     fi
 682   fi
 683   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 684   if test x$LIBVIS_PLUGINSDIR != x; then
 685     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 686         "$LIBVIS_PLUGINSDIR",
 687         [directory in which the detected libvisual's plugins are located])
 688   fi
 689 ])
 690
 691 dnl *** ogg ***
 692 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 693 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 694   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 695   if test $HAVE_OGG = no
 696   then
 697     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 698     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 699   fi
 700 ])
 701
 702 dnl *** pango ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 704 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 705   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 706 ])
 707
 708 dnl *** theora ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 710 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 711   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 712 ])
 713
 714 dnl *** vorbis ***
 715 dnl AM_PATH_VORBIS only takes two options
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 717 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 718   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 719   if test $HAVE_VORBIS = no
 720   then
 721     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 722     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 723   fi
 724 ])
 725
 726 if test "x$HAVE_VORBIS" = "xyes"; then
 727   ac_cflags_save="$CFLAGS"
 728   AC_COMPILE_IFELSE(
 729     AC_LANG_PROGRAM([
 730 #include <vorbis/codec.h>
 731                      ],[
 732 vorbis_dsp_state *v;
 733
 734 vorbis_synthesis_restart (v);
 735                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 736   if test "x$HAVE_VSR" = "xyes"; then
 737     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 738                        [defined if vorbis_synthesis_restart is present])
 739   fi
 740   CFLAGS="$ac_cflags_save"
 741 fi
 742
 743 else
 744
 745 dnl not building plugins with external dependencies,
 746 dnl but we still need to set the conditionals
 747 AM_CONDITIONAL(USE_ALSA, false)
 748 AM_CONDITIONAL(USE_CDPARANOIA, false)
 749 AM_CONDITIONAL(USE_GIO, false)
 750 AM_CONDITIONAL(USE_IVORBIS, false)
 751 AM_CONDITIONAL(USE_LIBVISUAL, false)
 752 AM_CONDITIONAL(USE_OGG, false)
 753 AM_CONDITIONAL(USE_PANGO, false)
 754 AM_CONDITIONAL(USE_THEORA, false)
 755 AM_CONDITIONAL(USE_VORBIS, false)
 756
 757 fi dnl of EXT plugins
 758
 759 dnl seeking needs freetype, so check for it here
 760 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 761   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 762 ])
 763 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 764 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 765 AC_SUBST(FT2_CFLAGS)
 766 AC_SUBST(FT2_LIBS)
 767
 768 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 769
 770 dnl Overview:
 771 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 772 dnl GST_*:              flags shared by built objects to link against GStreamer
 773 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 774 dnl                          (compare to other modules) or for i18n
 775 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 776 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 777 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 778 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 779
 780 dnl GST_OPTION_CFLAGS
 781 if test "x$USE_DEBUG" = xyes; then
 782    PROFILE_CFLAGS="-g"
 783 fi
 784 AC_SUBST(PROFILE_CFLAGS)
 785
 786 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 787   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 788   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 789 else
 790   DEPRECATED_CFLAGS=""
 791 fi
 792 AC_SUBST(DEPRECATED_CFLAGS)
 793
 794 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 795 dnl at make time with e.g. make ERROR_CFLAGS=""
 796 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 797 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 798 AC_SUBST(GST_OPTION_CFLAGS)
 799 AC_SUBST(GST_OPTION_CXXFLAGS)
 800
 801 dnl our libraries need to be versioned correctly
 802 AC_SUBST(GST_LT_LDFLAGS)
 803
 804 dnl GST_PLUGINS_BASE_CFLAGS
 805 dnl prefer internal headers to already installed ones
 806 dnl also add builddir include for enumtypes and marshal
 807 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 808 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 809
 810 dnl FIXME: do we want to rename to GST_ALL_* ?
 811 dnl add GST_OPTION_CFLAGS, but overridable
 812 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 813 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 814 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 815 AC_SUBST(GST_CFLAGS)
 816 AC_SUBST(GST_CXXFLAGS)
 817 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 818 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 819 AC_SUBST(GST_LIBS)
 820
 821 dnl LDFLAGS really should only contain flags, not libs - they get added before
 822 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 823 GST_ALL_LDFLAGS="-no-undefined"
 824 if test "x${enable_Bsymbolic}" = "xyes"; then
 825   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 826 fi
 827 AC_SUBST(GST_ALL_LDFLAGS)
 828
 829 dnl GST_LIB_LDFLAGS
 830 dnl linker flags shared by all libraries
 831 dnl LDFLAGS modifier defining exported symbols from built libraries
 832 dnl (export _gst_foo but not __gst_foo)
 833 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 834 AC_SUBST(GST_LIB_LDFLAGS)
 835
 836 dnl this really should only contain flags, not libs - they get added before
 837 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 838 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 839 AC_SUBST(GST_PLUGIN_LDFLAGS)
 840
 841 dnl *** output files ***
 842
 843 AC_CONFIG_FILES(
 844 Makefile
 845 gst-plugins-base.spec
 846 gst/Makefile
 847 gst/adder/Makefile
 848 gst/app/Makefile
 849 gst/audioconvert/Makefile
 850 gst/audiorate/Makefile
 851 gst/audiotestsrc/Makefile
 852 gst/encoding/Makefile
 853 gst/videoconvert/Makefile
 854 gst/gdp/Makefile
 855 gst/playback/Makefile
 856 gst/audioresample/Makefile
 857 gst/subparse/Makefile
 858 gst/tcp/Makefile
 859 gst/typefind/Makefile
 860 gst/videotestsrc/Makefile
 861 gst/videorate/Makefile
 862 gst/videoscale/Makefile
 863 gst/volume/Makefile
 864 sys/Makefile
 865 sys/ximage/Makefile
 866 sys/xvimage/Makefile
 867 ext/Makefile
 868 ext/alsa/Makefile
 869 ext/cdparanoia/Makefile
 870 ext/gio/Makefile
 871 ext/libvisual/Makefile
 872 ext/ogg/Makefile
 873 ext/pango/Makefile
 874 ext/theora/Makefile
 875 ext/vorbis/Makefile
 876 gst-libs/Makefile
 877 gst-libs/gst/Makefile
 878 gst-libs/gst/audio/Makefile
 879 gst-libs/gst/app/Makefile
 880 gst-libs/gst/fft/Makefile
 881 gst-libs/gst/interfaces/Makefile
 882 gst-libs/gst/riff/Makefile
 883 gst-libs/gst/rtp/Makefile
 884 gst-libs/gst/rtsp/Makefile
 885 gst-libs/gst/sdp/Makefile
 886 gst-libs/gst/tag/Makefile
 887 gst-libs/gst/pbutils/Makefile
 888 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 889 gst-libs/gst/video/Makefile
 890 tools/Makefile
 891 pkgconfig/Makefile
 892 pkgconfig/gstreamer-audio.pc
 893 pkgconfig/gstreamer-audio-uninstalled.pc
 894 pkgconfig/gstreamer-app.pc
 895 pkgconfig/gstreamer-app-uninstalled.pc
 896 pkgconfig/gstreamer-fft.pc
 897 pkgconfig/gstreamer-fft-uninstalled.pc
 898 pkgconfig/gstreamer-interfaces.pc
 899 pkgconfig/gstreamer-interfaces-uninstalled.pc
 900 pkgconfig/gstreamer-pbutils.pc
 901 pkgconfig/gstreamer-pbutils-uninstalled.pc
 902 pkgconfig/gstreamer-riff.pc
 903 pkgconfig/gstreamer-riff-uninstalled.pc
 904 pkgconfig/gstreamer-rtp.pc
 905 pkgconfig/gstreamer-rtp-uninstalled.pc
 906 pkgconfig/gstreamer-rtsp.pc
 907 pkgconfig/gstreamer-rtsp-uninstalled.pc
 908 pkgconfig/gstreamer-sdp.pc
 909 pkgconfig/gstreamer-sdp-uninstalled.pc
 910 pkgconfig/gstreamer-tag.pc
 911 pkgconfig/gstreamer-tag-uninstalled.pc
 912 pkgconfig/gstreamer-video.pc
 913 pkgconfig/gstreamer-video-uninstalled.pc
 914 pkgconfig/gstreamer-plugins-base.pc
 915 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 916 tests/Makefile
 917 tests/check/Makefile
 918 tests/examples/Makefile
 919 tests/examples/app/Makefile
 920 tests/examples/audio/Makefile
 921 tests/examples/dynamic/Makefile
 922 tests/examples/encoding/Makefile
 923 tests/examples/fft/Makefile
 924 tests/examples/gio/Makefile
 925 tests/examples/overlay/Makefile
 926 tests/examples/seek/Makefile
 927 tests/examples/snapshot/Makefile
 928 tests/examples/playrec/Makefile
 929 tests/files/Makefile
 930 tests/icles/Makefile
 931 tests/icles/playback/Makefile
 932 docs/Makefile
 933 docs/design/Makefile
 934 docs/libs/Makefile
 935 docs/plugins/Makefile
 936 docs/version.entities
 937 po/Makefile.in
 938 common/Makefile
 939 common/m4/Makefile
 940 m4/Makefile
 941 )
 942
 943 dnl Create the config.h file for Visual Studio builds
 944 dnl Beware of spaces and /'s in some of the shell variable contents.
 945 sed \
 946     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 947     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 948     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 949     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 950     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 951     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 952     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 953     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 954     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 955     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 956     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 957     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 958     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 959     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 960     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 961     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 962     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 963     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 964     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 965     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 966     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 967     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 968     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 969     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 970     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 971     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 972     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 973     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 974     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 975     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 976     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 977     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 978     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 979     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 980     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 981     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 982     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 983     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 984     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 985     config.h.in >win32/common/config.h-new
 986
 987
 988
 989 AC_OUTPUT
 990
 991 AG_GST_OUTPUT_PLUGINS
 992 ORC_OUTPUT
 993