configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.63)
   4
   5 AC_INIT([libffi], [3.0.10rc0], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AC_CANONICAL_SYSTEM
   9 target_alias=${target_alias-$host_alias}
  10
  11 . ${srcdir}/configure.host
  12
  13 AM_INIT_AUTOMAKE
  14
  15 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  16 # We must force CC to /not/ be precious variables; otherwise
  17 # the wrong, non-multilib-adjusted value will be used in multilibs.
  18 # As a side effect, we have to subst CFLAGS ourselves.
  19 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
  20 # defaults of its own if none are provided.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 save_CFLAGS=$CFLAGS
  25 AC_PROG_CC
  26 CFLAGS=$save_CFLAGS
  27 m4_undefine([_AC_ARG_VAR_PRECIOUS])
  28 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  29
  30 AC_SUBST(CFLAGS)
  31
  32 AM_PROG_AS
  33 AM_PROG_CC_C_O
  34 AC_PROG_LIBTOOL
  35 AC_CONFIG_MACRO_DIR([m4])
  36
  37 AM_MAINTAINER_MODE
  38
  39 AC_CHECK_HEADERS(sys/mman.h)
  40 AC_CHECK_FUNCS(mmap)
  41 AC_FUNC_MMAP_BLACKLIST
  42
  43 dnl The -no-testsuite modules omit the test subdir.
  44 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  45
  46 TARGETDIR="unknown"
  47 case "$host" in
  48   alpha*-*-*)
  49         TARGET=ALPHA; TARGETDIR=alpha;
  50         # Support 128-bit long double, changeable via command-line switch.
  51         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  52         ;;
  53
  54   arm*-*-*)
  55         TARGET=ARM; TARGETDIR=arm
  56         ;;
  57
  58   amd64-*-freebsd* | amd64-*-openbsd*)
  59         TARGET=X86_64; TARGETDIR=x86
  60         ;;
  61
  62   amd64-*-freebsd*)
  63         TARGET=X86_64; TARGETDIR=x86
  64         ;;
  65
  66   avr32*-*-*)
  67         TARGET=AVR32; TARGETDIR=avr32
  68         ;;
  69
  70   cris-*-*)
  71         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  72         ;;
  73
  74   frv-*-*)
  75         TARGET=FRV; TARGETDIR=frv
  76         ;;
  77
  78   hppa*-*-linux* | parisc*-*-linux*)
  79         TARGET=PA_LINUX; TARGETDIR=pa
  80         ;;
  81   hppa*64-*-hpux*)
  82         TARGET=PA64_HPUX; TARGETDIR=pa
  83         ;;
  84   hppa*-*-hpux*)
  85         TARGET=PA_HPUX; TARGETDIR=pa
  86         ;;
  87
  88   i?86-*-freebsd* | i?86-*-openbsd*)
  89         TARGET=X86_FREEBSD; TARGETDIR=x86
  90         ;;
  91   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2*)
  92         TARGET=X86_WIN32; TARGETDIR=x86
  93         # All mingw/cygwin/win32 builds require this for sharedlib
  94         AM_LTLDFLAGS="-no-undefined"
  95         ;;
  96   i?86-*-darwin*)
  97         TARGET=X86_DARWIN; TARGETDIR=x86
  98         ;;
  99   i?86-*-solaris2.1[[0-9]]*)
 100         TARGET=X86_64; TARGETDIR=x86
 101         ;;
 102   i?86-*-*)
 103         TARGET=X86; TARGETDIR=x86
 104         ;;
 105
 106   ia64*-*-*)
 107         TARGET=IA64; TARGETDIR=ia64
 108         ;;
 109
 110   m32r*-*-*)
 111         TARGET=M32R; TARGETDIR=m32r
 112         ;;
 113
 114   m68k-*-*)
 115         TARGET=M68K; TARGETDIR=m68k
 116         ;;
 117
 118   mips-sgi-irix5.* | mips-sgi-irix6.*)
 119         TARGET=MIPS; TARGETDIR=mips
 120         ;;
 121   mips*-*-linux*)
 122         # Support 128-bit long double for NewABI.
 123         HAVE_LONG_DOUBLE='defined(__mips64)'
 124         TARGET=MIPS; TARGETDIR=mips
 125         ;;
 126
 127   moxie-*-*)
 128         TARGET=MOXIE; TARGETDIR=moxie
 129         ;;
 130
 131   powerpc*-*-linux* | powerpc-*-sysv*)
 132         TARGET=POWERPC; TARGETDIR=powerpc
 133         ;;
 134   powerpc-*-beos*)
 135         TARGET=POWERPC; TARGETDIR=powerpc
 136         ;;
 137   powerpc-*-darwin*)
 138         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 139         ;;
 140   powerpc-*-aix* | rs6000-*-aix*)
 141         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 142         ;;
 143   powerpc-*-freebsd*)
 144         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 145         ;;
 146   powerpc*-*-rtems*)
 147         TARGET=POWERPC; TARGETDIR=powerpc
 148         ;;
 149
 150   s390-*-* | s390x-*-*)
 151         TARGET=S390; TARGETDIR=s390
 152         ;;
 153
 154   sh-*-* | sh[[34]]*-*-*)
 155         TARGET=SH; TARGETDIR=sh
 156         ;;
 157   sh64-*-* | sh5*-*-*)
 158         TARGET=SH64; TARGETDIR=sh64
 159         ;;
 160
 161   sparc*-*-*)
 162         TARGET=SPARC; TARGETDIR=sparc
 163         ;;
 164
 165   x86_64-*-darwin*)
 166         TARGET=X86_DARWIN; TARGETDIR=x86
 167         ;;
 168
 169   x86_64-*-cygwin* | x86_64-*-mingw*)
 170         TARGET=X86_WIN64; TARGETDIR=x86
 171         ;;
 172
 173   x86_64-*-*)
 174         TARGET=X86_64; TARGETDIR=x86
 175         ;;
 176 esac
 177
 178 AC_SUBST(AM_RUNTESTFLAGS)
 179 AC_SUBST(AM_LTLDFLAGS)
 180
 181 if test $TARGETDIR = unknown; then
 182   AC_MSG_ERROR(["libffi has not been ported to $host."])
 183 fi
 184
 185 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 186 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 187 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 188 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 189 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 190 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
 191 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 192 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 193 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 194 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 195 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 196 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
 197 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 198 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 199 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 200 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 201 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 202 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
 203 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 204 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 205 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 206 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 207 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 208 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 209 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 210 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 211 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 212
 213 AC_HEADER_STDC
 214 AC_CHECK_FUNCS(memcpy)
 215 AC_FUNC_ALLOCA
 216
 217 AC_CHECK_SIZEOF(double)
 218 AC_CHECK_SIZEOF(long double)
 219
 220 # Also AC_SUBST this variable for ffi.h.
 221 if test -z "$HAVE_LONG_DOUBLE"; then
 222   HAVE_LONG_DOUBLE=0
 223   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 224     if test $ac_cv_sizeof_long_double != 0; then
 225       HAVE_LONG_DOUBLE=1
 226       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 227     fi
 228   fi
 229 fi
 230 AC_SUBST(HAVE_LONG_DOUBLE)
 231
 232 AC_C_BIGENDIAN
 233
 234 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 235     libffi_cv_as_cfi_pseudo_op, [
 236     libffi_cv_as_cfi_pseudo_op=unknown
 237     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 238                    [libffi_cv_as_cfi_pseudo_op=yes],
 239                    [libffi_cv_as_cfi_pseudo_op=no])
 240 ])
 241 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 242     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 243               [Define if your assembler supports .cfi_* directives.])
 244 fi
 245
 246 if test x$TARGET = xSPARC; then
 247     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 248         libffi_cv_as_sparc_ua_pcrel, [
 249         save_CFLAGS="$CFLAGS"
 250         save_LDFLAGS="$LDFLAGS"
 251         CFLAGS="$CFLAGS -fpic"
 252         LDFLAGS="$LDFLAGS -shared"
 253         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 254                     [libffi_cv_as_sparc_ua_pcrel=yes],
 255                     [libffi_cv_as_sparc_ua_pcrel=no])
 256         CFLAGS="$save_CFLAGS"
 257         LDFLAGS="$save_LDFLAGS"])
 258     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 259         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 260                   [Define if your assembler and linker support unaligned PC relative relocs.])
 261     fi
 262
 263     AC_CACHE_CHECK([assembler .register pseudo-op support],
 264        libffi_cv_as_register_pseudo_op, [
 265        libffi_cv_as_register_pseudo_op=unknown
 266        # Check if we have .register
 267        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 268                        [libffi_cv_as_register_pseudo_op=yes],
 269                        [libffi_cv_as_register_pseudo_op=no])
 270     ])
 271     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 272        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 273                [Define if your assembler supports .register.])
 274     fi
 275 fi
 276
 277 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
 278     AC_CACHE_CHECK([assembler supports pc related relocs],
 279         libffi_cv_as_x86_pcrel, [
 280         libffi_cv_as_x86_pcrel=yes
 281         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 282         if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 283             libffi_cv_as_x86_pcrel=no
 284         fi
 285         ])
 286     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 287         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 288                   [Define if your assembler supports PC relative relocs.])
 289     fi
 290
 291     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
 292        libffi_cv_as_ascii_pseudo_op, [
 293        libffi_cv_as_ascii_pseudo_op=unknown
 294        # Check if we have .ascii
 295        AC_TRY_COMPILE([asm (".ascii \"string\"");],,
 296                        [libffi_cv_as_ascii_pseudo_op=yes],
 297                        [libffi_cv_as_ascii_pseudo_op=no])
 298     ])
 299     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
 300        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
 301                [Define if your assembler supports .ascii.])
 302     fi
 303
 304     AC_CACHE_CHECK([assembler .string pseudo-op support],
 305        libffi_cv_as_string_pseudo_op, [
 306        libffi_cv_as_string_pseudo_op=unknown
 307        # Check if we have .string
 308        AC_TRY_COMPILE([asm (".string \"string\"");],,
 309                        [libffi_cv_as_string_pseudo_op=yes],
 310                        [libffi_cv_as_string_pseudo_op=no])
 311     ])
 312     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
 313        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
 314                [Define if your assembler supports .string.])
 315     fi
 316 fi
 317
 318 case "$target" in
 319      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
 320        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
 321                  [Cannot use malloc on this target, so, we revert to
 322                    alternative means])
 323      ;;
 324 esac
 325
 326 if test x$TARGET = xX86_64; then
 327     AC_CACHE_CHECK([assembler supports unwind section type],
 328         libffi_cv_as_x86_64_unwind_section_type, [
 329         libffi_cv_as_x86_64_unwind_section_type=yes
 330         echo '.section .eh_frame,"a",@unwind' > conftest.s
 331         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 332             libffi_cv_as_x86_64_unwind_section_type=no
 333         fi
 334         ])
 335     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
 336         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 337                   [Define if your assembler supports unwind section type.])
 338     fi
 339 fi
 340
 341 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 342     libffi_cv_ro_eh_frame, [
 343         libffi_cv_ro_eh_frame=no
 344         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 345         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 346             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 347                 libffi_cv_ro_eh_frame=yes
 348             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 349                  | grep -v '#write' > /dev/null; then
 350                 libffi_cv_ro_eh_frame=yes
 351             fi
 352         fi
 353         rm -f conftest.*
 354     ])
 355 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 356     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 357               [Define if .eh_frame sections should be read-only.])
 358     AC_DEFINE(EH_FRAME_FLAGS, "a",
 359               [Define to the flags needed for the .section .eh_frame directive.])
 360 else
 361     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 362               [Define to the flags needed for the .section .eh_frame directive.])
 363 fi
 364
 365 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 366     libffi_cv_hidden_visibility_attribute, [
 367         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 368         libffi_cv_hidden_visibility_attribute=no
 369         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 370             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 371                 libffi_cv_hidden_visibility_attribute=yes
 372             fi
 373         fi
 374         rm -f conftest.*
 375     ])
 376 if test $libffi_cv_hidden_visibility_attribute = yes; then
 377     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 378               [Define if __attribute__((visibility("hidden"))) is supported.])
 379 fi
 380
 381 AH_BOTTOM([
 382 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 383 #ifdef LIBFFI_ASM
 384 #define FFI_HIDDEN(name) .hidden name
 385 #else
 386 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 387 #endif
 388 #else
 389 #ifdef LIBFFI_ASM
 390 #define FFI_HIDDEN(name)
 391 #else
 392 #define FFI_HIDDEN
 393 #endif
 394 #endif
 395 ])
 396
 397 AC_SUBST(TARGET)
 398 AC_SUBST(TARGETDIR)
 399
 400 AC_SUBST(SHELL)
 401
 402 AC_ARG_ENABLE(debug,
 403 [  --enable-debug          debugging mode],
 404   if test "$enable_debug" = "yes"; then
 405     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 406   fi)
 407 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
 408
 409 AC_ARG_ENABLE(structs,
 410 [  --disable-structs       omit code for struct support],
 411   if test "$enable_structs" = "no"; then
 412     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 413   fi)
 414
 415 AC_ARG_ENABLE(raw-api,
 416 [  --disable-raw-api       make the raw api unavailable],
 417   if test "$enable_raw_api" = "no"; then
 418     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 419   fi)
 420
 421 AC_ARG_ENABLE(purify-safety,
 422 [  --enable-purify-safety  purify-safe mode],
 423   if test "$enable_purify_safety" = "yes"; then
 424     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 425   fi)
 426
 427 if test -n "$with_cross_host" &&
 428    test x"$with_cross_host" != x"no"; then
 429   toolexecdir='$(exec_prefix)/$(target_alias)'
 430   toolexeclibdir='$(toolexecdir)/lib'
 431 else
 432   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 433   toolexeclibdir='$(libdir)'
 434 fi
 435 multi_os_directory=`$CC -print-multi-os-directory`
 436 case $multi_os_directory in
 437   .) ;; # Avoid trailing /.
 438   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 439 esac
 440 AC_SUBST(toolexecdir)
 441 AC_SUBST(toolexeclibdir)
 442
 443 if test "${multilib}" = "yes"; then
 444   multilib_arg="--enable-multilib"
 445 else
 446   multilib_arg=
 447 fi
 448
 449 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 450 AC_CONFIG_COMMANDS(src, [
 451 test -d src || mkdir src
 452 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 453 ], [TARGETDIR="$TARGETDIR"])
 454
 455 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 456
 457 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
 458
 459 AC_OUTPUT