configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [45])
  34 m4_define([glib_micro_version], [2])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS:+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 dnl
 121
 122 AC_MSG_CHECKING([for Win32])
 123 LIB_EXE_MACHINE_FLAG=X86
 124 case "$host" in
 125   *-*-mingw*)
 126     glib_native_win32=yes
 127     glib_pid_type='void *'
 128     glib_cv_stack_grows=no
 129     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 130     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 131     # (Sorry, I don't know exactly what is the problem, but it is related to
 132     # floating point formatting and decimal point vs. comma.)
 133     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 134     # rigorous enough to notice, though.
 135     # So preset the autoconf cache variables.
 136     ac_cv_func_vsnprintf_c99=no
 137     ac_cv_func_snprintf_c99=no
 138     case "$host" in
 139     x86_64-*-*)
 140       LIB_EXE_MACHINE_FLAG=X64
 141       ;;
 142     esac
 143
 144     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 145     ;;
 146   *)
 147     glib_native_win32=no
 148     glib_pid_type=int
 149     ;;
 150 esac
 151 case $host in
 152   *-*-linux*)
 153     glib_os_linux=yes
 154     ;;
 155 esac
 156
 157 AC_MSG_RESULT([$glib_native_win32])
 158
 159 AC_MSG_CHECKING([for the Android])
 160 case $host in
 161   *android*)
 162     glib_native_android="yes"
 163     ;;
 164   *)
 165     glib_native_android="no"
 166     ;;
 167 esac
 168 AC_MSG_RESULT([$glib_native_android])
 169
 170 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 171
 172 glib_have_carbon=no
 173 AC_MSG_CHECKING([for Mac OS X Carbon support])
 174 AC_TRY_CPP([
 175 #include <Carbon/Carbon.h>
 176 #include <CoreServices/CoreServices.h>
 177 ], glib_have_carbon=yes)
 178
 179 AC_MSG_RESULT([$glib_have_carbon])
 180
 181 glib_have_cocoa=no
 182 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 183 AC_TRY_CPP([
 184 #include <Cocoa/Cocoa.h>
 185 #ifdef GNUSTEP_BASE_VERSION
 186 #error "Detected GNUstep, not Cocoa"
 187 #endif
 188 ], glib_have_cocoa=yes)
 189
 190 AC_MSG_RESULT([$glib_have_cocoa])
 191
 192 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 193 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 194 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 195 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 196 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 197 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 198
 199 AS_IF([test "$glib_native_win32" = "yes"], [
 200   AC_CHECK_TOOL(WINDRES, windres, no)
 201   if test "$WINDRES" = no; then
 202     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 203   fi
 204   AC_CHECK_TOOL(NM, nm, no)
 205   if test "$NM" = no; then
 206     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 207   fi
 208   AC_CHECK_TOOL(RANLIB, ranlib, :)
 209   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 210   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 211 ])
 212 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 213
 214 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 215   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 216   CARBON_LIBS="-Wl,-framework,Carbon"
 217   LDFLAGS="$LDFLAGS $CARBON_LIBS"
 218 ], [CARBON_LIBS=""])
 219
 220 AC_SUBST([CARBON_LIBS])
 221
 222 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
 223   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 224   COCOA_LIBS="-Wl,-framework,Foundation"
 225   LDFLAGS="$LDFLAGS $COCOA_LIBS"
 226 ], [COCOA_LIBS=""])
 227
 228 AC_SUBST([COCOA_LIBS])
 229
 230 dnl declare --enable-* args and collect ac_help strings
 231 AC_ARG_ENABLE(debug,
 232               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 233                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 234               enable_debug=glib_debug_default)
 235
 236 AC_ARG_ENABLE(gc_friendly,
 237               [AS_HELP_STRING([--enable-gc-friendly],
 238                               [turn on garbage collector friendliness [default=no]])],,
 239               [enable_gc_friendly=no])
 240 AC_ARG_ENABLE(mem_pools,
 241               [AS_HELP_STRING([--disable-mem-pools],
 242                               [disable all glib memory pools])],,
 243               [disable_mem_pools=no])
 244 AC_ARG_ENABLE(rebuilds,
 245               [AS_HELP_STRING([--disable-rebuilds],
 246                               [disable all source autogeneration rules])],,
 247               [enable_rebuilds=yes])
 248
 249 GLIB_TESTS
 250
 251 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 252 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 253   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 254   AC_MSG_RESULT([yes])
 255 ], [ AC_MSG_RESULT([no]) ])
 256
 257 AC_MSG_CHECKING([whether to disable memory pools])
 258 AS_IF([test "x$disable_mem_pools" = "xno"], [
 259   AC_MSG_RESULT([no])
 260 ], [
 261   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 262   AC_MSG_RESULT([yes])
 263 ])
 264
 265 dnl location to install runtime libraries, e.g. ../../lib to install
 266 dnl to /lib if libdir is /usr/lib
 267 AC_ARG_WITH(runtime-libdir,
 268            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 269                            [install runtime libraries relative to libdir])],
 270            [],
 271            [with_runtime_libdir=""])
 272 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 273 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 274 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 275 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 276 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 277
 278 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 279 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 280 AC_LANG_SAVE
 281 AC_LANG_CPLUSPLUS
 282 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 283 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 284 AC_LANG_RESTORE
 285
 286 AM_PROG_CC_C_O
 287 AC_PROG_INSTALL
 288
 289 AC_SYS_LARGEFILE
 290
 291 PKG_PROG_PKG_CONFIG(0.16)
 292
 293 if test "x$enable_debug" = "xyes"; then
 294   if test "x$cflags_set" != "x" ; then
 295       case " $CFLAGS " in
 296       *[[\ \    ]]-g[[\ \       ]]*) ;;
 297       *) CFLAGS="$CFLAGS -g" ;;
 298       esac
 299   fi
 300   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 301 else
 302   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 303
 304   if test "x$enable_debug" = "xno"; then
 305     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 306   fi
 307 fi
 308
 309 # Ensure MSVC-compatible struct packing convention is used when
 310 # compiling for Win32 with gcc.
 311 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 312 # gcc2 uses "-fnative-struct".
 313 if test x"$glib_native_win32" = xyes; then
 314   if test x"$GCC" = xyes; then
 315     msnative_struct=''
 316     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 317     if test -z "$ac_cv_prog_CC"; then
 318       our_gcc="$CC"
 319     else
 320       our_gcc="$ac_cv_prog_CC"
 321     fi
 322     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 323       2.)
 324         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 325           msnative_struct='-fnative-struct'
 326         fi
 327         ;;
 328       *)
 329         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 330           msnative_struct='-mms-bitfields'
 331         fi
 332         ;;
 333     esac
 334     if test x"$msnative_struct" = x ; then
 335       AC_MSG_RESULT([no way])
 336       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 337     else
 338       CFLAGS="$CFLAGS $msnative_struct"
 339       AC_MSG_RESULT([${msnative_struct}])
 340     fi
 341   fi
 342 fi
 343 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 344 AC_SUBST(GLIB_EXTRA_CFLAGS)
 345
 346 AC_EXEEXT
 347
 348 # define a MAINT-like variable REBUILD which is set if Perl
 349 # and awk are found, so autogenerated sources can be rebuilt
 350 AC_PROG_AWK
 351 AC_CHECK_PROGS(PERL, [perl5 perl])
 352 # We would like indent, but don't require it.
 353 AC_CHECK_PROG(INDENT, indent, indent)
 354 REBUILD=\#
 355 if test "x$enable_rebuilds" = "xyes" && \
 356      test -n "$PERL" && \
 357      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 358      test -n "$AWK" ; then
 359   REBUILD=
 360 fi
 361 AC_SUBST(REBUILD)
 362
 363 # Need full path to Perl for glib-mkenums
 364 #
 365 if test "x$PERL" != x ; then
 366   AC_PATH_PROG(PERL_PATH, [$PERL])
 367 fi
 368 if test "x$PERL_PATH" = x ; then
 369   PERL_PATH="/usr/bin/env perl"
 370 fi
 371 AC_SUBST(PERL_PATH)
 372
 373 # option to specify python interpreter to use; this just sets $PYTHON, so that
 374 # we will fallback to reading $PYTHON if --with-python is not given, and
 375 # python.m4 will get the expected input
 376 AC_ARG_WITH(python,
 377             AS_HELP_STRING([--with-python=PATH],
 378                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 379             [PYTHON="$withval"], [])
 380 if test x"$PYTHON" = xyes; then
 381   AC_MSG_ERROR([--with-python option requires a path or program argument])
 382 fi
 383 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 384
 385
 386 dnl ***********************
 387 dnl *** Tests for iconv ***
 388 dnl ***********************
 389 dnl
 390 dnl We do this before the gettext checks, to avoid distortion
 391
 392 dnl On Windows we use a native implementation
 393
 394 AS_IF([ test x"$glib_native_win32" = xyes], [
 395   with_libiconv=native
 396 ], [
 397   AC_ARG_WITH(libiconv,
 398               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 399                               [use the libiconv library])],,
 400               [with_libiconv=maybe])
 401
 402   found_iconv=no
 403   case $with_libiconv in
 404     maybe)
 405       # Check in the C library first
 406       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 407       # Check if we have GNU libiconv
 408       if test $found_iconv = "no"; then
 409         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 410       fi
 411       # Check if we have a iconv in -liconv, possibly from vendor
 412       if test $found_iconv = "no"; then
 413         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 414       fi
 415       ;;
 416     no)
 417       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 418       ;;
 419     gnu|yes)
 420       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 421       ;;
 422     native)
 423       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 424       ;;
 425   esac
 426
 427   if test "x$found_iconv" = "xno" ; then
 428      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 429   fi
 430 ])
 431
 432 dnl
 433 dnl zlib support
 434 dnl
 435 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 436 AS_IF([test "x$found_zlib" = "xno"], [
 437   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 438   if test "x$found_zlib" = "xno" ; then
 439     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 440   fi
 441   ZLIB_LIBS='-lz'
 442   AC_SUBST(ZLIB_LIBS)
 443 ])
 444
 445 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 446 AC_SUBST(LIBFFI_CFLAGS)
 447 AC_SUBST(LIBFFI_LIBS)
 448
 449 dnl
 450 dnl gettext support
 451 dnl
 452
 453 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 454 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 455 GLIB_GNU_GETTEXT
 456
 457 if test "$gt_cv_have_gettext" != "yes" ; then
 458   AC_MSG_ERROR([
 459 *** You must have either have gettext support in your C library, or use the
 460 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 461 ])
 462 fi
 463
 464 LIBS="$INTLLIBS $LIBS"
 465
 466 GETTEXT_PACKAGE=glib20
 467 AC_SUBST(GETTEXT_PACKAGE)
 468 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 469   [Define the gettext package to be used])
 470
 471 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 472
 473 dnl
 474 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 475 dnl
 476
 477 AS_IF([test x"$glib_native_win32" != xyes], [
 478   if test x$with_libiconv != xno ; then
 479     case " $INTLLIBS " in
 480     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 481     *) ICONV_LIBS="-liconv" ;;
 482     esac
 483   fi
 484 ])
 485 AC_SUBST(ICONV_LIBS)
 486
 487 case $with_libiconv in
 488   gnu)
 489     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 490     ;;
 491   native)
 492     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 493     ;;
 494 esac
 495
 496 dnl Initialize libtool
 497 LT_PREREQ([2.2])
 498 LT_INIT([disable-static win32-dll])
 499 dnl when using libtool 2.x create libtool early, because it's used in configure
 500 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 501
 502
 503 AS_IF([test "$glib_native_win32" = "yes"], [
 504   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 505     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 506   fi
 507   if test x$enable_static = xyes; then
 508     glib_win32_static_compilation=yes
 509     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 510 #define GOBJECT_STATIC_COMPILATION 1"
 511     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 512   fi
 513 ])
 514 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 515
 516 # Checks for library functions.
 517 AC_FUNC_ALLOCA
 518 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 519 AC_CHECK_FUNCS(timegm gmtime_r)
 520
 521 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 522   [AC_TRY_LINK([#include <unistd.h>
 523     extern int __libc_enable_secure;],
 524     [return __libc_enable_secure;],
 525    glib_cv_have_libc_enable_secure=yes,
 526    glib_cv_have_libc_enable_secure=no)])
 527 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 528    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 529      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 530 ])
 531
 532 AC_CHECK_SIZEOF(char)
 533 AC_CHECK_SIZEOF(short)
 534 AC_CHECK_SIZEOF(long)
 535 AC_CHECK_SIZEOF(int)
 536 AC_CHECK_SIZEOF(void *)
 537 AC_CHECK_SIZEOF(long long)
 538 AC_CHECK_SIZEOF(__int64)
 539
 540 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 541   [AC_TRY_LINK([#include <signal.h>
 542      #include <sys/types.h>
 543      sig_atomic_t val = 42;],
 544     [return val == 42 ? 0 : 1],
 545    ac_cv_type_sig_atomic_t=yes,
 546    ac_cv_type_sig_atomic_t=no)])
 547 if test x$ac_cv_type_sig_atomic_t = xyes; then
 548    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 549      [Define if you have the 'sig_atomic_t' type.])
 550 fi
 551
 552 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 553   :
 554 else
 555   AC_MSG_ERROR([
 556 *** GLib requires a 64 bit type. You might want to consider
 557 *** using the GNU C compiler.
 558 ])
 559 fi
 560
 561 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 562         # long long is a 64 bit integer.
 563         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 564         AC_CACHE_VAL(glib_cv_long_long_format,[
 565                 for format in ll q I64; do
 566                   AC_TRY_RUN([#include <stdio.h>
 567                         int main()
 568                         {
 569                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 570                           char buffer[1000];
 571                           sprintf (buffer, "%${format}u", a);
 572                           sscanf (buffer, "%${format}u", &b);
 573                           exit (b!=a);
 574                         }
 575                         ],
 576                         [glib_cv_long_long_format=${format}
 577                         break],
 578                         [],[:])
 579                 done])
 580         AS_IF([ test -n "$glib_cv_long_long_format"], [
 581           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 582           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 583           if test x"$glib_cv_long_long_format" = xI64; then
 584             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 585           fi
 586         ], [AC_MSG_RESULT(none)])
 587 ],[ test x$ac_cv_sizeof___int64 = x8], [
 588         # __int64 is a 64 bit integer.
 589         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 590         # We know this is MSVCRT.DLL, and what the formats are
 591         glib_cv_long_long_format=I64
 592         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 593         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 594         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 595 ])
 596
 597 AC_C_CONST
 598
 599 dnl
 600 dnl check in which direction the stack grows
 601 dnl
 602 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 603         AC_TRY_RUN([
 604         volatile int *a = 0, *b = 0;
 605         void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
 606         int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
 607         ],
 608         glib_cv_stack_grows=yes
 609         ,
 610         glib_cv_stack_grows=no
 611         ,)
 612 ])
 613
 614 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 615 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 616 dnl actually supported.
 617 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 618         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 619         __inline int foo () { return 0; }
 620         int main () { return foo (); }
 621         ]])],
 622         glib_cv_has__inline=yes
 623         ,
 624         glib_cv_has__inline=no
 625         ,)
 626 ])
 627 case x$glib_cv_has__inline in
 628 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 629 esac
 630 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 631         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 632         __inline__ int foo () { return 0; }
 633         int main () { return foo (); }
 634         ]])],
 635         glib_cv_has__inline__=yes
 636         ,
 637         glib_cv_has__inline__=no
 638         ,)
 639 ])
 640 case x$glib_cv_has__inline__ in
 641 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 642 esac
 643 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 644         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 645         #undef inline
 646         inline int foo () { return 0; }
 647         int main () { return foo (); }
 648         ]])],
 649         glib_cv_hasinline=yes
 650         ,
 651         glib_cv_hasinline=no
 652         ,)
 653 ])
 654 case x$glib_cv_hasinline in
 655 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 656 esac
 657
 658 # if we can use inline functions in headers
 659 AC_MSG_CHECKING(if inline functions in headers work)
 660 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 661 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 662 #  undef inline
 663 #  define inline __inline__
 664 #elif !defined (G_HAVE_INLINE)
 665 #  undef inline
 666 #  if defined (G_HAVE___INLINE__)
 667 #    define inline __inline__
 668 #  elif defined (G_HAVE___INLINE)
 669 #    define inline __inline
 670 #  endif
 671 #endif
 672
 673 int glib_test_func2 (int);
 674
 675 static inline int
 676 glib_test_func1 (void) {
 677   return glib_test_func2 (1);
 678 }
 679
 680 int
 681 main (void) {
 682   int i = 1;
 683 }]])],[g_can_inline=yes],[g_can_inline=no])
 684 AC_MSG_RESULT($g_can_inline)
 685
 686 # check for flavours of varargs macros
 687 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 688 AC_TRY_COMPILE([],[
 689 int a(int p1, int p2, int p3);
 690 #define call_a(...) a(1,__VA_ARGS__)
 691 call_a(2,3);
 692 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 693 AC_MSG_RESULT($g_have_iso_c_varargs)
 694
 695 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 696 AS_IF([test "$CXX" = ""], [
 697 dnl No C++ compiler
 698   g_have_iso_cxx_varargs=no
 699 else
 700   AC_LANG_CPLUSPLUS
 701   AC_TRY_COMPILE([],[
 702 int a(int p1, int p2, int p3);
 703 #define call_a(...) a(1,__VA_ARGS__)
 704 call_a(2,3);
 705 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 706   AC_LANG_C
 707 ])
 708 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 709
 710 AC_MSG_CHECKING(for GNUC varargs macros)
 711 AC_TRY_COMPILE([],[
 712 int a(int p1, int p2, int p3);
 713 #define call_a(params...) a(1,params)
 714 call_a(2,3);
 715 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 716 AC_MSG_RESULT($g_have_gnuc_varargs)
 717
 718 # check for GNUC visibility support
 719 AC_MSG_CHECKING(for GNUC visibility attribute)
 720 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 721 void
 722 __attribute__ ((visibility ("hidden")))
 723      f_hidden (void)
 724 {
 725 }
 726 void
 727 __attribute__ ((visibility ("internal")))
 728      f_internal (void)
 729 {
 730 }
 731 void
 732 __attribute__ ((visibility ("protected")))
 733      f_protected (void)
 734 {
 735 }
 736 void
 737 __attribute__ ((visibility ("default")))
 738      f_default (void)
 739 {
 740 }
 741 int main (void)
 742 {
 743         f_hidden();
 744         f_internal();
 745         f_protected();
 746         f_default();
 747         return 0;
 748 }
 749 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 750 AC_MSG_RESULT($g_have_gnuc_visibility)
 751 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 752
 753 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 754 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 755 #else
 756 # include "error: this is not Sun Studio."
 757 #endif
 758 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 759 AC_MSG_RESULT($g_have_sunstudio_visibility)
 760 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 761
 762 # check for bytesex stuff
 763 AC_C_BIGENDIAN
 764 if test x$ac_cv_c_bigendian = xuniversal ; then
 765   AC_MSG_ERROR([Universal builds not supported: see https://bugs.gnome.org/742548])
 766 fi
 767
 768
 769 # check for header files
 770 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
 771 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
 772 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 773 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 774 AC_CHECK_HEADERS([linux/magic.h sys/prctl.h])
 775
 776 # Some versions of MSC lack these
 777 AC_CHECK_HEADERS([dirent.h sys/time.h])
 778
 779 # We don't care about this, but we need to keep including it in
 780 # glibconfig.h for backward compatibility
 781 AC_CHECK_HEADERS([values.h])
 782
 783 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 784 [#if HAVE_SYS_PARAM_H
 785  #include <sys/param.h>
 786  #endif
 787 ])
 788 AC_CHECK_FUNCS(sysctlbyname)
 789
 790 AC_HEADER_MAJOR
 791 AC_CHECK_HEADERS([xlocale.h])
 792
 793 # check for structure fields
 794 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 795 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 796 #include <sys/stat.h>
 797 #ifdef G_OS_UNIX
 798 #include <unistd.h>
 799 #endif
 800 #ifdef HAVE_SYS_STATFS_H
 801 #include <sys/statfs.h>
 802 #endif
 803 #ifdef HAVE_SYS_PARAM_H
 804 #include <sys/param.h>
 805 #endif
 806 #ifdef HAVE_SYS_MOUNT_H
 807 #include <sys/mount.h>
 808 #endif])
 809 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 810 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 811 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 812 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 813
 814 AC_STRUCT_DIRENT_D_TYPE
 815
 816 # Checks for libcharset
 817 AM_LANGINFO_CODESET
 818 gl_GLIBC21
 819
 820 # check additional type sizes
 821 AC_CHECK_SIZEOF(size_t)
 822
 823 dnl Try to figure out whether gsize should be long or int
 824 AC_MSG_CHECKING([for the appropriate definition for size_t])
 825
 826 case $ac_cv_sizeof_size_t in
 827   $ac_cv_sizeof_short)
 828       glib_size_type=short
 829       ;;
 830   $ac_cv_sizeof_int)
 831       glib_size_type=int
 832       ;;
 833   $ac_cv_sizeof_long)
 834       glib_size_type=long
 835       ;;
 836   $ac_cv_sizeof_long_long)
 837       glib_size_type='long long'
 838       ;;
 839   $ac_cv_sizeof__int64)
 840       glib_size_type='__int64'
 841       ;;
 842   *)  AC_MSG_ERROR([No type matching size_t in size])
 843       ;;
 844 esac
 845
 846 dnl If int/long are the same size, we see which one produces
 847 dnl warnings when used in the location as size_t. (This matters
 848 dnl on AIX with xlc)
 849 dnl
 850 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 851        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 852   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 853 #if defined(_AIX) && !defined(__GNUC__)
 854 #pragma options langlvl=stdc89
 855 #endif
 856 #include <stddef.h>
 857 int main ()
 858 {
 859   size_t s = 1;
 860   unsigned int *size_int = &s;
 861   return (int)*size_int;
 862 }
 863     ]])],glib_size_type=int,
 864       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 865 #if defined(_AIX) && !defined(__GNUC__)
 866 #pragma options langlvl=stdc89
 867 #endif
 868 #include <stddef.h>
 869 int main ()
 870 {
 871    size_t s = 1;
 872    unsigned long *size_long = &s;
 873    return (int)*size_long;
 874 }
 875         ]])],glib_size_type=long)])
 876 ])
 877
 878 AC_MSG_RESULT(unsigned $glib_size_type)
 879
 880 AC_CHECK_SIZEOF(ssize_t)
 881
 882 dnl Try to figure out whether gssize should be long or int
 883 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 884
 885 case $ac_cv_sizeof_ssize_t in
 886   $ac_cv_sizeof_short)
 887       glib_ssize_type=short
 888       ;;
 889   $ac_cv_sizeof_int)
 890       glib_ssize_type=int
 891       ;;
 892   $ac_cv_sizeof_long)
 893       glib_ssize_type=long
 894       ;;
 895   $ac_cv_sizeof_long_long)
 896       glib_ssize_type='long long'
 897       ;;
 898   $ac_cv_sizeof__int64)
 899       glib_ssize_type='__int64'
 900       ;;
 901   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 902       ;;
 903 esac
 904
 905 dnl If int/long are the same size, we see which one produces
 906 dnl warnings when used in the location as ssize_t. (This matters
 907 dnl on Android where ssize_t is long and size_t is unsigned int)
 908 dnl
 909 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 910        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 911   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 912 #if defined(_AIX) && !defined(__GNUC__)
 913 #pragma options langlvl=stdc89
 914 #endif
 915 #include <stddef.h>
 916 #ifdef HAVE_INTTYPES_H
 917 # include <inttypes.h>
 918 #endif
 919 #ifdef HAVE_STDINT_H
 920 # include <stdint.h>
 921 #endif
 922 #include <sys/types.h>
 923 int main ()
 924 {
 925   ssize_t s = 1;
 926   int *size_int = &s;
 927   return (int)*size_int;
 928 }
 929     ]])],glib_ssize_type=int,
 930       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 931 #if defined(_AIX) && !defined(__GNUC__)
 932 #pragma options langlvl=stdc89
 933 #endif
 934 #include <stddef.h>
 935 #ifdef HAVE_INTTYPES_H
 936 # include <inttypes.h>
 937 #endif
 938 #ifdef HAVE_STDINT_H
 939 # include <stdint.h>
 940 #endif
 941 #include <sys/types.h>
 942 int main ()
 943 {
 944    ssize_t s = 1;
 945    long *size_long = &s;
 946    return (int)*size_long;
 947 }
 948         ]])],glib_ssize_type=long)])
 949 ])
 950
 951 AC_MSG_RESULT($glib_ssize_type)
 952
 953 # Check for some functions
 954 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 955 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
 956 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
 957 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
 958 AC_CHECK_FUNCS(splice)
 959 AC_CHECK_FUNCS(prlimit)
 960
 961 # To avoid finding a compatibility unusable statfs, which typically
 962 # successfully compiles, but warns to use the newer statvfs interface:
 963 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 964 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 965
 966 AC_MSG_CHECKING([whether to use statfs or statvfs])
 967 # Some systems have both statfs and statvfs, pick the most "native" for these
 968 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
 969    [
 970    # on solaris and irix, statfs doesn't even have the f_bavail field
 971    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
 972       [ac_cv_func_statfs=no],
 973    # else, at least on linux, statfs is the actual syscall
 974       [ac_cv_func_statvfs=no])
 975    ])
 976
 977 AS_IF([test x$ac_cv_func_statfs = xyes],
 978       [
 979          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
 980          AC_MSG_RESULT([statfs])
 981       ],
 982       [test x$ac_cv_func_statvfs = xyes],
 983       [
 984          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
 985          AC_MSG_RESULT([statvfs])
 986       ],
 987       [  AC_MSG_RESULT([neither])])
 988
 989 AC_CHECK_HEADERS(crt_externs.h)
 990 AC_CHECK_FUNCS(_NSGetEnviron)
 991
 992 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
 993
 994 # Internet address families
 995 if test $glib_native_win32 = yes; then
 996   glib_inet_includes=["
 997 #include <winsock2.h>
 998   "]
 999 else
1000   glib_inet_includes=["
1001 #include <sys/types.h>
1002 #include <sys/socket.h>
1003   "]
1004 fi
1005
1006 glib_failed=false
1007 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1008 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1009 # winsock defines this even though it doesn't support it
1010 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1011 if $glib_failed ; then
1012   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1013 fi
1014
1015 glib_failed=false
1016 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1017 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1018 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1019 if $glib_failed ; then
1020   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1021 fi
1022
1023 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname sendmmsg)
1024
1025 AS_IF([test $glib_native_win32 = yes], [
1026   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1027   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1028   # they aren't present at run-time (on Windows 2000).
1029   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1030   AC_SUBST(WSPIAPI_INCLUDE)
1031 ], [
1032   # Android does not have C_IN in public headers, we define it wherever necessary
1033   AS_IF([test $glib_native_android != yes], [
1034     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1035     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1036                                         #include <arpa/nameser.h>],
1037                                        [int qclass = C_IN;])],
1038                       [AC_MSG_RESULT([no])],
1039                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1040                                                            #include <arpa/nameser.h>
1041                                                            #include <arpa/nameser_compat.h>],
1042                                                           [int qclass = C_IN;])],
1043                                          [AC_MSG_RESULT([yes])
1044                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1045                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1046   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1047
1048   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1049   NETWORK_LIBS=""
1050   AC_MSG_CHECKING([for res_query])
1051   AC_TRY_LINK([#include <sys/types.h>
1052                #include <netinet/in.h>
1053                #include <arpa/nameser.h>
1054                #include <resolv.h>
1055               ],[
1056                res_query("test", 0, 0, (void *)0, 0);
1057               ],[AC_MSG_RESULT([yes])],
1058               [save_libs="$LIBS"
1059                LIBS="-lresolv $LIBS"
1060                AC_TRY_LINK([#include <sys/types.h>
1061                             #include <netinet/in.h>
1062                             #include <arpa/nameser.h>
1063                             #include <resolv.h>
1064                            ],[
1065                             res_query("test", 0, 0, (void *)0, 0);
1066                            ],[AC_MSG_RESULT([in -lresolv])
1067                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1068                            [LIBS="-lbind $save_libs"
1069                             AC_TRY_LINK([#include <resolv.h>],
1070                                         [res_query("test", 0, 0, (void *)0, 0);],
1071                                         [AC_MSG_RESULT([in -lbind])
1072                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1073                                         [AC_MSG_ERROR(not found)])])
1074                LIBS="$save_libs"])
1075   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1076                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1077                                         [AC_MSG_ERROR(Could not find socket())]))
1078   save_libs="$LIBS"
1079   LIBS="$LIBS $NETWORK_LIBS"
1080   AC_MSG_CHECKING([for res_init])
1081   AC_TRY_LINK([#include <sys/types.h>
1082                #include <netinet/in.h>
1083                #include <arpa/nameser.h>
1084                #include <resolv.h>
1085               ],[
1086                res_init();
1087               ],[AC_MSG_RESULT([yes])
1088                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1089               ],[AC_MSG_RESULT([no])])
1090   LIBS="$save_libs"
1091 ])
1092 AC_SUBST(NETWORK_LIBS)
1093
1094 AC_CHECK_HEADER([linux/netlink.h],
1095                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1096                 [#include <sys/socket.h>])
1097 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1098
1099 AC_CHECK_TYPE([struct ip_mreqn], [
1100               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1101               [#include <netinet/in.h>])
1102
1103 case $host in
1104   *-*-solaris* )
1105      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1106      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1107      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1108      ;;
1109 esac
1110
1111 dnl
1112 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1113 dnl
1114 AS_IF([test "$ac_cv_func_statfs" = yes], [
1115   AC_MSG_CHECKING([number of arguments to statfs()])
1116   AC_TRY_COMPILE([#include <unistd.h>
1117   #ifdef HAVE_SYS_PARAM_H
1118   #include <sys/param.h>
1119   #endif
1120   #ifdef HAVE_SYS_VFS_H
1121   #include <sys/vfs.h>
1122   #endif
1123   #ifdef HAVE_SYS_MOUNT_H
1124   #include <sys/mount.h>
1125   #endif
1126   #ifdef HAVE_SYS_STATFS_H
1127   #include <sys/statfs.h>
1128   #endif], [struct statfs st;
1129   statfs(NULL, &st);],[
1130     AC_MSG_RESULT([2])
1131     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1132     AC_TRY_COMPILE([#include <unistd.h>
1133   #ifdef HAVE_SYS_PARAM_H
1134   #include <sys/param.h>
1135   #endif
1136   #ifdef HAVE_SYS_VFS_H
1137   #include <sys/vfs.h>
1138   #endif
1139   #ifdef HAVE_SYS_MOUNT_H
1140   #include <sys/mount.h>
1141   #endif
1142   #ifdef HAVE_SYS_STATFS_H
1143   #include <sys/statfs.h>
1144   #endif], [struct statfs st;
1145   statfs(NULL, &st, sizeof (st), 0);],[
1146       AC_MSG_RESULT([4])
1147       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1148       AC_MSG_RESULT(unknown)
1149       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1150 ])
1151
1152 dnl
1153 dnl open takes O_DIRECTORY as an option
1154 dnl
1155 AC_MSG_CHECKING([open() option O_DIRECTORY])
1156 AC_TRY_COMPILE([#include <fcntl.h>
1157 #include <sys/types.h>
1158 #include <sys/stat.h>],
1159 [open(0, O_DIRECTORY, 0);],[
1160         AC_MSG_RESULT([yes])
1161         AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1162         AC_MSG_RESULT([no])])
1163
1164 #
1165 # Check whether to use an included printf
1166 #
1167 AC_FUNC_VSNPRINTF_C99
1168 AC_FUNC_PRINTF_UNIX98
1169
1170 AC_ARG_ENABLE(included-printf,
1171               [AS_HELP_STRING([--enable-included-printf],
1172                               [use included printf [default=auto]])],
1173               enable_included_printf="$enableval")
1174
1175 need_included_printf=no
1176 if test "x$enable_included_printf" = "xyes" ; then
1177   need_included_printf=yes
1178 fi
1179 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1180   need_included_printf=yes
1181 fi
1182 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1183   need_included_printf=yes
1184 fi
1185 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1186    test -z "$glib_cv_long_long_format" ; then
1187   need_included_printf=yes
1188 fi
1189
1190 if test "x$enable_included_printf" = "xno" &&
1191    test "x$need_included_printf" = "xyes" ; then
1192   AC_MSG_ERROR([
1193 *** Your C library's printf doesn't appear to have the features that
1194 *** GLib needs, but you specified --enable-included-printf=no.])
1195 fi
1196
1197 enable_included_printf=$need_included_printf
1198
1199 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1200 AS_IF([test "$enable_included_printf" != "yes"], [
1201   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1202 ], [
1203   if test -z "$glib_cv_long_long_format" ; then
1204     glib_cv_long_long_format="ll"
1205   fi
1206   AC_DEFINE(HAVE_VASPRINTF,1)
1207 ])
1208
1209 # Checks needed for gnulib vasnprintf
1210 bh_C_SIGNED
1211 jm_AC_TYPE_LONG_LONG
1212 gt_TYPE_LONGDOUBLE
1213 gt_TYPE_WCHAR_T
1214 gt_TYPE_WINT_T
1215 AC_TYPE_SIZE_T
1216 AC_CHECK_TYPES(ptrdiff_t)
1217 jm_AC_TYPE_INTMAX_T
1218 AC_CHECK_FUNCS([snprintf wcslen])
1219 AC_FUNC_SNPRINTF_C99
1220
1221 # Check if <sys/select.h> needs to be included for fd_set
1222 AC_MSG_CHECKING([for fd_set])
1223 AC_TRY_COMPILE([#include <sys/types.h>],
1224         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1225 AS_IF([test "$gtk_ok" = "yes"], [
1226     AC_MSG_RESULT([yes, found in sys/types.h])
1227 ], [
1228     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1229     if test "$gtk_ok" = "yes"; then
1230         # *** FIXME: give it a different name
1231         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1232         AC_MSG_RESULT([yes, found in sys/select.h])
1233     else
1234         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1235         AC_MSG_RESULT(no)
1236     fi
1237 ])
1238
1239 dnl Check for nl_langinfo and CODESET
1240 AC_LANG_SAVE
1241 AC_LANG_C
1242 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1243         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1244                        [char *codeset = nl_langinfo (CODESET);])],
1245                 [glib_cv_langinfo_codeset=yes],
1246                 [glib_cv_langinfo_codeset=no])])
1247 if test x$glib_cv_langinfo_codeset = xyes; then
1248   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1249 fi
1250
1251 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1252 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1253         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1254                  [char *str;
1255                  str = nl_langinfo (PM_STR);
1256                  str = nl_langinfo (D_T_FMT);
1257                  str = nl_langinfo (D_FMT);
1258                  str = nl_langinfo (T_FMT);
1259                  str = nl_langinfo (T_FMT_AMPM);
1260                  str = nl_langinfo (MON_1);
1261                  str = nl_langinfo (ABMON_12);
1262                  str = nl_langinfo (DAY_1);
1263                  str = nl_langinfo (ABDAY_7);])],
1264                 [glib_cv_langinfo_time=yes],
1265                 [glib_cv_langinfo_time=no])])
1266 if test x$glib_cv_langinfo_time = xyes; then
1267   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1268 fi
1269
1270 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1271 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1272         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1273                 [char *str;
1274                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1275                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1276                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1277                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1278                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1279                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1280                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1281                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1282                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1283                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1284                 [glib_cv_langinfo_outdigit=yes],
1285                 [glib_cv_langinfo_outdigit=no])])
1286 if test x$glib_cv_langinfo_outdigit = xyes; then
1287   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1288 fi
1289 AC_LANG_RESTORE
1290
1291 dnl ****************************************
1292 dnl *** posix_memalign                   ***
1293 dnl ****************************************
1294 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1295 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1296     glib_cv_compliant_posix_memalign=0
1297     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1298         AC_TRY_RUN([
1299                 #define _XOPEN_SOURCE 600
1300                 #include <stdlib.h> /* posix_memalign() should be defined here */
1301                 /* some systems break if #include <malloc.h> used */
1302                 static void test_memalign (size_t boundary, size_t size) {
1303                     void *mem = 0;
1304                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1305                         exit (1);
1306                     else
1307                       free (mem);
1308                 }
1309                 int main() {
1310                     test_memalign (  128,   128 - 2 * sizeof (void*));
1311                     test_memalign (  256,   256 - 2 * sizeof (void*));
1312                     test_memalign (  512,   512 - 2 * sizeof (void*));
1313                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1314                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1315                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1316                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1317                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1318                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1319                     exit (0); /* success */
1320                 }
1321                 ],
1322             [glib_cv_compliant_posix_memalign=1], [], [:])
1323       :
1324     fi
1325     ])
1326 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1327     AC_MSG_RESULT(yes)
1328     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1329 ], [
1330     AC_MSG_RESULT(no)
1331 ])
1332
1333
1334 dnl ****************************************
1335 dnl *** strlcpy/strlcat                  ***
1336 dnl ****************************************
1337 # Check for strlcpy
1338 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1339 AC_TRY_RUN([#include <stdlib.h>
1340 #include <string.h>
1341 int main() {
1342   char p[10];
1343   (void) strlcpy (p, "hi", 10);
1344   if (strlcat (p, "bye", 0) != 3)
1345     return 1;
1346   return 0;
1347 }], glib_cv_have_strlcpy=yes,
1348     glib_cv_have_strlcpy=no,
1349     glib_cv_have_strlcpy=no)])
1350 if test "$glib_cv_have_strlcpy" = "yes"; then
1351     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1352 fi
1353
1354
1355 dnl **********************
1356 dnl *** va_copy checks ***
1357 dnl **********************
1358 dnl we currently check for all three va_copy possibilities, so we get
1359 dnl all results in config.log for bug reports.
1360 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1361         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1362 #include <stdlib.h>
1363         void f (int i, ...) {
1364         va_list args1, args2;
1365         va_start (args1, i);
1366         va_copy (args2, args1);
1367         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1368           exit (1);
1369         va_end (args1); va_end (args2);
1370         }
1371         int main() {
1372           f (0, 42);
1373           return 0;
1374         }]])],
1375         [glib_cv_va_copy=yes],
1376         [glib_cv_va_copy=no])
1377 ])
1378 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1379         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1380 #include <stdlib.h>
1381         void f (int i, ...) {
1382         va_list args1, args2;
1383         va_start (args1, i);
1384         __va_copy (args2, args1);
1385         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1386           exit (1);
1387         va_end (args1); va_end (args2);
1388         }
1389         int main() {
1390           f (0, 42);
1391           return 0;
1392         }]])],
1393         [glib_cv___va_copy=yes],
1394         [glib_cv___va_copy=no])
1395 ])
1396
1397 if test "x$glib_cv_va_copy" = "xyes"; then
1398   g_va_copy_func=va_copy
1399 else if test "x$glib_cv___va_copy" = "xyes"; then
1400   g_va_copy_func=__va_copy
1401 fi
1402 fi
1403
1404 if test -n "$g_va_copy_func"; then
1405   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1406 fi
1407
1408 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1409         AC_TRY_RUN([#include <stdarg.h>
1410 #include <stdlib.h>
1411         void f (int i, ...) {
1412         va_list args1, args2;
1413         va_start (args1, i);
1414         args2 = args1;
1415         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1416           exit (1);
1417         va_end (args1); va_end (args2);
1418         }
1419         int main() {
1420           f (0, 42);
1421           return 0;
1422         }],
1423         [glib_cv_va_val_copy=yes],
1424         [glib_cv_va_val_copy=no],
1425         [glib_cv_va_val_copy=yes])
1426 ])
1427
1428 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1429   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1430 ])
1431
1432 dnl ***********************
1433 dnl *** g_module checks ***
1434 dnl ***********************
1435 G_MODULE_LIBS=
1436 G_MODULE_LIBS_EXTRA=
1437 G_MODULE_PLUGIN_LIBS=
1438 if test x"$glib_native_win32" = xyes; then
1439   dnl No use for this on Win32
1440   G_MODULE_LDFLAGS=
1441 else
1442   export SED
1443   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1444 fi
1445 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1446 G_MODULE_NEED_USCORE=0
1447 G_MODULE_BROKEN_RTLD_GLOBAL=0
1448 G_MODULE_HAVE_DLERROR=0
1449 dnl *** force native WIN32 shared lib loader
1450 if test -z "$G_MODULE_IMPL"; then
1451   case "$host" in
1452   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1453   esac
1454 fi
1455 dnl *** force native AIX library loader
1456 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1457 if test -z "$G_MODULE_IMPL"; then
1458   case "$host" in
1459   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1460   esac
1461 fi
1462 dnl *** dlopen() and dlsym() in system libraries
1463 AS_IF([ test -z "$G_MODULE_IMPL"], [
1464         AC_CHECK_FUNC(dlopen,
1465                       [AC_CHECK_FUNC(dlsym,
1466                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1467                       [])
1468 ])
1469 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1470 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1471         AC_CHECK_FUNC(NSLinkModule,
1472                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1473                        G_MODULE_NEED_USCORE=1],
1474                       [])
1475 ])
1476 dnl *** dlopen() and dlsym() in libdl
1477 AS_IF([ test -z "$G_MODULE_IMPL"], [
1478         AC_CHECK_LIB(dl, dlopen,
1479                      [AC_CHECK_LIB(dl, dlsym,
1480                                    [G_MODULE_LIBS=-ldl
1481                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1482                      [])
1483 ])
1484 dnl *** additional checks for G_MODULE_IMPL_DL
1485 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1486         LIBS_orig="$LIBS"
1487         LDFLAGS_orig="$LDFLAGS"
1488         LIBS="$G_MODULE_LIBS $LIBS"
1489         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1490 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1491         echo "void glib_plugin_test(void) { }" > plugin.c
1492         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1493                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1494         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1495                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1496                 -shrext ".o" -avoid-version plugin.lo \
1497                 -rpath /dont/care >/dev/null 2>&1
1498         eval `./libtool --config | grep ^objdir`
1499         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1500                 glib_cv_rtldglobal_broken,[
1501                 AC_TRY_RUN([
1502 #include <dlfcn.h>
1503 #ifndef RTLD_GLOBAL
1504 #  define RTLD_GLOBAL 0
1505 #endif
1506 #ifndef RTLD_LAZY
1507 #  define RTLD_LAZY 0
1508 #endif
1509 int glib_plugin_test;
1510 int main () {
1511     void *handle, *global, *local;
1512     global = &glib_plugin_test;
1513     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1514     if (!handle) return 0;
1515     local = dlsym (handle, "glib_plugin_test");
1516     return global == local;
1517 }                       ],
1518                         [glib_cv_rtldglobal_broken=no],
1519                         [glib_cv_rtldglobal_broken=yes],
1520                         [glib_cv_rtldglobal_broken=no])
1521                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1522                 rmdir ${objdir} 2>/dev/null
1523         ])
1524         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1525                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1526         else
1527                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1528         fi
1529 dnl *** check whether we need preceeding underscores
1530         AC_CACHE_CHECK([for preceeding underscore in symbols],
1531                 glib_cv_uscore,[
1532                 AC_TRY_RUN([#include <dlfcn.h>
1533                 int glib_underscore_test (void) { return 42; }
1534                 int main() {
1535                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1536                   handle = dlopen ((void*)0, 0);
1537                   if (handle) {
1538                     f1 = dlsym (handle, "glib_underscore_test");
1539                     f2 = dlsym (handle, "_glib_underscore_test");
1540                   } return (!f2 || f1);
1541                 }],
1542                         [glib_cv_uscore=yes],
1543                         [glib_cv_uscore=no],
1544                         [])
1545                 rm -f plugin.c plugin.$ac_objext plugin.lo
1546         ])
1547         GLIB_ASSERT_SET(glib_cv_uscore)
1548         if test "x$glib_cv_uscore" = "xyes"; then
1549                 G_MODULE_NEED_USCORE=1
1550         else
1551                 G_MODULE_NEED_USCORE=0
1552         fi
1553
1554         LDFLAGS="$LDFLAGS_orig"
1555 dnl *** check for having dlerror()
1556         AC_CHECK_FUNC(dlerror,
1557                 [G_MODULE_HAVE_DLERROR=1],
1558                 [G_MODULE_HAVE_DLERROR=0])
1559         LIBS="$LIBS_orig"
1560 ])
1561 dnl *** done, have we got an implementation?
1562 if test -z "$G_MODULE_IMPL"; then
1563         G_MODULE_IMPL=0
1564         G_MODULE_SUPPORTED=false
1565 else
1566         G_MODULE_SUPPORTED=true
1567 fi
1568
1569 AC_MSG_CHECKING(for the suffix of module shared libraries)
1570 export SED
1571 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1572 eval $shrext_cmds
1573 module=yes eval std_shrext=$shrext_cmds
1574 # chop the initial dot
1575 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1576 AC_MSG_RESULT(.$glib_gmodule_suffix)
1577 # any reason it may fail?
1578 if test "x$glib_gmodule_suffix" = x; then
1579         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1580 fi
1581
1582 AC_SUBST(G_MODULE_SUPPORTED)
1583 AC_SUBST(G_MODULE_IMPL)
1584 AC_SUBST(G_MODULE_LIBS)
1585 AC_SUBST(G_MODULE_LIBS_EXTRA)
1586 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1587 AC_SUBST(G_MODULE_LDFLAGS)
1588 AC_SUBST(G_MODULE_HAVE_DLERROR)
1589 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1590 AC_SUBST(G_MODULE_NEED_USCORE)
1591 AC_SUBST(GLIB_DEBUG_FLAGS)
1592
1593 dnl **********************
1594 dnl *** g_spawn checks ***
1595 dnl **********************
1596
1597 AC_MSG_CHECKING(for gspawn implementation)
1598 case "$host" in
1599   *-*-mingw*)
1600     GSPAWN=gspawn-win32.lo
1601     ;;
1602   *)
1603     GSPAWN=gspawn.lo
1604     ;;
1605 esac
1606 AC_MSG_RESULT($GSPAWN)
1607 AC_SUBST(GSPAWN)
1608
1609 dnl *************************
1610 dnl *** GIOChannel checks ***
1611 dnl *************************
1612
1613 AC_MSG_CHECKING(for GIOChannel implementation)
1614 case "$host" in
1615   *-*-mingw*)
1616     GIO=giowin32.lo
1617     ;;
1618   *)
1619     GIO=giounix.lo
1620     ;;
1621 esac
1622 AC_MSG_RESULT($GIO)
1623 AC_SUBST(GIO)
1624
1625 dnl *********************************
1626 dnl *** Directory for GIO modules ***
1627 dnl *********************************
1628
1629 AC_ARG_WITH(gio-module-dir,
1630            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1631                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1632            [],
1633            [with_gio_module_dir='${libdir}/gio/modules'])
1634 GIO_MODULE_DIR=$with_gio_module_dir
1635 AC_SUBST(GIO_MODULE_DIR)
1636
1637 dnl **********************************
1638 dnl *** Check for libselinux (GIO) ***
1639 dnl **********************************
1640 AC_ARG_ENABLE(selinux,
1641               AS_HELP_STRING([--disable-selinux],
1642                              [build without selinux support]))
1643 msg_selinux=no
1644 SELINUX_LIBS=
1645 AS_IF([ test "x$enable_selinux" != "xno"], [
1646
1647  AC_CHECK_LIB(selinux, is_selinux_enabled,
1648    [AC_CHECK_HEADERS(selinux/selinux.h,
1649      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1650        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1651         SELINUX_LIBS="-lselinux"
1652         msg_selinux=yes])
1653      ])
1654    ])
1655 ])
1656 AC_SUBST(SELINUX_LIBS)
1657
1658 dnl *****************************
1659 dnl ** Check for inotify (GIO) **
1660 dnl *****************************
1661 inotify_support=no
1662 AC_CHECK_HEADERS([sys/inotify.h],
1663 [
1664   AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1665 ])
1666
1667 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1668
1669 dnl ****************************
1670 dnl ** Check for kqueue (GIO) **
1671 dnl ****************************
1672 kqueue_support=no
1673 AC_CHECK_HEADERS([sys/event.h],
1674 [
1675         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1676 ])
1677
1678 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1679
1680 dnl ****************************
1681 dnl *** Checks for FAM (GIO) ***
1682 dnl ****************************
1683
1684 should_disable_fam=no
1685
1686 AC_ARG_ENABLE(fam,
1687               AS_HELP_STRING([--disable-fam],
1688                              [don't use fam for file system monitoring]),
1689                          [
1690                                 if test "x$enable_fam" = "xno"; then
1691                                         should_disable_fam=yes
1692                                 fi
1693                          ]
1694                          )
1695 fam_support=no
1696 FAM_LIBS=
1697 if test "x$should_disable_fam" = "xno"; then
1698 AC_CHECK_LIB(fam, FAMOpen,
1699   [AC_CHECK_HEADERS(fam.h,
1700     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1701      AC_CHECK_LIB(fam, FAMNoExists,
1702                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1703      FAM_LIBS="-lfam"]
1704      fam_support=yes,
1705     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1706   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1707 AC_SUBST(FAM_LIBS)
1708 fi
1709 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1710
1711
1712 dnl *****************************
1713 dnl *** Check for xattr (GIO) ***
1714 dnl *****************************
1715 AC_ARG_ENABLE(xattr,
1716               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1717 msg_xattr=no
1718 XATTR_LIBS=
1719 AS_IF([ test "x$enable_xattr" != "xno"], [
1720
1721 dnl either glibc or libattr can provide xattr support
1722
1723 dnl for both of them, we check for getxattr being in
1724 dnl the library and a valid xattr header.
1725
1726 dnl try glibc
1727  AC_CHECK_LIB(c, getxattr,
1728    [AC_CHECK_HEADERS(sys/xattr.h,
1729      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1730       msg_xattr=yes])
1731    ])
1732
1733   AS_IF([ test "x$msg_xattr" != "xyes"], [
1734 dnl   failure. try libattr
1735    AC_CHECK_LIB(attr, getxattr,
1736       [AC_CHECK_HEADERS(attr/xattr.h,
1737        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1738         XATTR_LIBS="-lattr"
1739         msg_xattr=yes])
1740       ])
1741   ])
1742
1743   AS_IF([ test "x$msg_xattr" = "xyes"], [
1744     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1745     AC_TRY_COMPILE([
1746       #include <stdio.h>
1747       #ifdef HAVE_SYS_TYPES_H
1748       #include <sys/types.h>
1749       #endif
1750       #ifdef HAVE_SYS_XATTR_H
1751       #include <sys/xattr.h>
1752       #elif HAVE_ATTR_XATTR_H
1753       #include <attr/xattr.h>
1754       #endif
1755     ],
1756     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1757     [
1758       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1759       AC_MSG_RESULT([yes])
1760     ],
1761     [AC_MSG_RESULT([no])]
1762     )
1763   ])
1764 ])
1765 AC_SUBST(XATTR_LIBS)
1766
1767 dnl ************************
1768 dnl *** check for libelf ***
1769 dnl ************************
1770 AC_ARG_ENABLE(libelf,
1771               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1772 AS_IF([ test "x$enable_libelf" != "xno"],[
1773 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1774 AS_IF([ test $have_libelf = maybe ], [
1775   glib_save_LIBS=$LIBS
1776   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1777   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1778   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1779   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1780   LIBS=$glib_save_LIBS
1781
1782   if test $have_libelf != no; then
1783     LIBELF_LIBS=-lelf
1784     have_libelf=yes
1785   fi
1786 ])
1787 ])
1788
1789 if test x$have_libelf = xyes; then
1790   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1791 fi
1792
1793 dnl ****************************************
1794 dnl *** platform dependent source checks ***
1795 dnl ****************************************
1796
1797 AC_MSG_CHECKING(for platform-dependent source)
1798 case "$host" in
1799   *-*-cygwin*|*-*-mingw*)
1800     PLATFORMDEP=gwin32.lo
1801     ;;
1802   *)
1803     PLATFORMDEP=
1804     ;;
1805 esac
1806 AC_MSG_RESULT($PLATFORMDEP)
1807 AC_SUBST(PLATFORMDEP)
1808
1809 AC_MSG_CHECKING([whether to compile timeloop])
1810 case "$host" in
1811   *-*-cygwin*|*-*-mingw*|*-*-minix)
1812     enable_timeloop=no
1813     ;;
1814   *)
1815     enable_timeloop=yes
1816     ;;
1817 esac
1818 AC_MSG_RESULT($enable_timeloop)
1819 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1820
1821 AC_MSG_CHECKING([if building for some Win32 platform])
1822 case "$host" in
1823   *-*-mingw*|*-*-cygwin*)
1824     platform_win32=yes
1825     ;;
1826   *)
1827     platform_win32=no
1828     ;;
1829 esac
1830 AC_MSG_RESULT($platform_win32)
1831 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1832
1833 dnl ***********************
1834 dnl *** g_thread checks ***
1835 dnl ***********************
1836
1837 AC_ARG_WITH(threads,
1838            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1839                            [specify a thread implementation to use])],
1840            [],
1841            [with_threads=yes])
1842
1843 dnl error and warning message
1844 dnl *************************
1845
1846 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1847
1848 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1849                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1850                 compilation now, but then your programs might not work.
1851                 Please provide information on how it is done on your system."
1852
1853 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1854                  "
1855
1856 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1857                   provide information on your thread implementation."
1858
1859 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1860                 functions will not be MT-safe during their first call because
1861                 there is no working 'getpwuid_r' on your system."
1862
1863 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1864                 because there is no 'localtime_r' on your system."
1865
1866 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1867                 linking threaded applications. As GLib cannot do that
1868                 automatically, you will get an linkg error everytime you are
1869                 not using the right compiler. In that case you have to relink
1870                 with the right compiler. Ususally just '_r' is appended
1871                 to the compiler name."
1872
1873 dnl determination of thread implementation
1874 dnl ***************************************
1875
1876 AC_MSG_CHECKING(for thread implementation)
1877
1878 have_threads=no
1879 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1880         AS_IF([ test "x$have_threads" = xno], [
1881                 AC_TRY_COMPILE([#include <pthread.h>],
1882                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1883                         have_threads=posix)
1884         ])
1885         # Tru64Unix requires -pthread to find pthread.h. See #103020
1886         if test "x$have_threads" = xno; then
1887                 glib_save_CPPFLAGS="$CPPFLAGS"
1888                 CPPFLAGS="$CPPFLAGS -pthread"
1889                 AC_TRY_COMPILE([#include <pthread.h>],
1890                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1891                        have_threads=posix)
1892                 CPPFLAGS="$glib_save_CPPFLAGS"
1893         fi
1894 ])
1895 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1896         case $host in
1897                 *-*-mingw*)
1898                 have_threads=win32
1899                 ;;
1900         esac
1901 fi
1902
1903 if test "x$have_threads" = xno; then
1904         AC_MSG_RESULT(none available)
1905         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1906 else
1907         AC_MSG_RESULT($have_threads)
1908 fi
1909
1910
1911 dnl determination of G_THREAD_CFLAGS
1912 dnl ********************************
1913
1914 G_THREAD_LIBS=
1915 G_THREAD_LIBS_EXTRA=
1916 G_THREAD_CFLAGS=
1917
1918 dnl
1919 dnl Test program for basic POSIX threads functionality
1920 dnl
1921 m4_define([glib_thread_test],[
1922 #include <pthread.h>
1923 int check_me = 0;
1924 void* func(void* data) {check_me = 42; return &check_me;}
1925 int main()
1926  { pthread_t t;
1927    void *ret;
1928    pthread_create (&t, $1, func, 0);
1929    pthread_join (t, &ret);
1930    return (check_me != 42 || ret != &check_me);
1931 }])
1932
1933 AS_IF([ test x"$have_threads" = xposix], [
1934   # First we test for posix, whether -pthread or -pthreads do the trick as
1935   # both CPPFLAG and LIBS.
1936   # One of them does for most gcc versions and some other platforms/compilers
1937   # too and could be considered as the canonical way to go.
1938   case $host in
1939     *-*-cygwin*|*-*-darwin*)
1940        # skip cygwin and darwin -pthread or -pthreads test
1941        ;;
1942     *-solaris*)
1943       # These compiler/linker flags work with both Sun Studio and gcc
1944       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1945       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1946       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1947       G_THREAD_LIBS="-lpthread -lthread"
1948       ;;
1949     *)
1950       for flag in pthread pthreads mt; do
1951         glib_save_CFLAGS="$CFLAGS"
1952         CFLAGS="$CFLAGS -$flag"
1953         AC_TRY_RUN(glib_thread_test(0),
1954                    glib_flag_works=yes,
1955                    glib_flag_works=no,
1956                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1957                                    glib_flag_works=yes,
1958                                    glib_flag_works=no)])
1959         CFLAGS="$glib_save_CFLAGS"
1960         if test $glib_flag_works = yes ; then
1961            G_THREAD_CFLAGS=-$flag
1962         G_THREAD_LIBS=-$flag
1963         break;
1964         fi
1965       done
1966        ;;
1967   esac
1968 ])
1969
1970 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1971
1972   # The canonical -pthread[s] does not work. Try something different.
1973
1974   case $host in
1975         *-aix*)
1976                 if test x"$GCC" = xyes; then
1977                         # GCC 3.0 and above needs -pthread.
1978                         # Should be coverd by the case above.
1979                         # GCC 2.x and below needs -mthreads
1980                         G_THREAD_CFLAGS="-mthreads"
1981                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1982                 else
1983                         # We are probably using the aix compiler. Normaly a
1984                         # program would have to be compiled with the _r variant
1985                         # of the corresponding compiler, but we as GLib cannot
1986                         # do that: but the good news is that for compiling the
1987                         # only difference is the added -D_THREAD_SAFE compile
1988                         # option. This is according to the "C for AIX User's
1989                         # Guide".
1990                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1991                 fi
1992                 ;;
1993         *-sysv5uw7*) # UnixWare 7
1994                 # We are not using gcc with -pthread. Catched above.
1995                 G_THREAD_CFLAGS="-Kthread"
1996                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1997                 ;;
1998         *-mingw*)
1999                 # No flag needed when using MSVCRT.DLL
2000                 G_THREAD_CFLAGS=""
2001                 ;;
2002         *)
2003                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2004                 ;;
2005   esac
2006 ])
2007
2008 # if we are not finding the localtime_r function, then we probably are
2009 # not using the proper multithread flag
2010
2011 glib_save_CPPFLAGS="$CPPFLAGS"
2012 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2013
2014 # First we test, whether localtime_r is declared in time.h
2015 # directly. Then we test whether a macro localtime_r exists, in
2016 # which case localtime_r in the test program is replaced and thus
2017 # if we still find localtime_r in the output, it is not defined as
2018 # a macro.
2019
2020 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2021   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2022                                                            localtime_r(a,b)],
2023                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2024
2025 CPPFLAGS="$glib_save_CPPFLAGS"
2026
2027 AC_MSG_CHECKING(thread related cflags)
2028 AC_MSG_RESULT($G_THREAD_CFLAGS)
2029 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2030
2031 dnl determination of G_THREAD_LIBS
2032 dnl ******************************
2033
2034 AS_IF([test x$have_threads = xposix], [
2035           glib_save_CPPFLAGS="$CPPFLAGS"
2036           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2037           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2038             case $host in
2039               *-aix*)
2040                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2041                 # probably using the aix compiler.
2042                 AC_MSG_WARN($AIX_COMPILE_INFO)
2043                 ;;
2044               *)
2045                 G_THREAD_LIBS=error
2046                 glib_save_LIBS="$LIBS"
2047                 for thread_lib in "" pthread pthread32 pthreads thread; do
2048                         if test x"$thread_lib" = x; then
2049                                 add_thread_lib=""
2050                                 IN=""
2051                         else
2052                                 add_thread_lib="-l$thread_lib"
2053                                 IN=" in -l$thread_lib"
2054                         fi
2055                         if test x"$have_threads" = xposix; then
2056                                 defattr=0
2057                         else
2058                                 defattr=pthread_attr_default
2059                         fi
2060
2061                         LIBS="$add_thread_lib $glib_save_LIBS"
2062
2063                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2064                         AC_TRY_RUN(glib_thread_test($defattr),
2065                                    glib_result=yes,
2066                                    glib_result=no,
2067                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2068                                                    glib_result=yes,
2069                                                    glib_result=no)])
2070                         AC_MSG_RESULT($glib_result)
2071
2072                         if test "$glib_result" = "yes" ; then
2073                           G_THREAD_LIBS="$add_thread_lib"
2074                           break
2075                         fi
2076                 done
2077                 if test "x$G_THREAD_LIBS" = xerror; then
2078                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2079                 fi
2080                 LIBS="$glib_save_LIBS"
2081                 ;;
2082             esac
2083           ])
2084
2085           g_threads_impl="POSIX"
2086           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2087           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2088           CPPFLAGS="$glib_save_CPPFLAGS"
2089 ], [test x$have_threads = xwin32], [
2090            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2091            g_threads_impl="WIN32"
2092 ], [
2093            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2094            g_threads_impl="NONE"
2095            G_THREAD_LIBS=error
2096 ])
2097 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2098 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2099 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2100
2101 if test "x$G_THREAD_LIBS" = xerror; then
2102         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2103 fi
2104
2105 AC_MSG_CHECKING(thread related libraries)
2106 AC_MSG_RESULT($G_THREAD_LIBS)
2107
2108 dnl check for mt safe function variants and some posix functions
2109 dnl ************************************************************
2110
2111 glib_save_LIBS="$LIBS"
2112 # we are not doing the following for now, as this might require glib
2113 # to always be linked with the thread libs on some platforms.
2114 # LIBS="$LIBS $G_THREAD_LIBS"
2115 AC_CHECK_FUNCS(localtime_r gmtime_r)
2116 AS_IF([ test "$glib_native_win32" != "yes"], [
2117         AC_CACHE_CHECK([for posix getpwuid_r],
2118                 ac_cv_func_posix_getpwuid_r,
2119                 [AC_TRY_RUN([
2120 #include <errno.h>
2121 #include <pwd.h>
2122 int main () {
2123     char buffer[10000];
2124     struct passwd pwd, *pwptr = &pwd;
2125     int error;
2126     errno = 0;
2127     error = getpwuid_r (0, &pwd, buffer,
2128                         sizeof (buffer), &pwptr);
2129    return (error < 0 && errno == ENOSYS)
2130            || error == ENOSYS;
2131 }                               ],
2132                         [ac_cv_func_posix_getpwuid_r=yes],
2133                         [ac_cv_func_posix_getpwuid_r=no])])
2134         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2135         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2136                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2137                         [Have POSIX function getpwuid_r])
2138         else
2139                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2140                         ac_cv_func_nonposix_getpwuid_r,
2141                         [AC_TRY_LINK([#include <pwd.h>],
2142                                 [char buffer[10000];
2143                                 struct passwd pwd;
2144                                 getpwuid_r (0, &pwd, buffer,
2145                                                 sizeof (buffer));],
2146                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2147                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2148                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2149                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2150                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2151                                 [Have non-POSIX function getpwuid_r])
2152                 fi
2153         fi
2154 ])
2155 AS_IF([ test "$glib_native_win32" != "yes"], [
2156         AC_CACHE_CHECK([for posix getgrgid_r],
2157                 ac_cv_func_posix_getgrgid_r,
2158                 [AC_TRY_RUN([
2159 #include <errno.h>
2160 #include <grp.h>
2161 int main () {
2162     char buffer[10000];
2163     struct group grp, *grpptr = &grp;
2164     int error;
2165     errno = 0;
2166     error = getgrgid_r (0, &grp, buffer,
2167                         sizeof (buffer), &grpptr);
2168    return (error < 0 && errno == ENOSYS)
2169            || error == ENOSYS;
2170 }                              ],
2171                        [ac_cv_func_posix_getgrgid_r=yes],
2172                        [ac_cv_func_posix_getgrgid_r=no])])
2173         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2174         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2175                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2176                         [Have POSIX function getgrgid_r])
2177         ], [
2178                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2179                         ac_cv_func_nonposix_getgrgid_r,
2180                         [AC_TRY_LINK([#include <grp.h>],
2181                                 [char buffer[10000];
2182                                 struct group grp;
2183                                 getgrgid_r (0, &grp, buffer,
2184                                 sizeof (buffer));],
2185                         [ac_cv_func_nonposix_getgrgid_r=yes],
2186                         [ac_cv_func_nonposix_getgrgid_r=no])])
2187                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2188                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2189                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2190                                 [Have non-POSIX function getgrgid_r])
2191                 fi
2192         ])
2193 ])
2194 LIBS="$G_THREAD_LIBS $LIBS"
2195 AS_IF([ test x"$have_threads" = xposix], [
2196         glib_save_CPPFLAGS="$CPPFLAGS"
2197         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2198         # This is not AC_CHECK_FUNC to also work with function
2199         # name mangling in header files.
2200         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2201         AC_LINK_IFELSE(
2202             [AC_LANG_PROGRAM(
2203                 [#include <pthread.h>],
2204                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2205             [AC_MSG_RESULT(yes)
2206              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2207                 [Have function pthread_attr_setstacksize])],
2208             [AC_MSG_RESULT(no)])
2209         AC_MSG_CHECKING(for pthread_condattr_setclock)
2210         AC_LINK_IFELSE(
2211             [AC_LANG_PROGRAM(
2212                 [#include <pthread.h>],
2213                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2214             [AC_MSG_RESULT(yes)
2215              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2216                 [Have function pthread_condattr_setclock])],
2217             [AC_MSG_RESULT(no)])
2218         AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2219         AC_LINK_IFELSE(
2220             [AC_LANG_PROGRAM(
2221                 [#include <pthread.h>],
2222                 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2223             [AC_MSG_RESULT(yes)
2224              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2225                 [Have function pthread_cond_timedwait_relative_np])],
2226             [AC_MSG_RESULT(no)])
2227         dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2228         AC_MSG_CHECKING(for pthread_setname_np(const char*))
2229         AC_LINK_IFELSE(
2230             [AC_LANG_PROGRAM(
2231                 [#include <pthread.h>],
2232                 [pthread_setname_np("example")])],
2233             [AC_MSG_RESULT(yes)
2234              AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2235                 [Have function pthread_setname_np(const char*)])],
2236             [AC_MSG_RESULT(no)])
2237         CPPFLAGS="$glib_save_CPPFLAGS"
2238 ])
2239
2240 LIBS="$glib_save_LIBS"
2241
2242 # now spit out all the warnings.
2243 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2244    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2245         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2246 fi
2247 if test "$ac_cv_func_localtime_r" != "yes"; then
2248         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2249 fi
2250
2251 #
2252 # Hack to deal with:
2253 #
2254 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2255 #     building shared libraries with linux.
2256 #  b) FreeBSD doesn't do this either.
2257 #
2258 case $host in
2259   *android*)
2260     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2261     ;;
2262   *-*-freebsd*|*-*-linux*)
2263     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2264     ;;
2265   *)
2266     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2267     ;;
2268 esac
2269
2270 AC_SUBST(G_THREAD_CFLAGS)
2271 AC_SUBST(G_THREAD_LIBS)
2272 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2273 AC_SUBST(G_THREAD_LIBS_EXTRA)
2274
2275 AC_CHECK_FUNCS(clock_gettime, [], [
2276   AC_CHECK_LIB(rt, clock_gettime, [
2277     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2278     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2279   ])
2280 ])
2281
2282
2283 dnl ************************
2284 dnl *** g_atomic_* tests ***
2285 dnl ************************
2286
2287 dnl We need to decide at configure time if GLib will use real atomic
2288 dnl operations ("lock free") or emulated ones with a mutex.  This is
2289 dnl because we must put this information in glibconfig.h so we know if
2290 dnl it is safe or not to inline using compiler intrinsics directly from
2291 dnl the header.
2292 dnl
2293 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2294 dnl user is interested in knowing if they can use the atomic ops across
2295 dnl processes.
2296 dnl
2297 dnl We can currently support the atomic ops natively when building GLib
2298 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2299 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2300 dnl we are using GCC (and not mingw*).
2301 dnl
2302 dnl Note that the atomic ops are only available with GCC on x86 when
2303 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2304 dnl not available but would be available given the right flags, we want
2305 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2306 dnl that then to silently fall back on emulated atomic ops just because
2307 dnl the user had the wrong build environment.
2308
2309 dnl We may add other compilers here in the future...
2310
2311 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2312   case $host in
2313     *-*-mingw*)
2314       glib_cv_g_atomic_lock_free=yes
2315       ;;
2316     *)
2317       AC_TRY_LINK([],
2318                      [volatile int atomic = 2;\
2319                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2320                      [glib_cv_g_atomic_lock_free=yes],
2321                      [glib_cv_g_atomic_lock_free=no])
2322       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2323         SAVE_CFLAGS="${CFLAGS}"
2324         CFLAGS="-march=i486"
2325         AC_TRY_LINK([],
2326                        [volatile int atomic = 2;\
2327                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2328                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2329                        [])
2330         CFLAGS="${SAVE_CFLAGS}"
2331       fi
2332       ;;
2333   esac])
2334
2335
2336 case $host in
2337   *-*-mingw*)
2338     ;;
2339   *)
2340     # Some compilers support atomic operations but do not define
2341     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2342     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2343       AC_TRY_LINK([],
2344                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2345                      [],
2346                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2347     fi
2348     ;;
2349  esac
2350
2351 dnl We need a more robust approach here...
2352 case $host_cpu in
2353   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2354     glib_memory_barrier_needed=no
2355     ;;
2356   sparc*|alpha*|powerpc*|ia64)
2357     glib_memory_barrier_needed=yes
2358     ;;
2359   *)
2360     glib_memory_barrier_needed=yes
2361     ;;
2362 esac
2363
2364 dnl ************************
2365 dnl ** Check for futex(2) **
2366 dnl ************************
2367 AC_CACHE_CHECK(for futex(2) system call,
2368     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2369 #include <linux/futex.h>
2370 #include <sys/syscall.h>
2371 #include <unistd.h>
2372 ],[
2373   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2374 ])],glib_cv_futex=yes,glib_cv_futex=no))
2375 if test x"$glib_cv_futex" = xyes; then
2376   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2377 fi
2378
2379 AC_CACHE_CHECK(for eventfd(2) system call,
2380     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2381 #include <sys/eventfd.h>
2382 #include <unistd.h>
2383 ],[
2384   eventfd (0, EFD_CLOEXEC);
2385 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2386 if test x"$glib_cv_eventfd" = x"yes"; then
2387   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2388 fi
2389 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2390
2391 dnl ****************************************
2392 dnl *** GLib POLL* compatibility defines ***
2393 dnl ****************************************
2394
2395 glib_poll_includes=["
2396 #include <sys/types.h>
2397 #include <poll.h>
2398 "]
2399
2400 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2401    test $ac_cv_func_poll = yes ], [
2402   glib_failed=false
2403   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2404   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2405   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2406   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2407   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2408   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2409   if $glib_failed ; then
2410     AC_MSG_ERROR([Could not determine values for POLL* constants])
2411   fi
2412 ], [
2413   glib_cv_value_POLLIN=1
2414   glib_cv_value_POLLOUT=4
2415   glib_cv_value_POLLPRI=2
2416   glib_cv_value_POLLERR=8
2417   glib_cv_value_POLLHUP=16
2418   glib_cv_value_POLLNVAL=32
2419 ])
2420
2421 AC_MSG_CHECKING([for broken poll])
2422 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2423         #include <stdlib.h>
2424         #include <fcntl.h>
2425         #include <poll.h>
2426         int main(void) {
2427           struct pollfd fds[1];
2428           int fd;
2429           fd = open("/dev/null", 1);
2430           fds[0].fd = fd;
2431           fds[0].events = POLLIN;
2432           fds[0].revents = 0;
2433           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2434                 exit(1);  /* Does not work for devices -- fail */
2435           }
2436           exit(0);
2437         }]])],
2438   [broken_poll=no],
2439   [broken_poll=yes
2440    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2441   [broken_poll="no (cross compiling)"])
2442 AC_MSG_RESULT($broken_poll)
2443
2444 dnl *********************
2445 dnl *** GRegex checks ***
2446 dnl *********************
2447
2448 PCRE_REQUIRED_VERSION=8.13
2449
2450 # Check if we should use the internal or the system-supplied pcre
2451 AC_ARG_WITH(pcre,
2452             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2453                             [whether to use system PCRE [default=internal]])])
2454
2455 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2456
2457 AS_IF([ test "x$with_pcre" = xsystem], [
2458   PKG_CHECK_MODULES(PCRE,
2459                     libpcre >= $PCRE_REQUIRED_VERSION)
2460   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2461                   glib_save_CFLAGS="$CFLAGS"
2462                   glib_save_LIBS="$LIBS"
2463                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2464                   AC_TRY_RUN([#include <pcre.h>
2465                               int main () {
2466                                 int support;
2467                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2468                                 if (!support)
2469                                   return 1;
2470                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2471                                 if (!support)
2472                                   return 1;
2473                                 return 0;
2474                               }],
2475                   glib_cv_pcre_has_unicode=yes,
2476                   glib_cv_pcre_has_unicode=no,
2477                   glib_cv_pcre_has_unicode=yes)
2478                   CFLAGS="$glib_save_CFLAGS"
2479                   LIBS="$glib_save_LIBS"
2480       ])
2481   if test "$glib_cv_pcre_has_unicode" = "no"; then
2482     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2483   fi
2484   AC_SUBST(PCRE_CFLAGS)
2485   AC_SUBST(PCRE_LIBS)
2486   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2487   PCRE_REQUIRES=libpcre
2488   AC_SUBST(PCRE_REQUIRES)
2489 ], [
2490   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2491   AS_IF([ test x"$GCC" = xyes], [
2492     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2493     save_CFLAGS="$CFLAGS"
2494     CFLAGS="$CFLAGS -Wno-pointer-sign"
2495     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2496                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2497     CFLAGS="$save_CFLAGS"
2498   ])
2499 ])
2500 AC_SUBST(PCRE_WARN_CFLAGS)
2501
2502 dnl **********************
2503 dnl *** Win32 API libs ***
2504 dnl **********************
2505
2506 case $host in
2507   *-*-cygwin*)
2508         G_LIBS_EXTRA="-luser32 -lkernel32"
2509     ;;
2510   *-*-mingw*)
2511         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2512     ;;
2513   *)
2514         G_LIBS_EXTRA=""
2515     ;;
2516 esac
2517 AC_SUBST(G_LIBS_EXTRA)
2518
2519 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2520 dnl since we need it for g_iconv()
2521
2522 AC_MSG_CHECKING([for EILSEQ])
2523 AC_TRY_COMPILE([
2524 #include <errno.h>
2525 ],
2526 [
2527 int error = EILSEQ;
2528 ], have_eilseq=yes, have_eilseq=no);
2529 AC_MSG_RESULT($have_eilseq)
2530
2531 dnl ******************************************************************
2532 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2533 dnl *** glib-compile-schemas in PATH                               ***
2534 dnl ******************************************************************
2535
2536 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2537
2538 AS_IF([ test $cross_compiling = yes ], [
2539   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2540   if test x$GLIB_GENMARSHAL = xno; then
2541     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2542   fi
2543
2544   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2545   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2546     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2547   fi
2548
2549   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2550   if test x$GLIB_COMPILE_RESOURCES = xno; then
2551     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2552   fi
2553 ])
2554
2555 dnl **************************
2556 dnl *** Checks for gtk-doc ***
2557 dnl **************************
2558 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2559 # it on it's own line.
2560 m4_ifdef([GTK_DOC_CHECK], [
2561 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2562 ],[
2563 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2564 ])
2565
2566 AC_ARG_ENABLE(man,
2567               [AS_HELP_STRING([--enable-man],
2568                               [generate man pages [default=auto]])],,
2569               enable_man=maybe)
2570
2571 AS_IF([test "$enable_man" != no], [
2572   AC_PATH_PROG([XSLTPROC], [xsltproc])
2573   AS_IF([test -z "$XSLTPROC"], [
2574     AS_IF([test "$enable_man" = yes], [
2575       AC_MSG_ERROR([xsltproc is required for --enable-man])
2576     ])
2577     enable_man=no
2578   ])
2579 ])
2580
2581 AS_IF([ test "$enable_man" != no ], [
2582   dnl check for DocBook DTD in the local catalog
2583   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2584      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2585   AS_IF([test "$have_docbook_dtd" != yes], [
2586     AS_IF([test "$enable_man" = yes ], [
2587       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2588     ])
2589     enable_man=no
2590   ])
2591 ])
2592
2593 AS_IF([test "$enable_man" != no], [
2594   dnl check for DocBook XSL stylesheets in the local catalog
2595   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2596      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2597   AS_IF([ test "$have_docbook_dtd" != yes ], [
2598     AS_IF([ test "$enable_man" = yes ], [
2599       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2600     ])
2601     enable_man=no
2602   ])
2603 ])
2604
2605 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2606
2607 AC_MSG_CHECKING([whether to generate man pages])
2608 AS_IF([ test "$enable_man" != no ], [
2609   AC_MSG_RESULT([yes])
2610 ], [
2611   AC_MSG_RESULT([no])
2612 ])
2613
2614 dnl
2615 dnl Tracing
2616 dnl
2617
2618 AC_ARG_ENABLE([dtrace],
2619              [AS_HELP_STRING([--enable-dtrace],
2620                               [include tracing support for dtrace])])
2621 have_dtrace=no
2622 AC_MSG_CHECKING([whether to include dtrace tracing support])
2623 AS_IF([ test "x$enable_dtrace" != xno], [
2624   if test x$glib_have_carbon = xyes; then
2625     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2626   else
2627     AC_MSG_RESULT([yes])
2628     AC_CHECK_PROGS(DTRACE, dtrace)
2629     if test -z "$DTRACE"; then
2630       if test "x$enable_dtrace" = xyes; then
2631         AC_MSG_ERROR([dtrace not found])
2632       fi
2633     else
2634       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2635                       [if test "x$enable_dtrace" = xyes; then
2636                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2637                        fi])
2638     fi
2639   fi
2640 ], [
2641   AC_MSG_RESULT([no])
2642 ])
2643 if test "x$have_dtrace" = xyes; then
2644   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2645 fi
2646 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2647
2648 AC_MSG_CHECKING([whether to include systemtap tracing support])
2649 AC_ARG_ENABLE([systemtap],
2650              [AS_HELP_STRING([--enable-systemtap],
2651                               [include tracing support for systemtap])])
2652 have_systemtap=no
2653 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2654   have_systemtap=yes
2655 fi
2656 AC_MSG_RESULT(${have_systemtap})
2657
2658 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2659
2660 AC_ARG_WITH([tapset-install-dir],
2661             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2662                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2663             [if test "x${withval}" = x; then
2664                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2665              else
2666                ABS_TAPSET_DIR="${withval}"
2667               fi],
2668             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2669 AC_SUBST(ABS_TAPSET_DIR)
2670
2671 dnl ************************************
2672 dnl *** Enable lcov coverage reports ***
2673 dnl ************************************
2674
2675 AC_ARG_ENABLE(coverage,
2676   AS_HELP_STRING([--enable-coverage],
2677                  [enable coverage testing with gcov]),
2678   [use_gcov=$enableval], [use_gcov=no])
2679
2680 AS_IF([ test "x$use_gcov" = "xyes"], [
2681   dnl we need gcc:
2682   if test "$GCC" != "yes"; then
2683     AC_MSG_ERROR([GCC is required for --enable-coverage])
2684   fi
2685
2686   dnl Check if ccache is being used
2687   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2688   case `$SHTOOL path $CC` in
2689     *ccache*[)] gcc_ccache=yes;;
2690     *[)] gcc_ccache=no;;
2691   esac
2692
2693   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2694     AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2695   fi
2696
2697   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2698   AC_CHECK_PROG(LTP, lcov, lcov)
2699   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2700
2701   AS_IF([ test "$LTP" ], [
2702     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2703       glib_cv_ltp_version=invalid
2704       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2705       for ltp_check_version in $ltp_version_list; do
2706         if test "$ltp_version" = "$ltp_check_version"; then
2707           glib_cv_ltp_version="$ltp_check_version (ok)"
2708         fi
2709       done
2710     ])
2711   ], [
2712     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2713     AC_MSG_ERROR([$ltp_msg])
2714   ])
2715
2716   case $glib_cv_ltp_version in
2717     ""|invalid[)]
2718       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2719       AC_MSG_ERROR([$ltp_msg])
2720       LTP="exit 0;"
2721       ;;
2722   esac
2723
2724   if test -z "$LTP_GENHTML"; then
2725     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2726   fi
2727
2728   dnl Remove all optimization flags from CFLAGS
2729   changequote({,})
2730   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2731   changequote([,])
2732
2733   dnl Add the special gcc flags
2734   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2735   LDFLAGS="$LDFLAGS -lgcov"
2736 ])
2737
2738 dnl ******************************
2739 dnl *** output the whole stuff ***
2740 dnl ******************************
2741
2742 dnl this section will only be run if config.status is invoked with no
2743 dnl arguments, or with "glib/glibconfig.h" as an argument.
2744 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2745 [
2746         outfile=glib/glibconfig.h-tmp
2747         cat > $outfile <<\_______EOF
2748 /* glibconfig.h
2749  *
2750  * This is a generated file.  Please modify 'configure.ac'
2751  */
2752
2753 #ifndef __GLIBCONFIG_H__
2754 #define __GLIBCONFIG_H__
2755
2756 #include <glib/gmacros.h>
2757
2758 _______EOF
2759
2760         echo '#include <limits.h>' >> $outfile
2761         echo '#include <float.h>' >> $outfile
2762         if test x$glib_values_h = xyes; then
2763           echo '#include <values.h>' >> $outfile
2764         fi
2765         if test "$glib_header_alloca_h" = "yes"; then
2766           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2767         fi
2768         if test x$glib_included_printf != xyes; then
2769           echo "
2770 /* Specifies that GLib's g_print*() functions wrap the
2771  * system printf functions.  This is useful to know, for example,
2772  * when using glibc's register_printf_function().
2773  */" >> $outfile
2774           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2775         fi
2776
2777         cat >> $outfile <<_______EOF
2778
2779 G_BEGIN_DECLS
2780
2781 #define G_MINFLOAT      FLT_MIN
2782 #define G_MAXFLOAT      FLT_MAX
2783 #define G_MINDOUBLE     DBL_MIN
2784 #define G_MAXDOUBLE     DBL_MAX
2785 #define G_MINSHORT      SHRT_MIN
2786 #define G_MAXSHORT      SHRT_MAX
2787 #define G_MAXUSHORT     USHRT_MAX
2788 #define G_MININT        INT_MIN
2789 #define G_MAXINT        INT_MAX
2790 #define G_MAXUINT       UINT_MAX
2791 #define G_MINLONG       LONG_MIN
2792 #define G_MAXLONG       LONG_MAX
2793 #define G_MAXULONG      ULONG_MAX
2794
2795 _______EOF
2796
2797
2798         ### this should always be true in a modern C/C++ compiler
2799         ### and is statically asserted by glib-init.c
2800         cat >>$outfile <<_______EOF
2801 typedef signed char gint8;
2802 typedef unsigned char guint8;
2803 _______EOF
2804
2805
2806         if test -n "$gint16"; then
2807           cat >>$outfile <<_______EOF
2808 typedef signed $gint16 gint16;
2809 typedef unsigned $gint16 guint16;
2810 #define G_GINT16_MODIFIER $gint16_modifier
2811 #define G_GINT16_FORMAT $gint16_format
2812 #define G_GUINT16_FORMAT $guint16_format
2813 _______EOF
2814         fi
2815
2816
2817         if test -n "$gint32"; then
2818           cat >>$outfile <<_______EOF
2819 typedef signed $gint32 gint32;
2820 typedef unsigned $gint32 guint32;
2821 #define G_GINT32_MODIFIER $gint32_modifier
2822 #define G_GINT32_FORMAT $gint32_format
2823 #define G_GUINT32_FORMAT $guint32_format
2824 _______EOF
2825         fi
2826
2827         cat >>$outfile <<_______EOF
2828 #define G_HAVE_GINT64 1          /* deprecated, always true */
2829
2830 ${glib_extension}typedef signed $gint64 gint64;
2831 ${glib_extension}typedef unsigned $gint64 guint64;
2832
2833 #define G_GINT64_CONSTANT(val)  $gint64_constant
2834 #define G_GUINT64_CONSTANT(val) $guint64_constant
2835 _______EOF
2836
2837         if test x$gint64_format != x ; then
2838           cat >>$outfile <<_______EOF
2839 #define G_GINT64_MODIFIER $gint64_modifier
2840 #define G_GINT64_FORMAT $gint64_format
2841 #define G_GUINT64_FORMAT $guint64_format
2842 _______EOF
2843         else
2844           cat >>$outfile <<_______EOF
2845 #undef G_GINT64_MODIFIER
2846 #undef G_GINT64_FORMAT
2847 #undef G_GUINT64_FORMAT
2848 _______EOF
2849         fi
2850
2851         cat >>$outfile <<_______EOF
2852
2853 #define GLIB_SIZEOF_VOID_P $glib_void_p
2854 #define GLIB_SIZEOF_LONG   $glib_long
2855 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2856 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2857
2858 _______EOF
2859
2860         cat >>$outfile <<_______EOF
2861 typedef signed $glib_ssize_type_define gssize;
2862 typedef unsigned $glib_size_type_define gsize;
2863 #define G_GSIZE_MODIFIER $gsize_modifier
2864 #define G_GSSIZE_MODIFIER $gssize_modifier
2865 #define G_GSIZE_FORMAT $gsize_format
2866 #define G_GSSIZE_FORMAT $gssize_format
2867
2868 #define G_MAXSIZE       G_MAXU$glib_msize_type
2869 #define G_MINSSIZE      G_MIN$glib_mssize_type
2870 #define G_MAXSSIZE      G_MAX$glib_mssize_type
2871
2872 typedef gint64 goffset;
2873 #define G_MINOFFSET     G_MININT64
2874 #define G_MAXOFFSET     G_MAXINT64
2875
2876 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2877 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2878 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2879
2880 _______EOF
2881
2882         if test -z "$glib_unknown_void_p"; then
2883           cat >>$outfile <<_______EOF
2884
2885 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2886 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2887
2888 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2889 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2890
2891 typedef signed $glib_intptr_type_define gintptr;
2892 typedef unsigned $glib_intptr_type_define guintptr;
2893
2894 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2895 #define G_GINTPTR_FORMAT        $gintptr_format
2896 #define G_GUINTPTR_FORMAT       $guintptr_format
2897 _______EOF
2898         else
2899           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2900         fi
2901
2902
2903
2904         cat >>$outfile <<_______EOF
2905 #ifndef G_DISABLE_DEPRECATED
2906 #define g_ATEXIT(proc)  (atexit (proc))
2907 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2908 #endif
2909 $glib_defines
2910 $glib_os
2911 $glib_static_compilation
2912
2913 $glib_vacopy
2914
2915 #ifdef  __cplusplus
2916 #define G_HAVE_INLINE   1
2917 #else   /* !__cplusplus */
2918 $glib_inline
2919 #endif  /* !__cplusplus */
2920
2921 #ifdef  __cplusplus
2922 #define G_CAN_INLINE    1
2923 _______EOF
2924
2925         if test x$g_can_inline = xyes ; then
2926                 cat >>$outfile <<_______EOF
2927 #else   /* !__cplusplus */
2928 #define G_CAN_INLINE    1
2929 _______EOF
2930         fi
2931
2932         cat >>$outfile <<_______EOF
2933 #endif
2934
2935 _______EOF
2936
2937         if test x$g_have_iso_c_varargs = xyes ; then
2938                 cat >>$outfile <<_______EOF
2939 #ifndef __cplusplus
2940 # define G_HAVE_ISO_VARARGS 1
2941 #endif
2942 _______EOF
2943         fi
2944         if test x$g_have_iso_cxx_varargs = xyes ; then
2945                 cat >>$outfile <<_______EOF
2946 #ifdef __cplusplus
2947 # define G_HAVE_ISO_VARARGS 1
2948 #endif
2949 _______EOF
2950         fi
2951         if test x$g_have_gnuc_varargs = xyes ; then
2952                 cat >>$outfile <<_______EOF
2953
2954 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2955  * is passed ISO vararg support is turned off, and there is no work
2956  * around to turn it on, so we unconditionally turn it off.
2957  */
2958 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2959 #  undef G_HAVE_ISO_VARARGS
2960 #endif
2961
2962 #define G_HAVE_GNUC_VARARGS 1
2963 _______EOF
2964         fi
2965
2966         case x$g_stack_grows in
2967         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2968         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2969         esac
2970
2971
2972         echo >>$outfile
2973         if test x$g_have_eilseq = xno; then
2974                 cat >>$outfile <<_______EOF
2975 #ifndef EILSEQ
2976 /* On some pre-C99 systems, EILSEQ is not defined.
2977  * The correspondence between this and the corresponding definition
2978  * in libiconv is essential.
2979  */
2980 #  define EILSEQ ENOENT
2981 #endif
2982 _______EOF
2983
2984         fi
2985
2986         if test x$g_have_gnuc_visibility = xyes; then
2987                 cat >>$outfile <<_______EOF
2988 #define G_HAVE_GNUC_VISIBILITY 1
2989 _______EOF
2990         fi
2991                 cat >>$outfile <<_______EOF
2992 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2993 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2994 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2995 #define G_GNUC_INTERNAL __hidden
2996 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2997 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2998 #else
2999 #define G_GNUC_INTERNAL
3000 #endif
3001 _______EOF
3002
3003         echo >>$outfile
3004         cat >>$outfile <<_______EOF
3005 #define G_THREADS_ENABLED
3006 #define G_THREADS_IMPL_$g_threads_impl_def
3007 _______EOF
3008
3009         if test x"$g_memory_barrier_needed" != xno; then
3010           echo >>$outfile
3011           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3012         fi
3013         if test x"$g_atomic_lock_free" = xyes; then
3014           echo >>$outfile
3015           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3016         fi
3017         echo >>$outfile
3018         g_bit_sizes="16 32 64"
3019         for bits in $g_bit_sizes; do
3020           cat >>$outfile <<_______EOF
3021 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3022 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3023 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3024 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3025 _______EOF
3026         done
3027
3028         cat >>$outfile <<_______EOF
3029 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3030 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3031 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3032 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3033 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3034 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3035 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3036 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3037 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3038 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3039 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3040 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3041 #define G_BYTE_ORDER $g_byte_order
3042
3043 #define GLIB_SYSDEF_POLLIN =$g_pollin
3044 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3045 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3046 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3047 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3048 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3049
3050 #define G_MODULE_SUFFIX "$g_module_suffix"
3051
3052 typedef $g_pid_type GPid;
3053
3054 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3055 #define GLIB_SYSDEF_AF_INET $g_af_inet
3056 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3057
3058 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3059 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3060 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3061
3062 G_END_DECLS
3063
3064 #endif /* __GLIBCONFIG_H__ */
3065 _______EOF
3066
3067
3068         if cmp -s $outfile glib/glibconfig.h; then
3069           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3070           rm -f $outfile
3071         else
3072           mv $outfile glib/glibconfig.h
3073         fi
3074 ],[
3075
3076 # Note that if two cases are the same, case goes with the first one.
3077 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3078 # on variable expansion in case labels.  Look at the generated config.status
3079 # for a hint.
3080
3081 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3082   glib_header_alloca_h="$ac_cv_working_alloca_h"
3083 else
3084   glib_header_alloca_h="$ac_cv_header_alloca_h"
3085 fi
3086
3087 if test x$enable_included_printf = xyes ; then
3088   glib_included_printf=yes
3089 fi
3090
3091 case 2 in
3092 $ac_cv_sizeof_short)
3093   gint16=short
3094   gint16_modifier='"h"'
3095   gint16_format='"hi"'
3096   guint16_format='"hu"'
3097   ;;
3098 $ac_cv_sizeof_int)
3099   gint16=int
3100   gint16_modifier='""'
3101   gint16_format='"i"'
3102   guint16_format='"u"'
3103   ;;
3104 esac
3105 case 4 in
3106 $ac_cv_sizeof_short)
3107   gint32=short
3108   gint32_modifier='"h"'
3109   gint32_format='"hi"'
3110   guint32_format='"hu"'
3111   ;;
3112 $ac_cv_sizeof_int)
3113   gint32=int
3114   gint32_modifier='""'
3115   gint32_format='"i"'
3116   guint32_format='"u"'
3117   ;;
3118 $ac_cv_sizeof_long)
3119   gint32=long
3120   gint32_modifier='"l"'
3121   gint32_format='"li"'
3122   guint32_format='"lu"'
3123   ;;
3124 esac
3125 case 8 in
3126 $ac_cv_sizeof_int)
3127   gint64=int
3128   gint64_modifier='""'
3129   gint64_format='"i"'
3130   guint64_format='"u"'
3131   glib_extension=
3132   gint64_constant='(val)'
3133   guint64_constant='(val)'
3134   ;;
3135 $ac_cv_sizeof_long)
3136   gint64=long
3137   gint64_modifier='"l"'
3138   gint64_format='"li"'
3139   guint64_format='"lu"'
3140   glib_extension=
3141   gint64_constant='(val##L)'
3142   guint64_constant='(val##UL)'
3143   ;;
3144 $ac_cv_sizeof_long_long)
3145   gint64='long long'
3146   if test -n "$glib_cv_long_long_format"; then
3147     gint64_modifier='"'$glib_cv_long_long_format'"'
3148     gint64_format='"'$glib_cv_long_long_format'i"'
3149     guint64_format='"'$glib_cv_long_long_format'u"'
3150   fi
3151   glib_extension='G_GNUC_EXTENSION '
3152   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3153   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3154   ;;
3155 $ac_cv_sizeof___int64)
3156   gint64='__int64'
3157   if test -n "$glib_cv_long_long_format"; then
3158     gint64_modifier='"'$glib_cv_long_long_format'"'
3159     gint64_format='"'$glib_cv_long_long_format'i"'
3160     guint64_format='"'$glib_cv_long_long_format'u"'
3161   fi
3162   glib_extension=
3163   gint64_constant='(val##i64)'
3164   guint64_constant='(val##ui64)'
3165   ;;
3166 esac
3167 glib_size_t=$ac_cv_sizeof_size_t
3168 glib_ssize_t=$ac_cv_sizeof_ssize_t
3169 glib_size_type_define="$glib_size_type"
3170 glib_ssize_type_define="$glib_ssize_type"
3171 glib_void_p=$ac_cv_sizeof_void_p
3172 glib_long=$ac_cv_sizeof_long
3173
3174 case "$glib_size_type" in
3175 short)
3176   gsize_modifier='"h"'
3177   gsize_format='"hu"'
3178   glib_msize_type='SHRT'
3179   ;;
3180 int)
3181   gsize_modifier='""'
3182   gsize_format='"u"'
3183   glib_msize_type='INT'
3184   ;;
3185 long)
3186   gsize_modifier='"l"'
3187   gsize_format='"lu"'
3188   glib_msize_type='LONG'
3189   ;;
3190 "long long"|__int64)
3191   gsize_modifier='"I64"'
3192   gsize_format='"I64u"'
3193   glib_msize_type='INT64'
3194   ;;
3195 esac
3196
3197 case "$glib_ssize_type" in
3198 short)
3199   gssize_modifier='"h"'
3200   gssize_format='"hi"'
3201   glib_mssize_type='SHRT'
3202   ;;
3203 int)
3204   gssize_modifier='""'
3205   gssize_format='"i"'
3206   glib_mssize_type='INT'
3207   ;;
3208 long)
3209   gssize_modifier='"l"'
3210   gssize_format='"li"'
3211   glib_mssize_type='LONG'
3212   ;;
3213 "long long"|__int64)
3214   gssize_modifier='"I64"'
3215   gssize_format='"I64i"'
3216   glib_mssize_type='INT64'
3217   ;;
3218 esac
3219
3220 gintbits=`expr $ac_cv_sizeof_int \* 8`
3221 glongbits=`expr $ac_cv_sizeof_long \* 8`
3222 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3223 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3224
3225 case $ac_cv_sizeof_void_p in
3226 $ac_cv_sizeof_int)
3227   glib_intptr_type_define=int
3228   gintptr_modifier='""'
3229   gintptr_format='"i"'
3230   guintptr_format='"u"'
3231   glib_gpi_cast='(gint)'
3232   glib_gpui_cast='(guint)'
3233   ;;
3234 $ac_cv_sizeof_long)
3235   glib_intptr_type_define=long
3236   gintptr_modifier='"l"'
3237   gintptr_format='"li"'
3238   guintptr_format='"lu"'
3239   glib_gpi_cast='(glong)'
3240   glib_gpui_cast='(gulong)'
3241   ;;
3242 $ac_cv_sizeof_long_long)
3243   glib_intptr_type_define='long long'
3244   gintptr_modifier='"I64"'
3245   gintptr_format='"I64i"'
3246   guintptr_format='"I64u"'
3247   glib_gpi_cast='(gint64)'
3248   glib_gpui_cast='(guint64)'
3249   ;;
3250 $ac_cv_sizeof___int64)
3251   glib_intptr_type_define=__int64
3252   gintptr_modifier='"I64"'
3253   gintptr_format='"I64i"'
3254   guintptr_format='"I64u"'
3255   glib_gpi_cast='(gint64)'
3256   glib_gpui_cast='(guint64)'
3257   ;;
3258 *)
3259   glib_unknown_void_p=yes
3260   ;;
3261 esac
3262
3263
3264 glib_defines="
3265 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3266 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3267 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3268 "
3269
3270 case xyes in
3271 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3272 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3273 *)                      glib_vacopy=''
3274 esac
3275
3276 if test x$glib_cv_va_val_copy = xno; then
3277   glib_vacopy="\$glib_vacopy
3278 #define G_VA_COPY_AS_ARRAY 1"
3279 fi
3280
3281 if test x$glib_cv_hasinline = xyes; then
3282     glib_inline='#define G_HAVE_INLINE 1'
3283 fi
3284 if test x$glib_cv_has__inline = xyes; then
3285     glib_inline="\$glib_inline
3286 #define G_HAVE___INLINE 1"
3287 fi
3288 if test x$glib_cv_has__inline__ = xyes; then
3289     glib_inline="\$glib_inline
3290 #define G_HAVE___INLINE__ 1"
3291 fi
3292
3293 g_have_gnuc_varargs=$g_have_gnuc_varargs
3294 g_have_iso_c_varargs=$g_have_iso_c_varargs
3295 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3296
3297 g_can_inline=$g_can_inline
3298 g_have_gnuc_visibility=$g_have_gnuc_visibility
3299 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3300
3301 if test x$ac_cv_c_bigendian = xyes; then
3302   g_byte_order=G_BIG_ENDIAN
3303   g_bs_native=BE
3304   g_bs_alien=LE
3305 else
3306   g_byte_order=G_LITTLE_ENDIAN
3307   g_bs_native=LE
3308   g_bs_alien=BE
3309 fi
3310
3311 g_pollin=$glib_cv_value_POLLIN
3312 g_pollout=$glib_cv_value_POLLOUT
3313 g_pollpri=$glib_cv_value_POLLPRI
3314 g_pollhup=$glib_cv_value_POLLHUP
3315 g_pollerr=$glib_cv_value_POLLERR
3316 g_pollnval=$glib_cv_value_POLLNVAL
3317
3318 # If a family is not found on the system, define that family to
3319 # a negative value, picking a different one for each undefined
3320 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3321 # This is needed because glib-mkenums doesn't handle optional
3322 # values in enums, and thus we have to have all existing values
3323 # defined in the enum.
3324 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3325   g_af_unix=$glib_cv_value_AF_UNIX
3326 else
3327   g_af_unix=-1
3328 fi
3329 g_af_inet=$glib_cv_value_AF_INET
3330 g_af_inet6=$glib_cv_value_AF_INET6
3331
3332 g_msg_peek=$glib_cv_value_MSG_PEEK
3333 g_msg_oob=$glib_cv_value_MSG_OOB
3334 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3335
3336 g_stack_grows=$glib_cv_stack_grows
3337
3338 g_have_eilseq=$have_eilseq
3339
3340 g_threads_impl_def=$g_threads_impl
3341
3342 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3343 g_memory_barrier_needed="$glib_memory_barrier_needed"
3344 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3345
3346 g_module_suffix="$glib_gmodule_suffix"
3347
3348 g_pid_type="$glib_pid_type"
3349 case $host in
3350   *-*-cygwin*)
3351     glib_os="#define G_OS_UNIX
3352 #define G_PLATFORM_WIN32
3353 #define G_WITH_CYGWIN"
3354     ;;
3355   *-*-mingw*)
3356     glib_os="#define G_OS_WIN32
3357 #define G_PLATFORM_WIN32"
3358     ;;
3359   *)
3360     glib_os="#define G_OS_UNIX"
3361     ;;
3362 esac
3363 glib_static_compilation=""
3364 if test x$glib_win32_static_compilation = xyes; then
3365   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3366 #define GOBJECT_STATIC_COMPILATION 1"
3367 fi
3368 ])
3369
3370 # Redo enough to get guint32 and guint64 for the alignment checks below
3371 case 4 in
3372 $ac_cv_sizeof_short)
3373   gint32=short
3374   ;;
3375 $ac_cv_sizeof_int)
3376   gint32=int
3377   ;;
3378 $ac_cv_sizeof_long)
3379   gint32=long
3380   ;;
3381 esac
3382 case 8 in
3383 $ac_cv_sizeof_int)
3384   gint64=int
3385   ;;
3386 $ac_cv_sizeof_long)
3387   gint64=long
3388   ;;
3389 $ac_cv_sizeof_long_long)
3390   gint64='long long'
3391   ;;
3392 $ac_cv_sizeof___int64)
3393   gint64='__int64'
3394   ;;
3395 esac
3396
3397 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3398 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3399 typedef unsigned $gint32 guint32;])
3400 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3401 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3402 typedef unsigned $gint64 guint64;])
3403 AC_CHECK_TYPE([unsigned long])
3404 AC_CHECK_ALIGNOF([unsigned long])
3405
3406 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3407 #
3408 # 1.2.14 required for dbus_message_set_serial
3409 PKG_CHECK_MODULES(DBUS1,
3410      dbus-1 >= 1.2.14,
3411      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3412      have_dbus1=no)
3413 AC_SUBST(DBUS1_CFLAGS)
3414 AC_SUBST(DBUS1_LIBS)
3415 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3416
3417 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3418 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3419
3420 dnl
3421 dnl Check for -Bsymbolic-functions linker flag used to avoid
3422 dnl intra-library PLT jumps, if available.
3423 dnl
3424
3425 AC_ARG_ENABLE(Bsymbolic,
3426               [AS_HELP_STRING([--disable-Bsymbolic],
3427                               [avoid linking with -Bsymbolic])],,
3428               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3429                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3430                LDFLAGS=-Wl,-Bsymbolic-functions
3431                LIBS=
3432                AC_TRY_LINK([], [return 0],
3433                            AC_MSG_RESULT(yes)
3434                            enable_Bsymbolic=yes,
3435                            AC_MSG_RESULT(no)
3436                            enable_Bsymbolic=no)
3437                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3438
3439 if test "x${enable_Bsymbolic}" = "xyes"; then
3440   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3441 fi
3442
3443 AC_SUBST(GLIB_LINK_FLAGS)
3444
3445 dnl
3446 dnl Check for -z,nodelete linker flag: the type system assumes that
3447 dnl libgobject stays loaded for the lifetime of the process.
3448 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3449 dnl we also try to check for the --fatal-warnings linker flag if
3450 dnl auto-detecting.
3451 dnl
3452
3453 AC_ARG_ENABLE([znodelete],
3454               [AS_HELP_STRING([--disable-znodelete],
3455                               [avoid linking with -z,nodelete])],,
3456               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3457                AC_MSG_CHECKING([for --fatal-warnings linker flag])
3458                LDFLAGS=-Wl,--fatal-warnings
3459                LIBS=
3460                AC_TRY_LINK([], [return 0],
3461                            AC_MSG_RESULT(yes)
3462                            [ldflags_fatal=-Wl,--fatal-warnings],
3463                            AC_MSG_RESULT(no)
3464                            ldflags_fatal=)
3465                AC_MSG_CHECKING([for -z,nodelete linker flag])
3466                LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3467                AC_TRY_LINK([], [return 0],
3468                            AC_MSG_RESULT(yes)
3469                            enable_znodelete=yes,
3470                            AC_MSG_RESULT(no)
3471                            enable_znodelete=no)
3472                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3473
3474 if test "x${enable_znodelete}" = "xyes"; then
3475   GOBJECT_LINK_FLAGS=-Wl,-z,nodelete
3476 fi
3477
3478 AC_SUBST(GOBJECT_LINK_FLAGS)
3479
3480 dnl
3481 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3482 dnl visibility attributes for symbol export control
3483 dnl
3484 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3485 case "$host" in
3486   *-*-mingw*)
3487     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3488     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3489               [defines how to decorate public symbols while building])
3490     CFLAGS="${CFLAGS} -fvisibility=hidden"
3491     ;;
3492   *)
3493     dnl on other compilers, check if we can do -fvisibility=hidden
3494     SAVED_CFLAGS="${CFLAGS}"
3495     CFLAGS="-fvisibility=hidden"
3496     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3497     AC_TRY_COMPILE([], [return 0],
3498                    AC_MSG_RESULT(yes)
3499                    enable_fvisibility_hidden=yes,
3500                    AC_MSG_RESULT(no)
3501                    enable_fvisibility_hidden=no)
3502     CFLAGS="${SAVED_CFLAGS}"
3503
3504     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3505       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3506                 [defines how to decorate public symbols while building])
3507       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3508     ])
3509     ;;
3510 esac
3511 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3512
3513 dnl Compiler flags; macro originates from systemd
3514 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3515 AC_ARG_ENABLE(compile-warnings,
3516               [AS_HELP_STRING([--disable-compile-warnings],
3517                               [Don't use builtin compiler warnings])],,
3518                               enable_compile_warnings=yes)
3519 AS_IF([test "x$enable_compile_warnings" = xyes], [
3520   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3521    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3522    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3523    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3524    -Werror=format=2 -Werror=missing-include-dirs])
3525 ])
3526 AC_SUBST(GLIB_WARN_CFLAGS)
3527
3528 #
3529 # Define variables corresponding to the correct include paths to use for
3530 # in-tree building.
3531 #
3532
3533 # for config.h:
3534 config_h_INCLUDES='-I$(top_builddir)'
3535 AC_SUBST(config_h_INCLUDES)
3536
3537 # glib:
3538 #   config.h
3539 #   $(top_builddir)/glib: for glibconfig.h
3540 #   $(top_srcdir)/glib:   for glib.h
3541 #   $(top_srcdir):        for everything
3542 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3543 AC_SUBST(glib_INCLUDES)
3544
3545 # gobject:
3546 #   same as glib
3547 gobject_INCLUDES='$(glib_INCLUDES)'
3548 AC_SUBST(gobject_INCLUDES)
3549
3550 # gmodule:
3551 #   glib includes
3552 #   $(top_srcdir)/gmodule: for gmodule.h
3553 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3554 AC_SUBST(gmodule_INCLUDES)
3555
3556 # gio:
3557 #   same as gmodule
3558 gio_INCLUDES='$(gmodule_INCLUDES)'
3559 AC_SUBST(gio_INCLUDES)
3560
3561
3562 AC_CONFIG_FILES([
3563 glib-2.0.pc
3564 gmodule-2.0.pc
3565 gmodule-export-2.0.pc
3566 gmodule-no-export-2.0.pc
3567 gthread-2.0.pc
3568 gobject-2.0.pc
3569 gio-2.0.pc
3570 gio-unix-2.0.pc
3571 gio-windows-2.0.pc
3572 glib-zip
3573 glib-gettextize
3574 Makefile
3575 build/Makefile
3576 build/win32/Makefile
3577 build/win32/dirent/Makefile
3578 build/win32/vs9/Makefile
3579 build/win32/vs10/Makefile
3580 build/win32/vs11/Makefile
3581 build/win32/vs12/Makefile
3582 glib/Makefile
3583 glib/glib.stp
3584 glib/libcharset/Makefile
3585 glib/gnulib/Makefile
3586 glib/pcre/Makefile
3587 glib/update-pcre/Makefile
3588 glib/tests/Makefile
3589 gmodule/Makefile
3590 gmodule/gmoduleconf.h
3591 gobject/Makefile
3592 gobject/gobject.stp
3593 gobject/glib-mkenums
3594 gobject/tests/Makefile
3595 gthread/Makefile
3596 gio/Makefile
3597 gio/gdbus-2.0/codegen/Makefile
3598 gio/gdbus-2.0/codegen/config.py
3599 gio/gnetworking.h
3600 gio/xdgmime/Makefile
3601 gio/inotify/Makefile
3602 gio/kqueue/Makefile
3603 gio/fam/Makefile
3604 gio/win32/Makefile
3605 gio/tests/Makefile
3606 gio/tests/gdbus-object-manager-example/Makefile
3607 gio/tests/services/Makefile
3608 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3609 gio/tests/modules/Makefile
3610 po/Makefile.in
3611 docs/Makefile
3612 docs/reference/Makefile
3613 docs/reference/glib/Makefile
3614 docs/reference/glib/version.xml
3615 docs/reference/gobject/Makefile
3616 docs/reference/gobject/version.xml
3617 docs/reference/gio/Makefile
3618 docs/reference/gio/gdbus-object-manager-example/Makefile
3619 docs/reference/gio/version.xml
3620 tests/Makefile
3621 tests/gobject/Makefile
3622 tests/refcount/Makefile
3623 m4macros/Makefile
3624 ])
3625
3626 AC_CONFIG_COMMANDS([chmod-scripts],
3627 [chmod 0755 glib-zip
3628 chmod 0755 glib-gettextize
3629 chmod 0755 gobject/glib-mkenums])
3630
3631 # we want to invoke this macro solely so that the config.status script
3632 # and automake generated makefiles know about these generated files.
3633 # They are only needed to distcheck the package
3634 if false; then
3635   AC_CONFIG_FILES([
3636     INSTALL
3637     README
3638     config.h.win32
3639     glib/glibconfig.h.win32
3640     glib/makefile.msc
3641     glib/glib.rc
3642     gmodule/makefile.msc
3643     gmodule/gmodule.rc
3644     gobject/makefile.msc
3645     gobject/gobject.rc
3646     gthread/makefile.msc
3647     gthread/gthread.rc
3648     gio/gio.rc
3649     tests/makefile.msc
3650   ])
3651 fi
3652
3653 AC_OUTPUT