configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [6])
   6 m4_define([dbus_micro_version], [5])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22 # By default, rebuild autotools files on demand; only use ./missing if the
  23 # user says --disable-maintainer-mode (some distributions like to do this)
  24 AM_MAINTAINER_MODE([enable])
  25
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  29
  30 # libtool versioning - this applies to libdbus
  31 #
  32 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  33 #
  34
  35 ## increment if the interface has additions, changes, removals.
  36 LT_CURRENT=10
  37
  38 ## increment any time the source changes; set to
  39 ##  0 if you increment CURRENT
  40 LT_REVISION=2
  41
  42 ## increment if any interfaces have been added; set to 0
  43 ## if any interfaces have been changed or removed. removal has
  44 ## precedence over adding, so set to 0 if both happened.
  45 LT_AGE=7
  46
  47 AC_SUBST(LT_CURRENT)
  48 AC_SUBST(LT_REVISION)
  49 AC_SUBST(LT_AGE)
  50
  51 DBUS_MAJOR_VERSION=dbus_major_version
  52 DBUS_MINOR_VERSION=dbus_minor_version
  53 DBUS_MICRO_VERSION=dbus_micro_version
  54 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  55
  56 AC_SUBST(DBUS_MAJOR_VERSION)
  57 AC_SUBST(DBUS_MINOR_VERSION)
  58 AC_SUBST(DBUS_MICRO_VERSION)
  59 AC_SUBST(DBUS_VERSION)
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_CXX
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_ISC_POSIX
  66 AC_HEADER_STDC
  67 AC_C_INLINE
  68 AM_PROG_LIBTOOL
  69 AC_PROG_MKDIR_P
  70 COMPILER_COVERAGE
  71 COMPILER_OPTIMISATIONS
  72 PKG_PROG_PKG_CONFIG
  73
  74 # Initialize libtool
  75 LT_INIT([win32-dll])
  76 LT_LANG([Windows Resource])
  77
  78 # Set some internal variables depending on the platform for later use.
  79 dbus_win=no
  80 dbus_cygwin=no
  81 dbus_unix=no
  82 case "${host}" in
  83     *-mingw32ce*)
  84         dbus_win=yes
  85         dbus_wince=yes
  86         ;;
  87     *-mingw32*)
  88         dbus_win=yes
  89         ;;
  90     *-cygwin*)
  91         dbus_cygwin=yes
  92         dbus_unix=yes
  93         ;;
  94     *)
  95         dbus_unix=yes
  96        ;;
  97 esac
  98
  99 # Special defines for certain platforms
 100 if test "$dbus_win" = yes; then
 101     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 102     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 103     AC_SUBST(BUILD_TIMESTAMP)
 104     # Assume DBUS_VERSION is always three numbers
 105     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 106     AC_SUBST(BUILD_FILEVERSION)
 107     AC_CHECK_TOOL(WINDRES, windres, no)
 108     if test "$WINDRES" = no; then
 109       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 110     fi
 111     if test "$dbus_wince" = yes; then
 112       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 113       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 114     fi
 115 else
 116     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 117 fi
 118 if test "$dbus_cygwin" = yes; then
 119     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 120 fi
 121
 122 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 123 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 124 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 125 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 126
 127 # this must come first: other options use this to set their defaults
 128 AC_ARG_ENABLE([developer],
 129   [AS_HELP_STRING([--enable-developer],
 130     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
 131   [],
 132   [enable_developer=no])
 133
 134 DBUS_STATIC_BUILD_CPPFLAGS=
 135 if test "x$enable_shared" = xno; then
 136     # On Windows, linking against the static library requires special effort
 137     # to turn off DLL import/export processing. We normally link some things
 138     # against the dynamic library, but if we're not building that, we'll
 139     # have to link everything statically.
 140     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 141 fi
 142 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 143
 144 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 145 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 146 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 147 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 148 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 149 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 150 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 151 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 152 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 153 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 154 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 155 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 156 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 157 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 158 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 159 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 160
 161 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 162 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 163 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 164 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 165 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 166 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 167 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 168 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 169 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 170 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 171 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 172 AC_ARG_WITH(dbus_session_bus_default_address, AS_HELP_STRING([--with-dbus-session-bus-default-address=[nonce-tcp:/autolaunch:/tcp:host:port]],[Transport Type to be used (default: nonce-tcp:)]),with_dbus_session_bus_default_address=$withval,with_dbus_session_bus_default_address=nonce-tcp:)
 173
 174 AC_ARG_ENABLE([embedded-tests],
 175   AS_HELP_STRING([--enable-embedded-tests],
 176     [enable unit test code in the library and binaries]),
 177   [], [enable_embedded_tests=$enable_developer])
 178 AC_ARG_ENABLE([modular-tests],
 179   AS_HELP_STRING([--enable-modular-tests],
 180     [enable modular regression tests (requires GLib)]),
 181   [], [enable_modular_tests=auto])
 182 # --enable-tests overrides both --enable-embedded-tests and
 183 # --enable-modular-tests
 184 AC_ARG_ENABLE([tests],
 185   AS_HELP_STRING([--enable-tests],
 186     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 187   [
 188   if test "x$enableval" = xyes; then
 189     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 190     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 191   fi
 192   enable_embedded_tests=$enableval
 193   enable_modular_tests=$enableval
 194   ],
 195   [])
 196
 197 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 198 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 199 # name for this.
 200 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 201 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 202   [test "x$enable_embedded_tests" = xyes])
 203 if test "x$enable_embedded_tests" = xyes; then
 204     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 205       [Define to build test code into the library and binaries])
 206     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 207       [Define to build test code into the library and binaries])
 208 fi
 209
 210 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 211 # These use GTest, from GLib, because life's too short. They're enabled by
 212 # default (unless you don't have GLib), because they don't bloat the library
 213 # or binaries.
 214
 215 with_glib=yes
 216
 217 if test "x$enable_modular_tests" != xno; then
 218   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 219     [],
 220     [if test "x$enable_modular_tests" = xyes; then
 221       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 222       AC_MSG_ERROR([$GLIB_ERRORS])
 223     else # assumed to be "auto"
 224       with_glib=no
 225     fi])
 226   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 227   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 228     [],
 229     [if test "x$enable_modular_tests" = xyes; then
 230       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 231       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 232     else # assumed to be "auto"
 233       with_glib=no
 234     fi])
 235 fi
 236 if test "x$enable_modular_tests" != xno; then
 237   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 238     [Define to build independent test binaries])
 239 fi
 240 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 241   [test "x$enable_modular_tests" != xno])
 242
 243 if test "x$with_glib" != xno; then
 244   AC_DEFINE([DBUS_WITH_GLIB], [1],
 245     [Define if GLib, GObject, GIO are available])
 246 fi
 247 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 248
 249 AC_ARG_ENABLE([installed-tests],
 250   AS_HELP_STRING([--enable-installed-tests],
 251     [enable unit test code in the library and binaries]),
 252   [], [enable_installed_tests=no])
 253 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 254   [test "x$enable_installed_tests" = xyes])
 255
 256 if test "x$enable_tests" = xyes; then
 257   # full test coverage is required, Python is a hard dependency
 258   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 259   AM_PATH_PYTHON([2.6])
 260   AC_MSG_CHECKING([for Python modules for full test coverage])
 261   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 262     AC_MSG_RESULT([yes])
 263   else
 264     AC_MSG_RESULT([no])
 265     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 266   fi
 267 else
 268   # --enable-tests not given: do not abort if Python is missing
 269   AM_PATH_PYTHON([2.6], [], [:])
 270 fi
 271
 272 if test x$enable_verbose_mode = xyes; then
 273     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 274 fi
 275
 276 if test x$enable_asserts = xno; then
 277     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 278     DISABLE_UNUSED_WARNINGS="unused-label"
 279     R_DYNAMIC_LDFLAG=""
 280 else
 281     # -rdynamic is needed for glibc's backtrace_symbols to work.
 282     # No clue how much overhead this adds, but it's useful
 283     # to do this on any assertion failure,
 284     # so for now it's enabled anytime asserts are (currently not
 285     # in production builds).
 286
 287     # To get -rdynamic you pass -export-dynamic to libtool.
 288     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 289     R_DYNAMIC_LDFLAG=-export-dynamic
 290 fi
 291 AC_SUBST(R_DYNAMIC_LDFLAG)
 292
 293 if test x$enable_checks = xno; then
 294     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 295     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 296     DISABLE_UNUSED_WARNINGS="unused-label"
 297 fi
 298
 299 if test x$enable_userdb_cache = xyes; then
 300     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 301 fi
 302
 303 if test x$enable_compiler_coverage = xyes; then
 304      ## so that config.h changes when you toggle gcov support
 305      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 306 fi
 307
 308 # glibc21.m4 serial 3
 309 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 310 dnl This file is free software; the Free Software Foundation
 311 dnl gives unlimited permission to copy and/or distribute it,
 312 dnl with or without modifications, as long as this notice is preserved.
 313
 314 # Test for the GNU C Library, version 2.1 or newer.
 315 # From Bruno Haible.
 316
 317 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 318   ac_cv_gnu_library_2_1,
 319   [AC_EGREP_CPP([Lucky GNU user],
 320     [
 321 #include <features.h>
 322 #ifdef __GNU_LIBRARY__
 323  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 324   Lucky GNU user
 325  #endif
 326 #endif
 327     ],
 328     ac_cv_gnu_library_2_1=yes,
 329     ac_cv_gnu_library_2_1=no)
 330   ]
 331 )
 332
 333 #### Integer sizes
 334
 335 AC_CHECK_SIZEOF(char)
 336 AC_CHECK_SIZEOF(short)
 337 AC_CHECK_SIZEOF(long)
 338 AC_CHECK_SIZEOF(int)
 339 AC_CHECK_SIZEOF(void *)
 340 AC_CHECK_SIZEOF(long long)
 341 AC_CHECK_SIZEOF(__int64)
 342
 343 AC_ARG_WITH([64-bit],
 344   [AS_HELP_STRING([--without-64-bit],
 345     [If you have to use this option, please report it as a bug])],
 346   [],
 347   [with_64_bit=yes])
 348
 349 ### See what our 64 bit type is called
 350 AC_MSG_CHECKING([64-bit integer type])
 351
 352 case 8 in
 353 $ac_cv_sizeof_int)
 354   dbusint64=int
 355   dbusint64_constant='(val)'
 356   dbusuint64_constant='(val)'
 357   dbusint64_printf_modifier='""'
 358   ;;
 359 $ac_cv_sizeof_long)
 360   dbusint64=long
 361   dbusint64_constant='(val##L)'
 362   dbusuint64_constant='(val##UL)'
 363   dbusint64_printf_modifier='"l"'
 364   ;;
 365 $ac_cv_sizeof_long_long)
 366   dbusint64='long long'
 367   dbusint64_constant='(val##LL)'
 368   dbusuint64_constant='(val##ULL)'
 369   # Ideally we discover what the format is, but this is
 370   # only used in verbose mode, so eh...
 371   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 372     dbusint64_printf_modifier='"ll"'
 373   fi
 374   ;;
 375 $ac_cv_sizeof___int64)
 376   dbusint64=__int64
 377   dbusint64_constant='(val##i64)'
 378   dbusuint64_constant='(val##ui64)'
 379   # See above case
 380   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 381     dbusint64_printf_modifier='"ll"'
 382   fi
 383   ;;
 384 esac
 385
 386 AS_IF(
 387   [test "x$with_64_bit" = xno],
 388   [
 389         DBUS_INT64_TYPE="no_int64_type_detected"
 390         DBUS_HAVE_INT64=0
 391         DBUS_INT64_CONSTANT=
 392         DBUS_UINT64_CONSTANT=
 393         AC_MSG_RESULT([disabled via --without-64-bit])
 394   ],
 395   dnl else if
 396   [test -z "$dbusint64"],
 397   [AC_MSG_RESULT([not found])
 398   AC_MSG_ERROR([Could not find a 64-bit integer type.
 399
 400 Please report a bug here with details of your platform and compiler:
 401
 402     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 403
 404 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 405 the option "--without-64-bit".
 406
 407 This option is likely to be removed in future, unless you report that your
 408 platform needs it.])
 409   ],
 410   dnl else
 411   [
 412         DBUS_INT64_TYPE="$dbusint64"
 413         DBUS_HAVE_INT64=1
 414         DBUS_INT64_CONSTANT="$dbusint64_constant"
 415         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 416         if test x"$dbusint64_printf_modifier" != x; then
 417                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 418         fi
 419         AC_MSG_RESULT($DBUS_INT64_TYPE)
 420   ])
 421
 422 AC_SUBST(DBUS_INT64_TYPE)
 423 AC_SUBST(DBUS_INT64_CONSTANT)
 424 AC_SUBST(DBUS_UINT64_CONSTANT)
 425 AC_SUBST(DBUS_HAVE_INT64)
 426
 427 ### see what 32-bit int is called
 428 AC_MSG_CHECKING([32-bit integer type])
 429
 430 case 4 in
 431 $ac_cv_sizeof_short)
 432   dbusint32=short
 433   ;;
 434 $ac_cv_sizeof_int)
 435   dbusint32=int
 436   ;;
 437 $ac_cv_sizeof_long)
 438   dbusint32=long
 439   ;;
 440 esac
 441
 442 if test -z "$dbusint32" ; then
 443         DBUS_INT32_TYPE="no_int32_type_detected"
 444         AC_MSG_ERROR([No 32-bit integer type found])
 445 else
 446         DBUS_INT32_TYPE="$dbusint32"
 447         AC_MSG_RESULT($DBUS_INT32_TYPE)
 448 fi
 449
 450 AC_SUBST(DBUS_INT32_TYPE)
 451
 452 ### see what 16-bit int is called
 453 AC_MSG_CHECKING([16-bit integer type])
 454
 455 case 2 in
 456 $ac_cv_sizeof_short)
 457   dbusint16=short
 458   ;;
 459 $ac_cv_sizeof_int)
 460   dbusint16=int
 461   ;;
 462 esac
 463
 464 if test -z "$dbusint16" ; then
 465         DBUS_INT16_TYPE="no_int16_type_detected"
 466         AC_MSG_ERROR([No 16-bit integer type found])
 467 else
 468         DBUS_INT16_TYPE="$dbusint16"
 469         AC_MSG_RESULT($DBUS_INT16_TYPE)
 470 fi
 471
 472 AC_SUBST(DBUS_INT16_TYPE)
 473
 474 ## byte order
 475 case $host_os in
 476         darwin*)
 477                 # check at compile-time, so that it is possible to build universal
 478                 # (with multiple architectures at once on the compile line)
 479                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 480                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 481                         #if defined(__BIG_ENDIAN__)
 482                         #define WORDS_BIGENDIAN 1
 483                         #endif
 484                 ])
 485                 ;;
 486         *)
 487                 AC_C_BIGENDIAN
 488                 ;;
 489 esac
 490
 491 dnl **********************************
 492 dnl *** va_copy checks (from GLib) ***
 493 dnl **********************************
 494 dnl we currently check for all three va_copy possibilities, so we get
 495 dnl all results in config.log for bug reports.
 496 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 497         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 498 #include <stdlib.h>
 499         static void f (int i, ...) {
 500         va_list args1, args2;
 501         va_start (args1, i);
 502         va_copy (args2, args1);
 503         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 504           exit (1);
 505         va_end (args1); va_end (args2);
 506         }
 507         int main() {
 508           f (0, 42);
 509           return 0;
 510         }])],
 511         [dbus_cv_va_copy=yes],
 512         [dbus_cv_va_copy=no])
 513 ])
 514 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 515         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 516 #include <stdlib.h>
 517         static void f (int i, ...) {
 518         va_list args1, args2;
 519         va_start (args1, i);
 520         __va_copy (args2, args1);
 521         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 522           exit (1);
 523         va_end (args1); va_end (args2);
 524         }
 525         int main() {
 526           f (0, 42);
 527           return 0;
 528         }])],
 529         [dbus_cv___va_copy=yes],
 530         [dbus_cv___va_copy=no])
 531 ])
 532
 533 if test "x$dbus_cv_va_copy" = "xyes"; then
 534   dbus_va_copy_func=va_copy
 535 else if test "x$dbus_cv___va_copy" = "xyes"; then
 536   dbus_va_copy_func=__va_copy
 537 fi
 538 fi
 539
 540 if test -n "$dbus_va_copy_func"; then
 541   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 542 fi
 543
 544 AC_LANG_PUSH(C)
 545 AC_CACHE_CHECK([whether va_lists can be copied by value],
 546         dbus_cv_va_val_copy,
 547         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 548 [[
 549         #include <stdarg.h>
 550         #include <stdlib.h>
 551 ]],
 552 [[
 553         static void f (int i, ...) {
 554         va_list args1, args2;
 555         va_start (args1, i);
 556         args2 = args1;
 557         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 558           exit (1);
 559         va_end (args1); va_end (args2);
 560         }
 561         int main() {
 562           f (0, 42);
 563           return 0;
 564         }
 565 ]])],
 566         [dbus_cv_va_val_copy=yes],
 567         [dbus_cv_va_val_copy=no],
 568         [dbus_cv_va_val_copy=yes])
 569 ])
 570 AC_LANG_POP(C)
 571
 572 if test "x$dbus_cv_va_val_copy" = "xno"; then
 573   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 574 fi
 575
 576
 577 #### Atomic integers
 578
 579 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 580   dbus_cv_sync_sub_and_fetch,
 581   [AC_LINK_IFELSE([
 582      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 583      [dbus_cv_sync_sub_and_fetch=yes],
 584      [dbus_cv_sync_sub_and_fetch=no])
 585   ])
 586
 587 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 588    have_sync=1
 589 else
 590    have_sync=0
 591 fi
 592
 593 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 594
 595 #### Various functions
 596 AC_SEARCH_LIBS(socket,[socket network])
 597 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 598
 599 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull)
 600
 601 AC_CHECK_HEADERS([syslog.h])
 602 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 603   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 604 fi
 605
 606 #### Check for broken poll; taken from Glib's configure
 607
 608 AC_MSG_CHECKING([for broken poll])
 609 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 610     #include <stdlib.h>
 611     #include <fcntl.h>
 612     #include <poll.h>
 613     #ifdef HAVE_SYS_POLL_H
 614     #include <sys/poll.h>
 615     #endif
 616     int main(void) {
 617       struct pollfd fds[1];
 618       int fd;
 619       fd = open("/dev/null", 1);
 620       fds[0].fd = fd;
 621       fds[0].events = POLLIN;
 622       fds[0].revents = 0;
 623       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 624             exit(1);  /* Does not work for devices -- fail */
 625       }
 626       exit(0);
 627     }]])],
 628   [broken_poll=no],
 629   [broken_poll=yes
 630    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 631   [broken_poll="no (cross compiling)"])
 632 AC_MSG_RESULT($broken_poll)
 633
 634 AC_MSG_CHECKING(for dirfd)
 635 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 636 #include <sys/types.h>
 637 #include <dirent.h>
 638 ]], [[
 639 DIR *dirp;
 640 dirp = opendir(".");
 641 dirfd(dirp);
 642 closedir(dirp);
 643 ]])],
 644 [dbus_have_dirfd=yes],
 645 [dbus_have_dirfd=no])
 646 AC_MSG_RESULT($dbus_have_dirfd)
 647 if test "$dbus_have_dirfd" = yes; then
 648         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 649 else
 650         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 651         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 652 #include <sys/types.h>
 653 #include <dirent.h>
 654         ]], [[
 655 DIR *dirp;
 656 int fd;
 657 dirp = opendir(".");
 658 fd = dirp->dd_fd;
 659 closedir(dirp);
 660         ]])],
 661         [dbus_have_ddfd=yes],
 662         [dbus_have_ddfd=no])
 663         AC_MSG_RESULT($dbus_have_ddfd)
 664         if test "$dbus_have_ddfd" = yes; then
 665                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 666         fi
 667 fi
 668
 669 AC_CHECK_HEADERS(sys/resource.h)
 670
 671 AC_CHECK_HEADERS(dirent.h)
 672
 673 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 674
 675 AC_CHECK_HEADERS(errno.h)
 676
 677 AC_CHECK_HEADERS(signal.h)
 678
 679 AC_CHECK_HEADERS(locale.h)
 680
 681 AC_CHECK_HEADERS(byteswap.h)
 682
 683 AC_CHECK_HEADERS(unistd.h)
 684
 685 AC_CHECK_HEADERS(ws2tcpip.h)
 686
 687 AC_CHECK_HEADERS(wspiapi.h)
 688
 689 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 690 #
 691 case $host_os in
 692     solaris*)
 693        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 694 esac
 695
 696 # checking for a posix version of getpwnam_r
 697 # if we are cross compiling and can not run the test
 698 # assume getpwnam_r is the posix version
 699 # it is up to the person cross compiling to change
 700 # this behavior if desired
 701 AC_LANG_PUSH(C)
 702 AC_CACHE_CHECK([for posix getpwnam_r],
 703                 ac_cv_func_posix_getpwnam_r,
 704                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 705 [[
 706 #include <errno.h>
 707 #include <pwd.h>
 708 ]],
 709 [[
 710     char buffer[10000];
 711     struct passwd pwd, *pwptr = &pwd;
 712     int error;
 713     errno = 0;
 714     error = getpwnam_r ("", &pwd, buffer,
 715                         sizeof (buffer), &pwptr);
 716    return (error < 0 && errno == ENOSYS)
 717            || error == ENOSYS;
 718 ]])],
 719         [ac_cv_func_posix_getpwnam_r=yes],
 720         [ac_cv_func_posix_getpwnam_r=no],
 721         [ac_cv_func_posix_getpwnam_r=yes]
 722 )])
 723 AC_LANG_POP(C)
 724
 725 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 726         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 727                 [Have POSIX function getpwnam_r])
 728 else
 729         AC_CACHE_CHECK([for nonposix getpwnam_r],
 730                 ac_cv_func_nonposix_getpwnam_r,
 731                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 732                         struct passwd pwd;
 733                         getpwnam_r ("", &pwd, buffer,
 734                                         sizeof (buffer));]])],
 735                         [ac_cv_func_nonposix_getpwnam_r=yes],
 736                         [ac_cv_func_nonposix_getpwnam_r=no])])
 737                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 738                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 739                         [Have non-POSIX function getpwnam_r])
 740         fi
 741 fi
 742
 743 dnl check for socklen_t
 744 AC_MSG_CHECKING(whether socklen_t is defined)
 745 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 746 #include <sys/types.h>
 747 #include <sys/socket.h>
 748 #include <netdb.h>
 749 ]], [[
 750 socklen_t foo;
 751 foo = 1;
 752 ]])],
 753 [dbus_have_socklen_t=yes],
 754 [dbus_have_socklen_t=no])
 755 AC_MSG_RESULT($dbus_have_socklen_t)
 756
 757 if test "x$dbus_have_socklen_t" = "xyes"; then
 758     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 759 fi
 760
 761 dnl check for writev header and writev function so we're
 762 dnl good to go if HAVE_WRITEV gets defined.
 763 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 764
 765 dnl needed on darwin for NAME_MAX
 766 AC_CHECK_HEADERS(sys/syslimits.h)
 767
 768 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 769 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/socket.h> ]])
 770
 771 dnl check for flavours of varargs macros (test from GLib)
 772 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 773 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 774 int a(int p1, int p2, int p3);
 775 #define call_a(...) a(1,__VA_ARGS__)
 776 call_a(2,3);
 777 ]])],
 778 [dbus_have_iso_c_varargs=yes],
 779 [dbus_have_iso_c_varargs=no])
 780 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 781
 782 AC_MSG_CHECKING(for GNUC varargs macros)
 783 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 784 int a(int p1, int p2, int p3);
 785 #define call_a(params...) a(1,params)
 786 call_a(2,3);
 787 ]])],
 788 [dbus_have_gnuc_varargs=yes],
 789 [dbus_have_gnuc_varargs=no])
 790 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 791
 792 dnl Output varargs tests
 793 if test x$dbus_have_iso_c_varargs = xyes; then
 794     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 795 fi
 796 if test x$dbus_have_gnuc_varargs = xyes; then
 797     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 798 fi
 799
 800 dnl Check for various credentials.
 801 AC_MSG_CHECKING(for struct cmsgcred)
 802 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 803 #include <sys/types.h>
 804 #include <sys/socket.h>
 805 ]], [[
 806 struct cmsgcred cred;
 807
 808 cred.cmcred_pid = 0;
 809 ]])],
 810 [dbus_have_struct_cmsgcred=yes],
 811 [dbus_have_struct_cmsgcred=no])
 812 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 813
 814 if test x$dbus_have_struct_cmsgcred = xyes; then
 815     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 816 fi
 817
 818 AC_CHECK_FUNCS(getpeerucred getpeereid)
 819
 820 AC_CHECK_FUNCS(pipe2 accept4)
 821
 822 #### Abstract sockets
 823
 824 if test x$enable_abstract_sockets = xauto; then
 825 AC_LANG_PUSH(C)
 826 warn_on_xcompile=no
 827 AC_CACHE_CHECK([abstract socket namespace],
 828                 ac_cv_have_abstract_sockets,
 829                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 830 [[
 831 #include <sys/types.h>
 832 #include <stdlib.h>
 833 #include <string.h>
 834 #include <stdio.h>
 835 #include <sys/socket.h>
 836 #include <sys/un.h>
 837 #include <errno.h>
 838 ]],
 839 [[
 840   size_t slen;
 841   int listen_fd;
 842   struct sockaddr_un addr;
 843
 844   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 845
 846   if (listen_fd < 0)
 847     {
 848       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 849       exit (1);
 850     }
 851
 852   memset (&addr, '\0', sizeof (addr));
 853   addr.sun_family = AF_UNIX;
 854   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 855   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 856    * beginning.
 857    */
 858   slen = SUN_LEN(&addr);
 859   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 860
 861   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 862     {
 863        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 864                 strerror (errno));
 865        exit (1);
 866     }
 867   else
 868     exit (0);
 869 ]])],
 870               [ac_cv_have_abstract_sockets=yes],
 871               [ac_cv_have_abstract_sockets=no],
 872               [
 873                 ac_cv_have_abstract_sockets=no
 874                 warn_on_xcompile=yes
 875               ]
 876 )])
 877 if test x$warn_on_xcompile = xyes ; then
 878   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 879 fi
 880 AC_LANG_POP(C)
 881 fi
 882
 883 if test x$enable_abstract_sockets = xyes; then
 884     if test x$ac_cv_have_abstract_sockets = xno; then
 885         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 886     fi
 887 fi
 888
 889 if test x$enable_abstract_sockets = xno; then
 890    ac_cv_have_abstract_sockets=no;
 891 fi
 892
 893 if test x$ac_cv_have_abstract_sockets = xyes ; then
 894    DBUS_PATH_OR_ABSTRACT=abstract
 895    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 896 else
 897    DBUS_PATH_OR_ABSTRACT=path
 898 fi
 899
 900 # this is used in addresses to prefer abstract, e.g.
 901 # unix:path=/foo or unix:abstract=/foo
 902 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 903
 904 PKG_PROG_PKG_CONFIG
 905
 906 #### Sort out XML library
 907
 908 # see what we have
 909 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 910              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 911              have_expat=false)
 912
 913 # see what we want to use
 914 dbus_use_libxml=false
 915 dbus_use_expat=false
 916 if test x$with_xml = xexpat; then
 917         if ! $have_expat ; then
 918            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 919         fi
 920         dbus_use_expat=true
 921 elif test x$with_xml = xlibxml; then
 922         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 923         if ! $have_libxml ; then
 924            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 925         fi
 926         dbus_use_libxml=true
 927 else
 928         ### expat is the default because libxml can't currently survive
 929         ### our brutal OOM-handling unit test setup.
 930         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 931         if test x$have_expat = xfalse; then
 932                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 933         fi
 934         ### By default, only use Expat since it's tested and known to work.  If you're a
 935         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 936         ### if your OS is built around libxml, that's another case.
 937         dbus_use_expat=true
 938 fi
 939
 940 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 941 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 942
 943 if $dbus_use_expat; then
 944    XML_LIBS=-lexpat
 945    XML_CFLAGS=
 946 fi
 947 if $dbus_use_libxml; then
 948    XML_LIBS=$LIBXML_LIBS
 949    XML_CFLAGS=$LIBXML_CFLAGS
 950 fi
 951 AC_SUBST([XML_CFLAGS])
 952 AC_SUBST([XML_LIBS])
 953
 954 # Thread lib detection
 955 AC_CHECK_FUNC(pthread_cond_timedwait,[AC_CHECK_LIB(pthread,pthread_cond_timedwait,
 956                                                     [THREAD_LIBS="-lpthread"])])
 957 save_libs="$LIBS"
 958 LIBS="$LIBS $THREAD_LIBS"
 959 AC_CHECK_FUNC(pthread_condattr_setclock,have_pthread_condattr_setclock=true,have_pthread_condattr_setclock=false)
 960 if test x$have_pthread_condattr_setclock = xtrue; then
 961     AC_SEARCH_LIBS([clock_getres],[rt],[THREAD_LIBS="$THREAD_LIBS -lrt"])
 962     AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 963     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>
 964 #include <pthread.h>
 965 ]], [[
 966 struct timespec monotonic_timer;
 967 pthread_condattr_t attr;
 968 pthread_condattr_init (&attr);
 969 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 970 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 971 ]])],
 972 [have_clock_monotonic=true],
 973 [have_clock_monotonic=false])
 974 if test x$have_clock_monotonic = xtrue; then
 975     AC_MSG_RESULT([found])
 976     AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 977 else
 978     AC_MSG_RESULT([not found])
 979 fi
 980 fi
 981 LIBS="$save_libs"
 982
 983 AC_SUBST([THREAD_LIBS])
 984
 985 # SELinux detection
 986 if test x$enable_selinux = xno ; then
 987     have_selinux=no;
 988 else
 989     # See if we have SELinux library
 990     AC_CHECK_LIB(selinux, is_selinux_enabled,
 991                  have_selinux=yes, have_selinux=no)
 992
 993     # see if we have the SELinux header with the new D-Bus stuff in it
 994     if test x$have_selinux = xyes ; then
 995         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 996         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
 997                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
 998                             #else
 999                             #error DBUS__ACQUIRE_SVC not defined
