configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [11])
   6 m4_define([dbus_micro_version], [15])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CONFIG_AUX_DIR([build-aux])
  12
  13 m4_pattern_forbid([^AX_],
  14   [Unexpanded AX_ macro found. Please install GNU autoconf-archive])
  15
  16 AC_CANONICAL_HOST
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AC_CONFIG_MACRO_DIR([m4])
  20
  21 AM_INIT_AUTOMAKE([1.13 tar-ustar -Wno-portability subdir-objects])
  22
  23 GETTEXT_PACKAGE=dbus-1
  24 AC_SUBST(GETTEXT_PACKAGE)
  25 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  26
  27 # By default, rebuild autotools files on demand; only use ./missing if the
  28 # user says --disable-maintainer-mode (some distributions like to do this)
  29 AM_MAINTAINER_MODE([enable])
  30
  31 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  32
  33 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  34
  35 # libtool versioning - this applies to libdbus
  36 #
  37 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  38 #
  39
  40 ## increment if the interface has additions, changes, removals.
  41 LT_CURRENT=20
  42
  43 ## increment any time the source changes; set to
  44 ##  0 if you increment CURRENT
  45 LT_REVISION=0
  46
  47 ## increment if any interfaces have been added; set to 0
  48 ## if any interfaces have been changed or removed. removal has
  49 ## precedence over adding, so set to 0 if both happened.
  50 LT_AGE=17
  51
  52 AC_SUBST(LT_CURRENT)
  53 AC_SUBST(LT_REVISION)
  54 AC_SUBST(LT_AGE)
  55 SOVERSION=`expr ${LT_CURRENT} - ${LT_AGE}`
  56 AC_SUBST([SOVERSION])
  57
  58 DBUS_MAJOR_VERSION=dbus_major_version
  59 DBUS_MINOR_VERSION=dbus_minor_version
  60 DBUS_MICRO_VERSION=dbus_micro_version
  61 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  62
  63 AC_SUBST(DBUS_MAJOR_VERSION)
  64 AC_SUBST(DBUS_MINOR_VERSION)
  65 AC_SUBST(DBUS_MICRO_VERSION)
  66 AC_SUBST(DBUS_VERSION)
  67
  68 dnl
  69 dnl Build configuration
  70 dnl
  71
  72 dnl This must come first: other options use this to set their defaults. Don't
  73 dnl enable developer mode on production builds.
  74 AC_ARG_ENABLE([developer],
  75   [AS_HELP_STRING([--enable-developer],
  76     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
  77   [enable_developer=$enableval],
  78   [enable_developer=no])
  79
  80 dnl 'disable_developer' is the negation of 'enable_developer'. If
  81 dnl 'enable-developer' is set to 'no' (the default), the value of
  82 dnl 'disable_developer' is set to 'yes', and vice versa. It's used
  83 dnl for macros that require the opposite of 'enable_developer', such
  84 dnl as several AX_ macros.
  85 dnl See https://bugs.freedesktop.org/show_bug.cgi?id=97357
  86 AS_IF([test "x$enable_developer" = "xyes"],[
  87     disable_developer=no
  88   ],[
  89     disable_developer=yes
  90   ])
  91
  92 # The debugging check must run before the compiler tests. Other command-line
  93 # options also use it to set their defaults. We disable debugging by default,
  94 # except for developer builds.
  95 AX_CHECK_ENABLE_DEBUG([$enable_developer])
  96
  97 AC_PROG_CC
  98 AM_PROG_CC_C_O
  99 AC_PROG_CXX
 100 AC_USE_SYSTEM_EXTENSIONS
 101 AC_SYS_LARGEFILE
 102 AC_ISC_POSIX
 103 AC_HEADER_STDC
 104 AC_C_INLINE
 105 AM_PROG_LIBTOOL
 106 AC_PROG_MKDIR_P
 107 PKG_PROG_PKG_CONFIG
 108
 109 # TAP test driver support
 110 AC_PROG_AWK
 111 AC_REQUIRE_AUX_FILE([tap-driver.sh])
 112
 113 # This must come before we set up compiler warnings because it assumes
 114 # non-use of -Werror=missing-prototypes
 115 gl_VISIBILITY
 116 AM_CONDITIONAL([HAVE_VISIBILITY], [test "x$HAVE_VISIBILITY" = x1])
 117
 118 # Initialize libtool
 119 LT_INIT([win32-dll])
 120 LT_LANG([Windows Resource])
 121
 122 # Set some internal variables depending on the platform for later use.
 123 dbus_win=no
 124 dbus_cygwin=no
 125 dbus_unix=no
 126 case "${host}" in
 127     *-mingw32ce*)
 128         dbus_win=yes
 129         dbus_wince=yes
 130         ;;
 131     *-mingw32*)
 132         dbus_win=yes
 133         ;;
 134     *-cygwin*)
 135         dbus_cygwin=yes
 136         dbus_unix=yes
 137         ;;
 138     *)
 139         dbus_unix=yes
 140        ;;
 141 esac
 142
 143 # Special defines for certain platforms
 144 if test "$dbus_win" = yes; then
 145     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 146     # Yes, on Windows it really does work like this.
 147     # http://support.microsoft.com/kb/111855
 148     AC_DEFINE(FD_SETSIZE,8192,[The maximum number of connections that can be handled at once])
 149     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 150     AC_SUBST(BUILD_TIMESTAMP)
 151     # Assume DBUS_VERSION is always three numbers
 152     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 153     AC_SUBST(BUILD_FILEVERSION)
 154     AC_CHECK_TOOL(WINDRES, windres, no)
 155     if test "$WINDRES" = no; then
 156       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 157     fi
 158     if test "$dbus_wince" = yes; then
 159       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 160       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 161     fi
 162 else
 163     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 164 fi
 165 if test "$dbus_cygwin" = yes; then
 166     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 167 fi
 168
 169 # For best security, assume that all non-Windows platforms can do
 170 # credentials-passing.
 171 AS_IF([test "$dbus_win" = yes],
 172     [DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL="<!--<auth>EXTERNAL</auth>-->"],
 173     [DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL="<auth>EXTERNAL</auth>"])
 174 AC_SUBST([DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL])
 175
 176 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 177 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 178 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 179 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 180
 181 DBUS_STATIC_BUILD_CPPFLAGS=
 182 if test "x$enable_shared" = xno; then
 183     # On Windows, linking against the static library requires special effort
 184     # to turn off DLL import/export processing. We normally link some things
 185     # against the dynamic library, but if we're not building that, we'll
 186     # have to link everything statically.
 187     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 188 fi
 189 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 190
 191 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 192 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 193 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 194 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 195 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 196 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 197 AC_ARG_ENABLE([ducktype-docs],
 198               AS_HELP_STRING([--enable-ducktype-docs],
 199                              [build Ducktype documentation (requires Ducktype)]),
 200               [enable_ducktype_docs=$enableval], [enable_ducktype_docs=auto])
 201 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 202 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 203 AC_ARG_ENABLE([apparmor],
 204   [AS_HELP_STRING([--enable-apparmor], [build with AppArmor support])],
 205   [enable_apparmor=$enableval],
 206   [enable_apparmor=auto])
 207 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 208 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 209 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 210 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 211 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 212 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 213
 214 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 215 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 216 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 217 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 218 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 219 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 220 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 221 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 222 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 223 AC_ARG_WITH([test_user],
 224   [AS_HELP_STRING([--with-test-user=<user>],
 225     [Unprivileged user for regression tests, other than root and the dbus_user (default: nobody)])])
 226 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 227
 228 AC_ARG_ENABLE([embedded-tests],
 229   AS_HELP_STRING([--enable-embedded-tests],
 230     [enable unit test code in the library and binaries]),
 231   [], [enable_embedded_tests=$enable_developer])
 232 AC_ARG_ENABLE([modular-tests],
 233   AS_HELP_STRING([--enable-modular-tests],
 234     [enable modular regression tests (requires GLib)]),
 235   [], [enable_modular_tests=auto])
 236 # --enable-tests overrides both --enable-embedded-tests and
 237 # --enable-modular-tests
 238 AC_ARG_ENABLE([tests],
 239   AS_HELP_STRING([--enable-tests],
 240     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 241   [
 242   if test "x$enableval" = xyes; then
 243     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 244     AC_MSG_NOTICE([This has many dependencies (GLib, Python etc.)])
 245   fi
 246   enable_embedded_tests=$enableval
 247   enable_modular_tests=$enableval
 248   ],
 249   [])
 250
 251 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 252 # and also some stuff in the test/ subdir.
 253 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 254   [test "x$enable_embedded_tests" = xyes])
 255 if test "x$enable_embedded_tests" = xyes; then
 256     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 257       [Define to build test code into the library and binaries])
 258 fi
 259
 260 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 261 # These use GTest, from GLib, because life's too short. They're enabled by
 262 # default (unless you don't have GLib), because they don't bloat the library
 263 # or binaries.
 264
 265 AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_40], [Ignore post-2.40 deprecations])
 266 AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [GLIB_VERSION_2_40], [Prevent post-2.40 APIs])
 267
 268 with_glib=yes
 269
 270 AS_IF([test "x$enable_modular_tests" != xno],
 271   [
 272   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.40, gio-2.0 >= 2.40],
 273     [
 274       AS_IF([test "x$dbus_unix" = xyes],
 275         [PKG_CHECK_MODULES([GIO_UNIX], [gio-unix-2.0],
 276            [AC_DEFINE([HAVE_GIO_UNIX], [1], [Define if you have gio-unix-2.0])], [])])
 277     ],
 278     [if test "x$enable_modular_tests" = xyes; then
 279       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 280       AC_MSG_ERROR([$GLIB_ERRORS])
 281     else # assumed to be "auto"
 282       with_glib=no
 283     fi])
 284   ],
 285   [with_glib=no])
 286
 287 if test "x$enable_modular_tests" != xno; then
 288   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 289     [Define to build independent test binaries])
 290 fi
 291 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 292   [test "x$enable_modular_tests" != xno])
 293
 294 if test "x$with_glib" != xno; then
 295   AC_DEFINE([DBUS_WITH_GLIB], [1],
 296     [Define if GLib, GObject, GIO are available])
 297 fi
 298 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 299
 300 AC_ARG_ENABLE([installed-tests],
 301   AS_HELP_STRING([--enable-installed-tests],
 302     [enable unit test code in the library and binaries]),
 303   [], [enable_installed_tests=no])
 304 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 305   [test "x$enable_installed_tests" = xyes])
 306
 307 if test "x$enable_tests" = xyes; then
 308   # full test coverage is required, Python is a hard dependency
 309   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygi])
 310   AM_PATH_PYTHON([2.6])
 311   AC_MSG_CHECKING([for Python modules for full test coverage])
 312   if "$PYTHON" -c "import dbus, gi.repository.GObject, dbus.mainloop.glib"; then
 313     AC_MSG_RESULT([yes])
 314   else
 315     AC_MSG_RESULT([no])
 316     AC_MSG_ERROR([cannot import dbus, gi.repository.GObject, dbus.mainloop.glib Python modules])
 317   fi
 318 else
 319   # --enable-tests not given: do not abort if Python is missing
 320   AM_PATH_PYTHON([2.6], [], [:])
 321 fi
 322
 323 if test x$enable_verbose_mode = xyes; then
 324     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 325 fi
 326
 327 dnl Intentional:
 328 dnl - $DISABLE_WARNINGS disables unused-label warnings if not
 329 dnl   checking or not asserting (tested further below)
 330 dnl - missing field initializers being 0 is a C feature, not a bug
 331 dnl - unused-parameter is to make writing callbacks less annoying
 332 DISABLE_WARNINGS="$DISABLE_WARNINGS
 333                   -Wno-missing-field-initializers
 334                   -Wno-unused-parameter"
 335
 336 if test x$enable_asserts = xno; then
 337     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 338     DISABLE_WARNINGS="$DISABLE_WARNINGS -Wno-unused-label"
 339     R_DYNAMIC_LDFLAG=""
 340     if test x$enable_embedded_tests = xyes; then
 341         DISABLE_WARNINGS="$DISABLE_WARNINGS
 342                           -Wno-unused-but-set-variable
 343                           -Wno-unused-variable
 344                           -Wno-unused-function"
 345     fi
 346 else
 347     # -rdynamic is needed for glibc's backtrace_symbols to work.
 348     # No clue how much overhead this adds, but it's useful
 349     # to do this on any assertion failure,
 350     # so for now it's enabled anytime asserts are (currently not
 351     # in production builds).
 352
 353     # To get -rdynamic you pass -export-dynamic to libtool.
 354     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 355     R_DYNAMIC_LDFLAG=-export-dynamic
 356 fi
 357 AC_SUBST(R_DYNAMIC_LDFLAG)
 358
 359 if test x$enable_checks = xno; then
 360     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 361     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 362     DISABLE_WARNINGS="$DISABLE_WARNINGS -Wno-unused-label"
 363 fi
 364
 365 AH_BOTTOM([
 366 /* explicitly define these macros to get less confusing conditions */
 367 #ifndef DBUS_DISABLE_ASSERT
 368 #  define DBUS_ENABLE_ASSERT 1
 369 #endif
 370 #ifndef DBUS_DISABLE_CHECKS
 371 #  define DBUS_ENABLE_CHECKS 1
 372 #endif])
 373
 374 # Test for code-coverage tools if --enable-code-coverage
 375 AX_CODE_COVERAGE
 376
 377 AS_IF([test x$enable_code_coverage = xyes],[
 378     AC_DEFINE_UNQUOTED(
 379       [DBUS_GCOV_ENABLED], [1],
 380       [Defined if gcov is enabled to force a rebuild due to config.h changing])
 381   ])
 382
 383 #### Integer sizes
 384
 385 AC_CHECK_SIZEOF(char)
 386 AC_CHECK_SIZEOF(short)
 387 AC_CHECK_SIZEOF(long)
 388 AC_CHECK_SIZEOF(int)
 389 AC_CHECK_SIZEOF(void *)
 390 AC_CHECK_SIZEOF(long long)
 391 AC_CHECK_SIZEOF(__int64)
 392
 393 ### See what our 64 bit type is called
 394 AC_MSG_CHECKING([64-bit integer type])
 395
 396 case 8 in
 397 $ac_cv_sizeof_int)
 398   dbusint64=int
 399   dbusint64_constant='(val)'
 400   dbusuint64_constant='(val)'
 401   ;;
 402 $ac_cv_sizeof_long)
 403   dbusint64=long
 404   dbusint64_constant='(val##L)'
 405   dbusuint64_constant='(val##UL)'
 406   ;;
 407 $ac_cv_sizeof_long_long)
 408   dbusint64='long long'
 409   dbusint64_constant='(val##LL)'
 410   dbusuint64_constant='(val##ULL)'
 411   ;;
 412 $ac_cv_sizeof___int64)
 413   dbusint64=__int64
 414   dbusint64_constant='(val##i64)'
 415   dbusuint64_constant='(val##ui64)'
 416   ;;
 417 esac
 418
 419 AS_IF(
 420   [test -z "$dbusint64"],
 421   [AC_MSG_RESULT([not found])
 422   AC_MSG_ERROR([Could not find a 64-bit integer type.
 423
 424 Please report a bug here with details of your platform and compiler:
 425
 426     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core])
 427   ],
 428   dnl else
 429   [
 430         DBUS_INT64_TYPE="$dbusint64"
 431         DBUS_INT64_CONSTANT="$dbusint64_constant"
 432         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 433         AC_MSG_RESULT($DBUS_INT64_TYPE)
 434   ])
 435
 436 AC_SUBST(DBUS_INT64_TYPE)
 437 AC_SUBST(DBUS_INT64_CONSTANT)
 438 AC_SUBST(DBUS_UINT64_CONSTANT)
 439
 440 ### see what 32-bit int is called
 441 AC_MSG_CHECKING([32-bit integer type])
 442
 443 case 4 in
 444 $ac_cv_sizeof_short)
 445   dbusint32=short
 446   ;;
 447 $ac_cv_sizeof_int)
 448   dbusint32=int
 449   ;;
 450 $ac_cv_sizeof_long)
 451   dbusint32=long
 452   ;;
 453 esac
 454
 455 if test -z "$dbusint32" ; then
 456         DBUS_INT32_TYPE="no_int32_type_detected"
 457         AC_MSG_ERROR([No 32-bit integer type found])
 458 else
 459         DBUS_INT32_TYPE="$dbusint32"
 460         AC_MSG_RESULT($DBUS_INT32_TYPE)
 461 fi
 462
 463 AC_SUBST(DBUS_INT32_TYPE)
 464
 465 ### see what 16-bit int is called
 466 AC_MSG_CHECKING([16-bit integer type])
 467
 468 case 2 in
 469 $ac_cv_sizeof_short)
 470   dbusint16=short
 471   ;;
 472 $ac_cv_sizeof_int)
 473   dbusint16=int
 474   ;;
 475 esac
 476
 477 if test -z "$dbusint16" ; then
 478         DBUS_INT16_TYPE="no_int16_type_detected"
 479         AC_MSG_ERROR([No 16-bit integer type found])
 480 else
 481         DBUS_INT16_TYPE="$dbusint16"
 482         AC_MSG_RESULT($DBUS_INT16_TYPE)
 483 fi
 484
 485 AC_SUBST(DBUS_INT16_TYPE)
 486
 487 ## byte order
 488 case $host_os in
 489         darwin*)
 490                 # check at compile-time, so that it is possible to build universal
 491                 # (with multiple architectures at once on the compile line)
 492                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 493                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 494                         #if defined(__BIG_ENDIAN__)
 495                         #define WORDS_BIGENDIAN 1
 496                         #endif
 497                 ])
 498                 ;;
 499         *)
 500                 AC_C_BIGENDIAN
 501                 ;;
 502 esac
 503
 504 # As a GNU extension, glibc declares environ in unistd.h, which is one of
 505 # the AC_INCLUDES_DEFAULT.
 506 AC_CHECK_DECLS([environ])
 507
 508 dnl **********************************
 509 dnl *** va_copy checks (from GLib) ***
 510 dnl **********************************
 511 dnl we currently check for all three va_copy possibilities, so we get
 512 dnl all results in config.log for bug reports.
 513 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 514         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 515 #include <stdlib.h>
 516         static void f (int i, ...) {
 517         va_list args1, args2;
 518         va_start (args1, i);
 519         va_copy (args2, args1);
 520         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 521           exit (1);
 522         va_end (args1); va_end (args2);
 523         }
 524         int main() {
 525           f (0, 42);
 526           return 0;
 527         }])],
 528         [dbus_cv_va_copy=yes],
 529         [dbus_cv_va_copy=no])
 530 ])
 531 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 532         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 533 #include <stdlib.h>
 534         static void f (int i, ...) {
 535         va_list args1, args2;
 536         va_start (args1, i);
 537         __va_copy (args2, args1);
 538         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 539           exit (1);
 540         va_end (args1); va_end (args2);
 541         }
 542         int main() {
 543           f (0, 42);
 544           return 0;
 545         }])],
 546         [dbus_cv___va_copy=yes],
 547         [dbus_cv___va_copy=no])
 548 ])
 549
 550 if test "x$dbus_cv_va_copy" = "xyes"; then
 551   dbus_va_copy_func=va_copy
 552 else if test "x$dbus_cv___va_copy" = "xyes"; then
 553   dbus_va_copy_func=__va_copy
 554 fi
 555 fi
 556
 557 if test -n "$dbus_va_copy_func"; then
 558   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 559 fi
 560
 561 AC_LANG_PUSH(C)
 562 AC_CACHE_CHECK([whether va_lists can be copied by value],
 563         dbus_cv_va_val_copy,
 564         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 565 [[
 566         #include <stdarg.h>
 567         #include <stdlib.h>
 568 ]],
 569 [[
 570         static void f (int i, ...) {
 571         va_list args1, args2;
 572         va_start (args1, i);
 573         args2 = args1;
 574         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 575           exit (1);
 576         va_end (args1); va_end (args2);
 577         }
 578         int main() {
 579           f (0, 42);
 580           return 0;
 581         }
 582 ]])],
 583         [dbus_cv_va_val_copy=yes],
 584         [dbus_cv_va_val_copy=no],
 585         [dbus_cv_va_val_copy=yes])
 586 ])
 587 AC_LANG_POP(C)
 588
 589 if test "x$dbus_cv_va_val_copy" = "xno"; then
 590   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 591 fi
 592
 593
 594 #### Atomic integers
 595
 596 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 597   dbus_cv_sync_sub_and_fetch,
 598   [AC_LINK_IFELSE([
 599      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 600      [dbus_cv_sync_sub_and_fetch=yes],
 601      [dbus_cv_sync_sub_and_fetch=no])
 602   ])
 603
 604 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 605    have_sync=1
 606 else
 607    have_sync=0
 608 fi
 609
 610 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 611
 612 #### Various functions
 613 AC_SEARCH_LIBS(socket,[socket network])
 614 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 615
 616 AC_CHECK_FUNCS([vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid setresuid getrlimit])
 617
 618 AC_CHECK_HEADERS([syslog.h])
 619 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 620   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 621 fi
 622
 623 # For test-segfault.c
 624 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 625 AC_CHECK_FUNCS_ONCE([prctl raise])
 626
 627 #### Check for broken poll; taken from Glib's configure
 628
 629 AC_MSG_CHECKING([for broken poll])
 630 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 631     #include <stdlib.h>
 632     #include <fcntl.h>
 633     #include <poll.h>
 634     #ifdef HAVE_SYS_POLL_H
 635     #include <sys/poll.h>
 636     #endif
 637     int main(void) {
 638       struct pollfd fds[1];
 639       int fd;
 640       fd = open("/dev/null", 1);
 641       fds[0].fd = fd;
 642       fds[0].events = POLLIN;
 643       fds[0].revents = 0;
 644       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 645             exit(1);  /* Does not work for devices -- fail */
 646       }
 647       exit(0);
 648     }]])],
 649   [broken_poll=no],
 650   [broken_poll=yes
 651    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 652   [broken_poll="no (cross compiling)"])
 653 AC_MSG_RESULT($broken_poll)
 654
 655 AC_MSG_CHECKING(for dirfd)
 656 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 657 #include <sys/types.h>
 658 #include <dirent.h>
 659 ]], [[
 660 DIR *dirp;
 661 dirp = opendir(".");
 662 dirfd(dirp);
 663 closedir(dirp);
 664 ]])],
 665 [dbus_have_dirfd=yes],
 666 [dbus_have_dirfd=no])
 667 AC_MSG_RESULT($dbus_have_dirfd)
 668 if test "$dbus_have_dirfd" = yes; then
 669         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 670 else
 671         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 672         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 673 #include <sys/types.h>
 674 #include <dirent.h>
 675         ]], [[
 676 DIR *dirp;
 677 int fd;
 678 dirp = opendir(".");
 679 fd = dirp->dd_fd;
 680 closedir(dirp);
 681         ]])],
 682         [dbus_have_ddfd=yes],
 683         [dbus_have_ddfd=no])
 684         AC_MSG_RESULT($dbus_have_ddfd)
 685         if test "$dbus_have_ddfd" = yes; then
 686                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 687         fi
 688 fi
 689
 690 AC_CHECK_HEADERS(sys/resource.h)
 691
 692 AC_CHECK_HEADERS(dirent.h)
 693
 694 AC_CHECK_HEADERS([execinfo.h],
 695         [AC_SEARCH_LIBS([backtrace], [execinfo],
 696                 [AC_DEFINE([HAVE_BACKTRACE], [1],
 697                         [Define to 1 if you have backtrace().])])])
 698
 699 AC_CHECK_HEADERS(errno.h)
 700
 701 AC_CHECK_HEADERS(signal.h)
 702
 703 AC_CHECK_HEADERS(locale.h)
 704
 705 AC_CHECK_HEADERS(byteswap.h)
 706
 707 AC_CHECK_HEADERS(unistd.h)
 708
 709 AC_CHECK_HEADERS([stdint.h])
 710
 711 AC_CHECK_HEADERS(ws2tcpip.h)
 712
 713 AC_CHECK_HEADERS(alloca.h)
 714
 715 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 716 #
 717 case $host_os in
 718     solaris*)
 719        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 720 esac
 721
 722 # checking for a posix version of getpwnam_r
 723 # if we are cross compiling and can not run the test
 724 # assume getpwnam_r is the posix version
 725 # it is up to the person cross compiling to change
 726 # this behavior if desired
 727 AC_LANG_PUSH(C)
 728 AC_CACHE_CHECK([for posix getpwnam_r],
 729                 ac_cv_func_posix_getpwnam_r,
 730                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 731 [[
 732 #include <errno.h>
 733 #include <pwd.h>
 734 ]],
 735 [[
 736     char buffer[10000];
 737     struct passwd pwd, *pwptr = &pwd;
 738     int error;
 739     errno = 0;
 740     error = getpwnam_r ("", &pwd, buffer,
 741                         sizeof (buffer), &pwptr);
 742    return (error < 0 && errno == ENOSYS)
 743            || error == ENOSYS;
 744 ]])],
 745         [ac_cv_func_posix_getpwnam_r=yes],
 746         [ac_cv_func_posix_getpwnam_r=no],
 747         [ac_cv_func_posix_getpwnam_r=yes]
 748 )])
 749 AC_LANG_POP(C)
 750
 751 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 752         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 753                 [Have POSIX function getpwnam_r])
 754 else
 755         AC_CACHE_CHECK([for nonposix getpwnam_r],
 756                 ac_cv_func_nonposix_getpwnam_r,
 757                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 758                         struct passwd pwd;
 759                         getpwnam_r ("", &pwd, buffer,
 760                                         sizeof (buffer));]])],
 761                         [ac_cv_func_nonposix_getpwnam_r=yes],
 762                         [ac_cv_func_nonposix_getpwnam_r=no])])
 763                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 764                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 765                         [Have non-POSIX function getpwnam_r])
 766         fi
 767 fi
 768
 769 dnl check for socklen_t
 770 AC_MSG_CHECKING(whether socklen_t is defined)
 771 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 772 #include <sys/types.h>
 773 #include <sys/socket.h>
 774 #include <netdb.h>
 775 ]], [[
 776 socklen_t foo;
 777 foo = 1;
 778 ]])],
 779 [dbus_have_socklen_t=yes],
 780 [dbus_have_socklen_t=no])
 781 AC_MSG_RESULT($dbus_have_socklen_t)
 782
 783 if test "x$dbus_have_socklen_t" = "xyes"; then
 784     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 785 fi
 786
 787 dnl check for writev header and writev function so we're
 788 dnl good to go if HAVE_WRITEV gets defined.
 789 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 790
 791 dnl needed on darwin for NAME_MAX
 792 AC_CHECK_HEADERS(sys/syslimits.h)
 793
 794 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 795 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 796 #include <sys/socket.h> ]])
 797
 798 dnl check for flavours of varargs macros (test from GLib)
 799 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 800 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 801 int a(int p1, int p2, int p3);
 802 #define call_a(...) a(1,__VA_ARGS__)
 803 call_a(2,3);
 804 ]])],
 805 [dbus_have_iso_c_varargs=yes],
 806 [dbus_have_iso_c_varargs=no])
 807 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 808
 809 AC_MSG_CHECKING(for GNUC varargs macros)
 810 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 811 int a(int p1, int p2, int p3);
 812 #define call_a(params...) a(1,params)
 813 call_a(2,3);
 814 ]])],
 815 [dbus_have_gnuc_varargs=yes],
 816 [dbus_have_gnuc_varargs=no])
 817 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 818
 819 dnl Output varargs tests
 820 if test x$dbus_have_iso_c_varargs = xyes; then
 821     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 822 fi
 823 if test x$dbus_have_gnuc_varargs = xyes; then
 824     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 825 fi
 826
 827 dnl Check for various credentials.
 828 AC_MSG_CHECKING(for struct cmsgcred)
 829 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 830 #include <sys/types.h>
 831 #include <sys/socket.h>
 832 ]], [[
 833 struct cmsgcred cred;
 834
 835 cred.cmcred_pid = 0;
 836 ]])],
 837 [dbus_have_struct_cmsgcred=yes],
 838 [dbus_have_struct_cmsgcred=no])
 839 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 840
 841 if test x$dbus_have_struct_cmsgcred = xyes; then
 842     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 843 fi
 844
 845 AC_CHECK_MEMBER([struct unpcbid.unp_pid],
 846                 [AC_DEFINE([HAVE_UNPCBID], 1, [Have unpcbid structure])],
 847                 [],
 848                 [[#include <sys/un.h>]])
 849
 850 AC_CHECK_FUNCS(getpeerucred getpeereid)
 851
 852 AC_CHECK_FUNCS(pipe2 accept4)
 853
 854 #### Abstract sockets
 855
 856 if test x$enable_abstract_sockets = xauto; then
 857 AC_LANG_PUSH(C)
 858 warn_on_xcompile=no
 859 AC_CACHE_CHECK([abstract socket namespace],
 860                 ac_cv_have_abstract_sockets,
 861                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 862 [[
 863 #include <sys/types.h>
 864 #include <stdlib.h>
 865 #include <string.h>
 866 #include <stdio.h>
 867 #include <sys/socket.h>
 868 #include <sys/un.h>
 869 #include <errno.h>
 870 ]],
 871 [[
 872   size_t slen;
 873   int listen_fd;
 874   struct sockaddr_un addr;
 875
 876   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 877
 878   if (listen_fd < 0)
 879     {
 880       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 881       exit (1);
 882     }
 883
 884   memset (&addr, '\0', sizeof (addr));
 885   addr.sun_family = AF_UNIX;
 886   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 887   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 888    * beginning.
 889    */
 890   slen = SUN_LEN(&addr);
 891   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 892
 893   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 894     {
 895        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 896                 strerror (errno));
 897        exit (1);
 898     }
 899   else
 900     exit (0);
 901 ]])],
 902               [ac_cv_have_abstract_sockets=yes],
 903               [ac_cv_have_abstract_sockets=no],
 904               [
 905                 ac_cv_have_abstract_sockets=no
 906                 warn_on_xcompile=yes
 907               ]
 908 )])
 909 if test x$warn_on_xcompile = xyes ; then
 910   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 911 fi
 912 AC_LANG_POP(C)
 913 fi
 914
 915 if test x$enable_abstract_sockets = xyes; then
 916     if test x$ac_cv_have_abstract_sockets = xno; then
 917         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 918     fi
 919 fi
 920
 921 if test x$enable_abstract_sockets = xno; then
 922    ac_cv_have_abstract_sockets=no;
 923 fi
 924
 925 if test x$ac_cv_have_abstract_sockets = xyes ; then
 926    DBUS_PATH_OR_ABSTRACT=abstract
 927    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 928 else
 929    DBUS_PATH_OR_ABSTRACT=path
 930 fi
 931
 932 # this is used in addresses to prefer abstract, e.g.
 933 # unix:path=/foo or unix:abstract=/foo
 934 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 935
 936 PKG_CHECK_MODULES([EXPAT], [expat])
 937
 938 # Thread lib detection
 939 AC_ARG_VAR([THREAD_LIBS])
 940 save_libs="$LIBS"
 941 LIBS="$LIBS $THREAD_LIBS"
 942
 943 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 944
 945 # Don't do these automatic checks if the user set THREAD_LIBS on the
 946 # configure command-line. If they did, we assume they're right.
 947 #
 948 # We also don't do these checks on Windows, because you don't need magical
 949 # linker flags to have threading support there.
 950 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 951   [
 952     # Mandatory pthread functions. In principle, some of these could be made
 953     # optional if there are platforms that don't have them.
 954     #
 955     # Currently, we only look in -lpthread.
 956     # In principle we might need to look in -lpthreads, -lthreads, ...
 957     # as well - please file a bug if your platform needs this.
 958     AC_SEARCH_LIBS([pthread_cond_timedwait],
 959         [pthread],
 960         [THREAD_LIBS="$LIBS"],
 961         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 962         [])
 963     AC_SEARCH_LIBS([pthread_mutexattr_init],
 964         [pthread],
 965         [THREAD_LIBS="$LIBS"],
 966         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 967         [])
 968     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 969         [pthread],
 970         [THREAD_LIBS="$LIBS"],
 971         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 972         [])
 973
 974     # Optional, for monotonic clocks. Because it's optional, this check
 975     # is non-fatal if we don't find it.
 976     AC_SEARCH_LIBS([pthread_condattr_setclock],
 977         [pthread],
 978         [THREAD_LIBS="$LIBS"])
 979
 980     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
 981       [
 982         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
 983         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 984         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 985 [[#include <time.h>
 986 #include <pthread.h>
 987 ]], [[
 988 struct timespec monotonic_timer;
 989 pthread_condattr_t attr;
 990 pthread_condattr_init (&attr);
 991 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 992 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 993 ]])],
 994             [have_clock_monotonic=true],
 995             [have_clock_monotonic=false])
 996         AS_IF([test x$have_clock_monotonic = xtrue],
 997           [
 998             AC_MSG_RESULT([found])
 999             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
1000           ],
1001           [AC_MSG_RESULT([not found])])
1002       ]) dnl have pthread_condattr_setclock
1003   ]) dnl on Unix
1004
1005 LIBS="$save_libs"
1006
1007 AC_SUBST([THREAD_LIBS])
1008
1009 # SELinux detection
1010 if test x$enable_selinux = xno ; then
1011     have_selinux=no;
1012 else
1013     # See if we have SELinux library
1014     PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0.86],
1015                  [have_selinux=yes], [have_selinux=no])
1016
1017     if test x$enable_selinux = xauto ; then
1018         if test x$have_selinux = xno ; then
1019                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1020         fi
1021     else
1022         if test x$have_selinux = xno ; then
1023                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1024         fi
1025     fi
1026 fi
1027
1028 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1029
1030 if test x$have_selinux = xyes ; then
1031     # the selinux code creates threads
1032     # which requires libpthread even on linux
1033     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1034                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1035
1036     SELINUX_LIBS="$SELINUX_LIBS $SELINUX_THREAD_LIBS"
1037     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1038 else
1039     SELINUX_LIBS=
1040 fi
1041
1042 # AppArmor detection
1043 AS_IF([test x$enable_apparmor = xno],
1044   [have_apparmor=no],
1045   [
1046   PKG_CHECK_MODULES([APPARMOR], [libapparmor >= 2.8.95],
1047                     [have_apparmor=yes], [have_apparmor=no])
1048   PKG_CHECK_MODULES([APPARMOR_2_10], [libapparmor >= 2.10],
1049                     [have_apparmor_2_10=yes], [have_apparmor_2_10=no])
1050
1051   AS_IF([test x$enable_apparmor = xauto && test x$have_apparmor = xno],
1052         [AC_MSG_WARN([Sufficiently new AppArmor library not found])])
1053   AS_IF([test x$enable_apparmor != xauto && test x$have_apparmor = xno],
1054         [AC_MSG_ERROR([AppArmor explicitly required, and AppArmor library not found])])
1055   ])
1056
1057 AS_IF([test x$have_apparmor = xyes],
1058       [AC_DEFINE([HAVE_APPARMOR], [1], [AppArmor Support])])
1059 AS_IF([test x$have_apparmor_2_10 = xyes],
1060       [AC_DEFINE([HAVE_APPARMOR_2_10], [1],
1061                  [Define if libapparmor is version 2.10 or later])])
1062
1063 # inotify checks
1064 if test x$enable_inotify = xno ; then
1065     have_inotify=no;
1066 else
1067     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1068 fi
1069
1070 dnl check if inotify backend is enabled
1071 if test x$have_inotify = xyes; then
1072    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1073    AC_CHECK_FUNCS(inotify_init1)
1074 fi
1075
1076 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1077
1078 # For simplicity, we require the userland API for epoll_create1 at
1079 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1080 # not to have it at runtime.
1081 AC_ARG_ENABLE([epoll],
1082               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1083               [enable_epoll=$enableval], [enable_epoll=auto])
1084 if test x$enable_epoll = xno; then
1085     have_linux_epoll=no
1086 else
1087     AC_MSG_CHECKING([for Linux epoll(4)])
1088     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1089         [
1090         #ifndef __linux__
1091         #error This is not Linux
1092         #endif
1093         #include <sys/epoll.h>
1094         ],
1095         [epoll_create1 (EPOLL_CLOEXEC);])],
1096         [have_linux_epoll=yes],
1097         [have_linux_epoll=no])
1098     AC_MSG_RESULT([$have_linux_epoll])
1099 fi
1100 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1101     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1102 fi
1103 if test x$have_linux_epoll = xyes; then
1104   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1105 fi
1106 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1107
1108 # kqueue checks
1109 if test x$enable_kqueue = xno ; then
1110     have_kqueue=no
1111 else
1112     have_kqueue=yes
1113     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1114     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1115
1116     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1117         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1118     fi
1119 fi
1120
1121 dnl check if kqueue backend is enabled
1122 if test x$have_kqueue = xyes; then
1123    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1124 fi
1125
1126 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1127
1128 # launchd checks
1129 if test x$enable_launchd = xno ; then
1130     have_launchd=no
1131 else
1132     have_launchd=yes
1133     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1134     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1135     if test "x$LAUNCHCTL" = "x"; then
1136         have_launchd=no
1137     fi
1138
1139     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1140         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1141     fi
1142 fi
1143
1144 dnl check if launchd is enabled
1145 if test x$have_launchd = xyes; then
1146     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1147 fi
1148
1149 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1150
1151 #### Directory to place launchd agent file
1152 if test "x$with_launchd_agent_dir" = "x"; then
1153    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1154 else
1155    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1156 fi
1157
1158 AC_SUBST(LAUNCHD_AGENT_DIR)
1159
1160 dnl console owner file
1161 if test x$enable_console_owner_file = xno ; then
1162     have_console_owner_file=no;
1163 else
1164     case $host_os in
1165     solaris*)
1166         have_console_owner_file=yes;
1167         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1168         ;;
1169     *)
1170         have_console_owner_file=no;;
1171     esac
1172 fi
1173
1174 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1175
1176 dnl systemd detection
1177 if test x$enable_systemd = xno ; then
1178     have_systemd=no;
1179 else
1180     PKG_CHECK_MODULES([SYSTEMD],
1181         [libsystemd >= 209],
1182         [have_systemd=yes],
1183         [PKG_CHECK_MODULES([SYSTEMD],
1184             [libsystemd-login >= 32, libsystemd-daemon >= 32, libsystemd-journal >= 32],
1185             [have_systemd=yes],
1186             [have_systemd=no])])
1187 fi
1188
1189 if test x$have_systemd = xyes; then
1190     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1191 fi
1192
1193 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1194     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1195 fi
1196
1197 # If not found in $PATH, we might still have systemd and systemctl at runtime
1198 # (perhaps dbus is being compiled in a minimal chroot with no systemd).
1199 # Assume the upstream-recommended location. Distributors with split /usr
1200 # can override this with ./configure SYSTEMCTL=/bin/systemctl
1201 AC_PATH_PROG([SYSTEMCTL], [systemctl], [/usr/bin/systemctl])
1202
1203 # libaudit detection
1204 if test x$enable_libaudit = xno ; then
1205     have_libaudit=no;
1206 else
1207     # See if we have audit daemon & capabilities library
1208     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1209                  have_libaudit=yes, have_libaudit=no)
1210     if test x$have_libaudit = xyes ; then
1211         AC_CHECK_LIB(cap-ng, capng_clear,
1212                  have_libaudit=yes, have_libaudit=no)
1213     fi
1214 fi
1215
1216 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1217
1218 if test x$have_libaudit = xyes ; then
1219     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1220     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1221 fi
1222
1223 AC_SUBST([SELINUX_LIBS])
1224
1225 # Check for ADT API (Solaris Basic Security Mode auditing)
1226 AC_MSG_CHECKING(for ADT API)
1227 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1228 #include <bsm/adt.h>
1229 adt_user_context = ADT_USER;
1230 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1231
1232 if test ${check_adt_audit} = yes
1233 then
1234    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1235    ADT_LIBS="-lbsm"
1236    LIBS="-lbsm $LIBS"
1237    AC_MSG_RESULT(yes)
1238 else
1239    AC_MSG_RESULT(no)
1240 fi
1241 AC_SUBST([ADT_LIBS])
1242
1243 # Check for SCM_RIGHTS
1244 AC_MSG_CHECKING([for SCM_RIGHTS])
1245 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1246 #include <sys/types.h>
1247 #include <sys/socket.h>
1248 #include <sys/un.h>
1249 static int x = SCM_RIGHTS;
1250 ]], [[]])],
1251 [ AC_MSG_RESULT([supported])
1252   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1253 [ AC_MSG_RESULT([not supported]) ])
1254
1255 NETWORK_libs=
1256 if test x$dbus_win = xyes ; then
1257   if test x$dbus_wince = xyes ; then
1258     NETWORK_libs="-lws2"
1259   else
1260     NETWORK_libs="-lws2_32 -liphlpapi -ldbghelp"
1261   fi
1262 fi
1263
1264 AC_SUBST([NETWORK_libs])
1265
1266 AC_ARG_WITH([valgrind],
1267   [AS_HELP_STRING([--with-valgrind],
1268      [Add instrumentation to help valgrind to understand our allocator])],
1269   [],
1270   [with_valgrind=no])
1271
1272 AS_IF([test "x$with_valgrind" = xauto],
1273   [PKG_CHECK_EXISTS([valgrind >= 3.6],
1274     [with_valgrind=yes], [with_valgrind=no])])
1275
1276 if test x$with_valgrind != xno; then
1277   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1278   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1279 fi
1280
1281 #### Set up final flags
1282 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs $SYSTEMD_LIBS"
1283 AC_SUBST([LIBDBUS_LIBS])
1284
1285 ### X11 detection
1286 DBUS_X_LIBS=
1287 DBUS_X_CFLAGS=
1288
1289 AC_ARG_ENABLE([x11-autolaunch],
1290   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1291   [], [enable_x11_autolaunch=auto])
1292
1293 if test "x$dbus_win" = xyes; then
1294     if test "x$enable_x11_autolaunch" = xyes; then
1295         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1296     fi
1297
1298     enable_x11_autolaunch=no
1299     have_x11=no
1300 else
1301     AC_PATH_XTRA
1302
1303     if test "x$no_x" = xyes; then
1304         have_x11=no
1305     else
1306         have_x11=yes
1307         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1308         DBUS_X_CFLAGS="$X_CFLAGS"
1309     fi
1310 fi
1311
1312 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1313     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1314 else
1315     # move from "auto" to "yes" or "no" if necessary
1316     if test "x$enable_x11_autolaunch" != xno; then
1317         enable_x11_autolaunch="$have_x11"
1318     fi
1319 fi
1320
1321 if test "x$have_x11" = xyes ; then
1322    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1323 fi
1324
1325 if test "x$enable_x11_autolaunch" = xyes ; then
1326    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1327 fi
1328 AM_CONDITIONAL([DBUS_ENABLE_X11_AUTOLAUNCH],
1329   [test "x$enable_x11_autolaunch" = xyes])
1330
1331 AC_SUBST([DBUS_X_CFLAGS])
1332 AC_SUBST([DBUS_X_LIBS])
1333
1334 # We're treating -fno-common like a warning: it makes the linker more
1335 # strict, because on some systems the linker is *always* this strict
1336 TEST_CFLAGS="$TEST_CFLAGS -fno-common"
1337
1338 AS_IF([test "x$enable_ansi" = "xyes"],[
1339     TEST_CFLAGS="$TEST_CFLAGS -ansi -pedantic"
1340     AC_DEFINE([_POSIX_C_SOURCE],[199309L],[Define to enable POSIX features])
1341     AC_DEFINE([_BSD_SOURCE],[1],[Define to enable BSD features])
1342   ])
1343
1344 dnl We are only calling this for its side-effect of setting up
1345 dnl --enable-compile-warnings; the WARN_CFLAGS, etc. are ignored,
1346 dnl to work around https://github.com/peti/autoconf-archive/pull/96
1347 AX_COMPILER_FLAGS([], [], [$disable_developer])
1348
1349 dnl Work around https://github.com/peti/autoconf-archive/pull/96 by using
1350 dnl a non-default variable name here (in particular there is no way to tell
1351 dnl AX_COMPILER_FLAGS to not use WARN_CXXFLAGS)
1352 AX_COMPILER_FLAGS_CFLAGS([EXTRA_CFLAGS],
1353                          [$disable_developer],
1354                          [$TEST_CFLAGS],
1355                          [-Wchar-subscripts \
1356                           -Wfloat-equal \
1357                           -Wpointer-sign \
1358                           $DISABLE_WARNINGS])
1359 dnl cc1plus: warning: command line option ‘-Wpointer-sign’ is valid for
1360 dnl C/ObjC but not for C++
1361 AX_COMPILER_FLAGS_CXXFLAGS([EXTRA_CXXFLAGS],
1362                            [$disable_developer],
1363                            [],
1364                            [-Wchar-subscripts \
1365                             -Wfloat-equal \
1366                             $DISABLE_WARNINGS])
1367 AX_COMPILER_FLAGS_LDFLAGS([EXTRA_LDFLAGS],
1368                           [$disable_developer])
1369
1370 dnl TODO: In principle we should put EXTRA_CFLAGS in each Makefile.am like
1371 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1372 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1373 dnl is the next best thing.
1374 CFLAGS="$EXTRA_CFLAGS $CFLAGS"
1375 CXXFLAGS="$EXTRA_CXXFLAGS $CXXFLAGS"
1376 LDFLAGS="$EXTRA_LDFLAGS $LDFLAGS"
1377
1378 case $host_os in
1379     solaris*)
1380         # Solaris' C library apparently needs these runes to be threadsafe...
1381         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1382         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1383         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1384         # ... and this opt-in to get file descriptor passing support
1385         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1386         ;;
1387 esac
1388
1389 ### Detect if ld supports --version-script
1390
1391 gl_LD_VERSION_SCRIPT
1392 AM_CONDITIONAL([HAVE_LD_VERSION_SCRIPT],
1393                [test "x$have_ld_version_script" = xyes])
1394 ### Doxygen Documentation
1395
1396 AC_PATH_PROG(DOXYGEN, doxygen, no)
1397
1398 AC_MSG_CHECKING([whether to build Doxygen documentation])
1399
1400 if test x$DOXYGEN = xno ; then
1401     have_doxygen=no
1402 else
1403     have_doxygen=yes
1404 fi
1405
1406 if test x$enable_doxygen_docs = xauto ; then
1407     if test x$have_doxygen = xno ; then
1408         enable_doxygen_docs=no
1409     else
1410         enable_doxygen_docs=yes
1411     fi
1412 fi
1413
1414 if test x$enable_doxygen_docs = xyes; then
1415     if test x$have_doxygen = xno; then
1416         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1417     fi
1418 fi
1419
1420 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1421 AC_MSG_RESULT($enable_doxygen_docs)
1422
1423 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1424 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1425
1426 ### Ducktype/Yelp documentation
1427
1428 AC_PATH_PROG([DUCKTYPE],[ducktype],[no])
1429 AC_PATH_PROG([YELP_BUILD],[yelp-build],[no])
1430
1431 AC_MSG_CHECKING([whether to build Ducktype documentation])
1432
1433 AS_IF([test "$DUCKTYPE" = "no"],[have_ducktype=no],[have_ducktype=yes])
1434 AS_IF([test "$YELP_BUILD" = "no"],[have_yelp_build=no],[have_yelp_build=yes])
1435
1436 AS_IF([test "$enable_ducktype_docs" = "auto"],[
1437     AS_IF([test "$have_ducktype" = "no" || test "$have_yelp_build" = "no"],[
1438         enable_ducktype_docs=no
1439     ],[
1440         enable_ducktype_docs=yes
1441     ])
1442 ])
1443
1444 AS_IF([test "$enable_ducktype_docs" = "yes"],[
1445     AS_IF([test "$have_ducktype" = "no"],[
1446         AC_MSG_ERROR([Building Ducktype docs explicitly required, but ducktype not found])
1447     ])
1448     AS_IF([test "$have_yelp_build" = "no"],[
1449         AC_MSG_ERROR([Building Ducktype docs explicitly required, but yelp-build not found])
1450     ])
1451 ])
1452
1453 AM_CONDITIONAL([DBUS_DUCKTYPE_DOCS_ENABLED],[test "$enable_ducktype_docs" = "yes"])
1454 AC_MSG_RESULT([$enable_ducktype_docs])
1455
1456 ### XML Documentation
1457
1458 AC_PATH_PROG(XMLTO, xmlto, no)
1459
1460 AC_MSG_CHECKING([whether to build XML documentation])
1461
1462 if test x$XMLTO = xno ; then
1463     have_xmlto=no
1464 else
1465     have_xmlto=yes
1466 fi
1467
1468 if test x$enable_xml_docs = xauto ; then
1469     if test x$have_xmlto = xno ; then
1470         enable_xml_docs=no
1471     else
1472         enable_xml_docs=yes
1473     fi
1474 fi
1475
1476 if test x$enable_xml_docs = xyes; then
1477     if test x$have_xmlto = xno; then
1478         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1479     fi
1480 fi
1481
1482 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1483 AC_MSG_RESULT($enable_xml_docs)
1484
1485 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1486     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes &&
1487      test x$enable_ducktype_docs = xyes])
1488
1489 # Autoconf 2.70 will support this, and many distros patch this option in,
1490 # but Autoconf 2.70 hasn't actually been released yet.
1491 AS_IF([test -z "${runstatedir}"], [runstatedir='${localstatedir}/run'])
1492 AC_SUBST([runstatedir])
1493
1494 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1495
1496 #### find the actual value for $prefix that we'll end up with
1497 ##   (I know this is broken and should be done in the Makefile, but
1498 ##    that's a major pain and almost nobody actually seems to care)
1499 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1500 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1501 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1502 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1503 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1504 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1505 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1506 AS_AC_EXPAND(EXPANDED_RUNSTATEDIR, "$runstatedir")
1507
1508 #### Check our operating system
1509 operating_system=unknown
1510 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1511    operating_system=redhat
1512 fi
1513
1514 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1515    operating_system=slackware
1516 fi
1517
1518 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1519    operating_system=cygwin
1520 fi
1521
1522 #### Sort out init scripts
1523
1524 if test x$with_init_scripts = x; then
1525     case x$operating_system in
1526         xredhat)        with_init_scripts=redhat ;;
1527         xslackware)     with_init_scripts=slackware ;;
1528         xcygwin)        with_init_scripts=cygwin ;;
1529         *)                      with_init_scripts=none ;;
1530     esac
1531 fi
1532
1533 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1534 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1535 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1536
1537 ##### systemd unit files
1538 AC_ARG_WITH([systemdsystemunitdir],
1539 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1540     [],
1541     [
1542     PKG_CHECK_EXISTS([systemd],
1543       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1544       [with_systemdsystemunitdir=no])
1545     ])
1546 if test "x$with_systemdsystemunitdir" != xno; then
1547    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1548 fi
1549 AM_CONDITIONAL(HAVE_SYSTEMD, [test "x$have_systemd" != "xno" -a -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1550
1551 AC_ARG_WITH([systemduserunitdir],
1552 AS_HELP_STRING([--with-systemduserunitdir=DIR], [Directory for systemd user service files]),
1553     [],
1554     [
1555     PKG_CHECK_EXISTS([systemd],
1556       [with_systemduserunitdir=$($PKG_CONFIG --variable=systemduserunitdir systemd)],
1557       [with_systemduserunitdir='${libdir}/systemd/user'])
1558     ])
1559 AC_SUBST([systemduserunitdir], [$with_systemduserunitdir])
1560
1561 ##### Set up location for system bus socket
1562 if ! test -z "$with_system_socket"; then
1563    DBUS_SYSTEM_SOCKET=$with_system_socket
1564 else
1565    # We don't use runstatedir for this (yet?), because /var/run has been the
1566    # interoperable system bus socket for 10+ years.
1567    # See https://bugs.freedesktop.org/show_bug.cgi?id=101628
1568    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1569 fi
1570
1571 AC_SUBST(DBUS_SYSTEM_SOCKET)
1572 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1573
1574 ## System bus only listens on local domain sockets, and never
1575 ## on an abstract socket (so only root can create the socket).
1576 ##
1577 ## This won't work on Windows. It's not meant to - the system bus is
1578 ## meaningless on Windows anyway.
1579 ##
1580 ## This has to be suitable for hard-coding in client libraries as well as
1581 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1582 ## and also to connect to. If this ever changes, it'll need to be split into
1583 ## two variables, one for the listening address and one for the connecting
1584 ## address.
1585 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1586 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1587 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1588
1589 #### Set up the pid file
1590 if ! test -z "$with_system_pid_file"; then
1591    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1592 elif test x$with_init_scripts = xredhat ; then
1593    DBUS_SYSTEM_PID_FILE="${EXPANDED_RUNSTATEDIR}/messagebus.pid"
1594 else
1595    DBUS_SYSTEM_PID_FILE="${EXPANDED_RUNSTATEDIR}/dbus/pid"
1596 fi
1597
1598 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1599
1600 #### Directory to check for console ownership
1601 if ! test -z "$with_console_auth_dir"; then
1602    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1603 else
1604    # We don't use runstatedir for this, because /var/run is the
1605    # path that was traditionally used by pam_console and pam_foreground.
1606    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1607 fi
1608
1609 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1610 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1611
1612 #### File to check for console ownership
1613 if test x$have_console_owner_file = xyes; then
1614    if ! test -z "$with_console_owner_file"; then
1615       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1616    else
1617       DBUS_CONSOLE_OWNER_FILE=/dev/console
1618    fi
1619 else
1620   DBUS_CONSOLE_OWNER_FILE=
1621 fi
1622
1623 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1624 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1625
1626 #### User to start the system bus as
1627 if test -z "$with_dbus_user" ; then
1628     DBUS_USER=messagebus
1629 else
1630     DBUS_USER=$with_dbus_user
1631 fi
1632 AC_SUBST(DBUS_USER)
1633 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1634
1635 #### User for regression tests
1636 AS_IF([test -z "$with_test_user"], [with_test_user=nobody])
1637 DBUS_TEST_USER="$with_test_user"
1638 AC_SUBST([DBUS_TEST_USER])
1639 AC_DEFINE_UNQUOTED([DBUS_TEST_USER], ["$DBUS_TEST_USER"],
1640   [Unprivileged user used in some regression tests])
1641
1642 #### Prefix to install into
1643 DBUS_PREFIX=$EXPANDED_PREFIX
1644 AC_SUBST(DBUS_PREFIX)
1645 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1646
1647 #### Direcotry to install data files into
1648 DBUS_DATADIR=$EXPANDED_DATADIR
1649 AC_SUBST(DBUS_DATADIR)
1650 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1651
1652 #### Directory to install dbus-daemon
1653 if test -z "$with_dbus_daemondir" ; then
1654     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1655     dbus_daemondir='$bindir'
1656 else
1657     DBUS_DAEMONDIR=$with_dbus_daemondir
1658     dbus_daemondir=$with_dbus_daemondir
1659 fi
1660 AC_SUBST(DBUS_DAEMONDIR)
1661 AC_SUBST(dbus_daemondir)
1662 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1663
1664 #### Directory to install the other binaries
1665 DBUS_BINDIR="$EXPANDED_BINDIR"
1666 AC_SUBST(DBUS_BINDIR)
1667 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1668
1669 #### Directory to install the libexec binaries
1670 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1671 AC_SUBST(DBUS_LIBEXECDIR)
1672 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1673
1674 AC_ARG_ENABLE([relocation],
1675   [AS_HELP_STRING([--enable-relocation[=yes/no/auto]],
1676     [Make pkg-config metadata relocatable [default=auto]])],
1677   [], [enable_relocation=auto])
1678
1679 can_relocate=yes
1680
1681 AS_CASE(["${exec_prefix}"],
1682   ['NONE'|'${prefix}'],
1683     [:],
1684   [*],
1685     [can_relocate=no])
1686
1687 AS_CASE(["${libdir}"],
1688   ['${prefix}/lib'|'${prefix}/lib64'|'${exec_prefix}/lib'|'${exec_prefix}/lib64'],
1689     [:],
1690   [*],
1691     [can_relocate=no])
1692
1693 # If the user said --enable-relocation but we can't do it, error out
1694 AS_IF([test "x$can_relocate" = xno && test "x$enable_relocation" = xyes],
1695   [AC_MSG_ERROR([Relocatable pkg-config metadata requires --exec-prefix='\${prefix}' and the default libdir])])
1696
1697 # By default, on Windows we are relocatable if possible
1698 AS_IF([test "x$enable_relocation" = xauto && test "x$dbus_win" = xyes],
1699   [enable_relocation="$can_relocate"])
1700
1701 # By default, on non-Windows we are not relocatable because it can interfere
1702 # with pkg-config's ability to filter out system include directories,
1703 # resulting in linking an outdated system-wide library in preference to a
1704 # newer version installed elsewhere
1705 AS_IF([test "x$enable_relocation" = xauto],
1706   [enable_relocation="no"])
1707
1708
1709 AS_IF([test "x$enable_relocation" = xyes],
1710   [AC_SUBST([pkgconfig_prefix], ['${pcfiledir}/../../'])],
1711   [AC_SUBST([pkgconfig_prefix], ['${original_prefix}'])])
1712
1713 #### Directory to source sysconfdir configuration from
1714
1715 # On Windows this is relative to where we put the bus setup, in
1716 # ${datadir}/dbus-1. For simplicity, we only do this if
1717 # ${sysconfdir} = ${prefix}/etc and ${datadir} = ${prefix}/share.
1718 #
1719 # On Unix, or on Windows with weird install layouts, it's the absolute path.
1720 AS_IF([test "${dbus_win}" = yes && \
1721        test "$EXPANDED_SYSCONFDIR" = "$EXPANDED_PREFIX/etc" && \
1722        test "$EXPANDED_DATADIR" = "$EXPANDED_PREFIX/share"],
1723       [SYSCONFDIR_FROM_PKGDATADIR="../../etc"
1724        DATADIR_FROM_PKGSYSCONFDIR="../../share"],
1725       [SYSCONFDIR_FROM_PKGDATADIR="$EXPANDED_SYSCONFDIR"
1726        DATADIR_FROM_PKGSYSCONFDIR="$EXPANDED_DATADIR"])
1727 AC_SUBST([SYSCONFDIR_FROM_PKGDATADIR])
1728 AC_SUBST([DATADIR_FROM_PKGSYSCONFDIR])
1729
1730 #### Tell tests where to find certain stuff in builddir
1731
1732 DBUS_PWD=`pwd`
1733 # Useful in a cross-compilation environment, where the tests are run on the host system.
1734 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1735                            DBUS_PWD=$withval)
1736
1737 DBUS_TEST_EXEC="$DBUS_PWD/test"
1738 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1739
1740 AC_SUBST([DBUS_TEST_DATA])
1741 AC_SUBST([DBUS_TEST_EXEC])
1742
1743 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1744                    [Extension for executables, typically empty or .exe])
1745
1746 ## Export the non-setuid external helper
1747 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1748 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1749 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1750                    [Full path to the launch helper test program in the builddir])
1751
1752 #### Find socket directories
1753 if ! test -z "$TMPDIR" ; then
1754    DEFAULT_SOCKET_DIR=$TMPDIR
1755 elif ! test -z "$TEMP" ; then
1756    DEFAULT_SOCKET_DIR=$TEMP
1757 elif ! test -z "$TMP" ; then
1758    DEFAULT_SOCKET_DIR=$TMP
1759 else
1760    DEFAULT_SOCKET_DIR=/tmp
1761 fi
1762
1763 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1764
1765 if ! test -z "$with_test_socket_dir" ; then
1766    TEST_SOCKET_DIR="$with_test_socket_dir"
1767 else
1768    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1769 fi
1770 AC_SUBST(TEST_SOCKET_DIR)
1771 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1772
1773 if test "x$dbus_unix" = xyes; then
1774   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1775 else
1776   TEST_LISTEN="tcp:host=localhost"
1777 fi
1778 AC_SUBST([TEST_LISTEN])
1779 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1780   [Listening address for regression tests])
1781
1782 if ! test -z "$with_session_socket_dir" ; then
1783    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1784 else
1785    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1786 fi
1787 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1788 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1789
1790 # This must be a listening address. It doesn't necessarily need to be an
1791 # address you can connect to - it can be something vague like
1792 # "nonce-tcp:".
1793 #
1794 # The default varies by platform.
1795 AC_ARG_WITH([dbus_session_bus_listen_address],
1796             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1797                            [default address for a session bus to listen on (see configure.ac)]),
1798             [with_dbus_session_bus_listen_address=$withval],
1799             [with_dbus_session_bus_listen_address=])
1800
1801 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1802         # the user specified something, trust them
1803         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1804 elif test x$dbus_win = xyes; then
1805         # On Windows, you can (and should) listen on autolaunch addresses,
1806         # because autolaunching is different.
1807         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1808         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1809 elif test x$have_launchd = xyes; then
1810         # Mac OS X default is to use launchd
1811         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1812 else
1813         # The default on all other Unix platforms (notably Linux)
1814         # is to create a randomly named socket in /tmp or similar
1815         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1816 fi
1817 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1818
1819 # This must be an address you can connect to. It doesn't necessarily
1820 # need to be an address you can listen on - it can be "autolaunch:",
1821 # even on Unix.
1822 #
1823 # The default varies by platform.
1824 AC_ARG_WITH([dbus_session_bus_connect_address],
1825             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1826                            [fallback address for a session bus client to connect to (see configure.ac)]),
1827             [with_dbus_session_bus_connect_address=$withval],
1828             [with_dbus_session_bus_connect_address=])
1829
1830 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1831         # the user specified something, trust them
1832         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1833 elif test x$dbus_win = xyes; then
1834         # Windows autolaunching is a bit different; leaving it in its own
1835         # branch of the conditional because the default might conceivably
1836         # change (see #38201)
1837         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1838 else
1839         # The default on all other Unix platforms (notably Linux)
1840         # is to use auto-launching - this works a bit differently on Mac OS X
1841         # but comes out basically the same in the end
1842         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1843 fi
1844 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1845 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1846   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1847   [Fallback address for session bus clients])
1848
1849 # darwin needs this to initialize the environment
1850 AC_CHECK_HEADERS(crt_externs.h)
1851 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1852 AH_VERBATIM(_DARWIN_ENVIRON,
1853 [
1854 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1855 # include <sys/time.h>
1856 # include <crt_externs.h>
1857 # define environ (*_NSGetEnviron())
1858 #endif
1859 ])
1860
1861 AC_ARG_ENABLE([stats],
1862   [AS_HELP_STRING([--disable-stats],
1863     [disable bus daemon usage statistics])],
1864   [], [enable_stats=yes])
1865 if test "x$enable_stats" = xyes; then
1866   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1867     [Define to enable bus daemon usage statistics])
1868 fi
1869
1870 AC_ARG_ENABLE([user-session],
1871   [AS_HELP_STRING([--enable-user-session],
1872     [enable user-session semantics for session bus under systemd])],
1873   [], [enable_user_session=no])
1874 AM_CONDITIONAL([DBUS_ENABLE_USER_SESSION],
1875   [test "x$enable_user_session" = xyes])
1876
1877 AC_CONFIG_FILES([
1878 Doxyfile
1879 dbus/Version
1880 dbus/versioninfo.rc
1881 dbus/dbus-arch-deps.h
1882 bus/system.conf
1883 bus/session.conf
1884 bus/legacy-config/system.conf
1885 bus/legacy-config/session.conf
1886 bus/example-system-enable-stats.conf
1887 bus/example-session-disable-stats.conf
1888 bus/messagebus
1889 bus/messagebus-config
1890 bus/org.freedesktop.dbus-session.plist
1891 bus/rc.messagebus
1892 bus/dbus.service
1893 bus/dbus.socket
1894 bus/systemd-user/dbus.service
1895 bus/systemd-user/dbus.socket
1896 bus/sysusers.d/dbus.conf
1897 bus/tmpfiles.d/dbus.conf
1898 Makefile
1899 dbus/Makefile
1900 bus/Makefile
1901 tools/Makefile
1902 test/Makefile
1903 test/name-test/Makefile
1904 doc/Makefile
1905 doc/dbus-cleanup-sockets.1.xml
1906 doc/dbus-daemon.1.xml
1907 doc/dbus-launch.1.xml
1908 doc/dbus-monitor.1.xml
1909 doc/dbus-run-session.1.xml
1910 doc/dbus-send.1.xml
1911 doc/dbus-test-tool.1.xml
1912 doc/dbus-update-activation-environment.1.xml
1913 doc/dbus-uuidgen.1.xml
1914 dbus-1.pc
1915 dbus-1-uninstalled.pc
1916 cmake/DBus1Config.cmake:cmake/DBus1Config.pkgconfig.in
1917 cmake/DBus1ConfigVersion.cmake
1918 ])
1919 AC_OUTPUT
1920
1921 dnl ==========================================================================
1922 echo "
1923                     D-Bus $VERSION
1924                   ==============
1925
1926         prefix:                   ${EXPANDED_PREFIX}
1927         exec_prefix:              ${exec_prefix}
1928         libdir:                   ${EXPANDED_LIBDIR}
1929         libexecdir:               ${EXPANDED_LIBEXECDIR}
1930         bindir:                   ${EXPANDED_BINDIR}
1931         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1932         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1933         runstatedir:              ${EXPANDED_RUNSTATEDIR}
1934         datadir:                  ${EXPANDED_DATADIR}
1935         source code location:     ${srcdir}
1936         compiler:                 ${CC}
1937         cflags:                   ${CFLAGS}
1938         cppflags:                 ${CPPFLAGS}
1939         cxxflags:                 ${CXXFLAGS}
1940         ldflags:                  ${LDFLAGS}
1941         64-bit int:               ${DBUS_INT64_TYPE}
1942         32-bit int:               ${DBUS_INT32_TYPE}
1943         16-bit int:               ${DBUS_INT16_TYPE}
1944         Doxygen:                  ${DOXYGEN:-not found}
1945         xmlto:                    ${XMLTO:-not found}
1946         ducktype:                 ${DUCKTYPE:-not found}
1947         yelp-build:               ${YELP_BUILD:-not found}"
1948
1949 echo "
1950         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1951         gcc coverage profiling:   ${enable_code_coverage}
1952         Building embedded tests:  ${enable_embedded_tests}
1953         Building modular tests:   ${enable_modular_tests}
1954             - with GLib:          ${with_glib}
1955         Installing tests:         ${enable_installed_tests}
1956         Building verbose mode:    ${enable_verbose_mode}
1957         Building assertions:      ${enable_asserts}
1958         Building checks:          ${enable_checks}
1959         Building bus stats API:   ${enable_stats}
1960         Building SELinux support: ${have_selinux}
1961         Building AppArmor support: ${have_apparmor}
1962         Building inotify support: ${have_inotify}
1963         Building kqueue support:  ${have_kqueue}
1964         Building systemd support: ${have_systemd}
1965         Building X11 code:        ${have_x11}
1966         Building Doxygen docs:    ${enable_doxygen_docs}
1967         Building Ducktype docs:   ${enable_ducktype_docs}
1968         Building XML docs:        ${enable_xml_docs}
1969         Building launchd support: ${have_launchd}
1970         Init scripts style:       ${with_init_scripts}
1971         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1972         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1973         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1974         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1975         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1976         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1977         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1978         Console owner file:       ${have_console_owner_file}
1979         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1980         System bus user:          ${DBUS_USER}
1981         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1982         'make check' socket dir:  ${TEST_SOCKET_DIR}
1983 "
1984 if test x$have_launchd = xyes; then
1985         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1986 fi
1987 echo
1988
1989 if test x$enable_embedded_tests = xyes; then
1990         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1991 fi
1992 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1993         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1994 fi
1995 AS_IF([test x$enable_code_coverage = xyes],[
1996     AC_MSG_WARN([Building with coverage profiling is definitely for developers only.])
1997   ])
1998 if test x$enable_verbose_mode = xyes; then
1999         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
2000 fi
2001 if test x$enable_asserts = xyes; then
2002         echo "NOTE: building with assertions increases library size and decreases performance."
2003 fi
2004 if test x$enable_checks = xno; then
2005         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
2006 fi