configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([gssdp],
   3         [0.14.6],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=gupnp&component=gssdp],
   5         [gssdp],
   6         [http://www.gupnp.org/])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_SRCDIR(libgssdp/gssdp-client.c)
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_CONFIG_AUX_DIR([build-aux])
  12
  13 AC_CANONICAL_HOST
  14 AC_CANONICAL_TARGET
  15
  16 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-xz])
  17 AM_MAINTAINER_MODE([enable])
  18
  19 GNOME_COMPILE_WARNINGS
  20
  21 AM_SILENT_RULES([yes])
  22
  23 AC_SEARCH_LIBS([strerror],[cposix])
  24 AC_PROG_CC
  25 AC_HEADER_STDC
  26
  27 LT_PREREQ([2.2])
  28 LT_INIT
  29
  30 PKG_CHECK_MODULES(LIBGSSDP, glib-2.0 >= 2.32 \
  31                             gobject-2.0 >= 2.32 \
  32                             gio-2.0 >= 2.32 \
  33                             libsoup-2.4 >= 2.26.1)
  34
  35 LIBGTK_REQUIRED=3.0
  36
  37 AC_ARG_WITH( gtk,
  38   AS_HELP_STRING([--without-gtk],[compile without gtk+ support]),
  39   try_gtk=$withval, try_gtk=yes )
  40
  41 HAVE_LIBGTK=no
  42 if test x$try_gtk = xyes ; then
  43     dnl check for gtk+
  44     PKG_CHECK_MODULES(LIBGTK, gtk+-3.0 >= $LIBGTK_REQUIRED ,
  45       [
  46         HAVE_LIBGTK=yes
  47         AC_SUBST(LIBGTK_CFLAGS)
  48         AC_SUBST(LIBGTK_LIBS)
  49       ],
  50       [
  51         HAVE_LIBGTK=no
  52         AC_MSG_WARN([gtk+ $LIBGTK_REQUIRED or greater not found, some tools will not build.])
  53       ])
  54 else
  55     AC_MSG_NOTICE([gtk+ usage disabled, some tools may not build.])
  56 fi
  57
  58 if test x$HAVE_LIBGTK = xno; then
  59   USE_LIBGTK=no
  60 else
  61   USE_LIBGTK=yes
  62   AC_DEFINE(HAVE_LIBGTK, , [Use gtk+])
  63 fi
  64
  65 AC_SUBST(HAVE_LIBGTK)
  66 AM_CONDITIONAL(USE_LIBGTK, test x$USE_LIBGTK = xyes)
  67
  68 # glib-genmarshal
  69 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
  70 AC_SUBST(GLIB_GENMARSHAL)
  71
  72 # Debugging
  73 AC_ARG_ENABLE(debug,
  74         [  --enable-debug          enable debugging],,
  75         enable_debug=no)
  76 if test "x$enable_debug" = "xyes"; then
  77         CFLAGS="$CFLAGS -g -Wall"
  78 fi
  79
  80 AC_ARG_ENABLE([strict-c],
  81               AS_HELP_STRING([--enable-strict-c],[Error out on warnings]),,
  82               [enable_strict_c=no])
  83 AS_IF([test "x$[]enable_strict_c" = "xyes"],
  84       [CFLAGS="$CFLAGS -Werror"])
  85
  86 GOBJECT_INTROSPECTION_CHECK([0.6.7])
  87
  88 # vapigen
  89 have_vapigen=no
  90 AS_IF([test "x$found_introspection" = "xyes"],
  91       [
  92        dnl output of g-i >= 1.36.0 needs vapigen >= 0.20 to process
  93        AC_MSG_CHECKING([whether G-I is 1.36 or newer])
  94        VAPIGEN_MIN_VERSION=0.14
  95        AS_IF([pkg-config --atleast-version=1.36.0 gobject-introspection-1.0],
  96              [
  97               AC_MSG_RESULT([yes])
  98               VAPIGEN_MIN_VERSION=0.20
  99              ],[AC_MSG_RESULT([no])]
 100        )
 101        GUPNP_PROG_VAPIGEN([$VAPIGEN_MIN_VERSION])
 102       ]
 103 )
 104 AS_IF([test "x$VAPIGEN" != "x"], [have_vapigen=yes])
 105 AM_CONDITIONAL([HAVE_VAPIGEN], [test "x$VAPIGEN" != "x"])
 106
 107 dnl Check for Win32
 108 AC_MSG_CHECKING([for Win32])
 109 case "$host" in
 110     *-*-mingw*)
 111         os_win32=yes
 112         ;;
 113     *)
 114         os_win32=no
 115         ;;
 116 esac
 117 AC_MSG_RESULT([$os_win32])
 118 AM_CONDITIONAL(OS_WIN32, [test $os_win32 = yes])
 119
 120 dnl Check for Android
 121 AC_MSG_CHECKING([for Android as target OS])
 122 target_android=no
 123 case "$target_os" in
 124     linux-android*)
 125         target_android=yes
 126         ;;
 127     *)
 128         target_android=no
 129         ;;
 130 esac
 131 AC_MSG_RESULT([$target_android])
 132 AM_CONDITIONAL(TARGET_ANDROID, [test $target_android = yes])
 133
 134 GTK_DOC_CHECK([1.14], [--flavour no-tmpl])
 135
 136 AC_CONFIG_FILES([
 137 Makefile
 138 libgssdp/Makefile
 139 tools/Makefile
 140 tests/Makefile
 141 tests/gtest/Makefile
 142 vala/Makefile
 143 doc/Makefile
 144 doc/version.xml
 145 gssdp-1.0.pc
 146 gssdp-1.0-uninstalled.pc
 147 ])
 148 AC_OUTPUT
 149
 150 echo "
 151     ${PACKAGE} ${VERSION}
 152     ---------------------
 153
 154     Prefix:                ${prefix}
 155     GObject-Introspection: ${found_introspection}
 156     VALA bindings:         ${have_vapigen}
 157 "