1000                             #endif]])],
1001                           [have_selinux=yes],
1002                           [have_selinux=no])
1003         AC_MSG_RESULT($have_selinux)
1004     fi
1005
1006     if test x$enable_selinux = xauto ; then
1007         if test x$have_selinux = xno ; then
1008                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1009         fi
1010     else
1011         if test x$have_selinux = xno ; then
1012                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1013         fi
1014     fi
1015 fi
1016
1017 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1018
1019 if test x$have_selinux = xyes ; then
1020     # the selinux code creates threads
1021     # which requires libpthread even on linux
1022     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1023                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1024
1025     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1026     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1027 else
1028     SELINUX_LIBS=
1029 fi
1030
1031 # inotify checks
1032 if test x$enable_inotify = xno ; then
1033     have_inotify=no;
1034 else
1035     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1036 fi
1037
1038 dnl check if inotify backend is enabled
1039 if test x$have_inotify = xyes; then
1040    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1041    AC_CHECK_FUNCS(inotify_init1)
1042 fi
1043
1044 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1045
1046 # dnotify checks
1047 if test x$enable_dnotify = xno ; then
1048     have_dnotify=no;
1049 else
1050     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
1051         have_dnotify=yes;
1052     else
1053         have_dnotify=no;
1054     fi
1055 fi
1056
1057 dnl check if dnotify backend is enabled
1058 if test x$have_dnotify = xyes; then
1059    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
1060 fi
1061
1062 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
1063
1064 # For simplicity, we require the userland API for epoll_create1 at
1065 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1066 # not to have it at runtime.
1067 AC_ARG_ENABLE([epoll],
1068               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1069               [enable_epoll=$enableval], [enable_epoll=auto])
1070 if test x$enable_epoll = xno; then
1071     have_linux_epoll=no
1072 else
1073     AC_MSG_CHECKING([for Linux epoll(4)])
1074     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1075         [
1076         #ifndef __linux__
1077         #error This is not Linux
1078         #endif
1079         #include <sys/epoll.h>
1080         ],
1081         [epoll_create1 (EPOLL_CLOEXEC);])],
1082         [have_linux_epoll=yes],
1083         [have_linux_epoll=no])
1084     AC_MSG_RESULT([$have_linux_epoll])
1085 fi
1086 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1087     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1088 fi
1089 if test x$have_linux_epoll = xyes; then
1090   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1091 fi
1092 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1093
1094 # kqueue checks
1095 if test x$enable_kqueue = xno ; then
1096     have_kqueue=no
1097 else
1098     have_kqueue=yes
1099     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1100     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1101
1102     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1103         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1104     fi
1105 fi
1106
1107 dnl check if kqueue backend is enabled
1108 if test x$have_kqueue = xyes; then
1109    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1110 fi
1111
1112 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1113
1114 # launchd checks
1115 if test x$enable_launchd = xno ; then
1116     have_launchd=no
1117 else
1118     have_launchd=yes
1119     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1120     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1121     if test "x$LAUNCHCTL" = "x"; then
1122         have_launchd=no
1123     fi
1124
1125     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1126         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1127     fi
1128 fi
1129
1130 dnl check if launchd is enabled
1131 if test x$have_launchd = xyes; then
1132     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1133 fi
1134
1135 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1136
1137 #### Directory to place launchd agent file
1138 if test "x$with_launchd_agent_dir" = "x"; then
1139    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1140 else
1141    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1142 fi
1143
1144 AC_SUBST(LAUNCHD_AGENT_DIR)
1145
1146 dnl console owner file
1147 if test x$enable_console_owner_file = xno ; then
1148     have_console_owner_file=no;
1149 else
1150     case $host_os in
1151     solaris*)
1152         have_console_owner_file=yes;
1153         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1154         ;;
1155     *)
1156         have_console_owner_file=no;;
1157     esac
1158 fi
1159
1160 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1161
1162 dnl systemd detection
1163 if test x$enable_systemd = xno ; then
1164     have_systemd=no;
1165 else
1166     PKG_CHECK_MODULES(SYSTEMD,
1167         [libsystemd-login >= 32, libsystemd-daemon >= 32],
1168         have_systemd=yes,
1169         have_systemd=no)
1170 fi
1171
1172 if test x$have_systemd = xyes; then
1173     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1174 fi
1175
1176 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1177     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1178 fi
1179
1180 # libaudit detection
1181 if test x$enable_libaudit = xno ; then
1182     have_libaudit=no;
1183 else
1184     # See if we have audit daemon & capabilities library
1185     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1186                  have_libaudit=yes, have_libaudit=no)
1187     if test x$have_libaudit = xyes ; then
1188         AC_CHECK_LIB(cap-ng, capng_clear,
1189                  have_libaudit=yes, have_libaudit=no)
1190     fi
1191 fi
1192
1193 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1194
1195 if test x$have_libaudit = xyes ; then
1196     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1197     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1198 fi
1199
1200 AC_SUBST([SELINUX_LIBS])
1201
1202 # Check for ADT API (Solaris Basic Security Mode auditing)
1203 AC_MSG_CHECKING(for ADT API)
1204 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1205 #include <bsm/adt.h>
1206 adt_user_context = ADT_USER;
1207 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1208
1209 if test ${check_adt_audit} = yes
1210 then
1211    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1212    ADT_LIBS="-lbsm"
1213    LIBS="-lbsm $LIBS"
1214    AC_MSG_RESULT(yes)
1215 else
1216    AC_MSG_RESULT(no)
1217 fi
1218 AC_SUBST([ADT_LIBS])
1219
1220 # Check for SCM_RIGHTS
1221 AC_MSG_CHECKING([for SCM_RIGHTS])
1222 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1223 #include <sys/socket.h>
1224 #include <sys/un.h>
1225 static int x = SCM_RIGHTS;
1226 ]], [[]])],
1227 [ AC_MSG_RESULT([supported])
1228   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1229 [ AC_MSG_RESULT([not supported]) ])
1230
1231 NETWORK_libs=
1232 if test x$dbus_win = xyes ; then
1233   if test x$dbus_wince = xyes ; then
1234     NETWORK_libs="-lws2"
1235   else
1236     NETWORK_libs="-lws2_32"
1237   fi
1238 fi
1239
1240 AC_SUBST([NETWORK_libs])
1241
1242 AC_ARG_WITH([valgrind],
1243   [AS_HELP_STRING([--with-valgrind],
1244      [Add instrumentation to help valgrind to understand our allocator])],
1245   [],
1246   [with_valgrind=no])
1247
1248 if test x$with_valgrind != xno; then
1249   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1250   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1251 fi
1252
1253 #### Set up final flags
1254 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1255 AC_SUBST([LIBDBUS_LIBS])
1256
1257 ### X11 detection
1258 DBUS_X_LIBS=
1259 DBUS_X_CFLAGS=
1260
1261 AC_ARG_ENABLE([x11-autolaunch],
1262   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1263   [], [enable_x11_autolaunch=auto])
1264
1265 if test "x$dbus_win" = xyes; then
1266     if test "x$enable_x11_autolaunch" = xyes; then
1267         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1268     fi
1269
1270     enable_x11_autolaunch=no
1271     have_x11=no
1272 else
1273     AC_PATH_XTRA
1274
1275     if test "x$no_x" = xyes; then
1276         have_x11=no
1277     else
1278         have_x11=yes
1279         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1280         DBUS_X_CFLAGS="$X_CFLAGS"
1281     fi
1282 fi
1283
1284 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1285     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1286 else
1287     # move from "auto" to "yes" or "no" if necessary
1288     if test "x$enable_x11_autolaunch" != xno; then
1289         enable_x11_autolaunch="$have_x11"
1290     fi
1291 fi
1292
1293 if test "x$have_x11" = xyes ; then
1294    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1295 fi
1296
1297 if test "x$enable_x11_autolaunch" = xyes ; then
1298    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1299 fi
1300
1301 AC_SUBST([DBUS_X_CFLAGS])
1302 AC_SUBST([DBUS_X_LIBS])
1303
1304 #### gcc warning flags
1305
1306 cc_supports_flag() {
1307   AC_MSG_CHECKING(whether $CC supports "$*")
1308   save_CFLAGS="$CFLAGS"
1309   CFLAGS="$*"
1310   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1311   CFLAGS="$save_CFLAGS"
1312   AC_MSG_RESULT([$rc])
1313   test "x$rc" = xyes
1314 }
1315
1316 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1317   dnl Use -Werror by default if:
1318   dnl - we're not on Windows (too many warnings), and
1319   dnl - we're in developer mode (a D-Bus developer, not a distro or end-user)
1320   dnl Override with --enable-Werror or --disable-Werror
1321   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$enable_developer = xyes],
1322
1323   dnl Enable these warnings if possible:
1324   [all \
1325    extra \
1326    char-subscripts \
1327    missing-declarations \
1328    missing-prototypes \
1329    nested-externs \
1330    pointer-arith \
1331    cast-align \
1332    no-address \
1333    float-equal \
1334    declaration-after-statement \
1335   ],
1336
1337   dnl Disable these warnings if possible, make them non-fatal if possible,
1338   dnl and don't enable -Werror unless we succeeded.
1339   dnl
1340   dnl Intentional:
1341   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1342   dnl   checking or not asserting
1343   dnl - missing field initializers being 0 is a C feature, not a bug
1344   dnl - unused-parameter is to make writing callbacks less annoying
1345   dnl
1346   dnl To be fixed one day:
1347   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1348   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1349   dnl   is better than nothing
1350   [$DISABLE_UNUSED_WARNINGS \
1351    missing-field-initializers \
1352    unused-parameter \
1353    sign-compare \
1354    pointer-sign \
1355    type-limits \
1356   ])
1357
1358 if test "x$GCC" = "xyes"; then
1359   # We're treating -fno-common like a warning: it makes the linker more
1360   # strict, because on some systems the linker is *always* this strict
1361   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1362
1363   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1364   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1365
1366   if test "x$enable_ansi" = "xyes"; then
1367     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1368       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1369   fi
1370 fi
1371
1372 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1373 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1374 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1375 dnl is the next best thing
1376 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1377
1378 case $host_os in
1379     solaris*)
1380         # Solaris' C library apparently needs these runes to be threadsafe...
1381         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1382         # ... and this opt-in to get file descriptor passing support
1383         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1384         ;;
1385 esac
1386
1387 ### Doxygen Documentation
1388
1389 AC_PATH_PROG(DOXYGEN, doxygen, no)
1390
1391 AC_MSG_CHECKING([whether to build Doxygen documentation])
1392
1393 if test x$DOXYGEN = xno ; then
1394     have_doxygen=no
1395 else
1396     have_doxygen=yes
1397 fi
1398
1399 if test x$enable_doxygen_docs = xauto ; then
1400     if test x$have_doxygen = xno ; then
1401         enable_doxygen_docs=no
1402     else
1403         enable_doxygen_docs=yes
1404     fi
1405 fi
1406
1407 if test x$enable_doxygen_docs = xyes; then
1408     if test x$have_doxygen = xno; then
1409         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1410     fi
1411 fi
1412
1413 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1414 AC_MSG_RESULT($enable_doxygen_docs)
1415
1416 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1417 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1418
1419 ### XML Documentation
1420
1421 AC_PATH_PROG(XMLTO, xmlto, no)
1422
1423 AC_MSG_CHECKING([whether to build XML documentation])
1424
1425 if test x$XMLTO = xno ; then
1426     have_xmlto=no
1427 else
1428     have_xmlto=yes
1429 fi
1430
1431 if test x$enable_xml_docs = xauto ; then
1432     if test x$have_xmlto = xno ; then
1433         enable_xml_docs=no
1434     else
1435         enable_xml_docs=yes
1436     fi
1437 fi
1438
1439 if test x$enable_xml_docs = xyes; then
1440     if test x$have_xmlto = xno; then
1441         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1442     fi
1443 fi
1444
1445 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1446 AC_MSG_RESULT($enable_xml_docs)
1447
1448 AC_PATH_PROG([MAN2HTML], [man2html])
1449 AC_ARG_VAR([MAN2HTML], [Path to man2html (optional)])
1450 AM_CONDITIONAL(DBUS_HAVE_MAN2HTML, test x$MAN2HTML != x)
1451
1452 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1453     test x$enable_doxygen_docs = xyes -a x$enable_xml_docs = xyes -a \
1454          x$MAN2HTML != x)
1455
1456 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1457
1458 #### find the actual value for $prefix that we'll end up with
1459 ##   (I know this is broken and should be done in the Makefile, but
1460 ##    that's a major pain and almost nobody actually seems to care)
1461 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1462 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1463 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1464 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1465 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1466 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1467 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1468
1469 #### Check our operating system
1470 operating_system=unknown
1471 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1472    operating_system=redhat
1473 fi
1474
1475 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1476    operating_system=slackware
1477 fi
1478
1479 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1480    operating_system=cygwin
1481 fi
1482
1483 #### Sort out init scripts
1484
1485 if test x$with_init_scripts = x; then
1486     case x$operating_system in
1487         xredhat)        with_init_scripts=redhat ;;
1488         xslackware)     with_init_scripts=slackware ;;
1489         xcygwin)        with_init_scripts=cygwin ;;
1490         *)                      with_init_scripts=none ;;
1491     esac
1492 fi
1493
1494 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1495 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1496 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1497
1498 ##### systemd unit files
1499 AC_ARG_WITH([systemdsystemunitdir],
1500 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1501     [],
1502     [
1503     PKG_CHECK_EXISTS([systemd],
1504       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1505       [with_systemdsystemunitdir=no])
1506     ])
1507 if test "x$with_systemdsystemunitdir" != xno; then
1508    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1509 fi
1510 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1511
1512 ##### Set up location for system bus socket
1513 if ! test -z "$with_system_socket"; then
1514    DBUS_SYSTEM_SOCKET=$with_system_socket
1515 else
1516    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1517 fi
1518
1519 AC_SUBST(DBUS_SYSTEM_SOCKET)
1520 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1521
1522 ## system bus only listens on local domain sockets, and never
1523 ## on an abstract socket (so only root can create the socket)
1524 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1525 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1526 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1527
1528 #### Set up the pid file
1529 if ! test -z "$with_system_pid_file"; then
1530    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1531 elif test x$with_init_scripts = xredhat ; then
1532    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1533 else
1534    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1535 fi
1536
1537 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1538
1539 #### Directory to check for console ownership
1540 if ! test -z "$with_console_auth_dir"; then
1541    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1542 else
1543    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1544 fi
1545
1546 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1547 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1548
1549 #### File to check for console ownership
1550 if test x$have_console_owner_file = xyes; then
1551    if ! test -z "$with_console_owner_file"; then
1552       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1553    else
1554       DBUS_CONSOLE_OWNER_FILE=/dev/console
1555    fi
1556 else
1557   DBUS_CONSOLE_OWNER_FILE=
1558 fi
1559
1560 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1561 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1562
1563 #### User to start the system bus as
1564 if test -z "$with_dbus_user" ; then
1565     DBUS_USER=messagebus
1566 else
1567     DBUS_USER=$with_dbus_user
1568 fi
1569 AC_SUBST(DBUS_USER)
1570 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1571
1572 #### Prefix to install into
1573 DBUS_PREFIX=$EXPANDED_PREFIX
1574 AC_SUBST(DBUS_PREFIX)
1575 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1576
1577 #### Direcotry to install data files into
1578 DBUS_DATADIR=$EXPANDED_DATADIR
1579 AC_SUBST(DBUS_DATADIR)
1580 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1581
1582 #### Directory to install dbus-daemon
1583 if test -z "$with_dbus_daemondir" ; then
1584     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1585 else
1586     DBUS_DAEMONDIR=$with_dbus_daemondir
1587 fi
1588 AC_SUBST(DBUS_DAEMONDIR)
1589 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1590
1591 #### Directory to install the other binaries
1592 DBUS_BINDIR="$EXPANDED_BINDIR"
1593 AC_SUBST(DBUS_BINDIR)
1594 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1595
1596 #### Directory to install the libexec binaries
1597 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1598 AC_SUBST(DBUS_LIBEXECDIR)
1599 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1600
1601 #### Tell tests where to find certain stuff in builddir
1602
1603 DBUS_PWD=`pwd`
1604 # Useful in a cross-compilation environment, where the tests are run on the host system.
1605 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1606                            DBUS_PWD=$withval)
1607
1608 DBUS_TEST_EXEC="$DBUS_PWD/test"
1609 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1610
1611 AC_SUBST([DBUS_TEST_DATA])
1612 AC_SUBST([DBUS_TEST_EXEC])
1613
1614 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1615                    [Full path to the daemon in the builddir])
1616 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1617                    [Extension for executables, typically empty or .exe])
1618
1619 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, ["$DBUS_PWD/bus/dbus-daemon$EXEEXT"],
1620                    [Full path to the daemon in the builddir])
1621 AC_SUBST(TEST_BUS_BINARY)
1622
1623 ## Export the non-setuid external helper
1624 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1625 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1626 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1627                    [Full path to the launch helper test program in the builddir])
1628
1629 #### Find socket directories
1630 if ! test -z "$TMPDIR" ; then
1631    DEFAULT_SOCKET_DIR=$TMPDIR
1632 elif ! test -z "$TEMP" ; then
1633    DEFAULT_SOCKET_DIR=$TEMP
1634 elif ! test -z "$TMP" ; then
1635    DEFAULT_SOCKET_DIR=$TMP
1636 else
1637    DEFAULT_SOCKET_DIR=/tmp
1638 fi
1639
1640 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1641
1642 if ! test -z "$with_test_socket_dir" ; then
1643    TEST_SOCKET_DIR="$with_test_socket_dir"
1644 else
1645    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1646 fi
1647 AC_SUBST(TEST_SOCKET_DIR)
1648 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1649
1650 if test "x$dbus_unix" = xyes; then
1651   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1652 else
1653   TEST_LISTEN="tcp:host=localhost"
1654 fi
1655 AC_SUBST([TEST_LISTEN])
1656 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1657   [Listening address for regression tests])
1658
1659 if ! test -z "$with_session_socket_dir" ; then
1660    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1661 else
1662    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1663 fi
1664 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1665 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1666
1667 if test x$dbus_win = xyes; then
1668         DBUS_SESSION_BUS_DEFAULT_ADDRESS="$with_dbus_session_bus_default_address"
1669 elif test x$have_launchd = xyes; then
1670         DBUS_SESSION_BUS_DEFAULT_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1671 else
1672         DBUS_SESSION_BUS_DEFAULT_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1673 fi
1674 AC_SUBST(DBUS_SESSION_BUS_DEFAULT_ADDRESS)
1675
1676 # darwin needs this to initialize the environment
1677 AC_CHECK_HEADERS(crt_externs.h)
1678 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1679 AH_VERBATIM(_DARWIN_ENVIRON,
1680 [
1681 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1682 # include <sys/time.h>
1683 # include <crt_externs.h>
1684 # define environ (*_NSGetEnviron())
1685 #endif
1686 ])
1687
1688 AC_ARG_ENABLE([stats],
1689   [AS_HELP_STRING([--enable-stats],
1690     [enable bus daemon usage statistics])],
1691   [], [enable_stats=no])
1692 if test "x$enable_stats" = xyes; then
1693   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1694     [Define to enable bus daemon usage statistics])
1695 fi
1696
1697 AC_CONFIG_FILES([
1698 Doxyfile
1699 dbus/versioninfo.rc
1700 dbus/dbus-arch-deps.h
1701 bus/system.conf
1702 bus/session.conf
1703 bus/messagebus
1704 bus/messagebus-config
1705 bus/org.freedesktop.dbus-session.plist
1706 bus/rc.messagebus
1707 bus/dbus.service
1708 bus/dbus.socket
1709 Makefile
1710 dbus/Makefile
1711 bus/Makefile
1712 tools/Makefile
1713 test/Makefile
1714 test/name-test/Makefile
1715 doc/Makefile
1716 doc/dbus-daemon.1
1717 dbus-1.pc
1718 dbus-1-uninstalled.pc
1719 test/data/valid-config-files/debug-allow-all.conf
1720 test/data/valid-config-files/debug-allow-all-sha1.conf
1721 test/data/valid-config-files-system/debug-allow-all-pass.conf
1722 test/data/valid-config-files-system/debug-allow-all-fail.conf
1723 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1724 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1725 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1726 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1727 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1728 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1729 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1730 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1731 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1732 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1733 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1734 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1735 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1736 ])
1737 AC_OUTPUT
1738
1739 dnl ==========================================================================
1740 echo "
1741                     D-Bus $VERSION
1742                   ==============
1743
1744         prefix:                   ${EXPANDED_PREFIX}
1745         exec_prefix:              ${exec_prefix}
1746         libdir:                   ${EXPANDED_LIBDIR}
1747         libexecdir:               ${EXPANDED_LIBEXECDIR}
1748         bindir:                   ${EXPANDED_BINDIR}
1749         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1750         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1751         datadir:                  ${EXPANDED_DATADIR}
1752         source code location:     ${srcdir}
1753         compiler:                 ${CC}
1754         cflags:                   ${CFLAGS}
1755         cppflags:                 ${CPPFLAGS}
1756         cxxflags:                 ${CXXFLAGS}
1757         64-bit int:               ${DBUS_INT64_TYPE}
1758         32-bit int:               ${DBUS_INT32_TYPE}
1759         16-bit int:               ${DBUS_INT16_TYPE}
1760         Doxygen:                  ${DOXYGEN:-not found}
1761         xmlto:                    ${XMLTO:-not found}
1762         man2html:                 ${MAN2HTML:-not found}"
1763
1764 echo "
1765         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1766         gcc coverage profiling:   ${enable_compiler_coverage}
1767         Building embedded tests:  ${enable_embedded_tests}
1768         Building modular tests:   ${enable_modular_tests}
1769             - with GLib:          ${with_glib}
1770         Building verbose mode:    ${enable_verbose_mode}
1771         Building assertions:      ${enable_asserts}
1772         Building checks:          ${enable_checks}
1773         Building bus stats API:   ${enable_stats}
1774         Building SELinux support: ${have_selinux}
1775         Building inotify support: ${have_inotify}
1776         Building dnotify support: ${have_dnotify}
1777         Building kqueue support:  ${have_kqueue}
1778         Building systemd support: ${have_systemd}
1779         Building X11 code:        ${enable_x11}
1780         Building Doxygen docs:    ${enable_doxygen_docs}
1781         Building XML docs:        ${enable_xml_docs}
1782         Building cache support:   ${enable_userdb_cache}
1783         Building launchd support: ${have_launchd}
1784         Using XML parser:         ${with_xml}
1785         Init scripts style:       ${with_init_scripts}
1786         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1787         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1788         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1789         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1790         Session bus address:      ${DBUS_SESSION_BUS_DEFAULT_ADDRESS}
1791         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1792         Console owner file:       ${have_console_owner_file}
1793         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1794         System bus user:          ${DBUS_USER}
1795         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1796         'make check' socket dir:  ${TEST_SOCKET_DIR}
1797 "
1798 if test x$have_launchd = xyes; then
1799         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1800 fi
1801 echo
1802
1803 if test x$enable_embedded_tests = xyes; then
1804         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1805 fi
1806 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1807         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1808 fi
1809 if test x$enable_compiler_coverage = xyes; then
1810         echo "NOTE: building with coverage profiling is definitely for developers only."
1811 fi
1812 if test x$enable_verbose_mode = xyes; then
1813         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1814 fi
1815 if test x$enable_asserts = xyes; then
1816         echo "NOTE: building with assertions increases library size and decreases performance."
1817 fi
1818 if test x$enable_checks = xno; then
1819         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1820 fi
1821 if test x$dbus_use_libxml = xtrue; then
1822         echo
1823         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1824 fi
1825
1826 if test "x$DBUS_HAVE_INT64" = x0; then
1827   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1828
1829   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1830   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1831   used if your compiler lacks support for 64-bit integers. Please report a bug
1832   with details of your platform and compiler.
1833
1834   This option is likely to be removed in future, unless the D-Bus developers
1835   receive reports that it is still needed.
1836   ])
1837 fi